Canonicalise `MonadPlus` instances
[ghc.git] / libraries / base / Text / ParserCombinators / ReadPrec.hs
1 {-# LANGUAGE Trustworthy #-}
2 {-# LANGUAGE NoImplicitPrelude #-}
3
4 -----------------------------------------------------------------------------
5 -- |
6 -- Module : Text.ParserCombinators.ReadPrec
7 -- Copyright : (c) The University of Glasgow 2002
8 -- License : BSD-style (see the file libraries/base/LICENSE)
9 --
10 -- Maintainer : libraries@haskell.org
11 -- Stability : provisional
12 -- Portability : non-portable (uses Text.ParserCombinators.ReadP)
13 --
14 -- This library defines parser combinators for precedence parsing.
15
16 -----------------------------------------------------------------------------
17
18 module Text.ParserCombinators.ReadPrec
19 (
20 ReadPrec,
21
22 -- * Precedences
23 Prec,
24 minPrec,
25
26 -- * Precedence operations
27 lift,
28 prec,
29 step,
30 reset,
31
32 -- * Other operations
33 -- | All are based directly on their similarly-named 'ReadP' counterparts.
34 get,
35 look,
36 (+++),
37 (<++),
38 pfail,
39 choice,
40
41 -- * Converters
42 readPrec_to_P,
43 readP_to_Prec,
44 readPrec_to_S,
45 readS_to_Prec,
46 )
47 where
48
49
50 import Text.ParserCombinators.ReadP
51 ( ReadP
52 , ReadS
53 , readP_to_S
54 , readS_to_P
55 )
56
57 import qualified Text.ParserCombinators.ReadP as ReadP
58 ( get
59 , look
60 , (+++), (<++)
61 , pfail
62 )
63
64 import GHC.Num( Num(..) )
65 import GHC.Base
66
67 import qualified Control.Monad.Fail as MonadFail
68
69 -- ---------------------------------------------------------------------------
70 -- The readPrec type
71
72 newtype ReadPrec a = P (Prec -> ReadP a)
73
74 -- Functor, Monad, MonadPlus
75
76 instance Functor ReadPrec where
77 fmap h (P f) = P (\n -> fmap h (f n))
78
79 instance Applicative ReadPrec where
80 pure x = P (\_ -> pure x)
81 (<*>) = ap
82
83 instance Monad ReadPrec where
84 fail s = P (\_ -> fail s)
85 P f >>= k = P (\n -> do a <- f n; let P f' = k a in f' n)
86
87 instance MonadFail.MonadFail ReadPrec where
88 fail s = P (\_ -> fail s)
89
90 instance MonadPlus ReadPrec
91
92 instance Alternative ReadPrec where
93 empty = pfail
94 (<|>) = (+++)
95
96 -- precedences
97 type Prec = Int
98
99 minPrec :: Prec
100 minPrec = 0
101
102 -- ---------------------------------------------------------------------------
103 -- Operations over ReadPrec
104
105 lift :: ReadP a -> ReadPrec a
106 -- ^ Lift a precedence-insensitive 'ReadP' to a 'ReadPrec'.
107 lift m = P (\_ -> m)
108
109 step :: ReadPrec a -> ReadPrec a
110 -- ^ Increases the precedence context by one.
111 step (P f) = P (\n -> f (n+1))
112
113 reset :: ReadPrec a -> ReadPrec a
114 -- ^ Resets the precedence context to zero.
115 reset (P f) = P (\_ -> f minPrec)
116
117 prec :: Prec -> ReadPrec a -> ReadPrec a
118 -- ^ @(prec n p)@ checks whether the precedence context is
119 -- less than or equal to @n@, and
120 --
121 -- * if not, fails
122 --
123 -- * if so, parses @p@ in context @n@.
124 prec n (P f) = P (\c -> if c <= n then f n else ReadP.pfail)
125
126 -- ---------------------------------------------------------------------------
127 -- Derived operations
128
129 get :: ReadPrec Char
130 -- ^ Consumes and returns the next character.
131 -- Fails if there is no input left.
132 get = lift ReadP.get
133
134 look :: ReadPrec String
135 -- ^ Look-ahead: returns the part of the input that is left, without
136 -- consuming it.
137 look = lift ReadP.look
138
139 (+++) :: ReadPrec a -> ReadPrec a -> ReadPrec a
140 -- ^ Symmetric choice.
141 P f1 +++ P f2 = P (\n -> f1 n ReadP.+++ f2 n)
142
143 (<++) :: ReadPrec a -> ReadPrec a -> ReadPrec a
144 -- ^ Local, exclusive, left-biased choice: If left parser
145 -- locally produces any result at all, then right parser is
146 -- not used.
147 P f1 <++ P f2 = P (\n -> f1 n ReadP.<++ f2 n)
148
149 pfail :: ReadPrec a
150 -- ^ Always fails.
151 pfail = lift ReadP.pfail
152
153 choice :: [ReadPrec a] -> ReadPrec a
154 -- ^ Combines all parsers in the specified list.
155 choice ps = foldr (+++) pfail ps
156
157 -- ---------------------------------------------------------------------------
158 -- Converting between ReadPrec and Read
159
160 readPrec_to_P :: ReadPrec a -> (Int -> ReadP a)
161 readPrec_to_P (P f) = f
162
163 readP_to_Prec :: (Int -> ReadP a) -> ReadPrec a
164 readP_to_Prec f = P f
165
166 readPrec_to_S :: ReadPrec a -> (Int -> ReadS a)
167 readPrec_to_S (P f) n = readP_to_S (f n)
168
169 readS_to_Prec :: (Int -> ReadS a) -> ReadPrec a
170 readS_to_Prec f = P (\n -> readS_to_P (f n))
171