Provide way to build using existing C compiler on Windows.
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.3], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl this makes sure `./configure --target=<cross-compile-target>`
37 dnl works as expected, since we're slightly modifying how Autoconf
38 dnl interprets build/host/target and how this interacts with $CC tests
39 test -n "$target_alias" && ac_tool_prefix=$target_alias-
40
41 dnl ----------------------------------------------------------
42 dnl ** Find unixy sort and find commands,
43 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
44
45 dnl ** Find find command (for Win32's benefit)
46 FP_PROG_FIND
47 FP_PROG_SORT
48
49 dnl ----------------------------------------------------------
50 FP_SETUP_PROJECT_VERSION
51
52 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
53 AC_SUBST([release], [1])
54
55 # First off, a distrib sanity check..
56 AC_CONFIG_SRCDIR([mk/config.mk.in])
57
58 dnl * We require autoconf version 2.60
59 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
60 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
61 dnl Using autoconf 2.59 started to give nonsense like this
62 dnl  #define SIZEOF_CHAR 0
63 dnl recently.
64 AC_PREREQ([2.60])
65
66 # -------------------------------------------------------------------------
67 # Prepare to generate the following header files
68 #
69 #
70 AC_CONFIG_HEADER(mk/config.h)
71
72 # No, semi-sadly, we don't do `--srcdir'...
73 if test x"$srcdir" != 'x.' ; then
74     echo "This configuration does not support the \`--srcdir' option.."
75     exit 1
76 fi
77
78 dnl --------------------------------------------------------------
79 dnl * Project specific configuration options
80 dnl --------------------------------------------------------------
81 dnl What follows is a bunch of options that can either be configured
82 dnl through command line options to the configure script or by
83 dnl supplying defns in the build tree's mk/build.mk. Having the option to
84 dnl use either is considered a Feature.
85
86 dnl ** What command to use to compile compiler sources ?
87 dnl --------------------------------------------------------------
88
89 AC_ARG_WITH([ghc],
90 [AC_HELP_STRING([--with-ghc=ARG],
91   [Use ARG as the path to GHC  [default=autodetect]])],
92   [WithGhc="$withval"],
93   [if test "$GHC" = ""; then
94     AC_PATH_PROG([GHC], [ghc])
95   fi
96   WithGhc="$GHC"])
97
98 dnl ** Tell the make system which OS we are using
99 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
100 AC_SUBST(OSTYPE)
101
102 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
103 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
104                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
105         EnableBootstrapWithDevelSnaphost=YES,
106         EnableBootstrapWithDevelSnaphost=NO
107 )
108
109 AC_ARG_ENABLE(tarballs-autodownload,
110 [AC_HELP_STRING([--enable-tarballs-autodownload],
111                 [Automatically download Windows distribution binaries if needed.])],
112         TarballsAutodownload=YES,
113         TarballsAutodownload=NO
114 )
115
116 AC_ARG_ENABLE(distro-toolchain,
117 [AC_HELP_STRING([--enable-distro-toolchain],
118                 [Do not use bundled Windows toolchain binaries.])],
119         EnableDistroToolchain=YES,
120         EnableDistroToolchain=NO
121 )
122
123 if test "$EnableDistroToolchain" = "YES"; then
124   TarballsAutodownload=NO
125 fi
126
127 dnl CC_STAGE0 is like the "previous" variable CC (inherited by CC_STAGE[123])
128 dnl but instead used by stage0 for bootstrapping stage1
129 AC_ARG_VAR(CC_STAGE0, [C compiler command (bootstrap)])
130
131 if test "$WithGhc" != ""; then
132   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
133
134   if test "$GhcMajVersion" = "unknown" || test "$GhcMinVersion" = "unknown"; then
135      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
136   fi
137
138   AC_SUBST(GhcVersion)dnl
139   AC_SUBST(GhcMajVersion)dnl
140   AC_SUBST(GhcMinVersion)dnl
141   AC_SUBST(GhcPatchLevel)dnl
142   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
143   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
144
145   dnl infer CC_STAGE0 from `ghc --info` unless explicitly set by user
146   if test -z "$CC_STAGE0"; then
147     BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
148   fi
149
150   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
151   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
152   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
153   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
154 fi
155
156 dnl ** Must have GHC to build GHC
157 if test "$WithGhc" = ""
158 then
159     AC_MSG_ERROR([GHC is required.])
160 fi
161 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.10],
162     [AC_MSG_ERROR([GHC version 7.10 or later is required to compile GHC.])])
163
164 if test `expr $GhcMinVersion % 2` = "1"
165 then
166     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
167     then
168         AC_MSG_ERROR([
169      $WithGhc is a development snapshot of GHC, version $GhcVersion.
170      Bootstrapping using this version of GHC is not supported, and may not
171      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
172      or --with-ghc to specify a different GHC to use.])
173     fi
174 fi
175
176 GHC_PACKAGE_DB_FLAG=package-db
177 AC_SUBST(GHC_PACKAGE_DB_FLAG)
178
179 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.11],
180                     SUPPORTS_THIS_UNIT_ID=NO,
181                     SUPPORTS_THIS_UNIT_ID=YES)
182 AC_SUBST(SUPPORTS_THIS_UNIT_ID)
183
184 # GHC is passed to Cabal, so we need a native path
185 if test "${WithGhc}" != ""
186 then
187     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
188
189     if test "$ghc_host_os" = "mingw32"
190     then
191         if test "${OSTYPE}" = "msys"
192         then
193             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
194         else
195             # Canonicalise to <drive>:/path/to/ghc
196             WithGhc=`cygpath -m "${WithGhc}"`
197         fi
198         echo "GHC path canonicalised to: ${WithGhc}"
199     fi
200 fi
201 AC_SUBST([WithGhc])
202
203 dnl ** Without optimization some INLINE trickery fails for GHCi
204 SRC_CC_OPTS="-O"
205
206 dnl--------------------------------------------------------------------
207 dnl * Choose host(/target/build) platform
208 dnl--------------------------------------------------------------------
209 dnl If we aren't explicitly told what values to use with configure flags,
210 dnl we ask the bootstrapping compiler what platform it is for
211
212 if test "${WithGhc}" != ""
213 then
214         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
215         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
216         if test "$bootstrap_host" != "$bootstrap_target"
217         then
218                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
219         fi
220 fi
221
222 # We have to run these unconditionally, but we may discard their
223 # results in the following code
224 AC_CANONICAL_BUILD
225 AC_CANONICAL_HOST
226 AC_CANONICAL_TARGET
227
228 FPTOOLS_SET_PLATFORM_VARS
229
230 # Verify that the installed (bootstrap) GHC is capable of generating
231 # code for the requested build platform.
232 if test "$BuildPlatform" != "$bootstrap_target"
233 then
234     echo "This GHC (${WithGhc}) does not generate code for the build platform"
235     echo "   GHC target platform    : $bootstrap_target"
236     echo "   Desired build platform : $BuildPlatform"
237     exit 1
238 fi
239
240 # Testing if we shall enable shared libs support on Solaris.
241 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
242
243 SOLARIS_BROKEN_SHLD=NO
244
245 case $host in
246      i386-*-solaris2)
247      # here we go with the test
248      MINOR=`uname -r|cut -d '.' -f 2-`
249      if test "$MINOR" -lt "11"; then
250          SOLARIS_BROKEN_SHLD=YES
251      fi
252      ;;
253 esac
254
255 AC_SUBST(SOLARIS_BROKEN_SHLD)
256
257 dnl ** Do an unregisterised build?
258 dnl --------------------------------------------------------------
259 case "$TargetArch" in
260     i386|x86_64|powerpc|powerpc64|powerpc64le|arm|aarch64)
261         UnregisterisedDefault=NO
262         ;;
263     *)
264         UnregisterisedDefault=YES
265         ;;
266 esac
267 AC_ARG_ENABLE(unregisterised,
268 [AC_HELP_STRING([--enable-unregisterised],
269 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
270 [ if test x"$enableval" = x"yes"; then
271         Unregisterised=YES
272   else
273         Unregisterised=NO
274   fi
275 ],
276 [Unregisterised="$UnregisterisedDefault"]
277 )
278 AC_SUBST(Unregisterised)
279
280 dnl ** Does target have runtime linker support?
281 dnl --------------------------------------------------------------
282 case "$target" in
283     powerpc64-*|powerpc64le-*|powerpc-ibm-aix*)
284         HaskellHaveRTSLinker=NO
285         ;;
286     *)
287         HaskellHaveRTSLinker=YES
288         ;;
289 esac
290 AC_SUBST(HaskellHaveRTSLinker)
291
292 # Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
293 FP_FIND_ROOT
294
295 fail() {
296     echo >&2
297     echo "$1" >&2
298     exit 1
299 }
300
301
302 if test "$HostOS" = "mingw32"
303 then
304     # Find the mingw-w64 7z file to extract.
305     # NB. If you update the tarballs to a new version of gcc, don't
306     # forget to tweak the paths in driver/gcc/gcc.c.
307     if test "$HostArch" = "i386"
308     then
309         mingw_arch="i686"
310         tarball_dest_dir="mingw-w64/x86"
311         tarball_mingw_dir="mingw32"
312     else
313         mingw_arch="x86_64"
314         tarball_dest_dir="mingw-w64/x86_64"
315         tarball_mingw_dir="mingw64"
316     fi
317 fi
318
319 set_up_tarballs() {
320     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
321     local action
322     if test "$TarballsAutodownload" = "NO"
323     then
324         action="verify"
325     else
326         action="download"
327     fi
328     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
329     case $? in
330         0)
331            rm missing-win32-tarballs
332            ;;
333         2)
334            echo
335            echo "Error:"
336            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
337            echo
338            echo "  * run configure with the --enable-tarballs-autodownload option"
339            echo
340            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
341            echo
342            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
343            echo "    them in the ghc-tarballs directory."
344            echo
345            exit 1
346            ;;
347         *)
348            echo
349            echo "Error fetching msys2 tarballs; see errors above."
350            exit 1
351            ;;
352     esac
353
354     # Extract all the tarballs in one go
355     if ! test -d inplace/mingw
356     then
357         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
358         rm -rf inplace/mingw
359         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
360         ( cd inplace &&
361         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
362         rm ".MTREE" &&
363         rm ".PKGINFO" &&
364         cd .. ) || fail "Error: Could not extract Windows toolchains."
365
366         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
367         touch inplace/mingw
368
369         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
370         # make a wrapper around it to give it the proper paths
371         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
372         PATH=`pwd`/inplace/mingw/bin:$PATH
373         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
374
375         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
376     fi
377 }
378
379 if test "$HostOS" = "mingw32" -a "$EnableDistroToolchain" = "NO"
380 then
381     test -d inplace || mkdir inplace
382
383     # NB. Download and extract the MingW-w64 distribution if required
384     set_up_tarballs
385
386     mingwbin="$hardtop/inplace/mingw/bin/"
387     CC="${mingwbin}gcc.exe"
388     LD="${mingwbin}ld.exe"
389     NM="${mingwbin}nm.exe"
390     RANLIB="${mingwbin}ranlib.exe"
391     OBJDUMP="${mingwbin}objdump.exe"
392     fp_prog_ar="${mingwbin}ar.exe"
393
394     # NB. Download the perl binaries if required
395     if ! test -d inplace/perl ||
396          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
397     then
398         AC_MSG_NOTICE([Making in-tree perl tree])
399         rm -rf inplace/perl
400         mkdir inplace/perl
401         (
402             cd inplace/perl &&
403             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
404         )
405         AC_MSG_NOTICE([In-tree perl tree created])
406     fi
407 fi
408
409 # We don't want to bundle a MinGW-w64 toolchain
410 # So we have to find these individual tools.
411 if test "$EnableDistroToolchain" = "YES"
412 then
413     # Ideally should use AC_CHECK_TARGET_TOOL but our triples
414     # are screwed up. Configure doesn't think they're ever equal and
415     # so never tried without the prefix.
416     AC_PATH_PROG([CC],[gcc], [clang])
417     AC_PATH_PROG([LD],[ld], [lld])
418     AC_PATH_PROG([NM],[nm])
419     AC_PATH_PROG([AR],[ar])
420     AC_PATH_PROG([RANLIB],[ranlib])
421     AC_PATH_PROG([OBJDUMP],[objdump])
422     AC_PATH_PROG([DllWrap],[dllwrap])
423     AC_PATH_PROG([Windres],[windres])
424
425     DllWrapCmd="$DllWrap"
426     WindresCmd="$Windres"
427
428     AC_SUBST([DllWrapCmd])
429     AC_SUBST([WindresCmd])
430 fi
431
432 FP_ICONV
433 FP_GMP
434 FP_CURSES
435
436 XCODE_VERSION()
437
438
439 dnl ** Building a cross compiler?
440 dnl --------------------------------------------------------------
441 CrossCompiling=NO
442 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
443 if test "$TargetPlatform" != "$HostPlatform" ; then
444     CrossCompiling=YES
445     cross_compiling=yes   # This tells configure that it can accept just 'target',
446                           # otherwise you get
447                           #   configure: error: cannot run C compiled programs.
448                           #   If you meant to cross compile, use `--host'.
449 fi
450 if test "$BuildPlatform" != "$HostPlatform" ; then
451    AC_MSG_ERROR([
452 You've selected:
453
454   BUILD:  $BuildPlatform   (the architecture we're building on)
455   HOST:   $HostPlatform    (the architecture the compiler we're building will execute on)
456   TARGET: $TargetPlatform  (the architecture the compiler we're building will produce code for)
457
458 BUILD must equal HOST; that is, we do not support building GHC itself
459 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
460 1 will be a cross-compiler, and stage 2 will be the cross-compiled
461 GHC.
462 ])
463 fi
464 # Despite its similarity in name to TargetPlatform, TargetPlatformFull is used
465 # in calls to subproject configure scripts and thus must be set to the autoconf
466 # triple, not the normalized GHC triple that TargetPlatform is set to.
467 #
468 # We use the non-canonicalized triple, target_alias, here since the subproject
469 # configure scripts will use this triple to construct the names of the toolchain
470 # executables. If we instead passed down the triple produced by
471 # AC_CANONICAL_TARGET then it may look for the target toolchain under the wrong
472 # name (this is a known problem in the case of the Android NDK, which has
473 # slightly odd triples).
474 #
475 # It may be better to just do away with the GHC triples altogether. This would
476 # all be taken care of for us if we configured the subprojects using
477 # AC_CONFIG_DIR, but unfortunately Cabal needs to be the one to do the
478 # configuration.
479 #
480 # We also use non-canonicalized triple when install stage1 crosscompiler
481 if test -z "${target_alias}"
482 then
483   # --target wasn't given; use result from AC_CANONICAL_TARGET
484   TargetPlatformFull="${target}"
485 else
486   TargetPlatformFull="${target_alias}"
487 fi
488 if test "$CrossCompiling" = "YES"
489 then
490   # Use value passed by user from --target=
491   CrossCompilePrefix="${TargetPlatformFull}-"
492 else
493   CrossCompilePrefix=""
494 fi
495 AC_SUBST(CrossCompiling)
496 AC_SUBST(CrossCompilePrefix)
497 AC_SUBST(TargetPlatformFull)
498 AC_SUBST(EnableDistroToolchain)
499
500 dnl ** Which gcc to use?
501 dnl --------------------------------------------------------------
502
503 AC_ARG_WITH([gcc],
504         AS_HELP_STRING([--with-gcc=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
505         AC_MSG_ERROR([--with-gcc=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
506
507 AC_ARG_WITH([clang],
508         AS_HELP_STRING([--with-clang=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
509         AC_MSG_ERROR([--with-clang=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
510
511 dnl detect compiler (prefer gcc over clang) and set $CC (unless CC already set),
512 dnl later CC is copied to CC_STAGE{1,2,3}
513 AC_PROG_CC([gcc clang])
514
515 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
516
517 dnl make extensions visible to allow feature-tests to detect them lateron
518 AC_USE_SYSTEM_EXTENSIONS
519
520 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
521 AC_PROG_CPP
522
523 # --with-hs-cpp/--with-hs-cpp-flags
524 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
525 AC_SUBST([HaskellCPPCmd])
526 AC_SUBST([HaskellCPPArgs])
527
528 FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
529 FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
530 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
531 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
532
533 dnl ** Which ld to use?
534 dnl --------------------------------------------------------------
535 FIND_LD([$target],[LdCmd])
536 AC_SUBST([LdCmd])
537
538 dnl ** Which nm to use?
539 dnl --------------------------------------------------------------
540 if test "$HostOS" != "mingw32"; then
541     AC_CHECK_TARGET_TOOL([NM], [nm])
542     if test "$NM" = ":"; then
543         AC_MSG_ERROR([cannot find nm in your PATH])
544     fi
545 fi
546 NmCmd="$NM"
547 AC_SUBST([NmCmd])
548
549 if test "$TargetOS_CPP" = "darwin"
550 then
551     AC_MSG_CHECKING(whether nm program is broken)
552     # Some versions of XCode ship a broken version of `nm`. Detect and work
553     # around this issue. See : https://ghc.haskell.org/trac/ghc/ticket/11744
554     nmver=$(${NM} --version | grep version | sed 's/ //g')
555     case "$nmver" in
556         LLVMversion7.3.0|LLVMversion7.3.1)
557             AC_MSG_RESULT(yes)
558             echo "The detected nm program is broken."
559             echo
560             echo "See: https://ghc.haskell.org/trac/ghc/ticket/11744"
561             echo
562             echo "Try re-running configure with:"
563             echo
564             echo '   NM=$(xcrun --find nm-classic) ./configure'
565             echo
566             exit 1
567             ;;
568         *)
569             AC_MSG_RESULT(no)
570             ;;
571         esac
572 fi
573
574 dnl ** Which objdump to use?
575 dnl --------------------------------------------------------------
576 dnl Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
577 case $HostOS_CPP in
578   cygwin32|mingw32)
579     AC_CHECK_TARGET_TOOL([OBJDUMP], [objdump])
580     ;;
581 esac
582
583 ObjdumpCmd="$OBJDUMP"
584 AC_SUBST([ObjdumpCmd])
585
586 dnl ** Which ar to use?
587 dnl --------------------------------------------------------------
588 if test "$HostOS" != "mingw32"; then
589     AC_CHECK_TARGET_TOOL([AR], [ar])
590     if test "$AR" = ":"; then
591         AC_MSG_ERROR([cannot find ar in your PATH])
592     fi
593 fi
594 ArCmd="$AR"
595 fp_prog_ar="$AR"
596 AC_SUBST([ArCmd])
597
598 dnl ** Which ranlib to use?
599 dnl --------------------------------------------------------------
600 AC_PROG_RANLIB
601 if test "$RANLIB" = ":"; then
602     AC_MSG_ERROR([cannot find ranlib in your PATH])
603 fi
604 RanlibCmd="$RANLIB"
605 RANLIB="$RanlibCmd"
606
607 dnl ** which libtool to use?
608 dnl --------------------------------------------------------------
609 AC_CHECK_TARGET_TOOL([LIBTOOL], [libtool])
610 LibtoolCmd="$LIBTOOL"
611 LIBTOOL="$LibtoolCmd"
612
613 # Here is where we re-target which specific version of the LLVM
614 # tools we are looking for. In the past, GHC supported a number of
615 # versions of LLVM simultaneously, but that stopped working around
616 # 3.5/3.6 release of LLVM.
617 LlvmVersion=4.0
618 AC_SUBST([LlvmVersion])
619 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
620 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
621
622 dnl ** Which LLVM llc to use?
623 dnl --------------------------------------------------------------
624 FIND_LLVM_PROG([LLC], [llc], [$LlvmVersion])
625 LlcCmd="$LLC"
626 AC_SUBST([LlcCmd])
627
628 dnl ** Which LLVM opt to use?
629 dnl --------------------------------------------------------------
630 FIND_LLVM_PROG([OPT], [opt], [$LlvmVersion])
631 OptCmd="$OPT"
632 AC_SUBST([OptCmd])
633
634 dnl --------------------------------------------------------------
635 dnl End of configure script option section
636 dnl --------------------------------------------------------------
637
638
639 dnl --------------------------------------------------------------
640 dnl ** Can the unix package be built?
641 dnl --------------------------------------------------------------
642
643 if test "$TargetOS" = "mingw32"
644 then
645     GhcLibsWithUnix=NO
646 else
647     GhcLibsWithUnix=YES
648 fi
649 AC_SUBST([GhcLibsWithUnix])
650
651 dnl ** does #! work?
652 AC_SYS_INTERPRETER()
653
654 # Check for split-objs
655 SplitObjsBroken=NO
656 dnl ** look for `perl'
657 case $HostOS_CPP in
658 cygwin32|mingw32)
659   if test "$EnableDistroToolchain" = "NO"; then
660     PerlCmd=$hardtop/inplace/perl/perl
661   else
662     AC_PATH_PROG([PerlCmd],[perl])
663   fi
664   ;;
665 *)
666     AC_PATH_PROG([PerlCmd],[perl])
667     if test -z "$PerlCmd"
668     then
669         AC_MSG_WARN([No Perl on PATH, disabling split object support])
670         SplitObjsBroken=YES
671     else
672         FPTOOLS_CHECK_PERL_VERSION
673     fi
674     ;;
675 esac
676 AC_SUBST([SplitObjsBroken])
677
678 dnl ** look for GCC and find out which version
679 dnl     Figure out which C compiler to use.  Gcc is preferred.
680 dnl     If gcc, make sure it's at least 3.0
681 dnl
682 FP_GCC_VERSION
683
684 dnl ** See whether gcc supports -no-pie
685 FP_GCC_SUPPORTS_NO_PIE
686
687 dnl ** look to see if we have a C compiler using an llvm back end.
688 dnl
689 FP_CC_LLVM_BACKEND
690
691 FP_PROG_LD_IS_GNU
692 FP_PROG_LD_BUILD_ID
693 FP_PROG_LD_NO_COMPACT_UNWIND
694 FP_PROG_LD_FILELIST
695
696
697 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
698 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
699 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
700 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
701 # Stage 3 won't be supported by cross-compilation
702
703 FP_GCC_EXTRA_FLAGS
704
705 # See rules/distdir-way-opts.mk for details.
706 # Flags passed to the C compiler
707 AC_SUBST(CONF_CC_OPTS_STAGE0)
708 AC_SUBST(CONF_CC_OPTS_STAGE1)
709 AC_SUBST(CONF_CC_OPTS_STAGE2)
710 # Flags passed to the C compiler when we ask it to link
711 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
712 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
713 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
714 # Flags passed to the linker when we ask it to link
715 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
716 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
717 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
718 # Flags passed to the C preprocessor
719 AC_SUBST(CONF_CPP_OPTS_STAGE0)
720 AC_SUBST(CONF_CPP_OPTS_STAGE1)
721 AC_SUBST(CONF_CPP_OPTS_STAGE2)
722 # Flags passed to the Haskell compiler
723 AC_SUBST(CONF_HC_OPTS_STAGE0)
724 AC_SUBST(CONF_HC_OPTS_STAGE1)
725 AC_SUBST(CONF_HC_OPTS_STAGE2)
726
727 dnl ** Set up the variables for the platform in the settings file.
728 dnl May need to use gcc to find platform details.
729 dnl --------------------------------------------------------------
730 FPTOOLS_SET_HASKELL_PLATFORM_VARS
731
732 dnl ** figure out how to do context diffs
733 FP_PROG_CONTEXT_DIFF
734
735 dnl Let's make sure install-sh is executable here.  If we got it from
736 dnl a darcs repo, it might not be (see bug #978).
737 chmod +x install-sh
738 dnl ** figure out how to do a BSD-ish install
739 AC_PROG_INSTALL
740
741 dnl ** how to invoke `ar' and `ranlib'
742 FP_PROG_AR_SUPPORTS_ATFILE
743 FP_PROG_AR_NEEDS_RANLIB
744
745 dnl ** Check to see whether ln -s works
746 AC_PROG_LN_S
747
748 FP_SETTINGS
749
750 dnl ** Find the path to sed
751 AC_PATH_PROGS(SedCmd,gsed sed,sed)
752
753
754 dnl ** check for time command
755 AC_PATH_PROG(TimeCmd,time)
756
757 dnl ** check for tar
758 dnl   if GNU tar is named gtar, look for it first.
759 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
760
761 dnl ** check for compressors
762 AC_PATH_PROGS(Bzip2Cmd,bzip2, bzip2)
763 AC_PATH_PROGS(GzipCmd,gzip, gzip)
764 AC_PATH_PROGS(XzCmd,pxz xz, xz)
765
766 dnl ** check for patch
767 dnl if GNU patch is named gpatch, look for it first
768 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
769
770 dnl ** check for dtrace (currently only implemented for Mac OS X)
771 HaveDtrace=NO
772 AC_PATH_PROG(DtraceCmd,dtrace)
773 if test -n "$DtraceCmd"; then
774   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
775     HaveDtrace=YES
776   fi
777 fi
778 AC_SUBST(HaveDtrace)
779
780 AC_PATH_PROG(HSCOLOUR,HsColour)
781 # HsColour is passed to Cabal, so we need a native path
782 if test "$HostOS"      = "mingw32" && \
783    test "${OSTYPE}"   != "msys"    && \
784    test "${HSCOLOUR}" != ""
785 then
786     # Canonicalise to <drive>:/path/to/gcc
787     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
788 fi
789
790 dnl ** check for Sphinx toolchain
791 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
792 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
793 changequote(, )dnl
794 [if test -n "$SPHINXBUILD"; then
795   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
796 fi;
797 changequote([, ])dnl
798 ])
799 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
800     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
801
802 dnl ** check for xelatex
803 AC_PATH_PROG(XELATEX,xelatex)
804
805 dnl ** check for ghc-pkg command
806 FP_PROG_GHC_PKG
807
808 dnl ** check for installed happy binary + version
809 FPTOOLS_HAPPY
810
811 dnl ** check for installed alex binary + version
812 FPTOOLS_ALEX
813
814 dnl --------------------------------------------------
815 dnl ### program checking section ends here ###
816 dnl --------------------------------------------------
817
818 dnl --------------------------------------------------
819 dnl * Platform header file and syscall feature tests
820 dnl ### checking the state of the local header files and syscalls ###
821
822 dnl ** check for full ANSI header (.h) files
823 AC_HEADER_STDC
824
825 dnl ** Enable large file support.  NB. do this before testing the type of
826 dnl    off_t, because it will affect the result of that test.
827 AC_SYS_LARGEFILE
828
829 dnl ** check for specific header (.h) files that we are interested in
830 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
831
832 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
833 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
834 [[#if HAVE_SYS_PARAM_H
835 # include <sys/param.h>
836 #endif
837 ]])
838
839 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
840 AC_HEADER_TIME
841
842 dnl ** do we have long longs?
843 AC_CHECK_TYPES([long long])
844
845 dnl ** what are the sizes of various types
846 FP_CHECK_SIZEOF_AND_ALIGNMENT(char)
847 FP_CHECK_SIZEOF_AND_ALIGNMENT(double)
848 FP_CHECK_SIZEOF_AND_ALIGNMENT(float)
849 FP_CHECK_SIZEOF_AND_ALIGNMENT(int)
850 FP_CHECK_SIZEOF_AND_ALIGNMENT(long)
851 if test "$ac_cv_type_long_long" = yes; then
852 FP_CHECK_SIZEOF_AND_ALIGNMENT(long long)
853 fi
854 FP_CHECK_SIZEOF_AND_ALIGNMENT(short)
855 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned char)
856 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned int)
857 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long)
858 if test "$ac_cv_type_long_long" = yes; then
859 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long long)
860 fi
861 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned short)
862 FP_CHECK_SIZEOF_AND_ALIGNMENT(void *)
863
864 FP_CHECK_SIZEOF_AND_ALIGNMENT(int8_t)
865 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint8_t)
866 FP_CHECK_SIZEOF_AND_ALIGNMENT(int16_t)
867 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint16_t)
868 FP_CHECK_SIZEOF_AND_ALIGNMENT(int32_t)
869 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint32_t)
870 FP_CHECK_SIZEOF_AND_ALIGNMENT(int64_t)
871 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint64_t)
872
873
874 dnl for use in settings.in
875 WordSize=$ac_cv_sizeof_void_p
876 AC_SUBST(WordSize)
877 FP_CHECK_FUNC([WinExec],
878   [@%:@include <windows.h>], [WinExec("",0)])
879
880 FP_CHECK_FUNC([GetModuleFileName],
881   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
882
883 dnl ** check for more functions
884 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
885 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
886
887 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
888 dnl ** _POSIX_C_SOURCE is defined
889 AC_CHECK_DECLS([ctime_r], , ,
890 [#define _POSIX_SOURCE 1
891 #define _POSIX_C_SOURCE 199506L
892 #include <time.h>])
893
894 dnl ** check for mingwex library
895 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
896 AC_SUBST(HaveLibMingwEx)
897
898 if test $HaveLibMingwEx = YES ; then
899   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
900 fi
901
902 dnl ** check for math library
903 dnl    Keep that check as early as possible.
904 dnl    as we need to know whether we need libm
905 dnl    for math functions or not
906 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
907 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
908 if test $HaveLibM = YES
909 then
910   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
911 fi
912
913 FP_BFD_SUPPORT
914
915 dnl ################################################################
916 dnl Check for libraries
917 dnl ################################################################
918
919 # system libffi
920
921 AC_ARG_WITH([system-libffi],
922 [AC_HELP_STRING([--with-system-libffi],
923   [Use system provided libffi for RTS [default=no]])
924 ])
925
926 AS_IF([test "x$with_system_libffi" = "xyes"],
927   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
928 )
929
930
931 AC_SUBST(UseSystemLibFFI)
932
933 AC_ARG_WITH([ffi-includes],
934 [AC_HELP_STRING([--with-ffi-includes=ARG],
935   [Find includes for libffi in ARG [default=system default]])
936 ],
937 [
938  if test "x$UseSystemLibFFI" != "xYES"; then
939     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
940  else
941     FFIIncludeDir="$withval"
942     LIBFFI_CFLAGS="-I$withval"
943  fi
944 ])
945
946 AC_SUBST(FFIIncludeDir)
947
948 AC_ARG_WITH([ffi-libraries],
949 [AC_HELP_STRING([--with-ffi-libraries=ARG],
950   [Find libffi in ARG [default=system default]])
951 ],
952 [
953  if test "x$UseSystemLibFFI" != "xYES"; then
954     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
955  else
956     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
957  fi
958 ])
959
960 AC_SUBST(FFILibDir)
961
962 AS_IF([test "$UseSystemLibFFI" = "YES"], [
963  CFLAGS2="$CFLAGS"
964  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
965  LDFLAGS2="$LDFLAGS"
966  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
967  if test "$HostOS" = "openbsd";
968  then
969    # OpenBSD's libffi is not directly linked to the libpthread but
970    # still requires pthread functionality. This means that any client
971    # binary which links with libffi also needs to link with
972    # libpthread. If it does not, then linking fails with unresolved
973    # symbols.
974    LDFLAGS="$LDFLAGS -lpthread"
975  fi
976  AC_CHECK_LIB(ffi, ffi_call,
977   [AC_CHECK_HEADERS([ffi.h], [break], [])
978    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
979   [AC_MSG_ERROR([Cannot find system libffi])])
980  CFLAGS="$CFLAGS2"
981  LDFLAGS="$LDFLAGS2"
982 ])
983
984 dnl ** check whether we need -ldl to get dlopen()
985 AC_CHECK_LIB(dl, dlopen)
986
987 dnl --------------------------------------------------
988 dnl * Miscellaneous feature tests
989 dnl --------------------------------------------------
990
991 dnl ** can we get alloca?
992 AC_FUNC_ALLOCA
993
994 dnl ** working vfork?
995 AC_FUNC_FORK
996
997 dnl ** determine whether or not const works
998 AC_C_CONST
999
1000 dnl ** are we big endian?
1001 AC_C_BIGENDIAN
1002 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
1003
1004 dnl ** check for leading underscores in symbol names
1005 FP_LEADING_UNDERSCORE
1006
1007 FP_VISIBILITY_HIDDEN
1008
1009 dnl ** check for librt
1010 AC_CHECK_LIB(rt, clock_gettime)
1011 AC_CHECK_FUNCS(clock_gettime timer_settime)
1012 FP_CHECK_TIMER_CREATE
1013
1014 dnl ** check for Apple's "interesting" long double compatibility scheme
1015 AC_MSG_CHECKING(for printf\$LDBLStub)
1016 AC_TRY_LINK_FUNC(printf\$LDBLStub,
1017     [
1018         AC_MSG_RESULT(yes)
1019         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
1020             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
1021     ],
1022     [
1023         AC_MSG_RESULT(no)
1024         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
1025             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
1026     ])
1027
1028 dnl Some platforms (e.g. Android's Bionic) have pthreads support available
1029 dnl without linking against libpthread. Check whether -lpthread is necessary
1030 dnl to use pthreads.
1031 dnl
1032 dnl Note that it is important that this happens before we AC_CHECK_LIB(thread)
1033 AC_MSG_CHECKING(whether -lpthread is needed for pthreads)
1034 AC_CHECK_FUNC(pthread_create,
1035     [
1036         AC_MSG_RESULT(no)
1037         need_lpthread=0
1038     ],
1039     [
1040         AC_CHECK_LIB(pthread, pthread_create,
1041             [
1042                 AC_MSG_RESULT(yes)
1043                 need_lpthread=1
1044             ],
1045             [
1046                 AC_MSG_RESULT([no pthreads support found.])
1047                 need_lpthread=0
1048             ])
1049     ])
1050 AC_DEFINE_UNQUOTED([NEED_PTHREAD_LIB], [$need_lpthread],
1051     [Define 1 if we need to link code using pthreads with -lpthread])
1052
1053 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
1054 dnl    a different single-argument version.
1055 AC_CHECK_LIB(pthread, pthread_setname_np)
1056 AC_MSG_CHECKING(for pthread_setname_np)
1057 AC_TRY_LINK(
1058 [
1059 #define _GNU_SOURCE
1060 #include <pthread.h>
1061 ],
1062 [pthread_setname_np(pthread_self(), "name");],
1063     AC_MSG_RESULT(yes)
1064     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
1065       [Define to 1 if you have the glibc version of pthread_setname_np]),
1066     AC_MSG_RESULT(no)
1067 )
1068
1069 dnl ** check for eventfd which is needed by the I/O manager
1070 AC_CHECK_HEADERS([sys/eventfd.h])
1071 AC_CHECK_FUNCS([eventfd])
1072
1073 dnl ** Check for __thread support in the compiler
1074 AC_MSG_CHECKING(for __thread support)
1075 AC_COMPILE_IFELSE(
1076   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1077   [
1078    AC_MSG_RESULT(yes)
1079    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1080   ],
1081   [
1082    AC_MSG_RESULT(no)
1083    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1084   ])
1085
1086 dnl large address space support (see includes/rts/storage/MBlock.h)
1087 dnl
1088 dnl Darwin has vm_allocate/vm_protect
1089 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1090 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1091 dnl (They also have MADV_DONTNEED, but it means something else!)
1092 dnl
1093 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1094 dnl it counts page-table space as committed memory, and so quickly
1095 dnl runs out of paging file when we have multiple processes reserving
1096 dnl 1TB of address space, we get the following error:
1097 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1098 dnl
1099
1100 AC_ARG_ENABLE(large-address-space,
1101     [AC_HELP_STRING([--enable-large-address-space],
1102         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1103     EnableLargeAddressSpace=$enableval,
1104     EnableLargeAddressSpace=yes
1105 )
1106
1107 use_large_address_space=no
1108 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1109     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1110         if test "$ghc_host_os" = "darwin" ; then
1111             use_large_address_space=yes
1112         elif test "$ghc_host_os" = "openbsd" ; then
1113             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1114             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1115             # but is completely ignored by OS mmap
1116             use_large_address_space=no
1117         else
1118             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1119                 [
1120                 #include <unistd.h>
1121                 #include <sys/types.h>
1122                 #include <sys/mman.h>
1123                 #include <fcntl.h>
1124             ])
1125             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1126                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1127                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1128                     use_large_address_space=yes
1129             fi
1130         fi
1131     fi
1132 fi
1133 if test "$use_large_address_space" = "yes" ; then
1134    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1135 fi
1136
1137 dnl ** Use MMAP in the runtime linker?
1138 dnl --------------------------------------------------------------
1139
1140 case ${TargetOS} in
1141     linux|linux-android|freebsd|dragonfly|netbsd|openbsd|kfreebsdgnu|gnu|solaris2)
1142         RtsLinkerUseMmap=1
1143         ;;
1144     darwin|ios)
1145         # Don't use mmap on powerpc/darwin as the mmap there doesn't support
1146         # reallocating. Reallocating is needed to allocate jump islands just
1147         # after each object image. Jumps to these jump islands use relative
1148         # branches which are limited to offsets that can be represented in
1149         # 24-bits.
1150         if test "$TargetArch" != "powerpc" ; then
1151             RtsLinkerUseMmap=1
1152         else
1153             RtsLinkerUseMmap=0
1154         fi
1155         ;;
1156     *)
1157         # Windows (which doesn't have mmap) and everything else.
1158         RtsLinkerUseMmap=0
1159         ;;
1160     esac
1161
1162 AC_DEFINE_UNQUOTED([RTS_LINKER_USE_MMAP], [$RtsLinkerUseMmap],
1163                    [Use mmap in the runtime linker])
1164
1165 dnl ** Have libdw?
1166 dnl --------------------------------------------------------------
1167 UseLibdw=NO
1168 USE_LIBDW=0
1169 AC_ARG_ENABLE(dwarf-unwind,
1170     [AC_HELP_STRING([--enable-dwarf-unwind],
1171         [Enable DWARF unwinding support in the runtime system via elfutils' libdw [default=no]])],
1172     [AC_CHECK_LIB(dw, dwfl_attach_state, [UseLibdw=YES], [UseLibdw=NO])],
1173     [UseLibdw=NO]
1174 )
1175 AC_SUBST(UseLibdw)
1176 if test $UseLibdw = "YES" ; then
1177         USE_LIBDW=1
1178 fi
1179 AC_DEFINE_UNQUOTED([USE_LIBDW], [$USE_LIBDW], [Set to 1 to use libdw])
1180
1181 dnl ** Have libnuma?
1182 dnl --------------------------------------------------------------
1183 HaveLibNuma=0
1184 AC_CHECK_HEADERS([numa.h numaif.h])
1185
1186 if test "$ac_cv_header_numa_h$ac_cv_header_numaif_h" = "yesyes" ; then
1187     AC_CHECK_LIB(numa, numa_available,HaveLibNuma=1)
1188 fi
1189 AC_DEFINE_UNQUOTED([HAVE_LIBNUMA], [$HaveLibNuma], [Define to 1 if you have libnuma])
1190
1191 dnl ** Documentation
1192 dnl --------------------------------------------------------------
1193 if test -n "$SPHINXBUILD"; then
1194     BUILD_MAN=YES
1195     BUILD_SPHINX_HTML=YES
1196     if test -n "$XELATEX"; then
1197         BUILD_SPHINX_PDF=YES
1198     else
1199         BUILD_SPHINX_PDF=NO
1200     fi
1201 else
1202     BUILD_MAN=NO
1203     BUILD_SPHINX_HTML=NO
1204     BUILD_SPHINX_PDF=NO
1205 fi
1206 AC_SUBST(BUILD_MAN)
1207 AC_SUBST(BUILD_SPHINX_HTML)
1208 AC_SUBST(BUILD_SPHINX_PDF)
1209
1210 LIBRARY_VERSION(base)
1211 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1212 LIBRARY_VERSION(ghc-prim)
1213 LIBRARY_VERSION(ghc-compact)
1214 LIBRARY_ghc_VERSION="$ProjectVersion"
1215 AC_SUBST(LIBRARY_ghc_VERSION)
1216
1217 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1218    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1219 fi
1220
1221 # Create the configuration for the Hadrian build system if it is present
1222 if test -e hadrian/cfg/system.config.in; then
1223     AC_CONFIG_FILES([hadrian/cfg/system.config])
1224 fi
1225
1226 # We got caught by
1227 #     http://savannah.gnu.org/bugs/index.php?1516
1228 #     $(eval ...) inside conditionals causes errors
1229 # with make 3.80, so warn the user if it looks like they're about to
1230 # try to use it.
1231 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1232 print_make_warning=""
1233 checkMake380() {
1234     make_ver=`$1 --version 2>&1 | head -1`
1235     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1236     then
1237         print_make_warning="true"
1238     fi
1239     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1240     then
1241         MakeCmd=$1
1242         AC_SUBST(MakeCmd)
1243     fi
1244 }
1245
1246 checkMake380 make
1247 checkMake380 gmake
1248
1249 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghc-boot-th/ghc-boot-th.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt utils/mkUserGuidePart/mkUserGuidePart.cabal distrib/configure.ac])
1250 AC_OUTPUT
1251 [
1252 if test "$print_make_warning" = "true"; then
1253    echo
1254    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1255    echo "This version cannot be used to build GHC."
1256    echo "Please use GNU make >= 3.81."
1257 fi
1258
1259 echo "
1260 ----------------------------------------------------------------------
1261 Configure completed successfully.
1262
1263    Building GHC version  : $ProjectVersion
1264           Git commit id  : $ProjectGitCommitId
1265
1266    Build platform        : $BuildPlatform
1267    Host platform         : $HostPlatform
1268    Target platform       : $TargetPlatform
1269 "
1270
1271 echo "\
1272    Bootstrapping using   : $WithGhc
1273       which is version   : $GhcVersion
1274 "
1275
1276 if test "x$CC_LLVM_BACKEND" = "x1"; then
1277     if test "x$CC_CLANG_BACKEND" = "x1"; then
1278         CompilerName="clang        "
1279     else
1280         CompilerName="llvm-gcc     "
1281     fi
1282 else
1283     CompilerName="gcc          "
1284 fi
1285
1286 echo "\
1287    Using (for bootstrapping) : $CC_STAGE0
1288    Using $CompilerName       : $CC
1289       which is version       : $GccVersion
1290    Building a cross compiler : $CrossCompiling
1291    Unregisterised            : $Unregisterised
1292    hs-cpp       : $HaskellCPPCmd
1293    hs-cpp-flags : $HaskellCPPArgs
1294    ar           : $ArCmd
1295    ld           : $LdCmd
1296    nm           : $NmCmd
1297    libtool      : $LibtoolCmd
1298    objdump      : $ObjdumpCmd
1299    ranlib       : $RanlibCmd
1300    windres      : $WindresCmd
1301    dllwrap      : $DllWrapCmd
1302    Happy        : $HappyCmd ($HappyVersion)
1303    Alex         : $AlexCmd ($AlexVersion)
1304    Perl         : $PerlCmd
1305    sphinx-build : $SPHINXBUILD
1306    xelatex      : $XELATEX
1307
1308    Using LLVM tools
1309       llc   : $LlcCmd
1310       opt   : $OptCmd"
1311
1312 if test "$HSCOLOUR" = ""; then
1313 echo "
1314    HsColour was not found; documentation will not contain source links
1315 "
1316 else
1317 echo "\
1318    HsColour : $HSCOLOUR
1319 "
1320 fi
1321
1322 echo "\
1323    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1324    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"
1325
1326 echo "----------------------------------------------------------------------
1327 "
1328
1329 echo "\
1330 For a standard build of GHC (fully optimised with profiling), type (g)make.
1331
1332 To make changes to the default build configuration, copy the file
1333 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1334
1335 For more information on how to configure your GHC build, see
1336    http://ghc.haskell.org/trac/ghc/wiki/Building
1337 "]