Experimental flag -fdicts-cheap
[ghc.git] / compiler / simplCore / SimplUtils.lhs
1 %
2 % (c) The AQUA Project, Glasgow University, 1993-1998
3 %
4 \section[SimplUtils]{The simplifier utilities}
5
6 \begin{code}
7 module SimplUtils (
8         mkLam, mkCase,
9
10         -- Inlining,
11         preInlineUnconditionally, postInlineUnconditionally, activeInline, activeRule,
12         inlineMode,
13
14         -- The continuation type
15         SimplCont(..), DupFlag(..), LetRhsFlag(..), 
16         contIsDupable, contResultType,
17         countValArgs, countArgs, pushContArgs,
18         mkBoringStop, mkLazyArgStop, mkRhsStop, contIsRhs, contIsRhsOrArg,
19         getContArgs, interestingCallContext, interestingArgContext,
20         interestingArg, isStrictType
21
22     ) where
23
24 #include "HsVersions.h"
25
26 import SimplEnv
27 import DynFlags         ( SimplifierSwitch(..), SimplifierMode(..),
28                           DynFlags, DynFlag(..), dopt )
29 import StaticFlags      ( opt_UF_UpdateInPlace, opt_SimplNoPreInlining,
30                           opt_RulesOff )
31 import CoreSyn
32 import CoreFVs          ( exprFreeVars )
33 import CoreUtils        ( cheapEqExpr, exprType, exprIsTrivial, 
34                           etaExpand, exprEtaExpandArity, bindNonRec, mkCoerce2,
35                           findDefault, exprOkForSpeculation, exprIsHNF, mergeAlts
36                         )
37 import Literal          ( mkStringLit )
38 import CoreUnfold       ( smallEnoughToInline )
39 import MkId             ( eRROR_ID )
40 import Id               ( Id, idType, isDataConWorkId, idOccInfo, isDictId, 
41                           isDeadBinder, idNewDemandInfo, isExportedId,
42                           idUnfolding, idNewStrictness, idInlinePragma, idHasRules
43                         )
44 import NewDemand        ( isStrictDmd, isBotRes, splitStrictSig )
45 import SimplMonad
46 import Type             ( Type, splitFunTys, dropForAlls, isStrictType,
47                           splitTyConApp_maybe, tyConAppArgs 
48                         )
49 import TyCon            ( tyConDataCons_maybe )
50 import DataCon          ( dataConRepArity )
51 import VarSet
52 import BasicTypes       ( TopLevelFlag(..), isNotTopLevel, OccInfo(..), isLoopBreaker, isOneOcc,
53                           Activation, isAlwaysActive, isActive )
54 import Util             ( lengthExceeds )
55 import Outputable
56 \end{code}
57
58
59 %************************************************************************
60 %*                                                                      *
61 \subsection{The continuation data type}
62 %*                                                                      *
63 %************************************************************************
64
65 \begin{code}
66 data SimplCont          -- Strict contexts
67   = Stop     OutType    -- Type of the result
68              LetRhsFlag
69              Bool       -- True <=> There is something interesting about
70                         --          the context, and hence the inliner
71                         --          should be a bit keener (see interestingCallContext)
72                         -- Two cases:
73                         -- (a) This is the RHS of a thunk whose type suggests
74                         --     that update-in-place would be possible
75                         -- (b) This is an argument of a function that has RULES
76                         --     Inlining the call might allow the rule to fire
77
78   | CoerceIt OutType                    -- The To-type, simplified
79              SimplCont
80
81   | ApplyTo  DupFlag 
82              InExpr SimplEnv            -- The argument, as yet unsimplified, 
83              SimplCont                  -- and its environment
84
85   | Select   DupFlag 
86              InId [InAlt] SimplEnv      -- The case binder, alts, and subst-env
87              SimplCont
88
89   | ArgOf    LetRhsFlag         -- An arbitrary strict context: the argument 
90                                 --      of a strict function, or a primitive-arg fn
91                                 --      or a PrimOp
92                                 -- No DupFlag, because we never duplicate it
93              OutType            -- arg_ty: type of the argument itself
94              OutType            -- cont_ty: the type of the expression being sought by the context
95                                 --      f (error "foo") ==> coerce t (error "foo")
96                                 -- when f is strict
97                                 -- We need to know the type t, to which to coerce.
98
99              (SimplEnv -> OutExpr -> SimplM FloatsWithExpr)     -- What to do with the result
100                                 -- The result expression in the OutExprStuff has type cont_ty
101
102 data LetRhsFlag = AnArg         -- It's just an argument not a let RHS
103                 | AnRhs         -- It's the RHS of a let (so please float lets out of big lambdas)
104
105 instance Outputable LetRhsFlag where
106   ppr AnArg = ptext SLIT("arg")
107   ppr AnRhs = ptext SLIT("rhs")
108
109 instance Outputable SimplCont where
110   ppr (Stop ty is_rhs _)             = ptext SLIT("Stop") <> brackets (ppr is_rhs) <+> ppr ty
111   ppr (ApplyTo dup arg se cont)      = (ptext SLIT("ApplyTo") <+> ppr dup <+> ppr arg) $$ ppr cont
112   ppr (ArgOf _ _ _ _)                = ptext SLIT("ArgOf...")
113   ppr (Select dup bndr alts se cont) = (ptext SLIT("Select") <+> ppr dup <+> ppr bndr) $$ 
114                                        (nest 4 (ppr alts)) $$ ppr cont
115   ppr (CoerceIt ty cont)             = (ptext SLIT("CoerceIt") <+> ppr ty) $$ ppr cont
116
117 data DupFlag = OkToDup | NoDup
118
119 instance Outputable DupFlag where
120   ppr OkToDup = ptext SLIT("ok")
121   ppr NoDup   = ptext SLIT("nodup")
122
123
124 -------------------
125 mkBoringStop :: OutType -> SimplCont
126 mkBoringStop ty = Stop ty AnArg False
127
128 mkLazyArgStop :: OutType -> Bool -> SimplCont
129 mkLazyArgStop ty has_rules = Stop ty AnArg (canUpdateInPlace ty || has_rules)
130
131 mkRhsStop :: OutType -> SimplCont
132 mkRhsStop ty = Stop ty AnRhs (canUpdateInPlace ty)
133
134 contIsRhs :: SimplCont -> Bool
135 contIsRhs (Stop _ AnRhs _)    = True
136 contIsRhs (ArgOf AnRhs _ _ _) = True
137 contIsRhs other               = False
138
139 contIsRhsOrArg (Stop _ _ _)    = True
140 contIsRhsOrArg (ArgOf _ _ _ _) = True
141 contIsRhsOrArg other           = False
142
143 -------------------
144 contIsDupable :: SimplCont -> Bool
145 contIsDupable (Stop _ _ _)               = True
146 contIsDupable (ApplyTo  OkToDup _ _ _)   = True
147 contIsDupable (Select   OkToDup _ _ _ _) = True
148 contIsDupable (CoerceIt _ cont)          = contIsDupable cont
149 contIsDupable other                      = False
150
151 -------------------
152 discardableCont :: SimplCont -> Bool
153 discardableCont (Stop _ _ _)        = False
154 discardableCont (CoerceIt _ cont)   = discardableCont cont
155 discardableCont other               = True
156
157 discardCont :: SimplCont        -- A continuation, expecting
158             -> SimplCont        -- Replace the continuation with a suitable coerce
159 discardCont cont = case cont of
160                      Stop to_ty is_rhs _ -> cont
161                      other               -> CoerceIt to_ty (mkBoringStop to_ty)
162                  where
163                    to_ty = contResultType cont
164
165 -------------------
166 contResultType :: SimplCont -> OutType
167 contResultType (Stop to_ty _ _)      = to_ty
168 contResultType (ArgOf _ _ to_ty _)   = to_ty
169 contResultType (ApplyTo _ _ _ cont)  = contResultType cont
170 contResultType (CoerceIt _ cont)     = contResultType cont
171 contResultType (Select _ _ _ _ cont) = contResultType cont
172
173 -------------------
174 countValArgs :: SimplCont -> Int
175 countValArgs (ApplyTo _ (Type ty) se cont) = countValArgs cont
176 countValArgs (ApplyTo _ val_arg   se cont) = 1 + countValArgs cont
177 countValArgs other                         = 0
178
179 countArgs :: SimplCont -> Int
180 countArgs (ApplyTo _ arg se cont) = 1 + countArgs cont
181 countArgs other                   = 0
182
183 -------------------
184 pushContArgs :: SimplEnv -> [OutArg] -> SimplCont -> SimplCont
185 -- Pushes args with the specified environment
186 pushContArgs env []           cont = cont
187 pushContArgs env (arg : args) cont = ApplyTo NoDup arg env (pushContArgs env args cont)
188 \end{code}
189
190
191 \begin{code}
192 getContArgs :: SwitchChecker
193             -> OutId -> SimplCont 
194             -> ([(InExpr, SimplEnv, Bool)],     -- Arguments; the Bool is true for strict args
195                 SimplCont)                      -- Remaining continuation
196 -- getContArgs id k = (args, k', inl)
197 --      args are the leading ApplyTo items in k
198 --      (i.e. outermost comes first)
199 --      augmented with demand info from the functionn
200 getContArgs chkr fun orig_cont
201   = let
202                 -- Ignore strictness info if the no-case-of-case
203                 -- flag is on.  Strictness changes evaluation order
204                 -- and that can change full laziness
205         stricts | switchIsOn chkr NoCaseOfCase = vanilla_stricts
206                 | otherwise                    = computed_stricts
207     in
208     go [] stricts orig_cont
209   where
210     ----------------------------
211
212         -- Type argument
213     go acc ss (ApplyTo _ arg@(Type _) se cont)
214         = go ((arg,se,False) : acc) ss cont
215                 -- NB: don't bother to instantiate the function type
216
217         -- Value argument
218     go acc (s:ss) (ApplyTo _ arg se cont)
219         = go ((arg,se,s) : acc) ss cont
220
221         -- We're run out of arguments, or else we've run out of demands
222         -- The latter only happens if the result is guaranteed bottom
223         -- This is the case for
224         --      * case (error "hello") of { ... }
225         --      * (error "Hello") arg
226         --      * f (error "Hello") where f is strict
227         --      etc
228         -- Then, especially in the first of these cases, we'd like to discard
229         -- the continuation, leaving just the bottoming expression.  But the
230         -- type might not be right, so we may have to add a coerce.
231     go acc ss cont 
232         | null ss && discardableCont cont = (reverse acc, discardCont cont)
233         | otherwise                       = (reverse acc, cont)
234
235     ----------------------------
236     vanilla_stricts, computed_stricts :: [Bool]
237     vanilla_stricts  = repeat False
238     computed_stricts = zipWith (||) fun_stricts arg_stricts
239
240     ----------------------------
241     (val_arg_tys, _) = splitFunTys (dropForAlls (idType fun))
242     arg_stricts      = map isStrictType val_arg_tys ++ repeat False
243         -- These argument types are used as a cheap and cheerful way to find
244         -- unboxed arguments, which must be strict.  But it's an InType
245         -- and so there might be a type variable where we expect a function
246         -- type (the substitution hasn't happened yet).  And we don't bother
247         -- doing the type applications for a polymorphic function.
248         -- Hence the splitFunTys*IgnoringForAlls*
249
250     ----------------------------
251         -- If fun_stricts is finite, it means the function returns bottom
252         -- after that number of value args have been consumed
253         -- Otherwise it's infinite, extended with False
254     fun_stricts
255       = case splitStrictSig (idNewStrictness fun) of
256           (demands, result_info)
257                 | not (demands `lengthExceeds` countValArgs orig_cont)
258                 ->      -- Enough args, use the strictness given.
259                         -- For bottoming functions we used to pretend that the arg
260                         -- is lazy, so that we don't treat the arg as an
261                         -- interesting context.  This avoids substituting
262                         -- top-level bindings for (say) strings into 
263                         -- calls to error.  But now we are more careful about
264                         -- inlining lone variables, so its ok (see SimplUtils.analyseCont)
265                    if isBotRes result_info then
266                         map isStrictDmd demands         -- Finite => result is bottom
267                    else
268                         map isStrictDmd demands ++ vanilla_stricts
269
270           other -> vanilla_stricts      -- Not enough args, or no strictness
271
272 -------------------
273 interestingArg :: OutExpr -> Bool
274         -- An argument is interesting if it has *some* structure
275         -- We are here trying to avoid unfolding a function that
276         -- is applied only to variables that have no unfolding
277         -- (i.e. they are probably lambda bound): f x y z
278         -- There is little point in inlining f here.
279 interestingArg (Var v)           = hasSomeUnfolding (idUnfolding v)
280                                         -- Was: isValueUnfolding (idUnfolding v')
281                                         -- But that seems over-pessimistic
282                                  || isDataConWorkId v
283                                         -- This accounts for an argument like
284                                         -- () or [], which is definitely interesting
285 interestingArg (Type _)          = False
286 interestingArg (App fn (Type _)) = interestingArg fn
287 interestingArg (Note _ a)        = interestingArg a
288 interestingArg other             = True
289         -- Consider     let x = 3 in f x
290         -- The substitution will contain (x -> ContEx 3), and we want to
291         -- to say that x is an interesting argument.
292         -- But consider also (\x. f x y) y
293         -- The substitution will contain (x -> ContEx y), and we want to say
294         -- that x is not interesting (assuming y has no unfolding)
295 \end{code}
296
297 Comment about interestingCallContext
298 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
299 We want to avoid inlining an expression where there can't possibly be
300 any gain, such as in an argument position.  Hence, if the continuation
301 is interesting (eg. a case scrutinee, application etc.) then we
302 inline, otherwise we don't.  
303
304 Previously some_benefit used to return True only if the variable was
305 applied to some value arguments.  This didn't work:
306
307         let x = _coerce_ (T Int) Int (I# 3) in
308         case _coerce_ Int (T Int) x of
309                 I# y -> ....
310
311 we want to inline x, but can't see that it's a constructor in a case
312 scrutinee position, and some_benefit is False.
313
314 Another example:
315
316 dMonadST = _/\_ t -> :Monad (g1 _@_ t, g2 _@_ t, g3 _@_ t)
317
318 ....  case dMonadST _@_ x0 of (a,b,c) -> ....
319
320 we'd really like to inline dMonadST here, but we *don't* want to
321 inline if the case expression is just
322
323         case x of y { DEFAULT -> ... }
324
325 since we can just eliminate this case instead (x is in WHNF).  Similar
326 applies when x is bound to a lambda expression.  Hence
327 contIsInteresting looks for case expressions with just a single
328 default case.
329
330 \begin{code}
331 interestingCallContext :: Bool          -- False <=> no args at all
332                        -> Bool          -- False <=> no value args
333                        -> SimplCont -> Bool
334         -- The "lone-variable" case is important.  I spent ages
335         -- messing about with unsatisfactory varaints, but this is nice.
336         -- The idea is that if a variable appear all alone
337         --      as an arg of lazy fn, or rhs    Stop
338         --      as scrutinee of a case          Select
339         --      as arg of a strict fn           ArgOf
340         -- then we should not inline it (unless there is some other reason,
341         -- e.g. is is the sole occurrence).  We achieve this by making
342         -- interestingCallContext return False for a lone variable.
343         --
344         -- Why?  At least in the case-scrutinee situation, turning
345         --      let x = (a,b) in case x of y -> ...
346         -- into
347         --      let x = (a,b) in case (a,b) of y -> ...
348         -- and thence to 
349         --      let x = (a,b) in let y = (a,b) in ...
350         -- is bad if the binding for x will remain.
351         --
352         -- Another example: I discovered that strings
353         -- were getting inlined straight back into applications of 'error'
354         -- because the latter is strict.
355         --      s = "foo"
356         --      f = \x -> ...(error s)...
357
358         -- Fundamentally such contexts should not ecourage inlining because
359         -- the context can ``see'' the unfolding of the variable (e.g. case or a RULE)
360         -- so there's no gain.
361         --
362         -- However, even a type application or coercion isn't a lone variable.
363         -- Consider
364         --      case $fMonadST @ RealWorld of { :DMonad a b c -> c }
365         -- We had better inline that sucker!  The case won't see through it.
366         --
367         -- For now, I'm treating treating a variable applied to types 
368         -- in a *lazy* context "lone". The motivating example was
369         --      f = /\a. \x. BIG
370         --      g = /\a. \y.  h (f a)
371         -- There's no advantage in inlining f here, and perhaps
372         -- a significant disadvantage.  Hence some_val_args in the Stop case
373
374 interestingCallContext some_args some_val_args cont
375   = interesting cont
376   where
377     interesting (Select _ _ _ _ _)       = some_args
378     interesting (ApplyTo _ _ _ _)        = True -- Can happen if we have (coerce t (f x)) y
379                                                 -- Perhaps True is a bit over-keen, but I've
380                                                 -- seen (coerce f) x, where f has an INLINE prag,
381                                                 -- So we have to give some motivaiton for inlining it
382     interesting (ArgOf _ _ _ _)          = some_val_args
383     interesting (Stop ty _ interesting)  = some_val_args && interesting
384     interesting (CoerceIt _ cont)        = interesting cont
385         -- If this call is the arg of a strict function, the context
386         -- is a bit interesting.  If we inline here, we may get useful
387         -- evaluation information to avoid repeated evals: e.g.
388         --      x + (y * z)
389         -- Here the contIsInteresting makes the '*' keener to inline,
390         -- which in turn exposes a constructor which makes the '+' inline.
391         -- Assuming that +,* aren't small enough to inline regardless.
392         --
393         -- It's also very important to inline in a strict context for things
394         -- like
395         --              foldr k z (f x)
396         -- Here, the context of (f x) is strict, and if f's unfolding is
397         -- a build it's *great* to inline it here.  So we must ensure that
398         -- the context for (f x) is not totally uninteresting.
399
400
401 -------------------
402 interestingArgContext :: Id -> SimplCont -> Bool
403 -- If the argument has form (f x y), where x,y are boring,
404 -- and f is marked INLINE, then we don't want to inline f.
405 -- But if the context of the argument is
406 --      g (f x y) 
407 -- where g has rules, then we *do* want to inline f, in case it
408 -- exposes a rule that might fire.  Similarly, if the context is
409 --      h (g (f x x))
410 -- where h has rules, then we do want to inline f.
411 -- The interesting_arg_ctxt flag makes this happen; if it's
412 -- set, the inliner gets just enough keener to inline f 
413 -- regardless of how boring f's arguments are, if it's marked INLINE
414 --
415 -- The alternative would be to *always* inline an INLINE function,
416 -- regardless of how boring its context is; but that seems overkill
417 -- For example, it'd mean that wrapper functions were always inlined
418 interestingArgContext fn cont
419   = idHasRules fn || go cont
420   where
421     go (Select {})            = False
422     go (ApplyTo {})           = False
423     go (ArgOf {})             = True
424     go (CoerceIt _ c)         = go c
425     go (Stop _ _ interesting) = interesting
426
427 -------------------
428 canUpdateInPlace :: Type -> Bool
429 -- Consider   let x = <wurble> in ...
430 -- If <wurble> returns an explicit constructor, we might be able
431 -- to do update in place.  So we treat even a thunk RHS context
432 -- as interesting if update in place is possible.  We approximate
433 -- this by seeing if the type has a single constructor with a
434 -- small arity.  But arity zero isn't good -- we share the single copy
435 -- for that case, so no point in sharing.
436
437 canUpdateInPlace ty 
438   | not opt_UF_UpdateInPlace = False
439   | otherwise
440   = case splitTyConApp_maybe ty of 
441         Nothing         -> False 
442         Just (tycon, _) -> case tyConDataCons_maybe tycon of
443                                 Just [dc]  -> arity == 1 || arity == 2
444                                            where
445                                               arity = dataConRepArity dc
446                                 other -> False
447 \end{code}
448
449
450
451 %************************************************************************
452 %*                                                                      *
453 \subsection{Decisions about inlining}
454 %*                                                                      *
455 %************************************************************************
456
457 Inlining is controlled partly by the SimplifierMode switch.  This has two
458 settings:
459
460         SimplGently     (a) Simplifying before specialiser/full laziness
461                         (b) Simplifiying inside INLINE pragma
462                         (c) Simplifying the LHS of a rule
463                         (d) Simplifying a GHCi expression or Template 
464                                 Haskell splice
465
466         SimplPhase n    Used at all other times
467
468 The key thing about SimplGently is that it does no call-site inlining.
469 Before full laziness we must be careful not to inline wrappers,
470 because doing so inhibits floating
471     e.g. ...(case f x of ...)...
472     ==> ...(case (case x of I# x# -> fw x#) of ...)...
473     ==> ...(case x of I# x# -> case fw x# of ...)...
474 and now the redex (f x) isn't floatable any more.
475
476 The no-inlining thing is also important for Template Haskell.  You might be 
477 compiling in one-shot mode with -O2; but when TH compiles a splice before
478 running it, we don't want to use -O2.  Indeed, we don't want to inline
479 anything, because the byte-code interpreter might get confused about 
480 unboxed tuples and suchlike.
481
482 INLINE pragmas
483 ~~~~~~~~~~~~~~
484 SimplGently is also used as the mode to simplify inside an InlineMe note.
485
486 \begin{code}
487 inlineMode :: SimplifierMode
488 inlineMode = SimplGently
489 \end{code}
490
491 It really is important to switch off inlinings inside such
492 expressions.  Consider the following example 
493
494         let f = \pq -> BIG
495         in
496         let g = \y -> f y y
497             {-# INLINE g #-}
498         in ...g...g...g...g...g...
499
500 Now, if that's the ONLY occurrence of f, it will be inlined inside g,
501 and thence copied multiple times when g is inlined.
502
503
504 This function may be inlinined in other modules, so we
505 don't want to remove (by inlining) calls to functions that have
506 specialisations, or that may have transformation rules in an importing
507 scope.
508
509 E.g.    {-# INLINE f #-}
510                 f x = ...g...
511
512 and suppose that g is strict *and* has specialisations.  If we inline
513 g's wrapper, we deny f the chance of getting the specialised version
514 of g when f is inlined at some call site (perhaps in some other
515 module).
516
517 It's also important not to inline a worker back into a wrapper.
518 A wrapper looks like
519         wraper = inline_me (\x -> ...worker... )
520 Normally, the inline_me prevents the worker getting inlined into
521 the wrapper (initially, the worker's only call site!).  But,
522 if the wrapper is sure to be called, the strictness analyser will
523 mark it 'demanded', so when the RHS is simplified, it'll get an ArgOf
524 continuation.  That's why the keep_inline predicate returns True for
525 ArgOf continuations.  It shouldn't do any harm not to dissolve the
526 inline-me note under these circumstances.
527
528 Note that the result is that we do very little simplification
529 inside an InlineMe.  
530
531         all xs = foldr (&&) True xs
532         any p = all . map p  {-# INLINE any #-}
533
534 Problem: any won't get deforested, and so if it's exported and the
535 importer doesn't use the inlining, (eg passes it as an arg) then we
536 won't get deforestation at all.  We havn't solved this problem yet!
537
538
539 preInlineUnconditionally
540 ~~~~~~~~~~~~~~~~~~~~~~~~
541 @preInlineUnconditionally@ examines a bndr to see if it is used just
542 once in a completely safe way, so that it is safe to discard the
543 binding inline its RHS at the (unique) usage site, REGARDLESS of how
544 big the RHS might be.  If this is the case we don't simplify the RHS
545 first, but just inline it un-simplified.
546
547 This is much better than first simplifying a perhaps-huge RHS and then
548 inlining and re-simplifying it.  Indeed, it can be at least quadratically
549 better.  Consider
550
551         x1 = e1
552         x2 = e2[x1]
553         x3 = e3[x2]
554         ...etc...
555         xN = eN[xN-1]
556
557 We may end up simplifying e1 N times, e2 N-1 times, e3 N-3 times etc.
558 This can happen with cascades of functions too:
559
560         f1 = \x1.e1
561         f2 = \xs.e2[f1]
562         f3 = \xs.e3[f3]
563         ...etc...
564
565 THE MAIN INVARIANT is this:
566
567         ----  preInlineUnconditionally invariant -----
568    IF preInlineUnconditionally chooses to inline x = <rhs>
569    THEN doing the inlining should not change the occurrence
570         info for the free vars of <rhs>
571         ----------------------------------------------
572
573 For example, it's tempting to look at trivial binding like
574         x = y
575 and inline it unconditionally.  But suppose x is used many times,
576 but this is the unique occurrence of y.  Then inlining x would change
577 y's occurrence info, which breaks the invariant.  It matters: y
578 might have a BIG rhs, which will now be dup'd at every occurrenc of x.
579
580
581 Evne RHSs labelled InlineMe aren't caught here, because there might be
582 no benefit from inlining at the call site.
583
584 [Sept 01] Don't unconditionally inline a top-level thing, because that
585 can simply make a static thing into something built dynamically.  E.g.
586         x = (a,b)
587         main = \s -> h x
588
589 [Remember that we treat \s as a one-shot lambda.]  No point in
590 inlining x unless there is something interesting about the call site.
591
592 But watch out: if you aren't careful, some useful foldr/build fusion
593 can be lost (most notably in spectral/hartel/parstof) because the
594 foldr didn't see the build.  Doing the dynamic allocation isn't a big
595 deal, in fact, but losing the fusion can be.  But the right thing here
596 seems to be to do a callSiteInline based on the fact that there is
597 something interesting about the call site (it's strict).  Hmm.  That
598 seems a bit fragile.
599
600 Conclusion: inline top level things gaily until Phase 0 (the last
601 phase), at which point don't.
602
603 \begin{code}
604 preInlineUnconditionally :: SimplEnv -> TopLevelFlag -> InId -> InExpr -> Bool
605 preInlineUnconditionally env top_lvl bndr rhs
606   | not active             = False
607   | opt_SimplNoPreInlining = False
608   | otherwise = case idOccInfo bndr of
609                   IAmDead                    -> True    -- Happens in ((\x.1) v)
610                   OneOcc in_lam True int_cxt -> try_once in_lam int_cxt
611                   other                      -> False
612   where
613     phase = getMode env
614     active = case phase of
615                    SimplGently  -> isAlwaysActive prag
616                    SimplPhase n -> isActive n prag
617     prag = idInlinePragma bndr
618
619     try_once in_lam int_cxt     -- There's one textual occurrence
620         | not in_lam = isNotTopLevel top_lvl || early_phase
621         | otherwise  = int_cxt && canInlineInLam rhs
622
623 -- Be very careful before inlining inside a lambda, becuase (a) we must not 
624 -- invalidate occurrence information, and (b) we want to avoid pushing a
625 -- single allocation (here) into multiple allocations (inside lambda).  
626 -- Inlining a *function* with a single *saturated* call would be ok, mind you.
627 --      || (if is_cheap && not (canInlineInLam rhs) then pprTrace "preinline" (ppr bndr <+> ppr rhs) ok else ok)
628 --      where 
629 --              is_cheap = exprIsCheap rhs
630 --              ok = is_cheap && int_cxt
631
632         --      int_cxt         The context isn't totally boring
633         -- E.g. let f = \ab.BIG in \y. map f xs
634         --      Don't want to substitute for f, because then we allocate
635         --      its closure every time the \y is called
636         -- But: let f = \ab.BIG in \y. map (f y) xs
637         --      Now we do want to substitute for f, even though it's not 
638         --      saturated, because we're going to allocate a closure for 
639         --      (f y) every time round the loop anyhow.
640
641         -- canInlineInLam => free vars of rhs are (Once in_lam) or Many,
642         -- so substituting rhs inside a lambda doesn't change the occ info.
643         -- Sadly, not quite the same as exprIsHNF.
644     canInlineInLam (Lit l)              = True
645     canInlineInLam (Lam b e)            = isRuntimeVar b || canInlineInLam e
646     canInlineInLam (Note _ e)           = canInlineInLam e
647     canInlineInLam _                    = False
648
649     early_phase = case phase of
650                         SimplPhase 0 -> False
651                         other        -> True
652 -- If we don't have this early_phase test, consider
653 --      x = length [1,2,3]
654 -- The full laziness pass carefully floats all the cons cells to
655 -- top level, and preInlineUnconditionally floats them all back in.
656 -- Result is (a) static allocation replaced by dynamic allocation
657 --           (b) many simplifier iterations because this tickles
658 --               a related problem; only one inlining per pass
659 -- 
660 -- On the other hand, I have seen cases where top-level fusion is
661 -- lost if we don't inline top level thing (e.g. string constants)
662 -- Hence the test for phase zero (which is the phase for all the final
663 -- simplifications).  Until phase zero we take no special notice of
664 -- top level things, but then we become more leery about inlining
665 -- them.  
666
667 \end{code}
668
669 postInlineUnconditionally
670 ~~~~~~~~~~~~~~~~~~~~~~~~~
671 @postInlineUnconditionally@ decides whether to unconditionally inline
672 a thing based on the form of its RHS; in particular if it has a
673 trivial RHS.  If so, we can inline and discard the binding altogether.
674
675 NB: a loop breaker has must_keep_binding = True and non-loop-breakers
676 only have *forward* references Hence, it's safe to discard the binding
677         
678 NOTE: This isn't our last opportunity to inline.  We're at the binding
679 site right now, and we'll get another opportunity when we get to the
680 ocurrence(s)
681
682 Note that we do this unconditional inlining only for trival RHSs.
683 Don't inline even WHNFs inside lambdas; doing so may simply increase
684 allocation when the function is called. This isn't the last chance; see
685 NOTE above.
686
687 NB: Even inline pragmas (e.g. IMustBeINLINEd) are ignored here Why?
688 Because we don't even want to inline them into the RHS of constructor
689 arguments. See NOTE above
690
691 NB: At one time even NOINLINE was ignored here: if the rhs is trivial
692 it's best to inline it anyway.  We often get a=E; b=a from desugaring,
693 with both a and b marked NOINLINE.  But that seems incompatible with
694 our new view that inlining is like a RULE, so I'm sticking to the 'active'
695 story for now.
696
697 \begin{code}
698 postInlineUnconditionally :: SimplEnv -> TopLevelFlag -> OutId -> OccInfo -> OutExpr -> Unfolding -> Bool
699 postInlineUnconditionally env top_lvl bndr occ_info rhs unfolding
700   | not active             = False
701   | isLoopBreaker occ_info = False
702   | isExportedId bndr      = False
703   | exprIsTrivial rhs      = True
704   | otherwise
705   = case occ_info of
706       OneOcc in_lam one_br int_cxt
707         ->     (one_br || smallEnoughToInline unfolding)        -- Small enough to dup
708                         -- ToDo: consider discount on smallEnoughToInline if int_cxt is true
709                         --
710                         -- NB: Do we want to inline arbitrarily big things becuase
711                         -- one_br is True? that can lead to inline cascades.  But
712                         -- preInlineUnconditionlly has dealt with all the common cases
713                         -- so perhaps it's worth the risk. Here's an example
714                         --      let f = if b then Left (\x.BIG) else Right (\y.BIG)
715                         --      in \y. ....f....
716                         -- We can't preInlineUnconditionally because that woud invalidate
717                         -- the occ info for b.  Yet f is used just once, and duplicating
718                         -- the case work is fine (exprIsCheap).
719
720            &&  ((isNotTopLevel top_lvl && not in_lam) || 
721                         -- But outside a lambda, we want to be reasonably aggressive
722                         -- about inlining into multiple branches of case
723                         -- e.g. let x = <non-value> 
724                         --      in case y of { C1 -> ..x..; C2 -> ..x..; C3 -> ... } 
725                         -- Inlining can be a big win if C3 is the hot-spot, even if
726                         -- the uses in C1, C2 are not 'interesting'
727                         -- An example that gets worse if you add int_cxt here is 'clausify'
728
729                 (isCheapUnfolding unfolding && int_cxt))
730                         -- isCheap => acceptable work duplication; in_lam may be true
731                         -- int_cxt to prevent us inlining inside a lambda without some 
732                         -- good reason.  See the notes on int_cxt in preInlineUnconditionally
733
734       other -> False
735         -- The point here is that for *non-values* that occur
736         -- outside a lambda, the call-site inliner won't have
737         -- a chance (becuase it doesn't know that the thing
738         -- only occurs once).   The pre-inliner won't have gotten
739         -- it either, if the thing occurs in more than one branch
740         -- So the main target is things like
741         --      let x = f y in
742         --      case v of
743         --         True  -> case x of ...
744         --         False -> case x of ...
745         -- I'm not sure how important this is in practice
746   where
747     active = case getMode env of
748                    SimplGently  -> isAlwaysActive prag
749                    SimplPhase n -> isActive n prag
750     prag = idInlinePragma bndr
751
752 activeInline :: SimplEnv -> OutId -> OccInfo -> Bool
753 activeInline env id occ
754   = case getMode env of
755       SimplGently -> isOneOcc occ && isAlwaysActive prag
756         -- No inlining at all when doing gentle stuff,
757         -- except for local things that occur once
758         -- The reason is that too little clean-up happens if you 
759         -- don't inline use-once things.   Also a bit of inlining is *good* for
760         -- full laziness; it can expose constant sub-expressions.
761         -- Example in spectral/mandel/Mandel.hs, where the mandelset 
762         -- function gets a useful let-float if you inline windowToViewport
763
764         -- NB: we used to have a second exception, for data con wrappers.
765         -- On the grounds that we use gentle mode for rule LHSs, and 
766         -- they match better when data con wrappers are inlined.
767         -- But that only really applies to the trivial wrappers (like (:)),
768         -- and they are now constructed as Compulsory unfoldings (in MkId)
769         -- so they'll happen anyway.
770
771       SimplPhase n -> isActive n prag
772   where
773     prag = idInlinePragma id
774
775 activeRule :: SimplEnv -> Maybe (Activation -> Bool)
776 -- Nothing => No rules at all
777 activeRule env
778   | opt_RulesOff = Nothing
779   | otherwise
780   = case getMode env of
781         SimplGently  -> Just isAlwaysActive
782                         -- Used to be Nothing (no rules in gentle mode)
783                         -- Main motivation for changing is that I wanted
784                         --      lift String ===> ...
785                         -- to work in Template Haskell when simplifying
786                         -- splices, so we get simpler code for literal strings
787         SimplPhase n -> Just (isActive n)
788 \end{code}      
789
790
791 %************************************************************************
792 %*                                                                      *
793 \subsection{Rebuilding a lambda}
794 %*                                                                      *
795 %************************************************************************
796
797 \begin{code}
798 mkLam :: SimplEnv -> [OutBinder] -> OutExpr -> SimplCont -> SimplM FloatsWithExpr
799 \end{code}
800
801 Try three things
802         a) eta reduction, if that gives a trivial expression
803         b) eta expansion [only if there are some value lambdas]
804         c) floating lets out through big lambdas 
805                 [only if all tyvar lambdas, and only if this lambda
806                  is the RHS of a let]
807
808 \begin{code}
809 mkLam env bndrs body cont
810  = getDOptsSmpl  `thenSmpl` \dflags ->
811    mkLam' dflags env bndrs body cont
812  where
813  mkLam' dflags env bndrs body cont
814    | dopt Opt_DoEtaReduction dflags,
815      Just etad_lam <- tryEtaReduce bndrs body
816    = tick (EtaReduction (head bndrs))   `thenSmpl_`
817      returnSmpl (emptyFloats env, etad_lam)
818
819    | dopt Opt_DoLambdaEtaExpansion dflags,
820      any isRuntimeVar bndrs
821    = tryEtaExpansion dflags body        `thenSmpl` \ body' ->
822      returnSmpl (emptyFloats env, mkLams bndrs body')
823
824 {-      Sept 01: I'm experimenting with getting the
825         full laziness pass to float out past big lambdsa
826  | all isTyVar bndrs,   -- Only for big lambdas
827    contIsRhs cont       -- Only try the rhs type-lambda floating
828                         -- if this is indeed a right-hand side; otherwise
829                         -- we end up floating the thing out, only for float-in
830                         -- to float it right back in again!
831  = tryRhsTyLam env bndrs body           `thenSmpl` \ (floats, body') ->
832    returnSmpl (floats, mkLams bndrs body')
833 -}
834
835    | otherwise 
836    = returnSmpl (emptyFloats env, mkLams bndrs body)
837 \end{code}
838
839
840 %************************************************************************
841 %*                                                                      *
842 \subsection{Eta expansion and reduction}
843 %*                                                                      *
844 %************************************************************************
845
846 We try for eta reduction here, but *only* if we get all the 
847 way to an exprIsTrivial expression.    
848 We don't want to remove extra lambdas unless we are going 
849 to avoid allocating this thing altogether
850
851 \begin{code}
852 tryEtaReduce :: [OutBinder] -> OutExpr -> Maybe OutExpr
853 tryEtaReduce bndrs body 
854         -- We don't use CoreUtils.etaReduce, because we can be more
855         -- efficient here:
856         --  (a) we already have the binders
857         --  (b) we can do the triviality test before computing the free vars
858   = go (reverse bndrs) body
859   where
860     go (b : bs) (App fun arg) | ok_arg b arg = go bs fun        -- Loop round
861     go []       fun           | ok_fun fun   = Just fun         -- Success!
862     go _        _                            = Nothing          -- Failure!
863
864     ok_fun fun =  exprIsTrivial fun
865                && not (any (`elemVarSet` (exprFreeVars fun)) bndrs)
866                && (exprIsHNF fun || all ok_lam bndrs)
867     ok_lam v = isTyVar v || isDictId v
868         -- The exprIsHNF is because eta reduction is not 
869         -- valid in general:  \x. bot  /=  bot
870         -- So we need to be sure that the "fun" is a value.
871         --
872         -- However, we always want to reduce (/\a -> f a) to f
873         -- This came up in a RULE: foldr (build (/\a -> g a))
874         --      did not match      foldr (build (/\b -> ...something complex...))
875         -- The type checker can insert these eta-expanded versions,
876         -- with both type and dictionary lambdas; hence the slightly 
877         -- ad-hoc isDictTy
878
879     ok_arg b arg = varToCoreExpr b `cheapEqExpr` arg
880 \end{code}
881
882
883         Try eta expansion for RHSs
884
885 We go for:
886    f = \x1..xn -> N  ==>   f = \x1..xn y1..ym -> N y1..ym
887                                  (n >= 0)
888
889 where (in both cases) 
890
891         * The xi can include type variables
892
893         * The yi are all value variables
894
895         * N is a NORMAL FORM (i.e. no redexes anywhere)
896           wanting a suitable number of extra args.
897
898 We may have to sandwich some coerces between the lambdas
899 to make the types work.   exprEtaExpandArity looks through coerces
900 when computing arity; and etaExpand adds the coerces as necessary when
901 actually computing the expansion.
902
903 \begin{code}
904 tryEtaExpansion :: DynFlags -> OutExpr -> SimplM OutExpr
905 -- There is at least one runtime binder in the binders
906 tryEtaExpansion dflags body
907   = getUniquesSmpl                      `thenSmpl` \ us ->
908     returnSmpl (etaExpand fun_arity us body (exprType body))
909   where
910     fun_arity = exprEtaExpandArity dflags body
911 \end{code}
912
913
914 %************************************************************************
915 %*                                                                      *
916 \subsection{Floating lets out of big lambdas}
917 %*                                                                      *
918 %************************************************************************
919
920 tryRhsTyLam tries this transformation, when the big lambda appears as
921 the RHS of a let(rec) binding:
922
923         /\abc -> let(rec) x = e in b
924    ==>
925         let(rec) x' = /\abc -> let x = x' a b c in e
926         in 
927         /\abc -> let x = x' a b c in b
928
929 This is good because it can turn things like:
930
931         let f = /\a -> letrec g = ... g ... in g
932 into
933         letrec g' = /\a -> ... g' a ...
934         in
935         let f = /\ a -> g' a
936
937 which is better.  In effect, it means that big lambdas don't impede
938 let-floating.
939
940 This optimisation is CRUCIAL in eliminating the junk introduced by
941 desugaring mutually recursive definitions.  Don't eliminate it lightly!
942
943 So far as the implementation is concerned:
944
945         Invariant: go F e = /\tvs -> F e
946         
947         Equalities:
948                 go F (Let x=e in b)
949                 = Let x' = /\tvs -> F e 
950                   in 
951                   go G b
952                 where
953                     G = F . Let x = x' tvs
954         
955                 go F (Letrec xi=ei in b)
956                 = Letrec {xi' = /\tvs -> G ei} 
957                   in
958                   go G b
959                 where
960                   G = F . Let {xi = xi' tvs}
961
962 [May 1999]  If we do this transformation *regardless* then we can
963 end up with some pretty silly stuff.  For example, 
964
965         let 
966             st = /\ s -> let { x1=r1 ; x2=r2 } in ...
967         in ..
968 becomes
969         let y1 = /\s -> r1
970             y2 = /\s -> r2
971             st = /\s -> ...[y1 s/x1, y2 s/x2]
972         in ..
973
974 Unless the "..." is a WHNF there is really no point in doing this.
975 Indeed it can make things worse.  Suppose x1 is used strictly,
976 and is of the form
977
978         x1* = case f y of { (a,b) -> e }
979
980 If we abstract this wrt the tyvar we then can't do the case inline
981 as we would normally do.
982
983
984 \begin{code}
985 {-      Trying to do this in full laziness
986
987 tryRhsTyLam :: SimplEnv -> [OutTyVar] -> OutExpr -> SimplM FloatsWithExpr
988 -- Call ensures that all the binders are type variables
989
990 tryRhsTyLam env tyvars body             -- Only does something if there's a let
991   |  not (all isTyVar tyvars)
992   || not (worth_it body)                -- inside a type lambda, 
993   = returnSmpl (emptyFloats env, body)  -- and a WHNF inside that
994
995   | otherwise
996   = go env (\x -> x) body
997
998   where
999     worth_it e@(Let _ _) = whnf_in_middle e
1000     worth_it e           = False
1001
1002     whnf_in_middle (Let (NonRec x rhs) e) | isUnLiftedType (idType x) = False
1003     whnf_in_middle (Let _ e) = whnf_in_middle e
1004     whnf_in_middle e         = exprIsCheap e
1005
1006     main_tyvar_set = mkVarSet tyvars
1007
1008     go env fn (Let bind@(NonRec var rhs) body)
1009       | exprIsTrivial rhs
1010       = go env (fn . Let bind) body
1011
1012     go env fn (Let (NonRec var rhs) body)
1013       = mk_poly tyvars_here var                                                 `thenSmpl` \ (var', rhs') ->
1014         addAuxiliaryBind env (NonRec var' (mkLams tyvars_here (fn rhs)))        $ \ env -> 
1015         go env (fn . Let (mk_silly_bind var rhs')) body
1016
1017       where
1018
1019         tyvars_here = varSetElems (main_tyvar_set `intersectVarSet` exprSomeFreeVars isTyVar rhs)
1020                 -- Abstract only over the type variables free in the rhs
1021                 -- wrt which the new binding is abstracted.  But the naive
1022                 -- approach of abstract wrt the tyvars free in the Id's type
1023                 -- fails. Consider:
1024                 --      /\ a b -> let t :: (a,b) = (e1, e2)
1025                 --                    x :: a     = fst t
1026                 --                in ...
1027                 -- Here, b isn't free in x's type, but we must nevertheless
1028                 -- abstract wrt b as well, because t's type mentions b.
1029                 -- Since t is floated too, we'd end up with the bogus:
1030                 --      poly_t = /\ a b -> (e1, e2)
1031                 --      poly_x = /\ a   -> fst (poly_t a *b*)
1032                 -- So for now we adopt the even more naive approach of
1033                 -- abstracting wrt *all* the tyvars.  We'll see if that
1034                 -- gives rise to problems.   SLPJ June 98
1035
1036     go env fn (Let (Rec prs) body)
1037        = mapAndUnzipSmpl (mk_poly tyvars_here) vars     `thenSmpl` \ (vars', rhss') ->
1038          let
1039             gn body = fn (foldr Let body (zipWith mk_silly_bind vars rhss'))
1040             pairs   = vars' `zip` [mkLams tyvars_here (gn rhs) | rhs <- rhss]
1041          in
1042          addAuxiliaryBind env (Rec pairs)               $ \ env ->
1043          go env gn body 
1044        where
1045          (vars,rhss) = unzip prs
1046          tyvars_here = varSetElems (main_tyvar_set `intersectVarSet` exprsSomeFreeVars isTyVar (map snd prs))
1047                 -- See notes with tyvars_here above
1048
1049     go env fn body = returnSmpl (emptyFloats env, fn body)
1050
1051     mk_poly tyvars_here var
1052       = getUniqueSmpl           `thenSmpl` \ uniq ->
1053         let
1054             poly_name = setNameUnique (idName var) uniq         -- Keep same name
1055             poly_ty   = mkForAllTys tyvars_here (idType var)    -- But new type of course
1056             poly_id   = mkLocalId poly_name poly_ty 
1057
1058                 -- In the olden days, it was crucial to copy the occInfo of the original var, 
1059                 -- because we were looking at occurrence-analysed but as yet unsimplified code!
1060                 -- In particular, we mustn't lose the loop breakers.  BUT NOW we are looking
1061                 -- at already simplified code, so it doesn't matter
1062                 -- 
1063                 -- It's even right to retain single-occurrence or dead-var info:
1064                 -- Suppose we started with  /\a -> let x = E in B
1065                 -- where x occurs once in B. Then we transform to:
1066                 --      let x' = /\a -> E in /\a -> let x* = x' a in B
1067                 -- where x* has an INLINE prag on it.  Now, once x* is inlined,
1068                 -- the occurrences of x' will be just the occurrences originally
1069                 -- pinned on x.
1070         in
1071         returnSmpl (poly_id, mkTyApps (Var poly_id) (mkTyVarTys tyvars_here))
1072
1073     mk_silly_bind var rhs = NonRec var (Note InlineMe rhs)
1074                 -- Suppose we start with:
1075                 --
1076                 --      x = /\ a -> let g = G in E
1077                 --
1078                 -- Then we'll float to get
1079                 --
1080                 --      x = let poly_g = /\ a -> G
1081                 --          in /\ a -> let g = poly_g a in E
1082                 --
1083                 -- But now the occurrence analyser will see just one occurrence
1084                 -- of poly_g, not inside a lambda, so the simplifier will
1085                 -- PreInlineUnconditionally poly_g back into g!  Badk to square 1!
1086                 -- (I used to think that the "don't inline lone occurrences" stuff
1087                 --  would stop this happening, but since it's the *only* occurrence,
1088                 --  PreInlineUnconditionally kicks in first!)
1089                 --
1090                 -- Solution: put an INLINE note on g's RHS, so that poly_g seems
1091                 --           to appear many times.  (NB: mkInlineMe eliminates
1092                 --           such notes on trivial RHSs, so do it manually.)
1093 -}
1094 \end{code}
1095
1096 %************************************************************************
1097 %*                                                                      *
1098 \subsection{Case absorption and identity-case elimination}
1099 %*                                                                      *
1100 %************************************************************************
1101
1102 mkCase puts a case expression back together, trying various transformations first.
1103
1104 \begin{code}
1105 mkCase :: OutExpr -> OutId -> OutType
1106        -> [OutAlt]              -- Increasing order
1107        -> SimplM OutExpr
1108
1109 mkCase scrut case_bndr ty alts
1110   = getDOptsSmpl                        `thenSmpl` \dflags ->
1111     mkAlts dflags scrut case_bndr alts  `thenSmpl` \ better_alts ->
1112     mkCase1 scrut case_bndr ty better_alts
1113 \end{code}
1114
1115
1116 mkAlts tries these things:
1117
1118 1.  If several alternatives are identical, merge them into
1119     a single DEFAULT alternative.  I've occasionally seen this 
1120     making a big difference:
1121
1122         case e of               =====>     case e of
1123           C _ -> f x                         D v -> ....v....
1124           D v -> ....v....                   DEFAULT -> f x
1125           DEFAULT -> f x
1126
1127    The point is that we merge common RHSs, at least for the DEFAULT case.
1128    [One could do something more elaborate but I've never seen it needed.]
1129    To avoid an expensive test, we just merge branches equal to the *first*
1130    alternative; this picks up the common cases
1131         a) all branches equal
1132         b) some branches equal to the DEFAULT (which occurs first)
1133
1134 2.  Case merging:
1135        case e of b {             ==>   case e of b {
1136          p1 -> rhs1                      p1 -> rhs1
1137          ...                             ...
1138          pm -> rhsm                      pm -> rhsm
1139          _  -> case b of b' {            pn -> let b'=b in rhsn
1140                      pn -> rhsn          ...
1141                      ...                 po -> let b'=b in rhso
1142                      po -> rhso          _  -> let b'=b in rhsd
1143                      _  -> rhsd
1144        }  
1145     
1146     which merges two cases in one case when -- the default alternative of
1147     the outer case scrutises the same variable as the outer case This
1148     transformation is called Case Merging.  It avoids that the same
1149     variable is scrutinised multiple times.
1150
1151
1152 The case where transformation (1) showed up was like this (lib/std/PrelCError.lhs):
1153
1154         x | p `is` 1 -> e1
1155           | p `is` 2 -> e2
1156         ...etc...
1157
1158 where @is@ was something like
1159         
1160         p `is` n = p /= (-1) && p == n
1161
1162 This gave rise to a horrible sequence of cases
1163
1164         case p of
1165           (-1) -> $j p
1166           1    -> e1
1167           DEFAULT -> $j p
1168
1169 and similarly in cascade for all the join points!
1170
1171
1172
1173 \begin{code}
1174 --------------------------------------------------
1175 --      1. Merge identical branches
1176 --------------------------------------------------
1177 mkAlts dflags scrut case_bndr alts@((con1,bndrs1,rhs1) : con_alts)
1178   | all isDeadBinder bndrs1,                    -- Remember the default 
1179     length filtered_alts < length con_alts      -- alternative comes first
1180   = tick (AltMerge case_bndr)                   `thenSmpl_`
1181     returnSmpl better_alts
1182   where
1183     filtered_alts        = filter keep con_alts
1184     keep (con,bndrs,rhs) = not (all isDeadBinder bndrs && rhs `cheapEqExpr` rhs1)
1185     better_alts          = (DEFAULT, [], rhs1) : filtered_alts
1186
1187
1188 --------------------------------------------------
1189 --      2.  Merge nested cases
1190 --------------------------------------------------
1191
1192 mkAlts dflags scrut outer_bndr outer_alts
1193   | dopt Opt_CaseMerge dflags,
1194     (outer_alts_without_deflt, maybe_outer_deflt)   <- findDefault outer_alts,
1195     Just (Case (Var scrut_var) inner_bndr _ inner_alts) <- maybe_outer_deflt,
1196     scruting_same_var scrut_var
1197   = let
1198         munged_inner_alts = [(con, args, munge_rhs rhs) | (con, args, rhs) <- inner_alts]
1199         munge_rhs rhs = bindCaseBndr inner_bndr (Var outer_bndr) rhs
1200   
1201         new_alts = mergeAlts outer_alts_without_deflt munged_inner_alts
1202                 -- The merge keeps the inner DEFAULT at the front, if there is one
1203                 -- and eliminates any inner_alts that are shadowed by the outer_alts
1204     in
1205     tick (CaseMerge outer_bndr)                         `thenSmpl_`
1206     returnSmpl new_alts
1207         -- Warning: don't call mkAlts recursively!
1208         -- Firstly, there's no point, because inner alts have already had
1209         -- mkCase applied to them, so they won't have a case in their default
1210         -- Secondly, if you do, you get an infinite loop, because the bindCaseBndr
1211         -- in munge_rhs may put a case into the DEFAULT branch!
1212   where
1213         -- We are scrutinising the same variable if it's
1214         -- the outer case-binder, or if the outer case scrutinises a variable
1215         -- (and it's the same).  Testing both allows us not to replace the
1216         -- outer scrut-var with the outer case-binder (Simplify.simplCaseBinder).
1217     scruting_same_var = case scrut of
1218                           Var outer_scrut -> \ v -> v == outer_bndr || v == outer_scrut
1219                           other           -> \ v -> v == outer_bndr
1220
1221 ------------------------------------------------
1222 --      Catch-all
1223 ------------------------------------------------
1224
1225 mkAlts dflags scrut case_bndr other_alts = returnSmpl other_alts
1226 \end{code}
1227
1228
1229
1230 =================================================================================
1231
1232 mkCase1 tries these things
1233
1234 1.  Eliminate the case altogether if possible
1235
1236 2.  Case-identity:
1237
1238         case e of               ===> e
1239                 True  -> True;
1240                 False -> False
1241
1242     and similar friends.
1243
1244
1245 Start with a simple situation:
1246
1247         case x# of      ===>   e[x#/y#]
1248           y# -> e
1249
1250 (when x#, y# are of primitive type, of course).  We can't (in general)
1251 do this for algebraic cases, because we might turn bottom into
1252 non-bottom!
1253
1254 Actually, we generalise this idea to look for a case where we're
1255 scrutinising a variable, and we know that only the default case can
1256 match.  For example:
1257 \begin{verbatim}
1258         case x of
1259           0#    -> ...
1260           other -> ...(case x of
1261                          0#    -> ...
1262                          other -> ...) ...
1263 \end{code}
1264 Here the inner case can be eliminated.  This really only shows up in
1265 eliminating error-checking code.
1266
1267 We also make sure that we deal with this very common case:
1268
1269         case e of 
1270           x -> ...x...
1271
1272 Here we are using the case as a strict let; if x is used only once
1273 then we want to inline it.  We have to be careful that this doesn't 
1274 make the program terminate when it would have diverged before, so we
1275 check that 
1276         - x is used strictly, or
1277         - e is already evaluated (it may so if e is a variable)
1278
1279 Lastly, we generalise the transformation to handle this:
1280
1281         case e of       ===> r
1282            True  -> r
1283            False -> r
1284
1285 We only do this for very cheaply compared r's (constructors, literals
1286 and variables).  If pedantic bottoms is on, we only do it when the
1287 scrutinee is a PrimOp which can't fail.
1288
1289 We do it *here*, looking at un-simplified alternatives, because we
1290 have to check that r doesn't mention the variables bound by the
1291 pattern in each alternative, so the binder-info is rather useful.
1292
1293 So the case-elimination algorithm is:
1294
1295         1. Eliminate alternatives which can't match
1296
1297         2. Check whether all the remaining alternatives
1298                 (a) do not mention in their rhs any of the variables bound in their pattern
1299            and  (b) have equal rhss
1300
1301         3. Check we can safely ditch the case:
1302                    * PedanticBottoms is off,
1303                 or * the scrutinee is an already-evaluated variable
1304                 or * the scrutinee is a primop which is ok for speculation
1305                         -- ie we want to preserve divide-by-zero errors, and
1306                         -- calls to error itself!
1307
1308                 or * [Prim cases] the scrutinee is a primitive variable
1309
1310                 or * [Alg cases] the scrutinee is a variable and
1311                      either * the rhs is the same variable
1312                         (eg case x of C a b -> x  ===>   x)
1313                      or     * there is only one alternative, the default alternative,
1314                                 and the binder is used strictly in its scope.
1315                                 [NB this is helped by the "use default binder where
1316                                  possible" transformation; see below.]
1317
1318
1319 If so, then we can replace the case with one of the rhss.
1320
1321 Further notes about case elimination
1322 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1323 Consider:       test :: Integer -> IO ()
1324                 test = print
1325
1326 Turns out that this compiles to:
1327     Print.test
1328       = \ eta :: Integer
1329           eta1 :: State# RealWorld ->
1330           case PrelNum.< eta PrelNum.zeroInteger of wild { __DEFAULT ->
1331           case hPutStr stdout
1332                  (PrelNum.jtos eta ($w[] @ Char))
1333                  eta1
1334           of wild1 { (# new_s, a4 #) -> PrelIO.lvl23 new_s  }}
1335
1336 Notice the strange '<' which has no effect at all. This is a funny one.  
1337 It started like this:
1338
1339 f x y = if x < 0 then jtos x
1340           else if y==0 then "" else jtos x
1341
1342 At a particular call site we have (f v 1).  So we inline to get
1343
1344         if v < 0 then jtos x 
1345         else if 1==0 then "" else jtos x
1346
1347 Now simplify the 1==0 conditional:
1348
1349         if v<0 then jtos v else jtos v
1350
1351 Now common-up the two branches of the case:
1352
1353         case (v<0) of DEFAULT -> jtos v
1354
1355 Why don't we drop the case?  Because it's strict in v.  It's technically
1356 wrong to drop even unnecessary evaluations, and in practice they
1357 may be a result of 'seq' so we *definitely* don't want to drop those.
1358 I don't really know how to improve this situation.
1359
1360
1361 \begin{code}
1362 --------------------------------------------------
1363 --      0. Check for empty alternatives
1364 --------------------------------------------------
1365
1366 -- This isn't strictly an error.  It's possible that the simplifer might "see"
1367 -- that an inner case has no accessible alternatives before it "sees" that the
1368 -- entire branch of an outer case is inaccessible.  So we simply
1369 -- put an error case here insteadd
1370 mkCase1 scrut case_bndr ty []
1371   = pprTrace "mkCase1: null alts" (ppr case_bndr <+> ppr scrut) $
1372     return (mkApps (Var eRROR_ID)
1373                    [Type ty, Lit (mkStringLit "Impossible alternative")])
1374
1375 --------------------------------------------------
1376 --      1. Eliminate the case altogether if poss
1377 --------------------------------------------------
1378
1379 mkCase1 scrut case_bndr ty [(con,bndrs,rhs)]
1380   -- See if we can get rid of the case altogether
1381   -- See the extensive notes on case-elimination above
1382   -- mkCase made sure that if all the alternatives are equal, 
1383   -- then there is now only one (DEFAULT) rhs
1384  |  all isDeadBinder bndrs,
1385
1386         -- Check that the scrutinee can be let-bound instead of case-bound
1387     exprOkForSpeculation scrut
1388                 -- OK not to evaluate it
1389                 -- This includes things like (==# a# b#)::Bool
1390                 -- so that we simplify 
1391                 --      case ==# a# b# of { True -> x; False -> x }
1392                 -- to just
1393                 --      x
1394                 -- This particular example shows up in default methods for
1395                 -- comparision operations (e.g. in (>=) for Int.Int32)
1396         || exprIsHNF scrut                      -- It's already evaluated
1397         || var_demanded_later scrut             -- It'll be demanded later
1398
1399 --      || not opt_SimplPedanticBottoms)        -- Or we don't care!
1400 --      We used to allow improving termination by discarding cases, unless -fpedantic-bottoms was on,
1401 --      but that breaks badly for the dataToTag# primop, which relies on a case to evaluate
1402 --      its argument:  case x of { y -> dataToTag# y }
1403 --      Here we must *not* discard the case, because dataToTag# just fetches the tag from
1404 --      the info pointer.  So we'll be pedantic all the time, and see if that gives any
1405 --      other problems
1406 --      Also we don't want to discard 'seq's
1407   = tick (CaseElim case_bndr)                   `thenSmpl_` 
1408     returnSmpl (bindCaseBndr case_bndr scrut rhs)
1409
1410   where
1411         -- The case binder is going to be evaluated later, 
1412         -- and the scrutinee is a simple variable
1413     var_demanded_later (Var v) = isStrictDmd (idNewDemandInfo case_bndr)
1414     var_demanded_later other   = False
1415
1416
1417 --------------------------------------------------
1418 --      2. Identity case
1419 --------------------------------------------------
1420
1421 mkCase1 scrut case_bndr ty alts -- Identity case
1422   | all identity_alt alts
1423   = tick (CaseIdentity case_bndr)               `thenSmpl_`
1424     returnSmpl (re_note scrut)
1425   where
1426     identity_alt (con, args, rhs) = de_note rhs `cheapEqExpr` identity_rhs con args
1427
1428     identity_rhs (DataAlt con) args = mkConApp con (arg_tys ++ map varToCoreExpr args)
1429     identity_rhs (LitAlt lit)  _    = Lit lit
1430     identity_rhs DEFAULT       _    = Var case_bndr
1431
1432     arg_tys = map Type (tyConAppArgs (idType case_bndr))
1433
1434         -- We've seen this:
1435         --      case coerce T e of x { _ -> coerce T' x }
1436         -- And we definitely want to eliminate this case!
1437         -- So we throw away notes from the RHS, and reconstruct
1438         -- (at least an approximation) at the other end
1439     de_note (Note _ e) = de_note e
1440     de_note e          = e
1441
1442         -- re_note wraps a coerce if it might be necessary
1443     re_note scrut = case head alts of
1444                         (_,_,rhs1@(Note _ _)) -> mkCoerce2 (exprType rhs1) (idType case_bndr) scrut
1445                         other                 -> scrut
1446
1447
1448 --------------------------------------------------
1449 --      Catch-all
1450 --------------------------------------------------
1451 mkCase1 scrut bndr ty alts = returnSmpl (Case scrut bndr ty alts)
1452 \end{code}
1453
1454
1455 When adding auxiliary bindings for the case binder, it's worth checking if
1456 its dead, because it often is, and occasionally these mkCase transformations
1457 cascade rather nicely.
1458
1459 \begin{code}
1460 bindCaseBndr bndr rhs body
1461   | isDeadBinder bndr = body
1462   | otherwise         = bindNonRec bndr rhs body
1463 \end{code}