Bump array submodule
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.1], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl this makes sure `./configure --target=<cross-compile-target>`
37 dnl works as expected, since we're slightly modifying how Autoconf
38 dnl interprets build/host/target and how this interacts with $CC tests
39 test -n "$target_alias" && ac_tool_prefix=$target_alias-
40
41 dnl ----------------------------------------------------------
42 dnl ** Find unixy sort and find commands,
43 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
44
45 dnl ** Find find command (for Win32's benefit)
46 FP_PROG_FIND
47 FP_PROG_SORT
48
49 dnl ----------------------------------------------------------
50 FP_SETUP_PROJECT_VERSION
51
52 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
53 AC_SUBST([release], [1])
54
55 # First off, a distrib sanity check..
56 AC_CONFIG_SRCDIR([mk/config.mk.in])
57
58 dnl * We require autoconf version 2.60
59 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
60 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
61 dnl Using autoconf 2.59 started to give nonsense like this
62 dnl  #define SIZEOF_CHAR 0
63 dnl recently.
64 AC_PREREQ([2.60])
65
66 # -------------------------------------------------------------------------
67 # Prepare to generate the following header files
68 #
69 #
70 AC_CONFIG_HEADER(mk/config.h)
71
72 # No, semi-sadly, we don't do `--srcdir'...
73 if test x"$srcdir" != 'x.' ; then
74     echo "This configuration does not support the \`--srcdir' option.."
75     exit 1
76 fi
77
78 dnl --------------------------------------------------------------
79 dnl * Project specific configuration options
80 dnl --------------------------------------------------------------
81 dnl What follows is a bunch of options that can either be configured
82 dnl through command line options to the configure script or by
83 dnl supplying defns in the build tree's mk/build.mk. Having the option to
84 dnl use either is considered a Feature.
85
86 dnl ** What command to use to compile compiler sources ?
87 dnl --------------------------------------------------------------
88
89 AC_ARG_WITH([ghc],
90 [AC_HELP_STRING([--with-ghc=ARG],
91   [Use ARG as the path to GHC  [default=autodetect]])],
92   [WithGhc="$withval"],
93   [if test "$GHC" = ""; then
94     AC_PATH_PROG([GHC], [ghc])
95   fi
96   WithGhc="$GHC"])
97
98 dnl ** Tell the make system which OS we are using
99 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
100 AC_SUBST(OSTYPE)
101
102 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
103 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
104                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
105         EnableBootstrapWithDevelSnaphost=YES,
106         EnableBootstrapWithDevelSnaphost=NO
107 )
108
109 AC_ARG_ENABLE(tarballs-autodownload,
110 [AC_HELP_STRING([--enable-tarballs-autodownload],
111                 [Automatically download Windows distribution binaries if needed.])],
112         TarballsAutodownload=YES,
113         TarballsAutodownload=NO
114 )
115
116 dnl CC_STAGE0 is like the "previous" variable CC (inherited by CC_STAGE[123])
117 dnl but instead used by stage0 for bootstrapping stage1
118 AC_ARG_VAR(CC_STAGE0, [C compiler command (bootstrap)])
119
120 if test "$WithGhc" != ""; then
121   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
122
123   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
124      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
125   fi
126
127   AC_SUBST(GhcVersion)dnl
128   AC_SUBST(GhcMajVersion)dnl
129   AC_SUBST(GhcMinVersion)dnl
130   AC_SUBST(GhcPatchLevel)dnl
131   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
132   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
133
134   dnl infer CC_STAGE0 from `ghc --info` unless explicitly set by user
135   if test -z "$CC_STAGE0"; then
136     BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
137   fi
138
139   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
140   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
141   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
142   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
143 fi
144
145 dnl ** Must have GHC to build GHC
146 if test "$WithGhc" = ""
147 then
148     AC_MSG_ERROR([GHC is required.])
149 fi
150 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.10],
151     [AC_MSG_ERROR([GHC version 7.10 or later is required to compile GHC.])])
152
153 if test `expr $GhcMinVersion % 2` = "1"
154 then
155     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
156     then
157         AC_MSG_ERROR([
158      $WithGhc is a development snapshot of GHC, version $GhcVersion.
159      Bootstrapping using this version of GHC is not supported, and may not
160      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
161      or --with-ghc to specify a different GHC to use.])
162     fi
163 fi
164
165 GHC_PACKAGE_DB_FLAG=package-db
166 AC_SUBST(GHC_PACKAGE_DB_FLAG)
167
168 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.11],
169                     SUPPORTS_THIS_UNIT_ID=NO,
170                     SUPPORTS_THIS_UNIT_ID=YES)
171 AC_SUBST(SUPPORTS_THIS_UNIT_ID)
172
173 # GHC is passed to Cabal, so we need a native path
174 if test "${WithGhc}" != ""
175 then
176     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
177
178     if test "$ghc_host_os" = "mingw32"
179     then
180         # Canonicalise to <drive>:/path/to/ghc
181         WithGhc=`cygpath -m "${WithGhc}"`
182
183         echo "GHC path canonicalised to: ${WithGhc}"
184     fi
185 fi
186 AC_SUBST([WithGhc])
187
188 dnl ** Without optimization some INLINE trickery fails for GHCi
189 SRC_CC_OPTS="-O"
190
191 dnl--------------------------------------------------------------------
192 dnl * Choose host(/target/build) platform
193 dnl--------------------------------------------------------------------
194 dnl If we aren't explicitly told what values to use with configure flags,
195 dnl we ask the bootstrapping compiler what platform it is for
196
197 if test "${WithGhc}" != ""
198 then
199         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
200         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
201         if test "$bootstrap_host" != "$bootstrap_target"
202         then
203                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
204         fi
205 fi
206
207 # We have to run these unconditionally, but we may discard their
208 # results in the following code
209 AC_CANONICAL_BUILD
210 AC_CANONICAL_HOST
211 AC_CANONICAL_TARGET
212
213 FPTOOLS_SET_PLATFORM_VARS
214
215 # Verify that the installed (bootstrap) GHC is capable of generating
216 # code for the requested build platform.
217 if test "$BuildPlatform" != "$bootstrap_target"
218 then
219     echo "This GHC (${WithGhc}) does not generate code for the build platform"
220     echo "   GHC target platform    : $bootstrap_target"
221     echo "   Desired build platform : $BuildPlatform"
222     exit 1
223 fi
224
225 # Testing if we shall enable shared libs support on Solaris.
226 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
227
228 SOLARIS_BROKEN_SHLD=NO
229
230 case $host in
231      i386-*-solaris2)
232      # here we go with the test
233      MINOR=`uname -r|cut -d '.' -f 2-`
234      if test "$MINOR" -lt "11"; then
235          SOLARIS_BROKEN_SHLD=YES
236      fi
237      ;;
238 esac
239
240 AC_SUBST(SOLARIS_BROKEN_SHLD)
241
242 dnl ** Do an unregisterised build?
243 dnl --------------------------------------------------------------
244 case "$HostArch" in
245     i386|x86_64|powerpc|powerpc64|powerpc64le|arm)
246         UnregisterisedDefault=NO
247         ;;
248     *)
249         UnregisterisedDefault=YES
250         ;;
251 esac
252 AC_ARG_ENABLE(unregisterised,
253 [AC_HELP_STRING([--enable-unregisterised],
254 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
255 [ if test x"$enableval" = x"yes"; then
256         Unregisterised=YES
257   else
258         Unregisterised=NO
259   fi
260 ],
261 [Unregisterised="$UnregisterisedDefault"]
262 )
263 AC_SUBST(Unregisterised)
264
265 dnl ** Does target have runtime linker support?
266 dnl --------------------------------------------------------------
267 case "$target" in
268     powerpc64-*|powerpc64le-*|powerpc-ibm-aix*)
269         HaskellHaveRTSLinker=NO
270         ;;
271     *)
272         HaskellHaveRTSLinker=YES
273         ;;
274 esac
275 AC_SUBST(HaskellHaveRTSLinker)
276
277 # Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
278 FP_FIND_ROOT
279
280 fail() {
281     echo >&2
282     echo "$1" >&2
283     exit 1
284 }
285
286
287 if test "$HostOS" = "mingw32"
288 then
289     # Find the mingw-w64 7z file to extract.
290     # NB. If you update the tarballs to a new version of gcc, don't
291     # forget to tweak the paths in driver/gcc/gcc.c.
292     if test "$HostArch" = "i386"
293     then
294         mingw_arch="i686"
295         tarball_dest_dir="mingw-w64/x86"
296         tarball_mingw_dir="mingw32"
297     else
298         mingw_arch="x86_64"
299         tarball_dest_dir="mingw-w64/x86_64"
300         tarball_mingw_dir="mingw64"
301     fi
302 fi
303
304 set_up_tarballs() {
305     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
306     local action
307     if test "$TarballsAutodownload" = "NO"
308     then
309         action="verify"
310     else
311         action="download"
312     fi
313     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
314     case $? in
315         0)
316            rm missing-win32-tarballs
317            ;;
318         2)
319            echo
320            echo "Error:"
321            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
322            echo
323            echo "  * run configure with the --enable-tarballs-autodownload option"
324            echo
325            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
326            echo
327            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
328            echo "    them in the ghc-tarballs directory."
329            echo
330            exit 1
331            ;;
332         *)
333            echo
334            echo "Error fetching msys2 tarballs; see errors above."
335            exit 1
336            ;;
337     esac
338
339     # Extract all the tarballs in one go
340     if ! test -d inplace/mingw
341     then
342         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
343         rm -rf inplace/mingw
344         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
345         ( cd inplace &&
346         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
347         rm ".MTREE" &&
348         rm ".PKGINFO" &&
349         cd .. ) || fail "Error: Could not extract Windows toolchains."
350
351         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
352         touch inplace/mingw
353
354         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
355         # make a wrapper around it to give it the proper paths
356         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
357         PATH=`pwd`/inplace/mingw/bin:$PATH
358         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
359
360         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
361     fi
362 }
363
364 if test "$HostOS" = "mingw32"
365 then
366     test -d inplace || mkdir inplace
367
368     # NB. Download and extract the MingW-w64 distribution if required
369     set_up_tarballs
370
371     mingwbin="$hardtop/inplace/mingw/bin/"
372     CC="${mingwbin}gcc.exe"
373     LD="${mingwbin}ld.exe"
374     NM="${mingwbin}nm.exe"
375     RANLIB="${mingwbin}ranlib.exe"
376     OBJDUMP="${mingwbin}objdump.exe"
377     Windres="${mingwbin}windres.exe"
378     DllWrap="${mingwbin}dllwrap.exe"
379     fp_prog_ar="${mingwbin}ar.exe"
380
381     # NB. Download the perl binaries if required
382     if ! test -d inplace/perl ||
383          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
384     then
385         AC_MSG_NOTICE([Making in-tree perl tree])
386         rm -rf inplace/perl
387         mkdir inplace/perl
388         (
389             cd inplace/perl &&
390             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
391         )
392         AC_MSG_NOTICE([In-tree perl tree created])
393     fi
394 fi
395
396 FP_ICONV
397 FP_GMP
398 FP_CURSES
399
400 XCODE_VERSION()
401
402 SplitObjsBroken=NO
403 if test "$TargetOS_CPP" = "darwin"
404 then
405     # Split objects is broken (#4013) with XCode < 3.2
406     if test "$XCodeVersion1" -lt 3
407     then
408         SplitObjsBroken=YES
409     else
410         if test "$XCodeVersion1" -eq 3
411         then
412             if test "$XCodeVersion2" -lt 2
413             then
414                 SplitObjsBroken=YES
415             fi
416         fi
417     fi
418 fi
419 AC_SUBST([SplitObjsBroken])
420
421 dnl ** Building a cross compiler?
422 dnl --------------------------------------------------------------
423 CrossCompiling=NO
424 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
425 if test "$TargetPlatform" != "$HostPlatform" ; then
426     CrossCompiling=YES
427     cross_compiling=yes   # This tells configure that it can accept just 'target',
428                           # otherwise you get
429                           #   configure: error: cannot run C compiled programs.
430                           #   If you meant to cross compile, use `--host'.
431 fi
432 if test "$BuildPlatform" != "$HostPlatform" ; then
433    AC_MSG_ERROR([
434 You've selected:
435
436   BUILD:  $BuildPlatform   (the architecture we're building on)
437   HOST:   $HostPlatform    (the architecture the compiler we're building will execute on)
438   TARGET: $TargetPlatform  (the architecture the compiler we're building will produce code for)
439
440 BUILD must equal HOST; that is, we do not support building GHC itself
441 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
442 1 will be a cross-compiler, and stage 2 will be the cross-compiled
443 GHC.
444 ])
445 fi
446 if test "$CrossCompiling" = "YES"
447 then
448   CrossCompilePrefix="${target}-"
449 else
450   CrossCompilePrefix=""
451 fi
452 # Despite its similarity in name to TargetPlatform, TargetPlatformFull is used
453 # in calls to subproject configure scripts and thus must be set to the autoconf
454 # triple, not the normalized GHC triple that TargetPlatform is set to.
455 # It may be better to just do away with the GHC triples all together.
456 TargetPlatformFull="${target}"
457 AC_SUBST(CrossCompiling)
458 AC_SUBST(CrossCompilePrefix)
459 AC_SUBST(TargetPlatformFull)
460
461 dnl ** Which gcc to use?
462 dnl --------------------------------------------------------------
463
464 AC_ARG_WITH([gcc],
465         AS_HELP_STRING([--with-gcc=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
466         AC_MSG_ERROR([--with-gcc=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
467
468 AC_ARG_WITH([clang],
469         AS_HELP_STRING([--with-clang=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
470         AC_MSG_ERROR([--with-clang=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
471
472 dnl detect compiler (prefer gcc over clang) and set $CC (unless CC already set),
473 dnl later CC is copied to CC_STAGE{1,2,3}
474 AC_PROG_CC([gcc clang])
475
476 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
477
478 dnl make extensions visible to allow feature-tests to detect them lateron
479 AC_USE_SYSTEM_EXTENSIONS
480
481 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
482 AC_PROG_CPP
483
484 # --with-hs-cpp/--with-hs-cpp-flags
485 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
486 AC_SUBST([HaskellCPPCmd])
487 AC_SUBST([HaskellCPPArgs])
488
489 FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
490 FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
491 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
492 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
493
494 dnl ** Which ld to use?
495 dnl --------------------------------------------------------------
496 FIND_LD([LdCmd])
497 AC_SUBST([LdCmd])
498
499 dnl ** Which nm to use?
500 dnl --------------------------------------------------------------
501 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
502
503 if test "$TargetOS_CPP" = "darwin"
504 then
505     AC_MSG_CHECKING(whether nm program is broken)
506     # Some versions of XCode ship a broken version of `nm`. Detect and work
507     # around this issue. See : https://ghc.haskell.org/trac/ghc/ticket/11744
508     nmver=$(${NM} --version | grep version | sed 's/ //g')
509     case "$nmver" in
510         LLVMversion7.3.0|LLVMversion7.3.1)
511             AC_MSG_RESULT(yes)
512             echo "The detected nm program is broken."
513             echo
514             echo "See: https://ghc.haskell.org/trac/ghc/ticket/11744"
515             echo
516             echo "Try re-running configure with:"
517             echo
518             echo '   ./configure --with-nm=$(xcrun --find nm-classic)'
519             echo
520             exit 1
521             ;;
522         *)
523             AC_MSG_RESULT(no)
524             ;;
525         esac
526 fi
527
528 NmCmd="$NM"
529 AC_SUBST([NmCmd])
530
531 dnl ** Which objdump to use?
532 dnl --------------------------------------------------------------
533 FP_ARG_WITH_PATH_GNU_PROG_OPTIONAL([OBJDUMP], [objdump], [objdump])
534 ObjdumpCmd="$OBJDUMP"
535 AC_SUBST([ObjdumpCmd])
536
537 dnl ** Which ar to use?
538 dnl --------------------------------------------------------------
539 FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
540 ArCmd="$AR"
541 fp_prog_ar="$AR"
542 AC_SUBST([ArCmd])
543
544 dnl ** Which ranlib to use?
545 dnl --------------------------------------------------------------
546 FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
547 RanlibCmd="$RANLIB"
548 RANLIB="$RanlibCmd"
549
550
551 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
552 case $HostOS_CPP in
553 cygwin32|mingw32)
554     dnl ** Which objdump to use?
555     dnl --------------------------------------------------------------
556     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
557     ObjdumpCmd="$OBJDUMP"
558     AC_SUBST([ObjdumpCmd])
559     ;;
560 esac
561
562 # Here is where we re-target which specific version of the LLVM
563 # tools we are looking for. In the past, GHC supported a number of
564 # versions of LLVM simultaneously, but that stopped working around
565 # 3.5/3.6 release of LLVM.
566 LlvmVersion=3.9
567 AC_SUBST([LlvmVersion])
568 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
569 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
570
571 dnl ** Which LLVM llc to use?
572 dnl --------------------------------------------------------------
573 FIND_LLVM_PROG([LLC], [llc], [llc], [$LlvmVersion])
574 LlcCmd="$LLC"
575 AC_SUBST([LlcCmd])
576
577 dnl ** Which LLVM opt to use?
578 dnl --------------------------------------------------------------
579 FIND_LLVM_PROG([OPT], [opt], [opt], [$LlvmVersion])
580 OptCmd="$OPT"
581 AC_SUBST([OptCmd])
582
583 dnl --------------------------------------------------------------
584 dnl End of configure script option section
585 dnl --------------------------------------------------------------
586
587
588 dnl --------------------------------------------------------------
589 dnl ** Can the unix package be built?
590 dnl --------------------------------------------------------------
591
592 if test "$TargetOS" = "mingw32"
593 then
594     GhcLibsWithUnix=NO
595 else
596     GhcLibsWithUnix=YES
597 fi
598 AC_SUBST([GhcLibsWithUnix])
599
600 dnl ** does #! work?
601 AC_SYS_INTERPRETER()
602
603 dnl ** look for `perl'
604 case $HostOS_CPP in
605 cygwin32|mingw32)
606     PerlCmd=$hardtop/inplace/perl/perl
607     ;;
608 *)
609     AC_PATH_PROG(PerlCmd,perl)
610     if test -z "$PerlCmd"
611     then
612         echo "You must install perl before you can continue"
613         echo "Perhaps it is already installed, but not in your PATH?"
614         exit 1
615     else
616         FPTOOLS_CHECK_PERL_VERSION
617     fi
618     ;;
619 esac
620
621 dnl ** look for GCC and find out which version
622 dnl     Figure out which C compiler to use.  Gcc is preferred.
623 dnl     If gcc, make sure it's at least 3.0
624 dnl
625 FP_GCC_VERSION
626
627 dnl ** See whether gcc supports -no-pie
628 FP_GCC_SUPPORTS_NO_PIE
629
630 dnl ** look to see if we have a C compiler using an llvm back end.
631 dnl
632 FP_CC_LLVM_BACKEND
633
634 FP_PROG_LD_IS_GNU
635 FP_PROG_LD_BUILD_ID
636 FP_PROG_LD_NO_COMPACT_UNWIND
637 FP_PROG_LD_FILELIST
638
639
640 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
641 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
642 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
643 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
644 # Stage 3 won't be supported by cross-compilation
645
646 FP_GCC_EXTRA_FLAGS
647
648 # See rules/distdir-way-opts.mk for details.
649 # Flags passed to the C compiler
650 AC_SUBST(CONF_CC_OPTS_STAGE0)
651 AC_SUBST(CONF_CC_OPTS_STAGE1)
652 AC_SUBST(CONF_CC_OPTS_STAGE2)
653 # Flags passed to the C compiler when we ask it to link
654 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
655 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
656 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
657 # Flags passed to the linker when we ask it to link
658 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
659 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
660 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
661 # Flags passed to the C preprocessor
662 AC_SUBST(CONF_CPP_OPTS_STAGE0)
663 AC_SUBST(CONF_CPP_OPTS_STAGE1)
664 AC_SUBST(CONF_CPP_OPTS_STAGE2)
665 # Flags passed to the Haskell compiler
666 AC_SUBST(CONF_HC_OPTS_STAGE0)
667 AC_SUBST(CONF_HC_OPTS_STAGE1)
668 AC_SUBST(CONF_HC_OPTS_STAGE2)
669
670 dnl ** Set up the variables for the platform in the settings file.
671 dnl May need to use gcc to find platform details.
672 dnl --------------------------------------------------------------
673 FPTOOLS_SET_HASKELL_PLATFORM_VARS
674
675 dnl ** figure out how to do context diffs
676 FP_PROG_CONTEXT_DIFF
677
678 dnl Let's make sure install-sh is executable here.  If we got it from
679 dnl a darcs repo, it might not be (see bug #978).
680 chmod +x install-sh
681 dnl ** figure out how to do a BSD-ish install
682 AC_PROG_INSTALL
683
684 dnl ** how to invoke `ar' and `ranlib'
685 FP_PROG_AR_SUPPORTS_ATFILE
686 FP_PROG_AR_NEEDS_RANLIB
687
688 dnl ** Check to see whether ln -s works
689 AC_PROG_LN_S
690
691 FP_SETTINGS
692
693 dnl ** Find the path to sed
694 AC_PATH_PROGS(SedCmd,gsed sed,sed)
695
696
697 dnl ** check for time command
698 AC_PATH_PROG(TimeCmd,time)
699
700 dnl ** check for tar
701 dnl   if GNU tar is named gtar, look for it first.
702 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
703
704 dnl ** check for patch
705 dnl if GNU patch is named gpatch, look for it first
706 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
707
708 dnl ** check for dtrace (currently only implemented for Mac OS X)
709 HaveDtrace=NO
710 AC_PATH_PROG(DtraceCmd,dtrace)
711 if test -n "$DtraceCmd"; then
712   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
713     HaveDtrace=YES
714   fi
715 fi
716 AC_SUBST(HaveDtrace)
717
718 AC_PATH_PROG(HSCOLOUR,HsColour)
719 # HsColour is passed to Cabal, so we need a native path
720 if test "$HostOS"      = "mingw32" && \
721    test "${HSCOLOUR}" != ""
722 then
723     # Canonicalise to <drive>:/path/to/gcc
724     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
725 fi
726
727 dnl ** check for Sphinx toolchain
728 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
729 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
730 changequote(, )dnl
731 [if test -n "$SPHINXBUILD"; then
732   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
733 fi;
734 changequote([, ])dnl
735 ])
736 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
737     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
738
739 dnl ** check for xelatex
740 AC_PATH_PROG(XELATEX,xelatex)
741
742 dnl ** check for ghc-pkg command
743 FP_PROG_GHC_PKG
744
745 dnl ** check for installed happy binary + version
746 FPTOOLS_HAPPY
747
748 dnl ** check for installed alex binary + version
749 FPTOOLS_ALEX
750
751 dnl --------------------------------------------------
752 dnl ### program checking section ends here ###
753 dnl --------------------------------------------------
754
755 dnl --------------------------------------------------
756 dnl * Platform header file and syscall feature tests
757 dnl ### checking the state of the local header files and syscalls ###
758
759 dnl ** check for full ANSI header (.h) files
760 AC_HEADER_STDC
761
762 dnl ** Enable large file support.  NB. do this before testing the type of
763 dnl    off_t, because it will affect the result of that test.
764 AC_SYS_LARGEFILE
765
766 dnl ** check for specific header (.h) files that we are interested in
767 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
768
769 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
770 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
771 [[#if HAVE_SYS_PARAM_H
772 # include <sys/param.h>
773 #endif
774 ]])
775
776 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
777 AC_HEADER_TIME
778
779 dnl ** do we have long longs?
780 AC_CHECK_TYPES([long long])
781
782 dnl ** what are the sizes of various types
783 FP_CHECK_SIZEOF_AND_ALIGNMENT(char)
784 FP_CHECK_SIZEOF_AND_ALIGNMENT(double)
785 FP_CHECK_SIZEOF_AND_ALIGNMENT(float)
786 FP_CHECK_SIZEOF_AND_ALIGNMENT(int)
787 FP_CHECK_SIZEOF_AND_ALIGNMENT(long)
788 if test "$ac_cv_type_long_long" = yes; then
789 FP_CHECK_SIZEOF_AND_ALIGNMENT(long long)
790 fi
791 FP_CHECK_SIZEOF_AND_ALIGNMENT(short)
792 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned char)
793 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned int)
794 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long)
795 if test "$ac_cv_type_long_long" = yes; then
796 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long long)
797 fi
798 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned short)
799 FP_CHECK_SIZEOF_AND_ALIGNMENT(void *)
800
801 FP_CHECK_SIZEOF_AND_ALIGNMENT(int8_t)
802 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint8_t)
803 FP_CHECK_SIZEOF_AND_ALIGNMENT(int16_t)
804 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint16_t)
805 FP_CHECK_SIZEOF_AND_ALIGNMENT(int32_t)
806 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint32_t)
807 FP_CHECK_SIZEOF_AND_ALIGNMENT(int64_t)
808 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint64_t)
809
810
811 dnl for use in settings.in
812 WordSize=$ac_cv_sizeof_void_p
813 AC_SUBST(WordSize)
814 FP_CHECK_FUNC([WinExec],
815   [@%:@include <windows.h>], [WinExec("",0)])
816
817 FP_CHECK_FUNC([GetModuleFileName],
818   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
819
820 dnl ** check for more functions
821 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
822 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
823
824 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
825 dnl ** _POSIX_C_SOURCE is defined
826 AC_CHECK_DECLS([ctime_r], , ,
827 [#define _POSIX_SOURCE 1
828 #define _POSIX_C_SOURCE 199506L
829 #include <time.h>])
830
831 dnl ** check for mingwex library
832 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
833 AC_SUBST(HaveLibMingwEx)
834
835 if test $HaveLibMingwEx = YES ; then
836   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
837 fi
838
839 dnl ** check for math library
840 dnl    Keep that check as early as possible.
841 dnl    as we need to know whether we need libm
842 dnl    for math functions or not
843 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
844 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
845 if test $HaveLibM = YES
846 then
847   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
848 fi
849
850 FP_BFD_SUPPORT
851
852 dnl ################################################################
853 dnl Check for libraries
854 dnl ################################################################
855
856 # system libffi
857
858 AC_ARG_WITH([system-libffi],
859 [AC_HELP_STRING([--with-system-libffi],
860   [Use system provided libffi for RTS [default=no]])
861 ])
862
863 AS_IF([test "x$with_system_libffi" = "xyes"],
864   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
865 )
866
867
868 AC_SUBST(UseSystemLibFFI)
869
870 AC_ARG_WITH([ffi-includes],
871 [AC_HELP_STRING([--with-ffi-includes=ARG],
872   [Find includes for libffi in ARG [default=system default]])
873 ],
874 [
875  if test "x$UseSystemLibFFI" != "xYES"; then
876     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
877  else
878     FFIIncludeDir="$withval"
879     LIBFFI_CFLAGS="-I$withval"
880  fi
881 ])
882
883 AC_SUBST(FFIIncludeDir)
884
885 AC_ARG_WITH([ffi-libraries],
886 [AC_HELP_STRING([--with-ffi-libraries=ARG],
887   [Find libffi in ARG [default=system default]])
888 ],
889 [
890  if test "x$UseSystemLibFFI" != "xYES"; then
891     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
892  else
893     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
894  fi
895 ])
896
897 AC_SUBST(FFILibDir)
898
899 AS_IF([test "$UseSystemLibFFI" = "YES"], [
900  CFLAGS2="$CFLAGS"
901  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
902  LDFLAGS2="$LDFLAGS"
903  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
904  if test "$HostOS" = "openbsd";
905  then
906    # OpenBSD's libffi is not directly linked to the libpthread but
907    # still requires pthread functionality. This means that any client
908    # binary which links with libffi also needs to link with
909    # libpthread. If it does not, then linking fails with unresolved
910    # symbols.
911    LDFLAGS="$LDFLAGS -lpthread"
912  fi
913  AC_CHECK_LIB(ffi, ffi_call,
914   [AC_CHECK_HEADERS([ffi.h], [break], [])
915    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
916   [AC_MSG_ERROR([Cannot find system libffi])])
917  CFLAGS="$CFLAGS2"
918  LDFLAGS="$LDFLAGS2"
919 ])
920
921 dnl ** check whether we need -ldl to get dlopen()
922 AC_CHECK_LIB(dl, dlopen)
923
924 dnl --------------------------------------------------
925 dnl * Miscellaneous feature tests
926 dnl --------------------------------------------------
927
928 dnl ** can we get alloca?
929 AC_FUNC_ALLOCA
930
931 dnl ** working vfork?
932 AC_FUNC_FORK
933
934 dnl ** determine whether or not const works
935 AC_C_CONST
936
937 dnl ** are we big endian?
938 AC_C_BIGENDIAN
939 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
940
941 dnl ** check for leading underscores in symbol names
942 FP_LEADING_UNDERSCORE
943
944 FP_VISIBILITY_HIDDEN
945
946 dnl ** check for librt
947 AC_CHECK_LIB(rt, clock_gettime)
948 AC_CHECK_FUNCS(clock_gettime timer_settime)
949 FP_CHECK_TIMER_CREATE
950
951 dnl ** check for Apple's "interesting" long double compatibility scheme
952 AC_MSG_CHECKING(for printf\$LDBLStub)
953 AC_TRY_LINK_FUNC(printf\$LDBLStub,
954     [
955         AC_MSG_RESULT(yes)
956         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
957             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
958     ],
959     [
960         AC_MSG_RESULT(no)
961         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
962             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
963     ])
964
965 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
966 dnl    a different single-argument version.
967 AC_CHECK_LIB(pthread, pthread_setname_np)
968 AC_MSG_CHECKING(for pthread_setname_np)
969 AC_TRY_LINK(
970 [
971 #define _GNU_SOURCE
972 #include <pthread.h>
973 ],
974 [pthread_setname_np(pthread_self(), "name");],
975     AC_MSG_RESULT(yes)
976     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
977       [Define to 1 if you have the glibc version of pthread_setname_np]),
978     AC_MSG_RESULT(no)
979 )
980
981 dnl ** check for eventfd which is needed by the I/O manager
982 AC_CHECK_HEADERS([sys/eventfd.h])
983 AC_CHECK_FUNCS([eventfd])
984
985 dnl ** Check for __thread support in the compiler
986 AC_MSG_CHECKING(for __thread support)
987 AC_COMPILE_IFELSE(
988   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
989   [
990    AC_MSG_RESULT(yes)
991    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
992   ],
993   [
994    AC_MSG_RESULT(no)
995    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
996   ])
997
998 dnl large address space support (see includes/rts/storage/MBlock.h)
999 dnl
1000 dnl Darwin has vm_allocate/vm_protect
1001 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1002 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1003 dnl (They also have MADV_DONTNEED, but it means something else!)
1004 dnl
1005 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1006 dnl it counts page-table space as committed memory, and so quickly
1007 dnl runs out of paging file when we have multiple processes reserving
1008 dnl 1TB of address space, we get the following error:
1009 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1010 dnl
1011
1012 AC_ARG_ENABLE(large-address-space,
1013     [AC_HELP_STRING([--enable-large-address-space],
1014         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1015     EnableLargeAddressSpace=$enableval,
1016     EnableLargeAddressSpace=yes
1017 )
1018
1019 use_large_address_space=no
1020 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1021     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1022         if test "$ghc_host_os" = "darwin" ; then
1023             use_large_address_space=yes
1024         elif test "$ghc_host_os" = "openbsd" ; then
1025             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1026             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1027             # but is completely ignored by OS mmap
1028             use_large_address_space=no
1029         else
1030             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1031                 [
1032                 #include <unistd.h>
1033                 #include <sys/types.h>
1034                 #include <sys/mman.h>
1035                 #include <fcntl.h>
1036             ])
1037             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1038                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1039                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1040                     use_large_address_space=yes
1041             fi
1042         fi
1043     fi
1044 fi
1045 if test "$use_large_address_space" = "yes" ; then
1046    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1047 fi
1048
1049 dnl ** Use MMAP in the runtime linker?
1050 dnl --------------------------------------------------------------
1051
1052 case ${TargetOS} in
1053     linux|freebsd|dragonfly|netbsd|openbsd|kfreebsdgnu|gnu|solaris2)
1054         RtsLinkerUseMmap=1
1055         ;;
1056     darwin)
1057         # Don't use mmap on powerpc/darwin as the mmap there doesn't support
1058         # reallocating. Reallocating is needed to allocate jump islands just
1059         # after each object image. Jumps to these jump islands use relative
1060         # branches which are limited to offsets that can be represented in
1061         # 24-bits.
1062         if test "$TargetArch" != "powerpc" ; then
1063             RtsLinkerUseMmap=1
1064         else
1065             RtsLinkerUseMmap=0
1066         fi
1067         ;;
1068     *)
1069         # Windows (which doesn't have mmap) and everything else.
1070         RtsLinkerUseMmap=0
1071         ;;
1072     esac
1073
1074 AC_DEFINE_UNQUOTED([RTS_LINKER_USE_MMAP], [$RtsLinkerUseMmap],
1075                    [Use mmap in the runtime linker])
1076
1077 dnl ** Have libdw?
1078 dnl --------------------------------------------------------------
1079 UseLibdw=NO
1080 USE_LIBDW=0
1081 AC_ARG_ENABLE(dwarf-unwind,
1082     [AC_HELP_STRING([--enable-dwarf-unwind],
1083         [Enable DWARF unwinding support in the runtime system via elfutils' libdw [default=no]])],
1084     [AC_CHECK_LIB(dw, dwfl_attach_state, [UseLibdw=YES], [UseLibdw=NO])],
1085     [UseLibdw=NO]
1086 )
1087 AC_SUBST(UseLibdw)
1088 if test $UseLibdw = "YES" ; then
1089         USE_LIBDW=1
1090 fi
1091 AC_DEFINE_UNQUOTED([USE_LIBDW], [$USE_LIBDW], [Set to 1 to use libdw])
1092
1093 dnl ** Have libnuma?
1094 dnl --------------------------------------------------------------
1095 HaveLibNuma=0
1096 AC_CHECK_HEADERS([numa.h numaif.h])
1097
1098 if test "$ac_cv_header_numa_h$ac_cv_header_numaif_h" = "yesyes" ; then
1099     AC_CHECK_LIB(numa, numa_available,HaveLibNuma=1)
1100 fi
1101 AC_DEFINE_UNQUOTED([HAVE_LIBNUMA], [$HaveLibNuma], [Define to 1 if you have libnuma])
1102
1103 dnl ** Documentation
1104 dnl --------------------------------------------------------------
1105 if test -n "$SPHINXBUILD"; then
1106     BUILD_MAN=YES
1107     BUILD_SPHINX_HTML=YES
1108     if test -n "$XELATEX"; then
1109         BUILD_SPHINX_PDF=YES
1110     else
1111         BUILD_SPHINX_PDF=NO
1112     fi
1113 else
1114     BUILD_MAN=NO
1115     BUILD_SPHINX_HTML=NO
1116     BUILD_SPHINX_PDF=NO
1117 fi
1118 AC_SUBST(BUILD_MAN)
1119 AC_SUBST(BUILD_SPHINX_HTML)
1120 AC_SUBST(BUILD_SPHINX_PDF)
1121
1122 LIBRARY_VERSION(base)
1123 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1124 LIBRARY_VERSION(ghc-prim)
1125 LIBRARY_ghc_VERSION="$ProjectVersion"
1126 AC_SUBST(LIBRARY_ghc_VERSION)
1127
1128 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1129    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1130 fi
1131
1132 # Create the configuration for the Hadrian build system if it is present
1133 if test -e hadrian/cfg/system.config.in; then
1134     AC_CONFIG_FILES([hadrian/cfg/system.config])
1135 fi
1136
1137 # We got caught by
1138 #     http://savannah.gnu.org/bugs/index.php?1516
1139 #     $(eval ...) inside conditionals causes errors
1140 # with make 3.80, so warn the user if it looks like they're about to
1141 # try to use it.
1142 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1143 print_make_warning=""
1144 checkMake380() {
1145     make_ver=`$1 --version 2>&1 | head -1`
1146     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1147     then
1148         print_make_warning="true"
1149     fi
1150     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1151     then
1152         MakeCmd=$1
1153         AC_SUBST(MakeCmd)
1154     fi
1155 }
1156
1157 checkMake380 make
1158 checkMake380 gmake
1159
1160 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghc-boot-th/ghc-boot-th.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt distrib/configure.ac])
1161 AC_OUTPUT
1162
1163 if test "$print_make_warning" = "true"; then
1164    echo
1165    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1166    echo "This version cannot be used to build GHC."
1167    echo "Please use GNU make >= 3.81."
1168 fi
1169
1170 echo ["
1171 ----------------------------------------------------------------------
1172 Configure completed successfully.
1173
1174    Building GHC version  : $ProjectVersion
1175           Git commit id  : $ProjectGitCommitId
1176
1177    Build platform        : $BuildPlatform
1178    Host platform         : $HostPlatform
1179    Target platform       : $TargetPlatform
1180 "]
1181
1182 echo ["\
1183    Bootstrapping using   : $WithGhc
1184       which is version   : $GhcVersion
1185 "]
1186
1187 if test "x$CC_LLVM_BACKEND" = "x1"; then
1188     if test "x$CC_CLANG_BACKEND" = "x1"; then
1189         CompilerName="clang        "
1190     else
1191         CompilerName="llvm-gcc     "
1192     fi
1193 else
1194     CompilerName="gcc          "
1195 fi
1196
1197 echo ["\
1198    Using (for bootstrapping) : $CC_STAGE0
1199    Using $CompilerName       : $CC
1200       which is version       : $GccVersion
1201    Building a cross compiler : $CrossCompiling
1202    Unregisterised            : $Unregisterised
1203    hs-cpp       : $HaskellCPPCmd
1204    hs-cpp-flags : $HaskellCPPArgs
1205    ld           : $LdCmd
1206    nm           : $NmCmd
1207    objdump      : $ObjdumpCmd
1208    Happy        : $HappyCmd ($HappyVersion)
1209    Alex         : $AlexCmd ($AlexVersion)
1210    Perl         : $PerlCmd
1211    sphinx-build : $SPHINXBUILD
1212    xelatex      : $XELATEX
1213
1214    Using LLVM tools
1215       llc   : $LlcCmd
1216       opt   : $OptCmd"]
1217
1218 if test "$HSCOLOUR" = ""; then
1219 echo ["
1220    HsColour was not found; documentation will not contain source links
1221 "]
1222 else
1223 echo ["\
1224    HsColour : $HSCOLOUR
1225 "]
1226 fi
1227
1228 echo ["\
1229    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1230    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"]
1231
1232 echo ["----------------------------------------------------------------------
1233 "]
1234
1235 echo "\
1236 For a standard build of GHC (fully optimised with profiling), type (g)make.
1237
1238 To make changes to the default build configuration, copy the file
1239 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1240
1241 For more information on how to configure your GHC build, see
1242    http://ghc.haskell.org/trac/ghc/wiki/Building
1243 "