Implement Partial Type Signatures
[ghc.git] / compiler / typecheck / TcPat.lhs
1 %
2 % (c) The University of Glasgow 2006
3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4 %
5
6 TcPat: Typechecking patterns
7
8 \begin{code}
9 {-# LANGUAGE CPP, RankNTypes #-}
10
11 module TcPat ( tcLetPat, TcSigFun, TcPragFun
12              , TcSigInfo(..), TcPatSynInfo(..)
13              , findScopedTyVars, isPartialSig
14              , LetBndrSpec(..), addInlinePrags, warnPrags
15              , tcPat, tcPats, newNoSigLetBndr
16              , addDataConStupidTheta, badFieldCon, polyPatSig ) where
17
18 #include "HsVersions.h"
19
20 import {-# SOURCE #-}   TcExpr( tcSyntaxOp, tcInferRho)
21
22 import HsSyn
23 import TcHsSyn
24 import TcRnMonad
25 import Inst
26 import Id
27 import Var
28 import Name
29 import NameSet
30 import TcEnv
31 --import TcExpr
32 import TcMType
33 import TcValidity( arityErr )
34 import TcType
35 import TcUnify
36 import TcHsType
37 import TysWiredIn
38 import TcEvidence
39 import TyCon
40 import DataCon
41 import PatSyn
42 import ConLike
43 import PrelNames
44 import BasicTypes hiding (SuccessFlag(..))
45 import DynFlags
46 import SrcLoc
47 import Util
48 import Outputable
49 import FastString
50 import Control.Monad
51 \end{code}
52
53
54 %************************************************************************
55 %*                                                                      *
56                 External interface
57 %*                                                                      *
58 %************************************************************************
59
60 \begin{code}
61 tcLetPat :: TcSigFun -> LetBndrSpec
62          -> LPat Name -> TcSigmaType
63          -> TcM a
64          -> TcM (LPat TcId, a)
65 tcLetPat sig_fn no_gen pat pat_ty thing_inside
66   = tc_lpat pat pat_ty penv thing_inside
67   where
68     penv = PE { pe_lazy = True
69               , pe_ctxt = LetPat sig_fn no_gen }
70
71 -----------------
72 tcPats :: HsMatchContext Name
73        -> [LPat Name]            -- Patterns,
74        -> [TcSigmaType]          --   and their types
75        -> TcM a                  --   and the checker for the body
76        -> TcM ([LPat TcId], a)
77
78 -- This is the externally-callable wrapper function
79 -- Typecheck the patterns, extend the environment to bind the variables,
80 -- do the thing inside, use any existentially-bound dictionaries to
81 -- discharge parts of the returning LIE, and deal with pattern type
82 -- signatures
83
84 --   1. Initialise the PatState
85 --   2. Check the patterns
86 --   3. Check the body
87 --   4. Check that no existentials escape
88
89 tcPats ctxt pats pat_tys thing_inside
90   = tc_lpats penv pats pat_tys thing_inside
91   where
92     penv = PE { pe_lazy = False, pe_ctxt = LamPat ctxt }
93
94 tcPat :: HsMatchContext Name
95       -> LPat Name -> TcSigmaType
96       -> TcM a                 -- Checker for body, given
97                                -- its result type
98       -> TcM (LPat TcId, a)
99 tcPat ctxt pat pat_ty thing_inside
100   = tc_lpat pat pat_ty penv thing_inside
101   where
102     penv = PE { pe_lazy = False, pe_ctxt = LamPat ctxt }
103
104
105 -----------------
106 data PatEnv
107   = PE { pe_lazy :: Bool        -- True <=> lazy context, so no existentials allowed
108        , pe_ctxt :: PatCtxt     -- Context in which the whole pattern appears
109        }
110
111 data PatCtxt
112   = LamPat   -- Used for lambdas, case etc
113        (HsMatchContext Name)
114
115   | LetPat   -- Used only for let(rec) pattern bindings
116              -- See Note [Typing patterns in pattern bindings]
117        TcSigFun        -- Tells type sig if any
118        LetBndrSpec     -- True <=> no generalisation of this let
119
120 data LetBndrSpec
121   = LetLclBndr            -- The binder is just a local one;
122                           -- an AbsBinds will provide the global version
123
124   | LetGblBndr TcPragFun  -- Genrealisation plan is NoGen, so there isn't going
125                           -- to be an AbsBinds; So we must bind the global version
126                           -- of the binder right away.
127                           -- Oh, and dhhere is the inline-pragma information
128
129 makeLazy :: PatEnv -> PatEnv
130 makeLazy penv = penv { pe_lazy = True }
131
132 inPatBind :: PatEnv -> Bool
133 inPatBind (PE { pe_ctxt = LetPat {} }) = True
134 inPatBind (PE { pe_ctxt = LamPat {} }) = False
135
136 ---------------
137 type TcPragFun = Name -> [LSig Name]
138 type TcSigFun  = Name -> Maybe TcSigInfo
139
140 data TcSigInfo
141   = TcSigInfo {
142         sig_id     :: TcId,         --  *Polymorphic* binder for this value...
143
144         sig_tvs    :: [(Maybe Name, TcTyVar)],
145                            -- Instantiated type and kind variables
146                            -- Just n <=> this skolem is lexically in scope with name n
147                            -- See Note [Binding scoped type variables]
148
149         sig_nwcs   :: [(Name, TcTyVar)],
150                            -- Instantiated wildcard variables
151
152         sig_theta  :: TcThetaType,  -- Instantiated theta
153
154         sig_extra_cts :: Maybe SrcSpan, -- Just loc <=> An extra-constraints
155                                         -- wildcard was present. Any extra
156                                         -- constraints inferred during
157                                         -- type-checking will be added to the
158                                         -- partial type signature. Stores the
159                                         -- location of the wildcard.
160
161         sig_tau    :: TcSigmaType,  -- Instantiated tau
162                                     -- See Note [sig_tau may be polymorphic]
163
164         sig_loc    :: SrcSpan,      -- The location of the signature
165
166         sig_partial :: Bool         -- True <=> a partial type signature
167                                     -- containing wildcards
168     }
169   | TcPatSynInfo TcPatSynInfo
170
171 data TcPatSynInfo
172   = TPSI {
173         patsig_name  :: Name,
174         patsig_tau   :: TcSigmaType,
175         patsig_ex    :: [TcTyVar],
176         patsig_prov  :: TcThetaType,
177         patsig_univ  :: [TcTyVar],
178         patsig_req   :: TcThetaType
179     }
180
181 findScopedTyVars  -- See Note [Binding scoped type variables]
182   :: LHsType Name             -- The HsType
183   -> TcType                   -- The corresponding Type:
184                               --   uses same Names as the HsType
185   -> [TcTyVar]                -- The instantiated forall variables of the Type
186   -> [(Maybe Name, TcTyVar)]  -- In 1-1 correspondence with the instantiated vars
187 findScopedTyVars hs_ty sig_ty inst_tvs
188   = zipWith find sig_tvs inst_tvs
189   where
190     find sig_tv inst_tv
191       | tv_name `elemNameSet` scoped_names = (Just tv_name, inst_tv)
192       | otherwise                          = (Nothing,      inst_tv)
193       where
194         tv_name = tyVarName sig_tv
195
196     scoped_names = mkNameSet (hsExplicitTvs hs_ty)
197     (sig_tvs,_)  = tcSplitForAllTys sig_ty
198
199 instance NamedThing TcSigInfo where
200     getName TcSigInfo{ sig_id = id } = idName id
201     getName (TcPatSynInfo tpsi) = patsig_name tpsi
202
203 instance Outputable TcSigInfo where
204     ppr (TcSigInfo { sig_id = id, sig_tvs = tyvars, sig_theta = theta, sig_tau = tau })
205         = ppr id <+> dcolon <+> vcat [ pprSigmaType (mkSigmaTy (map snd tyvars) theta tau)
206                                      , ppr (map fst tyvars) ]
207     ppr (TcPatSynInfo tpsi) = text "TcPatSynInfo" <+> ppr tpsi
208
209 instance Outputable TcPatSynInfo where
210     ppr (TPSI{ patsig_name = name}) = ppr name
211
212 isPartialSig :: TcSigInfo -> Bool
213 isPartialSig = sig_partial
214 \end{code}
215
216 Note [Binding scoped type variables]
217 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
218 The type variables *brought into lexical scope* by a type signature may
219 be a subset of the *quantified type variables* of the signatures, for two reasons:
220
221 * With kind polymorphism a signature like
222     f :: forall f a. f a -> f a
223   may actually give rise to
224     f :: forall k. forall (f::k -> *) (a:k). f a -> f a
225   So the sig_tvs will be [k,f,a], but only f,a are scoped.
226   NB: the scoped ones are not necessarily the *inital* ones!
227
228 * Even aside from kind polymorphism, tere may be more instantiated
229   type variables than lexically-scoped ones.  For example:
230         type T a = forall b. b -> (a,b)
231         f :: forall c. T c
232   Here, the signature for f will have one scoped type variable, c,
233   but two instantiated type variables, c' and b'.
234
235 The function findScopedTyVars takes
236   * hs_ty:    the original HsForAllTy
237   * sig_ty:   the corresponding Type (which is guaranteed to use the same Names
238               as the HsForAllTy)
239   * inst_tvs: the skolems instantiated from the forall's in sig_ty
240 It returns a [(Maybe Name, TcTyVar)], in 1-1 correspondence with inst_tvs
241 but with a (Just n) for the lexically scoped name of each in-scope tyvar.
242
243 Note [sig_tau may be polymorphic]
244 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
245 Note that "sig_tau" might actually be a polymorphic type,
246 if the original function had a signature like
247    forall a. Eq a => forall b. Ord b => ....
248 But that's ok: tcMatchesFun (called by tcRhs) can deal with that
249 It happens, too!  See Note [Polymorphic methods] in TcClassDcl.
250
251 Note [Existential check]
252 ~~~~~~~~~~~~~~~~~~~~~~~~
253 Lazy patterns can't bind existentials.  They arise in two ways:
254   * Let bindings      let { C a b = e } in b
255   * Twiddle patterns  f ~(C a b) = e
256 The pe_lazy field of PatEnv says whether we are inside a lazy
257 pattern (perhaps deeply)
258
259 If we aren't inside a lazy pattern then we can bind existentials,
260 but we need to be careful about "extra" tyvars. Consider
261     (\C x -> d) : pat_ty -> res_ty
262 When looking for existential escape we must check that the existential
263 bound by C don't unify with the free variables of pat_ty, OR res_ty
264 (or of course the environment).   Hence we need to keep track of the
265 res_ty free vars.
266
267
268 %************************************************************************
269 %*                                                                      *
270                 Binders
271 %*                                                                      *
272 %************************************************************************
273
274 \begin{code}
275 tcPatBndr :: PatEnv -> Name -> TcSigmaType -> TcM (TcCoercion, TcId)
276 -- (coi, xp) = tcPatBndr penv x pat_ty
277 -- Then coi : pat_ty ~ typeof(xp)
278 --
279 tcPatBndr (PE { pe_ctxt = LetPat lookup_sig no_gen}) bndr_name pat_ty
280           -- See Note [Typing patterns in pattern bindings]
281   | LetGblBndr prags <- no_gen
282   , Just sig <- lookup_sig bndr_name
283   = do { bndr_id <- addInlinePrags (sig_id sig) (prags bndr_name)
284        ; traceTc "tcPatBndr(gbl,sig)" (ppr bndr_id $$ ppr (idType bndr_id))
285        ; co <- unifyPatType (idType bndr_id) pat_ty
286        ; return (co, bndr_id) }
287
288   | otherwise
289   = do { bndr_id <- newNoSigLetBndr no_gen bndr_name pat_ty
290        ; traceTc "tcPatBndr(no-sig)" (ppr bndr_id $$ ppr (idType bndr_id))
291        ; return (mkTcNomReflCo pat_ty, bndr_id) }
292
293 tcPatBndr (PE { pe_ctxt = _lam_or_proc }) bndr_name pat_ty
294   = do { bndr <- mkLocalBinder bndr_name pat_ty
295        ; return (mkTcNomReflCo pat_ty, bndr) }
296
297 ------------
298 newNoSigLetBndr :: LetBndrSpec -> Name -> TcType -> TcM TcId
299 -- In the polymorphic case (no_gen = LetLclBndr), generate a "monomorphic version"
300 --    of the Id; the original name will be bound to the polymorphic version
301 --    by the AbsBinds
302 -- In the monomorphic case (no_gen = LetBglBndr) there is no AbsBinds, and we
303 --    use the original name directly
304 newNoSigLetBndr LetLclBndr name ty
305   =do  { mono_name <- newLocalName name
306        ; mkLocalBinder mono_name ty }
307 newNoSigLetBndr (LetGblBndr prags) name ty
308   = do { id <- mkLocalBinder name ty
309        ; addInlinePrags id (prags name) }
310
311 ----------
312 addInlinePrags :: TcId -> [LSig Name] -> TcM TcId
313 addInlinePrags poly_id prags
314   = do { traceTc "addInlinePrags" (ppr poly_id $$ ppr prags)
315        ; tc_inl inl_sigs }
316   where
317     inl_sigs = filter isInlineLSig prags
318     tc_inl [] = return poly_id
319     tc_inl (L loc (InlineSig _ prag) : other_inls)
320        = do { unless (null other_inls) (setSrcSpan loc warn_dup_inline)
321             ; traceTc "addInlinePrag" (ppr poly_id $$ ppr prag)
322             ; return (poly_id `setInlinePragma` prag) }
323     tc_inl _ = panic "tc_inl"
324
325     warn_dup_inline = warnPrags poly_id inl_sigs $
326                       ptext (sLit "Duplicate INLINE pragmas for")
327
328 warnPrags :: Id -> [LSig Name] -> SDoc -> TcM ()
329 warnPrags id bad_sigs herald
330   = addWarnTc (hang (herald <+> quotes (ppr id))
331                   2 (ppr_sigs bad_sigs))
332   where
333     ppr_sigs sigs = vcat (map (ppr . getLoc) sigs)
334
335 -----------------
336 mkLocalBinder :: Name -> TcType -> TcM TcId
337 mkLocalBinder name ty
338   = return (Id.mkLocalId name ty)
339 \end{code}
340
341 Note [Typing patterns in pattern bindings]
342 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
343 Suppose we are typing a pattern binding
344     pat = rhs
345 Then the PatCtxt will be (LetPat sig_fn let_bndr_spec).
346
347 There can still be signatures for the binders:
348      data T = MkT (forall a. a->a) Int
349      x :: forall a. a->a
350      y :: Int
351      MkT x y = <rhs>
352
353 Two cases, dealt with by the LetPat case of tcPatBndr
354
355  * If we are generalising (generalisation plan is InferGen or
356    CheckGen), then the let_bndr_spec will be LetLclBndr.  In that case
357    we want to bind a cloned, local version of the variable, with the
358    type given by the pattern context, *not* by the signature (even if
359    there is one; see Trac #7268). The mkExport part of the
360    generalisation step will do the checking and impedence matching
361    against the signature.
362
363  * If for some some reason we are not generalising (plan = NoGen), the
364    LetBndrSpec will be LetGblBndr.  In that case we must bind the
365    global version of the Id, and do so with precisely the type given
366    in the signature.  (Then we unify with the type from the pattern
367    context type.
368
369
370 %************************************************************************
371 %*                                                                      *
372                 The main worker functions
373 %*                                                                      *
374 %************************************************************************
375
376 Note [Nesting]
377 ~~~~~~~~~~~~~~
378 tcPat takes a "thing inside" over which the pattern scopes.  This is partly
379 so that tcPat can extend the environment for the thing_inside, but also
380 so that constraints arising in the thing_inside can be discharged by the
381 pattern.
382
383 This does not work so well for the ErrCtxt carried by the monad: we don't
384 want the error-context for the pattern to scope over the RHS.
385 Hence the getErrCtxt/setErrCtxt stuff in tcMultiple
386
387 \begin{code}
388 --------------------
389 type Checker inp out =  forall r.
390                           inp
391                        -> PatEnv
392                        -> TcM r
393                        -> TcM (out, r)
394
395 tcMultiple :: Checker inp out -> Checker [inp] [out]
396 tcMultiple tc_pat args penv thing_inside
397   = do  { err_ctxt <- getErrCtxt
398         ; let loop _ []
399                 = do { res <- thing_inside
400                      ; return ([], res) }
401
402               loop penv (arg:args)
403                 = do { (p', (ps', res))
404                                 <- tc_pat arg penv $
405                                    setErrCtxt err_ctxt $
406                                    loop penv args
407                 -- setErrCtxt: restore context before doing the next pattern
408                 -- See note [Nesting] above
409
410                      ; return (p':ps', res) }
411
412         ; loop penv args }
413
414 --------------------
415 tc_lpat :: LPat Name
416         -> TcSigmaType
417         -> PatEnv
418         -> TcM a
419         -> TcM (LPat TcId, a)
420 tc_lpat (L span pat) pat_ty penv thing_inside
421   = setSrcSpan span $
422     do  { (pat', res) <- maybeWrapPatCtxt pat (tc_pat penv pat pat_ty)
423                                           thing_inside
424         ; return (L span pat', res) }
425
426 tc_lpats :: PatEnv
427          -> [LPat Name] -> [TcSigmaType]
428          -> TcM a
429          -> TcM ([LPat TcId], a)
430 tc_lpats penv pats tys thing_inside
431   = ASSERT2( equalLength pats tys, ppr pats $$ ppr tys )
432     tcMultiple (\(p,t) -> tc_lpat p t)
433                 (zipEqual "tc_lpats" pats tys)
434                 penv thing_inside
435
436 --------------------
437 tc_pat  :: PatEnv
438         -> Pat Name
439         -> TcSigmaType  -- Fully refined result type
440         -> TcM a                -- Thing inside
441         -> TcM (Pat TcId,       -- Translated pattern
442                 a)              -- Result of thing inside
443
444 tc_pat penv (VarPat name) pat_ty thing_inside
445   = do  { (co, id) <- tcPatBndr penv name pat_ty
446         ; res <- tcExtendIdEnv1 name id thing_inside
447         ; return (mkHsWrapPatCo co (VarPat id) pat_ty, res) }
448
449 tc_pat penv (ParPat pat) pat_ty thing_inside
450   = do  { (pat', res) <- tc_lpat pat pat_ty penv thing_inside
451         ; return (ParPat pat', res) }
452
453 tc_pat penv (BangPat pat) pat_ty thing_inside
454   = do  { (pat', res) <- tc_lpat pat pat_ty penv thing_inside
455         ; return (BangPat pat', res) }
456
457 tc_pat penv lpat@(LazyPat pat) pat_ty thing_inside
458   = do  { (pat', (res, pat_ct))
459                 <- tc_lpat pat pat_ty (makeLazy penv) $
460                    captureConstraints thing_inside
461                 -- Ignore refined penv', revert to penv
462
463         ; emitConstraints pat_ct
464         -- captureConstraints/extendConstraints:
465         --   see Note [Hopping the LIE in lazy patterns]
466
467         -- Check there are no unlifted types under the lazy pattern
468         ; when (any (isUnLiftedType . idType) $ collectPatBinders pat') $
469                lazyUnliftedPatErr lpat
470
471         -- Check that the expected pattern type is itself lifted
472         ; pat_ty' <- newFlexiTyVarTy liftedTypeKind
473         ; _ <- unifyType pat_ty pat_ty'
474
475         ; return (LazyPat pat', res) }
476
477 tc_pat _ p@(QuasiQuotePat _) _ _
478   = pprPanic "Should never see QuasiQuotePat in type checker" (ppr p)
479
480 tc_pat _ (WildPat _) pat_ty thing_inside
481   = do  { res <- thing_inside
482         ; return (WildPat pat_ty, res) }
483
484 tc_pat penv (AsPat (L nm_loc name) pat) pat_ty thing_inside
485   = do  { (co, bndr_id) <- setSrcSpan nm_loc (tcPatBndr penv name pat_ty)
486         ; (pat', res) <- tcExtendIdEnv1 name bndr_id $
487                          tc_lpat pat (idType bndr_id) penv thing_inside
488             -- NB: if we do inference on:
489             --          \ (y@(x::forall a. a->a)) = e
490             -- we'll fail.  The as-pattern infers a monotype for 'y', which then
491             -- fails to unify with the polymorphic type for 'x'.  This could
492             -- perhaps be fixed, but only with a bit more work.
493             --
494             -- If you fix it, don't forget the bindInstsOfPatIds!
495         ; return (mkHsWrapPatCo co (AsPat (L nm_loc bndr_id) pat') pat_ty, res) }
496
497 tc_pat penv (ViewPat expr pat _) overall_pat_ty thing_inside
498   = do  {
499          -- Morally, expr must have type `forall a1...aN. OPT' -> B`
500          -- where overall_pat_ty is an instance of OPT'.
501          -- Here, we infer a rho type for it,
502          -- which replaces the leading foralls and constraints
503          -- with fresh unification variables.
504         ; (expr',expr'_inferred) <- tcInferRho expr
505
506          -- next, we check that expr is coercible to `overall_pat_ty -> pat_ty`
507          -- NOTE: this forces pat_ty to be a monotype (because we use a unification
508          -- variable to find it).  this means that in an example like
509          -- (view -> f)    where view :: _ -> forall b. b
510          -- we will only be able to use view at one instantation in the
511          -- rest of the view
512         ; (expr_co, pat_ty) <- tcInfer $ \ pat_ty ->
513                 unifyType expr'_inferred (mkFunTy overall_pat_ty pat_ty)
514
515          -- pattern must have pat_ty
516         ; (pat', res) <- tc_lpat pat pat_ty penv thing_inside
517
518         ; return (ViewPat (mkLHsWrapCo expr_co expr') pat' overall_pat_ty, res) }
519
520 -- Type signatures in patterns
521 -- See Note [Pattern coercions] below
522 tc_pat penv (SigPatIn pat sig_ty) pat_ty thing_inside
523   = do  { (inner_ty, tv_binds, nwc_binds, wrap) <- tcPatSig (inPatBind penv)
524                                                             sig_ty pat_ty
525         ; (pat', res) <- tcExtendTyVarEnv2 (tv_binds ++ nwc_binds) $
526                          tc_lpat pat inner_ty penv thing_inside
527         ; return (mkHsWrapPat wrap (SigPatOut pat' inner_ty) pat_ty, res) }
528
529 ------------------------
530 -- Lists, tuples, arrays
531 tc_pat penv (ListPat pats _ Nothing) pat_ty thing_inside
532   = do  { (coi, elt_ty) <- matchExpectedPatTy matchExpectedListTy pat_ty
533         ; (pats', res) <- tcMultiple (\p -> tc_lpat p elt_ty)
534                                      pats penv thing_inside
535         ; return (mkHsWrapPat coi (ListPat pats' elt_ty Nothing) pat_ty, res)
536         }
537
538 tc_pat penv (ListPat pats _ (Just (_,e))) pat_ty thing_inside
539   = do  { list_pat_ty <- newFlexiTyVarTy liftedTypeKind
540         ; e' <- tcSyntaxOp ListOrigin e (mkFunTy pat_ty list_pat_ty)
541         ; (coi, elt_ty) <- matchExpectedPatTy matchExpectedListTy list_pat_ty
542         ; (pats', res) <- tcMultiple (\p -> tc_lpat p elt_ty)
543                                      pats penv thing_inside
544         ; return (mkHsWrapPat coi (ListPat pats' elt_ty (Just (pat_ty,e'))) list_pat_ty, res)
545         }
546
547 tc_pat penv (PArrPat pats _) pat_ty thing_inside
548   = do  { (coi, elt_ty) <- matchExpectedPatTy matchExpectedPArrTy pat_ty
549         ; (pats', res) <- tcMultiple (\p -> tc_lpat p elt_ty)
550                                      pats penv thing_inside
551         ; return (mkHsWrapPat coi (PArrPat pats' elt_ty) pat_ty, res)
552         }
553
554 tc_pat penv (TuplePat pats boxity _) pat_ty thing_inside
555   = do  { let tc = tupleTyCon (boxityNormalTupleSort boxity) (length pats)
556         ; (coi, arg_tys) <- matchExpectedPatTy (matchExpectedTyConApp tc) pat_ty
557         ; (pats', res) <- tc_lpats penv pats arg_tys thing_inside
558
559         ; dflags <- getDynFlags
560
561         -- Under flag control turn a pattern (x,y,z) into ~(x,y,z)
562         -- so that we can experiment with lazy tuple-matching.
563         -- This is a pretty odd place to make the switch, but
564         -- it was easy to do.
565         ; let
566               unmangled_result = TuplePat pats' boxity arg_tys
567                                  -- pat_ty /= pat_ty iff coi /= IdCo
568               possibly_mangled_result
569                 | gopt Opt_IrrefutableTuples dflags &&
570                   isBoxed boxity            = LazyPat (noLoc unmangled_result)
571                 | otherwise                 = unmangled_result
572
573         ; ASSERT( length arg_tys == length pats )      -- Syntactically enforced
574           return (mkHsWrapPat coi possibly_mangled_result pat_ty, res)
575         }
576
577 ------------------------
578 -- Data constructors
579 tc_pat penv (ConPatIn con arg_pats) pat_ty thing_inside
580   = tcConPat penv con pat_ty arg_pats thing_inside
581
582 ------------------------
583 -- Literal patterns
584 tc_pat _ (LitPat simple_lit) pat_ty thing_inside
585   = do  { let lit_ty = hsLitType simple_lit
586         ; co <- unifyPatType lit_ty pat_ty
587                 -- coi is of kind: pat_ty ~ lit_ty
588         ; res <- thing_inside
589         ; return ( mkHsWrapPatCo co (LitPat simple_lit) pat_ty
590                  , res) }
591
592 ------------------------
593 -- Overloaded patterns: n, and n+k
594 tc_pat _ (NPat over_lit mb_neg eq) pat_ty thing_inside
595   = do  { let orig = LiteralOrigin over_lit
596         ; lit'    <- newOverloadedLit orig over_lit pat_ty
597         ; eq'     <- tcSyntaxOp orig eq (mkFunTys [pat_ty, pat_ty] boolTy)
598         ; mb_neg' <- case mb_neg of
599                         Nothing  -> return Nothing      -- Positive literal
600                         Just neg ->     -- Negative literal
601                                         -- The 'negate' is re-mappable syntax
602                             do { neg' <- tcSyntaxOp orig neg (mkFunTy pat_ty pat_ty)
603                                ; return (Just neg') }
604         ; res <- thing_inside
605         ; return (NPat lit' mb_neg' eq', res) }
606
607 tc_pat penv (NPlusKPat (L nm_loc name) lit ge minus) pat_ty thing_inside
608   = do  { (co, bndr_id) <- setSrcSpan nm_loc (tcPatBndr penv name pat_ty)
609         ; let pat_ty' = idType bndr_id
610               orig    = LiteralOrigin lit
611         ; lit' <- newOverloadedLit orig lit pat_ty'
612
613         -- The '>=' and '-' parts are re-mappable syntax
614         ; ge'    <- tcSyntaxOp orig ge    (mkFunTys [pat_ty', pat_ty'] boolTy)
615         ; minus' <- tcSyntaxOp orig minus (mkFunTys [pat_ty', pat_ty'] pat_ty')
616         ; let pat' = NPlusKPat (L nm_loc bndr_id) lit' ge' minus'
617
618         -- The Report says that n+k patterns must be in Integral
619         -- We may not want this when using re-mappable syntax, though (ToDo?)
620         ; icls <- tcLookupClass integralClassName
621         ; instStupidTheta orig [mkClassPred icls [pat_ty']]
622
623         ; res <- tcExtendIdEnv1 name bndr_id thing_inside
624         ; return (mkHsWrapPatCo co pat' pat_ty, res) }
625
626 tc_pat _ _other_pat _ _ = panic "tc_pat"        -- ConPatOut, SigPatOut
627
628 ----------------
629 unifyPatType :: TcType -> TcType -> TcM TcCoercion
630 -- In patterns we want a coercion from the
631 -- context type (expected) to the actual pattern type
632 -- But we don't want to reverse the args to unifyType because
633 -- that controls the actual/expected stuff in error messages
634 unifyPatType actual_ty expected_ty
635   = do { coi <- unifyType actual_ty expected_ty
636        ; return (mkTcSymCo coi) }
637 \end{code}
638
639 Note [Hopping the LIE in lazy patterns]
640 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
641 In a lazy pattern, we must *not* discharge constraints from the RHS
642 from dictionaries bound in the pattern.  E.g.
643         f ~(C x) = 3
644 We can't discharge the Num constraint from dictionaries bound by
645 the pattern C!
646
647 So we have to make the constraints from thing_inside "hop around"
648 the pattern.  Hence the captureConstraints and emitConstraints.
649
650 The same thing ensures that equality constraints in a lazy match
651 are not made available in the RHS of the match. For example
652         data T a where { T1 :: Int -> T Int; ... }
653         f :: T a -> Int -> a
654         f ~(T1 i) y = y
655 It's obviously not sound to refine a to Int in the right
656 hand side, because the arugment might not match T1 at all!
657
658 Finally, a lazy pattern should not bind any existential type variables
659 because they won't be in scope when we do the desugaring
660
661
662 %************************************************************************
663 %*                                                                      *
664         Most of the work for constructors is here
665         (the rest is in the ConPatIn case of tc_pat)
666 %*                                                                      *
667 %************************************************************************
668
669 [Pattern matching indexed data types]
670 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
671 Consider the following declarations:
672
673   data family Map k :: * -> *
674   data instance Map (a, b) v = MapPair (Map a (Pair b v))
675
676 and a case expression
677
678   case x :: Map (Int, c) w of MapPair m -> ...
679
680 As explained by [Wrappers for data instance tycons] in MkIds.lhs, the
681 worker/wrapper types for MapPair are
682
683   $WMapPair :: forall a b v. Map a (Map a b v) -> Map (a, b) v
684   $wMapPair :: forall a b v. Map a (Map a b v) -> :R123Map a b v
685
686 So, the type of the scrutinee is Map (Int, c) w, but the tycon of MapPair is
687 :R123Map, which means the straight use of boxySplitTyConApp would give a type
688 error.  Hence, the smart wrapper function boxySplitTyConAppWithFamily calls
689 boxySplitTyConApp with the family tycon Map instead, which gives us the family
690 type list {(Int, c), w}.  To get the correct split for :R123Map, we need to
691 unify the family type list {(Int, c), w} with the instance types {(a, b), v}
692 (provided by tyConFamInst_maybe together with the family tycon).  This
693 unification yields the substitution [a -> Int, b -> c, v -> w], which gives us
694 the split arguments for the representation tycon :R123Map as {Int, c, w}
695
696 In other words, boxySplitTyConAppWithFamily implicitly takes the coercion
697
698   Co123Map a b v :: {Map (a, b) v ~ :R123Map a b v}
699
700 moving between representation and family type into account.  To produce type
701 correct Core, this coercion needs to be used to case the type of the scrutinee
702 from the family to the representation type.  This is achieved by
703 unwrapFamInstScrutinee using a CoPat around the result pattern.
704
705 Now it might appear seem as if we could have used the previous GADT type
706 refinement infrastructure of refineAlt and friends instead of the explicit
707 unification and CoPat generation.  However, that would be wrong.  Why?  The
708 whole point of GADT refinement is that the refinement is local to the case
709 alternative.  In contrast, the substitution generated by the unification of
710 the family type list and instance types needs to be propagated to the outside.
711 Imagine that in the above example, the type of the scrutinee would have been
712 (Map x w), then we would have unified {x, w} with {(a, b), v}, yielding the
713 substitution [x -> (a, b), v -> w].  In contrast to GADT matching, the
714 instantiation of x with (a, b) must be global; ie, it must be valid in *all*
715 alternatives of the case expression, whereas in the GADT case it might vary
716 between alternatives.
717
718 RIP GADT refinement: refinements have been replaced by the use of explicit
719 equality constraints that are used in conjunction with implication constraints
720 to express the local scope of GADT refinements.
721
722 \begin{code}
723 --      Running example:
724 -- MkT :: forall a b c. (a~[b]) => b -> c -> T a
725 --       with scrutinee of type (T ty)
726
727 tcConPat :: PatEnv -> Located Name
728          -> TcRhoType           -- Type of the pattern
729          -> HsConPatDetails Name -> TcM a
730          -> TcM (Pat TcId, a)
731 tcConPat penv con_lname@(L _ con_name) pat_ty arg_pats thing_inside
732   = do  { con_like <- tcLookupConLike con_name
733         ; case con_like of
734             RealDataCon data_con -> tcDataConPat penv con_lname data_con
735                                                  pat_ty arg_pats thing_inside
736             PatSynCon pat_syn -> tcPatSynPat penv con_lname pat_syn
737                                              pat_ty arg_pats thing_inside
738         }
739
740 tcDataConPat :: PatEnv -> Located Name -> DataCon
741              -> TcRhoType               -- Type of the pattern
742              -> HsConPatDetails Name -> TcM a
743              -> TcM (Pat TcId, a)
744 tcDataConPat penv (L con_span con_name) data_con pat_ty arg_pats thing_inside
745   = do  { let tycon = dataConTyCon data_con
746                   -- For data families this is the representation tycon
747               (univ_tvs, ex_tvs, eq_spec, theta, arg_tys, _)
748                 = dataConFullSig data_con
749               header = L con_span (RealDataCon data_con)
750
751           -- Instantiate the constructor type variables [a->ty]
752           -- This may involve doing a family-instance coercion,
753           -- and building a wrapper
754         ; (wrap, ctxt_res_tys) <- matchExpectedPatTy (matchExpectedConTy tycon) pat_ty
755
756           -- Add the stupid theta
757         ; setSrcSpan con_span $ addDataConStupidTheta data_con ctxt_res_tys
758
759         ; checkExistentials ex_tvs penv
760         ; (tenv, ex_tvs') <- tcInstSuperSkolTyVarsX
761                                (zipTopTvSubst univ_tvs ctxt_res_tys) ex_tvs
762                      -- Get location from monad, not from ex_tvs
763
764         ; let -- pat_ty' = mkTyConApp tycon ctxt_res_tys
765               -- pat_ty' is type of the actual constructor application
766               -- pat_ty' /= pat_ty iff coi /= IdCo
767
768               arg_tys' = substTys tenv arg_tys
769
770         ; traceTc "tcConPat" (vcat [ ppr con_name, ppr univ_tvs, ppr ex_tvs, ppr eq_spec
771                                    , ppr ex_tvs', ppr ctxt_res_tys, ppr arg_tys' ])
772         ; if null ex_tvs && null eq_spec && null theta
773           then do { -- The common case; no class bindings etc
774                     -- (see Note [Arrows and patterns])
775                     (arg_pats', res) <- tcConArgs (RealDataCon data_con) arg_tys'
776                                                   arg_pats penv thing_inside
777                   ; let res_pat = ConPatOut { pat_con = header,
778                                               pat_tvs = [], pat_dicts = [],
779                                               pat_binds = emptyTcEvBinds,
780                                               pat_args = arg_pats',
781                                               pat_arg_tys = ctxt_res_tys,
782                                               pat_wrap = idHsWrapper }
783
784                   ; return (mkHsWrapPat wrap res_pat pat_ty, res) }
785
786           else do   -- The general case, with existential,
787                     -- and local equality constraints
788         { let theta'   = substTheta tenv (eqSpecPreds eq_spec ++ theta)
789                            -- order is *important* as we generate the list of
790                            -- dictionary binders from theta'
791               no_equalities = not (any isEqPred theta')
792               skol_info = case pe_ctxt penv of
793                             LamPat mc -> PatSkol (RealDataCon data_con) mc
794                             LetPat {} -> UnkSkol -- Doesn't matter
795
796         ; gadts_on    <- xoptM Opt_GADTs
797         ; families_on <- xoptM Opt_TypeFamilies
798         ; checkTc (no_equalities || gadts_on || families_on)
799                   (ptext (sLit "A pattern match on a GADT requires GADTs or TypeFamilies"))
800                   -- Trac #2905 decided that a *pattern-match* of a GADT
801                   -- should require the GADT language flag.
802                   -- Re TypeFamilies see also #7156
803
804         ; given <- newEvVars theta'
805         ; (ev_binds, (arg_pats', res))
806              <- checkConstraints skol_info ex_tvs' given $
807                 tcConArgs (RealDataCon data_con) arg_tys' arg_pats penv thing_inside
808
809         ; let res_pat = ConPatOut { pat_con   = header,
810                                     pat_tvs   = ex_tvs',
811                                     pat_dicts = given,
812                                     pat_binds = ev_binds,
813                                     pat_args  = arg_pats',
814                                     pat_arg_tys = ctxt_res_tys,
815                                     pat_wrap  = idHsWrapper }
816         ; return (mkHsWrapPat wrap res_pat pat_ty, res)
817         } }
818
819 tcPatSynPat :: PatEnv -> Located Name -> PatSyn
820             -> TcRhoType                -- Type of the pattern
821             -> HsConPatDetails Name -> TcM a
822             -> TcM (Pat TcId, a)
823 tcPatSynPat penv (L con_span _) pat_syn pat_ty arg_pats thing_inside
824   = do  { let (univ_tvs, ex_tvs, prov_theta, req_theta, arg_tys, ty) = patSynSig pat_syn
825
826         ; (subst, univ_tvs') <- tcInstTyVars univ_tvs
827
828         ; checkExistentials ex_tvs penv
829         ; (tenv, ex_tvs') <- tcInstSuperSkolTyVarsX subst ex_tvs
830         ; let ty' = substTy tenv ty
831               arg_tys' = substTys tenv arg_tys
832               prov_theta' = substTheta tenv prov_theta
833               req_theta' = substTheta tenv req_theta
834
835         ; wrap <- coToHsWrapper <$> unifyType ty' pat_ty
836         ; traceTc "tcPatSynPat" (ppr pat_syn $$
837                                  ppr pat_ty $$
838                                  ppr ty' $$
839                                  ppr ex_tvs' $$
840                                  ppr prov_theta' $$
841                                  ppr req_theta' $$
842                                  ppr arg_tys')
843
844         ; prov_dicts' <- newEvVars prov_theta'
845
846         ; let skol_info = case pe_ctxt penv of
847                             LamPat mc -> PatSkol (PatSynCon pat_syn) mc
848                             LetPat {} -> UnkSkol -- Doesn't matter
849
850         ; req_wrap <- instCall PatOrigin (mkTyVarTys univ_tvs') req_theta'
851         ; traceTc "instCall" (ppr req_wrap)
852
853         ; traceTc "checkConstraints {" Outputable.empty
854         ; (ev_binds, (arg_pats', res))
855              <- checkConstraints skol_info ex_tvs' prov_dicts' $
856                 tcConArgs (PatSynCon pat_syn) arg_tys' arg_pats penv thing_inside
857
858         ; traceTc "checkConstraints }" (ppr ev_binds)
859         ; let res_pat = ConPatOut { pat_con   = L con_span $ PatSynCon pat_syn,
860                                     pat_tvs   = ex_tvs',
861                                     pat_dicts = prov_dicts',
862                                     pat_binds = ev_binds,
863                                     pat_args  = arg_pats',
864                                     pat_arg_tys = mkTyVarTys univ_tvs',
865                                     pat_wrap  = req_wrap }
866         ; return (mkHsWrapPat wrap res_pat pat_ty, res) }
867
868 ----------------------------
869 matchExpectedPatTy :: (TcRhoType -> TcM (TcCoercion, a))
870                     -> TcRhoType -> TcM (HsWrapper, a)
871 -- See Note [Matching polytyped patterns]
872 -- Returns a wrapper : pat_ty ~ inner_ty
873 matchExpectedPatTy inner_match pat_ty
874   | null tvs && null theta
875   = do { (co, res) <- inner_match pat_ty
876        ; return (coToHsWrapper (mkTcSymCo co), res) }
877          -- The Sym is because the inner_match returns a coercion
878          -- that is the other way round to matchExpectedPatTy
879
880   | otherwise
881   = do { (subst, tvs') <- tcInstTyVars tvs
882        ; wrap1 <- instCall PatOrigin (mkTyVarTys tvs') (substTheta subst theta)
883        ; (wrap2, arg_tys) <- matchExpectedPatTy inner_match (TcType.substTy subst tau)
884        ; return (wrap2 <.> wrap1, arg_tys) }
885   where
886     (tvs, theta, tau) = tcSplitSigmaTy pat_ty
887
888 ----------------------------
889 matchExpectedConTy :: TyCon      -- The TyCon that this data
890                                  -- constructor actually returns
891                    -> TcRhoType  -- The type of the pattern
892                    -> TcM (TcCoercion, [TcSigmaType])
893 -- See Note [Matching constructor patterns]
894 -- Returns a coercion : T ty1 ... tyn ~ pat_ty
895 -- This is the same way round as matchExpectedListTy etc
896 -- but the other way round to matchExpectedPatTy
897 matchExpectedConTy data_tc pat_ty
898   | Just (fam_tc, fam_args, co_tc) <- tyConFamInstSig_maybe data_tc
899          -- Comments refer to Note [Matching constructor patterns]
900          -- co_tc :: forall a. T [a] ~ T7 a
901   = do { (subst, tvs') <- tcInstTyVars (tyConTyVars data_tc)
902              -- tys = [ty1,ty2]
903
904        ; traceTc "matchExpectedConTy" (vcat [ppr data_tc,
905                                              ppr (tyConTyVars data_tc),
906                                              ppr fam_tc, ppr fam_args])
907        ; co1 <- unifyType (mkTyConApp fam_tc (substTys subst fam_args)) pat_ty
908              -- co1 : T (ty1,ty2) ~ pat_ty
909
910        ; let tys' = mkTyVarTys tvs'
911              co2 = mkTcUnbranchedAxInstCo Nominal co_tc tys'
912              -- co2 : T (ty1,ty2) ~ T7 ty1 ty2
913
914        ; return (mkTcSymCo co2 `mkTcTransCo` co1, tys') }
915
916   | otherwise
917   = matchExpectedTyConApp data_tc pat_ty
918              -- coi : T tys ~ pat_ty
919 \end{code}
920
921 Note [Matching constructor patterns]
922 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
923 Suppose (coi, tys) = matchExpectedConType data_tc pat_ty
924
925  * In the simple case, pat_ty = tc tys
926
927  * If pat_ty is a polytype, we want to instantiate it
928    This is like part of a subsumption check.  Eg
929       f :: (forall a. [a]) -> blah
930       f [] = blah
931
932  * In a type family case, suppose we have
933           data family T a
934           data instance T (p,q) = A p | B q
935        Then we'll have internally generated
936               data T7 p q = A p | B q
937               axiom coT7 p q :: T (p,q) ~ T7 p q
938
939        So if pat_ty = T (ty1,ty2), we return (coi, [ty1,ty2]) such that
940            coi = coi2 . coi1 : T7 t ~ pat_ty
941            coi1 : T (ty1,ty2) ~ pat_ty
942            coi2 : T7 ty1 ty2 ~ T (ty1,ty2)
943
944    For families we do all this matching here, not in the unifier,
945    because we never want a whisper of the data_tycon to appear in
946    error messages; it's a purely internal thing
947
948 \begin{code}
949 tcConArgs :: ConLike -> [TcSigmaType]
950           -> Checker (HsConPatDetails Name) (HsConPatDetails Id)
951
952 tcConArgs con_like arg_tys (PrefixCon arg_pats) penv thing_inside
953   = do  { checkTc (con_arity == no_of_args)     -- Check correct arity
954                   (arityErr "Constructor" con_like con_arity no_of_args)
955         ; let pats_w_tys = zipEqual "tcConArgs" arg_pats arg_tys
956         ; (arg_pats', res) <- tcMultiple tcConArg pats_w_tys
957                                               penv thing_inside
958         ; return (PrefixCon arg_pats', res) }
959   where
960     con_arity  = conLikeArity con_like
961     no_of_args = length arg_pats
962
963 tcConArgs con_like arg_tys (InfixCon p1 p2) penv thing_inside
964   = do  { checkTc (con_arity == 2)      -- Check correct arity
965                   (arityErr "Constructor" con_like con_arity 2)
966         ; let [arg_ty1,arg_ty2] = arg_tys       -- This can't fail after the arity check
967         ; ([p1',p2'], res) <- tcMultiple tcConArg [(p1,arg_ty1),(p2,arg_ty2)]
968                                               penv thing_inside
969         ; return (InfixCon p1' p2', res) }
970   where
971     con_arity  = conLikeArity con_like
972
973 tcConArgs con_like arg_tys (RecCon (HsRecFields rpats dd)) penv thing_inside
974   = do  { (rpats', res) <- tcMultiple tc_field rpats penv thing_inside
975         ; return (RecCon (HsRecFields rpats' dd), res) }
976   where
977     tc_field :: Checker (LHsRecField FieldLabel (LPat Name))
978                         (LHsRecField TcId (LPat TcId))
979     tc_field (L l (HsRecField field_lbl pat pun)) penv thing_inside
980       = do { (sel_id, pat_ty) <- wrapLocFstM find_field_ty field_lbl
981            ; (pat', res) <- tcConArg (pat, pat_ty) penv thing_inside
982            ; return (L l (HsRecField sel_id pat' pun), res) }
983
984     find_field_ty :: FieldLabel -> TcM (Id, TcType)
985     find_field_ty field_lbl
986         = case [ty | (f,ty) <- field_tys, f == field_lbl] of
987
988                 -- No matching field; chances are this field label comes from some
989                 -- other record type (or maybe none).  If this happens, just fail,
990                 -- otherwise we get crashes later (Trac #8570), and similar:
991                 --      f (R { foo = (a,b) }) = a+b
992                 -- If foo isn't one of R's fields, we don't want to crash when
993                 -- typechecking the "a+b".
994            [] -> failWith (badFieldCon con_like field_lbl)
995
996                 -- The normal case, when the field comes from the right constructor
997            (pat_ty : extras) ->
998                 ASSERT( null extras )
999                 do { sel_id <- tcLookupField field_lbl
1000                    ; return (sel_id, pat_ty) }
1001
1002     field_tys :: [(FieldLabel, TcType)]
1003     field_tys = case con_like of
1004         RealDataCon data_con -> zip (dataConFieldLabels data_con) arg_tys
1005           -- Don't use zipEqual! If the constructor isn't really a record, then
1006           -- dataConFieldLabels will be empty (and each field in the pattern
1007           -- will generate an error below).
1008         PatSynCon{} -> []
1009
1010 conLikeArity :: ConLike -> Arity
1011 conLikeArity (RealDataCon data_con) = dataConSourceArity data_con
1012 conLikeArity (PatSynCon   pat_syn)  = patSynArity pat_syn
1013
1014 tcConArg :: Checker (LPat Name, TcSigmaType) (LPat Id)
1015 tcConArg (arg_pat, arg_ty) penv thing_inside
1016   = tc_lpat arg_pat arg_ty penv thing_inside
1017 \end{code}
1018
1019 \begin{code}
1020 addDataConStupidTheta :: DataCon -> [TcType] -> TcM ()
1021 -- Instantiate the "stupid theta" of the data con, and throw
1022 -- the constraints into the constraint set
1023 addDataConStupidTheta data_con inst_tys
1024   | null stupid_theta = return ()
1025   | otherwise         = instStupidTheta origin inst_theta
1026   where
1027     origin = OccurrenceOf (dataConName data_con)
1028         -- The origin should always report "occurrence of C"
1029         -- even when C occurs in a pattern
1030     stupid_theta = dataConStupidTheta data_con
1031     tenv = mkTopTvSubst (dataConUnivTyVars data_con `zip` inst_tys)
1032          -- NB: inst_tys can be longer than the univ tyvars
1033          --     because the constructor might have existentials
1034     inst_theta = substTheta tenv stupid_theta
1035 \end{code}
1036
1037 Note [Arrows and patterns]
1038 ~~~~~~~~~~~~~~~~~~~~~~~~~~
1039 (Oct 07) Arrow noation has the odd property that it involves
1040 "holes in the scope". For example:
1041   expr :: Arrow a => a () Int
1042   expr = proc (y,z) -> do
1043           x <- term -< y
1044           expr' -< x
1045
1046 Here the 'proc (y,z)' binding scopes over the arrow tails but not the
1047 arrow body (e.g 'term').  As things stand (bogusly) all the
1048 constraints from the proc body are gathered together, so constraints
1049 from 'term' will be seen by the tcPat for (y,z).  But we must *not*
1050 bind constraints from 'term' here, because the desugarer will not make
1051 these bindings scope over 'term'.
1052
1053 The Right Thing is not to confuse these constraints together. But for
1054 now the Easy Thing is to ensure that we do not have existential or
1055 GADT constraints in a 'proc', and to short-cut the constraint
1056 simplification for such vanilla patterns so that it binds no
1057 constraints. Hence the 'fast path' in tcConPat; but it's also a good
1058 plan for ordinary vanilla patterns to bypass the constraint
1059 simplification step.
1060
1061 %************************************************************************
1062 %*                                                                      *
1063                 Note [Pattern coercions]
1064 %*                                                                      *
1065 %************************************************************************
1066
1067 In principle, these program would be reasonable:
1068
1069         f :: (forall a. a->a) -> Int
1070         f (x :: Int->Int) = x 3
1071
1072         g :: (forall a. [a]) -> Bool
1073         g [] = True
1074
1075 In both cases, the function type signature restricts what arguments can be passed
1076 in a call (to polymorphic ones).  The pattern type signature then instantiates this
1077 type.  For example, in the first case,  (forall a. a->a) <= Int -> Int, and we
1078 generate the translated term
1079         f = \x' :: (forall a. a->a).  let x = x' Int in x 3
1080
1081 From a type-system point of view, this is perfectly fine, but it's *very* seldom useful.
1082 And it requires a significant amount of code to implement, because we need to decorate
1083 the translated pattern with coercion functions (generated from the subsumption check
1084 by tcSub).
1085
1086 So for now I'm just insisting on type *equality* in patterns.  No subsumption.
1087
1088 Old notes about desugaring, at a time when pattern coercions were handled:
1089
1090 A SigPat is a type coercion and must be handled one at at time.  We can't
1091 combine them unless the type of the pattern inside is identical, and we don't
1092 bother to check for that.  For example:
1093
1094         data T = T1 Int | T2 Bool
1095         f :: (forall a. a -> a) -> T -> t
1096         f (g::Int->Int)   (T1 i) = T1 (g i)
1097         f (g::Bool->Bool) (T2 b) = T2 (g b)
1098
1099 We desugar this as follows:
1100
1101         f = \ g::(forall a. a->a) t::T ->
1102             let gi = g Int
1103             in case t of { T1 i -> T1 (gi i)
1104                            other ->
1105             let gb = g Bool
1106             in case t of { T2 b -> T2 (gb b)
1107                            other -> fail }}
1108
1109 Note that we do not treat the first column of patterns as a
1110 column of variables, because the coerced variables (gi, gb)
1111 would be of different types.  So we get rather grotty code.
1112 But I don't think this is a common case, and if it was we could
1113 doubtless improve it.
1114
1115 Meanwhile, the strategy is:
1116         * treat each SigPat coercion (always non-identity coercions)
1117                 as a separate block
1118         * deal with the stuff inside, and then wrap a binding round
1119                 the result to bind the new variable (gi, gb, etc)
1120
1121
1122 %************************************************************************
1123 %*                                                                      *
1124 \subsection{Errors and contexts}
1125 %*                                                                      *
1126 %************************************************************************
1127
1128 \begin{code}
1129 maybeWrapPatCtxt :: Pat Name -> (TcM a -> TcM b) -> TcM a -> TcM b
1130 -- Not all patterns are worth pushing a context
1131 maybeWrapPatCtxt pat tcm thing_inside
1132   | not (worth_wrapping pat) = tcm thing_inside
1133   | otherwise                = addErrCtxt msg $ tcm $ popErrCtxt thing_inside
1134                                -- Remember to pop before doing thing_inside
1135   where
1136    worth_wrapping (VarPat {}) = False
1137    worth_wrapping (ParPat {}) = False
1138    worth_wrapping (AsPat {})  = False
1139    worth_wrapping _           = True
1140    msg = hang (ptext (sLit "In the pattern:")) 2 (ppr pat)
1141
1142 -----------------------------------------------
1143 checkExistentials :: [TyVar] -> PatEnv -> TcM ()
1144           -- See Note [Arrows and patterns]
1145 checkExistentials [] _                                 = return ()
1146 checkExistentials _ (PE { pe_ctxt = LetPat {}})        = failWithTc existentialLetPat
1147 checkExistentials _ (PE { pe_ctxt = LamPat ProcExpr }) = failWithTc existentialProcPat
1148 checkExistentials _ (PE { pe_lazy = True })            = failWithTc existentialLazyPat
1149 checkExistentials _ _                                  = return ()
1150
1151 existentialLazyPat :: SDoc
1152 existentialLazyPat
1153   = hang (ptext (sLit "An existential or GADT data constructor cannot be used"))
1154        2 (ptext (sLit "inside a lazy (~) pattern"))
1155
1156 existentialProcPat :: SDoc
1157 existentialProcPat
1158   = ptext (sLit "Proc patterns cannot use existential or GADT data constructors")
1159
1160 existentialLetPat :: SDoc
1161 existentialLetPat
1162   = vcat [text "My brain just exploded",
1163           text "I can't handle pattern bindings for existential or GADT data constructors.",
1164           text "Instead, use a case-expression, or do-notation, to unpack the constructor."]
1165
1166 badFieldCon :: ConLike -> Name -> SDoc
1167 badFieldCon con field
1168   = hsep [ptext (sLit "Constructor") <+> quotes (ppr con),
1169           ptext (sLit "does not have field"), quotes (ppr field)]
1170
1171 polyPatSig :: TcType -> SDoc
1172 polyPatSig sig_ty
1173   = hang (ptext (sLit "Illegal polymorphic type signature in pattern:"))
1174        2 (ppr sig_ty)
1175
1176 lazyUnliftedPatErr :: OutputableBndr name => Pat name -> TcM ()
1177 lazyUnliftedPatErr pat
1178   = failWithTc $
1179     hang (ptext (sLit "A lazy (~) pattern cannot contain unlifted types:"))
1180        2 (ppr pat)
1181 \end{code}