ec9f6fa9d67333c764bc90499b1deaf33d1190fa
[ghc.git] / compiler / stgSyn / StgLint.lhs
1 %
2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
3 %
4 \section[StgLint]{A ``lint'' pass to check for Stg correctness}
5
6 \begin{code}
7 {-# LANGUAGE CPP #-}
8
9 module StgLint ( lintStgBindings ) where
10
11 import StgSyn
12
13 import Bag              ( Bag, emptyBag, isEmptyBag, snocBag, bagToList )
14 import Id               ( Id, idType, isLocalId )
15 import VarSet
16 import DataCon
17 import CoreSyn          ( AltCon(..) )
18 import PrimOp           ( primOpType )
19 import Literal          ( literalType )
20 import Maybes
21 import Name             ( getSrcLoc )
22 import ErrUtils         ( MsgDoc, Severity(..), mkLocMessage )
23 import TypeRep
24 import Type
25 import TyCon
26 import Util 
27 import SrcLoc
28 import Outputable
29 import FastString
30 import Control.Applicative ( Applicative(..) )
31 import Control.Monad
32 import Data.Function
33
34 #include "HsVersions.h"
35 \end{code}
36
37 Checks for
38         (a) *some* type errors
39         (b) locally-defined variables used but not defined
40
41
42 Note: unless -dverbose-stg is on, display of lint errors will result
43 in "panic: bOGUS_LVs".
44
45 WARNING:
46 ~~~~~~~~
47
48 This module has suffered bit-rot; it is likely to yield lint errors
49 for Stg code that is currently perfectly acceptable for code
50 generation.  Solution: don't use it!  (KSW 2000-05).
51
52
53 %************************************************************************
54 %*                                                                      *
55 \subsection{``lint'' for various constructs}
56 %*                                                                      *
57 %************************************************************************
58
59 @lintStgBindings@ is the top-level interface function.
60
61 \begin{code}
62 lintStgBindings :: String -> [StgBinding] -> [StgBinding]
63
64 lintStgBindings whodunnit binds
65   = {-# SCC "StgLint" #-}
66     case (initL (lint_binds binds)) of
67       Nothing  -> binds
68       Just msg -> pprPanic "" (vcat [
69                         ptext (sLit "*** Stg Lint ErrMsgs: in") <+>
70                               text whodunnit <+> ptext (sLit "***"),
71                         msg,
72                         ptext (sLit "*** Offending Program ***"),
73                         pprStgBindings binds,
74                         ptext (sLit "*** End of Offense ***")])
75   where
76     lint_binds :: [StgBinding] -> LintM ()
77
78     lint_binds [] = return ()
79     lint_binds (bind:binds) = do
80         binders <- lintStgBinds bind
81         addInScopeVars binders $
82             lint_binds binds
83 \end{code}
84
85
86 \begin{code}
87 lintStgArg :: StgArg -> LintM (Maybe Type)
88 lintStgArg (StgLitArg lit) = return (Just (literalType lit))
89 lintStgArg (StgVarArg v)   = lintStgVar v
90
91 lintStgVar :: Id -> LintM (Maybe Kind)
92 lintStgVar v = do checkInScope v
93                   return (Just (idType v))
94 \end{code}
95
96 \begin{code}
97 lintStgBinds :: StgBinding -> LintM [Id] -- Returns the binders
98 lintStgBinds (StgNonRec binder rhs) = do
99     lint_binds_help (binder,rhs)
100     return [binder]
101
102 lintStgBinds (StgRec pairs)
103   = addInScopeVars binders $ do
104         mapM_ lint_binds_help pairs
105         return binders
106   where
107     binders = [b | (b,_) <- pairs]
108
109 lint_binds_help :: (Id, StgRhs) -> LintM ()
110 lint_binds_help (binder, rhs)
111   = addLoc (RhsOf binder) $ do
112         -- Check the rhs
113         _maybe_rhs_ty <- lintStgRhs rhs
114
115         -- Check binder doesn't have unlifted type
116         checkL (not (isUnLiftedType binder_ty))
117                (mkUnLiftedTyMsg binder rhs)
118
119         -- Check match to RHS type
120         -- Actually we *can't* check the RHS type, because
121         -- unsafeCoerce means it really might not match at all
122         -- notably;  eg x::Int = (error @Bool "urk") |> unsafeCoerce...
123         -- case maybe_rhs_ty of
124         --  Nothing     -> return ()
125         --    Just rhs_ty -> checkTys binder_ty
126         --                          rhs_ty
127         ---                         (mkRhsMsg binder rhs_ty)
128
129         return ()
130   where
131     binder_ty = idType binder
132 \end{code}
133
134 \begin{code}
135 lintStgRhs :: StgRhs -> LintM (Maybe Type)   -- Just ty => type is exact
136
137 lintStgRhs (StgRhsClosure _ _ _ _ _ [] expr)
138   = lintStgExpr expr
139
140 lintStgRhs (StgRhsClosure _ _ _ _ _ binders expr)
141   = addLoc (LambdaBodyOf binders) $
142       addInScopeVars binders $ runMaybeT $ do
143         body_ty <- MaybeT $ lintStgExpr expr
144         return (mkFunTys (map idType binders) body_ty)
145
146 lintStgRhs (StgRhsCon _ con args) = runMaybeT $ do
147     arg_tys <- mapM (MaybeT . lintStgArg) args
148     MaybeT $ checkFunApp con_ty arg_tys (mkRhsConMsg con_ty arg_tys)
149   where
150     con_ty = dataConRepType con
151 \end{code}
152
153 \begin{code}
154 lintStgExpr :: StgExpr -> LintM (Maybe Type) -- Just ty => type is exact
155
156 lintStgExpr (StgLit l) = return (Just (literalType l))
157
158 lintStgExpr e@(StgApp fun args) = runMaybeT $ do
159     fun_ty <- MaybeT $ lintStgVar fun
160     arg_tys <- mapM (MaybeT . lintStgArg) args
161     MaybeT $ checkFunApp fun_ty arg_tys (mkFunAppMsg fun_ty arg_tys e)
162
163 lintStgExpr e@(StgConApp con args) = runMaybeT $ do
164     arg_tys <- mapM (MaybeT . lintStgArg) args
165     MaybeT $ checkFunApp con_ty arg_tys (mkFunAppMsg con_ty arg_tys e)
166   where
167     con_ty = dataConRepType con
168
169 lintStgExpr e@(StgOpApp (StgPrimOp op) args _) = runMaybeT $ do
170     arg_tys <- mapM (MaybeT . lintStgArg) args
171     MaybeT $ checkFunApp op_ty arg_tys (mkFunAppMsg op_ty arg_tys e)
172   where
173     op_ty = primOpType op
174
175 lintStgExpr (StgOpApp _ args res_ty) = runMaybeT $ do
176         -- We don't have enough type information to check
177         -- the application for StgFCallOp and StgPrimCallOp; ToDo
178     _maybe_arg_tys <- mapM (MaybeT . lintStgArg) args
179     return res_ty
180
181 lintStgExpr (StgLam bndrs _) = do
182     addErrL (ptext (sLit "Unexpected StgLam") <+> ppr bndrs)
183     return Nothing
184
185 lintStgExpr (StgLet binds body) = do
186     binders <- lintStgBinds binds
187     addLoc (BodyOfLetRec binders) $
188       addInScopeVars binders $
189         lintStgExpr body
190
191 lintStgExpr (StgLetNoEscape _ _ binds body) = do
192     binders <- lintStgBinds binds
193     addLoc (BodyOfLetRec binders) $
194       addInScopeVars binders $
195         lintStgExpr body
196
197 lintStgExpr (StgSCC _ _ _ expr) = lintStgExpr expr
198
199 lintStgExpr (StgCase scrut _ _ bndr _ alts_type alts) = runMaybeT $ do
200     _ <- MaybeT $ lintStgExpr scrut
201
202     in_scope <- MaybeT $ liftM Just $
203      case alts_type of
204         AlgAlt tc    -> check_bndr tc >> return True
205         PrimAlt tc   -> check_bndr tc >> return True
206         UbxTupAlt _  -> return False -- Binder is always dead in this case
207         PolyAlt      -> return True
208
209     MaybeT $ addInScopeVars [bndr | in_scope] $
210              lintStgAlts alts scrut_ty
211   where
212     scrut_ty          = idType bndr
213     UnaryRep scrut_rep = repType scrut_ty -- Not used if scrutinee is unboxed tuple
214     check_bndr tc = case tyConAppTyCon_maybe scrut_rep of
215                         Just bndr_tc -> checkL (tc == bndr_tc) bad_bndr
216                         Nothing      -> addErrL bad_bndr
217                   where
218                      bad_bndr = mkDefltMsg bndr tc
219
220 lintStgExpr e = pprPanic "lintStgExpr" (ppr e)
221
222 lintStgAlts :: [StgAlt]
223             -> Type               -- Type of scrutinee
224             -> LintM (Maybe Type) -- Just ty => type is accurage
225
226 lintStgAlts alts scrut_ty = do
227     maybe_result_tys <- mapM (lintAlt scrut_ty) alts
228
229     -- Check the result types
230     case catMaybes (maybe_result_tys) of
231       []             -> return Nothing
232
233       (first_ty:_tys) -> do -- mapM_ check tys
234                            return (Just first_ty)
235         where
236           -- check ty = checkTys first_ty ty (mkCaseAltMsg alts)
237           -- We can't check that the alternatives have the
238           -- same type, because they don't, with unsafeCoerce#
239
240 lintAlt :: Type -> (AltCon, [Id], [Bool], StgExpr) -> LintM (Maybe Type)
241 lintAlt _ (DEFAULT, _, _, rhs)
242  = lintStgExpr rhs
243
244 lintAlt scrut_ty (LitAlt lit, _, _, rhs) = do
245    checkTys (literalType lit) scrut_ty (mkAltMsg1 scrut_ty)
246    lintStgExpr rhs
247
248 lintAlt scrut_ty (DataAlt con, args, _, rhs) = do
249     case splitTyConApp_maybe scrut_ty of
250       Just (tycon, tys_applied) | isAlgTyCon tycon &&
251                                   not (isNewTyCon tycon) -> do
252          let
253            cons    = tyConDataCons tycon
254            arg_tys = dataConInstArgTys con tys_applied
255                 -- This does not work for existential constructors
256
257          checkL (con `elem` cons) (mkAlgAltMsg2 scrut_ty con)
258          checkL (length args == dataConRepArity con) (mkAlgAltMsg3 con args)
259          when (isVanillaDataCon con) $
260            mapM_ check (zipEqual "lintAlgAlt:stg" arg_tys args)
261          return ()
262       _ ->
263          addErrL (mkAltMsg1 scrut_ty)
264
265     addInScopeVars args $
266          lintStgExpr rhs
267   where
268     check (ty, arg) = checkTys ty (idType arg) (mkAlgAltMsg4 ty arg)
269
270     -- elem: yes, the elem-list here can sometimes be long-ish,
271     -- but as it's use-once, probably not worth doing anything different
272     -- We give it its own copy, so it isn't overloaded.
273     elem _ []       = False
274     elem x (y:ys)   = x==y || elem x ys
275 \end{code}
276
277
278 %************************************************************************
279 %*                                                                      *
280 \subsection[lint-monad]{The Lint monad}
281 %*                                                                      *
282 %************************************************************************
283
284 \begin{code}
285 newtype LintM a = LintM
286     { unLintM :: [LintLocInfo]      -- Locations
287               -> IdSet              -- Local vars in scope
288               -> Bag MsgDoc        -- Error messages so far
289               -> (a, Bag MsgDoc)   -- Result and error messages (if any)
290     }
291
292 data LintLocInfo
293   = RhsOf Id            -- The variable bound
294   | LambdaBodyOf [Id]   -- The lambda-binder
295   | BodyOfLetRec [Id]   -- One of the binders
296
297 dumpLoc :: LintLocInfo -> (SrcSpan, SDoc)
298 dumpLoc (RhsOf v) =
299   (srcLocSpan (getSrcLoc v), ptext (sLit " [RHS of ") <> pp_binders [v] <> char ']' )
300 dumpLoc (LambdaBodyOf bs) =
301   (srcLocSpan (getSrcLoc (head bs)), ptext (sLit " [in body of lambda with binders ") <> pp_binders bs <> char ']' )
302
303 dumpLoc (BodyOfLetRec bs) =
304   (srcLocSpan (getSrcLoc (head bs)), ptext (sLit " [in body of letrec with binders ") <> pp_binders bs <> char ']' )
305
306
307 pp_binders :: [Id] -> SDoc
308 pp_binders bs
309   = sep (punctuate comma (map pp_binder bs))
310   where
311     pp_binder b
312       = hsep [ppr b, dcolon, ppr (idType b)]
313 \end{code}
314
315 \begin{code}
316 initL :: LintM a -> Maybe MsgDoc
317 initL (LintM m)
318   = case (m [] emptyVarSet emptyBag) of { (_, errs) ->
319     if isEmptyBag errs then
320         Nothing
321     else
322         Just (vcat (punctuate blankLine (bagToList errs)))
323     }
324
325 instance Functor LintM where
326       fmap = liftM
327
328 instance Applicative LintM where
329       pure = return
330       (<*>) = ap
331
332 instance Monad LintM where
333     return a = LintM $ \_loc _scope errs -> (a, errs)
334     (>>=) = thenL
335     (>>)  = thenL_
336
337 thenL :: LintM a -> (a -> LintM b) -> LintM b
338 thenL m k = LintM $ \loc scope errs
339   -> case unLintM m loc scope errs of
340       (r, errs') -> unLintM (k r) loc scope errs'
341
342 thenL_ :: LintM a -> LintM b -> LintM b
343 thenL_ m k = LintM $ \loc scope errs
344   -> case unLintM m loc scope errs of
345       (_, errs') -> unLintM k loc scope errs'
346 \end{code}
347
348 \begin{code}
349 checkL :: Bool -> MsgDoc -> LintM ()
350 checkL True  _   = return ()
351 checkL False msg = addErrL msg
352
353 addErrL :: MsgDoc -> LintM ()
354 addErrL msg = LintM $ \loc _scope errs -> ((), addErr errs msg loc)
355
356 addErr :: Bag MsgDoc -> MsgDoc -> [LintLocInfo] -> Bag MsgDoc
357 addErr errs_so_far msg locs
358   = errs_so_far `snocBag` mk_msg locs
359   where
360     mk_msg (loc:_) = let (l,hdr) = dumpLoc loc
361                      in  mkLocMessage SevWarning l (hdr $$ msg)
362     mk_msg []      = msg
363
364 addLoc :: LintLocInfo -> LintM a -> LintM a
365 addLoc extra_loc m = LintM $ \loc scope errs
366    -> unLintM m (extra_loc:loc) scope errs
367
368 addInScopeVars :: [Id] -> LintM a -> LintM a
369 addInScopeVars ids m = LintM $ \loc scope errs
370  -> -- We check if these "new" ids are already
371     -- in scope, i.e., we have *shadowing* going on.
372     -- For now, it's just a "trace"; we may make
373     -- a real error out of it...
374     let
375         new_set = mkVarSet ids
376     in
377 --  After adding -fliberate-case, Simon decided he likes shadowed
378 --  names after all.  WDP 94/07
379 --  (if isEmptyVarSet shadowed
380 --  then id
381 --  else pprTrace "Shadowed vars:" (ppr (varSetElems shadowed))) $
382     unLintM m loc (scope `unionVarSet` new_set) errs
383 \end{code}
384
385 Checking function applications: we only check that the type has the
386 right *number* of arrows, we don't actually compare the types.  This
387 is because we can't expect the types to be equal - the type
388 applications and type lambdas that we use to calculate accurate types
389 have long since disappeared.
390
391 \begin{code}
392 checkFunApp :: Type                 -- The function type
393             -> [Type]               -- The arg type(s)
394             -> MsgDoc              -- Error message
395             -> LintM (Maybe Type)   -- Just ty => result type is accurate
396
397 checkFunApp fun_ty arg_tys msg
398  = do { case mb_msg of
399           Just msg -> addErrL msg
400           Nothing  -> return ()
401       ; return mb_ty }
402  where
403   (mb_ty, mb_msg) = cfa True fun_ty arg_tys
404
405   cfa :: Bool -> Type -> [Type] -> (Maybe Type          -- Accurate result?
406                                    , Maybe MsgDoc)      -- Errors?
407
408   cfa accurate fun_ty []      -- Args have run out; that's fine
409       = (if accurate then Just fun_ty else Nothing, Nothing)
410
411   cfa accurate fun_ty arg_tys@(arg_ty':arg_tys')   
412       | Just (arg_ty, res_ty) <- splitFunTy_maybe fun_ty
413       = if accurate && not (arg_ty `stgEqType` arg_ty') 
414         then (Nothing, Just msg)       -- Arg type mismatch
415         else cfa accurate res_ty arg_tys'
416
417       | Just (_, fun_ty') <- splitForAllTy_maybe fun_ty
418       = cfa False fun_ty' arg_tys
419
420       | Just (tc,tc_args) <- splitTyConApp_maybe fun_ty
421       , isNewTyCon tc
422       = if length tc_args < tyConArity tc 
423         then WARN( True, text "cfa: unsaturated newtype" <+> ppr fun_ty $$ msg )
424              (Nothing, Nothing)   -- This is odd, but I've seen it
425         else cfa False (newTyConInstRhs tc tc_args) arg_tys
426
427       | Just tc <- tyConAppTyCon_maybe fun_ty
428       , not (isSynFamilyTyCon tc)       -- Definite error
429       = (Nothing, Just msg)             -- Too many args
430
431       | otherwise
432       = (Nothing, Nothing)
433 \end{code}
434
435 \begin{code}
436 stgEqType :: Type -> Type -> Bool
437 -- Compare types, but crudely because we have discarded
438 -- both casts and type applications, so types might look
439 -- different but be the same.  So reply "True" if in doubt.
440 -- "False" means that the types are definitely different.
441 --
442 -- Fundamentally this is a losing battle because of unsafeCoerce
443
444 stgEqType orig_ty1 orig_ty2 
445   = gos (repType orig_ty1) (repType orig_ty2)
446   where
447     gos :: RepType -> RepType -> Bool
448     gos (UbxTupleRep tys1) (UbxTupleRep tys2)
449       = equalLength tys1 tys2 && and (zipWith go tys1 tys2)
450     gos (UnaryRep ty1) (UnaryRep ty2) = go ty1 ty2
451     gos _ _ = False
452
453     go :: UnaryType -> UnaryType -> Bool
454     go ty1 ty2
455       | Just (tc1, tc_args1) <- splitTyConApp_maybe ty1
456       , Just (tc2, tc_args2) <- splitTyConApp_maybe ty2
457       , let res = if tc1 == tc2 
458                   then equalLength tc_args1 tc_args2 && and (zipWith (gos `on` repType) tc_args1 tc_args2)
459                   else  -- TyCons don't match; but don't bleat if either is a 
460                         -- family TyCon because a coercion might have made it 
461                         -- equal to something else
462                     (isFamilyTyCon tc1 || isFamilyTyCon tc2)
463       = if res then True
464         else 
465         pprTrace "stgEqType: unequal" (vcat [ppr ty1, ppr ty2]) 
466         False
467
468       | otherwise = True  -- Conservatively say "fine".  
469                           -- Type variables in particular
470
471 checkInScope :: Id -> LintM ()
472 checkInScope id = LintM $ \loc scope errs
473  -> if isLocalId id && not (id `elemVarSet` scope) then
474         ((), addErr errs (hsep [ppr id, ptext (sLit "is out of scope")]) loc)
475     else
476         ((), errs)
477
478 checkTys :: Type -> Type -> MsgDoc -> LintM ()
479 checkTys ty1 ty2 msg = LintM $ \loc _scope errs
480   -> if (ty1 `stgEqType` ty2)
481      then ((), errs)
482      else ((), addErr errs msg loc)
483 \end{code}
484
485 \begin{code}
486 _mkCaseAltMsg :: [StgAlt] -> MsgDoc
487 _mkCaseAltMsg _alts
488   = ($$) (text "In some case alternatives, type of alternatives not all same:")
489             (empty) -- LATER: ppr alts
490
491 mkDefltMsg :: Id -> TyCon -> MsgDoc
492 mkDefltMsg bndr tc
493   = ($$) (ptext (sLit "Binder of a case expression doesn't match type of scrutinee:"))
494          (ppr bndr $$ ppr (idType bndr) $$ ppr tc)
495
496 mkFunAppMsg :: Type -> [Type] -> StgExpr -> MsgDoc
497 mkFunAppMsg fun_ty arg_tys expr
498   = vcat [text "In a function application, function type doesn't match arg types:",
499               hang (ptext (sLit "Function type:")) 4 (ppr fun_ty),
500               hang (ptext (sLit "Arg types:")) 4 (vcat (map (ppr) arg_tys)),
501               hang (ptext (sLit "Expression:")) 4 (ppr expr)]
502
503 mkRhsConMsg :: Type -> [Type] -> MsgDoc
504 mkRhsConMsg fun_ty arg_tys
505   = vcat [text "In a RHS constructor application, con type doesn't match arg types:",
506               hang (ptext (sLit "Constructor type:")) 4 (ppr fun_ty),
507               hang (ptext (sLit "Arg types:")) 4 (vcat (map (ppr) arg_tys))]
508
509 mkAltMsg1 :: Type -> MsgDoc
510 mkAltMsg1 ty
511   = ($$) (text "In a case expression, type of scrutinee does not match patterns")
512          (ppr ty)
513
514 mkAlgAltMsg2 :: Type -> DataCon -> MsgDoc
515 mkAlgAltMsg2 ty con
516   = vcat [
517         text "In some algebraic case alternative, constructor is not a constructor of scrutinee type:",
518         ppr ty,
519         ppr con
520     ]
521
522 mkAlgAltMsg3 :: DataCon -> [Id] -> MsgDoc
523 mkAlgAltMsg3 con alts
524   = vcat [
525         text "In some algebraic case alternative, number of arguments doesn't match constructor:",
526         ppr con,
527         ppr alts
528     ]
529
530 mkAlgAltMsg4 :: Type -> Id -> MsgDoc
531 mkAlgAltMsg4 ty arg
532   = vcat [
533         text "In some algebraic case alternative, type of argument doesn't match data constructor:",
534         ppr ty,
535         ppr arg
536     ]
537
538 _mkRhsMsg :: Id -> Type -> MsgDoc
539 _mkRhsMsg binder ty
540   = vcat [hsep [ptext (sLit "The type of this binder doesn't match the type of its RHS:"),
541                      ppr binder],
542               hsep [ptext (sLit "Binder's type:"), ppr (idType binder)],
543               hsep [ptext (sLit "Rhs type:"), ppr ty]
544              ]
545
546 mkUnLiftedTyMsg :: Id -> StgRhs -> SDoc
547 mkUnLiftedTyMsg binder rhs
548   = (ptext (sLit "Let(rec) binder") <+> quotes (ppr binder) <+>
549      ptext (sLit "has unlifted type") <+> quotes (ppr (idType binder)))
550     $$
551     (ptext (sLit "RHS:") <+> ppr rhs)
552 \end{code}