Merge branch 'master' of darcs.haskell.org:/home/darcs/ghc
[ghc.git] / compiler / ghci / ByteCodeItbls.lhs
1 %
2 % (c) The University of Glasgow 2000-2006
3 %
4 ByteCodeItbls: Generate infotables for interpreter-made bytecodes
5
6 \begin{code}
7 {-# OPTIONS -optc-DNON_POSIX_SOURCE #-}
8
9 #ifndef GHCI_TABLES_NEXT_TO_CODE
10 {-# OPTIONS_GHC -Wwarn #-}
11 -- There are lots of warnings when GHCI_TABLES_NEXT_TO_CODE is off.
12 -- It would be nice to fix this properly, but for now we turn -Werror
13 -- off.
14 #endif
15
16 module ByteCodeItbls ( ItblEnv, ItblPtr(..), itblCode, mkITbls
17                      , StgInfoTable(..)
18                      , State(..), runState, evalState, execState, MonadT(..)
19                      ) where
20
21 #include "HsVersions.h"
22
23 import DynFlags
24 import Name             ( Name, getName )
25 import NameEnv
26 import ClosureInfo
27 import DataCon          ( DataCon, dataConRepArgTys, dataConIdentity )
28 import TyCon            ( TyCon, tyConFamilySize, isDataTyCon, tyConDataCons )
29 import Type             ( flattenRepType, repType )
30 import CgHeapery        ( mkVirtHeapOffsets )
31 import Util
32
33 import Foreign
34 import Foreign.C
35
36 import Control.Monad    ( liftM )
37
38 import GHC.Exts         ( Int(I#), addr2Int# )
39 import GHC.Ptr          ( Ptr(..) )
40 \end{code}
41
42 %************************************************************************
43 %*                                                                      *
44 \subsection{Manufacturing of info tables for DataCons}
45 %*                                                                      *
46 %************************************************************************
47
48 \begin{code}
49 newtype ItblPtr = ItblPtr (Ptr ()) deriving Show
50
51 itblCode :: DynFlags -> ItblPtr -> Ptr ()
52 itblCode dflags (ItblPtr ptr)
53  | ghciTablesNextToCode = castPtr ptr `plusPtr` conInfoTableSizeB dflags
54  | otherwise            = castPtr ptr
55
56 -- XXX bogus
57 conInfoTableSizeB :: DynFlags -> Int
58 conInfoTableSizeB dflags = 3 * wORD_SIZE dflags
59
60 type ItblEnv = NameEnv (Name, ItblPtr)
61         -- We need the Name in the range so we know which
62         -- elements to filter out when unloading a module
63
64 mkItblEnv :: [(Name,ItblPtr)] -> ItblEnv
65 mkItblEnv pairs = mkNameEnv [(n, (n,p)) | (n,p) <- pairs]
66
67
68 -- Make info tables for the data decls in this module
69 mkITbls :: DynFlags -> [TyCon] -> IO ItblEnv
70 mkITbls _ [] = return emptyNameEnv
71 mkITbls dflags (tc:tcs) = do itbls  <- mkITbl dflags tc
72                              itbls2 <- mkITbls dflags tcs
73                              return (itbls `plusNameEnv` itbls2)
74
75 mkITbl :: DynFlags -> TyCon -> IO ItblEnv
76 mkITbl dflags tc
77    | not (isDataTyCon tc) 
78    = return emptyNameEnv
79    | dcs `lengthIs` n -- paranoia; this is an assertion.
80    = make_constr_itbls dflags dcs
81      where
82         dcs = tyConDataCons tc
83         n   = tyConFamilySize tc
84
85 mkITbl _ _ = error "Unmatched patter in mkITbl: assertion failed!"
86
87 #include "../includes/rts/storage/ClosureTypes.h"
88 cONSTR :: Int   -- Defined in ClosureTypes.h
89 cONSTR = CONSTR 
90
91 -- Assumes constructors are numbered from zero, not one
92 make_constr_itbls :: DynFlags -> [DataCon] -> IO ItblEnv
93 make_constr_itbls dflags cons
94    = do is <- mapM mk_dirret_itbl (zip cons [0..])
95         return (mkItblEnv is)
96      where
97         mk_dirret_itbl (dcon, conNo)
98            = mk_itbl dcon conNo stg_interp_constr_entry
99
100         mk_itbl :: DataCon -> Int -> Ptr () -> IO (Name,ItblPtr)
101         mk_itbl dcon conNo entry_addr = do
102            let rep_args = [ (typeCgRep rep_arg,rep_arg) | arg <- dataConRepArgTys dcon, rep_arg <- flattenRepType (repType arg) ]
103                (tot_wds, ptr_wds, _) = mkVirtHeapOffsets dflags False{-not a THUNK-} rep_args
104
105                ptrs'  = ptr_wds
106                nptrs' = tot_wds - ptr_wds
107                nptrs_really
108                   | ptrs' + nptrs' >= mIN_PAYLOAD_SIZE dflags = nptrs'
109                   | otherwise = mIN_PAYLOAD_SIZE dflags - ptrs'
110                code' = mkJumpToAddr entry_addr
111                itbl  = StgInfoTable {
112 #ifndef GHCI_TABLES_NEXT_TO_CODE
113                            entry = entry_addr,
114 #endif
115                            ptrs  = fromIntegral ptrs', 
116                            nptrs = fromIntegral nptrs_really,
117                            tipe  = fromIntegral cONSTR,
118                            srtlen = fromIntegral conNo
119 #ifdef GHCI_TABLES_NEXT_TO_CODE
120                          , code  = code'
121 #endif
122                         }
123            qNameCString <- newArray0 0 $ dataConIdentity dcon 
124            let conInfoTbl = StgConInfoTable {
125                                  conDesc = qNameCString,
126                                  infoTable = itbl
127                             }
128                -- Make a piece of code to jump to "entry_label".
129                -- This is the only arch-dependent bit.
130            addrCon <- newExecConItbl dflags conInfoTbl
131                     --putStrLn ("SIZE of itbl is " ++ show (sizeOf itbl))
132                     --putStrLn ("# ptrs  of itbl is " ++ show ptrs)
133                     --putStrLn ("# nptrs of itbl is " ++ show nptrs_really)
134            return (getName dcon, ItblPtr (castFunPtrToPtr addrCon))
135
136
137 -- Make code which causes a jump to the given address.  This is the
138 -- only arch-dependent bit of the itbl story.  The returned list is
139 -- itblCodeLength elements (bytes) long.
140
141 -- For sparc_TARGET_ARCH, i386_TARGET_ARCH, etc.
142 #include "nativeGen/NCG.h"
143
144 itblCodeLength :: Int
145 itblCodeLength = length (mkJumpToAddr undefined)
146
147 mkJumpToAddr :: Ptr () -> [ItblCode]
148
149 ptrToInt :: Ptr a -> Int
150 ptrToInt (Ptr a#) = I# (addr2Int# a#)
151
152 #if sparc_TARGET_ARCH
153 -- After some consideration, we'll try this, where
154 -- 0x55555555 stands in for the address to jump to.
155 -- According to includes/rts/MachRegs.h, %g3 is very
156 -- likely indeed to be baggable.
157 --
158 --   0000 07155555              sethi   %hi(0x55555555), %g3
159 --   0004 8610E155              or      %g3, %lo(0x55555555), %g3
160 --   0008 81C0C000              jmp     %g3
161 --   000c 01000000              nop
162
163 type ItblCode = Word32
164 mkJumpToAddr a
165    = let w32 = fromIntegral (ptrToInt a)
166
167          hi22, lo10 :: Word32 -> Word32
168          lo10 x = x .&. 0x3FF
169          hi22 x = (x `shiftR` 10) .&. 0x3FFFF
170
171      in  [ 0x07000000 .|. (hi22 w32),
172            0x8610E000 .|. (lo10 w32),
173            0x81C0C000,
174            0x01000000 ]
175
176 #elif powerpc_TARGET_ARCH
177 -- We'll use r12, for no particular reason.
178 -- 0xDEADBEEF stands for the adress:
179 -- 3D80DEAD lis r12,0xDEAD
180 -- 618CBEEF ori r12,r12,0xBEEF
181 -- 7D8903A6 mtctr r12
182 -- 4E800420 bctr
183
184 type ItblCode = Word32
185 mkJumpToAddr a =
186     let w32 = fromIntegral (ptrToInt a)
187         hi16 x = (x `shiftR` 16) .&. 0xFFFF
188         lo16 x = x .&. 0xFFFF
189     in  [
190         0x3D800000 .|. hi16 w32,
191         0x618C0000 .|. lo16 w32,
192         0x7D8903A6, 0x4E800420
193         ]
194
195 #elif i386_TARGET_ARCH
196 -- Let the address to jump to be 0xWWXXYYZZ.
197 -- Generate   movl $0xWWXXYYZZ,%eax  ;  jmp *%eax
198 -- which is
199 -- B8 ZZ YY XX WW FF E0
200
201 type ItblCode = Word8
202 mkJumpToAddr a
203    = let w32 = fromIntegral (ptrToInt a) :: Word32
204          insnBytes :: [Word8]
205          insnBytes
206             = [0xB8, byte0 w32, byte1 w32, 
207                      byte2 w32, byte3 w32, 
208                0xFF, 0xE0]
209      in
210          insnBytes
211
212 #elif x86_64_TARGET_ARCH
213 -- Generates:
214 --      jmpq *.L1(%rip)
215 --      .align 8
216 -- .L1: 
217 --      .quad <addr>
218 --
219 -- We need a full 64-bit pointer (we can't assume the info table is
220 -- allocated in low memory).  Assuming the info pointer is aligned to
221 -- an 8-byte boundary, the addr will also be aligned.
222
223 type ItblCode = Word8
224 mkJumpToAddr a
225    = let w64 = fromIntegral (ptrToInt a) :: Word64
226          insnBytes :: [Word8]
227          insnBytes
228             = [0xff, 0x25, 0x02, 0x00, 0x00, 0x00, 0x00, 0x00,
229                byte0 w64, byte1 w64, byte2 w64, byte3 w64,
230                byte4 w64, byte5 w64, byte6 w64, byte7 w64]
231      in
232          insnBytes
233
234 #elif alpha_TARGET_ARCH
235 type ItblCode = Word32
236 mkJumpToAddr a
237     = [ 0xc3800000      -- br   at, .+4
238       , 0xa79c000c      -- ldq  at, 12(at)
239       , 0x6bfc0000      -- jmp  (at)    # with zero hint -- oh well
240       , 0x47ff041f      -- nop
241       , fromIntegral (w64 .&. 0x0000FFFF)
242       , fromIntegral ((w64 `shiftR` 32) .&. 0x0000FFFF) ]
243     where w64 = fromIntegral (ptrToInt a) :: Word64
244
245 #else
246 type ItblCode = Word32
247 mkJumpToAddr a
248     = undefined
249 #endif
250
251 #if defined(i386_TARGET_ARCH) || defined(x86_64_TARGET_ARCH)
252 byte0, byte1, byte2, byte3 :: (Integral w, Bits w) => w -> Word8
253 byte0 w = fromIntegral w
254 byte1 w = fromIntegral (w `shiftR` 8)
255 byte2 w = fromIntegral (w `shiftR` 16)
256 byte3 w = fromIntegral (w `shiftR` 24)
257 #endif
258
259 #if defined(x86_64_TARGET_ARCH)
260 byte4, byte5, byte6, byte7 :: (Integral w, Bits w) => w -> Word8
261 byte4 w = fromIntegral (w `shiftR` 32)
262 byte5 w = fromIntegral (w `shiftR` 40)
263 byte6 w = fromIntegral (w `shiftR` 48)
264 byte7 w = fromIntegral (w `shiftR` 56)
265 #endif
266
267 #ifndef __HADDOCK__
268 -- entry point for direct returns for created constr itbls
269 foreign import ccall "&stg_interp_constr_entry" stg_interp_constr_entry :: Ptr ()
270 #endif
271
272
273
274
275 -- Ultra-minimalist version specially for constructors
276 #if SIZEOF_VOID_P == 8
277 type HalfWord = Word32
278 #else
279 type HalfWord = Word16
280 #endif
281
282 data StgConInfoTable = StgConInfoTable {
283    conDesc   :: Ptr Word8,
284    infoTable :: StgInfoTable
285 }
286
287 sizeOfConItbl :: StgConInfoTable -> Int
288 sizeOfConItbl conInfoTable
289       = sum [ sizeOf (conDesc conInfoTable)
290             , sizeOf (infoTable conInfoTable) ]
291
292 pokeConItbl :: DynFlags -> Ptr StgConInfoTable -> Ptr StgConInfoTable -> StgConInfoTable
293             -> IO ()
294 pokeConItbl dflags wr_ptr ex_ptr itbl
295       = evalState (castPtr wr_ptr) $ do
296 #ifdef GHCI_TABLES_NEXT_TO_CODE
297            store (conDesc itbl `minusPtr` (ex_ptr `plusPtr` conInfoTableSizeB dflags))
298 #endif
299            store (infoTable itbl)
300 #ifndef GHCI_TABLES_NEXT_TO_CODE
301            store (conDesc itbl)
302 #endif
303
304 data StgInfoTable = StgInfoTable {
305 #ifndef GHCI_TABLES_NEXT_TO_CODE
306    entry  :: Ptr (),
307 #endif
308    ptrs   :: HalfWord,
309    nptrs  :: HalfWord,
310    tipe   :: HalfWord,
311    srtlen :: HalfWord
312 #ifdef GHCI_TABLES_NEXT_TO_CODE
313  , code   :: [ItblCode]
314 #endif
315   }
316
317 instance Storable StgInfoTable where
318
319    sizeOf itbl 
320       = sum
321         [
322 #ifndef GHCI_TABLES_NEXT_TO_CODE
323          fieldSz entry itbl,
324 #endif
325          fieldSz ptrs itbl,
326          fieldSz nptrs itbl,
327          fieldSz tipe itbl,
328          fieldSz srtlen itbl
329 #ifdef GHCI_TABLES_NEXT_TO_CODE
330         ,fieldSz (head.code) itbl * itblCodeLength
331 #endif
332         ]
333
334    alignment _ 
335       = SIZEOF_VOID_P
336
337    poke a0 itbl
338       = evalState (castPtr a0)
339       $ do
340 #ifndef GHCI_TABLES_NEXT_TO_CODE
341            store (entry  itbl)
342 #endif
343            store (ptrs   itbl)
344            store (nptrs  itbl)
345            store (tipe   itbl)
346            store (srtlen itbl)
347 #ifdef GHCI_TABLES_NEXT_TO_CODE
348            sequence_ (map store (code itbl))
349 #endif
350
351    peek a0
352       = evalState (castPtr a0)
353       $ do
354 #ifndef GHCI_TABLES_NEXT_TO_CODE
355            entry'  <- load
356 #endif
357            ptrs'   <- load
358            nptrs'  <- load
359            tipe'   <- load
360            srtlen' <- load
361 #ifdef GHCI_TABLES_NEXT_TO_CODE
362            code'   <- sequence (replicate itblCodeLength load)
363 #endif
364            return 
365               StgInfoTable { 
366 #ifndef GHCI_TABLES_NEXT_TO_CODE
367                  entry  = entry',
368 #endif
369                  ptrs   = ptrs',
370                  nptrs  = nptrs',
371                  tipe   = tipe',
372                  srtlen = srtlen'
373 #ifdef GHCI_TABLES_NEXT_TO_CODE
374                 ,code   = code'
375 #endif
376               }
377
378 fieldSz :: (Storable a, Storable b) => (a -> b) -> a -> Int
379 fieldSz sel x = sizeOf (sel x)
380
381 newtype State s m a = State (s -> m (s, a))
382
383 instance Monad m => Monad (State s m) where
384   return a      = State (\s -> return (s, a))
385   State m >>= k = State (\s -> m s >>= \(s', a) -> case k a of State n -> n s')
386   fail str      = State (\_ -> fail str)
387
388 class (Monad m, Monad (t m)) => MonadT t m where
389   lift :: m a -> t m a
390
391 instance Monad m => MonadT (State s) m where
392   lift m        = State (\s -> m >>= \a -> return (s, a))
393
394 runState :: Monad m => s -> State s m a -> m (s, a)
395 runState s (State m) = m s
396
397 evalState :: Monad m => s -> State s m a -> m a
398 evalState s m = liftM snd (runState s m)
399
400 execState :: Monad m => s -> State s m a -> m s
401 execState s m = liftM fst (runState s m)
402
403 type PtrIO = State (Ptr Word8) IO
404
405 advance :: Storable a => PtrIO (Ptr a)
406 advance = State adv where
407     adv addr = case castPtr addr of { addrCast -> return
408         (addr `plusPtr` sizeOfPointee addrCast, addrCast) }
409
410 sizeOfPointee :: (Storable a) => Ptr a -> Int
411 sizeOfPointee addr = sizeOf (typeHack addr)
412     where typeHack = undefined :: Ptr a -> a
413
414 store :: Storable a => a -> PtrIO ()
415 store x = do addr <- advance
416              lift (poke addr x)
417
418 load :: Storable a => PtrIO a
419 load = do addr <- advance
420           lift (peek addr)
421
422
423 newExecConItbl :: DynFlags -> StgConInfoTable -> IO (FunPtr ())
424 newExecConItbl dflags obj
425    = alloca $ \pcode -> do
426         wr_ptr <- _allocateExec (fromIntegral (sizeOfConItbl obj)) pcode
427         ex_ptr <- peek pcode
428         pokeConItbl dflags wr_ptr ex_ptr obj
429         return (castPtrToFunPtr ex_ptr)
430
431 foreign import ccall unsafe "allocateExec"
432   _allocateExec :: CUInt -> Ptr (Ptr a) -> IO (Ptr a)  
433 \end{code}