add install-includes: field
[packages/pretty.git] / Foreign / Marshal / Array.hs
1 {-# OPTIONS_GHC -fno-implicit-prelude #-}
2 -----------------------------------------------------------------------------
3 -- |
4 -- Module : Foreign.Marshal.Array
5 -- Copyright : (c) The FFI task force 2001
6 -- License : BSD-style (see the file libraries/base/LICENSE)
7 --
8 -- Maintainer : ffi@haskell.org
9 -- Stability : provisional
10 -- Portability : portable
11 --
12 -- Marshalling support: routines allocating, storing, and retrieving Haskell
13 -- lists that are represented as arrays in the foreign language
14 --
15 -----------------------------------------------------------------------------
16
17 module Foreign.Marshal.Array (
18 -- * Marshalling arrays
19
20 -- ** Allocation
21 --
22 mallocArray, -- :: Storable a => Int -> IO (Ptr a)
23 mallocArray0, -- :: Storable a => Int -> IO (Ptr a)
24
25 allocaArray, -- :: Storable a => Int -> (Ptr a -> IO b) -> IO b
26 allocaArray0, -- :: Storable a => Int -> (Ptr a -> IO b) -> IO b
27
28 reallocArray, -- :: Storable a => Ptr a -> Int -> IO (Ptr a)
29 reallocArray0, -- :: Storable a => Ptr a -> Int -> IO (Ptr a)
30
31 -- ** Marshalling
32 --
33 peekArray, -- :: Storable a => Int -> Ptr a -> IO [a]
34 peekArray0, -- :: (Storable a, Eq a) => a -> Ptr a -> IO [a]
35
36 pokeArray, -- :: Storable a => Ptr a -> [a] -> IO ()
37 pokeArray0, -- :: Storable a => a -> Ptr a -> [a] -> IO ()
38
39 -- ** Combined allocation and marshalling
40 --
41 newArray, -- :: Storable a => [a] -> IO (Ptr a)
42 newArray0, -- :: Storable a => a -> [a] -> IO (Ptr a)
43
44 withArray, -- :: Storable a => [a] -> (Ptr a -> IO b) -> IO b
45 withArray0, -- :: Storable a => a -> [a] -> (Ptr a -> IO b) -> IO b
46
47 withArrayLen, -- :: Storable a => [a] -> (Int -> Ptr a -> IO b) -> IO b
48 withArrayLen0, -- :: Storable a => a -> [a] -> (Int -> Ptr a -> IO b) -> IO b
49
50 -- ** Copying
51
52 -- | (argument order: destination, source)
53 copyArray, -- :: Storable a => Ptr a -> Ptr a -> Int -> IO ()
54 moveArray, -- :: Storable a => Ptr a -> Ptr a -> Int -> IO ()
55
56 -- ** Finding the length
57 --
58 lengthArray0, -- :: (Storable a, Eq a) => a -> Ptr a -> IO Int
59
60 -- ** Indexing
61 --
62 advancePtr, -- :: Storable a => Ptr a -> Int -> Ptr a
63 ) where
64
65 import Control.Monad
66 import Foreign.Ptr (Ptr, plusPtr)
67 import Foreign.Storable (Storable(sizeOf,peekElemOff,pokeElemOff))
68 import Foreign.Marshal.Alloc (mallocBytes, allocaBytes, reallocBytes)
69 import Foreign.Marshal.Utils (copyBytes, moveBytes)
70
71 #ifdef __GLASGOW_HASKELL__
72 import GHC.IOBase
73 import GHC.Num
74 import GHC.List
75 import GHC.Err
76 import GHC.Base
77 #endif
78
79 -- allocation
80 -- ----------
81
82 -- |Allocate storage for the given number of elements of a storable type
83 -- (like 'Foreign.Marshal.Alloc.malloc', but for multiple elements).
84 --
85 mallocArray :: Storable a => Int -> IO (Ptr a)
86 mallocArray = doMalloc undefined
87 where
88 doMalloc :: Storable a' => a' -> Int -> IO (Ptr a')
89 doMalloc dummy size = mallocBytes (size * sizeOf dummy)
90
91 -- |Like 'mallocArray', but add an extra position to hold a special
92 -- termination element.
93 --
94 mallocArray0 :: Storable a => Int -> IO (Ptr a)
95 mallocArray0 size = mallocArray (size + 1)
96
97 -- |Temporarily allocate space for the given number of elements
98 -- (like 'Foreign.Marshal.Alloc.alloca', but for multiple elements).
99 --
100 allocaArray :: Storable a => Int -> (Ptr a -> IO b) -> IO b
101 allocaArray = doAlloca undefined
102 where
103 doAlloca :: Storable a' => a' -> Int -> (Ptr a' -> IO b') -> IO b'
104 doAlloca dummy size = allocaBytes (size * sizeOf dummy)
105
106 -- |Like 'allocaArray', but add an extra position to hold a special
107 -- termination element.
108 --
109 allocaArray0 :: Storable a => Int -> (Ptr a -> IO b) -> IO b
110 allocaArray0 size = allocaArray (size + 1)
111
112 -- |Adjust the size of an array
113 --
114 reallocArray :: Storable a => Ptr a -> Int -> IO (Ptr a)
115 reallocArray = doRealloc undefined
116 where
117 doRealloc :: Storable a' => a' -> Ptr a' -> Int -> IO (Ptr a')
118 doRealloc dummy ptr size = reallocBytes ptr (size * sizeOf dummy)
119
120 -- |Adjust the size of an array including an extra position for the end marker.
121 --
122 reallocArray0 :: Storable a => Ptr a -> Int -> IO (Ptr a)
123 reallocArray0 ptr size = reallocArray ptr (size + 1)
124
125
126 -- marshalling
127 -- -----------
128
129 -- |Convert an array of given length into a Haskell list. This version
130 -- traverses the array backwards using an accumulating parameter,
131 -- which uses constant stack space. The previous version using mapM
132 -- needed linear stack space.
133 --
134 peekArray :: Storable a => Int -> Ptr a -> IO [a]
135 peekArray size ptr | size <= 0 = return []
136 | otherwise = f (size-1) []
137 where
138 f 0 acc = do e <- peekElemOff ptr 0; return (e:acc)
139 f n acc = do e <- peekElemOff ptr n; f (n-1) (e:acc)
140
141 -- |Convert an array terminated by the given end marker into a Haskell list
142 --
143 peekArray0 :: (Storable a, Eq a) => a -> Ptr a -> IO [a]
144 peekArray0 marker ptr = do
145 size <- lengthArray0 marker ptr
146 peekArray size ptr
147
148 -- |Write the list elements consecutive into memory
149 --
150 pokeArray :: Storable a => Ptr a -> [a] -> IO ()
151 #ifndef __GLASGOW_HASKELL__
152 pokeArray ptr vals = zipWithM_ (pokeElemOff ptr) [0..] vals
153 #else
154 pokeArray ptr vals = go vals 0#
155 where go [] n# = return ()
156 go (val:vals) n# = do pokeElemOff ptr (I# n#) val; go vals (n# +# 1#)
157 #endif
158
159 -- |Write the list elements consecutive into memory and terminate them with the
160 -- given marker element
161 --
162 pokeArray0 :: Storable a => a -> Ptr a -> [a] -> IO ()
163 #ifndef __GLASGOW_HASKELL__
164 pokeArray0 marker ptr vals = do
165 pokeArray ptr vals
166 pokeElemOff ptr (length vals) marker
167 #else
168 pokeArray0 marker ptr vals = go vals 0#
169 where go [] n# = pokeElemOff ptr (I# n#) marker
170 go (val:vals) n# = do pokeElemOff ptr (I# n#) val; go vals (n# +# 1#)
171 #endif
172
173
174 -- combined allocation and marshalling
175 -- -----------------------------------
176
177 -- |Write a list of storable elements into a newly allocated, consecutive
178 -- sequence of storable values
179 -- (like 'Foreign.Marshal.Utils.new', but for multiple elements).
180 --
181 newArray :: Storable a => [a] -> IO (Ptr a)
182 newArray vals = do
183 ptr <- mallocArray (length vals)
184 pokeArray ptr vals
185 return ptr
186
187 -- |Write a list of storable elements into a newly allocated, consecutive
188 -- sequence of storable values, where the end is fixed by the given end marker
189 --
190 newArray0 :: Storable a => a -> [a] -> IO (Ptr a)
191 newArray0 marker vals = do
192 ptr <- mallocArray0 (length vals)
193 pokeArray0 marker ptr vals
194 return ptr
195
196 -- |Temporarily store a list of storable values in memory
197 -- (like 'Foreign.Marshal.Utils.with', but for multiple elements).
198 --
199 withArray :: Storable a => [a] -> (Ptr a -> IO b) -> IO b
200 withArray vals = withArrayLen vals . const
201
202 -- |Like 'withArray', but the action gets the number of values
203 -- as an additional parameter
204 --
205 withArrayLen :: Storable a => [a] -> (Int -> Ptr a -> IO b) -> IO b
206 withArrayLen vals f =
207 allocaArray len $ \ptr -> do
208 pokeArray ptr vals
209 res <- f len ptr
210 return res
211 where
212 len = length vals
213
214 -- |Like 'withArray', but a terminator indicates where the array ends
215 --
216 withArray0 :: Storable a => a -> [a] -> (Ptr a -> IO b) -> IO b
217 withArray0 marker vals = withArrayLen0 marker vals . const
218
219 -- |Like 'withArrayLen', but a terminator indicates where the array ends
220 --
221 withArrayLen0 :: Storable a => a -> [a] -> (Int -> Ptr a -> IO b) -> IO b
222 withArrayLen0 marker vals f =
223 allocaArray0 len $ \ptr -> do
224 pokeArray0 marker ptr vals
225 res <- f len ptr
226 return res
227 where
228 len = length vals
229
230
231 -- copying (argument order: destination, source)
232 -- -------
233
234 -- |Copy the given number of elements from the second array (source) into the
235 -- first array (destination); the copied areas may /not/ overlap
236 --
237 copyArray :: Storable a => Ptr a -> Ptr a -> Int -> IO ()
238 copyArray = doCopy undefined
239 where
240 doCopy :: Storable a' => a' -> Ptr a' -> Ptr a' -> Int -> IO ()
241 doCopy dummy dest src size = copyBytes dest src (size * sizeOf dummy)
242
243 -- |Copy the given number of elements from the second array (source) into the
244 -- first array (destination); the copied areas /may/ overlap
245 --
246 moveArray :: Storable a => Ptr a -> Ptr a -> Int -> IO ()
247 moveArray = doMove undefined
248 where
249 doMove :: Storable a' => a' -> Ptr a' -> Ptr a' -> Int -> IO ()
250 doMove dummy dest src size = moveBytes dest src (size * sizeOf dummy)
251
252
253 -- finding the length
254 -- ------------------
255
256 -- |Return the number of elements in an array, excluding the terminator
257 --
258 lengthArray0 :: (Storable a, Eq a) => a -> Ptr a -> IO Int
259 lengthArray0 marker ptr = loop 0
260 where
261 loop i = do
262 val <- peekElemOff ptr i
263 if val == marker then return i else loop (i+1)
264
265
266 -- indexing
267 -- --------
268
269 -- |Advance a pointer into an array by the given number of elements
270 --
271 advancePtr :: Storable a => Ptr a -> Int -> Ptr a
272 advancePtr = doAdvance undefined
273 where
274 doAdvance :: Storable a' => a' -> Ptr a' -> Int -> Ptr a'
275 doAdvance dummy ptr i = ptr `plusPtr` (i * sizeOf dummy)