Fix misspellings of the word "instance" in comments
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.1], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl this makes sure `./configure --target=<cross-compile-target>`
37 dnl works as expected, since we're slightly modifying how Autoconf
38 dnl interprets build/host/target and how this interacts with $CC tests
39 test -n "$target_alias" && ac_tool_prefix=$target_alias-
40
41 dnl ----------------------------------------------------------
42 dnl ** Find unixy sort and find commands,
43 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
44
45 dnl ** Find find command (for Win32's benefit)
46 FP_PROG_FIND
47 FP_PROG_SORT
48
49 dnl ----------------------------------------------------------
50 FP_SETUP_PROJECT_VERSION
51
52 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
53 AC_SUBST([release], [1])
54
55 # First off, a distrib sanity check..
56 AC_CONFIG_SRCDIR([mk/config.mk.in])
57
58 dnl * We require autoconf version 2.60
59 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
60 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
61 dnl Using autoconf 2.59 started to give nonsense like this
62 dnl  #define SIZEOF_CHAR 0
63 dnl recently.
64 AC_PREREQ([2.60])
65
66 # -------------------------------------------------------------------------
67 # Prepare to generate the following header files
68 #
69 #
70 AC_CONFIG_HEADER(mk/config.h)
71
72 # No, semi-sadly, we don't do `--srcdir'...
73 if test x"$srcdir" != 'x.' ; then
74     echo "This configuration does not support the \`--srcdir' option.."
75     exit 1
76 fi
77
78 dnl --------------------------------------------------------------
79 dnl * Project specific configuration options
80 dnl --------------------------------------------------------------
81 dnl What follows is a bunch of options that can either be configured
82 dnl through command line options to the configure script or by
83 dnl supplying defns in the build tree's mk/build.mk. Having the option to
84 dnl use either is considered a Feature.
85
86 dnl ** What command to use to compile compiler sources ?
87 dnl --------------------------------------------------------------
88
89 AC_ARG_WITH([ghc],
90 [AC_HELP_STRING([--with-ghc=ARG],
91   [Use ARG as the path to GHC  [default=autodetect]])],
92   [WithGhc="$withval"],
93   [if test "$GHC" = ""; then
94     AC_PATH_PROG([GHC], [ghc])
95   fi
96   WithGhc="$GHC"])
97
98 dnl ** Tell the make system which OS we are using
99 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
100 AC_SUBST(OSTYPE)
101
102 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
103 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
104                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
105         EnableBootstrapWithDevelSnaphost=YES,
106         EnableBootstrapWithDevelSnaphost=NO
107 )
108
109 AC_ARG_ENABLE(tarballs-autodownload,
110 [AC_HELP_STRING([--enable-tarballs-autodownload],
111                 [Automatically download Windows distribution binaries if needed.])],
112         TarballsAutodownload=YES,
113         TarballsAutodownload=NO
114 )
115
116 dnl CC_STAGE0 is like the "previous" variable CC (inherited by CC_STAGE[123])
117 dnl but instead used by stage0 for bootstrapping stage1
118 AC_ARG_VAR(CC_STAGE0, [C compiler command (bootstrap)])
119
120 if test "$WithGhc" != ""; then
121   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
122
123   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
124      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
125   fi
126
127   AC_SUBST(GhcVersion)dnl
128   AC_SUBST(GhcMajVersion)dnl
129   AC_SUBST(GhcMinVersion)dnl
130   AC_SUBST(GhcPatchLevel)dnl
131   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
132   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
133
134   dnl infer CC_STAGE0 from `ghc --info` unless explicitly set by user
135   if test -z "$CC_STAGE0"; then
136     BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
137   fi
138
139   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
140   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
141   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
142   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
143 fi
144
145 dnl ** Must have GHC to build GHC
146 if test "$WithGhc" = ""
147 then
148     AC_MSG_ERROR([GHC is required.])
149 fi
150 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.10],
151     [AC_MSG_ERROR([GHC version 7.10 or later is required to compile GHC.])])
152
153 if test `expr $GhcMinVersion % 2` = "1"
154 then
155     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
156     then
157         AC_MSG_ERROR([
158      $WithGhc is a development snapshot of GHC, version $GhcVersion.
159      Bootstrapping using this version of GHC is not supported, and may not
160      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
161      or --with-ghc to specify a different GHC to use.])
162     fi
163 fi
164
165 GHC_PACKAGE_DB_FLAG=package-db
166 AC_SUBST(GHC_PACKAGE_DB_FLAG)
167
168 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.11],
169                     SUPPORTS_THIS_UNIT_ID=NO,
170                     SUPPORTS_THIS_UNIT_ID=YES)
171 AC_SUBST(SUPPORTS_THIS_UNIT_ID)
172
173 # GHC is passed to Cabal, so we need a native path
174 if test "${WithGhc}" != ""
175 then
176     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
177
178     if test "$ghc_host_os" = "mingw32"
179     then
180         # Canonicalise to <drive>:/path/to/ghc
181         WithGhc=`cygpath -m "${WithGhc}"`
182
183         echo "GHC path canonicalised to: ${WithGhc}"
184     fi
185 fi
186 AC_SUBST([WithGhc])
187
188 dnl ** Without optimization some INLINE trickery fails for GHCi
189 SRC_CC_OPTS="-O"
190
191 dnl--------------------------------------------------------------------
192 dnl * Choose host(/target/build) platform
193 dnl--------------------------------------------------------------------
194 dnl If we aren't explicitly told what values to use with configure flags,
195 dnl we ask the bootstrapping compiler what platform it is for
196
197 if test "${WithGhc}" != ""
198 then
199         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
200         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
201         if test "$bootstrap_host" != "$bootstrap_target"
202         then
203                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
204         fi
205 fi
206
207 # We have to run these unconditionally, but we may discard their
208 # results in the following code
209 AC_CANONICAL_BUILD
210 AC_CANONICAL_HOST
211 AC_CANONICAL_TARGET
212
213 FPTOOLS_SET_PLATFORM_VARS
214
215 # Verify that the installed (bootstrap) GHC is capable of generating
216 # code for the requested build platform.
217 if test "$BuildPlatform" != "$bootstrap_target"
218 then
219     echo "This GHC (${WithGhc}) does not generate code for the build platform"
220     echo "   GHC target platform    : $bootstrap_target"
221     echo "   Desired build platform : $BuildPlatform"
222     exit 1
223 fi
224
225 # Testing if we shall enable shared libs support on Solaris.
226 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
227
228 SOLARIS_BROKEN_SHLD=NO
229
230 case $host in
231      i386-*-solaris2)
232      # here we go with the test
233      MINOR=`uname -r|cut -d '.' -f 2-`
234      if test "$MINOR" -lt "11"; then
235          SOLARIS_BROKEN_SHLD=YES
236      fi
237      ;;
238 esac
239
240 AC_SUBST(SOLARIS_BROKEN_SHLD)
241
242 dnl ** Do an unregisterised build?
243 dnl --------------------------------------------------------------
244 case "$HostArch" in
245     i386|x86_64|powerpc|powerpc64|powerpc64le|arm)
246         UnregisterisedDefault=NO
247         ;;
248     *)
249         UnregisterisedDefault=YES
250         ;;
251 esac
252 AC_ARG_ENABLE(unregisterised,
253 [AC_HELP_STRING([--enable-unregisterised],
254 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
255 [ if test x"$enableval" = x"yes"; then
256         Unregisterised=YES
257   else
258         Unregisterised=NO
259   fi
260 ],
261 [Unregisterised="$UnregisterisedDefault"]
262 )
263 AC_SUBST(Unregisterised)
264
265 # Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
266 FP_FIND_ROOT
267
268 fail() {
269     echo >&2
270     echo "$1" >&2
271     exit 1
272 }
273
274
275 if test "$HostOS" = "mingw32"
276 then
277     # Find the mingw-w64 7z file to extract.
278     # NB. If you update the tarballs to a new version of gcc, don't
279     # forget to tweak the paths in driver/gcc/gcc.c.
280     if test "$HostArch" = "i386"
281     then
282         mingw_arch="i686"
283         tarball_dest_dir="mingw-w64/x86"
284         tarball_mingw_dir="mingw32"
285     else
286         mingw_arch="x86_64"
287         tarball_dest_dir="mingw-w64/x86_64"
288         tarball_mingw_dir="mingw64"
289     fi
290 fi
291
292 set_up_tarballs() {
293     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
294     local action
295     if test "$TarballsAutodownload" = "NO"
296     then
297         action="verify"
298     else
299         action="download"
300     fi
301     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
302     case $? in
303         0)
304            rm missing-win32-tarballs
305            ;;
306         2)
307            echo
308            echo "Error:"
309            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
310            echo
311            echo "  * run configure with the --enable-tarballs-autodownload option"
312            echo
313            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
314            echo
315            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
316            echo "    them in the ghc-tarballs directory."
317            echo
318            exit 1
319            ;;
320         *)
321            echo
322            echo "Error fetching msys2 tarballs; see errors above."
323            exit 1
324            ;;
325     esac
326
327     # Extract all the tarballs in one go
328     if ! test -d inplace/mingw
329     then
330         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
331         rm -rf inplace/mingw
332         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
333         ( cd inplace &&
334         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
335         rm ".MTREE" &&
336         rm ".PKGINFO" &&
337         cd .. ) || fail "Error: Could not extract Windows toolchains."
338
339         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
340         touch inplace/mingw
341
342         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
343         # make a wrapper around it to give it the proper paths
344         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
345         PATH=`pwd`/inplace/mingw/bin:$PATH
346         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
347
348         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
349     fi
350 }
351
352 if test "$HostOS" = "mingw32"
353 then
354     test -d inplace || mkdir inplace
355
356     # NB. Download and extract the MingW-w64 distribution if required
357     set_up_tarballs
358
359     mingwbin="$hardtop/inplace/mingw/bin/"
360     CC="${mingwbin}gcc.exe"
361     LD="${mingwbin}ld.exe"
362     NM="${mingwbin}nm.exe"
363     RANLIB="${mingwbin}ranlib.exe"
364     OBJDUMP="${mingwbin}objdump.exe"
365     Windres="${mingwbin}windres.exe"
366     DllWrap="${mingwbin}dllwrap.exe"
367     fp_prog_ar="${mingwbin}ar.exe"
368
369     # NB. Download the perl binaries if required
370     if ! test -d inplace/perl ||
371          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
372     then
373         AC_MSG_NOTICE([Making in-tree perl tree])
374         rm -rf inplace/perl
375         mkdir inplace/perl
376         (
377             cd inplace/perl &&
378             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
379         )
380         AC_MSG_NOTICE([In-tree perl tree created])
381     fi
382 fi
383
384 FP_ICONV
385 FP_GMP
386 FP_CURSES
387
388 XCODE_VERSION()
389
390 SplitObjsBroken=NO
391 if test "$TargetOS_CPP" = "darwin"
392 then
393     # Split objects is broken (#4013) with XCode < 3.2
394     if test "$XCodeVersion1" -lt 3
395     then
396         SplitObjsBroken=YES
397     else
398         if test "$XCodeVersion1" -eq 3
399         then
400             if test "$XCodeVersion2" -lt 2
401             then
402                 SplitObjsBroken=YES
403             fi
404         fi
405     fi
406 fi
407 AC_SUBST([SplitObjsBroken])
408
409 dnl ** Building a cross compiler?
410 dnl --------------------------------------------------------------
411 CrossCompiling=NO
412 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
413 if test "$target" != "$host" ; then
414     CrossCompiling=YES
415     cross_compiling=yes   # This tells configure that it can accept just 'target',
416                           # otherwise you get
417                           #   configure: error: cannot run C compiled programs.
418                           #   If you meant to cross compile, use `--host'.
419 fi
420 if test "$build" != "$host" ; then
421    AC_MSG_ERROR([
422 You've selected:
423
424   BUILD:  $build   (the architecture we're building on)
425   HOST:   $host    (the architecture the compiler we're building will execute on)
426   TARGET: $target  (the architecture the compiler we're building will produce code for)
427
428 BUILD must equal HOST; that is, we do not support building GHC itself
429 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
430 1 will be a cross-compiler, and stage 2 will be the cross-compiled
431 GHC.
432 ])
433 fi
434 if test "$CrossCompiling" = "YES"
435 then
436   CrossCompilePrefix="${target}-"
437 else
438   CrossCompilePrefix=""
439 fi
440 TargetPlatformFull="${target}"
441 AC_SUBST(CrossCompiling)
442 AC_SUBST(CrossCompilePrefix)
443 AC_SUBST(TargetPlatformFull)
444
445 dnl ** Which gcc to use?
446 dnl --------------------------------------------------------------
447
448 AC_ARG_WITH([gcc],
449         AS_HELP_STRING([--with-gcc=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
450         AC_MSG_ERROR([--with-gcc=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
451
452 AC_ARG_WITH([clang],
453         AS_HELP_STRING([--with-clang=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
454         AC_MSG_ERROR([--with-clang=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
455
456 dnl detect compiler (prefer gcc over clang) and set $CC (unless CC already set),
457 dnl later CC is copied to CC_STAGE{1,2,3}
458 AC_PROG_CC([gcc clang])
459
460 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
461
462 dnl make extensions visible to allow feature-tests to detect them lateron
463 AC_USE_SYSTEM_EXTENSIONS
464
465 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
466 AC_PROG_CPP
467
468 # --with-hs-cpp/--with-hs-cpp-flags
469 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
470 AC_SUBST([HaskellCPPCmd])
471 AC_SUBST([HaskellCPPArgs])
472
473 FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
474 FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
475 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
476 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
477
478 dnl ** Which ld to use?
479 dnl --------------------------------------------------------------
480 FIND_LD([LdCmd])
481 AC_SUBST([LdCmd])
482
483 dnl ** Which nm to use?
484 dnl --------------------------------------------------------------
485 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
486 NmCmd="$NM"
487 AC_SUBST([NmCmd])
488
489 dnl ** Which objdump to use?
490 dnl --------------------------------------------------------------
491 FP_ARG_WITH_PATH_GNU_PROG_OPTIONAL([OBJDUMP], [objdump], [objdump])
492 ObjdumpCmd="$OBJDUMP"
493 AC_SUBST([ObjdumpCmd])
494
495 dnl ** Which ar to use?
496 dnl --------------------------------------------------------------
497 FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
498 ArCmd="$AR"
499 fp_prog_ar="$AR"
500 AC_SUBST([ArCmd])
501
502 dnl ** Which ranlib to use?
503 dnl --------------------------------------------------------------
504 FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
505 RanlibCmd="$RANLIB"
506 RANLIB="$RanlibCmd"
507
508
509 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
510 case $HostOS_CPP in
511 cygwin32|mingw32)
512     dnl ** Which objdump to use?
513     dnl --------------------------------------------------------------
514     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
515     ObjdumpCmd="$OBJDUMP"
516     AC_SUBST([ObjdumpCmd])
517     ;;
518 esac
519
520 # Here is where we re-target which specific version of the LLVM
521 # tools we are looking for. In the past, GHC supported a number of
522 # versions of LLVM simultaneously, but that stopped working around
523 # 3.5/3.6 release of LLVM.
524 LlvmVersion=3.8
525 AC_SUBST([LlvmVersion])
526 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
527 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
528
529 dnl ** Which LLVM llc to use?
530 dnl --------------------------------------------------------------
531 FIND_LLVM_PROG([LLC], [llc], [llc], [$LlvmVersion])
532 LlcCmd="$LLC"
533 AC_SUBST([LlcCmd])
534
535 dnl ** Which LLVM opt to use?
536 dnl --------------------------------------------------------------
537 FIND_LLVM_PROG([OPT], [opt], [opt], [$LlvmVersion])
538 OptCmd="$OPT"
539 AC_SUBST([OptCmd])
540
541 dnl --------------------------------------------------------------
542 dnl End of configure script option section
543 dnl --------------------------------------------------------------
544
545
546 dnl --------------------------------------------------------------
547 dnl * General configuration checks
548 dnl --------------------------------------------------------------
549
550 dnl ** Bug 9439: Some GHC 7.8 releases had broken LLVM code generator.
551 dnl Unfortunately we don't know whether the user is going to request a
552 dnl build with the LLVM backend as this is only given in build.mk.
553 dnl
554 dnl Instead, we try to do as much work as possible here, checking
555 dnl whether -fllvm is the stage 0 compiler's default. If so we
556 dnl fail. If not, we check whether -fllvm is affected explicitly and
557 dnl if so set a flag. The build system will later check this flag
558 dnl after the desired build flags are known.
559
560 dnl This problem is further complicated by the fact that the llvm
561 dnl version used by the bootstrap compiler may be different from the
562 dnl version we arre trying to compile GHC against. Therefore, we need
563 dnl to find the boostrap compiler's `settings` file then check to see
564 dnl if the `opt` and `llc` command strings are non-empty and if these
565 dnl programs exist. Only if they exist to we test for bug #9439.
566
567 FIND_GHC_BOOTSTRAP_PROG([BootstrapLlcCmd], [${WithGhc}], "LLVM llc command")
568 FIND_GHC_BOOTSTRAP_PROG([BootstrapOptCmd], [${WithGhc}], "LLVM opt command")
569
570 if test -n "$BootstrapLlcCmd" && test -n "$BootstrapOptCmd"
571 then
572     AC_MSG_CHECKING(whether bootstrap compiler is affected by bug 9439)
573     echo "main = putStrLn \"%function\"" > conftestghc.hs
574
575     # Check whether LLVM backend is default for this platform
576     "${WithGhc}" -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" conftestghc.hs 2>&1 >/dev/null
577     res=`./conftestghc`
578     if test "x$res" = "x%object"
579     then
580         AC_MSG_RESULT(yes)
581         echo "Buggy bootstrap compiler"
582         echo ""
583         echo "The stage 0 compiler $WithGhc is affected by GHC Bug \#9439"
584         echo "and therefore will miscompile the LLVM backend if -fllvm is"
585         echo "used."
586         echo
587         echo "Please use another bootstrap compiler"
588         exit 1
589     fi
590
591     # -fllvm is not the default, but set a flag so the Makefile can check
592     # -for it in the build flags later on
593     "${WithGhc}" -fforce-recomp -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" -fllvm conftestghc.hs 2>&1 >/dev/null
594     if test $? = 0
595     then
596         res=`./conftestghc`
597         if test "x$res" = "x%object"
598         then
599             AC_MSG_RESULT(yes)
600             GHC_LLVM_AFFECTED_BY_9439=1
601         elif test "x$res" = "x%function"
602         then
603             AC_MSG_RESULT(no)
604             GHC_LLVM_AFFECTED_BY_9439=0
605         else
606             AC_MSG_WARN(unexpected output $res)
607         fi
608     else
609         AC_MSG_RESULT(failed to compile, assuming no)
610     fi
611 fi
612 AC_SUBST([GHC_LLVM_AFFECTED_BY_9439])
613
614 dnl ** Can the unix package be built?
615 dnl --------------------------------------------------------------
616
617 if test "$TargetOS" = "mingw32"
618 then
619     GhcLibsWithUnix=NO
620 else
621     GhcLibsWithUnix=YES
622 fi
623 AC_SUBST([GhcLibsWithUnix])
624
625 dnl ** does #! work?
626 AC_SYS_INTERPRETER()
627
628 dnl ** look for `perl'
629 case $HostOS_CPP in
630 cygwin32|mingw32)
631     PerlCmd=$hardtop/inplace/perl/perl
632     ;;
633 *)
634     AC_PATH_PROG(PerlCmd,perl)
635     if test -z "$PerlCmd"
636     then
637         echo "You must install perl before you can continue"
638         echo "Perhaps it is already installed, but not in your PATH?"
639         exit 1
640     else
641         FPTOOLS_CHECK_PERL_VERSION
642     fi
643     ;;
644 esac
645
646 dnl ** look for GCC and find out which version
647 dnl     Figure out which C compiler to use.  Gcc is preferred.
648 dnl     If gcc, make sure it's at least 3.0
649 dnl
650 FP_GCC_VERSION
651
652 dnl ** look to see if we have a C compiler using an llvm back end.
653 dnl
654 FP_CC_LLVM_BACKEND
655
656 FP_PROG_LD_IS_GNU
657 FP_PROG_LD_BUILD_ID
658 FP_PROG_LD_NO_COMPACT_UNWIND
659 FP_PROG_LD_FILELIST
660
661
662 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
663 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
664 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
665 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
666 # Stage 3 won't be supported by cross-compilation
667
668 FP_GCC_EXTRA_FLAGS
669
670 AC_SUBST(CONF_CC_OPTS_STAGE0)
671 AC_SUBST(CONF_CC_OPTS_STAGE1)
672 AC_SUBST(CONF_CC_OPTS_STAGE2)
673 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
674 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
675 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
676 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
677 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
678 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
679 AC_SUBST(CONF_CPP_OPTS_STAGE0)
680 AC_SUBST(CONF_CPP_OPTS_STAGE1)
681 AC_SUBST(CONF_CPP_OPTS_STAGE2)
682
683 dnl ** Set up the variables for the platform in the settings file.
684 dnl May need to use gcc to find platform details.
685 dnl --------------------------------------------------------------
686 FPTOOLS_SET_HASKELL_PLATFORM_VARS
687
688 dnl ** figure out how to do context diffs
689 FP_PROG_CONTEXT_DIFF
690
691 dnl Let's make sure install-sh is executable here.  If we got it from
692 dnl a darcs repo, it might not be (see bug #978).
693 chmod +x install-sh
694 dnl ** figure out how to do a BSD-ish install
695 AC_PROG_INSTALL
696
697 dnl ** how to invoke `ar' and `ranlib'
698 FP_PROG_AR_SUPPORTS_ATFILE
699 FP_PROG_AR_NEEDS_RANLIB
700
701 dnl ** Check to see whether ln -s works
702 AC_PROG_LN_S
703
704 FP_SETTINGS
705
706 dnl ** Find the path to sed
707 AC_PATH_PROGS(SedCmd,gsed sed,sed)
708
709
710 dnl ** check for time command
711 AC_PATH_PROG(TimeCmd,time)
712
713 dnl ** check for tar
714 dnl   if GNU tar is named gtar, look for it first.
715 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
716
717 dnl ** check for patch
718 dnl if GNU patch is named gpatch, look for it first
719 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
720
721 dnl ** check for dtrace (currently only implemented for Mac OS X)
722 HaveDtrace=NO
723 AC_PATH_PROG(DtraceCmd,dtrace)
724 if test -n "$DtraceCmd"; then
725   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
726     HaveDtrace=YES
727   fi
728 fi
729 AC_SUBST(HaveDtrace)
730
731 AC_PATH_PROG(HSCOLOUR,HsColour)
732 # HsColour is passed to Cabal, so we need a native path
733 if test "$HostOS"      = "mingw32" && \
734    test "${HSCOLOUR}" != ""
735 then
736     # Canonicalise to <drive>:/path/to/gcc
737     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
738 fi
739
740 dnl ** check for Sphinx toolchain
741 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
742 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
743 changequote(, )dnl
744 [if test -n "$SPHINXBUILD"; then
745   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
746 fi;
747 changequote([, ])dnl
748 ])
749 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
750     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
751
752 dnl ** check for xelatex
753 AC_PATH_PROG(XELATEX,xelatex)
754
755 dnl ** check for ghc-pkg command
756 FP_PROG_GHC_PKG
757
758 dnl ** check for installed happy binary + version
759 FPTOOLS_HAPPY
760
761 dnl ** check for installed alex binary + version
762 FPTOOLS_ALEX
763
764 dnl --------------------------------------------------
765 dnl ### program checking section ends here ###
766 dnl --------------------------------------------------
767
768 dnl --------------------------------------------------
769 dnl * Platform header file and syscall feature tests
770 dnl ### checking the state of the local header files and syscalls ###
771
772 dnl ** check for full ANSI header (.h) files
773 AC_HEADER_STDC
774
775 dnl ** Enable large file support.  NB. do this before testing the type of
776 dnl    off_t, because it will affect the result of that test.
777 AC_SYS_LARGEFILE
778
779 dnl ** check for specific header (.h) files that we are interested in
780 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
781
782 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
783 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
784 [[#if HAVE_SYS_PARAM_H
785 # include <sys/param.h>
786 #endif
787 ]])
788
789 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
790 AC_HEADER_TIME
791
792 dnl ** do we have long longs?
793 AC_CHECK_TYPES([long long])
794
795 dnl ** what are the sizes of various types
796 FP_CHECK_SIZEOF_AND_ALIGNMENT(char)
797 FP_CHECK_SIZEOF_AND_ALIGNMENT(double)
798 FP_CHECK_SIZEOF_AND_ALIGNMENT(float)
799 FP_CHECK_SIZEOF_AND_ALIGNMENT(int)
800 FP_CHECK_SIZEOF_AND_ALIGNMENT(long)
801 if test "$ac_cv_type_long_long" = yes; then
802 FP_CHECK_SIZEOF_AND_ALIGNMENT(long long)
803 fi
804 FP_CHECK_SIZEOF_AND_ALIGNMENT(short)
805 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned char)
806 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned int)
807 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long)
808 if test "$ac_cv_type_long_long" = yes; then
809 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long long)
810 fi
811 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned short)
812 FP_CHECK_SIZEOF_AND_ALIGNMENT(void *)
813
814 FP_CHECK_SIZEOF_AND_ALIGNMENT(int8_t)
815 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint8_t)
816 FP_CHECK_SIZEOF_AND_ALIGNMENT(int16_t)
817 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint16_t)
818 FP_CHECK_SIZEOF_AND_ALIGNMENT(int32_t)
819 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint32_t)
820 FP_CHECK_SIZEOF_AND_ALIGNMENT(int64_t)
821 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint64_t)
822
823
824 dnl for use in settings.in
825 WordSize=$ac_cv_sizeof_void_p
826 AC_SUBST(WordSize)
827 FP_CHECK_FUNC([WinExec],
828   [@%:@include <windows.h>], [WinExec("",0)])
829
830 FP_CHECK_FUNC([GetModuleFileName],
831   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
832
833 dnl ** check for more functions
834 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
835 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
836
837 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
838 dnl ** _POSIX_C_SOURCE is defined
839 AC_CHECK_DECLS([ctime_r], , ,
840 [#define _POSIX_SOURCE 1
841 #define _POSIX_C_SOURCE 199506L
842 #include <time.h>])
843
844 dnl ** check for mingwex library
845 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
846 AC_SUBST(HaveLibMingwEx)
847
848 if test $HaveLibMingwEx = YES ; then
849   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
850 fi
851
852 dnl ** check for math library
853 dnl    Keep that check as early as possible.
854 dnl    as we need to know whether we need libm
855 dnl    for math functions or not
856 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
857 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
858 if test $HaveLibM = YES
859 then
860   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
861 fi
862
863 FP_BFD_SUPPORT
864
865 dnl ################################################################
866 dnl Check for libraries
867 dnl ################################################################
868
869 # system libffi
870
871 AC_ARG_WITH([system-libffi],
872 [AC_HELP_STRING([--with-system-libffi],
873   [Use system provided libffi for RTS [default=no]])
874 ])
875
876 AS_IF([test "x$with_system_libffi" = "xyes"],
877   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
878 )
879
880
881 AC_SUBST(UseSystemLibFFI)
882
883 AC_ARG_WITH([ffi-includes],
884 [AC_HELP_STRING([--with-ffi-includes=ARG],
885   [Find includes for libffi in ARG [default=system default]])
886 ],
887 [
888  if test "x$UseSystemLibFFI" != "xYES"; then
889     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
890  else
891     FFIIncludeDir="$withval"
892     LIBFFI_CFLAGS="-I$withval"
893  fi
894 ])
895
896 AC_SUBST(FFIIncludeDir)
897
898 AC_ARG_WITH([ffi-libraries],
899 [AC_HELP_STRING([--with-ffi-libraries=ARG],
900   [Find libffi in ARG [default=system default]])
901 ],
902 [
903  if test "x$UseSystemLibFFI" != "xYES"; then
904     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
905  else
906     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
907  fi
908 ])
909
910 AC_SUBST(FFILibDir)
911
912 AS_IF([test "$UseSystemLibFFI" = "YES"], [
913  CFLAGS2="$CFLAGS"
914  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
915  LDFLAGS2="$LDFLAGS"
916  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
917  if test "$HostOS" = "openbsd";
918  then
919    # OpenBSD's libffi is not directly linked to the libpthread but
920    # still requires pthread functionality. This means that any client
921    # binary which links with libffi also needs to link with
922    # libpthread. If it does not, then linking fails with unresolved
923    # symbols.
924    LDFLAGS="$LDFLAGS -lpthread"
925  fi
926  AC_CHECK_LIB(ffi, ffi_call,
927   [AC_CHECK_HEADERS([ffi.h], [break], [])
928    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
929   [AC_MSG_ERROR([Cannot find system libffi])])
930  CFLAGS="$CFLAGS2"
931  LDFLAGS="$LDFLAGS2"
932 ])
933
934 dnl ** check whether we need -ldl to get dlopen()
935 AC_CHECK_LIB(dl, dlopen)
936
937 dnl --------------------------------------------------
938 dnl * Miscellaneous feature tests
939 dnl --------------------------------------------------
940
941 dnl ** can we get alloca?
942 AC_FUNC_ALLOCA
943
944 dnl ** working vfork?
945 AC_FUNC_FORK
946
947 dnl ** determine whether or not const works
948 AC_C_CONST
949
950 dnl ** are we big endian?
951 AC_C_BIGENDIAN
952 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
953
954 dnl ** check for leading underscores in symbol names
955 FP_LEADING_UNDERSCORE
956
957 FP_VISIBILITY_HIDDEN
958
959 dnl ** check for librt
960 AC_CHECK_LIB(rt, clock_gettime)
961 AC_CHECK_FUNCS(clock_gettime timer_settime)
962 FP_CHECK_TIMER_CREATE
963
964 dnl ** check for Apple's "interesting" long double compatibility scheme
965 AC_MSG_CHECKING(for printf\$LDBLStub)
966 AC_TRY_LINK_FUNC(printf\$LDBLStub,
967     [
968         AC_MSG_RESULT(yes)
969         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
970             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
971     ],
972     [
973         AC_MSG_RESULT(no)
974         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
975             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
976     ])
977
978 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
979 dnl    a different single-argument version.
980 AC_CHECK_LIB(pthread, pthread_setname_np)
981 AC_MSG_CHECKING(for pthread_setname_np)
982 AC_TRY_LINK(
983 [
984 #define _GNU_SOURCE
985 #include <pthread.h>
986 ],
987 [pthread_setname_np(pthread_self(), "name");],
988     AC_MSG_RESULT(yes)
989     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
990       [Define to 1 if you have the glibc version of pthread_setname_np]),
991     AC_MSG_RESULT(no)
992 )
993
994 dnl ** check for eventfd which is needed by the I/O manager
995 AC_CHECK_HEADERS([sys/eventfd.h])
996 AC_CHECK_FUNCS([eventfd])
997
998 dnl ** Check for __thread support in the compiler
999 AC_MSG_CHECKING(for __thread support)
1000 AC_COMPILE_IFELSE(
1001   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1002   [
1003    AC_MSG_RESULT(yes)
1004    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1005   ],
1006   [
1007    AC_MSG_RESULT(no)
1008    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1009   ])
1010
1011 dnl large address space support (see includes/rts/storage/MBlock.h)
1012 dnl
1013 dnl Darwin has vm_allocate/vm_protect
1014 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1015 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1016 dnl (They also have MADV_DONTNEED, but it means something else!)
1017 dnl
1018 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1019 dnl it counts page-table space as committed memory, and so quickly
1020 dnl runs out of paging file when we have multiple processes reserving
1021 dnl 1TB of address space, we get the following error:
1022 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1023 dnl
1024
1025 AC_ARG_ENABLE(large-address-space,
1026     [AC_HELP_STRING([--enable-large-address-space],
1027         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1028     EnableLargeAddressSpace=$enableval,
1029     EnableLargeAddressSpace=yes
1030 )
1031
1032 use_large_address_space=no
1033 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1034     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1035         if test "$ghc_host_os" = "darwin" ; then
1036             use_large_address_space=yes
1037         elif test "$ghc_host_os" = "openbsd" ; then
1038             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1039             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1040             # but is completely ignored by OS mmap
1041             use_large_address_space=no
1042         else
1043             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1044                 [
1045                 #include <unistd.h>
1046                 #include <sys/types.h>
1047                 #include <sys/mman.h>
1048                 #include <fcntl.h>
1049             ])
1050             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1051                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1052                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1053                     use_large_address_space=yes
1054             fi
1055         fi
1056     fi
1057 fi
1058 if test "$use_large_address_space" = "yes" ; then
1059    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1060 fi
1061
1062 dnl ** Use MMAP in the runtime linker?
1063 dnl --------------------------------------------------------------
1064
1065 case ${TargetOS} in
1066     linux|freebsd|dragonfly|netbsd|openbsd|kfreebsdgnu|gnu|solaris2)
1067         RtsLinkerUseMmap=1
1068         ;;
1069     darwin)
1070         # Don't use mmap on powerpc/darwin as the mmap there doesn't support
1071         # reallocating. Reallocating is needed to allocate jump islands just
1072         # after each object image. Jumps to these jump islands use relative
1073         # branches which are limited to offsets that can be represented in
1074         # 24-bits.
1075         if test "$TargetArch" != "powerpc" ; then
1076             RtsLinkerUseMmap=1
1077         else
1078             RtsLinkerUseMmap=0
1079         fi
1080         ;;
1081     *)
1082         # Windows (which doesn't have mmap) and everything else.
1083         RtsLinkerUseMmap=0
1084         ;;
1085     esac
1086
1087 AC_DEFINE_UNQUOTED([RTS_LINKER_USE_MMAP], [$RtsLinkerUseMmap],
1088                    [Use mmap in the runtime linker])
1089
1090 dnl ** Have libdw?
1091 dnl --------------------------------------------------------------
1092 UseLibdw=NO
1093 USE_LIBDW=0
1094 AC_ARG_ENABLE(dwarf-unwind,
1095     [AC_HELP_STRING([--enable-dwarf-unwind],
1096         [Enable DWARF unwinding support in the runtime system via elfutils' libdw [default=no]])],
1097     [AC_CHECK_LIB(dw, dwfl_attach_state, [UseLibdw=YES], [UseLibdw=NO])],
1098     [UseLibdw=NO]
1099 )
1100 AC_SUBST(UseLibdw)
1101 if test $UseLibdw = "YES" ; then
1102         USE_LIBDW=1
1103 fi
1104 AC_DEFINE_UNQUOTED([USE_LIBDW], [$USE_LIBDW], [Set to 1 to use libdw])
1105
1106 dnl ** Have libnuma?
1107 dnl --------------------------------------------------------------
1108 HaveLibNuma=0
1109 AC_CHECK_HEADERS([numa.h numaif.h])
1110
1111 if test "$ac_cv_header_numa_h$ac_cv_header_numaif_h" = "yesyes" ; then
1112     AC_CHECK_LIB(numa, numa_available,HaveLibNuma=1)
1113 fi
1114 AC_DEFINE_UNQUOTED([USE_LIBNUMA], [$HaveLibNuma], [Define to 1 if you have libnuma])
1115
1116 dnl ** Documentation
1117 dnl --------------------------------------------------------------
1118 if test -n "$SPHINXBUILD"; then
1119     BUILD_MAN=YES
1120     BUILD_SPHINX_HTML=YES
1121     if test -n "$XELATEX"; then
1122         BUILD_SPHINX_PDF=YES
1123     else
1124         BUILD_SPHINX_PDF=NO
1125     fi
1126 else
1127     BUILD_MAN=NO
1128     BUILD_SPHINX_HTML=NO
1129     BUILD_SPHINX_PDF=NO
1130 fi
1131 AC_SUBST(BUILD_MAN)
1132 AC_SUBST(BUILD_SPHINX_HTML)
1133 AC_SUBST(BUILD_SPHINX_PDF)
1134
1135 LIBRARY_VERSION(base)
1136 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1137 LIBRARY_VERSION(ghc-prim)
1138 LIBRARY_ghc_VERSION="$ProjectVersion"
1139 AC_SUBST(LIBRARY_ghc_VERSION)
1140
1141 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1142    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1143 fi
1144
1145 # Create the configuration for the Hadrian build system if it is present
1146 if test -e hadrian/cfg/system.config.in; then
1147     AC_CONFIG_FILES([hadrian/cfg/system.config])
1148 fi
1149
1150 # We got caught by
1151 #     http://savannah.gnu.org/bugs/index.php?1516
1152 #     $(eval ...) inside conditionals causes errors
1153 # with make 3.80, so warn the user if it looks like they're about to
1154 # try to use it.
1155 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1156 print_make_warning=""
1157 checkMake380() {
1158     make_ver=`$1 --version 2>&1 | head -1`
1159     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1160     then
1161         print_make_warning="true"
1162     fi
1163     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1164     then
1165         MakeCmd=$1
1166         AC_SUBST(MakeCmd)
1167     fi
1168 }
1169
1170 checkMake380 make
1171 checkMake380 gmake
1172
1173 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghc-boot-th/ghc-boot-th.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt distrib/configure.ac])
1174 AC_OUTPUT
1175
1176 if test "$print_make_warning" = "true"; then
1177    echo
1178    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1179    echo "This version cannot be used to build GHC."
1180    echo "Please use GNU make >= 3.81."
1181 fi
1182
1183 echo ["
1184 ----------------------------------------------------------------------
1185 Configure completed successfully.
1186
1187    Building GHC version  : $ProjectVersion
1188           Git commit id  : $ProjectGitCommitId
1189
1190    Build platform        : $BuildPlatform
1191    Host platform         : $HostPlatform
1192    Target platform       : $TargetPlatform
1193 "]
1194
1195 echo ["\
1196    Bootstrapping using   : $WithGhc
1197       which is version   : $GhcVersion
1198 "]
1199
1200 if test "x$CC_LLVM_BACKEND" = "x1"; then
1201     if test "x$CC_CLANG_BACKEND" = "x1"; then
1202         CompilerName="clang        "
1203     else
1204         CompilerName="llvm-gcc     "
1205     fi
1206 else
1207     CompilerName="gcc          "
1208 fi
1209
1210 echo ["\
1211    Using (for bootstrapping) : $CC_STAGE0
1212    Using $CompilerName       : $CC
1213       which is version       : $GccVersion
1214    Building a cross compiler : $CrossCompiling
1215    hs-cpp       : $HaskellCPPCmd
1216    hs-cpp-flags : $HaskellCPPArgs
1217    ld           : $LdCmd
1218    nm           : $NmCmd
1219    objdump      : $ObjdumpCmd
1220    Happy        : $HappyCmd ($HappyVersion)
1221    Alex         : $AlexCmd ($AlexVersion)
1222    Perl         : $PerlCmd
1223    sphinx-build : $SPHINXBUILD
1224    xelatex      : $XELATEX
1225
1226    Using LLVM tools
1227       llc   : $LlcCmd
1228       opt   : $OptCmd"]
1229
1230 if test "$HSCOLOUR" = ""; then
1231 echo ["
1232    HsColour was not found; documentation will not contain source links
1233 "]
1234 else
1235 echo ["\
1236    HsColour : $HSCOLOUR
1237 "]
1238 fi
1239
1240 echo ["\
1241    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1242    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"]
1243
1244 echo ["----------------------------------------------------------------------
1245 "]
1246
1247 echo "\
1248 For a standard build of GHC (fully optimised with profiling), type (g)make.
1249
1250 To make changes to the default build configuration, copy the file
1251 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1252
1253 For more information on how to configure your GHC build, see
1254    http://ghc.haskell.org/trac/ghc/wiki/Building
1255 "