base: Import Data.Int in KQueue
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.1], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl this makes sure `./configure --target=<cross-compile-target>`
37 dnl works as expected, since we're slightly modifying how Autoconf
38 dnl interprets build/host/target and how this interacts with $CC tests
39 test -n "$target_alias" && ac_tool_prefix=$target_alias-
40
41 dnl ----------------------------------------------------------
42 dnl ** Find unixy sort and find commands,
43 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
44
45 dnl ** Find find command (for Win32's benefit)
46 FP_PROG_FIND
47 FP_PROG_SORT
48
49 dnl ----------------------------------------------------------
50 FP_SETUP_PROJECT_VERSION
51
52 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
53 AC_SUBST([release], [1])
54
55 # First off, a distrib sanity check..
56 AC_CONFIG_SRCDIR([mk/config.mk.in])
57
58 dnl * We require autoconf version 2.60
59 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
60 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
61 dnl Using autoconf 2.59 started to give nonsense like this
62 dnl  #define SIZEOF_CHAR 0
63 dnl recently.
64 AC_PREREQ([2.60])
65
66 # -------------------------------------------------------------------------
67 # Prepare to generate the following header files
68 #
69 #
70 AC_CONFIG_HEADER(mk/config.h)
71
72 # No, semi-sadly, we don't do `--srcdir'...
73 if test x"$srcdir" != 'x.' ; then
74     echo "This configuration does not support the \`--srcdir' option.."
75     exit 1
76 fi
77
78 dnl --------------------------------------------------------------
79 dnl * Project specific configuration options
80 dnl --------------------------------------------------------------
81 dnl What follows is a bunch of options that can either be configured
82 dnl through command line options to the configure script or by
83 dnl supplying defns in the build tree's mk/build.mk. Having the option to
84 dnl use either is considered a Feature.
85
86 dnl ** What command to use to compile compiler sources ?
87 dnl --------------------------------------------------------------
88
89 AC_ARG_WITH([ghc],
90 [AC_HELP_STRING([--with-ghc=ARG],
91   [Use ARG as the path to GHC  [default=autodetect]])],
92   [WithGhc="$withval"],
93   [if test "$GHC" = ""; then
94     AC_PATH_PROG([GHC], [ghc])
95   fi
96   WithGhc="$GHC"])
97
98 dnl ** Tell the make system which OS we are using
99 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
100 AC_SUBST(OSTYPE)
101
102 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
103 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
104                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
105         EnableBootstrapWithDevelSnaphost=YES,
106         EnableBootstrapWithDevelSnaphost=NO
107 )
108
109 AC_ARG_ENABLE(tarballs-autodownload,
110 [AC_HELP_STRING([--enable-tarballs-autodownload],
111                 [Automatically download Windows distribution binaries if needed.])],
112         TarballsAutodownload=YES,
113         TarballsAutodownload=NO
114 )
115
116 dnl CC_STAGE0 is like the "previous" variable CC (inherited by CC_STAGE[123])
117 dnl but instead used by stage0 for bootstrapping stage1
118 AC_ARG_VAR(CC_STAGE0, [C compiler command (bootstrap)])
119
120 if test "$WithGhc" != ""; then
121   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
122
123   if test "$GhcMajVersion" = "unknown" || test "$GhcMinVersion" = "unknown"; then
124      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
125   fi
126
127   AC_SUBST(GhcVersion)dnl
128   AC_SUBST(GhcMajVersion)dnl
129   AC_SUBST(GhcMinVersion)dnl
130   AC_SUBST(GhcPatchLevel)dnl
131   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
132   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
133
134   dnl infer CC_STAGE0 from `ghc --info` unless explicitly set by user
135   if test -z "$CC_STAGE0"; then
136     BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
137   fi
138
139   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
140   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
141   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
142   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
143 fi
144
145 dnl ** Must have GHC to build GHC
146 if test "$WithGhc" = ""
147 then
148     AC_MSG_ERROR([GHC is required.])
149 fi
150 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.10],
151     [AC_MSG_ERROR([GHC version 7.10 or later is required to compile GHC.])])
152
153 if test `expr $GhcMinVersion % 2` = "1"
154 then
155     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
156     then
157         AC_MSG_ERROR([
158      $WithGhc is a development snapshot of GHC, version $GhcVersion.
159      Bootstrapping using this version of GHC is not supported, and may not
160      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
161      or --with-ghc to specify a different GHC to use.])
162     fi
163 fi
164
165 GHC_PACKAGE_DB_FLAG=package-db
166 AC_SUBST(GHC_PACKAGE_DB_FLAG)
167
168 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.11],
169                     SUPPORTS_THIS_UNIT_ID=NO,
170                     SUPPORTS_THIS_UNIT_ID=YES)
171 AC_SUBST(SUPPORTS_THIS_UNIT_ID)
172
173 # GHC is passed to Cabal, so we need a native path
174 if test "${WithGhc}" != ""
175 then
176     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
177
178     if test "$ghc_host_os" = "mingw32"
179     then
180         # Canonicalise to <drive>:/path/to/ghc
181         WithGhc=`cygpath -m "${WithGhc}"`
182
183         echo "GHC path canonicalised to: ${WithGhc}"
184     fi
185 fi
186 AC_SUBST([WithGhc])
187
188 dnl ** Without optimization some INLINE trickery fails for GHCi
189 SRC_CC_OPTS="-O"
190
191 dnl--------------------------------------------------------------------
192 dnl * Choose host(/target/build) platform
193 dnl--------------------------------------------------------------------
194 dnl If we aren't explicitly told what values to use with configure flags,
195 dnl we ask the bootstrapping compiler what platform it is for
196
197 if test "${WithGhc}" != ""
198 then
199         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
200         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
201         if test "$bootstrap_host" != "$bootstrap_target"
202         then
203                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
204         fi
205 fi
206
207 # We have to run these unconditionally, but we may discard their
208 # results in the following code
209 AC_CANONICAL_BUILD
210 AC_CANONICAL_HOST
211 AC_CANONICAL_TARGET
212
213 FPTOOLS_SET_PLATFORM_VARS
214
215 # Verify that the installed (bootstrap) GHC is capable of generating
216 # code for the requested build platform.
217 if test "$BuildPlatform" != "$bootstrap_target"
218 then
219     echo "This GHC (${WithGhc}) does not generate code for the build platform"
220     echo "   GHC target platform    : $bootstrap_target"
221     echo "   Desired build platform : $BuildPlatform"
222     exit 1
223 fi
224
225 # Testing if we shall enable shared libs support on Solaris.
226 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
227
228 SOLARIS_BROKEN_SHLD=NO
229
230 case $host in
231      i386-*-solaris2)
232      # here we go with the test
233      MINOR=`uname -r|cut -d '.' -f 2-`
234      if test "$MINOR" -lt "11"; then
235          SOLARIS_BROKEN_SHLD=YES
236      fi
237      ;;
238 esac
239
240 AC_SUBST(SOLARIS_BROKEN_SHLD)
241
242 dnl ** Do an unregisterised build?
243 dnl --------------------------------------------------------------
244 case "$HostArch" in
245     i386|x86_64|powerpc|powerpc64|powerpc64le|arm)
246         UnregisterisedDefault=NO
247         ;;
248     *)
249         UnregisterisedDefault=YES
250         ;;
251 esac
252 AC_ARG_ENABLE(unregisterised,
253 [AC_HELP_STRING([--enable-unregisterised],
254 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
255 [ if test x"$enableval" = x"yes"; then
256         Unregisterised=YES
257   else
258         Unregisterised=NO
259   fi
260 ],
261 [Unregisterised="$UnregisterisedDefault"]
262 )
263 AC_SUBST(Unregisterised)
264
265 dnl ** Does target have runtime linker support?
266 dnl --------------------------------------------------------------
267 case "$target" in
268     powerpc64-*|powerpc64le-*|powerpc-ibm-aix*)
269         HaskellHaveRTSLinker=NO
270         ;;
271     *)
272         HaskellHaveRTSLinker=YES
273         ;;
274 esac
275 AC_SUBST(HaskellHaveRTSLinker)
276
277 # Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
278 FP_FIND_ROOT
279
280 fail() {
281     echo >&2
282     echo "$1" >&2
283     exit 1
284 }
285
286
287 if test "$HostOS" = "mingw32"
288 then
289     # Find the mingw-w64 7z file to extract.
290     # NB. If you update the tarballs to a new version of gcc, don't
291     # forget to tweak the paths in driver/gcc/gcc.c.
292     if test "$HostArch" = "i386"
293     then
294         mingw_arch="i686"
295         tarball_dest_dir="mingw-w64/x86"
296         tarball_mingw_dir="mingw32"
297     else
298         mingw_arch="x86_64"
299         tarball_dest_dir="mingw-w64/x86_64"
300         tarball_mingw_dir="mingw64"
301     fi
302 fi
303
304 set_up_tarballs() {
305     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
306     local action
307     if test "$TarballsAutodownload" = "NO"
308     then
309         action="verify"
310     else
311         action="download"
312     fi
313     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
314     case $? in
315         0)
316            rm missing-win32-tarballs
317            ;;
318         2)
319            echo
320            echo "Error:"
321            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
322            echo
323            echo "  * run configure with the --enable-tarballs-autodownload option"
324            echo
325            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
326            echo
327            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
328            echo "    them in the ghc-tarballs directory."
329            echo
330            exit 1
331            ;;
332         *)
333            echo
334            echo "Error fetching msys2 tarballs; see errors above."
335            exit 1
336            ;;
337     esac
338
339     # Extract all the tarballs in one go
340     if ! test -d inplace/mingw
341     then
342         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
343         rm -rf inplace/mingw
344         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
345         ( cd inplace &&
346         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
347         rm ".MTREE" &&
348         rm ".PKGINFO" &&
349         cd .. ) || fail "Error: Could not extract Windows toolchains."
350
351         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
352         touch inplace/mingw
353
354         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
355         # make a wrapper around it to give it the proper paths
356         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
357         PATH=`pwd`/inplace/mingw/bin:$PATH
358         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
359
360         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
361     fi
362 }
363
364 if test "$HostOS" = "mingw32"
365 then
366     test -d inplace || mkdir inplace
367
368     # NB. Download and extract the MingW-w64 distribution if required
369     set_up_tarballs
370
371     mingwbin="$hardtop/inplace/mingw/bin/"
372     CC="${mingwbin}gcc.exe"
373     LD="${mingwbin}ld.exe"
374     NM="${mingwbin}nm.exe"
375     RANLIB="${mingwbin}ranlib.exe"
376     OBJDUMP="${mingwbin}objdump.exe"
377     Windres="${mingwbin}windres.exe"
378     DllWrap="${mingwbin}dllwrap.exe"
379     fp_prog_ar="${mingwbin}ar.exe"
380
381     # NB. Download the perl binaries if required
382     if ! test -d inplace/perl ||
383          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
384     then
385         AC_MSG_NOTICE([Making in-tree perl tree])
386         rm -rf inplace/perl
387         mkdir inplace/perl
388         (
389             cd inplace/perl &&
390             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
391         )
392         AC_MSG_NOTICE([In-tree perl tree created])
393     fi
394 fi
395
396 FP_ICONV
397 FP_GMP
398 FP_CURSES
399
400 XCODE_VERSION()
401
402
403 dnl ** Building a cross compiler?
404 dnl --------------------------------------------------------------
405 CrossCompiling=NO
406 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
407 if test "$TargetPlatform" != "$HostPlatform" ; then
408     CrossCompiling=YES
409     cross_compiling=yes   # This tells configure that it can accept just 'target',
410                           # otherwise you get
411                           #   configure: error: cannot run C compiled programs.
412                           #   If you meant to cross compile, use `--host'.
413 fi
414 if test "$BuildPlatform" != "$HostPlatform" ; then
415    AC_MSG_ERROR([
416 You've selected:
417
418   BUILD:  $BuildPlatform   (the architecture we're building on)
419   HOST:   $HostPlatform    (the architecture the compiler we're building will execute on)
420   TARGET: $TargetPlatform  (the architecture the compiler we're building will produce code for)
421
422 BUILD must equal HOST; that is, we do not support building GHC itself
423 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
424 1 will be a cross-compiler, and stage 2 will be the cross-compiled
425 GHC.
426 ])
427 fi
428 if test "$CrossCompiling" = "YES"
429 then
430   CrossCompilePrefix="${target}-"
431 else
432   CrossCompilePrefix=""
433 fi
434 # Despite its similarity in name to TargetPlatform, TargetPlatformFull is used
435 # in calls to subproject configure scripts and thus must be set to the autoconf
436 # triple, not the normalized GHC triple that TargetPlatform is set to.
437 #
438 # We use the non-canonicalized triple, target_alias, here since the subproject
439 # configure scripts will use this triple to construct the names of the toolchain
440 # executables. If we instead passed down the triple produced by
441 # AC_CANONICAL_TARGET then it may look for the target toolchain under the wrong
442 # name (this is a known problem in the case of the Android NDK, which has
443 # slightly odd triples).
444 #
445 # It may be better to just do away with the GHC triples altogether. This would
446 # all be taken care of for us if we configured the subprojects using
447 # AC_CONFIG_DIR, but unfortunately Cabal needs to be the one to do the
448 # configuration.
449 TargetPlatformFull="${target_alias}"
450 AC_SUBST(CrossCompiling)
451 AC_SUBST(CrossCompilePrefix)
452 AC_SUBST(TargetPlatformFull)
453
454 dnl ** Which gcc to use?
455 dnl --------------------------------------------------------------
456
457 AC_ARG_WITH([gcc],
458         AS_HELP_STRING([--with-gcc=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
459         AC_MSG_ERROR([--with-gcc=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
460
461 AC_ARG_WITH([clang],
462         AS_HELP_STRING([--with-clang=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
463         AC_MSG_ERROR([--with-clang=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
464
465 dnl detect compiler (prefer gcc over clang) and set $CC (unless CC already set),
466 dnl later CC is copied to CC_STAGE{1,2,3}
467 AC_PROG_CC([gcc clang])
468
469 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
470
471 dnl make extensions visible to allow feature-tests to detect them lateron
472 AC_USE_SYSTEM_EXTENSIONS
473
474 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
475 AC_PROG_CPP
476
477 # --with-hs-cpp/--with-hs-cpp-flags
478 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
479 AC_SUBST([HaskellCPPCmd])
480 AC_SUBST([HaskellCPPArgs])
481
482 FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
483 FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
484 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
485 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
486
487 dnl ** Which ld to use?
488 dnl --------------------------------------------------------------
489 FIND_LD([LdCmd])
490 AC_SUBST([LdCmd])
491
492 dnl ** Which nm to use?
493 dnl --------------------------------------------------------------
494 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
495
496 if test "$TargetOS_CPP" = "darwin"
497 then
498     AC_MSG_CHECKING(whether nm program is broken)
499     # Some versions of XCode ship a broken version of `nm`. Detect and work
500     # around this issue. See : https://ghc.haskell.org/trac/ghc/ticket/11744
501     nmver=$(${NM} --version | grep version | sed 's/ //g')
502     case "$nmver" in
503         LLVMversion7.3.0|LLVMversion7.3.1)
504             AC_MSG_RESULT(yes)
505             echo "The detected nm program is broken."
506             echo
507             echo "See: https://ghc.haskell.org/trac/ghc/ticket/11744"
508             echo
509             echo "Try re-running configure with:"
510             echo
511             echo '   ./configure --with-nm=$(xcrun --find nm-classic)'
512             echo
513             exit 1
514             ;;
515         *)
516             AC_MSG_RESULT(no)
517             ;;
518         esac
519 fi
520
521 NmCmd="$NM"
522 AC_SUBST([NmCmd])
523
524 dnl ** Which objdump to use?
525 dnl --------------------------------------------------------------
526 FP_ARG_WITH_PATH_GNU_PROG_OPTIONAL([OBJDUMP], [objdump], [objdump])
527 ObjdumpCmd="$OBJDUMP"
528 AC_SUBST([ObjdumpCmd])
529
530 dnl ** Which ar to use?
531 dnl --------------------------------------------------------------
532 FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
533 ArCmd="$AR"
534 fp_prog_ar="$AR"
535 AC_SUBST([ArCmd])
536
537 dnl ** Which ranlib to use?
538 dnl --------------------------------------------------------------
539 FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
540 RanlibCmd="$RANLIB"
541 RANLIB="$RanlibCmd"
542
543
544 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
545 case $HostOS_CPP in
546 cygwin32|mingw32)
547     dnl ** Which objdump to use?
548     dnl --------------------------------------------------------------
549     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
550     ObjdumpCmd="$OBJDUMP"
551     AC_SUBST([ObjdumpCmd])
552     ;;
553 esac
554
555 # Here is where we re-target which specific version of the LLVM
556 # tools we are looking for. In the past, GHC supported a number of
557 # versions of LLVM simultaneously, but that stopped working around
558 # 3.5/3.6 release of LLVM.
559 LlvmVersion=3.9
560 AC_SUBST([LlvmVersion])
561 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
562 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
563
564 dnl ** Which LLVM llc to use?
565 dnl --------------------------------------------------------------
566 FIND_LLVM_PROG([LLC], [llc], [llc], [$LlvmVersion])
567 LlcCmd="$LLC"
568 AC_SUBST([LlcCmd])
569
570 dnl ** Which LLVM opt to use?
571 dnl --------------------------------------------------------------
572 FIND_LLVM_PROG([OPT], [opt], [opt], [$LlvmVersion])
573 OptCmd="$OPT"
574 AC_SUBST([OptCmd])
575
576 dnl --------------------------------------------------------------
577 dnl End of configure script option section
578 dnl --------------------------------------------------------------
579
580
581 dnl --------------------------------------------------------------
582 dnl ** Can the unix package be built?
583 dnl --------------------------------------------------------------
584
585 if test "$TargetOS" = "mingw32"
586 then
587     GhcLibsWithUnix=NO
588 else
589     GhcLibsWithUnix=YES
590 fi
591 AC_SUBST([GhcLibsWithUnix])
592
593 dnl ** does #! work?
594 AC_SYS_INTERPRETER()
595
596 # Check for split-objs
597 SplitObjsBroken=NO
598 dnl ** look for `perl'
599 case $HostOS_CPP in
600 cygwin32|mingw32)
601   PerlCmd=$hardtop/inplace/perl/perl
602   ;;
603 *)
604     AC_PATH_PROG([PerlCmd],[perl])
605     if test -z "$PerlCmd"
606     then
607         AC_MSG_WARN([No Perl on PATH, disabling split object support])
608         SplitObjsBroken=YES
609     else
610         FPTOOLS_CHECK_PERL_VERSION
611     fi
612     ;;
613 esac
614 AC_SUBST([SplitObjsBroken])
615
616 dnl ** look for GCC and find out which version
617 dnl     Figure out which C compiler to use.  Gcc is preferred.
618 dnl     If gcc, make sure it's at least 3.0
619 dnl
620 FP_GCC_VERSION
621
622 dnl ** See whether gcc supports -no-pie
623 FP_GCC_SUPPORTS_NO_PIE
624
625 dnl ** look to see if we have a C compiler using an llvm back end.
626 dnl
627 FP_CC_LLVM_BACKEND
628
629 FP_PROG_LD_IS_GNU
630 FP_PROG_LD_BUILD_ID
631 FP_PROG_LD_NO_COMPACT_UNWIND
632 FP_PROG_LD_FILELIST
633
634
635 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
636 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
637 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
638 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
639 # Stage 3 won't be supported by cross-compilation
640
641 FP_GCC_EXTRA_FLAGS
642
643 # See rules/distdir-way-opts.mk for details.
644 # Flags passed to the C compiler
645 AC_SUBST(CONF_CC_OPTS_STAGE0)
646 AC_SUBST(CONF_CC_OPTS_STAGE1)
647 AC_SUBST(CONF_CC_OPTS_STAGE2)
648 # Flags passed to the C compiler when we ask it to link
649 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
650 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
651 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
652 # Flags passed to the linker when we ask it to link
653 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
654 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
655 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
656 # Flags passed to the C preprocessor
657 AC_SUBST(CONF_CPP_OPTS_STAGE0)
658 AC_SUBST(CONF_CPP_OPTS_STAGE1)
659 AC_SUBST(CONF_CPP_OPTS_STAGE2)
660 # Flags passed to the Haskell compiler
661 AC_SUBST(CONF_HC_OPTS_STAGE0)
662 AC_SUBST(CONF_HC_OPTS_STAGE1)
663 AC_SUBST(CONF_HC_OPTS_STAGE2)
664
665 dnl ** Set up the variables for the platform in the settings file.
666 dnl May need to use gcc to find platform details.
667 dnl --------------------------------------------------------------
668 FPTOOLS_SET_HASKELL_PLATFORM_VARS
669
670 dnl ** figure out how to do context diffs
671 FP_PROG_CONTEXT_DIFF
672
673 dnl Let's make sure install-sh is executable here.  If we got it from
674 dnl a darcs repo, it might not be (see bug #978).
675 chmod +x install-sh
676 dnl ** figure out how to do a BSD-ish install
677 AC_PROG_INSTALL
678
679 dnl ** how to invoke `ar' and `ranlib'
680 FP_PROG_AR_SUPPORTS_ATFILE
681 FP_PROG_AR_NEEDS_RANLIB
682
683 dnl ** Check to see whether ln -s works
684 AC_PROG_LN_S
685
686 FP_SETTINGS
687
688 dnl ** Find the path to sed
689 AC_PATH_PROGS(SedCmd,gsed sed,sed)
690
691
692 dnl ** check for time command
693 AC_PATH_PROG(TimeCmd,time)
694
695 dnl ** check for tar
696 dnl   if GNU tar is named gtar, look for it first.
697 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
698
699 dnl ** check for patch
700 dnl if GNU patch is named gpatch, look for it first
701 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
702
703 dnl ** check for dtrace (currently only implemented for Mac OS X)
704 HaveDtrace=NO
705 AC_PATH_PROG(DtraceCmd,dtrace)
706 if test -n "$DtraceCmd"; then
707   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
708     HaveDtrace=YES
709   fi
710 fi
711 AC_SUBST(HaveDtrace)
712
713 AC_PATH_PROG(HSCOLOUR,HsColour)
714 # HsColour is passed to Cabal, so we need a native path
715 if test "$HostOS"      = "mingw32" && \
716    test "${HSCOLOUR}" != ""
717 then
718     # Canonicalise to <drive>:/path/to/gcc
719     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
720 fi
721
722 dnl ** check for Sphinx toolchain
723 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
724 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
725 changequote(, )dnl
726 [if test -n "$SPHINXBUILD"; then
727   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
728 fi;
729 changequote([, ])dnl
730 ])
731 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
732     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
733
734 dnl ** check for xelatex
735 AC_PATH_PROG(XELATEX,xelatex)
736
737 dnl ** check for ghc-pkg command
738 FP_PROG_GHC_PKG
739
740 dnl ** check for installed happy binary + version
741 FPTOOLS_HAPPY
742
743 dnl ** check for installed alex binary + version
744 FPTOOLS_ALEX
745
746 dnl --------------------------------------------------
747 dnl ### program checking section ends here ###
748 dnl --------------------------------------------------
749
750 dnl --------------------------------------------------
751 dnl * Platform header file and syscall feature tests
752 dnl ### checking the state of the local header files and syscalls ###
753
754 dnl ** check for full ANSI header (.h) files
755 AC_HEADER_STDC
756
757 dnl ** Enable large file support.  NB. do this before testing the type of
758 dnl    off_t, because it will affect the result of that test.
759 AC_SYS_LARGEFILE
760
761 dnl ** check for specific header (.h) files that we are interested in
762 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
763
764 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
765 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
766 [[#if HAVE_SYS_PARAM_H
767 # include <sys/param.h>
768 #endif
769 ]])
770
771 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
772 AC_HEADER_TIME
773
774 dnl ** do we have long longs?
775 AC_CHECK_TYPES([long long])
776
777 dnl ** what are the sizes of various types
778 FP_CHECK_SIZEOF_AND_ALIGNMENT(char)
779 FP_CHECK_SIZEOF_AND_ALIGNMENT(double)
780 FP_CHECK_SIZEOF_AND_ALIGNMENT(float)
781 FP_CHECK_SIZEOF_AND_ALIGNMENT(int)
782 FP_CHECK_SIZEOF_AND_ALIGNMENT(long)
783 if test "$ac_cv_type_long_long" = yes; then
784 FP_CHECK_SIZEOF_AND_ALIGNMENT(long long)
785 fi
786 FP_CHECK_SIZEOF_AND_ALIGNMENT(short)
787 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned char)
788 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned int)
789 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long)
790 if test "$ac_cv_type_long_long" = yes; then
791 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long long)
792 fi
793 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned short)
794 FP_CHECK_SIZEOF_AND_ALIGNMENT(void *)
795
796 FP_CHECK_SIZEOF_AND_ALIGNMENT(int8_t)
797 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint8_t)
798 FP_CHECK_SIZEOF_AND_ALIGNMENT(int16_t)
799 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint16_t)
800 FP_CHECK_SIZEOF_AND_ALIGNMENT(int32_t)
801 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint32_t)
802 FP_CHECK_SIZEOF_AND_ALIGNMENT(int64_t)
803 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint64_t)
804
805
806 dnl for use in settings.in
807 WordSize=$ac_cv_sizeof_void_p
808 AC_SUBST(WordSize)
809 FP_CHECK_FUNC([WinExec],
810   [@%:@include <windows.h>], [WinExec("",0)])
811
812 FP_CHECK_FUNC([GetModuleFileName],
813   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
814
815 dnl ** check for more functions
816 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
817 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
818
819 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
820 dnl ** _POSIX_C_SOURCE is defined
821 AC_CHECK_DECLS([ctime_r], , ,
822 [#define _POSIX_SOURCE 1
823 #define _POSIX_C_SOURCE 199506L
824 #include <time.h>])
825
826 dnl ** check for mingwex library
827 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
828 AC_SUBST(HaveLibMingwEx)
829
830 if test $HaveLibMingwEx = YES ; then
831   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
832 fi
833
834 dnl ** check for math library
835 dnl    Keep that check as early as possible.
836 dnl    as we need to know whether we need libm
837 dnl    for math functions or not
838 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
839 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
840 if test $HaveLibM = YES
841 then
842   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
843 fi
844
845 FP_BFD_SUPPORT
846
847 dnl ################################################################
848 dnl Check for libraries
849 dnl ################################################################
850
851 # system libffi
852
853 AC_ARG_WITH([system-libffi],
854 [AC_HELP_STRING([--with-system-libffi],
855   [Use system provided libffi for RTS [default=no]])
856 ])
857
858 AS_IF([test "x$with_system_libffi" = "xyes"],
859   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
860 )
861
862
863 AC_SUBST(UseSystemLibFFI)
864
865 AC_ARG_WITH([ffi-includes],
866 [AC_HELP_STRING([--with-ffi-includes=ARG],
867   [Find includes for libffi in ARG [default=system default]])
868 ],
869 [
870  if test "x$UseSystemLibFFI" != "xYES"; then
871     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
872  else
873     FFIIncludeDir="$withval"
874     LIBFFI_CFLAGS="-I$withval"
875  fi
876 ])
877
878 AC_SUBST(FFIIncludeDir)
879
880 AC_ARG_WITH([ffi-libraries],
881 [AC_HELP_STRING([--with-ffi-libraries=ARG],
882   [Find libffi in ARG [default=system default]])
883 ],
884 [
885  if test "x$UseSystemLibFFI" != "xYES"; then
886     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
887  else
888     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
889  fi
890 ])
891
892 AC_SUBST(FFILibDir)
893
894 AS_IF([test "$UseSystemLibFFI" = "YES"], [
895  CFLAGS2="$CFLAGS"
896  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
897  LDFLAGS2="$LDFLAGS"
898  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
899  if test "$HostOS" = "openbsd";
900  then
901    # OpenBSD's libffi is not directly linked to the libpthread but
902    # still requires pthread functionality. This means that any client
903    # binary which links with libffi also needs to link with
904    # libpthread. If it does not, then linking fails with unresolved
905    # symbols.
906    LDFLAGS="$LDFLAGS -lpthread"
907  fi
908  AC_CHECK_LIB(ffi, ffi_call,
909   [AC_CHECK_HEADERS([ffi.h], [break], [])
910    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
911   [AC_MSG_ERROR([Cannot find system libffi])])
912  CFLAGS="$CFLAGS2"
913  LDFLAGS="$LDFLAGS2"
914 ])
915
916 dnl ** check whether we need -ldl to get dlopen()
917 AC_CHECK_LIB(dl, dlopen)
918
919 dnl --------------------------------------------------
920 dnl * Miscellaneous feature tests
921 dnl --------------------------------------------------
922
923 dnl ** can we get alloca?
924 AC_FUNC_ALLOCA
925
926 dnl ** working vfork?
927 AC_FUNC_FORK
928
929 dnl ** determine whether or not const works
930 AC_C_CONST
931
932 dnl ** are we big endian?
933 AC_C_BIGENDIAN
934 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
935
936 dnl ** check for leading underscores in symbol names
937 FP_LEADING_UNDERSCORE
938
939 FP_VISIBILITY_HIDDEN
940
941 dnl ** check for librt
942 AC_CHECK_LIB(rt, clock_gettime)
943 AC_CHECK_FUNCS(clock_gettime timer_settime)
944 FP_CHECK_TIMER_CREATE
945
946 dnl ** check for Apple's "interesting" long double compatibility scheme
947 AC_MSG_CHECKING(for printf\$LDBLStub)
948 AC_TRY_LINK_FUNC(printf\$LDBLStub,
949     [
950         AC_MSG_RESULT(yes)
951         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
952             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
953     ],
954     [
955         AC_MSG_RESULT(no)
956         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
957             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
958     ])
959
960 dnl Some platforms (e.g. Android's Bionic) have pthreads support available
961 dnl without linking against libpthread. Check whether -lpthread is necessary
962 dnl to use pthreads.
963 dnl
964 dnl Note that it is important that this happens before we AC_CHECK_LIB(thread)
965 AC_MSG_CHECKING(whether -lpthread is needed for pthreads)
966 AC_CHECK_FUNC(pthread_create,
967     [
968         AC_MSG_RESULT(no)
969         need_lpthread=0
970     ],
971     [
972         AC_CHECK_LIB(pthread, pthread_create,
973             [
974                 AC_MSG_RESULT(yes)
975                 need_lpthread=1
976             ],
977             [
978                 AC_MSG_RESULT([no pthreads support found.])
979                 need_lpthread=0
980             ])
981     ])
982 AC_DEFINE_UNQUOTED([NEED_PTHREAD_LIB], [$need_lpthread],
983     [Define 1 if we need to link code using pthreads with -lpthread])
984
985 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
986 dnl    a different single-argument version.
987 AC_CHECK_LIB(pthread, pthread_setname_np)
988 AC_MSG_CHECKING(for pthread_setname_np)
989 AC_TRY_LINK(
990 [
991 #define _GNU_SOURCE
992 #include <pthread.h>
993 ],
994 [pthread_setname_np(pthread_self(), "name");],
995     AC_MSG_RESULT(yes)
996     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
997       [Define to 1 if you have the glibc version of pthread_setname_np]),
998     AC_MSG_RESULT(no)
999 )
1000
1001 dnl ** check for eventfd which is needed by the I/O manager
1002 AC_CHECK_HEADERS([sys/eventfd.h])
1003 AC_CHECK_FUNCS([eventfd])
1004
1005 dnl ** Check for __thread support in the compiler
1006 AC_MSG_CHECKING(for __thread support)
1007 AC_COMPILE_IFELSE(
1008   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1009   [
1010    AC_MSG_RESULT(yes)
1011    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1012   ],
1013   [
1014    AC_MSG_RESULT(no)
1015    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1016   ])
1017
1018 dnl large address space support (see includes/rts/storage/MBlock.h)
1019 dnl
1020 dnl Darwin has vm_allocate/vm_protect
1021 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1022 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1023 dnl (They also have MADV_DONTNEED, but it means something else!)
1024 dnl
1025 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1026 dnl it counts page-table space as committed memory, and so quickly
1027 dnl runs out of paging file when we have multiple processes reserving
1028 dnl 1TB of address space, we get the following error:
1029 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1030 dnl
1031
1032 AC_ARG_ENABLE(large-address-space,
1033     [AC_HELP_STRING([--enable-large-address-space],
1034         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1035     EnableLargeAddressSpace=$enableval,
1036     EnableLargeAddressSpace=yes
1037 )
1038
1039 use_large_address_space=no
1040 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1041     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1042         if test "$ghc_host_os" = "darwin" ; then
1043             use_large_address_space=yes
1044         elif test "$ghc_host_os" = "openbsd" ; then
1045             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1046             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1047             # but is completely ignored by OS mmap
1048             use_large_address_space=no
1049         else
1050             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1051                 [
1052                 #include <unistd.h>
1053                 #include <sys/types.h>
1054                 #include <sys/mman.h>
1055                 #include <fcntl.h>
1056             ])
1057             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1058                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1059                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1060                     use_large_address_space=yes
1061             fi
1062         fi
1063     fi
1064 fi
1065 if test "$use_large_address_space" = "yes" ; then
1066    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1067 fi
1068
1069 dnl ** Use MMAP in the runtime linker?
1070 dnl --------------------------------------------------------------
1071
1072 case ${TargetOS} in
1073     linux|freebsd|dragonfly|netbsd|openbsd|kfreebsdgnu|gnu|solaris2)
1074         RtsLinkerUseMmap=1
1075         ;;
1076     darwin)
1077         # Don't use mmap on powerpc/darwin as the mmap there doesn't support
1078         # reallocating. Reallocating is needed to allocate jump islands just
1079         # after each object image. Jumps to these jump islands use relative
1080         # branches which are limited to offsets that can be represented in
1081         # 24-bits.
1082         if test "$TargetArch" != "powerpc" ; then
1083             RtsLinkerUseMmap=1
1084         else
1085             RtsLinkerUseMmap=0
1086         fi
1087         ;;
1088     *)
1089         # Windows (which doesn't have mmap) and everything else.
1090         RtsLinkerUseMmap=0
1091         ;;
1092     esac
1093
1094 AC_DEFINE_UNQUOTED([RTS_LINKER_USE_MMAP], [$RtsLinkerUseMmap],
1095                    [Use mmap in the runtime linker])
1096
1097 dnl ** Have libdw?
1098 dnl --------------------------------------------------------------
1099 UseLibdw=NO
1100 USE_LIBDW=0
1101 AC_ARG_ENABLE(dwarf-unwind,
1102     [AC_HELP_STRING([--enable-dwarf-unwind],
1103         [Enable DWARF unwinding support in the runtime system via elfutils' libdw [default=no]])],
1104     [AC_CHECK_LIB(dw, dwfl_attach_state, [UseLibdw=YES], [UseLibdw=NO])],
1105     [UseLibdw=NO]
1106 )
1107 AC_SUBST(UseLibdw)
1108 if test $UseLibdw = "YES" ; then
1109         USE_LIBDW=1
1110 fi
1111 AC_DEFINE_UNQUOTED([USE_LIBDW], [$USE_LIBDW], [Set to 1 to use libdw])
1112
1113 dnl ** Have libnuma?
1114 dnl --------------------------------------------------------------
1115 HaveLibNuma=0
1116 AC_CHECK_HEADERS([numa.h numaif.h])
1117
1118 if test "$ac_cv_header_numa_h$ac_cv_header_numaif_h" = "yesyes" ; then
1119     AC_CHECK_LIB(numa, numa_available,HaveLibNuma=1)
1120 fi
1121 AC_DEFINE_UNQUOTED([HAVE_LIBNUMA], [$HaveLibNuma], [Define to 1 if you have libnuma])
1122
1123 dnl ** Documentation
1124 dnl --------------------------------------------------------------
1125 if test -n "$SPHINXBUILD"; then
1126     BUILD_MAN=YES
1127     BUILD_SPHINX_HTML=YES
1128     if test -n "$XELATEX"; then
1129         BUILD_SPHINX_PDF=YES
1130     else
1131         BUILD_SPHINX_PDF=NO
1132     fi
1133 else
1134     BUILD_MAN=NO
1135     BUILD_SPHINX_HTML=NO
1136     BUILD_SPHINX_PDF=NO
1137 fi
1138 AC_SUBST(BUILD_MAN)
1139 AC_SUBST(BUILD_SPHINX_HTML)
1140 AC_SUBST(BUILD_SPHINX_PDF)
1141
1142 LIBRARY_VERSION(base)
1143 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1144 LIBRARY_VERSION(ghc-prim)
1145 LIBRARY_VERSION(ghc-compact)
1146 LIBRARY_ghc_VERSION="$ProjectVersion"
1147 AC_SUBST(LIBRARY_ghc_VERSION)
1148
1149 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1150    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1151 fi
1152
1153 # Create the configuration for the Hadrian build system if it is present
1154 if test -e hadrian/cfg/system.config.in; then
1155     AC_CONFIG_FILES([hadrian/cfg/system.config])
1156 fi
1157
1158 # We got caught by
1159 #     http://savannah.gnu.org/bugs/index.php?1516
1160 #     $(eval ...) inside conditionals causes errors
1161 # with make 3.80, so warn the user if it looks like they're about to
1162 # try to use it.
1163 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1164 print_make_warning=""
1165 checkMake380() {
1166     make_ver=`$1 --version 2>&1 | head -1`
1167     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1168     then
1169         print_make_warning="true"
1170     fi
1171     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1172     then
1173         MakeCmd=$1
1174         AC_SUBST(MakeCmd)
1175     fi
1176 }
1177
1178 checkMake380 make
1179 checkMake380 gmake
1180
1181 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghc-boot-th/ghc-boot-th.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt utils/mkUserGuidePart/mkUserGuidePart.cabal distrib/configure.ac])
1182 AC_OUTPUT
1183 [
1184 if test "$print_make_warning" = "true"; then
1185    echo
1186    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1187    echo "This version cannot be used to build GHC."
1188    echo "Please use GNU make >= 3.81."
1189 fi
1190
1191 echo "
1192 ----------------------------------------------------------------------
1193 Configure completed successfully.
1194
1195    Building GHC version  : $ProjectVersion
1196           Git commit id  : $ProjectGitCommitId
1197
1198    Build platform        : $BuildPlatform
1199    Host platform         : $HostPlatform
1200    Target platform       : $TargetPlatform
1201 "
1202
1203 echo "\
1204    Bootstrapping using   : $WithGhc
1205       which is version   : $GhcVersion
1206 "
1207
1208 if test "x$CC_LLVM_BACKEND" = "x1"; then
1209     if test "x$CC_CLANG_BACKEND" = "x1"; then
1210         CompilerName="clang        "
1211     else
1212         CompilerName="llvm-gcc     "
1213     fi
1214 else
1215     CompilerName="gcc          "
1216 fi
1217
1218 echo "\
1219    Using (for bootstrapping) : $CC_STAGE0
1220    Using $CompilerName       : $CC
1221       which is version       : $GccVersion
1222    Building a cross compiler : $CrossCompiling
1223    Unregisterised            : $Unregisterised
1224    hs-cpp       : $HaskellCPPCmd
1225    hs-cpp-flags : $HaskellCPPArgs
1226    ld           : $LdCmd
1227    nm           : $NmCmd
1228    objdump      : $ObjdumpCmd
1229    Happy        : $HappyCmd ($HappyVersion)
1230    Alex         : $AlexCmd ($AlexVersion)
1231    Perl         : $PerlCmd
1232    sphinx-build : $SPHINXBUILD
1233    xelatex      : $XELATEX
1234
1235    Using LLVM tools
1236       llc   : $LlcCmd
1237       opt   : $OptCmd"
1238
1239 if test "$HSCOLOUR" = ""; then
1240 echo "
1241    HsColour was not found; documentation will not contain source links
1242 "
1243 else
1244 echo "\
1245    HsColour : $HSCOLOUR
1246 "
1247 fi
1248
1249 echo "\
1250    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1251    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"
1252
1253 echo "----------------------------------------------------------------------
1254 "
1255
1256 echo "\
1257 For a standard build of GHC (fully optimised with profiling), type (g)make.
1258
1259 To make changes to the default build configuration, copy the file
1260 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1261
1262 For more information on how to configure your GHC build, see
1263    http://ghc.haskell.org/trac/ghc/wiki/Building
1264 "]