Merge branch 'master' of darcs.haskell.org:/home/darcs/ghc
[ghc.git] / compiler / ghci / ByteCodeGen.lhs
1 %
2 % (c) The University of Glasgow 2002-2006
3 %
4
5 ByteCodeGen: Generate bytecode from Core
6
7 \begin{code}
8 {-# OPTIONS -fno-warn-tabs #-}
9 -- The above warning supression flag is a temporary kludge.
10 -- While working on this module you are encouraged to remove it and
11 -- detab the module (please do the detabbing in a separate patch). See
12 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#TabsvsSpaces
13 -- for details
14
15 module ByteCodeGen ( UnlinkedBCO, byteCodeGen, coreExprToBCOs ) where
16
17 #include "HsVersions.h"
18
19 import ByteCodeInstr
20 import ByteCodeItbls
21 import ByteCodeAsm
22 import ByteCodeLink
23 import LibFFI
24
25 import DynFlags
26 import Outputable
27 import Platform
28 import Name
29 import MkId
30 import Id
31 import ForeignCall
32 import HscTypes
33 import CoreUtils
34 import CoreSyn
35 import PprCore
36 import Literal
37 import PrimOp
38 import CoreFVs
39 import Type
40 import DataCon
41 import TyCon
42 import Util
43 import VarSet
44 import TysPrim
45 import ErrUtils
46 import Unique
47 import FastString
48 import Panic
49 import StgCmmLayout     ( ArgRep(..), toArgRep, argRepSizeW )
50 import SMRep
51 import Bitmap
52 import OrdList
53
54 import Data.List
55 import Foreign
56 import Foreign.C
57
58 import Control.Monad
59 import Data.Char
60
61 import UniqSupply
62 import BreakArray
63 import Data.Maybe
64 import Module
65
66 import Data.Map (Map)
67 import qualified Data.Map as Map
68 import qualified FiniteMap as Map
69 import Data.Ord
70
71 -- -----------------------------------------------------------------------------
72 -- Generating byte code for a complete module
73
74 byteCodeGen :: DynFlags
75             -> Module
76             -> CoreProgram
77             -> [TyCon]
78             -> ModBreaks
79             -> IO CompiledByteCode
80 byteCodeGen dflags this_mod binds tycs modBreaks
81    = do showPass dflags "ByteCodeGen"
82
83         let flatBinds = [ (bndr, freeVars rhs)
84                         | (bndr, rhs) <- flattenBinds binds]
85
86         us <- mkSplitUniqSupply 'y'
87         (BcM_State _dflags _us _this_mod _final_ctr mallocd _, proto_bcos)
88            <- runBc dflags us this_mod modBreaks (mapM schemeTopBind flatBinds)
89
90         when (notNull mallocd)
91              (panic "ByteCodeGen.byteCodeGen: missing final emitBc?")
92
93         dumpIfSet_dyn dflags Opt_D_dump_BCOs
94            "Proto-BCOs" (vcat (intersperse (char ' ') (map ppr proto_bcos)))
95
96         assembleBCOs dflags proto_bcos tycs
97
98 -- -----------------------------------------------------------------------------
99 -- Generating byte code for an expression
100
101 -- Returns: (the root BCO for this expression,
102 --           a list of auxilary BCOs resulting from compiling closures)
103 coreExprToBCOs :: DynFlags
104                -> Module
105                -> CoreExpr
106                -> IO UnlinkedBCO
107 coreExprToBCOs dflags this_mod expr
108  = do showPass dflags "ByteCodeGen"
109
110       -- create a totally bogus name for the top-level BCO; this
111       -- should be harmless, since it's never used for anything
112       let invented_name  = mkSystemVarName (mkPseudoUniqueE 0) (fsLit "ExprTopLevel")
113           invented_id    = Id.mkLocalId invented_name (panic "invented_id's type")
114
115       -- the uniques are needed to generate fresh variables when we introduce new
116       -- let bindings for ticked expressions
117       us <- mkSplitUniqSupply 'y'
118       (BcM_State _dflags _us _this_mod _final_ctr mallocd _ , proto_bco)
119          <- runBc dflags us this_mod emptyModBreaks $
120               schemeTopBind (invented_id, freeVars expr)
121
122       when (notNull mallocd)
123            (panic "ByteCodeGen.coreExprToBCOs: missing final emitBc?")
124
125       dumpIfSet_dyn dflags Opt_D_dump_BCOs "Proto-BCOs" (ppr proto_bco)
126
127       assembleBCO dflags proto_bco
128
129
130 -- -----------------------------------------------------------------------------
131 -- Compilation schema for the bytecode generator
132
133 type BCInstrList = OrdList BCInstr
134
135 type Sequel = Word -- back off to this depth before ENTER
136
137 -- Maps Ids to the offset from the stack _base_ so we don't have
138 -- to mess with it after each push/pop.
139 type BCEnv = Map Id Word -- To find vars on the stack
140
141 {-
142 ppBCEnv :: BCEnv -> SDoc
143 ppBCEnv p
144    = text "begin-env"
145      $$ nest 4 (vcat (map pp_one (sortBy cmp_snd (Map.toList p))))
146      $$ text "end-env"
147      where
148         pp_one (var, offset) = int offset <> colon <+> ppr var <+> ppr (bcIdArgRep var)
149         cmp_snd x y = compare (snd x) (snd y)
150 -}
151
152 -- Create a BCO and do a spot of peephole optimisation on the insns
153 -- at the same time.
154 mkProtoBCO
155    :: DynFlags
156    -> name
157    -> BCInstrList
158    -> Either  [AnnAlt Id VarSet] (AnnExpr Id VarSet)
159    -> Int
160    -> Word16
161    -> [StgWord]
162    -> Bool      -- True <=> is a return point, rather than a function
163    -> [BcPtr]
164    -> ProtoBCO name
165 mkProtoBCO dflags nm instrs_ordlist origin arity bitmap_size bitmap is_ret mallocd_blocks
166    = ProtoBCO {
167         protoBCOName = nm,
168         protoBCOInstrs = maybe_with_stack_check,
169         protoBCOBitmap = bitmap,
170         protoBCOBitmapSize = bitmap_size,
171         protoBCOArity = arity,
172         protoBCOExpr = origin,
173         protoBCOPtrs = mallocd_blocks
174       }
175      where
176         -- Overestimate the stack usage (in words) of this BCO,
177         -- and if >= iNTERP_STACK_CHECK_THRESH, add an explicit
178         -- stack check.  (The interpreter always does a stack check
179         -- for iNTERP_STACK_CHECK_THRESH words at the start of each
180         -- BCO anyway, so we only need to add an explicit one in the
181         -- (hopefully rare) cases when the (overestimated) stack use
182         -- exceeds iNTERP_STACK_CHECK_THRESH.
183         maybe_with_stack_check
184            | is_ret && stack_usage < fromIntegral (aP_STACK_SPLIM dflags) = peep_d
185                 -- don't do stack checks at return points,
186                 -- everything is aggregated up to the top BCO
187                 -- (which must be a function).
188                 -- That is, unless the stack usage is >= AP_STACK_SPLIM,
189                 -- see bug #1466.
190            | stack_usage >= fromIntegral iNTERP_STACK_CHECK_THRESH
191            = STKCHECK stack_usage : peep_d
192            | otherwise
193            = peep_d     -- the supposedly common case
194
195         -- We assume that this sum doesn't wrap
196         stack_usage = sum (map bciStackUse peep_d)
197
198         -- Merge local pushes
199         peep_d = peep (fromOL instrs_ordlist)
200
201         peep (PUSH_L off1 : PUSH_L off2 : PUSH_L off3 : rest)
202            = PUSH_LLL off1 (off2-1) (off3-2) : peep rest
203         peep (PUSH_L off1 : PUSH_L off2 : rest)
204            = PUSH_LL off1 (off2-1) : peep rest
205         peep (i:rest)
206            = i : peep rest
207         peep []
208            = []
209
210 argBits :: DynFlags -> [ArgRep] -> [Bool]
211 argBits _      [] = []
212 argBits dflags (rep : args)
213   | isFollowableArg rep  = False : argBits dflags args
214   | otherwise = take (argRepSizeW dflags rep) (repeat True) ++ argBits dflags args
215
216 -- -----------------------------------------------------------------------------
217 -- schemeTopBind
218
219 -- Compile code for the right-hand side of a top-level binding
220
221 schemeTopBind :: (Id, AnnExpr Id VarSet) -> BcM (ProtoBCO Name)
222
223
224 schemeTopBind (id, rhs)
225   | Just data_con <- isDataConWorkId_maybe id,
226     isNullaryRepDataCon data_con = do
227     dflags <- getDynFlags
228         -- Special case for the worker of a nullary data con.
229         -- It'll look like this:        Nil = /\a -> Nil a
230         -- If we feed it into schemeR, we'll get
231         --      Nil = Nil
232         -- because mkConAppCode treats nullary constructor applications
233         -- by just re-using the single top-level definition.  So
234         -- for the worker itself, we must allocate it directly.
235     -- ioToBc (putStrLn $ "top level BCO")
236     emitBc (mkProtoBCO dflags (getName id) (toOL [PACK data_con 0, ENTER])
237                        (Right rhs) 0 0 [{-no bitmap-}] False{-not alts-})
238
239   | otherwise
240   = schemeR [{- No free variables -}] (id, rhs)
241
242
243 -- -----------------------------------------------------------------------------
244 -- schemeR
245
246 -- Compile code for a right-hand side, to give a BCO that,
247 -- when executed with the free variables and arguments on top of the stack,
248 -- will return with a pointer to the result on top of the stack, after
249 -- removing the free variables and arguments.
250 --
251 -- Park the resulting BCO in the monad.  Also requires the
252 -- variable to which this value was bound, so as to give the
253 -- resulting BCO a name.
254
255 schemeR :: [Id]                 -- Free vars of the RHS, ordered as they
256                                 -- will appear in the thunk.  Empty for
257                                 -- top-level things, which have no free vars.
258         -> (Id, AnnExpr Id VarSet)
259         -> BcM (ProtoBCO Name)
260 schemeR fvs (nm, rhs)
261 {-
262    | trace (showSDoc (
263               (char ' '
264                $$ (ppr.filter (not.isTyVar).varSetElems.fst) rhs
265                $$ pprCoreExpr (deAnnotate rhs)
266                $$ char ' '
267               ))) False
268    = undefined
269    | otherwise
270 -}
271    = schemeR_wrk fvs nm rhs (collect rhs)
272
273 collect :: AnnExpr Id VarSet -> ([Var], AnnExpr' Id VarSet)
274 collect (_, e) = go [] e
275   where
276     go xs e | Just e' <- bcView e = go xs e'
277     go xs (AnnLam x (_,e)) 
278       | UbxTupleRep _ <- repType (idType x)
279       = unboxedTupleException
280       | otherwise
281       = go (x:xs) e
282     go xs not_lambda = (reverse xs, not_lambda)
283
284 schemeR_wrk :: [Id] -> Id -> AnnExpr Id VarSet -> ([Var], AnnExpr' Var VarSet) -> BcM (ProtoBCO Name)
285 schemeR_wrk fvs nm original_body (args, body)
286    = do
287      dflags <- getDynFlags
288      let
289          all_args  = reverse args ++ fvs
290          arity     = length all_args
291          -- all_args are the args in reverse order.  We're compiling a function
292          -- \fv1..fvn x1..xn -> e
293          -- i.e. the fvs come first
294
295          szsw_args = map (fromIntegral . idSizeW dflags) all_args
296          szw_args  = sum szsw_args
297          p_init    = Map.fromList (zip all_args (mkStackOffsets 0 szsw_args))
298
299          -- make the arg bitmap
300          bits = argBits dflags (reverse (map bcIdArgRep all_args))
301          bitmap_size = genericLength bits
302          bitmap = mkBitmap dflags bits
303      body_code <- schemeER_wrk szw_args p_init body
304
305      emitBc (mkProtoBCO dflags (getName nm) body_code (Right original_body)
306                  arity bitmap_size bitmap False{-not alts-})
307
308 -- introduce break instructions for ticked expressions
309 schemeER_wrk :: Word -> BCEnv -> AnnExpr' Id VarSet -> BcM BCInstrList
310 schemeER_wrk d p rhs
311   | AnnTick (Breakpoint tick_no fvs) (_annot, newRhs) <- rhs
312   = do  code <- schemeE (fromIntegral d) 0 p newRhs
313         arr <- getBreakArray
314         this_mod <- getCurrentModule
315         let idOffSets = getVarOffSets d p fvs
316         let breakInfo = BreakInfo
317                         { breakInfo_module = this_mod
318                         , breakInfo_number = tick_no
319                         , breakInfo_vars = idOffSets
320                         , breakInfo_resty = exprType (deAnnotate' newRhs)
321                         }
322         let breakInstr = case arr of
323                          BA arr# ->
324                              BRK_FUN arr# (fromIntegral tick_no) breakInfo
325         return $ breakInstr `consOL` code
326    | otherwise = schemeE (fromIntegral d) 0 p rhs
327
328 getVarOffSets :: Word -> BCEnv -> [Id] -> [(Id, Word16)]
329 getVarOffSets d p = catMaybes . map (getOffSet d p)
330
331 getOffSet :: Word -> BCEnv -> Id -> Maybe (Id, Word16)
332 getOffSet d env id
333    = case lookupBCEnv_maybe id env of
334         Nothing     -> Nothing
335         Just offset -> Just (id, trunc16 $ d - offset)
336
337 trunc16 :: Word -> Word16
338 trunc16 w
339     | w > fromIntegral (maxBound :: Word16)
340     = panic "stack depth overflow"
341     | otherwise
342     = fromIntegral w
343
344 fvsToEnv :: BCEnv -> VarSet -> [Id]
345 -- Takes the free variables of a right-hand side, and
346 -- delivers an ordered list of the local variables that will
347 -- be captured in the thunk for the RHS
348 -- The BCEnv argument tells which variables are in the local
349 -- environment: these are the ones that should be captured
350 --
351 -- The code that constructs the thunk, and the code that executes
352 -- it, have to agree about this layout
353 fvsToEnv p fvs = [v | v <- varSetElems fvs,
354                       isId v,           -- Could be a type variable
355                       v `Map.member` p]
356
357 -- -----------------------------------------------------------------------------
358 -- schemeE
359
360 returnUnboxedAtom :: Word -> Sequel -> BCEnv
361                  -> AnnExpr' Id VarSet -> ArgRep
362                  -> BcM BCInstrList
363 -- Returning an unlifted value.
364 -- Heave it on the stack, SLIDE, and RETURN.
365 returnUnboxedAtom d s p e e_rep
366    = do (push, szw) <- pushAtom d p e
367         return (push                       -- value onto stack
368                 `appOL`  mkSLIDE szw (d-s) -- clear to sequel
369                 `snocOL` RETURN_UBX e_rep) -- go
370
371 -- Compile code to apply the given expression to the remaining args
372 -- on the stack, returning a HNF.
373 schemeE :: Word -> Sequel -> BCEnv -> AnnExpr' Id VarSet -> BcM BCInstrList
374
375 schemeE d s p e
376    | Just e' <- bcView e
377    = schemeE d s p e'
378
379 -- Delegate tail-calls to schemeT.
380 schemeE d s p e@(AnnApp _ _) = schemeT d s p e
381
382 schemeE d s p e@(AnnLit lit)     = returnUnboxedAtom d s p e (typeArgRep (literalType lit))
383 schemeE d s p e@(AnnCoercion {}) = returnUnboxedAtom d s p e V
384
385 schemeE d s p e@(AnnVar v)
386     | isUnLiftedType (idType v) = returnUnboxedAtom d s p e (bcIdArgRep v)
387     | otherwise                 = schemeT d s p e
388
389 schemeE d s p (AnnLet (AnnNonRec x (_,rhs)) (_,body))
390    | (AnnVar v, args_r_to_l) <- splitApp rhs,
391      Just data_con <- isDataConWorkId_maybe v,
392      dataConRepArity data_con == length args_r_to_l
393    = do -- Special case for a non-recursive let whose RHS is a
394         -- saturatred constructor application.
395         -- Just allocate the constructor and carry on
396         alloc_code <- mkConAppCode d s p data_con args_r_to_l
397         body_code <- schemeE (d+1) s (Map.insert x d p) body
398         return (alloc_code `appOL` body_code)
399
400 -- General case for let.  Generates correct, if inefficient, code in
401 -- all situations.
402 schemeE d s p (AnnLet binds (_,body)) = do
403      dflags <- getDynFlags
404      let (xs,rhss) = case binds of AnnNonRec x rhs  -> ([x],[rhs])
405                                    AnnRec xs_n_rhss -> unzip xs_n_rhss
406          n_binds = genericLength xs
407
408          fvss  = map (fvsToEnv p' . fst) rhss
409
410          -- Sizes of free vars
411          sizes = map (\rhs_fvs -> sum (map (fromIntegral . idSizeW dflags) rhs_fvs)) fvss
412
413          -- the arity of each rhs
414          arities = map (genericLength . fst . collect) rhss
415
416          -- This p', d' defn is safe because all the items being pushed
417          -- are ptrs, so all have size 1.  d' and p' reflect the stack
418          -- after the closures have been allocated in the heap (but not
419          -- filled in), and pointers to them parked on the stack.
420          p'    = Map.insertList (zipE xs (mkStackOffsets d (genericReplicate n_binds 1))) p
421          d'    = d + fromIntegral n_binds
422          zipE  = zipEqual "schemeE"
423
424          -- ToDo: don't build thunks for things with no free variables
425          build_thunk _ [] size bco off arity
426             = return (PUSH_BCO bco `consOL` unitOL (mkap (off+size) size))
427            where
428                 mkap | arity == 0 = MKAP
429                      | otherwise  = MKPAP
430          build_thunk dd (fv:fvs) size bco off arity = do
431               (push_code, pushed_szw) <- pushAtom dd p' (AnnVar fv)
432               more_push_code <- build_thunk (dd + fromIntegral pushed_szw) fvs size bco off arity
433               return (push_code `appOL` more_push_code)
434
435          alloc_code = toOL (zipWith mkAlloc sizes arities)
436            where mkAlloc sz 0
437                     | is_tick     = ALLOC_AP_NOUPD sz
438                     | otherwise   = ALLOC_AP sz
439                  mkAlloc sz arity = ALLOC_PAP arity sz
440
441          is_tick = case binds of
442                      AnnNonRec id _ -> occNameFS (getOccName id) == tickFS
443                      _other -> False
444
445          compile_bind d' fvs x rhs size arity off = do
446                 bco <- schemeR fvs (x,rhs)
447                 build_thunk d' fvs size bco off arity
448
449          compile_binds =
450             [ compile_bind d' fvs x rhs size arity n
451             | (fvs, x, rhs, size, arity, n) <-
452                 zip6 fvss xs rhss sizes arities [n_binds, n_binds-1 .. 1]
453             ]
454      body_code <- schemeE d' s p' body
455      thunk_codes <- sequence compile_binds
456      return (alloc_code `appOL` concatOL thunk_codes `appOL` body_code)
457
458 -- introduce a let binding for a ticked case expression. This rule
459 -- *should* only fire when the expression was not already let-bound
460 -- (the code gen for let bindings should take care of that).  Todo: we
461 -- call exprFreeVars on a deAnnotated expression, this may not be the
462 -- best way to calculate the free vars but it seemed like the least
463 -- intrusive thing to do
464 schemeE d s p exp@(AnnTick (Breakpoint _id _fvs) _rhs)
465    = if isUnLiftedType ty
466         then do
467           -- If the result type is unlifted, then we must generate
468           --   let f = \s . tick<n> e
469           --   in  f realWorld#
470           -- When we stop at the breakpoint, _result will have an unlifted
471           -- type and hence won't be bound in the environment, but the
472           -- breakpoint will otherwise work fine.
473           id <- newId (mkFunTy realWorldStatePrimTy ty)
474           st <- newId realWorldStatePrimTy
475           let letExp = AnnLet (AnnNonRec id (fvs, AnnLam st (emptyVarSet, exp)))
476                               (emptyVarSet, (AnnApp (emptyVarSet, AnnVar id)
477                                                     (emptyVarSet, AnnVar realWorldPrimId)))
478           schemeE d s p letExp
479         else do
480           id <- newId ty
481           -- Todo: is emptyVarSet correct on the next line?
482           let letExp = AnnLet (AnnNonRec id (fvs, exp)) (emptyVarSet, AnnVar id)
483           schemeE d s p letExp
484    where exp' = deAnnotate' exp
485          fvs  = exprFreeVars exp'
486          ty   = exprType exp'
487
488 -- ignore other kinds of tick
489 schemeE d s p (AnnTick _ (_, rhs)) = schemeE d s p rhs
490
491 schemeE d s p (AnnCase (_,scrut) _ _ []) = schemeE d s p scrut
492         -- no alts: scrut is guaranteed to diverge
493
494 schemeE d s p (AnnCase scrut bndr _ [(DataAlt dc, [bind1, bind2], rhs)])
495    | isUnboxedTupleCon dc
496    , UnaryRep rep_ty1 <- repType (idType bind1), UnaryRep rep_ty2 <- repType (idType bind2)
497         -- Convert
498         --      case .... of x { (# V'd-thing, a #) -> ... }
499         -- to
500         --      case .... of a { DEFAULT -> ... }
501         -- becuse the return convention for both are identical.
502         --
503         -- Note that it does not matter losing the void-rep thing from the
504         -- envt (it won't be bound now) because we never look such things up.
505    , Just res <- case () of
506                    _ | VoidRep <- typePrimRep rep_ty1
507                      -> Just $ doCase d s p scrut bind2 [(DEFAULT, [], rhs)] (Just bndr){-unboxed tuple-}
508                      | VoidRep <- typePrimRep rep_ty2
509                      -> Just $ doCase d s p scrut bind1 [(DEFAULT, [], rhs)] (Just bndr){-unboxed tuple-}
510                      | otherwise
511                      -> Nothing
512    = res
513
514 schemeE d s p (AnnCase scrut bndr _ [(DataAlt dc, [bind1], rhs)])
515    | isUnboxedTupleCon dc, UnaryRep _ <- repType (idType bind1)
516         -- Similarly, convert
517         --      case .... of x { (# a #) -> ... }
518         -- to
519         --      case .... of a { DEFAULT -> ... }
520    = --trace "automagic mashing of case alts (# a #)"  $
521      doCase d s p scrut bind1 [(DEFAULT, [], rhs)] (Just bndr){-unboxed tuple-}
522
523 schemeE d s p (AnnCase scrut bndr _ [(DEFAULT, [], rhs)])
524    | Just (tc, tys) <- splitTyConApp_maybe (idType bndr)
525    , isUnboxedTupleTyCon tc
526    , Just res <- case tys of
527         [ty]       | UnaryRep _ <- repType ty
528                    , let bind = bndr `setIdType` ty
529                    -> Just $ doCase d s p scrut bind [(DEFAULT, [], rhs)] (Just bndr){-unboxed tuple-}
530         [ty1, ty2] | UnaryRep rep_ty1 <- repType ty1
531                    , UnaryRep rep_ty2 <- repType ty2
532                    -> case () of
533                        _ | VoidRep <- typePrimRep rep_ty1
534                          , let bind2 = bndr `setIdType` ty2
535                          -> Just $ doCase d s p scrut bind2 [(DEFAULT, [], rhs)] (Just bndr){-unboxed tuple-}
536                          | VoidRep <- typePrimRep rep_ty2
537                          , let bind1 = bndr `setIdType` ty1
538                          -> Just $ doCase d s p scrut bind1 [(DEFAULT, [], rhs)] (Just bndr){-unboxed tuple-}
539                          | otherwise
540                          -> Nothing
541         _ -> Nothing
542    = res
543
544 schemeE d s p (AnnCase scrut bndr _ alts)
545    = doCase d s p scrut bndr alts Nothing{-not an unboxed tuple-}
546
547 schemeE _ _ _ expr
548    = pprPanic "ByteCodeGen.schemeE: unhandled case"
549                (pprCoreExpr (deAnnotate' expr))
550
551 {-
552    Ticked Expressions
553    ------------------
554
555   The idea is that the "breakpoint<n,fvs> E" is really just an annotation on
556   the code. When we find such a thing, we pull out the useful information,
557   and then compile the code as if it was just the expression E.
558
559 -}
560
561 -- Compile code to do a tail call.  Specifically, push the fn,
562 -- slide the on-stack app back down to the sequel depth,
563 -- and enter.  Four cases:
564 --
565 -- 0.  (Nasty hack).
566 --     An application "GHC.Prim.tagToEnum# <type> unboxed-int".
567 --     The int will be on the stack.  Generate a code sequence
568 --     to convert it to the relevant constructor, SLIDE and ENTER.
569 --
570 -- 1.  The fn denotes a ccall.  Defer to generateCCall.
571 --
572 -- 2.  (Another nasty hack).  Spot (# a::V, b #) and treat
573 --     it simply as  b  -- since the representations are identical
574 --     (the V takes up zero stack space).  Also, spot
575 --     (# b #) and treat it as  b.
576 --
577 -- 3.  Application of a constructor, by defn saturated.
578 --     Split the args into ptrs and non-ptrs, and push the nonptrs,
579 --     then the ptrs, and then do PACK and RETURN.
580 --
581 -- 4.  Otherwise, it must be a function call.  Push the args
582 --     right to left, SLIDE and ENTER.
583
584 schemeT :: Word         -- Stack depth
585         -> Sequel       -- Sequel depth
586         -> BCEnv        -- stack env
587         -> AnnExpr' Id VarSet
588         -> BcM BCInstrList
589
590 schemeT d s p app
591
592 --   | trace ("schemeT: env in = \n" ++ showSDocDebug (ppBCEnv p)) False
593 --   = panic "schemeT ?!?!"
594
595 --   | trace ("\nschemeT\n" ++ showSDoc (pprCoreExpr (deAnnotate' app)) ++ "\n") False
596 --   = error "?!?!"
597
598    -- Case 0
599    | Just (arg, constr_names) <- maybe_is_tagToEnum_call
600    = do (push, arg_words) <- pushAtom d p arg
601         tagToId_sequence <- implement_tagToId constr_names
602         return (push `appOL`  tagToId_sequence
603                        `appOL`  mkSLIDE 1 (d - s + fromIntegral arg_words)
604                        `snocOL` ENTER)
605
606    -- Case 1
607    | Just (CCall ccall_spec) <- isFCallId_maybe fn
608    = generateCCall d s p ccall_spec fn args_r_to_l
609
610    -- Case 2: Constructor application
611    | Just con <- maybe_saturated_dcon,
612      isUnboxedTupleCon con
613    = case args_r_to_l of
614         [arg1,arg2] | isVAtom arg1 ->
615                   unboxedTupleReturn d s p arg2
616         [arg1,arg2] | isVAtom arg2 ->
617                   unboxedTupleReturn d s p arg1
618         _other -> unboxedTupleException
619
620    -- Case 3: Ordinary data constructor
621    | Just con <- maybe_saturated_dcon
622    = do alloc_con <- mkConAppCode d s p con args_r_to_l
623         return (alloc_con         `appOL`
624                 mkSLIDE 1 (d - s) `snocOL`
625                 ENTER)
626
627    -- Case 4: Tail call of function
628    | otherwise
629    = doTailCall d s p fn args_r_to_l
630
631    where
632       -- Detect and extract relevant info for the tagToEnum kludge.
633       maybe_is_tagToEnum_call
634          = let extract_constr_Names ty
635                  | UnaryRep rep_ty <- repType ty
636                  , Just tyc <- tyConAppTyCon_maybe rep_ty,
637                    isDataTyCon tyc
638                    = map (getName . dataConWorkId) (tyConDataCons tyc)
639                    -- NOTE: use the worker name, not the source name of
640                    -- the DataCon.  See DataCon.lhs for details.
641                  | otherwise
642                    = pprPanic "maybe_is_tagToEnum_call.extract_constr_Ids" (ppr ty)
643            in
644            case app of
645               (AnnApp (_, AnnApp (_, AnnVar v) (_, AnnType t)) arg)
646                  -> case isPrimOpId_maybe v of
647                        Just TagToEnumOp -> Just (snd arg, extract_constr_Names t)
648                        _                -> Nothing
649               _ -> Nothing
650
651         -- Extract the args (R->L) and fn
652         -- The function will necessarily be a variable,
653         -- because we are compiling a tail call
654       (AnnVar fn, args_r_to_l) = splitApp app
655
656       -- Only consider this to be a constructor application iff it is
657       -- saturated.  Otherwise, we'll call the constructor wrapper.
658       n_args = length args_r_to_l
659       maybe_saturated_dcon
660         = case isDataConWorkId_maybe fn of
661                 Just con | dataConRepArity con == n_args -> Just con
662                 _ -> Nothing
663
664 -- -----------------------------------------------------------------------------
665 -- Generate code to build a constructor application,
666 -- leaving it on top of the stack
667
668 mkConAppCode :: Word -> Sequel -> BCEnv
669              -> DataCon                 -- The data constructor
670              -> [AnnExpr' Id VarSet]    -- Args, in *reverse* order
671              -> BcM BCInstrList
672
673 mkConAppCode _ _ _ con []       -- Nullary constructor
674   = ASSERT( isNullaryRepDataCon con )
675     return (unitOL (PUSH_G (getName (dataConWorkId con))))
676         -- Instead of doing a PACK, which would allocate a fresh
677         -- copy of this constructor, use the single shared version.
678
679 mkConAppCode orig_d _ p con args_r_to_l
680   = ASSERT( dataConRepArity con == length args_r_to_l )
681     do_pushery orig_d (non_ptr_args ++ ptr_args)
682  where
683         -- The args are already in reverse order, which is the way PACK
684         -- expects them to be.  We must push the non-ptrs after the ptrs.
685       (ptr_args, non_ptr_args) = partition isPtrAtom args_r_to_l
686
687       do_pushery d (arg:args)
688          = do (push, arg_words) <- pushAtom d p arg
689               more_push_code <- do_pushery (d + fromIntegral arg_words) args
690               return (push `appOL` more_push_code)
691       do_pushery d []
692          = return (unitOL (PACK con n_arg_words))
693          where
694            n_arg_words = trunc16 $ d - orig_d
695
696
697 -- -----------------------------------------------------------------------------
698 -- Returning an unboxed tuple with one non-void component (the only
699 -- case we can handle).
700 --
701 -- Remember, we don't want to *evaluate* the component that is being
702 -- returned, even if it is a pointed type.  We always just return.
703
704 unboxedTupleReturn
705         :: Word -> Sequel -> BCEnv
706         -> AnnExpr' Id VarSet -> BcM BCInstrList
707 unboxedTupleReturn d s p arg = returnUnboxedAtom d s p arg (atomRep arg)
708
709 -- -----------------------------------------------------------------------------
710 -- Generate code for a tail-call
711
712 doTailCall
713         :: Word -> Sequel -> BCEnv
714         -> Id -> [AnnExpr' Id VarSet]
715         -> BcM BCInstrList
716 doTailCall init_d s p fn args
717   = do_pushes init_d args (map atomRep args)
718   where
719   do_pushes d [] reps = do
720         ASSERT( null reps ) return ()
721         (push_fn, sz) <- pushAtom d p (AnnVar fn)
722         ASSERT( sz == 1 ) return ()
723         return (push_fn `appOL` (
724                   mkSLIDE (trunc16 $ d - init_d + 1) (init_d - s) `appOL`
725                   unitOL ENTER))
726   do_pushes d args reps = do
727       let (push_apply, n, rest_of_reps) = findPushSeq reps
728           (these_args, rest_of_args) = splitAt n args
729       (next_d, push_code) <- push_seq d these_args
730       instrs <- do_pushes (next_d + 1) rest_of_args rest_of_reps
731       --                          ^^^ for the PUSH_APPLY_ instruction
732       return (push_code `appOL` (push_apply `consOL` instrs))
733
734   push_seq d [] = return (d, nilOL)
735   push_seq d (arg:args) = do
736     (push_code, sz) <- pushAtom d p arg
737     (final_d, more_push_code) <- push_seq (d + fromIntegral sz) args
738     return (final_d, push_code `appOL` more_push_code)
739
740 -- v. similar to CgStackery.findMatch, ToDo: merge
741 findPushSeq :: [ArgRep] -> (BCInstr, Int, [ArgRep])
742 findPushSeq (P: P: P: P: P: P: rest)
743   = (PUSH_APPLY_PPPPPP, 6, rest)
744 findPushSeq (P: P: P: P: P: rest)
745   = (PUSH_APPLY_PPPPP, 5, rest)
746 findPushSeq (P: P: P: P: rest)
747   = (PUSH_APPLY_PPPP, 4, rest)
748 findPushSeq (P: P: P: rest)
749   = (PUSH_APPLY_PPP, 3, rest)
750 findPushSeq (P: P: rest)
751   = (PUSH_APPLY_PP, 2, rest)
752 findPushSeq (P: rest)
753   = (PUSH_APPLY_P, 1, rest)
754 findPushSeq (V: rest)
755   = (PUSH_APPLY_V, 1, rest)
756 findPushSeq (N: rest)
757   = (PUSH_APPLY_N, 1, rest)
758 findPushSeq (F: rest)
759   = (PUSH_APPLY_F, 1, rest)
760 findPushSeq (D: rest)
761   = (PUSH_APPLY_D, 1, rest)
762 findPushSeq (L: rest)
763   = (PUSH_APPLY_L, 1, rest)
764 findPushSeq _
765   = panic "ByteCodeGen.findPushSeq"
766
767 -- -----------------------------------------------------------------------------
768 -- Case expressions
769
770 doCase  :: Word -> Sequel -> BCEnv
771         -> AnnExpr Id VarSet -> Id -> [AnnAlt Id VarSet]
772         -> Maybe Id  -- Just x <=> is an unboxed tuple case with scrut binder, don't enter the result
773         -> BcM BCInstrList
774 doCase d s p (_,scrut) bndr alts is_unboxed_tuple
775   | UbxTupleRep _ <- repType (idType bndr)
776   = unboxedTupleException
777   | otherwise
778   = do
779      dflags <- getDynFlags
780      let
781         -- Top of stack is the return itbl, as usual.
782         -- underneath it is the pointer to the alt_code BCO.
783         -- When an alt is entered, it assumes the returned value is
784         -- on top of the itbl.
785         ret_frame_sizeW :: Word
786         ret_frame_sizeW = 2
787
788         -- An unlifted value gets an extra info table pushed on top
789         -- when it is returned.
790         unlifted_itbl_sizeW :: Word
791         unlifted_itbl_sizeW | isAlgCase = 0
792                             | otherwise = 1
793
794         -- depth of stack after the return value has been pushed
795         d_bndr = d + ret_frame_sizeW + fromIntegral (idSizeW dflags bndr)
796
797         -- depth of stack after the extra info table for an unboxed return
798         -- has been pushed, if any.  This is the stack depth at the
799         -- continuation.
800         d_alts = d_bndr + unlifted_itbl_sizeW
801
802         -- Env in which to compile the alts, not including
803         -- any vars bound by the alts themselves
804         d_bndr' = fromIntegral d_bndr - 1
805         p_alts0 = Map.insert bndr d_bndr' p
806         p_alts = case is_unboxed_tuple of
807                    Just ubx_bndr -> Map.insert ubx_bndr d_bndr' p_alts0
808                    Nothing       -> p_alts0
809
810         bndr_ty = idType bndr
811         isAlgCase = not (isUnLiftedType bndr_ty) && isNothing is_unboxed_tuple
812
813         -- given an alt, return a discr and code for it.
814         codeAlt (DEFAULT, _, (_,rhs))
815            = do rhs_code <- schemeE d_alts s p_alts rhs
816                 return (NoDiscr, rhs_code)
817
818         codeAlt alt@(_, bndrs, (_,rhs))
819            -- primitive or nullary constructor alt: no need to UNPACK
820            | null real_bndrs = do
821                 rhs_code <- schemeE d_alts s p_alts rhs
822                 return (my_discr alt, rhs_code)
823            | any (\bndr -> case repType (idType bndr) of UbxTupleRep _ -> True; _ -> False) bndrs
824            = unboxedTupleException
825            -- algebraic alt with some binders
826            | otherwise =
827              let
828                  (ptrs,nptrs) = partition (isFollowableArg.bcIdArgRep) real_bndrs
829                  ptr_sizes    = map (fromIntegral . idSizeW dflags) ptrs
830                  nptrs_sizes  = map (fromIntegral . idSizeW dflags) nptrs
831                  bind_sizes   = ptr_sizes ++ nptrs_sizes
832                  size         = sum ptr_sizes + sum nptrs_sizes
833                  -- the UNPACK instruction unpacks in reverse order...
834                  p' = Map.insertList
835                         (zip (reverse (ptrs ++ nptrs))
836                           (mkStackOffsets d_alts (reverse bind_sizes)))
837                         p_alts
838              in do
839              MASSERT(isAlgCase)
840              rhs_code <- schemeE (d_alts + size) s p' rhs
841              return (my_discr alt, unitOL (UNPACK (trunc16 size)) `appOL` rhs_code)
842            where
843              real_bndrs = filterOut isTyVar bndrs
844
845         my_discr (DEFAULT, _, _) = NoDiscr {-shouldn't really happen-}
846         my_discr (DataAlt dc, _, _)
847            | isUnboxedTupleCon dc
848            = unboxedTupleException
849            | otherwise
850            = DiscrP (fromIntegral (dataConTag dc - fIRST_TAG))
851         my_discr (LitAlt l, _, _)
852            = case l of MachInt i     -> DiscrI (fromInteger i)
853                        MachWord w    -> DiscrW (fromInteger w)
854                        MachFloat r   -> DiscrF (fromRational r)
855                        MachDouble r  -> DiscrD (fromRational r)
856                        MachChar i    -> DiscrI (ord i)
857                        _ -> pprPanic "schemeE(AnnCase).my_discr" (ppr l)
858
859         maybe_ncons
860            | not isAlgCase = Nothing
861            | otherwise
862            = case [dc | (DataAlt dc, _, _) <- alts] of
863                 []     -> Nothing
864                 (dc:_) -> Just (tyConFamilySize (dataConTyCon dc))
865
866         -- the bitmap is relative to stack depth d, i.e. before the
867         -- BCO, info table and return value are pushed on.
868         -- This bit of code is v. similar to buildLivenessMask in CgBindery,
869         -- except that here we build the bitmap from the known bindings of
870         -- things that are pointers, whereas in CgBindery the code builds the
871         -- bitmap from the free slots and unboxed bindings.
872         -- (ToDo: merge?)
873         --
874         -- NOTE [7/12/2006] bug #1013, testcase ghci/should_run/ghci002.
875         -- The bitmap must cover the portion of the stack up to the sequel only.
876         -- Previously we were building a bitmap for the whole depth (d), but we
877         -- really want a bitmap up to depth (d-s).  This affects compilation of
878         -- case-of-case expressions, which is the only time we can be compiling a
879         -- case expression with s /= 0.
880         bitmap_size = trunc16 $ d-s
881         bitmap_size' :: Int
882         bitmap_size' = fromIntegral bitmap_size
883         bitmap = intsToReverseBitmap dflags bitmap_size'{-size-}
884                         (sort (filter (< bitmap_size') rel_slots))
885           where
886           binds = Map.toList p
887           -- NB: unboxed tuple cases bind the scrut binder to the same offset
888           -- as one of the alt binders, so we have to remove any duplicates here:
889           rel_slots = nub $ map fromIntegral $ concat (map spread binds)
890           spread (id, offset) | isFollowableArg (bcIdArgRep id) = [ rel_offset ]
891                               | otherwise                      = []
892                 where rel_offset = trunc16 $ d - fromIntegral offset - 1
893
894      alt_stuff <- mapM codeAlt alts
895      alt_final <- mkMultiBranch maybe_ncons alt_stuff
896
897      let
898          alt_bco_name = getName bndr
899          alt_bco = mkProtoBCO dflags alt_bco_name alt_final (Left alts)
900                        0{-no arity-} bitmap_size bitmap True{-is alts-}
901 --     trace ("case: bndr = " ++ showSDocDebug (ppr bndr) ++ "\ndepth = " ++ show d ++ "\nenv = \n" ++ showSDocDebug (ppBCEnv p) ++
902 --            "\n      bitmap = " ++ show bitmap) $ do
903      scrut_code <- schemeE (d + ret_frame_sizeW)
904                            (d + ret_frame_sizeW)
905                            p scrut
906      alt_bco' <- emitBc alt_bco
907      let push_alts
908             | isAlgCase = PUSH_ALTS alt_bco'
909             | otherwise = PUSH_ALTS_UNLIFTED alt_bco' (typeArgRep bndr_ty)
910      return (push_alts `consOL` scrut_code)
911
912
913 -- -----------------------------------------------------------------------------
914 -- Deal with a CCall.
915
916 -- Taggedly push the args onto the stack R->L,
917 -- deferencing ForeignObj#s and adjusting addrs to point to
918 -- payloads in Ptr/Byte arrays.  Then, generate the marshalling
919 -- (machine) code for the ccall, and create bytecodes to call that and
920 -- then return in the right way.
921
922 generateCCall :: Word -> Sequel         -- stack and sequel depths
923               -> BCEnv
924               -> CCallSpec              -- where to call
925               -> Id                     -- of target, for type info
926               -> [AnnExpr' Id VarSet]   -- args (atoms)
927               -> BcM BCInstrList
928
929 generateCCall d0 s p (CCallSpec target cconv safety) fn args_r_to_l
930  = do
931      dflags <- getDynFlags
932
933      let
934          -- useful constants
935          addr_sizeW :: Word16
936          addr_sizeW = fromIntegral (argRepSizeW dflags N)
937
938          -- Get the args on the stack, with tags and suitably
939          -- dereferenced for the CCall.  For each arg, return the
940          -- depth to the first word of the bits for that arg, and the
941          -- ArgRep of what was actually pushed.
942
943          pargs _ [] = return []
944          pargs d (a:az)
945             = let UnaryRep arg_ty = repType (exprType (deAnnotate' a))
946
947               in case tyConAppTyCon_maybe arg_ty of
948                     -- Don't push the FO; instead push the Addr# it
949                     -- contains.
950                     Just t
951                      | t == arrayPrimTyCon || t == mutableArrayPrimTyCon
952                        -> do rest <- pargs (d + fromIntegral addr_sizeW) az
953                              code <- parg_ArrayishRep (fromIntegral (arrPtrsHdrSize dflags)) d p a
954                              return ((code,AddrRep):rest)
955
956                      | t == byteArrayPrimTyCon || t == mutableByteArrayPrimTyCon
957                        -> do rest <- pargs (d + fromIntegral addr_sizeW) az
958                              code <- parg_ArrayishRep (fromIntegral (arrWordsHdrSize dflags)) d p a
959                              return ((code,AddrRep):rest)
960
961                     -- Default case: push taggedly, but otherwise intact.
962                     _
963                        -> do (code_a, sz_a) <- pushAtom d p a
964                              rest <- pargs (d + fromIntegral sz_a) az
965                              return ((code_a, atomPrimRep a) : rest)
966
967          -- Do magic for Ptr/Byte arrays.  Push a ptr to the array on
968          -- the stack but then advance it over the headers, so as to
969          -- point to the payload.
970          parg_ArrayishRep :: Word16 -> Word -> BCEnv -> AnnExpr' Id VarSet
971                           -> BcM BCInstrList
972          parg_ArrayishRep hdrSize d p a
973             = do (push_fo, _) <- pushAtom d p a
974                  -- The ptr points at the header.  Advance it over the
975                  -- header and then pretend this is an Addr#.
976                  return (push_fo `snocOL` SWIZZLE 0 hdrSize)
977
978      code_n_reps <- pargs d0 args_r_to_l
979      let
980          (pushs_arg, a_reps_pushed_r_to_l) = unzip code_n_reps
981          a_reps_sizeW = fromIntegral (sum (map (primRepSizeW dflags) a_reps_pushed_r_to_l))
982
983          push_args    = concatOL pushs_arg
984          d_after_args = d0 + a_reps_sizeW
985          a_reps_pushed_RAW
986             | null a_reps_pushed_r_to_l || head a_reps_pushed_r_to_l /= VoidRep
987             = panic "ByteCodeGen.generateCCall: missing or invalid World token?"
988             | otherwise
989             = reverse (tail a_reps_pushed_r_to_l)
990
991          -- Now: a_reps_pushed_RAW are the reps which are actually on the stack.
992          -- push_args is the code to do that.
993          -- d_after_args is the stack depth once the args are on.
994
995          -- Get the result rep.
996          (returns_void, r_rep)
997             = case maybe_getCCallReturnRep (idType fn) of
998                  Nothing -> (True,  VoidRep)
999                  Just rr -> (False, rr)
1000          {-
1001          Because the Haskell stack grows down, the a_reps refer to
1002          lowest to highest addresses in that order.  The args for the call
1003          are on the stack.  Now push an unboxed Addr# indicating
1004          the C function to call.  Then push a dummy placeholder for the
1005          result.  Finally, emit a CCALL insn with an offset pointing to the
1006          Addr# just pushed, and a literal field holding the mallocville
1007          address of the piece of marshalling code we generate.
1008          So, just prior to the CCALL insn, the stack looks like this
1009          (growing down, as usual):
1010
1011             <arg_n>
1012             ...
1013             <arg_1>
1014             Addr# address_of_C_fn
1015             <placeholder-for-result#> (must be an unboxed type)
1016
1017          The interpreter then calls the marshall code mentioned
1018          in the CCALL insn, passing it (& <placeholder-for-result#>),
1019          that is, the addr of the topmost word in the stack.
1020          When this returns, the placeholder will have been
1021          filled in.  The placeholder is slid down to the sequel
1022          depth, and we RETURN.
1023
1024          This arrangement makes it simple to do f-i-dynamic since the Addr#
1025          value is the first arg anyway.
1026
1027          The marshalling code is generated specifically for this
1028          call site, and so knows exactly the (Haskell) stack
1029          offsets of the args, fn address and placeholder.  It
1030          copies the args to the C stack, calls the stacked addr,
1031          and parks the result back in the placeholder.  The interpreter
1032          calls it as a normal C call, assuming it has a signature
1033             void marshall_code ( StgWord* ptr_to_top_of_stack )
1034          -}
1035          -- resolve static address
1036          get_target_info = do
1037              case target of
1038                  DynamicTarget
1039                     -> return (False, panic "ByteCodeGen.generateCCall(dyn)")
1040
1041                  StaticTarget _ _ False ->
1042                      panic "generateCCall: unexpected FFI value import"
1043                  StaticTarget target _ True
1044                     -> do res <- ioToBc (lookupStaticPtr stdcall_adj_target)
1045                           return (True, res)
1046                    where
1047                       stdcall_adj_target
1048                           | OSMinGW32 <- platformOS (targetPlatform dflags)
1049                           , StdCallConv <- cconv
1050                           = let size = fromIntegral a_reps_sizeW * wORD_SIZE dflags in
1051                             mkFastString (unpackFS target ++ '@':show size)
1052                           | otherwise
1053                           = target
1054
1055      (is_static, static_target_addr) <- get_target_info
1056      let
1057
1058          -- Get the arg reps, zapping the leading Addr# in the dynamic case
1059          a_reps --  | trace (showSDoc (ppr a_reps_pushed_RAW)) False = error "???"
1060                 | is_static = a_reps_pushed_RAW
1061                 | otherwise = if null a_reps_pushed_RAW
1062                               then panic "ByteCodeGen.generateCCall: dyn with no args"
1063                               else tail a_reps_pushed_RAW
1064
1065          -- push the Addr#
1066          (push_Addr, d_after_Addr)
1067             | is_static
1068             = (toOL [PUSH_UBX (Right static_target_addr) addr_sizeW],
1069                d_after_args + fromIntegral addr_sizeW)
1070             | otherwise -- is already on the stack
1071             = (nilOL, d_after_args)
1072
1073          -- Push the return placeholder.  For a call returning nothing,
1074          -- this is a V (tag).
1075          r_sizeW   = fromIntegral (primRepSizeW dflags r_rep)
1076          d_after_r = d_after_Addr + fromIntegral r_sizeW
1077          r_lit     = mkDummyLiteral r_rep
1078          push_r    = (if   returns_void
1079                       then nilOL
1080                       else unitOL (PUSH_UBX (Left r_lit) r_sizeW))
1081
1082          -- generate the marshalling code we're going to call
1083
1084          -- Offset of the next stack frame down the stack.  The CCALL
1085          -- instruction needs to describe the chunk of stack containing
1086          -- the ccall args to the GC, so it needs to know how large it
1087          -- is.  See comment in Interpreter.c with the CCALL instruction.
1088          stk_offset   = trunc16 $ d_after_r - s
1089
1090      -- the only difference in libffi mode is that we prepare a cif
1091      -- describing the call type by calling libffi, and we attach the
1092      -- address of this to the CCALL instruction.
1093      token <- ioToBc $ prepForeignCall dflags cconv a_reps r_rep
1094      let addr_of_marshaller = castPtrToFunPtr token
1095
1096      recordItblMallocBc (ItblPtr (castFunPtrToPtr addr_of_marshaller))
1097      let
1098          -- do the call
1099          do_call      = unitOL (CCALL stk_offset (castFunPtrToPtr addr_of_marshaller)
1100                                  (fromIntegral (fromEnum (playInterruptible safety))))
1101          -- slide and return
1102          wrapup       = mkSLIDE r_sizeW (d_after_r - fromIntegral r_sizeW - s)
1103                         `snocOL` RETURN_UBX (toArgRep r_rep)
1104          --trace (show (arg1_offW, args_offW  ,  (map argRepSizeW a_reps) )) $
1105      return (
1106          push_args `appOL`
1107          push_Addr `appOL` push_r `appOL` do_call `appOL` wrapup
1108          )
1109
1110 -- Make a dummy literal, to be used as a placeholder for FFI return
1111 -- values on the stack.
1112 mkDummyLiteral :: PrimRep -> Literal
1113 mkDummyLiteral pr
1114    = case pr of
1115         IntRep    -> MachInt 0
1116         WordRep   -> MachWord 0
1117         AddrRep   -> MachNullAddr
1118         DoubleRep -> MachDouble 0
1119         FloatRep  -> MachFloat 0
1120         Int64Rep  -> MachInt64 0
1121         Word64Rep -> MachWord64 0
1122         _         -> panic "mkDummyLiteral"
1123
1124
1125 -- Convert (eg)
1126 --     GHC.Prim.Char# -> GHC.Prim.State# GHC.Prim.RealWorld
1127 --                   -> (# GHC.Prim.State# GHC.Prim.RealWorld, GHC.Prim.Int# #)
1128 --
1129 -- to  Just IntRep
1130 -- and check that an unboxed pair is returned wherein the first arg is V'd.
1131 --
1132 -- Alternatively, for call-targets returning nothing, convert
1133 --
1134 --     GHC.Prim.Char# -> GHC.Prim.State# GHC.Prim.RealWorld
1135 --                   -> (# GHC.Prim.State# GHC.Prim.RealWorld #)
1136 --
1137 -- to  Nothing
1138
1139 maybe_getCCallReturnRep :: Type -> Maybe PrimRep
1140 maybe_getCCallReturnRep fn_ty
1141    = let (_a_tys, r_ty) = splitFunTys (dropForAlls fn_ty)
1142          maybe_r_rep_to_go
1143             = if isSingleton r_reps then Nothing else Just (r_reps !! 1)
1144          r_reps = case repType r_ty of
1145                       UbxTupleRep reps -> map typePrimRep reps
1146                       UnaryRep _       -> blargh
1147          ok = ( ( r_reps `lengthIs` 2 && VoidRep == head r_reps)
1148                 || r_reps == [VoidRep] )
1149               && case maybe_r_rep_to_go of
1150                     Nothing    -> True
1151                     Just r_rep -> r_rep /= PtrRep
1152                                   -- if it was, it would be impossible
1153                                   -- to create a valid return value
1154                                   -- placeholder on the stack
1155
1156          blargh :: a -- Used at more than one type
1157          blargh = pprPanic "maybe_getCCallReturn: can't handle:"
1158                            (pprType fn_ty)
1159      in
1160      --trace (showSDoc (ppr (a_reps, r_reps))) $
1161      if ok then maybe_r_rep_to_go else blargh
1162
1163 -- Compile code which expects an unboxed Int on the top of stack,
1164 -- (call it i), and pushes the i'th closure in the supplied list
1165 -- as a consequence.
1166 implement_tagToId :: [Name] -> BcM BCInstrList
1167 implement_tagToId names
1168    = ASSERT( notNull names )
1169      do labels <- getLabelsBc (genericLength names)
1170         label_fail <- getLabelBc
1171         label_exit <- getLabelBc
1172         let infos = zip4 labels (tail labels ++ [label_fail])
1173                                 [0 ..] names
1174             steps = map (mkStep label_exit) infos
1175         return (concatOL steps
1176                   `appOL`
1177                   toOL [LABEL label_fail, CASEFAIL, LABEL label_exit])
1178      where
1179         mkStep l_exit (my_label, next_label, n, name_for_n)
1180            = toOL [LABEL my_label,
1181                    TESTEQ_I n next_label,
1182                    PUSH_G name_for_n,
1183                    JMP l_exit]
1184
1185
1186 -- -----------------------------------------------------------------------------
1187 -- pushAtom
1188
1189 -- Push an atom onto the stack, returning suitable code & number of
1190 -- stack words used.
1191 --
1192 -- The env p must map each variable to the highest- numbered stack
1193 -- slot for it.  For example, if the stack has depth 4 and we
1194 -- tagged-ly push (v :: Int#) on it, the value will be in stack[4],
1195 -- the tag in stack[5], the stack will have depth 6, and p must map v
1196 -- to 5 and not to 4.  Stack locations are numbered from zero, so a
1197 -- depth 6 stack has valid words 0 .. 5.
1198
1199 pushAtom :: Word -> BCEnv -> AnnExpr' Id VarSet -> BcM (BCInstrList, Word16)
1200
1201 pushAtom d p e
1202    | Just e' <- bcView e
1203    = pushAtom d p e'
1204
1205 pushAtom _ _ (AnnCoercion {})   -- Coercions are zero-width things, 
1206    = return (nilOL, 0)          -- treated just like a variable V
1207
1208 pushAtom d p (AnnVar v)
1209    | UnaryRep rep_ty <- repType (idType v)
1210    , V <- typeArgRep rep_ty
1211    = return (nilOL, 0)
1212
1213    | isFCallId v
1214    = pprPanic "pushAtom: shouldn't get an FCallId here" (ppr v)
1215
1216    | Just primop <- isPrimOpId_maybe v
1217    = return (unitOL (PUSH_PRIMOP primop), 1)
1218
1219    | Just d_v <- lookupBCEnv_maybe v p  -- v is a local variable
1220    = do dflags <- getDynFlags
1221         let sz :: Word16
1222             sz = fromIntegral (idSizeW dflags v)
1223             l = trunc16 $ d - d_v + fromIntegral sz - 2
1224         return (toOL (genericReplicate sz (PUSH_L l)), sz)
1225          -- d - d_v                 the number of words between the TOS
1226          --                         and the 1st slot of the object
1227          --
1228          -- d - d_v - 1             the offset from the TOS of the 1st slot
1229          --
1230          -- d - d_v - 1 + sz - 1    the offset from the TOS of the last slot
1231          --                         of the object.
1232          --
1233          -- Having found the last slot, we proceed to copy the right number of
1234          -- slots on to the top of the stack.
1235
1236    | otherwise  -- v must be a global variable
1237    = do dflags <- getDynFlags
1238         let sz :: Word16
1239             sz = fromIntegral (idSizeW dflags v)
1240         MASSERT(sz == 1)
1241         return (unitOL (PUSH_G (getName v)), sz)
1242
1243
1244 pushAtom _ _ (AnnLit lit) = do
1245      dflags <- getDynFlags
1246      let code rep
1247              = let size_host_words = fromIntegral (argRepSizeW dflags rep)
1248                in  return (unitOL (PUSH_UBX (Left lit) size_host_words),
1249                            size_host_words)
1250
1251      case lit of
1252         MachLabel _ _ _ -> code N
1253         MachWord _    -> code N
1254         MachInt _     -> code N
1255         MachWord64 _  -> code L
1256         MachInt64 _   -> code L
1257         MachFloat _   -> code F
1258         MachDouble _  -> code D
1259         MachChar _    -> code N
1260         MachNullAddr  -> code N
1261         MachStr s     -> pushStr s
1262         -- No LitInteger's should be left by the time this is called.
1263         -- CorePrep should have converted them all to a real core
1264         -- representation.
1265         LitInteger {} -> panic "pushAtom: LitInteger"
1266      where
1267         pushStr s
1268            = let getMallocvilleAddr
1269                     = case s of
1270                          FastBytes n fp ->
1271                             -- we could grab the Ptr from the ForeignPtr,
1272                             -- but then we have no way to control its lifetime.
1273                             -- In reality it'll probably stay alive long enoungh
1274                             -- by virtue of the global FastString table, but
1275                             -- to be on the safe side we copy the string into
1276                             -- a malloc'd area of memory.
1277                                 do ptr <- ioToBc (mallocBytes (n+1))
1278                                    recordMallocBc ptr
1279                                    ioToBc (
1280                                       withForeignPtr fp $ \p -> do
1281                                          memcpy ptr p (fromIntegral n)
1282                                          pokeByteOff ptr n (fromIntegral (ord '\0') :: Word8)
1283                                          return ptr
1284                                       )
1285              in do
1286                 addr <- getMallocvilleAddr
1287                 -- Get the addr on the stack, untaggedly
1288                 return (unitOL (PUSH_UBX (Right addr) 1), 1)
1289
1290 pushAtom _ _ expr
1291    = pprPanic "ByteCodeGen.pushAtom"
1292               (pprCoreExpr (deAnnotate (undefined, expr)))
1293
1294 foreign import ccall unsafe "memcpy"
1295  memcpy :: Ptr a -> Ptr b -> CSize -> IO ()
1296
1297
1298 -- -----------------------------------------------------------------------------
1299 -- Given a bunch of alts code and their discrs, do the donkey work
1300 -- of making a multiway branch using a switch tree.
1301 -- What a load of hassle!
1302
1303 mkMultiBranch :: Maybe Int      -- # datacons in tycon, if alg alt
1304                                 -- a hint; generates better code
1305                                 -- Nothing is always safe
1306               -> [(Discr, BCInstrList)]
1307               -> BcM BCInstrList
1308 mkMultiBranch maybe_ncons raw_ways = do
1309      lbl_default <- getLabelBc
1310
1311      let
1312          mkTree :: [(Discr, BCInstrList)] -> Discr -> Discr -> BcM BCInstrList
1313          mkTree [] _range_lo _range_hi = return (unitOL (JMP lbl_default))
1314              -- shouldn't happen?
1315
1316          mkTree [val] range_lo range_hi
1317             | range_lo == range_hi
1318             = return (snd val)
1319             | null defaults -- Note [CASEFAIL]
1320             = do lbl <- getLabelBc
1321                  return (testEQ (fst val) lbl
1322                             `consOL` (snd val
1323                             `appOL`  (LABEL lbl `consOL` unitOL CASEFAIL)))
1324             | otherwise
1325             = return (testEQ (fst val) lbl_default `consOL` snd val)
1326
1327             -- Note [CASEFAIL] It may be that this case has no default
1328             -- branch, but the alternatives are not exhaustive - this
1329             -- happens for GADT cases for example, where the types
1330             -- prove that certain branches are impossible.  We could
1331             -- just assume that the other cases won't occur, but if
1332             -- this assumption was wrong (because of a bug in GHC)
1333             -- then the result would be a segfault.  So instead we
1334             -- emit an explicit test and a CASEFAIL instruction that
1335             -- causes the interpreter to barf() if it is ever
1336             -- executed.
1337
1338          mkTree vals range_lo range_hi
1339             = let n = length vals `div` 2
1340                   vals_lo = take n vals
1341                   vals_hi = drop n vals
1342                   v_mid = fst (head vals_hi)
1343               in do
1344               label_geq <- getLabelBc
1345               code_lo <- mkTree vals_lo range_lo (dec v_mid)
1346               code_hi <- mkTree vals_hi v_mid range_hi
1347               return (testLT v_mid label_geq
1348                       `consOL` (code_lo
1349                       `appOL`   unitOL (LABEL label_geq)
1350                       `appOL`   code_hi))
1351
1352          the_default
1353             = case defaults of
1354                 []         -> nilOL
1355                 [(_, def)] -> LABEL lbl_default `consOL` def
1356                 _          -> panic "mkMultiBranch/the_default"
1357      instrs <- mkTree notd_ways init_lo init_hi
1358      return (instrs `appOL` the_default)
1359   where
1360          (defaults, not_defaults) = partition (isNoDiscr.fst) raw_ways
1361          notd_ways = sortBy (comparing fst) not_defaults
1362
1363          testLT (DiscrI i) fail_label = TESTLT_I i fail_label
1364          testLT (DiscrW i) fail_label = TESTLT_W i fail_label
1365          testLT (DiscrF i) fail_label = TESTLT_F i fail_label
1366          testLT (DiscrD i) fail_label = TESTLT_D i fail_label
1367          testLT (DiscrP i) fail_label = TESTLT_P i fail_label
1368          testLT NoDiscr    _          = panic "mkMultiBranch NoDiscr"
1369
1370          testEQ (DiscrI i) fail_label = TESTEQ_I i fail_label
1371          testEQ (DiscrW i) fail_label = TESTEQ_W i fail_label
1372          testEQ (DiscrF i) fail_label = TESTEQ_F i fail_label
1373          testEQ (DiscrD i) fail_label = TESTEQ_D i fail_label
1374          testEQ (DiscrP i) fail_label = TESTEQ_P i fail_label
1375          testEQ NoDiscr    _          = panic "mkMultiBranch NoDiscr"
1376
1377          -- None of these will be needed if there are no non-default alts
1378          (init_lo, init_hi)
1379             | null notd_ways
1380             = panic "mkMultiBranch: awesome foursome"
1381             | otherwise
1382             = case fst (head notd_ways) of
1383                 DiscrI _ -> ( DiscrI minBound,  DiscrI maxBound )
1384                 DiscrW _ -> ( DiscrW minBound,  DiscrW maxBound )
1385                 DiscrF _ -> ( DiscrF minF,      DiscrF maxF )
1386                 DiscrD _ -> ( DiscrD minD,      DiscrD maxD )
1387                 DiscrP _ -> ( DiscrP algMinBound, DiscrP algMaxBound )
1388                 NoDiscr -> panic "mkMultiBranch NoDiscr"
1389
1390          (algMinBound, algMaxBound)
1391             = case maybe_ncons of
1392                  -- XXX What happens when n == 0?
1393                  Just n  -> (0, fromIntegral n - 1)
1394                  Nothing -> (minBound, maxBound)
1395
1396          isNoDiscr NoDiscr = True
1397          isNoDiscr _       = False
1398
1399          dec (DiscrI i) = DiscrI (i-1)
1400          dec (DiscrW w) = DiscrW (w-1)
1401          dec (DiscrP i) = DiscrP (i-1)
1402          dec other      = other         -- not really right, but if you
1403                 -- do cases on floating values, you'll get what you deserve
1404
1405          -- same snotty comment applies to the following
1406          minF, maxF :: Float
1407          minD, maxD :: Double
1408          minF = -1.0e37
1409          maxF =  1.0e37
1410          minD = -1.0e308
1411          maxD =  1.0e308
1412
1413
1414 -- -----------------------------------------------------------------------------
1415 -- Supporting junk for the compilation schemes
1416
1417 -- Describes case alts
1418 data Discr
1419    = DiscrI Int
1420    | DiscrW Word
1421    | DiscrF Float
1422    | DiscrD Double
1423    | DiscrP Word16
1424    | NoDiscr
1425     deriving (Eq, Ord)
1426
1427 instance Outputable Discr where
1428    ppr (DiscrI i) = int i
1429    ppr (DiscrW w) = text (show w)
1430    ppr (DiscrF f) = text (show f)
1431    ppr (DiscrD d) = text (show d)
1432    ppr (DiscrP i) = ppr i
1433    ppr NoDiscr    = text "DEF"
1434
1435
1436 lookupBCEnv_maybe :: Id -> BCEnv -> Maybe Word
1437 lookupBCEnv_maybe = Map.lookup
1438
1439 idSizeW :: DynFlags -> Id -> Int
1440 idSizeW dflags = argRepSizeW dflags . bcIdArgRep
1441
1442 bcIdArgRep :: Id -> ArgRep
1443 bcIdArgRep = toArgRep . bcIdPrimRep
1444
1445 bcIdPrimRep :: Id -> PrimRep
1446 bcIdPrimRep = typePrimRep . bcIdUnaryType
1447
1448 isFollowableArg :: ArgRep -> Bool
1449 isFollowableArg P = True
1450 isFollowableArg _ = False
1451
1452 isVoidArg :: ArgRep -> Bool
1453 isVoidArg V = True
1454 isVoidArg _ = False
1455
1456 bcIdUnaryType :: Id -> UnaryType
1457 bcIdUnaryType x = case repType (idType x) of
1458     UnaryRep rep_ty -> rep_ty
1459     UbxTupleRep [rep_ty] -> rep_ty
1460     UbxTupleRep [rep_ty1, rep_ty2]
1461       | VoidRep <- typePrimRep rep_ty1 -> rep_ty2
1462       | VoidRep <- typePrimRep rep_ty2 -> rep_ty1
1463     _ -> pprPanic "bcIdUnaryType" (ppr x $$ ppr (idType x))
1464
1465 -- See bug #1257
1466 unboxedTupleException :: a
1467 unboxedTupleException
1468    = throwGhcException
1469         (ProgramError
1470            ("Error: bytecode compiler can't handle unboxed tuples.\n"++
1471             "  Possibly due to foreign import/export decls in source.\n"++
1472             "  Workaround: use -fobject-code, or compile this module to .o separately."))
1473
1474
1475 mkSLIDE :: Word16 -> Word -> OrdList BCInstr
1476 mkSLIDE n d
1477     -- if the amount to slide doesn't fit in a word,
1478     -- generate multiple slide instructions
1479     | d > fromIntegral limit
1480     = SLIDE n limit `consOL` mkSLIDE n (d - fromIntegral limit)
1481     | d == 0
1482     = nilOL
1483     | otherwise
1484     = if d == 0 then nilOL else unitOL (SLIDE n $ fromIntegral d)
1485     where
1486         limit :: Word16
1487         limit = maxBound
1488
1489 splitApp :: AnnExpr' Var ann -> (AnnExpr' Var ann, [AnnExpr' Var ann])
1490         -- The arguments are returned in *right-to-left* order
1491 splitApp e | Just e' <- bcView e = splitApp e'
1492 splitApp (AnnApp (_,f) (_,a))    = case splitApp f of
1493                                       (f', as) -> (f', a:as)
1494 splitApp e                       = (e, [])
1495
1496
1497 bcView :: AnnExpr' Var ann -> Maybe (AnnExpr' Var ann)
1498 -- The "bytecode view" of a term discards
1499 --  a) type abstractions
1500 --  b) type applications
1501 --  c) casts
1502 --  d) ticks (but not breakpoints)
1503 -- Type lambdas *can* occur in random expressions,
1504 -- whereas value lambdas cannot; that is why they are nuked here
1505 bcView (AnnCast (_,e) _)             = Just e
1506 bcView (AnnLam v (_,e)) | isTyVar v  = Just e
1507 bcView (AnnApp (_,e) (_, AnnType _)) = Just e
1508 bcView (AnnTick Breakpoint{} _)      = Nothing
1509 bcView (AnnTick _other_tick (_,e))   = Just e
1510 bcView _                             = Nothing
1511
1512 isVAtom :: AnnExpr' Var ann -> Bool
1513 isVAtom e | Just e' <- bcView e = isVAtom e'
1514 isVAtom (AnnVar v)              = isVoidArg (bcIdArgRep v)
1515 isVAtom (AnnCoercion {})        = True
1516 isVAtom _                     = False
1517
1518 atomPrimRep :: AnnExpr' Id ann -> PrimRep
1519 atomPrimRep e | Just e' <- bcView e = atomPrimRep e'
1520 atomPrimRep (AnnVar v)              = bcIdPrimRep v
1521 atomPrimRep (AnnLit l)              = typePrimRep (literalType l)
1522 atomPrimRep (AnnCoercion {})        = VoidRep
1523 atomPrimRep other = pprPanic "atomPrimRep" (ppr (deAnnotate (undefined,other)))
1524
1525 atomRep :: AnnExpr' Id ann -> ArgRep
1526 atomRep e = toArgRep (atomPrimRep e)
1527
1528 isPtrAtom :: AnnExpr' Id ann -> Bool
1529 isPtrAtom e = isFollowableArg (atomRep e)
1530
1531 -- Let szsw be the sizes in words of some items pushed onto the stack,
1532 -- which has initial depth d'.  Return the values which the stack environment
1533 -- should map these items to.
1534 mkStackOffsets :: Word -> [Word] -> [Word]
1535 mkStackOffsets original_depth szsw
1536    = map (subtract 1) (tail (scanl (+) original_depth szsw))
1537
1538 typeArgRep :: Type -> ArgRep
1539 typeArgRep = toArgRep . typePrimRep
1540
1541 -- -----------------------------------------------------------------------------
1542 -- The bytecode generator's monad
1543
1544 type BcPtr = Either ItblPtr (Ptr ())
1545
1546 data BcM_State
1547    = BcM_State
1548         { bcm_dflags :: DynFlags
1549         , uniqSupply :: UniqSupply       -- for generating fresh variable names
1550         , thisModule :: Module           -- current module (for breakpoints)
1551         , nextlabel :: Word16            -- for generating local labels
1552         , malloced  :: [BcPtr]           -- thunks malloced for current BCO
1553                                          -- Should be free()d when it is GCd
1554         , breakArray :: BreakArray       -- array of breakpoint flags
1555         }
1556
1557 newtype BcM r = BcM (BcM_State -> IO (BcM_State, r))
1558
1559 ioToBc :: IO a -> BcM a
1560 ioToBc io = BcM $ \st -> do
1561   x <- io
1562   return (st, x)
1563
1564 runBc :: DynFlags -> UniqSupply -> Module -> ModBreaks -> BcM r
1565       -> IO (BcM_State, r)
1566 runBc dflags us this_mod modBreaks (BcM m)
1567    = m (BcM_State dflags us this_mod 0 [] breakArray)
1568    where
1569    breakArray = modBreaks_flags modBreaks
1570
1571 thenBc :: BcM a -> (a -> BcM b) -> BcM b
1572 thenBc (BcM expr) cont = BcM $ \st0 -> do
1573   (st1, q) <- expr st0
1574   let BcM k = cont q
1575   (st2, r) <- k st1
1576   return (st2, r)
1577
1578 thenBc_ :: BcM a -> BcM b -> BcM b
1579 thenBc_ (BcM expr) (BcM cont) = BcM $ \st0 -> do
1580   (st1, _) <- expr st0
1581   (st2, r) <- cont st1
1582   return (st2, r)
1583
1584 returnBc :: a -> BcM a
1585 returnBc result = BcM $ \st -> (return (st, result))
1586
1587 instance Monad BcM where
1588   (>>=) = thenBc
1589   (>>)  = thenBc_
1590   return = returnBc
1591
1592 instance HasDynFlags BcM where
1593     getDynFlags = BcM $ \st -> return (st, bcm_dflags st)
1594
1595 emitBc :: ([BcPtr] -> ProtoBCO Name) -> BcM (ProtoBCO Name)
1596 emitBc bco
1597   = BcM $ \st -> return (st{malloced=[]}, bco (malloced st))
1598
1599 recordMallocBc :: Ptr a -> BcM ()
1600 recordMallocBc a
1601   = BcM $ \st -> return (st{malloced = Right (castPtr a) : malloced st}, ())
1602
1603 recordItblMallocBc :: ItblPtr -> BcM ()
1604 recordItblMallocBc a
1605   = BcM $ \st -> return (st{malloced = Left a : malloced st}, ())
1606
1607 getLabelBc :: BcM Word16
1608 getLabelBc
1609   = BcM $ \st -> do let nl = nextlabel st
1610                     when (nl == maxBound) $
1611                         panic "getLabelBc: Ran out of labels"
1612                     return (st{nextlabel = nl + 1}, nl)
1613
1614 getLabelsBc :: Word16 -> BcM [Word16]
1615 getLabelsBc n
1616   = BcM $ \st -> let ctr = nextlabel st
1617                  in return (st{nextlabel = ctr+n}, [ctr .. ctr+n-1])
1618
1619 getBreakArray :: BcM BreakArray
1620 getBreakArray = BcM $ \st -> return (st, breakArray st)
1621
1622 newUnique :: BcM Unique
1623 newUnique = BcM $
1624    \st -> case takeUniqFromSupply (uniqSupply st) of
1625              (uniq, us) -> let newState = st { uniqSupply = us }
1626                            in  return (newState, uniq)
1627
1628 getCurrentModule :: BcM Module
1629 getCurrentModule = BcM $ \st -> return (st, thisModule st)
1630
1631 newId :: Type -> BcM Id
1632 newId ty = do
1633     uniq <- newUnique
1634     return $ mkSysLocal tickFS uniq ty
1635
1636 tickFS :: FastString
1637 tickFS = fsLit "ticked"
1638 \end{code}