Shave the hair off mkCastTy.
[ghc.git] / compiler / types / Type.hs
1 -- (c) The University of Glasgow 2006
2 -- (c) The GRASP/AQUA Project, Glasgow University, 1998
3 --
4 -- Type - public interface
5
6 {-# LANGUAGE CPP, FlexibleContexts #-}
7 {-# OPTIONS_GHC -fno-warn-orphans #-}
8
9 -- | Main functions for manipulating types and type-related things
10 module Type (
11 -- Note some of this is just re-exports from TyCon..
12
13 -- * Main data types representing Types
14 -- $type_classification
15
16 -- $representation_types
17 TyThing(..), Type, ArgFlag(..), KindOrType, PredType, ThetaType,
18 Var, TyVar, isTyVar, TyCoVar, TyBinder, TyVarBinder,
19
20 -- ** Constructing and deconstructing types
21 mkTyVarTy, mkTyVarTys, getTyVar, getTyVar_maybe, repGetTyVar_maybe,
22 getCastedTyVar_maybe, tyVarKind,
23
24 mkAppTy, mkAppTys, splitAppTy, splitAppTys, repSplitAppTys,
25 splitAppTy_maybe, repSplitAppTy_maybe, tcRepSplitAppTy_maybe,
26
27 mkFunTy, mkFunTys, splitFunTy, splitFunTy_maybe,
28 splitFunTys, funResultTy, funArgTy,
29
30 mkTyConApp, mkTyConTy,
31 tyConAppTyCon_maybe, tyConAppTyConPicky_maybe,
32 tyConAppArgs_maybe, tyConAppTyCon, tyConAppArgs,
33 splitTyConApp_maybe, splitTyConApp, tyConAppArgN, nextRole,
34 tcRepSplitTyConApp_maybe, tcSplitTyConApp_maybe,
35 splitListTyConApp_maybe,
36 repSplitTyConApp_maybe,
37
38 mkForAllTy, mkForAllTys, mkInvForAllTys, mkSpecForAllTys,
39 mkVisForAllTys, mkInvForAllTy,
40 splitForAllTys, splitForAllTyVarBndrs,
41 splitForAllTy_maybe, splitForAllTy,
42 splitPiTy_maybe, splitPiTy, splitPiTys,
43 mkPiTy, mkPiTys, mkTyConBindersPreferAnon,
44 mkLamType, mkLamTypes,
45 piResultTy, piResultTys,
46 applyTysX, dropForAlls,
47
48 mkNumLitTy, isNumLitTy,
49 mkStrLitTy, isStrLitTy,
50
51 getRuntimeRep_maybe, getRuntimeRepFromKind_maybe,
52
53 mkCastTy, mkCoercionTy, splitCastTy_maybe,
54
55 userTypeError_maybe, pprUserTypeErrorTy,
56
57 coAxNthLHS,
58 stripCoercionTy, splitCoercionType_maybe,
59
60 splitPiTysInvisible, filterOutInvisibleTypes,
61 filterOutInvisibleTyVars, partitionInvisibles,
62 synTyConResKind,
63
64 modifyJoinResTy, setJoinResTy,
65
66 -- Analyzing types
67 TyCoMapper(..), mapType, mapCoercion,
68
69 -- (Newtypes)
70 newTyConInstRhs,
71
72 -- Pred types
73 mkFamilyTyConApp,
74 isDictLikeTy,
75 mkPrimEqPred, mkReprPrimEqPred, mkPrimEqPredRole,
76 equalityTyCon,
77 mkHeteroPrimEqPred, mkHeteroReprPrimEqPred,
78 mkClassPred,
79 isClassPred, isEqPred, isNomEqPred,
80 isIPPred, isIPPred_maybe, isIPTyCon, isIPClass,
81 isCTupleClass,
82
83 -- Deconstructing predicate types
84 PredTree(..), EqRel(..), eqRelRole, classifyPredType,
85 getClassPredTys, getClassPredTys_maybe,
86 getEqPredTys, getEqPredTys_maybe, getEqPredRole,
87 predTypeEqRel,
88
89 -- ** Binders
90 sameVis,
91 mkTyVarBinder, mkTyVarBinders,
92 mkAnonBinder,
93 isAnonTyBinder, isNamedTyBinder,
94 binderVar, binderVars, binderKind, binderArgFlag,
95 tyBinderType,
96 binderRelevantType_maybe, caseBinder,
97 isVisibleArgFlag, isInvisibleArgFlag, isVisibleBinder, isInvisibleBinder,
98 tyConBindersTyBinders,
99 mkTyBinderTyConBinder,
100
101 -- ** Common type constructors
102 funTyCon,
103
104 -- ** Predicates on types
105 isTyVarTy, isFunTy, isDictTy, isPredTy, isCoercionTy,
106 isCoercionTy_maybe, isCoercionType, isForAllTy,
107 isPiTy, isTauTy, isFamFreeTy,
108
109 isValidJoinPointType,
110
111 -- (Lifting and boxity)
112 isLiftedType_maybe, isUnliftedType, isUnboxedTupleType, isUnboxedSumType,
113 isAlgType, isClosedAlgType, isDataFamilyAppType,
114 isPrimitiveType, isStrictType,
115 isRuntimeRepTy, isRuntimeRepVar, isRuntimeRepKindedTy,
116 dropRuntimeRepArgs,
117 getRuntimeRep, getRuntimeRepFromKind,
118
119 -- * Main data types representing Kinds
120 Kind,
121
122 -- ** Finding the kind of a type
123 typeKind, isTypeLevPoly, resultIsLevPoly,
124
125 -- ** Common Kind
126 liftedTypeKind,
127
128 -- * Type free variables
129 tyCoFVsOfType, tyCoFVsBndr,
130 tyCoVarsOfType, tyCoVarsOfTypes,
131 tyCoVarsOfTypeDSet,
132 coVarsOfType,
133 coVarsOfTypes, closeOverKinds, closeOverKindsList,
134 noFreeVarsOfType,
135 splitVisVarsOfType, splitVisVarsOfTypes,
136 expandTypeSynonyms,
137 typeSize,
138
139 -- * Well-scoped lists of variables
140 dVarSetElemsWellScoped, toposortTyVars, tyCoVarsOfTypeWellScoped,
141 tyCoVarsOfTypesWellScoped,
142
143 -- * Type comparison
144 eqType, eqTypeX, eqTypes, nonDetCmpType, nonDetCmpTypes, nonDetCmpTypeX,
145 nonDetCmpTypesX, nonDetCmpTc,
146 eqVarBndrs,
147
148 -- * Forcing evaluation of types
149 seqType, seqTypes,
150
151 -- * Other views onto Types
152 coreView, tcView,
153
154 tyConsOfType,
155
156 -- * Main type substitution data types
157 TvSubstEnv, -- Representation widely visible
158 TCvSubst(..), -- Representation visible to a few friends
159
160 -- ** Manipulating type substitutions
161 emptyTvSubstEnv, emptyTCvSubst, mkEmptyTCvSubst,
162
163 mkTCvSubst, zipTvSubst, mkTvSubstPrs,
164 notElemTCvSubst,
165 getTvSubstEnv, setTvSubstEnv,
166 zapTCvSubst, getTCvInScope, getTCvSubstRangeFVs,
167 extendTCvInScope, extendTCvInScopeList, extendTCvInScopeSet,
168 extendTCvSubst, extendCvSubst,
169 extendTvSubst, extendTvSubstBinder,
170 extendTvSubstList, extendTvSubstAndInScope,
171 extendTvSubstWithClone,
172 isInScope, composeTCvSubstEnv, composeTCvSubst, zipTyEnv, zipCoEnv,
173 isEmptyTCvSubst, unionTCvSubst,
174
175 -- ** Performing substitution on types and kinds
176 substTy, substTys, substTyWith, substTysWith, substTheta,
177 substTyAddInScope,
178 substTyUnchecked, substTysUnchecked, substThetaUnchecked,
179 substTyWithUnchecked,
180 substCoUnchecked, substCoWithUnchecked,
181 substTyVarBndr, substTyVar, substTyVars,
182 cloneTyVarBndr, cloneTyVarBndrs, lookupTyVar,
183
184 -- * Pretty-printing
185 pprType, pprParendType, pprTypeApp, pprTyThingCategory, pprShortTyThing,
186 pprTvBndr, pprTvBndrs, pprForAll, pprUserForAll,
187 pprSigmaType, ppSuggestExplicitKinds,
188 pprTheta, pprThetaArrowTy, pprClassPred,
189 pprKind, pprParendKind, pprSourceTyCon,
190 TyPrec(..), maybeParen,
191 pprTyVar, pprTyVars, pprPrefixApp, pprArrowChain,
192
193 -- * Tidying type related things up for printing
194 tidyType, tidyTypes,
195 tidyOpenType, tidyOpenTypes,
196 tidyOpenKind,
197 tidyTyCoVarBndr, tidyTyCoVarBndrs, tidyFreeTyCoVars,
198 tidyOpenTyCoVar, tidyOpenTyCoVars,
199 tidyTyVarOcc,
200 tidyTopType,
201 tidyKind,
202 tidyTyVarBinder, tidyTyVarBinders
203 ) where
204
205 #include "HsVersions.h"
206
207 import BasicTypes
208
209 -- We import the representation and primitive functions from TyCoRep.
210 -- Many things are reexported, but not the representation!
211
212 import Kind
213 import TyCoRep
214
215 -- friends:
216 import Var
217 import VarEnv
218 import VarSet
219 import UniqSet
220
221 import Class
222 import TyCon
223 import TysPrim
224 import {-# SOURCE #-} TysWiredIn ( listTyCon, typeNatKind
225 , typeSymbolKind, liftedTypeKind )
226 import PrelNames
227 import CoAxiom
228 import {-# SOURCE #-} Coercion
229
230 -- others
231 import Util
232 import Outputable
233 import FastString
234 import Pair
235 import ListSetOps
236 import Digraph
237 import Unique ( nonDetCmpUnique )
238 import SrcLoc ( SrcSpan )
239 import OccName ( OccName )
240 import Name ( mkInternalName )
241
242 import Maybes ( orElse )
243 import Data.Maybe ( isJust, mapMaybe )
244 import Control.Monad ( guard )
245 import Control.Arrow ( first, second )
246
247 -- $type_classification
248 -- #type_classification#
249 --
250 -- Types are one of:
251 --
252 -- [Unboxed] Iff its representation is other than a pointer
253 -- Unboxed types are also unlifted.
254 --
255 -- [Lifted] Iff it has bottom as an element.
256 -- Closures always have lifted types: i.e. any
257 -- let-bound identifier in Core must have a lifted
258 -- type. Operationally, a lifted object is one that
259 -- can be entered.
260 -- Only lifted types may be unified with a type variable.
261 --
262 -- [Algebraic] Iff it is a type with one or more constructors, whether
263 -- declared with @data@ or @newtype@.
264 -- An algebraic type is one that can be deconstructed
265 -- with a case expression. This is /not/ the same as
266 -- lifted types, because we also include unboxed
267 -- tuples in this classification.
268 --
269 -- [Data] Iff it is a type declared with @data@, or a boxed tuple.
270 --
271 -- [Primitive] Iff it is a built-in type that can't be expressed in Haskell.
272 --
273 -- Currently, all primitive types are unlifted, but that's not necessarily
274 -- the case: for example, @Int@ could be primitive.
275 --
276 -- Some primitive types are unboxed, such as @Int#@, whereas some are boxed
277 -- but unlifted (such as @ByteArray#@). The only primitive types that we
278 -- classify as algebraic are the unboxed tuples.
279 --
280 -- Some examples of type classifications that may make this a bit clearer are:
281 --
282 -- @
283 -- Type primitive boxed lifted algebraic
284 -- -----------------------------------------------------------------------------
285 -- Int# Yes No No No
286 -- ByteArray# Yes Yes No No
287 -- (\# a, b \#) Yes No No Yes
288 -- (\# a | b \#) Yes No No Yes
289 -- ( a, b ) No Yes Yes Yes
290 -- [a] No Yes Yes Yes
291 -- @
292
293 -- $representation_types
294 -- A /source type/ is a type that is a separate type as far as the type checker is
295 -- concerned, but which has a more low-level representation as far as Core-to-Core
296 -- passes and the rest of the back end is concerned.
297 --
298 -- You don't normally have to worry about this, as the utility functions in
299 -- this module will automatically convert a source into a representation type
300 -- if they are spotted, to the best of it's abilities. If you don't want this
301 -- to happen, use the equivalent functions from the "TcType" module.
302
303 {-
304 ************************************************************************
305 * *
306 Type representation
307 * *
308 ************************************************************************
309
310 Note [coreView vs tcView]
311 ~~~~~~~~~~~~~~~~~~~~~~~~~
312 So far as the typechecker is concerned, 'Constraint' and 'TYPE LiftedRep' are distinct kinds.
313
314 But in Core these two are treated as identical.
315
316 We implement this by making 'coreView' convert 'Constraint' to 'TYPE LiftedRep' on the fly.
317 The function tcView (used in the type checker) does not do this.
318
319 See also Trac #11715, which tracks removing this inconsistency.
320
321 -}
322
323 {-# INLINE coreView #-}
324 coreView :: Type -> Maybe Type
325 -- ^ This function Strips off the /top layer only/ of a type synonym
326 -- application (if any) its underlying representation type.
327 -- Returns Nothing if there is nothing to look through.
328 -- This function considers 'Constraint' to be a synonym of @TYPE LiftedRep@.
329 --
330 -- By being non-recursive and inlined, this case analysis gets efficiently
331 -- joined onto the case analysis that the caller is already doing
332 coreView (TyConApp tc tys) | Just (tenv, rhs, tys') <- expandSynTyCon_maybe tc tys
333 = Just (mkAppTys (substTy (mkTvSubstPrs tenv) rhs) tys')
334 -- The free vars of 'rhs' should all be bound by 'tenv', so it's
335 -- ok to use 'substTy' here.
336 -- See also Note [The substitution invariant] in TyCoRep.
337 -- Its important to use mkAppTys, rather than (foldl AppTy),
338 -- because the function part might well return a
339 -- partially-applied type constructor; indeed, usually will!
340 coreView (TyConApp tc [])
341 | isStarKindSynonymTyCon tc
342 = Just liftedTypeKind
343
344 coreView _ = Nothing
345
346 -- | Gives the typechecker view of a type. This unwraps synonyms but
347 -- leaves 'Constraint' alone. c.f. coreView, which turns Constraint into
348 -- TYPE LiftedRep. Returns Nothing if no unwrapping happens.
349 -- See also Note [coreView vs tcView] in Type.
350 {-# INLINE tcView #-}
351 tcView :: Type -> Maybe Type
352 tcView (TyConApp tc tys) | Just (tenv, rhs, tys') <- expandSynTyCon_maybe tc tys
353 = Just (mkAppTys (substTy (mkTvSubstPrs tenv) rhs) tys')
354 -- The free vars of 'rhs' should all be bound by 'tenv', so it's
355 -- ok to use 'substTy' here.
356 -- See also Note [The substitution invariant] in TyCoRep.
357 -- Its important to use mkAppTys, rather than (foldl AppTy),
358 -- because the function part might well return a
359 -- partially-applied type constructor; indeed, usually will!
360 tcView _ = Nothing
361
362 -----------------------------------------------
363 expandTypeSynonyms :: Type -> Type
364 -- ^ Expand out all type synonyms. Actually, it'd suffice to expand out
365 -- just the ones that discard type variables (e.g. type Funny a = Int)
366 -- But we don't know which those are currently, so we just expand all.
367 --
368 -- 'expandTypeSynonyms' only expands out type synonyms mentioned in the type,
369 -- not in the kinds of any TyCon or TyVar mentioned in the type.
370 --
371 -- Keep this synchronized with 'synonymTyConsOfType'
372 expandTypeSynonyms ty
373 = go (mkEmptyTCvSubst in_scope) ty
374 where
375 in_scope = mkInScopeSet (tyCoVarsOfType ty)
376
377 go subst (TyConApp tc tys)
378 | Just (tenv, rhs, tys') <- expandSynTyCon_maybe tc expanded_tys
379 = let subst' = mkTvSubst in_scope (mkVarEnv tenv)
380 -- Make a fresh substitution; rhs has nothing to
381 -- do with anything that has happened so far
382 -- NB: if you make changes here, be sure to build an
383 -- /idempotent/ substitution, even in the nested case
384 -- type T a b = a -> b
385 -- type S x y = T y x
386 -- (Trac #11665)
387 in mkAppTys (go subst' rhs) tys'
388 | otherwise
389 = TyConApp tc expanded_tys
390 where
391 expanded_tys = (map (go subst) tys)
392
393 go _ (LitTy l) = LitTy l
394 go subst (TyVarTy tv) = substTyVar subst tv
395 go subst (AppTy t1 t2) = mkAppTy (go subst t1) (go subst t2)
396 go subst (FunTy arg res)
397 = mkFunTy (go subst arg) (go subst res)
398 go subst (ForAllTy (TvBndr tv vis) t)
399 = let (subst', tv') = substTyVarBndrCallback go subst tv in
400 ForAllTy (TvBndr tv' vis) (go subst' t)
401 go subst (CastTy ty co) = mkCastTy (go subst ty) (go_co subst co)
402 go subst (CoercionTy co) = mkCoercionTy (go_co subst co)
403
404 go_co subst (Refl r ty)
405 = mkReflCo r (go subst ty)
406 -- NB: coercions are always expanded upon creation
407 go_co subst (TyConAppCo r tc args)
408 = mkTyConAppCo r tc (map (go_co subst) args)
409 go_co subst (AppCo co arg)
410 = mkAppCo (go_co subst co) (go_co subst arg)
411 go_co subst (ForAllCo tv kind_co co)
412 = let (subst', tv', kind_co') = go_cobndr subst tv kind_co in
413 mkForAllCo tv' kind_co' (go_co subst' co)
414 go_co subst (FunCo r co1 co2)
415 = mkFunCo r (go_co subst co1) (go_co subst co2)
416 go_co subst (CoVarCo cv)
417 = substCoVar subst cv
418 go_co subst (AxiomInstCo ax ind args)
419 = mkAxiomInstCo ax ind (map (go_co subst) args)
420 go_co subst (UnivCo p r t1 t2)
421 = mkUnivCo (go_prov subst p) r (go subst t1) (go subst t2)
422 go_co subst (SymCo co)
423 = mkSymCo (go_co subst co)
424 go_co subst (TransCo co1 co2)
425 = mkTransCo (go_co subst co1) (go_co subst co2)
426 go_co subst (NthCo n co)
427 = mkNthCo n (go_co subst co)
428 go_co subst (LRCo lr co)
429 = mkLRCo lr (go_co subst co)
430 go_co subst (InstCo co arg)
431 = mkInstCo (go_co subst co) (go_co subst arg)
432 go_co subst (CoherenceCo co1 co2)
433 = mkCoherenceCo (go_co subst co1) (go_co subst co2)
434 go_co subst (KindCo co)
435 = mkKindCo (go_co subst co)
436 go_co subst (SubCo co)
437 = mkSubCo (go_co subst co)
438 go_co subst (AxiomRuleCo ax cs) = AxiomRuleCo ax (map (go_co subst) cs)
439
440 go_prov _ UnsafeCoerceProv = UnsafeCoerceProv
441 go_prov subst (PhantomProv co) = PhantomProv (go_co subst co)
442 go_prov subst (ProofIrrelProv co) = ProofIrrelProv (go_co subst co)
443 go_prov _ p@(PluginProv _) = p
444 go_prov _ (HoleProv h) = pprPanic "expandTypeSynonyms hit a hole" (ppr h)
445
446 -- the "False" and "const" are to accommodate the type of
447 -- substForAllCoBndrCallback, which is general enough to
448 -- handle coercion optimization (which sometimes swaps the
449 -- order of a coercion)
450 go_cobndr subst = substForAllCoBndrCallback False (go_co subst) subst
451
452 {-
453 ************************************************************************
454 * *
455 Analyzing types
456 * *
457 ************************************************************************
458
459 These functions do a map-like operation over types, performing some operation
460 on all variables and binding sites. Primarily used for zonking.
461
462 Note [Efficiency for mapCoercion ForAllCo case]
463 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
464 As noted in Note [Forall coercions] in TyCoRep, a ForAllCo is a bit redundant.
465 It stores a TyVar and a Coercion, where the kind of the TyVar always matches
466 the left-hand kind of the coercion. This is convenient lots of the time, but
467 not when mapping a function over a coercion.
468
469 The problem is that tcm_tybinder will affect the TyVar's kind and
470 mapCoercion will affect the Coercion, and we hope that the results will be
471 the same. Even if they are the same (which should generally happen with
472 correct algorithms), then there is an efficiency issue. In particular,
473 this problem seems to make what should be a linear algorithm into a potentially
474 exponential one. But it's only going to be bad in the case where there's
475 lots of foralls in the kinds of other foralls. Like this:
476
477 forall a : (forall b : (forall c : ...). ...). ...
478
479 This construction seems unlikely. So we'll do the inefficient, easy way
480 for now.
481
482 Note [Specialising mappers]
483 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
484 These INLINABLE pragmas are indispensable. mapType/mapCoercion are used
485 to implement zonking, and it's vital that they get specialised to the TcM
486 monad. This specialisation happens automatically (that is, without a
487 SPECIALISE pragma) as long as the definitions are INLINABLE. For example,
488 this one change made a 20% allocation difference in perf/compiler/T5030.
489
490 -}
491
492 -- | This describes how a "map" operation over a type/coercion should behave
493 data TyCoMapper env m
494 = TyCoMapper
495 { tcm_smart :: Bool -- ^ Should the new type be created with smart
496 -- constructors?
497 , tcm_tyvar :: env -> TyVar -> m Type
498 , tcm_covar :: env -> CoVar -> m Coercion
499 , tcm_hole :: env -> CoercionHole -> Role
500 -> Type -> Type -> m Coercion
501 -- ^ What to do with coercion holes. See Note [Coercion holes] in
502 -- TyCoRep.
503
504 , tcm_tybinder :: env -> TyVar -> ArgFlag -> m (env, TyVar)
505 -- ^ The returned env is used in the extended scope
506 }
507
508 {-# INLINABLE mapType #-} -- See Note [Specialising mappers]
509 mapType :: Monad m => TyCoMapper env m -> env -> Type -> m Type
510 mapType mapper@(TyCoMapper { tcm_smart = smart, tcm_tyvar = tyvar
511 , tcm_tybinder = tybinder })
512 env ty
513 = go ty
514 where
515 go (TyVarTy tv) = tyvar env tv
516 go (AppTy t1 t2) = mkappty <$> go t1 <*> go t2
517 go t@(TyConApp _ []) = return t -- avoid allocation in this exceedingly
518 -- common case (mostly, for *)
519 go (TyConApp tc tys) = mktyconapp tc <$> mapM go tys
520 go (FunTy arg res) = FunTy <$> go arg <*> go res
521 go (ForAllTy (TvBndr tv vis) inner)
522 = do { (env', tv') <- tybinder env tv vis
523 ; inner' <- mapType mapper env' inner
524 ; return $ ForAllTy (TvBndr tv' vis) inner' }
525 go ty@(LitTy {}) = return ty
526 go (CastTy ty co) = mkcastty <$> go ty <*> mapCoercion mapper env co
527 go (CoercionTy co) = CoercionTy <$> mapCoercion mapper env co
528
529 (mktyconapp, mkappty, mkcastty)
530 | smart = (mkTyConApp, mkAppTy, mkCastTy)
531 | otherwise = (TyConApp, AppTy, CastTy)
532
533 {-# INLINABLE mapCoercion #-} -- See Note [Specialising mappers]
534 mapCoercion :: Monad m
535 => TyCoMapper env m -> env -> Coercion -> m Coercion
536 mapCoercion mapper@(TyCoMapper { tcm_smart = smart, tcm_covar = covar
537 , tcm_hole = cohole, tcm_tybinder = tybinder })
538 env co
539 = go co
540 where
541 go (Refl r ty) = Refl r <$> mapType mapper env ty
542 go (TyConAppCo r tc args)
543 = mktyconappco r tc <$> mapM go args
544 go (AppCo c1 c2) = mkappco <$> go c1 <*> go c2
545 go (ForAllCo tv kind_co co)
546 = do { kind_co' <- go kind_co
547 ; (env', tv') <- tybinder env tv Inferred
548 ; co' <- mapCoercion mapper env' co
549 ; return $ mkforallco tv' kind_co' co' }
550 -- See Note [Efficiency for mapCoercion ForAllCo case]
551 go (FunCo r c1 c2) = mkFunCo r <$> go c1 <*> go c2
552 go (CoVarCo cv) = covar env cv
553 go (AxiomInstCo ax i args)
554 = mkaxiominstco ax i <$> mapM go args
555 go (UnivCo (HoleProv hole) r t1 t2)
556 = cohole env hole r t1 t2
557 go (UnivCo p r t1 t2)
558 = mkunivco <$> go_prov p <*> pure r
559 <*> mapType mapper env t1 <*> mapType mapper env t2
560 go (SymCo co) = mksymco <$> go co
561 go (TransCo c1 c2) = mktransco <$> go c1 <*> go c2
562 go (AxiomRuleCo r cos) = AxiomRuleCo r <$> mapM go cos
563 go (NthCo i co) = mknthco i <$> go co
564 go (LRCo lr co) = mklrco lr <$> go co
565 go (InstCo co arg) = mkinstco <$> go co <*> go arg
566 go (CoherenceCo c1 c2) = mkcoherenceco <$> go c1 <*> go c2
567 go (KindCo co) = mkkindco <$> go co
568 go (SubCo co) = mksubco <$> go co
569
570 go_prov UnsafeCoerceProv = return UnsafeCoerceProv
571 go_prov (PhantomProv co) = PhantomProv <$> go co
572 go_prov (ProofIrrelProv co) = ProofIrrelProv <$> go co
573 go_prov p@(PluginProv _) = return p
574 go_prov (HoleProv _) = panic "mapCoercion"
575
576 ( mktyconappco, mkappco, mkaxiominstco, mkunivco
577 , mksymco, mktransco, mknthco, mklrco, mkinstco, mkcoherenceco
578 , mkkindco, mksubco, mkforallco)
579 | smart
580 = ( mkTyConAppCo, mkAppCo, mkAxiomInstCo, mkUnivCo
581 , mkSymCo, mkTransCo, mkNthCo, mkLRCo, mkInstCo, mkCoherenceCo
582 , mkKindCo, mkSubCo, mkForAllCo )
583 | otherwise
584 = ( TyConAppCo, AppCo, AxiomInstCo, UnivCo
585 , SymCo, TransCo, NthCo, LRCo, InstCo, CoherenceCo
586 , KindCo, SubCo, ForAllCo )
587
588 {-
589 ************************************************************************
590 * *
591 \subsection{Constructor-specific functions}
592 * *
593 ************************************************************************
594
595
596 ---------------------------------------------------------------------
597 TyVarTy
598 ~~~~~~~
599 -}
600
601 -- | Attempts to obtain the type variable underlying a 'Type', and panics with the
602 -- given message if this is not a type variable type. See also 'getTyVar_maybe'
603 getTyVar :: String -> Type -> TyVar
604 getTyVar msg ty = case getTyVar_maybe ty of
605 Just tv -> tv
606 Nothing -> panic ("getTyVar: " ++ msg)
607
608 isTyVarTy :: Type -> Bool
609 isTyVarTy ty = isJust (getTyVar_maybe ty)
610
611 -- | Attempts to obtain the type variable underlying a 'Type'
612 getTyVar_maybe :: Type -> Maybe TyVar
613 getTyVar_maybe ty | Just ty' <- coreView ty = getTyVar_maybe ty'
614 | otherwise = repGetTyVar_maybe ty
615
616 -- | If the type is a tyvar, possibly under a cast, returns it, along
617 -- with the coercion. Thus, the co is :: kind tv ~R kind type
618 getCastedTyVar_maybe :: Type -> Maybe (TyVar, Coercion)
619 getCastedTyVar_maybe ty | Just ty' <- coreView ty = getCastedTyVar_maybe ty'
620 getCastedTyVar_maybe (CastTy (TyVarTy tv) co) = Just (tv, co)
621 getCastedTyVar_maybe (TyVarTy tv)
622 = Just (tv, mkReflCo Nominal (tyVarKind tv))
623 getCastedTyVar_maybe _ = Nothing
624
625 -- | Attempts to obtain the type variable underlying a 'Type', without
626 -- any expansion
627 repGetTyVar_maybe :: Type -> Maybe TyVar
628 repGetTyVar_maybe (TyVarTy tv) = Just tv
629 repGetTyVar_maybe _ = Nothing
630
631 {-
632 ---------------------------------------------------------------------
633 AppTy
634 ~~~~~
635 We need to be pretty careful with AppTy to make sure we obey the
636 invariant that a TyConApp is always visibly so. mkAppTy maintains the
637 invariant: use it.
638
639 Note [Decomposing fat arrow c=>t]
640 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
641 Can we unify (a b) with (Eq a => ty)? If we do so, we end up with
642 a partial application like ((=>) Eq a) which doesn't make sense in
643 source Haskell. In contrast, we *can* unify (a b) with (t1 -> t2).
644 Here's an example (Trac #9858) of how you might do it:
645 i :: (Typeable a, Typeable b) => Proxy (a b) -> TypeRep
646 i p = typeRep p
647
648 j = i (Proxy :: Proxy (Eq Int => Int))
649 The type (Proxy (Eq Int => Int)) is only accepted with -XImpredicativeTypes,
650 but suppose we want that. But then in the call to 'i', we end
651 up decomposing (Eq Int => Int), and we definitely don't want that.
652
653 This really only applies to the type checker; in Core, '=>' and '->'
654 are the same, as are 'Constraint' and '*'. But for now I've put
655 the test in repSplitAppTy_maybe, which applies throughout, because
656 the other calls to splitAppTy are in Unify, which is also used by
657 the type checker (e.g. when matching type-function equations).
658
659 -}
660
661 -- | Applies a type to another, as in e.g. @k a@
662 mkAppTy :: Type -> Type -> Type
663 mkAppTy (TyConApp tc tys) ty2 = mkTyConApp tc (tys ++ [ty2])
664 mkAppTy ty1 ty2 = AppTy ty1 ty2
665 -- Note that the TyConApp could be an
666 -- under-saturated type synonym. GHC allows that; e.g.
667 -- type Foo k = k a -> k a
668 -- type Id x = x
669 -- foo :: Foo Id -> Foo Id
670 --
671 -- Here Id is partially applied in the type sig for Foo,
672 -- but once the type synonyms are expanded all is well
673
674 mkAppTys :: Type -> [Type] -> Type
675 mkAppTys ty1 [] = ty1
676 mkAppTys (TyConApp tc tys1) tys2 = mkTyConApp tc (tys1 ++ tys2)
677 mkAppTys ty1 tys2 = foldl AppTy ty1 tys2
678
679 -------------
680 splitAppTy_maybe :: Type -> Maybe (Type, Type)
681 -- ^ Attempt to take a type application apart, whether it is a
682 -- function, type constructor, or plain type application. Note
683 -- that type family applications are NEVER unsaturated by this!
684 splitAppTy_maybe ty | Just ty' <- coreView ty
685 = splitAppTy_maybe ty'
686 splitAppTy_maybe ty = repSplitAppTy_maybe ty
687
688 -------------
689 repSplitAppTy_maybe :: Type -> Maybe (Type,Type)
690 -- ^ Does the AppTy split as in 'splitAppTy_maybe', but assumes that
691 -- any Core view stuff is already done
692 repSplitAppTy_maybe (FunTy ty1 ty2)
693 | Just rep1 <- getRuntimeRep_maybe ty1
694 , Just rep2 <- getRuntimeRep_maybe ty2
695 = Just (TyConApp funTyCon [rep1, rep2, ty1], ty2)
696
697 | otherwise
698 = pprPanic "repSplitAppTy_maybe" (ppr ty1 $$ ppr ty2)
699 repSplitAppTy_maybe (AppTy ty1 ty2)
700 = Just (ty1, ty2)
701 repSplitAppTy_maybe (TyConApp tc tys)
702 | mightBeUnsaturatedTyCon tc || tys `lengthExceeds` tyConArity tc
703 , Just (tys', ty') <- snocView tys
704 = Just (TyConApp tc tys', ty') -- Never create unsaturated type family apps!
705 repSplitAppTy_maybe _other = Nothing
706
707 -- this one doesn't braek apart (c => t).
708 -- See Note [Decomposing fat arrow c=>t]
709 -- Defined here to avoid module loops between Unify and TcType.
710 tcRepSplitAppTy_maybe :: Type -> Maybe (Type,Type)
711 -- ^ Does the AppTy split as in 'tcSplitAppTy_maybe', but assumes that
712 -- any coreView stuff is already done. Refuses to look through (c => t)
713 tcRepSplitAppTy_maybe (FunTy ty1 ty2)
714 | isConstraintKind (typeKind ty1)
715 = Nothing -- See Note [Decomposing fat arrow c=>t]
716
717 | Just rep1 <- getRuntimeRep_maybe ty1
718 , Just rep2 <- getRuntimeRep_maybe ty2
719 = Just (TyConApp funTyCon [rep1, rep2, ty1], ty2)
720
721 | otherwise
722 = pprPanic "repSplitAppTy_maybe" (ppr ty1 $$ ppr ty2)
723 tcRepSplitAppTy_maybe (AppTy ty1 ty2) = Just (ty1, ty2)
724 tcRepSplitAppTy_maybe (TyConApp tc tys)
725 | mightBeUnsaturatedTyCon tc || tys `lengthExceeds` tyConArity tc
726 , Just (tys', ty') <- snocView tys
727 = Just (TyConApp tc tys', ty') -- Never create unsaturated type family apps!
728 tcRepSplitAppTy_maybe _other = Nothing
729
730 -- | Split a type constructor application into its type constructor and
731 -- applied types. Note that this may fail in the case of a 'FunTy' with an
732 -- argument of unknown kind 'FunTy' (e.g. @FunTy (a :: k) Int@. since the kind
733 -- of @a@ isn't of the form @TYPE rep@). Consequently, you may need to zonk your
734 -- type before using this function.
735 --
736 -- If you only need the 'TyCon', consider using 'tcTyConAppTyCon_maybe'.
737 tcSplitTyConApp_maybe :: HasCallStack => Type -> Maybe (TyCon, [Type])
738 -- Defined here to avoid module loops between Unify and TcType.
739 tcSplitTyConApp_maybe ty | Just ty' <- tcView ty = tcSplitTyConApp_maybe ty'
740 tcSplitTyConApp_maybe ty = tcRepSplitTyConApp_maybe ty
741
742 -- | Like 'tcSplitTyConApp_maybe' but doesn't look through type synonyms.
743 tcRepSplitTyConApp_maybe :: HasCallStack => Type -> Maybe (TyCon, [Type])
744 -- Defined here to avoid module loops between Unify and TcType.
745 tcRepSplitTyConApp_maybe (TyConApp tc tys) = Just (tc, tys)
746 tcRepSplitTyConApp_maybe (FunTy arg res)
747 | Just arg_rep <- getRuntimeRep_maybe arg
748 , Just res_rep <- getRuntimeRep_maybe res
749 = Just (funTyCon, [arg_rep, res_rep, arg, res])
750
751 | otherwise
752 = pprPanic "tcRepSplitTyConApp_maybe" (ppr arg $$ ppr res)
753 tcRepSplitTyConApp_maybe _ = Nothing
754
755
756 -------------
757 splitAppTy :: Type -> (Type, Type)
758 -- ^ Attempts to take a type application apart, as in 'splitAppTy_maybe',
759 -- and panics if this is not possible
760 splitAppTy ty = case splitAppTy_maybe ty of
761 Just pr -> pr
762 Nothing -> panic "splitAppTy"
763
764 -------------
765 splitAppTys :: Type -> (Type, [Type])
766 -- ^ Recursively splits a type as far as is possible, leaving a residual
767 -- type being applied to and the type arguments applied to it. Never fails,
768 -- even if that means returning an empty list of type applications.
769 splitAppTys ty = split ty ty []
770 where
771 split orig_ty ty args | Just ty' <- coreView ty = split orig_ty ty' args
772 split _ (AppTy ty arg) args = split ty ty (arg:args)
773 split _ (TyConApp tc tc_args) args
774 = let -- keep type families saturated
775 n | mightBeUnsaturatedTyCon tc = 0
776 | otherwise = tyConArity tc
777 (tc_args1, tc_args2) = splitAt n tc_args
778 in
779 (TyConApp tc tc_args1, tc_args2 ++ args)
780 split _ (FunTy ty1 ty2) args
781 | Just rep1 <- getRuntimeRep_maybe ty1
782 , Just rep2 <- getRuntimeRep_maybe ty2
783 = ASSERT( null args )
784 (TyConApp funTyCon [], [rep1, rep2, ty1, ty2])
785
786 | otherwise
787 = pprPanic "splitAppTys" (ppr ty1 $$ ppr ty2 $$ ppr args)
788 split orig_ty _ args = (orig_ty, args)
789
790 -- | Like 'splitAppTys', but doesn't look through type synonyms
791 repSplitAppTys :: Type -> (Type, [Type])
792 repSplitAppTys ty = split ty []
793 where
794 split (AppTy ty arg) args = split ty (arg:args)
795 split (TyConApp tc tc_args) args
796 = let n | mightBeUnsaturatedTyCon tc = 0
797 | otherwise = tyConArity tc
798 (tc_args1, tc_args2) = splitAt n tc_args
799 in
800 (TyConApp tc tc_args1, tc_args2 ++ args)
801 split (FunTy ty1 ty2) args
802 | Just rep1 <- getRuntimeRep_maybe ty1
803 , Just rep2 <- getRuntimeRep_maybe ty2
804 = ASSERT( null args )
805 (TyConApp funTyCon [], [rep1, rep2, ty1, ty2])
806
807 | otherwise
808 = pprPanic "repSplitAppTys" (ppr ty1 $$ ppr ty2 $$ ppr args)
809 split ty args = (ty, args)
810
811 {-
812 LitTy
813 ~~~~~
814 -}
815
816 mkNumLitTy :: Integer -> Type
817 mkNumLitTy n = LitTy (NumTyLit n)
818
819 -- | Is this a numeric literal. We also look through type synonyms.
820 isNumLitTy :: Type -> Maybe Integer
821 isNumLitTy ty | Just ty1 <- coreView ty = isNumLitTy ty1
822 isNumLitTy (LitTy (NumTyLit n)) = Just n
823 isNumLitTy _ = Nothing
824
825 mkStrLitTy :: FastString -> Type
826 mkStrLitTy s = LitTy (StrTyLit s)
827
828 -- | Is this a symbol literal. We also look through type synonyms.
829 isStrLitTy :: Type -> Maybe FastString
830 isStrLitTy ty | Just ty1 <- coreView ty = isStrLitTy ty1
831 isStrLitTy (LitTy (StrTyLit s)) = Just s
832 isStrLitTy _ = Nothing
833
834
835 -- | Is this type a custom user error?
836 -- If so, give us the kind and the error message.
837 userTypeError_maybe :: Type -> Maybe Type
838 userTypeError_maybe t
839 = do { (tc, _kind : msg : _) <- splitTyConApp_maybe t
840 -- There may be more than 2 arguments, if the type error is
841 -- used as a type constructor (e.g. at kind `Type -> Type`).
842
843 ; guard (tyConName tc == errorMessageTypeErrorFamName)
844 ; return msg }
845
846 -- | Render a type corresponding to a user type error into a SDoc.
847 pprUserTypeErrorTy :: Type -> SDoc
848 pprUserTypeErrorTy ty =
849 case splitTyConApp_maybe ty of
850
851 -- Text "Something"
852 Just (tc,[txt])
853 | tyConName tc == typeErrorTextDataConName
854 , Just str <- isStrLitTy txt -> ftext str
855
856 -- ShowType t
857 Just (tc,[_k,t])
858 | tyConName tc == typeErrorShowTypeDataConName -> ppr t
859
860 -- t1 :<>: t2
861 Just (tc,[t1,t2])
862 | tyConName tc == typeErrorAppendDataConName ->
863 pprUserTypeErrorTy t1 <> pprUserTypeErrorTy t2
864
865 -- t1 :$$: t2
866 Just (tc,[t1,t2])
867 | tyConName tc == typeErrorVAppendDataConName ->
868 pprUserTypeErrorTy t1 $$ pprUserTypeErrorTy t2
869
870 -- An uneavaluated type function
871 _ -> ppr ty
872
873
874
875
876 {-
877 ---------------------------------------------------------------------
878 FunTy
879 ~~~~~
880
881 Note [Representation of function types]
882 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
883
884 Functions (e.g. Int -> Char) are can be thought of as being applications
885 of funTyCon (known in Haskell surface syntax as (->)),
886
887 (->) :: forall (r1 :: RuntimeRep) (r2 :: RuntimeRep)
888 (a :: TYPE r1) (b :: TYPE r2).
889 a -> b -> Type
890
891 However, for efficiency's sake we represent saturated applications of (->)
892 with FunTy. For instance, the type,
893
894 (->) r1 r2 a b
895
896 is equivalent to,
897
898 FunTy (Anon a) b
899
900 Note how the RuntimeReps are implied in the FunTy representation. For this
901 reason we must be careful when recontructing the TyConApp representation (see,
902 for instance, splitTyConApp_maybe).
903
904 In the compiler we maintain the invariant that all saturated applications of
905 (->) are represented with FunTy.
906
907 See #11714.
908 -}
909
910 isFunTy :: Type -> Bool
911 isFunTy ty = isJust (splitFunTy_maybe ty)
912
913 splitFunTy :: Type -> (Type, Type)
914 -- ^ Attempts to extract the argument and result types from a type, and
915 -- panics if that is not possible. See also 'splitFunTy_maybe'
916 splitFunTy ty | Just ty' <- coreView ty = splitFunTy ty'
917 splitFunTy (FunTy arg res) = (arg, res)
918 splitFunTy other = pprPanic "splitFunTy" (ppr other)
919
920 splitFunTy_maybe :: Type -> Maybe (Type, Type)
921 -- ^ Attempts to extract the argument and result types from a type
922 splitFunTy_maybe ty | Just ty' <- coreView ty = splitFunTy_maybe ty'
923 splitFunTy_maybe (FunTy arg res) = Just (arg, res)
924 splitFunTy_maybe _ = Nothing
925
926 splitFunTys :: Type -> ([Type], Type)
927 splitFunTys ty = split [] ty ty
928 where
929 split args orig_ty ty | Just ty' <- coreView ty = split args orig_ty ty'
930 split args _ (FunTy arg res) = split (arg:args) res res
931 split args orig_ty _ = (reverse args, orig_ty)
932
933 funResultTy :: Type -> Type
934 -- ^ Extract the function result type and panic if that is not possible
935 funResultTy ty | Just ty' <- coreView ty = funResultTy ty'
936 funResultTy (FunTy _ res) = res
937 funResultTy ty = pprPanic "funResultTy" (ppr ty)
938
939 funArgTy :: Type -> Type
940 -- ^ Extract the function argument type and panic if that is not possible
941 funArgTy ty | Just ty' <- coreView ty = funArgTy ty'
942 funArgTy (FunTy arg _res) = arg
943 funArgTy ty = pprPanic "funArgTy" (ppr ty)
944
945 piResultTy :: Type -> Type -> Type
946 piResultTy ty arg = case piResultTy_maybe ty arg of
947 Just res -> res
948 Nothing -> pprPanic "piResultTy" (ppr ty $$ ppr arg)
949
950 piResultTy_maybe :: Type -> Type -> Maybe Type
951
952 -- ^ Just like 'piResultTys' but for a single argument
953 -- Try not to iterate 'piResultTy', because it's inefficient to substitute
954 -- one variable at a time; instead use 'piResultTys"
955 piResultTy_maybe ty arg
956 | Just ty' <- coreView ty = piResultTy_maybe ty' arg
957
958 | FunTy _ res <- ty
959 = Just res
960
961 | ForAllTy (TvBndr tv _) res <- ty
962 = let empty_subst = mkEmptyTCvSubst $ mkInScopeSet $
963 tyCoVarsOfTypes [arg,res]
964 in Just (substTy (extendTvSubst empty_subst tv arg) res)
965
966 | otherwise
967 = Nothing
968
969 -- | (piResultTys f_ty [ty1, .., tyn]) gives the type of (f ty1 .. tyn)
970 -- where f :: f_ty
971 -- 'piResultTys' is interesting because:
972 -- 1. 'f_ty' may have more for-alls than there are args
973 -- 2. Less obviously, it may have fewer for-alls
974 -- For case 2. think of:
975 -- piResultTys (forall a.a) [forall b.b, Int]
976 -- This really can happen, but only (I think) in situations involving
977 -- undefined. For example:
978 -- undefined :: forall a. a
979 -- Term: undefined @(forall b. b->b) @Int
980 -- This term should have type (Int -> Int), but notice that
981 -- there are more type args than foralls in 'undefined's type.
982
983 -- If you edit this function, you may need to update the GHC formalism
984 -- See Note [GHC Formalism] in coreSyn/CoreLint.hs
985
986 -- This is a heavily used function (e.g. from typeKind),
987 -- so we pay attention to efficiency, especially in the special case
988 -- where there are no for-alls so we are just dropping arrows from
989 -- a function type/kind.
990 piResultTys :: Type -> [Type] -> Type
991 piResultTys ty [] = ty
992 piResultTys ty orig_args@(arg:args)
993 | Just ty' <- coreView ty
994 = piResultTys ty' orig_args
995
996 | FunTy _ res <- ty
997 = piResultTys res args
998
999 | ForAllTy (TvBndr tv _) res <- ty
1000 = go (extendVarEnv emptyTvSubstEnv tv arg) res args
1001
1002 | otherwise
1003 = pprPanic "piResultTys1" (ppr ty $$ ppr orig_args)
1004 where
1005 in_scope = mkInScopeSet (tyCoVarsOfTypes (ty:orig_args))
1006
1007 go :: TvSubstEnv -> Type -> [Type] -> Type
1008 go tv_env ty [] = substTy (mkTvSubst in_scope tv_env) ty
1009
1010 go tv_env ty all_args@(arg:args)
1011 | Just ty' <- coreView ty
1012 = go tv_env ty' all_args
1013
1014 | FunTy _ res <- ty
1015 = go tv_env res args
1016
1017 | ForAllTy (TvBndr tv _) res <- ty
1018 = go (extendVarEnv tv_env tv arg) res args
1019
1020 | TyVarTy tv <- ty
1021 , Just ty' <- lookupVarEnv tv_env tv
1022 -- Deals with piResultTys (forall a. a) [forall b.b, Int]
1023 = piResultTys ty' all_args
1024
1025 | otherwise
1026 = pprPanic "piResultTys2" (ppr ty $$ ppr orig_args $$ ppr all_args)
1027
1028 applyTysX :: [TyVar] -> Type -> [Type] -> Type
1029 -- applyTyxX beta-reduces (/\tvs. body_ty) arg_tys
1030 -- Assumes that (/\tvs. body_ty) is closed
1031 applyTysX tvs body_ty arg_tys
1032 = ASSERT2( length arg_tys >= n_tvs, pp_stuff )
1033 ASSERT2( tyCoVarsOfType body_ty `subVarSet` mkVarSet tvs, pp_stuff )
1034 mkAppTys (substTyWith tvs (take n_tvs arg_tys) body_ty)
1035 (drop n_tvs arg_tys)
1036 where
1037 pp_stuff = vcat [ppr tvs, ppr body_ty, ppr arg_tys]
1038 n_tvs = length tvs
1039
1040 {-
1041 ---------------------------------------------------------------------
1042 TyConApp
1043 ~~~~~~~~
1044 -}
1045
1046 -- | A key function: builds a 'TyConApp' or 'FunTy' as appropriate to
1047 -- its arguments. Applies its arguments to the constructor from left to right.
1048 mkTyConApp :: TyCon -> [Type] -> Type
1049 mkTyConApp tycon tys
1050 | isFunTyCon tycon
1051 , [_rep1,_rep2,ty1,ty2] <- tys
1052 = FunTy ty1 ty2
1053
1054 | otherwise
1055 = TyConApp tycon tys
1056
1057 -- splitTyConApp "looks through" synonyms, because they don't
1058 -- mean a distinct type, but all other type-constructor applications
1059 -- including functions are returned as Just ..
1060
1061 -- | Retrieve the tycon heading this type, if there is one. Does /not/
1062 -- look through synonyms.
1063 tyConAppTyConPicky_maybe :: Type -> Maybe TyCon
1064 tyConAppTyConPicky_maybe (TyConApp tc _) = Just tc
1065 tyConAppTyConPicky_maybe (FunTy {}) = Just funTyCon
1066 tyConAppTyConPicky_maybe _ = Nothing
1067
1068
1069 -- | The same as @fst . splitTyConApp@
1070 tyConAppTyCon_maybe :: Type -> Maybe TyCon
1071 tyConAppTyCon_maybe ty | Just ty' <- coreView ty = tyConAppTyCon_maybe ty'
1072 tyConAppTyCon_maybe (TyConApp tc _) = Just tc
1073 tyConAppTyCon_maybe (FunTy {}) = Just funTyCon
1074 tyConAppTyCon_maybe _ = Nothing
1075
1076 tyConAppTyCon :: Type -> TyCon
1077 tyConAppTyCon ty = tyConAppTyCon_maybe ty `orElse` pprPanic "tyConAppTyCon" (ppr ty)
1078
1079 -- | The same as @snd . splitTyConApp@
1080 tyConAppArgs_maybe :: Type -> Maybe [Type]
1081 tyConAppArgs_maybe ty | Just ty' <- coreView ty = tyConAppArgs_maybe ty'
1082 tyConAppArgs_maybe (TyConApp _ tys) = Just tys
1083 tyConAppArgs_maybe (FunTy arg res)
1084 | Just rep1 <- getRuntimeRep_maybe arg
1085 , Just rep2 <- getRuntimeRep_maybe res
1086 = Just [rep1, rep2, arg, res]
1087 tyConAppArgs_maybe _ = Nothing
1088
1089 tyConAppArgs :: Type -> [Type]
1090 tyConAppArgs ty = tyConAppArgs_maybe ty `orElse` pprPanic "tyConAppArgs" (ppr ty)
1091
1092 tyConAppArgN :: Int -> Type -> Type
1093 -- Executing Nth
1094 tyConAppArgN n ty
1095 = case tyConAppArgs_maybe ty of
1096 Just tys -> ASSERT2( n < length tys, ppr n <+> ppr tys ) tys `getNth` n
1097 Nothing -> pprPanic "tyConAppArgN" (ppr n <+> ppr ty)
1098
1099 -- | Attempts to tease a type apart into a type constructor and the application
1100 -- of a number of arguments to that constructor. Panics if that is not possible.
1101 -- See also 'splitTyConApp_maybe'
1102 splitTyConApp :: Type -> (TyCon, [Type])
1103 splitTyConApp ty = case splitTyConApp_maybe ty of
1104 Just stuff -> stuff
1105 Nothing -> pprPanic "splitTyConApp" (ppr ty)
1106
1107 -- | Attempts to tease a type apart into a type constructor and the application
1108 -- of a number of arguments to that constructor
1109 splitTyConApp_maybe :: HasDebugCallStack => Type -> Maybe (TyCon, [Type])
1110 splitTyConApp_maybe ty | Just ty' <- coreView ty = splitTyConApp_maybe ty'
1111 splitTyConApp_maybe ty = repSplitTyConApp_maybe ty
1112
1113 -- | Like 'splitTyConApp_maybe', but doesn't look through synonyms. This
1114 -- assumes the synonyms have already been dealt with.
1115 repSplitTyConApp_maybe :: HasDebugCallStack => Type -> Maybe (TyCon, [Type])
1116 repSplitTyConApp_maybe (TyConApp tc tys) = Just (tc, tys)
1117 repSplitTyConApp_maybe (FunTy arg res)
1118 | Just rep1 <- getRuntimeRep_maybe arg
1119 , Just rep2 <- getRuntimeRep_maybe res
1120 = Just (funTyCon, [rep1, rep2, arg, res])
1121 | otherwise
1122 = pprPanic "repSplitTyConApp_maybe"
1123 (ppr arg $$ ppr res $$ ppr (typeKind res))
1124 repSplitTyConApp_maybe _ = Nothing
1125
1126 -- | Attempts to tease a list type apart and gives the type of the elements if
1127 -- successful (looks through type synonyms)
1128 splitListTyConApp_maybe :: Type -> Maybe Type
1129 splitListTyConApp_maybe ty = case splitTyConApp_maybe ty of
1130 Just (tc,[e]) | tc == listTyCon -> Just e
1131 _other -> Nothing
1132
1133 -- | What is the role assigned to the next parameter of this type? Usually,
1134 -- this will be 'Nominal', but if the type is a 'TyConApp', we may be able to
1135 -- do better. The type does *not* have to be well-kinded when applied for this
1136 -- to work!
1137 nextRole :: Type -> Role
1138 nextRole ty
1139 | Just (tc, tys) <- splitTyConApp_maybe ty
1140 , let num_tys = length tys
1141 , num_tys < tyConArity tc
1142 = tyConRoles tc `getNth` num_tys
1143
1144 | otherwise
1145 = Nominal
1146
1147 newTyConInstRhs :: TyCon -> [Type] -> Type
1148 -- ^ Unwrap one 'layer' of newtype on a type constructor and its
1149 -- arguments, using an eta-reduced version of the @newtype@ if possible.
1150 -- This requires tys to have at least @newTyConInstArity tycon@ elements.
1151 newTyConInstRhs tycon tys
1152 = ASSERT2( tvs `leLength` tys, ppr tycon $$ ppr tys $$ ppr tvs )
1153 applyTysX tvs rhs tys
1154 where
1155 (tvs, rhs) = newTyConEtadRhs tycon
1156
1157 {-
1158 ---------------------------------------------------------------------
1159 CastTy
1160 ~~~~~~
1161 A casted type has its *kind* casted into something new.
1162
1163 Note [No reflexive casts in types]
1164 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1165 As far as possible, we would like to maintain the following property:
1166
1167 (*) If (t1 `eqType` t2), then t1 and t2 are treated identically within GHC.
1168
1169 The (*) property is very useful, because we have a tendency to compare two
1170 types to see if they're equal, and then arbitrarily choose one. We don't
1171 want this arbitrary choice to then matter later on. Maintaining (*) means
1172 that every function that looks at a structure of a type must think about
1173 casts. In places where we directly pattern-match, this consideration is
1174 forced by consideration of the CastTy constructor.
1175
1176 But, when we call a splitXXX function, it's easy to ignore the possibility
1177 of casts. In particular, splitTyConApp is used extensively, and we don't
1178 want it to fail on (T a b c |> co). Happily, if we have
1179 (T a b c |> co) `eqType` (T d e f)
1180 then co must be reflexive. Why? eqType checks that the kinds are equal, as
1181 well as checking that (a `eqType` d), (b `eqType` e), and (c `eqType` f).
1182 By the kind check, we know that (T a b c |> co) and (T d e f) have the same
1183 kind. So the only way that co could be non-reflexive is for (T a b c) to have
1184 a different kind than (T d e f). But because T's kind is closed (all tycon kinds
1185 are closed), the only way for this to happen is that one of the arguments has
1186 to differ, leading to a contradiction. Thus, co is reflexive.
1187
1188 Accordingly, by eliminating reflexive casts, splitTyConApp need not worry
1189 about outermost casts to uphold (*).
1190
1191 Unforunately, that's not the end of the story. Consider comparing
1192 (T a b c) =? (T a b |> (co -> <Type>)) (c |> sym co)
1193 These two types have the same kind (Type), but the left type is a TyConApp
1194 while the right type is not. To handle this case, we will have to implement
1195 some variant of the dreaded KPush algorithm (c.f. CoreOpt.pushCoDataCon).
1196 This stone is left unturned for now, meaning that we don't yet uphold (*).
1197
1198 The other place where (*) will be hard to guarantee is in splitAppTy, because
1199 I (Richard E) can't think of a way to push coercions into AppTys. The good
1200 news here is that splitAppTy is not used all that much, and so all clients of
1201 that function can simply be told to use splitCastTy as well, in order to
1202 uphold (*). This, too, is left undone, for now.
1203
1204 -}
1205
1206 splitCastTy_maybe :: Type -> Maybe (Type, Coercion)
1207 splitCastTy_maybe ty | Just ty' <- coreView ty = splitCastTy_maybe ty'
1208 splitCastTy_maybe (CastTy ty co) = Just (ty, co)
1209 splitCastTy_maybe _ = Nothing
1210
1211 -- | Make a 'CastTy'. The Coercion must be nominal. Checks the
1212 -- Coercion for reflexivity, dropping it if it's reflexive.
1213 -- See Note [No reflexive casts in types]
1214 mkCastTy :: Type -> Coercion -> Type
1215 mkCastTy ty co | isReflexiveCo co = ty
1216 -- NB: Do the slow check here. This is important to keep the splitXXX
1217 -- functions working properly. Otherwise, we may end up with something
1218 -- like (((->) |> something_reflexive_but_not_obviously_so) biz baz)
1219 -- fails under splitFunTy_maybe. This happened with the cheaper check
1220 -- in test dependent/should_compile/dynamic-paper.
1221
1222 mkCastTy (CastTy ty co1) co2 = mkCastTy ty (co1 `mkTransCo` co2)
1223 mkCastTy ty co = CastTy ty co
1224
1225 tyConTyBinders :: TyCon -> [TyBinder]
1226 -- Return the tyConBinders in TyBinder form
1227 tyConTyBinders tycon = tyConBindersTyBinders (tyConBinders tycon)
1228
1229 tyConBindersTyBinders :: [TyConBinder] -> [TyBinder]
1230 -- Return the tyConBinders in TyBinder form
1231 tyConBindersTyBinders = map to_tyb
1232 where
1233 to_tyb (TvBndr tv (NamedTCB vis)) = Named (TvBndr tv vis)
1234 to_tyb (TvBndr tv AnonTCB) = Anon (tyVarKind tv)
1235
1236 {-
1237 --------------------------------------------------------------------
1238 CoercionTy
1239 ~~~~~~~~~~
1240 CoercionTy allows us to inject coercions into types. A CoercionTy
1241 should appear only in the right-hand side of an application.
1242 -}
1243
1244 mkCoercionTy :: Coercion -> Type
1245 mkCoercionTy = CoercionTy
1246
1247 isCoercionTy :: Type -> Bool
1248 isCoercionTy (CoercionTy _) = True
1249 isCoercionTy _ = False
1250
1251 isCoercionTy_maybe :: Type -> Maybe Coercion
1252 isCoercionTy_maybe (CoercionTy co) = Just co
1253 isCoercionTy_maybe _ = Nothing
1254
1255 stripCoercionTy :: Type -> Coercion
1256 stripCoercionTy (CoercionTy co) = co
1257 stripCoercionTy ty = pprPanic "stripCoercionTy" (ppr ty)
1258
1259 {-
1260 ---------------------------------------------------------------------
1261 SynTy
1262 ~~~~~
1263
1264 Notes on type synonyms
1265 ~~~~~~~~~~~~~~~~~~~~~~
1266 The various "split" functions (splitFunTy, splitRhoTy, splitForAllTy) try
1267 to return type synonyms wherever possible. Thus
1268
1269 type Foo a = a -> a
1270
1271 we want
1272 splitFunTys (a -> Foo a) = ([a], Foo a)
1273 not ([a], a -> a)
1274
1275 The reason is that we then get better (shorter) type signatures in
1276 interfaces. Notably this plays a role in tcTySigs in TcBinds.hs.
1277
1278
1279 ---------------------------------------------------------------------
1280 ForAllTy
1281 ~~~~~~~~
1282 -}
1283
1284 -- | Make a dependent forall over an Inferred (as opposed to Specified)
1285 -- variable
1286 mkInvForAllTy :: TyVar -> Type -> Type
1287 mkInvForAllTy tv ty = ASSERT( isTyVar tv )
1288 ForAllTy (TvBndr tv Inferred) ty
1289
1290 -- | Like mkForAllTys, but assumes all variables are dependent and Inferred,
1291 -- a common case
1292 mkInvForAllTys :: [TyVar] -> Type -> Type
1293 mkInvForAllTys tvs ty = ASSERT( all isTyVar tvs )
1294 foldr mkInvForAllTy ty tvs
1295
1296 -- | Like mkForAllTys, but assumes all variables are dependent and specified,
1297 -- a common case
1298 mkSpecForAllTys :: [TyVar] -> Type -> Type
1299 mkSpecForAllTys tvs = ASSERT( all isTyVar tvs )
1300 mkForAllTys [ TvBndr tv Specified | tv <- tvs ]
1301
1302 -- | Like mkForAllTys, but assumes all variables are dependent and visible
1303 mkVisForAllTys :: [TyVar] -> Type -> Type
1304 mkVisForAllTys tvs = ASSERT( all isTyVar tvs )
1305 mkForAllTys [ TvBndr tv Required | tv <- tvs ]
1306
1307 mkLamType :: Var -> Type -> Type
1308 -- ^ Makes a @(->)@ type or an implicit forall type, depending
1309 -- on whether it is given a type variable or a term variable.
1310 -- This is used, for example, when producing the type of a lambda.
1311 -- Always uses Inferred binders.
1312 mkLamTypes :: [Var] -> Type -> Type
1313 -- ^ 'mkLamType' for multiple type or value arguments
1314
1315 mkLamType v ty
1316 | isTyVar v = ForAllTy (TvBndr v Inferred) ty
1317 | otherwise = FunTy (varType v) ty
1318
1319 mkLamTypes vs ty = foldr mkLamType ty vs
1320
1321 -- | Given a list of type-level vars and a result type, makes TyBinders, preferring
1322 -- anonymous binders if the variable is, in fact, not dependent.
1323 -- All binders are /visible/.
1324 mkTyConBindersPreferAnon :: [TyVar] -> Type -> [TyConBinder]
1325 mkTyConBindersPreferAnon vars inner_ty = fst (go vars)
1326 where
1327 go :: [TyVar] -> ([TyConBinder], VarSet) -- also returns the free vars
1328 go [] = ([], tyCoVarsOfType inner_ty)
1329 go (v:vs) | v `elemVarSet` fvs
1330 = ( TvBndr v (NamedTCB Required) : binders
1331 , fvs `delVarSet` v `unionVarSet` kind_vars )
1332 | otherwise
1333 = ( TvBndr v AnonTCB : binders
1334 , fvs `unionVarSet` kind_vars )
1335 where
1336 (binders, fvs) = go vs
1337 kind_vars = tyCoVarsOfType $ tyVarKind v
1338
1339 -- | Take a ForAllTy apart, returning the list of tyvars and the result type.
1340 -- This always succeeds, even if it returns only an empty list. Note that the
1341 -- result type returned may have free variables that were bound by a forall.
1342 splitForAllTys :: Type -> ([TyVar], Type)
1343 splitForAllTys ty = split ty ty []
1344 where
1345 split orig_ty ty tvs | Just ty' <- coreView ty = split orig_ty ty' tvs
1346 split _ (ForAllTy (TvBndr tv _) ty) tvs = split ty ty (tv:tvs)
1347 split orig_ty _ tvs = (reverse tvs, orig_ty)
1348
1349 -- | Like 'splitPiTys' but split off only /named/ binders.
1350 splitForAllTyVarBndrs :: Type -> ([TyVarBinder], Type)
1351 splitForAllTyVarBndrs ty = split ty ty []
1352 where
1353 split orig_ty ty bs | Just ty' <- coreView ty = split orig_ty ty' bs
1354 split _ (ForAllTy b res) bs = split res res (b:bs)
1355 split orig_ty _ bs = (reverse bs, orig_ty)
1356
1357 -- | Checks whether this is a proper forall (with a named binder)
1358 isForAllTy :: Type -> Bool
1359 isForAllTy ty | Just ty' <- coreView ty = isForAllTy ty'
1360 isForAllTy (ForAllTy {}) = True
1361 isForAllTy _ = False
1362
1363 -- | Is this a function or forall?
1364 isPiTy :: Type -> Bool
1365 isPiTy ty | Just ty' <- coreView ty = isForAllTy ty'
1366 isPiTy (ForAllTy {}) = True
1367 isPiTy (FunTy {}) = True
1368 isPiTy _ = False
1369
1370 -- | Take a forall type apart, or panics if that is not possible.
1371 splitForAllTy :: Type -> (TyVar, Type)
1372 splitForAllTy ty
1373 | Just answer <- splitForAllTy_maybe ty = answer
1374 | otherwise = pprPanic "splitForAllTy" (ppr ty)
1375
1376 -- | Drops all ForAllTys
1377 dropForAlls :: Type -> Type
1378 dropForAlls ty = go ty
1379 where
1380 go ty | Just ty' <- coreView ty = go ty'
1381 go (ForAllTy _ res) = go res
1382 go res = res
1383
1384 -- | Attempts to take a forall type apart, but only if it's a proper forall,
1385 -- with a named binder
1386 splitForAllTy_maybe :: Type -> Maybe (TyVar, Type)
1387 splitForAllTy_maybe ty = go ty
1388 where
1389 go ty | Just ty' <- coreView ty = go ty'
1390 go (ForAllTy (TvBndr tv _) ty) = Just (tv, ty)
1391 go _ = Nothing
1392
1393 -- | Attempts to take a forall type apart; works with proper foralls and
1394 -- functions
1395 splitPiTy_maybe :: Type -> Maybe (TyBinder, Type)
1396 splitPiTy_maybe ty = go ty
1397 where
1398 go ty | Just ty' <- coreView ty = go ty'
1399 go (ForAllTy bndr ty) = Just (Named bndr, ty)
1400 go (FunTy arg res) = Just (Anon arg, res)
1401 go _ = Nothing
1402
1403 -- | Takes a forall type apart, or panics
1404 splitPiTy :: Type -> (TyBinder, Type)
1405 splitPiTy ty
1406 | Just answer <- splitPiTy_maybe ty = answer
1407 | otherwise = pprPanic "splitPiTy" (ppr ty)
1408
1409 -- | Split off all TyBinders to a type, splitting both proper foralls
1410 -- and functions
1411 splitPiTys :: Type -> ([TyBinder], Type)
1412 splitPiTys ty = split ty ty []
1413 where
1414 split orig_ty ty bs | Just ty' <- coreView ty = split orig_ty ty' bs
1415 split _ (ForAllTy b res) bs = split res res (Named b : bs)
1416 split _ (FunTy arg res) bs = split res res (Anon arg : bs)
1417 split orig_ty _ bs = (reverse bs, orig_ty)
1418
1419 -- Like splitPiTys, but returns only *invisible* binders, including constraints
1420 -- Stops at the first visible binder
1421 splitPiTysInvisible :: Type -> ([TyBinder], Type)
1422 splitPiTysInvisible ty = split ty ty []
1423 where
1424 split orig_ty ty bs | Just ty' <- coreView ty = split orig_ty ty' bs
1425 split _ (ForAllTy b@(TvBndr _ vis) res) bs
1426 | isInvisibleArgFlag vis = split res res (Named b : bs)
1427 split _ (FunTy arg res) bs
1428 | isPredTy arg = split res res (Anon arg : bs)
1429 split orig_ty _ bs = (reverse bs, orig_ty)
1430
1431 -- | Given a tycon and its arguments, filters out any invisible arguments
1432 filterOutInvisibleTypes :: TyCon -> [Type] -> [Type]
1433 filterOutInvisibleTypes tc tys = snd $ partitionInvisibles tc id tys
1434
1435 -- | Like 'filterOutInvisibles', but works on 'TyVar's
1436 filterOutInvisibleTyVars :: TyCon -> [TyVar] -> [TyVar]
1437 filterOutInvisibleTyVars tc tvs = snd $ partitionInvisibles tc mkTyVarTy tvs
1438
1439 -- | Given a tycon and a list of things (which correspond to arguments),
1440 -- partitions the things into
1441 -- Inferred or Specified ones and
1442 -- Required ones
1443 -- The callback function is necessary for this scenario:
1444 --
1445 -- > T :: forall k. k -> k
1446 -- > partitionInvisibles T [forall m. m -> m -> m, S, R, Q]
1447 --
1448 -- After substituting, we get
1449 --
1450 -- > T (forall m. m -> m -> m) :: (forall m. m -> m -> m) -> forall n. n -> n -> n
1451 --
1452 -- Thus, the first argument is invisible, @S@ is visible, @R@ is invisible again,
1453 -- and @Q@ is visible.
1454 --
1455 -- If you're absolutely sure that your tycon's kind doesn't end in a variable,
1456 -- it's OK if the callback function panics, as that's the only time it's
1457 -- consulted.
1458 partitionInvisibles :: TyCon -> (a -> Type) -> [a] -> ([a], [a])
1459 partitionInvisibles tc get_ty = go emptyTCvSubst (tyConKind tc)
1460 where
1461 go _ _ [] = ([], [])
1462 go subst (ForAllTy (TvBndr tv vis) res_ki) (x:xs)
1463 | isVisibleArgFlag vis = second (x :) (go subst' res_ki xs)
1464 | otherwise = first (x :) (go subst' res_ki xs)
1465 where
1466 subst' = extendTvSubst subst tv (get_ty x)
1467 go subst (TyVarTy tv) xs
1468 | Just ki <- lookupTyVar subst tv = go subst ki xs
1469 go _ _ xs = ([], xs) -- something is ill-kinded. But this can happen
1470 -- when printing errors. Assume everything is visible.
1471
1472 -- @isTauTy@ tests if a type has no foralls
1473 isTauTy :: Type -> Bool
1474 isTauTy ty | Just ty' <- coreView ty = isTauTy ty'
1475 isTauTy (TyVarTy _) = True
1476 isTauTy (LitTy {}) = True
1477 isTauTy (TyConApp tc tys) = all isTauTy tys && isTauTyCon tc
1478 isTauTy (AppTy a b) = isTauTy a && isTauTy b
1479 isTauTy (FunTy a b) = isTauTy a && isTauTy b
1480 isTauTy (ForAllTy {}) = False
1481 isTauTy (CastTy ty _) = isTauTy ty
1482 isTauTy (CoercionTy _) = False -- Not sure about this
1483
1484 {-
1485 %************************************************************************
1486 %* *
1487 TyBinders
1488 %* *
1489 %************************************************************************
1490 -}
1491
1492 -- | Make a named binder
1493 mkTyVarBinder :: ArgFlag -> Var -> TyVarBinder
1494 mkTyVarBinder vis var = TvBndr var vis
1495
1496 -- | Make many named binders
1497 mkTyVarBinders :: ArgFlag -> [TyVar] -> [TyVarBinder]
1498 mkTyVarBinders vis = map (mkTyVarBinder vis)
1499
1500 -- | Make an anonymous binder
1501 mkAnonBinder :: Type -> TyBinder
1502 mkAnonBinder = Anon
1503
1504 -- | Does this binder bind a variable that is /not/ erased? Returns
1505 -- 'True' for anonymous binders.
1506 isAnonTyBinder :: TyBinder -> Bool
1507 isAnonTyBinder (Named {}) = False
1508 isAnonTyBinder (Anon {}) = True
1509
1510 isNamedTyBinder :: TyBinder -> Bool
1511 isNamedTyBinder (Named {}) = True
1512 isNamedTyBinder (Anon {}) = False
1513
1514 tyBinderType :: TyBinder -> Type
1515 -- Barely used
1516 tyBinderType (Named tvb) = binderKind tvb
1517 tyBinderType (Anon ty) = ty
1518
1519 -- | Extract a relevant type, if there is one.
1520 binderRelevantType_maybe :: TyBinder -> Maybe Type
1521 binderRelevantType_maybe (Named {}) = Nothing
1522 binderRelevantType_maybe (Anon ty) = Just ty
1523
1524 -- | Like 'maybe', but for binders.
1525 caseBinder :: TyBinder -- ^ binder to scrutinize
1526 -> (TyVarBinder -> a) -- ^ named case
1527 -> (Type -> a) -- ^ anonymous case
1528 -> a
1529 caseBinder (Named v) f _ = f v
1530 caseBinder (Anon t) _ d = d t
1531
1532 -- | Create a TCvSubst combining the binders and types provided.
1533 -- NB: It is specifically OK if the lists are of different lengths.
1534 -- Barely used
1535 zipTyBinderSubst :: [TyBinder] -> [Type] -> TCvSubst
1536 zipTyBinderSubst bndrs tys
1537 = mkTvSubstPrs [ (tv, ty) | (Named (TvBndr tv _), ty) <- zip bndrs tys ]
1538
1539 -- | Manufacture a new 'TyConBinder' from a 'TyBinder'. Anonymous
1540 -- 'TyBinder's are still assigned names as 'TyConBinder's, so we need
1541 -- the extra gunk with which to construct a 'Name'. Used when producing
1542 -- tyConTyVars from a datatype kind signature. Defined here to avoid module
1543 -- loops.
1544 mkTyBinderTyConBinder :: TyBinder -> SrcSpan -> Unique -> OccName -> TyConBinder
1545 mkTyBinderTyConBinder (Named (TvBndr tv argf)) _ _ _ = TvBndr tv (NamedTCB argf)
1546 mkTyBinderTyConBinder (Anon kind) loc uniq occ
1547 = TvBndr (mkTyVar (mkInternalName uniq occ loc) kind) AnonTCB
1548
1549 {-
1550 %************************************************************************
1551 %* *
1552 Pred
1553 * *
1554 ************************************************************************
1555
1556 Predicates on PredType
1557
1558 Note [isPredTy complications]
1559 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1560 You would think that we could define
1561 isPredTy ty = isConstraintKind (typeKind ty)
1562 But there are a number of complications:
1563
1564 * isPredTy is used when printing types, which can happen in debug
1565 printing during type checking of not-fully-zonked types. So it's
1566 not cool to say isConstraintKind (typeKind ty) because, absent
1567 zonking, the type might be ill-kinded, and typeKind crashes. Hence the
1568 rather tiresome story here
1569
1570 * isPredTy must return "True" to *unlifted* coercions, such as (t1 ~# t2)
1571 and (t1 ~R# t2), which are not of kind Constraint! Currently they are
1572 of kind #.
1573
1574 * If we do form the type '(C a => C [a]) => blah', then we'd like to
1575 print it as such. But that means that isPredTy must return True for
1576 (C a => C [a]). Admittedly that type is illegal in Haskell, but we
1577 want to print it nicely in error messages.
1578 -}
1579
1580 -- | Is the type suitable to classify a given/wanted in the typechecker?
1581 isPredTy :: Type -> Bool
1582 -- See Note [isPredTy complications]
1583 isPredTy ty = go ty []
1584 where
1585 go :: Type -> [KindOrType] -> Bool
1586 go (AppTy ty1 ty2) args = go ty1 (ty2 : args)
1587 go (TyVarTy tv) args = go_k (tyVarKind tv) args
1588 go (TyConApp tc tys) args = ASSERT( null args ) -- TyConApp invariant
1589 go_tc tc tys
1590 go (FunTy arg res) []
1591 | isPredTy arg = isPredTy res -- (Eq a => C a)
1592 | otherwise = False -- (Int -> Bool)
1593 go (ForAllTy _ ty) [] = go ty []
1594 go (CastTy _ co) args = go_k (pSnd (coercionKind co)) args
1595 go _ _ = False
1596
1597 go_tc :: TyCon -> [KindOrType] -> Bool
1598 go_tc tc args
1599 | tc `hasKey` eqPrimTyConKey || tc `hasKey` eqReprPrimTyConKey
1600 = length args == 4 -- ~# and ~R# sadly have result kind #
1601 -- not Constraint; but we still want
1602 -- isPredTy to reply True.
1603 | otherwise = go_k (tyConKind tc) args
1604
1605 go_k :: Kind -> [KindOrType] -> Bool
1606 -- True <=> ('k' applied to 'kts') = Constraint
1607 go_k k [] = isConstraintKind k
1608 go_k k (arg:args) = case piResultTy_maybe k arg of
1609 Just k' -> go_k k' args
1610 Nothing -> WARN( True, text "isPredTy" <+> ppr ty )
1611 False
1612 -- This last case shouldn't happen under most circumstances. It can
1613 -- occur if we call isPredTy during kind checking, especially if one
1614 -- of the following happens:
1615 --
1616 -- 1. There is actually a kind error. Example in which this showed up:
1617 -- polykinds/T11399
1618 --
1619 -- 2. A type constructor application appears to be oversaturated. An
1620 -- example of this occurred in GHC Trac #13187:
1621 --
1622 -- {-# LANGUAGE PolyKinds #-}
1623 -- type Const a b = b
1624 -- f :: Const Int (,) Bool Char -> Char
1625 --
1626 -- We call isPredTy (Const k1 k2 Int (,) Bool Char
1627 -- where k1,k2 are unification variables that have been
1628 -- unified to *, and (*->*->*) resp, /but not zonked/.
1629 -- This shows that isPredTy can report a false negative
1630 -- if a constraint is similarly oversaturated, but
1631 -- it's hard to do better than isPredTy currently does without
1632 -- zonking, so we punt on such cases for now. This only happens
1633 -- during debug-printing, so it doesn't matter.
1634
1635 isClassPred, isEqPred, isNomEqPred, isIPPred :: PredType -> Bool
1636 isClassPred ty = case tyConAppTyCon_maybe ty of
1637 Just tyCon | isClassTyCon tyCon -> True
1638 _ -> False
1639 isEqPred ty = case tyConAppTyCon_maybe ty of
1640 Just tyCon -> tyCon `hasKey` eqPrimTyConKey
1641 || tyCon `hasKey` eqReprPrimTyConKey
1642 _ -> False
1643
1644 isNomEqPred ty = case tyConAppTyCon_maybe ty of
1645 Just tyCon -> tyCon `hasKey` eqPrimTyConKey
1646 _ -> False
1647
1648 isIPPred ty = case tyConAppTyCon_maybe ty of
1649 Just tc -> isIPTyCon tc
1650 _ -> False
1651
1652 isIPTyCon :: TyCon -> Bool
1653 isIPTyCon tc = tc `hasKey` ipClassKey
1654 -- Class and its corresponding TyCon have the same Unique
1655
1656 isIPClass :: Class -> Bool
1657 isIPClass cls = cls `hasKey` ipClassKey
1658
1659 isCTupleClass :: Class -> Bool
1660 isCTupleClass cls = isTupleTyCon (classTyCon cls)
1661
1662 isIPPred_maybe :: Type -> Maybe (FastString, Type)
1663 isIPPred_maybe ty =
1664 do (tc,[t1,t2]) <- splitTyConApp_maybe ty
1665 guard (isIPTyCon tc)
1666 x <- isStrLitTy t1
1667 return (x,t2)
1668
1669 {-
1670 Make PredTypes
1671
1672 --------------------- Equality types ---------------------------------
1673 -}
1674
1675 -- | Makes a lifted equality predicate at the given role
1676 mkPrimEqPredRole :: Role -> Type -> Type -> PredType
1677 mkPrimEqPredRole Nominal = mkPrimEqPred
1678 mkPrimEqPredRole Representational = mkReprPrimEqPred
1679 mkPrimEqPredRole Phantom = panic "mkPrimEqPredRole phantom"
1680
1681 -- | Creates a primitive type equality predicate.
1682 -- Invariant: the types are not Coercions
1683 mkPrimEqPred :: Type -> Type -> Type
1684 mkPrimEqPred ty1 ty2
1685 = TyConApp eqPrimTyCon [k1, k2, ty1, ty2]
1686 where
1687 k1 = typeKind ty1
1688 k2 = typeKind ty2
1689
1690 -- | Creates a primite type equality predicate with explicit kinds
1691 mkHeteroPrimEqPred :: Kind -> Kind -> Type -> Type -> Type
1692 mkHeteroPrimEqPred k1 k2 ty1 ty2 = TyConApp eqPrimTyCon [k1, k2, ty1, ty2]
1693
1694 -- | Creates a primitive representational type equality predicate
1695 -- with explicit kinds
1696 mkHeteroReprPrimEqPred :: Kind -> Kind -> Type -> Type -> Type
1697 mkHeteroReprPrimEqPred k1 k2 ty1 ty2
1698 = TyConApp eqReprPrimTyCon [k1, k2, ty1, ty2]
1699
1700 -- | Try to split up a coercion type into the types that it coerces
1701 splitCoercionType_maybe :: Type -> Maybe (Type, Type)
1702 splitCoercionType_maybe ty
1703 = do { (tc, [_, _, ty1, ty2]) <- splitTyConApp_maybe ty
1704 ; guard $ tc `hasKey` eqPrimTyConKey || tc `hasKey` eqReprPrimTyConKey
1705 ; return (ty1, ty2) }
1706
1707 mkReprPrimEqPred :: Type -> Type -> Type
1708 mkReprPrimEqPred ty1 ty2
1709 = TyConApp eqReprPrimTyCon [k1, k2, ty1, ty2]
1710 where
1711 k1 = typeKind ty1
1712 k2 = typeKind ty2
1713
1714 equalityTyCon :: Role -> TyCon
1715 equalityTyCon Nominal = eqPrimTyCon
1716 equalityTyCon Representational = eqReprPrimTyCon
1717 equalityTyCon Phantom = eqPhantPrimTyCon
1718
1719 -- --------------------- Dictionary types ---------------------------------
1720
1721 mkClassPred :: Class -> [Type] -> PredType
1722 mkClassPred clas tys = TyConApp (classTyCon clas) tys
1723
1724 isDictTy :: Type -> Bool
1725 isDictTy = isClassPred
1726
1727 isDictLikeTy :: Type -> Bool
1728 -- Note [Dictionary-like types]
1729 isDictLikeTy ty | Just ty' <- coreView ty = isDictLikeTy ty'
1730 isDictLikeTy ty = case splitTyConApp_maybe ty of
1731 Just (tc, tys) | isClassTyCon tc -> True
1732 | isTupleTyCon tc -> all isDictLikeTy tys
1733 _other -> False
1734
1735 {-
1736 Note [Dictionary-like types]
1737 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1738 Being "dictionary-like" means either a dictionary type or a tuple thereof.
1739 In GHC 6.10 we build implication constraints which construct such tuples,
1740 and if we land up with a binding
1741 t :: (C [a], Eq [a])
1742 t = blah
1743 then we want to treat t as cheap under "-fdicts-cheap" for example.
1744 (Implication constraints are normally inlined, but sadly not if the
1745 occurrence is itself inside an INLINE function! Until we revise the
1746 handling of implication constraints, that is.) This turned out to
1747 be important in getting good arities in DPH code. Example:
1748
1749 class C a
1750 class D a where { foo :: a -> a }
1751 instance C a => D (Maybe a) where { foo x = x }
1752
1753 bar :: (C a, C b) => a -> b -> (Maybe a, Maybe b)
1754 {-# INLINE bar #-}
1755 bar x y = (foo (Just x), foo (Just y))
1756
1757 Then 'bar' should jolly well have arity 4 (two dicts, two args), but
1758 we ended up with something like
1759 bar = __inline_me__ (\d1,d2. let t :: (D (Maybe a), D (Maybe b)) = ...
1760 in \x,y. <blah>)
1761
1762 This is all a bit ad-hoc; eg it relies on knowing that implication
1763 constraints build tuples.
1764
1765
1766 Decomposing PredType
1767 -}
1768
1769 -- | A choice of equality relation. This is separate from the type 'Role'
1770 -- because 'Phantom' does not define a (non-trivial) equality relation.
1771 data EqRel = NomEq | ReprEq
1772 deriving (Eq, Ord)
1773
1774 instance Outputable EqRel where
1775 ppr NomEq = text "nominal equality"
1776 ppr ReprEq = text "representational equality"
1777
1778 eqRelRole :: EqRel -> Role
1779 eqRelRole NomEq = Nominal
1780 eqRelRole ReprEq = Representational
1781
1782 data PredTree = ClassPred Class [Type]
1783 | EqPred EqRel Type Type
1784 | IrredPred PredType
1785
1786 classifyPredType :: PredType -> PredTree
1787 classifyPredType ev_ty = case splitTyConApp_maybe ev_ty of
1788 Just (tc, [_, _, ty1, ty2])
1789 | tc `hasKey` eqReprPrimTyConKey -> EqPred ReprEq ty1 ty2
1790 | tc `hasKey` eqPrimTyConKey -> EqPred NomEq ty1 ty2
1791 Just (tc, tys)
1792 | Just clas <- tyConClass_maybe tc -> ClassPred clas tys
1793 _ -> IrredPred ev_ty
1794
1795 getClassPredTys :: PredType -> (Class, [Type])
1796 getClassPredTys ty = case getClassPredTys_maybe ty of
1797 Just (clas, tys) -> (clas, tys)
1798 Nothing -> pprPanic "getClassPredTys" (ppr ty)
1799
1800 getClassPredTys_maybe :: PredType -> Maybe (Class, [Type])
1801 getClassPredTys_maybe ty = case splitTyConApp_maybe ty of
1802 Just (tc, tys) | Just clas <- tyConClass_maybe tc -> Just (clas, tys)
1803 _ -> Nothing
1804
1805 getEqPredTys :: PredType -> (Type, Type)
1806 getEqPredTys ty
1807 = case splitTyConApp_maybe ty of
1808 Just (tc, [_, _, ty1, ty2])
1809 | tc `hasKey` eqPrimTyConKey
1810 || tc `hasKey` eqReprPrimTyConKey
1811 -> (ty1, ty2)
1812 _ -> pprPanic "getEqPredTys" (ppr ty)
1813
1814 getEqPredTys_maybe :: PredType -> Maybe (Role, Type, Type)
1815 getEqPredTys_maybe ty
1816 = case splitTyConApp_maybe ty of
1817 Just (tc, [_, _, ty1, ty2])
1818 | tc `hasKey` eqPrimTyConKey -> Just (Nominal, ty1, ty2)
1819 | tc `hasKey` eqReprPrimTyConKey -> Just (Representational, ty1, ty2)
1820 _ -> Nothing
1821
1822 getEqPredRole :: PredType -> Role
1823 getEqPredRole ty = eqRelRole (predTypeEqRel ty)
1824
1825 -- | Get the equality relation relevant for a pred type.
1826 predTypeEqRel :: PredType -> EqRel
1827 predTypeEqRel ty
1828 | Just (tc, _) <- splitTyConApp_maybe ty
1829 , tc `hasKey` eqReprPrimTyConKey
1830 = ReprEq
1831 | otherwise
1832 = NomEq
1833
1834 {-
1835 %************************************************************************
1836 %* *
1837 Well-scoped tyvars
1838 * *
1839 ************************************************************************
1840 -}
1841
1842 -- | Do a topological sort on a list of tyvars,
1843 -- so that binders occur before occurrences
1844 -- E.g. given [ a::k, k::*, b::k ]
1845 -- it'll return a well-scoped list [ k::*, a::k, b::k ]
1846 --
1847 -- This is a deterministic sorting operation
1848 -- (that is, doesn't depend on Uniques).
1849 toposortTyVars :: [TyVar] -> [TyVar]
1850 toposortTyVars tvs = reverse $
1851 [ node_payload node | node <- topologicalSortG $
1852 graphFromEdgedVerticesOrd nodes ]
1853 where
1854 var_ids :: VarEnv Int
1855 var_ids = mkVarEnv (zip tvs [1..])
1856
1857 nodes :: [ Node Int TyVar ]
1858 nodes = [ DigraphNode
1859 tv
1860 (lookupVarEnv_NF var_ids tv)
1861 (mapMaybe (lookupVarEnv var_ids)
1862 (tyCoVarsOfTypeList (tyVarKind tv)))
1863 | tv <- tvs ]
1864
1865 -- | Extract a well-scoped list of variables from a deterministic set of
1866 -- variables. The result is deterministic.
1867 -- NB: There used to exist varSetElemsWellScoped :: VarSet -> [Var] which
1868 -- took a non-deterministic set and produced a non-deterministic
1869 -- well-scoped list. If you care about the list being well-scoped you also
1870 -- most likely care about it being in deterministic order.
1871 dVarSetElemsWellScoped :: DVarSet -> [Var]
1872 dVarSetElemsWellScoped = toposortTyVars . dVarSetElems
1873
1874 -- | Get the free vars of a type in scoped order
1875 tyCoVarsOfTypeWellScoped :: Type -> [TyVar]
1876 tyCoVarsOfTypeWellScoped = toposortTyVars . tyCoVarsOfTypeList
1877
1878 -- | Get the free vars of types in scoped order
1879 tyCoVarsOfTypesWellScoped :: [Type] -> [TyVar]
1880 tyCoVarsOfTypesWellScoped = toposortTyVars . tyCoVarsOfTypesList
1881
1882 {-
1883 ************************************************************************
1884 * *
1885 \subsection{Type families}
1886 * *
1887 ************************************************************************
1888 -}
1889
1890 mkFamilyTyConApp :: TyCon -> [Type] -> Type
1891 -- ^ Given a family instance TyCon and its arg types, return the
1892 -- corresponding family type. E.g:
1893 --
1894 -- > data family T a
1895 -- > data instance T (Maybe b) = MkT b
1896 --
1897 -- Where the instance tycon is :RTL, so:
1898 --
1899 -- > mkFamilyTyConApp :RTL Int = T (Maybe Int)
1900 mkFamilyTyConApp tc tys
1901 | Just (fam_tc, fam_tys) <- tyConFamInst_maybe tc
1902 , let tvs = tyConTyVars tc
1903 fam_subst = ASSERT2( length tvs == length tys, ppr tc <+> ppr tys )
1904 zipTvSubst tvs tys
1905 = mkTyConApp fam_tc (substTys fam_subst fam_tys)
1906 | otherwise
1907 = mkTyConApp tc tys
1908
1909 -- | Get the type on the LHS of a coercion induced by a type/data
1910 -- family instance.
1911 coAxNthLHS :: CoAxiom br -> Int -> Type
1912 coAxNthLHS ax ind =
1913 mkTyConApp (coAxiomTyCon ax) (coAxBranchLHS (coAxiomNthBranch ax ind))
1914
1915 -- | Pretty prints a 'TyCon', using the family instance in case of a
1916 -- representation tycon. For example:
1917 --
1918 -- > data T [a] = ...
1919 --
1920 -- In that case we want to print @T [a]@, where @T@ is the family 'TyCon'
1921 pprSourceTyCon :: TyCon -> SDoc
1922 pprSourceTyCon tycon
1923 | Just (fam_tc, tys) <- tyConFamInst_maybe tycon
1924 = ppr $ fam_tc `TyConApp` tys -- can't be FunTyCon
1925 | otherwise
1926 = ppr tycon
1927
1928 -- @isTauTy@ tests if a type has no foralls
1929 isFamFreeTy :: Type -> Bool
1930 isFamFreeTy ty | Just ty' <- coreView ty = isFamFreeTy ty'
1931 isFamFreeTy (TyVarTy _) = True
1932 isFamFreeTy (LitTy {}) = True
1933 isFamFreeTy (TyConApp tc tys) = all isFamFreeTy tys && isFamFreeTyCon tc
1934 isFamFreeTy (AppTy a b) = isFamFreeTy a && isFamFreeTy b
1935 isFamFreeTy (FunTy a b) = isFamFreeTy a && isFamFreeTy b
1936 isFamFreeTy (ForAllTy _ ty) = isFamFreeTy ty
1937 isFamFreeTy (CastTy ty _) = isFamFreeTy ty
1938 isFamFreeTy (CoercionTy _) = False -- Not sure about this
1939
1940 {-
1941 ************************************************************************
1942 * *
1943 \subsection{Liftedness}
1944 * *
1945 ************************************************************************
1946 -}
1947
1948 -- | Returns Just True if this type is surely lifted, Just False
1949 -- if it is surely unlifted, Nothing if we can't be sure (i.e., it is
1950 -- levity polymorphic), and panics if the kind does not have the shape
1951 -- TYPE r.
1952 isLiftedType_maybe :: HasDebugCallStack => Type -> Maybe Bool
1953 isLiftedType_maybe ty = go (getRuntimeRep "isLiftedType_maybe" ty)
1954 where
1955 go rr | Just rr' <- coreView rr = go rr'
1956 go (TyConApp lifted_rep [])
1957 | lifted_rep `hasKey` liftedRepDataConKey = Just True
1958 go (TyConApp {}) = Just False -- everything else is unlifted
1959 go _ = Nothing -- levity polymorphic
1960
1961 -- | See "Type#type_classification" for what an unlifted type is.
1962 -- Panics on levity polymorphic types.
1963 isUnliftedType :: HasDebugCallStack => Type -> Bool
1964 -- isUnliftedType returns True for forall'd unlifted types:
1965 -- x :: forall a. Int#
1966 -- I found bindings like these were getting floated to the top level.
1967 -- They are pretty bogus types, mind you. It would be better never to
1968 -- construct them
1969 isUnliftedType ty
1970 = not (isLiftedType_maybe ty `orElse`
1971 pprPanic "isUnliftedType" (ppr ty <+> dcolon <+> ppr (typeKind ty)))
1972
1973 -- | Extract the RuntimeRep classifier of a type. For instance,
1974 -- @getRuntimeRep_maybe Int = LiftedRep@. Returns 'Nothing' if this is not
1975 -- possible.
1976 getRuntimeRep_maybe :: HasDebugCallStack
1977 => Type -> Maybe Type
1978 getRuntimeRep_maybe = getRuntimeRepFromKind_maybe . typeKind
1979
1980 -- | Extract the RuntimeRep classifier of a type. For instance,
1981 -- @getRuntimeRep_maybe Int = LiftedRep@. Panics if this is not possible.
1982 getRuntimeRep :: HasDebugCallStack
1983 => String -- ^ Printed in case of an error
1984 -> Type -> Type
1985 getRuntimeRep err ty =
1986 case getRuntimeRep_maybe ty of
1987 Just r -> r
1988 Nothing -> pprPanic "getRuntimeRep"
1989 (text err $$ ppr ty <+> dcolon <+> ppr (typeKind ty))
1990
1991 -- | Extract the RuntimeRep classifier of a type from its kind. For example,
1992 -- @getRuntimeRepFromKind * = LiftedRep@; Panics if this is not possible.
1993 getRuntimeRepFromKind :: HasDebugCallStack
1994 => String -> Type -> Type
1995 getRuntimeRepFromKind err k =
1996 case getRuntimeRepFromKind_maybe k of
1997 Just r -> r
1998 Nothing -> pprPanic "getRuntimeRepFromKind"
1999 (text err $$ ppr k <+> dcolon <+> ppr (typeKind k))
2000
2001 -- | Extract the RuntimeRep classifier of a type from its kind. For example,
2002 -- @getRuntimeRepFromKind * = LiftedRep@; Returns 'Nothing' if this is not
2003 -- possible.
2004 getRuntimeRepFromKind_maybe :: HasDebugCallStack
2005 => Type -> Maybe Type
2006 getRuntimeRepFromKind_maybe = go
2007 where
2008 go k | Just k' <- coreView k = go k'
2009 go k
2010 | Just (_tc, [arg]) <- splitTyConApp_maybe k
2011 = ASSERT2( _tc `hasKey` tYPETyConKey, ppr k )
2012 Just arg
2013 go _ = Nothing
2014
2015 isUnboxedTupleType :: Type -> Bool
2016 isUnboxedTupleType ty
2017 = tyConAppTyCon (getRuntimeRep "isUnboxedTupleType" ty) `hasKey` tupleRepDataConKey
2018 -- NB: Do not use typePrimRep, as that can't tell the difference between
2019 -- unboxed tuples and unboxed sums
2020
2021
2022 isUnboxedSumType :: Type -> Bool
2023 isUnboxedSumType ty
2024 = tyConAppTyCon (getRuntimeRep "isUnboxedSumType" ty) `hasKey` sumRepDataConKey
2025
2026 -- | See "Type#type_classification" for what an algebraic type is.
2027 -- Should only be applied to /types/, as opposed to e.g. partially
2028 -- saturated type constructors
2029 isAlgType :: Type -> Bool
2030 isAlgType ty
2031 = case splitTyConApp_maybe ty of
2032 Just (tc, ty_args) -> ASSERT( ty_args `lengthIs` tyConArity tc )
2033 isAlgTyCon tc
2034 _other -> False
2035
2036 -- | See "Type#type_classification" for what an algebraic type is.
2037 -- Should only be applied to /types/, as opposed to e.g. partially
2038 -- saturated type constructors. Closed type constructors are those
2039 -- with a fixed right hand side, as opposed to e.g. associated types
2040 isClosedAlgType :: Type -> Bool
2041 isClosedAlgType ty
2042 = case splitTyConApp_maybe ty of
2043 Just (tc, ty_args) | isAlgTyCon tc && not (isFamilyTyCon tc)
2044 -> ASSERT2( ty_args `lengthIs` tyConArity tc, ppr ty ) True
2045 _other -> False
2046
2047 -- | Check whether a type is a data family type
2048 isDataFamilyAppType :: Type -> Bool
2049 isDataFamilyAppType ty = case tyConAppTyCon_maybe ty of
2050 Just tc -> isDataFamilyTyCon tc
2051 _ -> False
2052
2053 -- | Computes whether an argument (or let right hand side) should
2054 -- be computed strictly or lazily, based only on its type.
2055 -- Currently, it's just 'isUnliftedType'. Panics on levity-polymorphic types.
2056 isStrictType :: HasDebugCallStack => Type -> Bool
2057 isStrictType = isUnliftedType
2058
2059 isPrimitiveType :: Type -> Bool
2060 -- ^ Returns true of types that are opaque to Haskell.
2061 isPrimitiveType ty = case splitTyConApp_maybe ty of
2062 Just (tc, ty_args) -> ASSERT( ty_args `lengthIs` tyConArity tc )
2063 isPrimTyCon tc
2064 _ -> False
2065
2066 {-
2067 ************************************************************************
2068 * *
2069 \subsection{Join points}
2070 * *
2071 ************************************************************************
2072 -}
2073
2074 -- | Determine whether a type could be the type of a join point of given total
2075 -- arity, according to the polymorphism rule. A join point cannot be polymorphic
2076 -- in its return type, since given
2077 -- join j @a @b x y z = e1 in e2,
2078 -- the types of e1 and e2 must be the same, and a and b are not in scope for e2.
2079 -- (See Note [The polymorphism rule of join points] in CoreSyn.) Returns False
2080 -- also if the type simply doesn't have enough arguments.
2081 --
2082 -- Note that we need to know how many arguments (type *and* value) the putative
2083 -- join point takes; for instance, if
2084 -- j :: forall a. a -> Int
2085 -- then j could be a binary join point returning an Int, but it could *not* be a
2086 -- unary join point returning a -> Int.
2087 --
2088 -- TODO: See Note [Excess polymorphism and join points]
2089 isValidJoinPointType :: JoinArity -> Type -> Bool
2090 isValidJoinPointType arity ty
2091 = valid_under emptyVarSet arity ty
2092 where
2093 valid_under tvs arity ty
2094 | arity == 0
2095 = isEmptyVarSet (tvs `intersectVarSet` tyCoVarsOfType ty)
2096 | Just (t, ty') <- splitForAllTy_maybe ty
2097 = valid_under (tvs `extendVarSet` t) (arity-1) ty'
2098 | Just (_, res_ty) <- splitFunTy_maybe ty
2099 = valid_under tvs (arity-1) res_ty
2100 | otherwise
2101 = False
2102
2103 {-
2104 ************************************************************************
2105 * *
2106 \subsection{Sequencing on types}
2107 * *
2108 ************************************************************************
2109 -}
2110
2111 seqType :: Type -> ()
2112 seqType (LitTy n) = n `seq` ()
2113 seqType (TyVarTy tv) = tv `seq` ()
2114 seqType (AppTy t1 t2) = seqType t1 `seq` seqType t2
2115 seqType (FunTy t1 t2) = seqType t1 `seq` seqType t2
2116 seqType (TyConApp tc tys) = tc `seq` seqTypes tys
2117 seqType (ForAllTy (TvBndr tv _) ty) = seqType (tyVarKind tv) `seq` seqType ty
2118 seqType (CastTy ty co) = seqType ty `seq` seqCo co
2119 seqType (CoercionTy co) = seqCo co
2120
2121 seqTypes :: [Type] -> ()
2122 seqTypes [] = ()
2123 seqTypes (ty:tys) = seqType ty `seq` seqTypes tys
2124
2125 {-
2126 ************************************************************************
2127 * *
2128 Comparison for types
2129 (We don't use instances so that we know where it happens)
2130 * *
2131 ************************************************************************
2132
2133 Note [Equality on AppTys]
2134 ~~~~~~~~~~~~~~~~~~~~~~~~~
2135 In our cast-ignoring equality, we want to say that the following two
2136 are equal:
2137
2138 (Maybe |> co) (Int |> co') ~? Maybe Int
2139
2140 But the left is an AppTy while the right is a TyConApp. The solution is
2141 to use repSplitAppTy_maybe to break up the TyConApp into its pieces and
2142 then continue. Easy to do, but also easy to forget to do.
2143
2144 -}
2145
2146 eqType :: Type -> Type -> Bool
2147 -- ^ Type equality on source types. Does not look through @newtypes@ or
2148 -- 'PredType's, but it does look through type synonyms.
2149 -- This first checks that the kinds of the types are equal and then
2150 -- checks whether the types are equal, ignoring casts and coercions.
2151 -- (The kind check is a recursive call, but since all kinds have type
2152 -- @Type@, there is no need to check the types of kinds.)
2153 -- See also Note [Non-trivial definitional equality] in TyCoRep.
2154 eqType t1 t2 = isEqual $ nonDetCmpType t1 t2
2155 -- It's OK to use nonDetCmpType here and eqType is deterministic,
2156 -- nonDetCmpType does equality deterministically
2157
2158 -- | Compare types with respect to a (presumably) non-empty 'RnEnv2'.
2159 eqTypeX :: RnEnv2 -> Type -> Type -> Bool
2160 eqTypeX env t1 t2 = isEqual $ nonDetCmpTypeX env t1 t2
2161 -- It's OK to use nonDetCmpType here and eqTypeX is deterministic,
2162 -- nonDetCmpTypeX does equality deterministically
2163
2164 -- | Type equality on lists of types, looking through type synonyms
2165 -- but not newtypes.
2166 eqTypes :: [Type] -> [Type] -> Bool
2167 eqTypes tys1 tys2 = isEqual $ nonDetCmpTypes tys1 tys2
2168 -- It's OK to use nonDetCmpType here and eqTypes is deterministic,
2169 -- nonDetCmpTypes does equality deterministically
2170
2171 eqVarBndrs :: RnEnv2 -> [Var] -> [Var] -> Maybe RnEnv2
2172 -- Check that the var lists are the same length
2173 -- and have matching kinds; if so, extend the RnEnv2
2174 -- Returns Nothing if they don't match
2175 eqVarBndrs env [] []
2176 = Just env
2177 eqVarBndrs env (tv1:tvs1) (tv2:tvs2)
2178 | eqTypeX env (tyVarKind tv1) (tyVarKind tv2)
2179 = eqVarBndrs (rnBndr2 env tv1 tv2) tvs1 tvs2
2180 eqVarBndrs _ _ _= Nothing
2181
2182 -- Now here comes the real worker
2183
2184 {-
2185 Note [nonDetCmpType nondeterminism]
2186 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2187 nonDetCmpType is implemented in terms of nonDetCmpTypeX. nonDetCmpTypeX
2188 uses nonDetCmpTc which compares TyCons by their Unique value. Using Uniques for
2189 ordering leads to nondeterminism. We hit the same problem in the TyVarTy case,
2190 comparing type variables is nondeterministic, note the call to nonDetCmpVar in
2191 nonDetCmpTypeX.
2192 See Note [Unique Determinism] for more details.
2193 -}
2194
2195 nonDetCmpType :: Type -> Type -> Ordering
2196 nonDetCmpType t1 t2
2197 -- we know k1 and k2 have the same kind, because they both have kind *.
2198 = nonDetCmpTypeX rn_env t1 t2
2199 where
2200 rn_env = mkRnEnv2 (mkInScopeSet (tyCoVarsOfTypes [t1, t2]))
2201
2202 nonDetCmpTypes :: [Type] -> [Type] -> Ordering
2203 nonDetCmpTypes ts1 ts2 = nonDetCmpTypesX rn_env ts1 ts2
2204 where
2205 rn_env = mkRnEnv2 (mkInScopeSet (tyCoVarsOfTypes (ts1 ++ ts2)))
2206
2207 -- | An ordering relation between two 'Type's (known below as @t1 :: k1@
2208 -- and @t2 :: k2@)
2209 data TypeOrdering = TLT -- ^ @t1 < t2@
2210 | TEQ -- ^ @t1 ~ t2@ and there are no casts in either,
2211 -- therefore we can conclude @k1 ~ k2@
2212 | TEQX -- ^ @t1 ~ t2@ yet one of the types contains a cast so
2213 -- they may differ in kind.
2214 | TGT -- ^ @t1 > t2@
2215 deriving (Eq, Ord, Enum, Bounded)
2216
2217 nonDetCmpTypeX :: RnEnv2 -> Type -> Type -> Ordering -- Main workhorse
2218 -- See Note [Non-trivial definitional equality] in TyCoRep
2219 nonDetCmpTypeX env orig_t1 orig_t2 =
2220 case go env orig_t1 orig_t2 of
2221 -- If there are casts then we also need to do a comparison of the kinds of
2222 -- the types being compared
2223 TEQX -> toOrdering $ go env k1 k2
2224 ty_ordering -> toOrdering ty_ordering
2225 where
2226 k1 = typeKind orig_t1
2227 k2 = typeKind orig_t2
2228
2229 toOrdering :: TypeOrdering -> Ordering
2230 toOrdering TLT = LT
2231 toOrdering TEQ = EQ
2232 toOrdering TEQX = EQ
2233 toOrdering TGT = GT
2234
2235 liftOrdering :: Ordering -> TypeOrdering
2236 liftOrdering LT = TLT
2237 liftOrdering EQ = TEQ
2238 liftOrdering GT = TGT
2239
2240 thenCmpTy :: TypeOrdering -> TypeOrdering -> TypeOrdering
2241 thenCmpTy TEQ rel = rel
2242 thenCmpTy TEQX rel = hasCast rel
2243 thenCmpTy rel _ = rel
2244
2245 hasCast :: TypeOrdering -> TypeOrdering
2246 hasCast TEQ = TEQX
2247 hasCast rel = rel
2248
2249 -- Returns both the resulting ordering relation between the two types
2250 -- and whether either contains a cast.
2251 go :: RnEnv2 -> Type -> Type -> TypeOrdering
2252 go env t1 t2
2253 | Just t1' <- coreView t1 = go env t1' t2
2254 | Just t2' <- coreView t2 = go env t1 t2'
2255
2256 go env (TyVarTy tv1) (TyVarTy tv2)
2257 = liftOrdering $ rnOccL env tv1 `nonDetCmpVar` rnOccR env tv2
2258 go env (ForAllTy (TvBndr tv1 _) t1) (ForAllTy (TvBndr tv2 _) t2)
2259 = go env (tyVarKind tv1) (tyVarKind tv2)
2260 `thenCmpTy` go (rnBndr2 env tv1 tv2) t1 t2
2261 -- See Note [Equality on AppTys]
2262 go env (AppTy s1 t1) ty2
2263 | Just (s2, t2) <- repSplitAppTy_maybe ty2
2264 = go env s1 s2 `thenCmpTy` go env t1 t2
2265 go env ty1 (AppTy s2 t2)
2266 | Just (s1, t1) <- repSplitAppTy_maybe ty1
2267 = go env s1 s2 `thenCmpTy` go env t1 t2
2268 go env (FunTy s1 t1) (FunTy s2 t2)
2269 = go env s1 s2 `thenCmpTy` go env t1 t2
2270 go env (TyConApp tc1 tys1) (TyConApp tc2 tys2)
2271 = liftOrdering (tc1 `nonDetCmpTc` tc2) `thenCmpTy` gos env tys1 tys2
2272 go _ (LitTy l1) (LitTy l2) = liftOrdering (compare l1 l2)
2273 go env (CastTy t1 _) t2 = hasCast $ go env t1 t2
2274 go env t1 (CastTy t2 _) = hasCast $ go env t1 t2
2275
2276 go _ (CoercionTy {}) (CoercionTy {}) = TEQ
2277
2278 -- Deal with the rest: TyVarTy < CoercionTy < AppTy < LitTy < TyConApp < ForAllTy
2279 go _ ty1 ty2
2280 = liftOrdering $ (get_rank ty1) `compare` (get_rank ty2)
2281 where get_rank :: Type -> Int
2282 get_rank (CastTy {})
2283 = pprPanic "nonDetCmpTypeX.get_rank" (ppr [ty1,ty2])
2284 get_rank (TyVarTy {}) = 0
2285 get_rank (CoercionTy {}) = 1
2286 get_rank (AppTy {}) = 3
2287 get_rank (LitTy {}) = 4
2288 get_rank (TyConApp {}) = 5
2289 get_rank (FunTy {}) = 6
2290 get_rank (ForAllTy {}) = 7
2291
2292 gos :: RnEnv2 -> [Type] -> [Type] -> TypeOrdering
2293 gos _ [] [] = TEQ
2294 gos _ [] _ = TLT
2295 gos _ _ [] = TGT
2296 gos env (ty1:tys1) (ty2:tys2) = go env ty1 ty2 `thenCmpTy` gos env tys1 tys2
2297
2298 -------------
2299 nonDetCmpTypesX :: RnEnv2 -> [Type] -> [Type] -> Ordering
2300 nonDetCmpTypesX _ [] [] = EQ
2301 nonDetCmpTypesX env (t1:tys1) (t2:tys2) = nonDetCmpTypeX env t1 t2
2302 `thenCmp` nonDetCmpTypesX env tys1 tys2
2303 nonDetCmpTypesX _ [] _ = LT
2304 nonDetCmpTypesX _ _ [] = GT
2305
2306 -------------
2307 -- | Compare two 'TyCon's. NB: This should /never/ see the "star synonyms",
2308 -- as recognized by Kind.isStarKindSynonymTyCon. See Note
2309 -- [Kind Constraint and kind *] in Kind.
2310 -- See Note [nonDetCmpType nondeterminism]
2311 nonDetCmpTc :: TyCon -> TyCon -> Ordering
2312 nonDetCmpTc tc1 tc2
2313 = ASSERT( not (isStarKindSynonymTyCon tc1) && not (isStarKindSynonymTyCon tc2) )
2314 u1 `nonDetCmpUnique` u2
2315 where
2316 u1 = tyConUnique tc1
2317 u2 = tyConUnique tc2
2318
2319 {-
2320 ************************************************************************
2321 * *
2322 The kind of a type
2323 * *
2324 ************************************************************************
2325 -}
2326
2327 typeKind :: Type -> Kind
2328 typeKind (TyConApp tc tys) = piResultTys (tyConKind tc) tys
2329 typeKind (AppTy fun arg) = piResultTy (typeKind fun) arg
2330 typeKind (LitTy l) = typeLiteralKind l
2331 typeKind (FunTy {}) = liftedTypeKind
2332 typeKind (ForAllTy _ ty) = typeKind ty
2333 typeKind (TyVarTy tyvar) = tyVarKind tyvar
2334 typeKind (CastTy _ty co) = pSnd $ coercionKind co
2335 typeKind (CoercionTy co) = coercionType co
2336
2337 typeLiteralKind :: TyLit -> Kind
2338 typeLiteralKind l =
2339 case l of
2340 NumTyLit _ -> typeNatKind
2341 StrTyLit _ -> typeSymbolKind
2342
2343 -- | Returns True if a type is levity polymorphic. Should be the same
2344 -- as (isKindLevPoly . typeKind) but much faster.
2345 -- Precondition: The type has kind (TYPE blah)
2346 isTypeLevPoly :: Type -> Bool
2347 isTypeLevPoly = go
2348 where
2349 go ty@(TyVarTy {}) = check_kind ty
2350 go ty@(AppTy {}) = check_kind ty
2351 go ty@(TyConApp tc _) | not (isTcLevPoly tc) = False
2352 | otherwise = check_kind ty
2353 go (ForAllTy _ ty) = go ty
2354 go (FunTy {}) = False
2355 go (LitTy {}) = False
2356 go ty@(CastTy {}) = check_kind ty
2357 go ty@(CoercionTy {}) = pprPanic "isTypeLevPoly co" (ppr ty)
2358
2359 check_kind = isKindLevPoly . typeKind
2360
2361 -- | Looking past all pi-types, is the end result potentially levity polymorphic?
2362 -- Example: True for (forall r (a :: TYPE r). String -> a)
2363 -- Example: False for (forall r1 r2 (a :: TYPE r1) (b :: TYPE r2). a -> b -> Type)
2364 resultIsLevPoly :: Type -> Bool
2365 resultIsLevPoly = isTypeLevPoly . snd . splitPiTys
2366
2367 {-
2368 %************************************************************************
2369 %* *
2370 Miscellaneous functions
2371 %* *
2372 %************************************************************************
2373
2374 -}
2375 -- | All type constructors occurring in the type; looking through type
2376 -- synonyms, but not newtypes.
2377 -- When it finds a Class, it returns the class TyCon.
2378 tyConsOfType :: Type -> UniqSet TyCon
2379 tyConsOfType ty
2380 = go ty
2381 where
2382 go :: Type -> UniqSet TyCon -- The UniqSet does duplicate elim
2383 go ty | Just ty' <- coreView ty = go ty'
2384 go (TyVarTy {}) = emptyUniqSet
2385 go (LitTy {}) = emptyUniqSet
2386 go (TyConApp tc tys) = go_tc tc `unionUniqSets` go_s tys
2387 go (AppTy a b) = go a `unionUniqSets` go b
2388 go (FunTy a b) = go a `unionUniqSets` go b `unionUniqSets` go_tc funTyCon
2389 go (ForAllTy (TvBndr tv _) ty) = go ty `unionUniqSets` go (tyVarKind tv)
2390 go (CastTy ty co) = go ty `unionUniqSets` go_co co
2391 go (CoercionTy co) = go_co co
2392
2393 go_co (Refl _ ty) = go ty
2394 go_co (TyConAppCo _ tc args) = go_tc tc `unionUniqSets` go_cos args
2395 go_co (AppCo co arg) = go_co co `unionUniqSets` go_co arg
2396 go_co (ForAllCo _ kind_co co) = go_co kind_co `unionUniqSets` go_co co
2397 go_co (FunCo _ co1 co2) = go_co co1 `unionUniqSets` go_co co2
2398 go_co (AxiomInstCo ax _ args) = go_ax ax `unionUniqSets` go_cos args
2399 go_co (UnivCo p _ t1 t2) = go_prov p `unionUniqSets` go t1 `unionUniqSets` go t2
2400 go_co (CoVarCo {}) = emptyUniqSet
2401 go_co (SymCo co) = go_co co
2402 go_co (TransCo co1 co2) = go_co co1 `unionUniqSets` go_co co2
2403 go_co (NthCo _ co) = go_co co
2404 go_co (LRCo _ co) = go_co co
2405 go_co (InstCo co arg) = go_co co `unionUniqSets` go_co arg
2406 go_co (CoherenceCo co1 co2) = go_co co1 `unionUniqSets` go_co co2
2407 go_co (KindCo co) = go_co co
2408 go_co (SubCo co) = go_co co
2409 go_co (AxiomRuleCo _ cs) = go_cos cs
2410
2411 go_prov UnsafeCoerceProv = emptyUniqSet
2412 go_prov (PhantomProv co) = go_co co
2413 go_prov (ProofIrrelProv co) = go_co co
2414 go_prov (PluginProv _) = emptyUniqSet
2415 go_prov (HoleProv _) = emptyUniqSet
2416 -- this last case can happen from the tyConsOfType used from
2417 -- checkTauTvUpdate
2418
2419 go_s tys = foldr (unionUniqSets . go) emptyUniqSet tys
2420 go_cos cos = foldr (unionUniqSets . go_co) emptyUniqSet cos
2421
2422 go_tc tc = unitUniqSet tc
2423 go_ax ax = go_tc $ coAxiomTyCon ax
2424
2425 -- | Find the result 'Kind' of a type synonym,
2426 -- after applying it to its 'arity' number of type variables
2427 -- Actually this function works fine on data types too,
2428 -- but they'd always return '*', so we never need to ask
2429 synTyConResKind :: TyCon -> Kind
2430 synTyConResKind tycon = piResultTys (tyConKind tycon) (mkTyVarTys (tyConTyVars tycon))
2431
2432 -- | Retrieve the free variables in this type, splitting them based
2433 -- on whether they are used visibly or invisibly. Invisible ones come
2434 -- first.
2435 splitVisVarsOfType :: Type -> Pair TyCoVarSet
2436 splitVisVarsOfType orig_ty = Pair invis_vars vis_vars
2437 where
2438 Pair invis_vars1 vis_vars = go orig_ty
2439 invis_vars = invis_vars1 `minusVarSet` vis_vars
2440
2441 go (TyVarTy tv) = Pair (tyCoVarsOfType $ tyVarKind tv) (unitVarSet tv)
2442 go (AppTy t1 t2) = go t1 `mappend` go t2
2443 go (TyConApp tc tys) = go_tc tc tys
2444 go (FunTy t1 t2) = go t1 `mappend` go t2
2445 go (ForAllTy (TvBndr tv _) ty)
2446 = ((`delVarSet` tv) <$> go ty) `mappend`
2447 (invisible (tyCoVarsOfType $ tyVarKind tv))
2448 go (LitTy {}) = mempty
2449 go (CastTy ty co) = go ty `mappend` invisible (tyCoVarsOfCo co)
2450 go (CoercionTy co) = invisible $ tyCoVarsOfCo co
2451
2452 invisible vs = Pair vs emptyVarSet
2453
2454 go_tc tc tys = let (invis, vis) = partitionInvisibles tc id tys in
2455 invisible (tyCoVarsOfTypes invis) `mappend` foldMap go vis
2456
2457 splitVisVarsOfTypes :: [Type] -> Pair TyCoVarSet
2458 splitVisVarsOfTypes = foldMap splitVisVarsOfType
2459
2460 modifyJoinResTy :: Int -- Number of binders to skip
2461 -> (Type -> Type) -- Function to apply to result type
2462 -> Type -- Type of join point
2463 -> Type -- New type
2464 -- INVARIANT: If any of the first n binders are foralls, those tyvars cannot
2465 -- appear in the original result type. See isValidJoinPointType.
2466 modifyJoinResTy orig_ar f orig_ty
2467 = go orig_ar orig_ty
2468 where
2469 go 0 ty = f ty
2470 go n ty | Just (arg_bndr, res_ty) <- splitPiTy_maybe ty
2471 = mkPiTy arg_bndr (go (n-1) res_ty)
2472 | otherwise
2473 = pprPanic "modifyJoinResTy" (ppr orig_ar <+> ppr orig_ty)
2474
2475 setJoinResTy :: Int -- Number of binders to skip
2476 -> Type -- New result type
2477 -> Type -- Type of join point
2478 -> Type -- New type
2479 -- INVARIANT: Same as for modifyJoinResTy
2480 setJoinResTy ar new_res_ty ty
2481 = modifyJoinResTy ar (const new_res_ty) ty