Fix the handling of Opt_Static
[ghc.git] / distrib / configure.ac.in
1 dnl
2 dnl Binary distribution configure script
3 dnl
4 #!/bin/sh
5 #
6
7 AC_INIT([The Glorious Glasgow Haskell Compilation System], [@ProjectVersion@], [glasgow-haskell-bugs@haskell.org], [ghc])
8
9 FP_BINDIST_GHC_PWD
10 FP_FIND_ROOT
11
12 dnl--------------------------------------------------------------------
13 dnl * Deal with arguments telling us gmp is somewhere odd
14 dnl--------------------------------------------------------------------
15
16 FP_GMP
17
18 bootstrap_target=@TargetPlatform@
19 FPTOOLS_SET_PLATFORM_VARS
20
21 # ToDo: if Stage1Only=YES, should be YES
22 CrossCompiling=NO
23 CrossCompilePrefix=""
24 TargetPlatformFull="${target}"
25
26 AC_SUBST(CrossCompiling)
27 AC_SUBST(CrossCompilePrefix)
28 AC_SUBST(TargetPlatformFull)
29
30 Unregisterised="@Unregisterised@"
31 AC_SUBST(Unregisterised)
32
33 #
34 dnl ** Check Perl installation **
35 #
36 AC_PATH_PROG(PerlCmd,perl)
37 if test -z "$PerlCmd"; then
38    echo "You must install perl before you can continue"
39    echo "Perhaps it is already installed, but not in your PATH?"
40    exit 1
41 fi
42
43 #
44 dnl ** figure out how to do a BSD-ish install **
45 #
46 AC_PROG_INSTALL
47
48 #
49 dnl ** how to do symlinks **
50 #
51 AC_PROG_LN_S()
52
53 #
54 dnl ** Find the path to sed **
55 #
56 AC_PATH_PROG(SedCmd,gsed sed,sed)
57
58 XCODE_VERSION()
59
60 dnl ** Which gcc to use?
61 dnl --------------------------------------------------------------
62 FIND_GCC([WhatGccIsCalled], [gcc], [gcc])
63 CC="$WhatGccIsCalled"
64 export CC
65
66 dnl ** Which ld to use?
67 dnl --------------------------------------------------------------
68 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld], [ld])
69 LdCmd="$LD"
70 AC_SUBST([LdCmd])
71
72 FP_GCC_VERSION
73 AC_PROG_CPP
74
75 FP_PROG_LD_HashSize31
76 FP_PROG_LD_ReduceMemoryOverheads
77 FP_PROG_LD_IS_GNU
78 FP_PROG_LD_BUILD_ID
79 FP_PROG_LD_NO_COMPACT_UNWIND
80
81 #
82 dnl ** Check gcc version and flags we need to pass it **
83 #
84 FP_GCC_EXTRA_FLAGS
85
86 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
87 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
88 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
89 # Stage 3 won't be supported by cross-compilation
90 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
91
92 AC_SUBST(CONF_CC_OPTS_STAGE0)
93 AC_SUBST(CONF_CC_OPTS_STAGE1)
94 AC_SUBST(CONF_CC_OPTS_STAGE2)
95 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
96 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
97 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
98 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
99 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
100 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
101 AC_SUBST(CONF_CPP_OPTS_STAGE0)
102 AC_SUBST(CONF_CPP_OPTS_STAGE1)
103 AC_SUBST(CONF_CPP_OPTS_STAGE2)
104
105 dnl ** Set up the variables for the platform in the settings file.
106 dnl May need to use gcc to find platform details.
107 dnl --------------------------------------------------------------
108 FPTOOLS_SET_HASKELL_PLATFORM_VARS
109
110 dnl WordSize for settings.in
111 AC_CHECK_SIZEOF(void *, 4)
112 WordSize=$ac_cv_sizeof_void_p
113 AC_SUBST(WordSize)
114
115 #
116 dnl ** how to invoke `ar' and `ranlib'
117 #
118 FP_PROG_AR_NEEDS_RANLIB
119
120 FP_SETTINGS
121
122 #
123 AC_CONFIG_FILES(settings mk/config.mk mk/install.mk)
124 AC_OUTPUT
125
126 # We get caught by
127 #     http://savannah.gnu.org/bugs/index.php?1516
128 #     $(eval ...) inside conditionals causes errors
129 # with make 3.80, so warn the user if it looks like they're about to
130 # try to use it.
131 # We would use "grep -q" here, but Solaris's grep doesn't support it.
132 checkMake380() {
133     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
134     then
135         echo
136         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
137         echo "This version cannot be used to build GHC."
138         echo "Please use GNU make >= 3.81."
139     fi
140 }
141
142 checkMake380 make
143 checkMake380 gmake
144
145 echo "****************************************************"
146 echo "Configuration done, ready to 'make install'"
147 echo "(see README and INSTALL files for more info.)"
148 echo "****************************************************"