[project @ 2004-11-20 16:02:41 by panne]
[ghc.git] / aclocal.m4
1 # Extra autoconf macros for the Glasgow fptools
2 #
3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
4 # ensure we don't clash with any pre-supplied autoconf ones.
5
6
7 # FP_EVAL_STDERR(COMMAND)
8 # -----------------------
9 # Eval COMMAND, save its stderr (without lines resulting from shell tracing)
10 # into the file conftest.err and the exit status in the variable fp_status.
11 AC_DEFUN([FP_EVAL_STDERR],
12 [{ (eval $1) 2>conftest.er1
13   fp_status=$?
14   grep -v '^ *+' conftest.er1 >conftest.err
15   rm -f conftest.er1
16   (exit $fp_status); }[]dnl
17 ])# FP_EVAL_STDERR
18
19
20 # FP_CHECK_FLAG(FLAG, [ACTION-IF-SUPPORTED], [ACTION-IF-NOT-SUPPORTED])
21 # ---------------------------------------------------------------------
22 # Check to see whether the compiler for the current language supports a
23 # particular option.
24 #
25 # Implementation note: When given an unkown option, GCC issues an warning on
26 # stderr only, but returns an exit value of 0 nevertheless. Consequently we have
27 # to check stderr *and* the exit value.
28 #
29 # Used by ghc.
30 AC_DEFUN(FP_CHECK_FLAG,
31 [AC_LANG_COMPILER_REQUIRE()dnl
32 AC_LANG_CASE([C],          [fp_compiler="$CC"  m4_pushdef([fp_Flags], [CFLAGS])],
33              [C++],        [fp_compiler="$CXX" m4_pushdef([fp_Flags], [CXXFLAGS])],
34              [Fortran 77], [fp_compiler="$F77" m4_pushdef([fp_Flags], [FFLAGS])])
35 m4_pushdef([fp_Cache], [fp_cv_[]fp_Flags[]AS_TR_SH([$1])])[]dnl
36 AC_CACHE_CHECK([whether $fp_compiler accepts $1], [fp_Cache],
37 [AC_LANG_CONFTEST([AC_LANG_PROGRAM()])
38 fp_save_flags="$fp_Flags"
39 fp_Flags="$fp_Flags $1"
40 fp_Cache=no
41 if FP_EVAL_STDERR([$ac_compile conftest.$ac_ext]) >/dev/null; then
42   test -s conftest.err || fp_Cache=yes
43 fi
44 fp_Flags="$fp_save_flags"
45 rm -f conftest.err conftest.$ac_ext])
46 AS_IF([test $fp_Cache = yes], [$2], [$3])[]dnl
47 m4_popdef([fp_Cache])[]dnl
48 m4_popdef([fp_Flags])[]dnl
49 ])# FP_CHECK_FLAG
50
51
52 # FP_PROG_CONTEXT_DIFF
53 # --------------------
54 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
55 #
56 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
57 #
58 # Used by ghc, glafp-utils/ltx, and glafp-utils/runstdtest.
59 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
60 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
61 [echo foo > conftest1
62 echo foo > conftest2
63 fp_cv_context_diff=no
64 for fp_var in '-C 1' '-c1'
65 do
66   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
67     fp_cv_context_diff="diff $fp_var"
68     break
69   fi
70 done])
71 if test x"$fp_cv_context_diff" = xno; then
72    AC_MSG_ERROR([cannot figure out how to do context diffs])
73 fi
74 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
75 ])# FP_PROG_CONTEXT_DIFF
76
77
78 # FP_DECL_ALTZONE
79 # ---------------
80 # Defines HAVE_DECL_ALTZONE to 1 if declared, 0 otherwise.
81 #
82 # Used by base package.
83 AC_DEFUN([FP_DECL_ALTZONE],
84 [AC_REQUIRE([AC_HEADER_TIME])dnl
85 AC_CHECK_HEADERS([sys/time.h])
86 AC_CHECK_DECLS([altzone], [], [],[#if TIME_WITH_SYS_TIME
87 # include <sys/time.h>
88 # include <time.h>
89 #else
90 # if HAVE_SYS_TIME_H
91 #  include <sys/time.h>
92 # else
93 #  include <time.h>
94 # endif
95 #endif])
96 ])# FP_DECL_ALTZONE
97
98
99 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
100 # --------------------------------------------------------
101 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
102 # compilation. Execute IF-FAILS when unable to determine the value. Works for
103 # cross-compilation, too.
104 #
105 # Implementation note: We are lazy and use an internal autoconf macro, but it
106 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
107 # little risk.
108 AC_DEFUN([FP_COMPUTE_INT],
109 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
110 ])# FP_COMPUTE_INT
111
112
113 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
114 # ------------------------------------------------------------------
115 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
116 # given type. Defines ALIGNMENT_TYPE.
117 AC_DEFUN([FP_CHECK_ALIGNMENT],
118 [AS_LITERAL_IF([$1], [],
119                [AC_FATAL([$0: requires literal arguments])])[]dnl
120 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
121 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
122 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
123 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
124   FP_COMPUTE_INT([(long) (&((struct { char c; $1 ty; } *)0)->ty)],
125                  [fp_Cache],
126                  [AC_INCLUDES_DEFAULT([$3])],
127                  [AC_MSG_ERROR([cannot compute alignment ($1)
128 See `config.log' for more details.], [77])])
129 else
130   fp_Cache=0
131 fi])[]dnl
132 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
133 m4_popdef([fp_Cache])[]dnl
134 ])# FP_CHECK_ALIGNMENT
135
136
137 # FP_LEADING_UNDERSCORE
138 # ---------------------
139 # Test for determining whether symbol names have a leading underscore. We assume
140 # that they _haven't_ if anything goes wrong. Sets the output variable
141 # LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
142 #
143 # Some nlist implementations seem to try to be compatible by ignoring a leading
144 # underscore sometimes (eg. FreeBSD). We therefore have to work around this by
145 # checking for *no* leading underscore first. Sigh.  --SDM
146 #
147 # Similarly on OpenBSD, but this test doesn't help. -- dons
148 AC_DEFUN([FP_LEADING_UNDERSCORE],
149 [AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
150 AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
151 # Hack!: nlist() under Digital UNIX insist on there being an _,
152 # but symbol table listings shows none. What is going on here?!?
153 #
154 # Another hack: cygwin doesn't come with nlist.h , so we hardwire
155 # the underscoredness of that "platform"
156 case $HostPlatform in
157 *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
158   case $build in
159     i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
160     *) fptools_cv_leading_underscore=no ;;
161   esac ;;
162 alpha-dec-osf*) fptools_cv_leading_underscore=no;;
163 *cygwin32) fptools_cv_leading_underscore=yes;;
164 *mingw32) fptools_cv_leading_underscore=yes;;
165 *) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
166 #include <nlist.h>
167 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
168 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
169 #endif
170
171 int main(argc, argv)
172 int argc;
173 char **argv;
174 {
175 #ifdef HAVE_NLIST_H
176     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
177         exit(1);
178     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
179         exit(0);
180 #endif
181     exit(1);
182 }]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
183 ;;
184 esac]);
185 AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
186 if test x"$fptools_cv_leading_underscore" = xyes; then
187    AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
188 fi])# FP_LEADING_UNDERSCORE
189
190
191 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
192 # ----------------------------------------------------------------------------------
193 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
194 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
195 AC_DEFUN([FP_COMPARE_VERSIONS],
196 [fp_version1=$1; fp_version2=$3
197 fp_save_IFS=$IFS; IFS='.'
198 while test x"$fp_version1" != x || test x"$fp_version2" != x
199 do
200
201   set dummy $fp_version1; shift
202   fp_num1=""
203   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
204   test x"$fp_num1" = x && fp_num1="0"
205   fp_version1="[$]*"
206
207   set dummy $fp_version2; shift
208   fp_num2=""
209   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
210   test x"$fp_num2" = x && fp_num2="0"
211   fp_version2="[$]*"
212
213   test "$fp_num1" = "$fp_num2" || break;
214 done
215 IFS=$fp_save_IFS
216 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
217 ])# FP_COMPARE_VERSIONS
218
219
220 dnl
221 dnl Check for GreenCard and version.
222 dnl
223 AC_DEFUN(FPTOOLS_GREENCARD,
224 [
225 AC_PATH_PROG(GreenCardCmd,greencard)
226 AC_CACHE_CHECK([for version of greencard], fptools_cv_greencard_version,
227 changequote(, )dnl
228 [if test x"$GreenCardCmd" != x; then
229    fptools_cv_greencard_version="`$GreenCardCmd --version |
230                           grep 'version' | sed -e 's/greencard. version \([^ ]*\).*/\1/g'`"
231 else
232    fptools_cv_greencard_version=""
233 fi
234 changequote([, ])dnl
235 ])
236 FP_COMPARE_VERSIONS([$fptools_cv_greencard_version],[-lt],[$1],
237   [AC_MSG_ERROR([greencard version $1 or later is required (found '$fptools_cv_greencard_version')])])[]dnl
238 GreenCardVersion=$fptools_cv_greencard_version
239 AC_SUBST(GreenCardVersion)
240 ])
241
242 dnl
243 dnl Check for Happy and version.  If we're building GHC, then we need
244 dnl at least Happy version 1.14.  If there's no installed Happy, we look
245 dnl for a happy source tree and point the build system at that instead.
246 dnl
247 AC_DEFUN(FPTOOLS_HAPPY,
248 [
249 if test -d $srcdir/happy; then
250    SrcTreeHappyCmd=$hardtop/happy/src/happy-inplace
251 fi
252 if test x"$UseSrcTreeHappy" = xYES; then
253   HappyCmd=$SrcTreeHappyCmd
254 else
255   AC_PATH_PROG(HappyCmd,happy,$SrcTreeHappyCmd)
256 fi
257 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
258 changequote(, )dnl
259 [if test x"$HappyCmd" = x"$SrcTreeHappyCmd" -a -e $srcdir/happy/mk/version.mk; then
260    fptools_cv_happy_version=`grep '^ProjectVersion[     ]*=' $srcdir/happy/mk/version.mk | sed 's/.*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
261 elif test x"$HappyCmd" != x; then
262    fptools_cv_happy_version="`$HappyCmd -v |
263                           grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'`" ;
264 else
265    fptools_cv_happy_version="";
266 fi;
267 changequote([, ])dnl
268 ])
269 if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Parser.hs; then
270   FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.14],
271   [AC_MSG_ERROR([Happy version 1.14 or later is required to compile GHC.])])[]dnl
272 fi
273 HappyVersion=$fptools_cv_happy_version;
274 AC_SUBST(HappyVersion)
275 ])
276
277 dnl
278 dnl Check for Haddock and version.  If there's no installed Haddock, we look
279 dnl for a haddock source tree and point the build system at that instead.
280 dnl
281 AC_DEFUN(FPTOOLS_HADDOCK,
282 [
283 if test -d $srcdir/haddock; then
284    SrcTreeHaddockCmd=$hardtop/haddock/src/haddock-inplace
285 fi
286 if test x"$UseSrcTreeHaddock" = xYES; then
287   HaddockCmd=$SrcTreeHaddockCmd
288 else
289   AC_PATH_PROG(HaddockCmd,haddock,$SrcTreeHaddockCmd)
290 fi
291 dnl Darn, I forgot to make Haddock print out its version number when
292 dnl invoked with -v.  We could try generating some HTML and grepping
293 dnl through that to find the version number, but I think we'll make
294 dnl do without it for now.
295 ])
296
297 dnl
298 dnl Check for Alex and version.  If we're building GHC, then we need
299 dnl at least Alex version 2.0.  If there's no installed Alex, we look
300 dnl for a alex source tree and point the build system at that instead.
301 dnl
302 AC_DEFUN(FPTOOLS_ALEX,
303 [
304 if test -d $srcdir/alex; then
305    SrcTreeAlexCmd=$hardtop/alex/src/alex-inplace
306 fi
307 if test x"$UseSrcTreeAlex" = xYES; then
308   AlexCmd=$SrcTreeAlexCmd
309 else
310   AC_PATH_PROG(AlexCmd,alex,$SrcTreeAlexCmd)
311 fi
312 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
313 changequote(, )dnl
314 [if test x"$AlexCmd" = x"$SrcTreeAlexCmd"; then
315    fptools_cv_alex_version=`grep '^ProjectVersion[      ]*=' $srcdir/alex/mk/version.mk | sed 's/.*\([0-9][0-9]*\.[0-9][0-9]*\).*/\1/g'`;
316 elif test x"$AlexCmd" != x; then
317    fptools_cv_alex_version="`$AlexCmd -v |
318                           grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'`" ;
319 else
320    fptools_cv_alex_version="";
321 fi;
322 changequote([, ])dnl
323 ])
324 if test -d $srcdir/ghc -a ! -f $srcdir/ghc/compiler/parser/Lexer.hs; then
325   FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[2.0],
326   [AC_MSG_ERROR([Alex version 2.0 or later is required to compile GHC.])])[]dnl
327 fi
328 AlexVersion=$fptools_cv_alex_version;
329 AC_SUBST(AlexVersion)
330 ])
331
332
333 dnl
334 dnl Check whether ld supports -x
335 dnl
336 AC_DEFUN(FPTOOLS_LD_X,
337 [AC_CACHE_CHECK([whether ld understands -x], fptools_cv_ld_x,
338 [
339 echo 'foo() {}' > conftest.c
340 ${CC-cc} -c conftest.c
341 if ${LdCmd} -r -x -o foo.o conftest.o; then
342    fptools_cv_ld_x=yes
343 else
344    fptools_cv_ld_x=no
345 fi
346 rm -rf conftest.c conftest.o foo.o
347 ])
348 if test "$fptools_cv_ld_x" = yes; then
349         LdXFlag=-x
350 else
351         LdXFlag=
352 fi
353 AC_SUBST(LdXFlag)
354 ])
355
356
357 # FP_PROG_AR
358 # ----------
359 # Sets fp_prog_ar_raw to the full path of ar and fp_prog_ar to a non-Cygwin
360 # version of it. Exits if no ar can be found
361 AC_DEFUN([FP_PROG_AR],
362 [AC_PATH_PROG([fp_prog_ar_raw], [ar])
363 if test -z "$fp_prog_ar_raw"; then
364   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
365 fi
366 fp_prog_ar=$fp_prog_ar_raw
367 case $HostPlatform in
368   *mingw32) if test x${OSTYPE} != xmsys; then
369               fp_prog_ar="`cygpath -w ${fp_prog_ar_raw} | sed -e 's@\\\\@/@g'`"
370               AC_MSG_NOTICE([normalized ar command to $fp_prog_ar])
371             fi
372             ;;
373 esac
374 ])# FP_PROG_AR
375
376
377 # FP_PROG_AR_IS_GNU
378 # -----------------
379 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
380 AC_DEFUN([FP_PROG_AR_IS_GNU],
381 [AC_REQUIRE([FP_PROG_AR])
382 AC_CACHE_CHECK([whether $fp_prog_ar_raw is GNU ar], [fp_cv_prog_ar_is_gnu],
383 [if $fp_prog_ar_raw --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
384   fp_cv_prog_ar_is_gnu=yes
385 else
386   fp_cv_prog_ar_is_gnu=no
387 fi])
388 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
389 ])# FP_PROG_AR_IS_GNU
390
391
392 # FP_PROG_AR_ARGS
393 # ---------------
394 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
395 # to a non-Cygwin invocation of ar including these arguments.
396 AC_DEFUN([FP_PROG_AR_ARGS],
397 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
398 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
399 [
400 # GNU ar needs special treatment: it appears to have problems with
401 # object files with the same name if you use the 's' modifier, but
402 # simple 'ar q' works fine, and doesn't need a separate ranlib.
403 if test $fp_prog_ar_is_gnu = yes; then
404   fp_cv_prog_ar_args="q"
405 else
406   touch conftest.dummy
407   for fp_var in clqsZ clqs cqs clq cq ; do
408      rm -f conftest.a
409      if $fp_prog_ar_raw $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
410         fp_cv_prog_ar_args=$fp_var
411         break
412      fi
413   done
414   rm -f conftest*
415   if test -z "$fp_cv_prog_ar_args"; then
416     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar_raw])
417   fi
418 fi])
419 fp_prog_ar_args=$fp_cv_prog_ar_args
420 AC_SUBST([ArCmd], ["$fp_prog_ar $fp_prog_ar_args"])
421
422 ])# FP_PROG_AR_ARGS
423
424
425 # FP_PROG_AR_NEEDS_RANLIB
426 # -----------------------
427 # Sets the output variable RANLIB to "ranlib" if it is needed and found,
428 # to ":" otherwise.
429 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],
430 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
431 AC_REQUIRE([FP_PROG_AR_ARGS])
432 AC_CACHE_CHECK([whether ranlib is needed], [fp_cv_prog_ar_needs_ranlib],
433 [if test $fp_prog_ar_is_gnu = yes; then
434   fp_cv_prog_ar_needs_ranlib=no
435 elif echo $fp_prog_ar_args | grep "s" > /dev/null 2> /dev/null; then
436   fp_cv_prog_ar_needs_ranlib=no
437 else
438   fp_cv_prog_ar_needs_ranlib=yes
439 fi])
440 if test $fp_cv_prog_ar_needs_ranlib = yes; then
441    AC_PROG_RANLIB
442 else
443   RANLIB=":"
444   AC_SUBST([RANLIB])
445 fi
446 ])# FP_PROG_AR_NEEDS_RANLIB
447
448
449 # FP_PROG_AR_SUPPORTS_INPUT
450 # -------------------------
451 # Sets the output variable ArSupportsInput to "-input" or "", depending on
452 # whether ar supports -input flag is supported or not.
453 AC_DEFUN([FP_PROG_AR_SUPPORTS_INPUT],
454 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
455 AC_REQUIRE([FP_PROG_AR_ARGS])
456 AC_CACHE_CHECK([whether $fp_prog_ar_raw supports -input], [fp_cv_prog_ar_supports_input],
457 [fp_cv_prog_ar_supports_input=no
458 if test $fp_prog_ar_is_gnu = no; then
459   rm -f conftest*
460   touch conftest.lst
461   if FP_EVAL_STDERR([$fp_prog_ar_raw $fp_prog_ar_args conftest.a -input conftest.lst]) >/dev/null; then
462     test -s conftest.err || fp_cv_prog_ar_supports_input=yes
463   fi
464   rm -f conftest*
465 fi])
466 if test $fp_cv_prog_ar_supports_input = yes; then
467     ArSupportsInput="-input"
468 else
469     ArSupportsInput=""
470 fi
471 AC_SUBST([ArSupportsInput])
472 ])# FP_PROG_AR_SUPPORTS_INPUT
473
474
475 dnl
476 dnl AC_SHEBANG_PERL - can we she-bang perl?
477 dnl
478 AC_DEFUN(FPTOOLS_SHEBANG_PERL,
479 [AC_CACHE_CHECK([if your perl works in shell scripts], fptools_cv_shebang_perl,
480 [echo "#!$PerlCmd"'
481 exit $1;
482 ' > conftest
483 chmod u+x conftest
484 (SHELL=/bin/sh; export SHELL; ./conftest 69 > /dev/null)
485 if test $? -ne 69; then
486    fptools_cv_shebang_perl=yes
487 else
488    fptools_cv_shebang_perl=no
489 fi
490 rm -f conftest
491 ])])
492
493
494 # FP_HAVE_GCC
495 # -----------
496 # Extra testing of the result AC_PROG_CC, testing the gcc version no. Sets the
497 # output variables HaveGcc and GccVersion.
498 AC_DEFUN([FP_HAVE_GCC],
499 [AC_REQUIRE([AC_PROG_CC])
500 AC_CACHE_CHECK([whether your gcc is OK], [fp_cv_have_gcc],
501 [if test -z "$GCC"; then
502   fp_cv_have_gcc='no'
503   AC_MSG_WARN([You would be better off with gcc, perhaps it is already installed, but not in your PATH?])
504 else
505   fp_cv_have_gcc='yes'
506   gcc_version_str="`$CC -v 2>&1 | grep 'version ' | sed -e 's/.*version [[^0-9]]*\([[0-9]][[0-9]]*\)\.\([[0-9]][[0-9]]*\).*/\1\.\2/g' `"
507   FP_COMPARE_VERSIONS([$gcc_version_str], [-lt], [2.0],
508     [AC_MSG_ERROR([Need at least gcc version 2.0 (2.95.3 recommend)])])
509 fi])
510 AC_SUBST([HaveGcc], [`echo $fp_cv_have_gcc | sed 'y/yesno/YESNO/'`])
511 AC_SUBST([GccVersion], [`gcc --version | grep mingw | cut -f 3 -d ' '`])
512 ])# FP_HAVE_GCC
513
514
515 dnl Small feature test for perl version. Assumes PerlCmd
516 dnl contains path to perl binary
517 dnl
518 AC_DEFUN(FPTOOLS_CHECK_PERL_VERSION,
519 [$PerlCmd -v >conftest.out 2>&1
520 if grep "version 5" conftest.out >/dev/null 2>&1; then
521    :
522 else
523    if grep "v5.6" conftest.out >/dev/null 2>&1; then
524       :
525    else
526       if grep "v5.8" conftest.out >/dev/null 2>&1; then
527          :
528       else
529          if grep "version 6" conftest.out >/dev/null 2>&1; then
530             :
531          else
532             echo "Your version of perl probably won't work."
533          fi  
534       fi
535    fi
536 fi
537 rm -fr conftest*
538 ])
539
540
541 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
542 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
543 # -----------------------------------------------------
544 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
545 # of PROG-TO-CHECK-FOR when found.
546 AC_DEFUN([FP_CHECK_PROG],
547 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
548 )# FP_CHECK_PROC
549
550
551 # FP_PROG_FIND
552 # ------------
553 # Find a non-WinDoze version of the "find" utility.
554 AC_DEFUN([FP_PROG_FIND],
555 [AC_PATH_PROG([fp_prog_find], [find])
556 echo foo > conftest.txt
557 $fp_prog_find conftest.txt -print > conftest.out 2>&1
558 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
559   # OK, looks like a real "find".
560   FindCmd="$fp_prog_find"
561 else
562   # Found a poor WinDoze version of "find", ignore it.
563   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
564   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
565 fi
566 rm -f conftest.txt conftest.out
567 AC_SUBST([FindCmd])[]dnl
568 ])# FP_PROG_FIND
569
570
571 dnl
572 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
573 dnl values of the second argument to the result of running
574 dnl the commands given by the third. It does not cache its
575 dnl result, so it is suitable for checks which should be
576 dnl run every time.
577 dnl
578 AC_DEFUN(FPTOOLS_NOCACHE_CHECK,
579 [AC_MSG_CHECKING([$1])
580  $3
581  AC_MSG_RESULT([$][$2])
582 ])
583
584 dnl
585 dnl FPTOOLS_GHC_VERSION(version)
586 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
587 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
588 dnl
589 dnl Test for version of installed ghc.  Uses $GHC.
590 dnl [original version pinched from c2hs]
591 dnl
592 AC_DEFUN(FPTOOLS_GHC_VERSION,
593 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
594 ["${WithGhc-ghc}" --version > conftestghc 2>&1
595   cat conftestghc >&AS_MESSAGE_LOG_FD
596 #Useless Use Of cat award...
597   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
598   rm -fr conftest*
599   if test "[$]fptools_version_of_ghc" = ""
600   then
601     fptools_version_of_ghc='unknown'
602   fi
603 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
604 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
605 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
606 #
607 if test "[$]fptools_version_of_ghc[_pl]" = ""
608 then
609   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
610   fptools_version_of_ghc[_pl]="0"
611 else
612   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
613 fi
614 #
615 ifelse($#, [1], [dnl
616 [$1]="[$]fptools_version_of_ghc[_all]"
617 ], $#, [2], [dnl
618 [$1]="[$]fptools_version_of_ghc[_major]"
619 [$2]="[$]fptools_version_of_ghc[_minor]"
620 ], $#, [3], [dnl
621 [$1]="[$]fptools_version_of_ghc[_major]"
622 [$2]="[$]fptools_version_of_ghc[_minor]"
623 [$3]="[$]fptools_version_of_ghc[_pl]"
624 ], $#, [4], [dnl
625 [$1]="[$]fptools_version_of_ghc[_all]"
626 [$2]="[$]fptools_version_of_ghc[_major]"
627 [$3]="[$]fptools_version_of_ghc[_minor]"
628 [$4]="[$]fptools_version_of_ghc[_pl]"
629 ])
630 ])
631 ])dnl
632
633
634 dnl ** Map an arithmetic C type to a Haskell type.
635 dnl    Based on autconf's AC_CHECK_SIZEOF.
636
637 dnl FPTOOLS_CHECK_HTYPE(TYPE [, DEFAULT_VALUE, [, VALUE-FOR-CROSS-COMPILATION])
638 AC_DEFUN(FPTOOLS_CHECK_HTYPE,
639 [changequote(<<, >>)dnl
640 dnl The name to #define.
641 define(<<AC_TYPE_NAME>>, translit(htype_$1, [a-z *], [A-Z_P]))dnl
642 dnl The cache variable name.
643 define(<<AC_CV_NAME>>, translit(fptools_cv_htype_$1, [ *], [_p]))dnl
644 define(<<AC_CV_NAME_supported>>, translit(fptools_cv_htype_sup_$1, [ *], [_p]))dnl
645 changequote([, ])dnl
646 AC_MSG_CHECKING(Haskell type for $1)
647 AC_CACHE_VAL(AC_CV_NAME,
648 [AC_CV_NAME_supported=yes
649 fp_check_htype_save_cppflags="$CPPFLAGS"
650 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
651 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdio.h>
652 #include <stddef.h>
653
654 #if HAVE_SYS_TYPES_H
655 # include <sys/types.h>
656 #endif
657
658 #if HAVE_UNISTD_H
659 # include <unistd.h>
660 #endif
661
662 #if HAVE_SYS_STAT_H
663 # include <sys/stat.h>
664 #endif
665
666 #if HAVE_FCNTL_H
667 # include <fcntl.h>
668 #endif
669
670 #if HAVE_SIGNAL_H
671 # include <signal.h>
672 #endif
673
674 #if HAVE_TIME_H
675 # include <time.h>
676 #endif
677
678 #if HAVE_TERMIOS_H
679 # include <termios.h>
680 #endif
681
682 #if HAVE_STRING_H
683 # include <string.h>
684 #endif
685
686 #if HAVE_CTYPE_H
687 # include <ctype.h>
688 #endif
689
690 #if defined(HAVE_GL_GL_H)
691 # include <GL/gl.h>
692 #elif defined(HAVE_OPENGL_GL_H)
693 # include <OpenGL/gl.h>
694 #endif
695
696 #if defined(HAVE_AL_ALC_H)
697 # include <AL/alc.h>
698 #elif defined(HAVE_OPENAL_ALC_H)
699 # include <OpenAL/alc.h>
700 #endif
701
702 #if HAVE_SYS_RESOURCE_H
703 # include <sys/resource.h>
704 #endif
705
706 typedef $1 testing;
707
708 main() {
709   FILE *f=fopen("conftestval", "w");
710   if (!f) exit(1);
711   if (((testing)((int)((testing)1.4))) == ((testing)1.4)) {
712     fprintf(f, "%s%d\n",
713            ((testing)(-1) < (testing)0) ? "Int" : "Word",
714            sizeof(testing)*8);
715   } else {
716     fprintf(f,"%s\n",
717            (sizeof(testing) >  sizeof(double)) ? "LDouble" :
718            (sizeof(testing) == sizeof(double)) ? "Double"  : "Float");
719   }
720   fclose(f);
721   exit(0);
722 }]])],[AC_CV_NAME=`cat conftestval`],
723 [ifelse([$2], , [AC_CV_NAME=NotReallyAType; AC_CV_NAME_supported=no], [AC_CV_NAME=$2])],
724 [ifelse([$3], , [AC_CV_NAME=NotReallyATypeCross; AC_CV_NAME_supported=no], [AC_CV_NAME=$3])])]) dnl
725 CPPFLAGS="$fp_check_htype_save_cppflags"
726 if test "$AC_CV_NAME_supported" = yes; then
727   AC_MSG_RESULT($AC_CV_NAME)
728   AC_DEFINE_UNQUOTED(AC_TYPE_NAME, $AC_CV_NAME, [Define to Haskell type for $1])
729 else
730   AC_MSG_RESULT([not supported])
731 fi
732 undefine([AC_TYPE_NAME])dnl
733 undefine([AC_CV_NAME])dnl
734 undefine([AC_CV_NAME_supported])dnl
735 ])
736
737
738 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
739 # ---------------------------------------------------------------------------------
740 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
741 # additional flexibility of specifying the PROLOGUE and BODY.
742 AC_DEFUN([FP_CHECK_FUNC],
743 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
744 AC_CACHE_CHECK([for $1], fp_func,
745 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
746                 [AS_VAR_SET(fp_func, yes)],
747                 [AS_VAR_SET(fp_func, no)])])
748 AS_IF([test AS_VAR_GET(fp_func) = yes],
749       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
750                 [Define to 1 if you have the `]$1[' function.]) $4],
751       [$5])dnl
752 AS_VAR_POPDEF([fp_func])dnl
753 ])# FP_CHECK_FUNC
754
755
756 # FP_GEN_DOCBOOK_XML
757 # ------------------
758 # Generates a DocBook XML V4.2 document in conftest.xml.
759 AC_DEFUN([FP_GEN_DOCBOOK_XML],
760 [rm -f conftest.xml
761 cat > conftest.xml << EOF
762 <?xml version="1.0" encoding="iso-8859-1"?>
763 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V4.2//EN"
764    "http://www.oasis-open.org/docbook/xml/4.2/docbookx.dtd">
765 <book id="test">
766   <title>A DocBook Test Document</title>
767   <chapter id="id-one">
768     <title>A Chapter Title</title>
769     <para>This is a paragraph, referencing <xref linkend="id-two"/>.</para>
770   </chapter>
771   <chapter id="id-two">
772     <title>Another Chapter Title</title>
773     <para>This is another paragraph, referencing <xref linkend="id-one"/>.</para>
774   </chapter>
775 </book>
776 EOF
777 ]) # FP_GEN_DOCBOOK_XML
778
779
780 # FP_PROG_XSLTPROC
781 # ----------------
782 # Sets the output variable XsltprocCmd to the full path of the XSLT processor
783 # xsltproc. XsltprocCmd is empty if xsltproc could not be found.
784 AC_DEFUN([FP_PROG_XSLTPROC],
785 [AC_PATH_PROG([XsltprocCmd], [xsltproc])
786 if test -z "$XsltprocCmd"; then
787   AC_MSG_WARN([cannot find xsltproc in your PATH, you will not be able to build the documentation])
788 fi
789 ])# FP_PROG_XSLTPROC
790
791
792 # FP_DIR_DOCBOOK_XSL(XSL-DIRS)
793 # ----------------------------
794 # Check which of the directories XSL-DIRS contains DocBook XSL stylesheets. The
795 # output variable DIR_DOCBOOK_XSL will contain the first usable directory or
796 # will be empty if none could be found.
797 AC_DEFUN([FP_DIR_DOCBOOK_XSL],
798 [AC_REQUIRE([FP_PROG_XSLTPROC])dnl
799 if test -n "$XsltprocCmd"; then
800   AC_CACHE_CHECK([for DocBook XSL stylesheet directory], fp_cv_dir_docbook_xsl,
801   [FP_GEN_DOCBOOK_XML
802   fp_cv_dir_docbook_xsl=no
803   for fp_var in $1; do
804      if $XsltprocCmd ${fp_var}/html/docbook.xsl conftest.xml > /dev/null 2>&1; then
805         fp_cv_dir_docbook_xsl=$fp_var
806         break
807      fi
808   done
809   rm -rf conftest*])
810 fi
811 if test x"$fp_cv_dir_docbook_xsl" = xno; then
812   AC_MSG_WARN([cannot find DocBook XSL stylesheets, you will not be able to build the documentation])
813   DIR_DOCBOOK_XSL=
814 else
815   DIR_DOCBOOK_XSL=$fp_cv_dir_docbook_xsl
816 fi
817 AC_SUBST([DIR_DOCBOOK_XSL])
818 ])# FP_DIR_DOCBOOK_XSL
819
820
821 # FP_PROG_XMLLINT
822 # ----------------
823 # Sets the output variable XmllintCmd to the full path of the XSLT processor
824 # xmllint. XmllintCmd is empty if xmllint could not be found.
825 AC_DEFUN([FP_PROG_XMLLINT],
826 [AC_PATH_PROG([XmllintCmd], [xmllint])
827 if test -z "$XmllintCmd"; then
828   AC_MSG_WARN([cannot find xmllint in your PATH, you will not be able to validate your documentation])
829 fi
830 ])# FP_PROG_XMLLINT
831
832
833 # FP_CHECK_DOCBOOK_DTD
834 # --------------------
835 AC_DEFUN([FP_CHECK_DOCBOOK_DTD],
836 [AC_REQUIRE([FP_PROG_XMLLINT])dnl
837 if test -n "$XmllintCmd"; then
838   AC_MSG_CHECKING([for DocBook DTD])
839   FP_GEN_DOCBOOK_XML
840   if $XmllintCmd --valid --noout conftest.xml > /dev/null 2>&1; then
841     AC_MSG_RESULT([ok])
842   else
843     AC_MSG_RESULT([failed])
844     AC_MSG_WARN([cannot find a DTD for DocBook XML V4.2, you will not be able to validate your documentation])
845     AC_MSG_WARN([check your XML_CATALOG_FILES environment variable and/or /etc/xml/catalog])
846   fi
847   rm -rf conftest*
848 fi
849 ])# FP_CHECK_DOCBOOK_DTD
850
851
852 # FP_GEN_FO
853 # ------------------
854 # Generates a formatting objects document in conftest.fo.
855 AC_DEFUN([FP_GEN_FO],
856 [rm -f conftest.fo
857 cat > conftest.fo << EOF
858 <?xml version="1.0"?>
859 <fo:root xmlns:fo="http://www.w3.org/1999/XSL/Format">
860   <fo:layout-master-set>
861     <fo:simple-page-master master-name="blank">
862       <fo:region-body/>
863     </fo:simple-page-master>
864   </fo:layout-master-set>
865   <fo:page-sequence master-reference="blank">
866     <fo:flow flow-name="xsl-region-body">
867       <fo:block>
868         Test!
869       </fo:block>
870     </fo:flow>
871   </fo:page-sequence>
872 </fo:root>
873 EOF
874 ]) # FP_GEN_FO
875
876
877 # FP_PROG_FOP
878 # -----------
879 # Set the output variable 'FopCmd' to the first working 'fop' in the current
880 # 'PATH'. Note that /usr/bin/fop is broken in SuSE 9.1 (unpatched), so try
881 # /usr/share/fop/fop.sh in that case (or no 'fop'), too.
882 AC_DEFUN([FP_PROG_FOP],
883 [AC_PATH_PROGS([FopCmd1], [fop])
884 if test -n "$FopCmd1"; then
885   AC_CACHE_CHECK([for $FopCmd1 usability], [fp_cv_fop_usability],
886     [FP_GEN_FO
887     if "$FopCmd1" -fo conftest.fo -ps conftest.ps > /dev/null 2>&1; then
888       fp_cv_fop_usability=yes
889     else
890       fp_cv_fop_usability=no
891     fi
892     rm -rf conftest*])
893   if test x"$fp_cv_fop_usability" = xyes; then
894      FopCmd=$FopCmd1
895   fi
896 fi
897 if test -z "$FopCmd"; then
898   AC_PATH_PROGS([FopCmd2], [fop.sh], , [/usr/share/fop])
899   FopCmd=$FopCmd2
900 fi
901 AC_SUBST([FopCmd])
902 ])# FP_PROG_FOP
903
904
905 # FP_PROG_FO_PROCESSOR
906 # --------------------
907 # Try to find an FO processor. PassiveTeX output is sometimes a bit strange, so
908 # try FOP first. Sets the output variables FopCmd, XmltexCmd, DvipsCmd, and
909 # PdfxmltexCmd.
910 AC_DEFUN([FP_PROG_FO_PROCESSOR],
911 [AC_REQUIRE([FP_PROG_FOP])
912 AC_PATH_PROG([XmltexCmd], [xmltex])
913 AC_PATH_PROG([DvipsCmd], [dvips])
914 if test -z "$FopCmd"; then
915   if test -z "$XmltexCmd"; then
916     AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI or PostScript documentation])
917   else
918     if test -z "$DvipsCmd"; then
919       AC_MSG_WARN([cannot find a DVI  => PS converter, you will not be able to build PostScript documentation])
920     fi
921   fi
922   AC_PATH_PROG([PdfxmltexCmd], [pdfxmltex])
923   if test -z "$PdfxmltexCmd"; then
924     AC_MSG_WARN([cannot find an FO => PDF converter, you will not be able to build PDF documentation])
925   fi
926 elif test -z "$XmltexCmd"; then
927   AC_MSG_WARN([cannot find an FO => DVI converter, you will not be able to build DVI documentation])
928 fi
929 ])# FP_PROG_FO_PROCESSOR
930
931
932 # FP_PROG_GHC_PKG
933 # ----------------
934 # Try to find a ghc-pkg matching the ghc mentioned in the environment variable
935 # WithGhc. If the latter is unset or no matching ghc-pkg can be found, try to
936 # find a plain ghc-pkg. Sets the output variable GhcPkgCmd.
937 AC_DEFUN([FP_PROG_GHC_PKG],
938 [AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
939 [fp_ghc_pkg_guess=`echo $WithGhc | sed 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
940 if "$fp_ghc_pkg_guess" -l > /dev/null 2>&1; then
941   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
942 else
943   fp_cv_matching_ghc_pkg=no
944 fi])
945 if test x"$fp_cv_matching_ghc_pkg" = xno; then
946   AC_PATH_PROG([GhcPkgCmd], [ghc-pkg])
947 else
948   GhcPkgCmd=$fp_cv_matching_ghc_pkg
949 fi])# FP_PROG_GHC_PKG
950
951
952 # FP_CHECK_WIN32
953 # --------------
954 # If Windows is the target platform (e.g. MinGW/MSYS or Cygwin with
955 # -mno-cygwin), the variable "is_win32" is set to "yes", otherwise (e.g. *nix
956 # systems or plain Cygwin) it is set to "no".
957 AC_DEFUN([FP_CHECK_WIN32],
958 [AC_CACHE_CHECK([for Windows environment], [fp_cv_is_win32],
959   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
960 #if !_WIN32
961    syntax error;
962 #endif
963 ])], [fp_cv_is_win32=yes], [fp_cv_is_win32=no])])
964 is_win32="$fp_cv_is_win32"[]dnl
965 ])# FP_CHECK_WIN32
966
967
968 # FP_PATH_X
969 # ---------
970 # Same as AC_PATH_X, but works even for broken Cygwins which try to include the
971 # non-existant <gl/mesa_wgl.h> header when -mno-cygwin is used.
972 AC_DEFUN([FP_PATH_X],
973 [AC_REQUIRE([FP_CHECK_WIN32])
974 if test x"$is_win32" = xyes; then
975   no_x=yes
976 else
977   AC_PATH_X
978 fi
979 ])# FP_PATH_X
980
981
982 # FP_PATH_XTRA
983 # ------------
984 # Same as AC_PATH_XTRA, but works even for broken Cygwins which try to include
985 # the non-existant <gl/mesa_wgl.h> header when -mno-cygwin is used.
986 AC_DEFUN([FP_PATH_XTRA],
987 [AC_REQUIRE([FP_CHECK_WIN32])
988 if test x"$is_win32" = xyes; then
989   no_x=yes
990 else
991   AC_PATH_XTRA
992 fi
993 ])# FP_PATH_XTRA
994
995
996 # FP_CHECK_GL_HELPER(LIBNAME, LIBS, INCLUDES, FUNCTION-BODY)
997 # ----------------------------------------------------------
998 # Try each library in LIBS to successfully link INCLUDES plus FUNCTION-BODY,
999 # setting LIBNAME_CFLAGS and LIBNAME_LIBS to the corresponding values. Sets
1000 # no_LIBNAME to "yes" if no suitable library was found. (LIBNAME_CFLAGS0
1001 # contains the value of LIBNAME_CFLAGS without CPPFLAGS, and LIBNAME_LIBS0
1002 # contains the value of LIBNAME_LIBS without LDFLAGS, but these are only
1003 # used internally.)
1004 AC_DEFUN([FP_CHECK_GL_HELPER],
1005 [AC_CACHE_CHECK([for $1 library], [fp_cv_check_$1_lib],
1006   [fp_cv_check_$1_lib="no"
1007   fp_save_CPPFLAGS="$CPPFLAGS"
1008   CPPFLAGS="$CPPFLAGS ${$1_CFLAGS}"
1009   fp_save_LIBS="$LIBS"
1010   for fp_try_lib in $2; do
1011     # transform "-lfoo" to "foo.lib" when using cl
1012     if test x"$CC" = xcl; then
1013       fp_try_lib=`echo $fp_try_lib | sed -e 's/^-l//' -e 's/$/.lib/'`
1014     fi
1015     LIBS="$fp_try_lib ${$1_LIBS} $fp_save_LIBS"
1016     AC_LINK_IFELSE([AC_LANG_PROGRAM([$3], [$4])], [fp_cv_check_$1_lib="$fp_try_lib ${$1_LIBS}"; break])
1017   done
1018   LIBS="$fp_save_LIBS"
1019   CPPFLAGS="$fp_save_CPPFLAGS"])
1020
1021   if test x"$fp_cv_check_$1_lib" = xno; then
1022     no_$1=yes
1023     $1_CFLAGS=
1024     $1_LIBS=
1025   else
1026     $1_CFLAGS0="${$1_CFLAGS}"
1027     $1_CFLAGS="$CPPFLAGS ${$1_CFLAGS0}"
1028     $1_LIBS0="$fp_cv_check_$1_lib"
1029     $1_LIBS="$LDFLAGS ${$1_LIBS0}"
1030   fi
1031 ])# FP_CHECK_GL_HELPER
1032
1033
1034 # FP_CHECK_GL
1035 # -----------
1036 AC_DEFUN([FP_CHECK_GL],
1037 [AC_REQUIRE([FP_PATH_X])
1038 AC_REQUIRE([AC_CANONICAL_TARGET])
1039
1040 AC_ARG_ENABLE([hopengl],
1041   [AC_HELP_STRING([--enable-hopengl],
1042     [build a Haskell binding for OpenGL (GL/GLU). On Mac OS X, use
1043      --enable-hopengl=x11 to use X11 instead of the "native" libraries.
1044      (default=no)])],
1045   [enable_opengl=$enableval], [enable_opengl=no])
1046
1047 if test x"$enable_opengl" = xno; then
1048    no_GL=yes
1049 else
1050   use_quartz_opengl=no
1051   case $target_os in
1052   darwin*)
1053     if test x"$enable_opengl" != xx11; then
1054       AC_DEFINE([USE_QUARTZ_OPENGL], [1],
1055                 [Define to 1 if native OpenGL should be used on Mac OS X])
1056       use_quartz_opengl=yes
1057     fi
1058     ;;
1059   esac
1060
1061   if test x"$use_quartz_opengl" != xyes; then
1062     AC_CHECK_LIB([m], [atan], [GL_LIBS="-lm $GL_LIBS"])
1063
1064     if test x"$no_x" != xyes; then
1065       test -n "$x_includes" && GL_CFLAGS="-I$x_includes $GL_CFLAGS"
1066       test -n "$x_libraries" && GL_LIBS="-L$x_libraries -lX11 $GL_LIBS"
1067     fi
1068
1069     FP_CHECK_GL_HELPER([GL], [-lGL -lopengl32], [@%:@include <GL/gl.h>], [glEnd()])
1070
1071     if test x"$no_GL" != xyes; then
1072       # Ugly: To get wglGetProcAddress on Windows, we have to link with
1073       # opengl32.dll, too, even when we are using Cygwin with X11.
1074       case "$GL_LIBS" in
1075         *-lopengl32*|*opengl32.lib*) ;;
1076         *) fp_save_LIBS="$LIBS"
1077            LIBS="$LIBS -lopengl32"
1078            AC_LINK_IFELSE([AC_LANG_PROGRAM([[@%:@include <GL/gl.h>]], [[glEnd()]])],
1079              [GL_LIBS="$GL_LIBS -lopengl32"; GL_LIBS0="$GL_LIBS0 -lopengl32"])
1080            LIBS="$fp_save_LIBS"
1081            ;;
1082       esac
1083     fi
1084   fi
1085 fi
1086
1087 AC_SUBST([GL_CFLAGS])
1088 AC_SUBST([GL_LIBS])
1089 ])# FP_CHECK_GL
1090
1091
1092 # FP_CHECK_GLU
1093 # ------------
1094 AC_DEFUN([FP_CHECK_GLU],
1095 [AC_REQUIRE([FP_CHECK_GL])dnl
1096 GLU_CFLAGS="$GL_CFLAGS0"
1097 GLU_LIBS="$GL_LIBS0"
1098
1099 if test x"$enable_opengl" = xno; then
1100    no_GLU=yes
1101 elif test x"$use_quartz_opengl" != xyes; then
1102   FP_CHECK_GL_HELPER([GLU], [-lglu32 -lGLU], [@%:@include <GL/glu.h>], [gluNewQuadric()])
1103 fi
1104
1105 AC_SUBST([GLU_CFLAGS])
1106 AC_SUBST([GLU_LIBS])
1107 ])# FP_CHECK_GLU
1108
1109
1110 # FP_CHECK_GLUT
1111 # -------------
1112 AC_DEFUN([FP_CHECK_GLUT],
1113 [AC_REQUIRE([FP_CHECK_GLU])
1114 FP_PATH_XTRA
1115
1116 if test x"$enable_opengl" = xno; then
1117    no_GLUT=yes
1118 elif test x"$use_quartz_opengl" != xyes; then
1119   GLUT_CFLAGS="$GLU_CFLAGS0"
1120   GLUT_LIBS="$GLU_LIBS0"
1121
1122   if test x"$no_x" != xyes; then
1123     GLUT_LIBS="$X_PRE_LIBS -lXmu -lXi $X_EXTRA_LIBS $GLUT_LIBS"
1124   fi
1125
1126   AC_CHECK_HEADERS([windows.h GL/glut.h])
1127   # Note 1: On Cygwin with X11, GL/GLU functions use the "normal" calling
1128   # convention, but GLUT functions use stdcall. To get this right, it is
1129   # necessary to include <windows.h> first.
1130   # Note 2: MinGW/MSYS comes without a GLUT header, so we use Cygwin's one in
1131   # that case.
1132   FP_CHECK_GL_HELPER([GLUT], [-lglut32 -lglut], [
1133 #if HAVE_WINDOWS_H
1134 #include <windows.h>
1135 #endif
1136 #if HAVE_GL_GLUT_H
1137 #include <GL/glut.h>
1138 #else
1139 #include "glut_local.h"
1140 #endif
1141     ], [glutMainLoop()])
1142 fi
1143
1144 AC_SUBST([GLUT_CFLAGS])
1145 AC_SUBST([GLUT_LIBS])
1146 ])# FP_CHECK_GLUT
1147
1148 # LocalWords:  fi