cb71c7d7de5396b09e710bfc0ef5ca41d3935881
[ghc.git] / compiler / cmm / CmmLex.x
1 -----------------------------------------------------------------------------
2 --
3 -- (c) The University of Glasgow, 2004-2006
4 --
5 -- Lexer for concrete Cmm.  We try to stay close to the C-- spec, but there
6 -- are a few minor differences:
7 --
8 --   * extra keywords for our macros, and float32/float64 types
9 --   * global registers (Sp,Hp, etc.)
10 --
11 -----------------------------------------------------------------------------
12
13 {
14 {-# OPTIONS_GHC -fno-warn-unused-matches #-}
15 {-# OPTIONS_GHC -fno-warn-unused-binds #-}
16 {-# OPTIONS_GHC -fno-warn-tabs #-}
17 {-# OPTIONS_GHC -fno-warn-missing-signatures #-}
18 -- The above warning suppression flags are a temporary kludge.
19 -- While working on this module you are encouraged to remove it and fix
20 -- any warnings in the module. See
21 --     http://ghc.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
22 -- for details
23
24 module CmmLex (
25    CmmToken(..), cmmlex,
26   ) where
27
28 import CmmExpr
29
30 import Lexer
31 import SrcLoc
32 import UniqFM
33 import StringBuffer
34 import FastString
35 import Ctype
36 import Util
37 --import TRACE
38
39 import Data.Word
40 import Data.Char hiding (ord)
41 }
42
43 $whitechar   = [\ \t\n\r\f\v\xa0] -- \xa0 is Unicode no-break space
44 $white_no_nl = $whitechar # \n
45
46 $ascdigit  = 0-9
47 $unidigit  = \x01 -- Trick Alex into handling Unicode. See alexGetChar.
48 $digit     = [$ascdigit $unidigit]
49 $octit     = 0-7
50 $hexit     = [$digit A-F a-f]
51
52 $unilarge  = \x03 -- Trick Alex into handling Unicode. See alexGetChar.
53 $asclarge  = [A-Z \xc0-\xd6 \xd8-\xde]
54 $large     = [$asclarge $unilarge]
55
56 $unismall  = \x04 -- Trick Alex into handling Unicode. See alexGetChar.
57 $ascsmall  = [a-z \xdf-\xf6 \xf8-\xff]
58 $small     = [$ascsmall $unismall \_]
59
60 $namebegin = [$large $small \. \$ \@]
61 $namechar  = [$namebegin $digit]
62
63 @decimal     = $digit+
64 @octal       = $octit+
65 @hexadecimal = $hexit+
66 @exponent    = [eE] [\-\+]? @decimal
67
68 @floating_point = @decimal \. @decimal @exponent? | @decimal @exponent
69
70 @escape      = \\ ([abfnrt\\\'\"\?] | x $hexit{1,2} | $octit{1,3})
71 @strchar     = ($printable # [\"\\]) | @escape
72
73 cmm :-
74
75 $white_no_nl+           ;
76 ^\# pragma .* \n        ; -- Apple GCC 3.3 CPP generates pragmas in its output
77
78 ^\# (line)?             { begin line_prag }
79
80 -- single-line line pragmas, of the form
81 --    # <line> "<file>" <extra-stuff> \n
82 <line_prag> $digit+                     { setLine line_prag1 }
83 <line_prag1> \" [^\"]* \"       { setFile line_prag2 }
84 <line_prag2> .*                         { pop }
85
86 <0> {
87   \n                    ;
88
89   [\:\;\{\}\[\]\(\)\=\`\~\/\*\%\-\+\&\^\|\>\<\,\!]      { special_char }
90
91   ".."                  { kw CmmT_DotDot }
92   "::"                  { kw CmmT_DoubleColon }
93   ">>"                  { kw CmmT_Shr }
94   "<<"                  { kw CmmT_Shl }
95   ">="                  { kw CmmT_Ge }
96   "<="                  { kw CmmT_Le }
97   "=="                  { kw CmmT_Eq }
98   "!="                  { kw CmmT_Ne }
99   "&&"                  { kw CmmT_BoolAnd }
100   "||"                  { kw CmmT_BoolOr }
101
102   P@decimal             { global_regN (\n -> VanillaReg n VGcPtr) }
103   R@decimal             { global_regN (\n -> VanillaReg n VNonGcPtr) }
104   F@decimal             { global_regN FloatReg }
105   D@decimal             { global_regN DoubleReg }
106   L@decimal             { global_regN LongReg }
107   Sp                    { global_reg Sp }
108   SpLim                 { global_reg SpLim }
109   Hp                    { global_reg Hp }
110   HpLim                 { global_reg HpLim }
111   CCCS                  { global_reg CCCS }
112   CurrentTSO            { global_reg CurrentTSO }
113   CurrentNursery        { global_reg CurrentNursery }
114   HpAlloc               { global_reg HpAlloc }
115   BaseReg               { global_reg BaseReg }
116
117   $namebegin $namechar* { name }
118
119   0 @octal              { tok_octal }
120   @decimal              { tok_decimal }
121   0[xX] @hexadecimal    { tok_hexadecimal }
122   @floating_point       { strtoken tok_float }
123
124   \" @strchar* \"       { strtoken tok_string }
125 }
126
127 {
128 data CmmToken
129   = CmmT_SpecChar  Char
130   | CmmT_DotDot
131   | CmmT_DoubleColon
132   | CmmT_Shr
133   | CmmT_Shl
134   | CmmT_Ge
135   | CmmT_Le
136   | CmmT_Eq
137   | CmmT_Ne
138   | CmmT_BoolAnd
139   | CmmT_BoolOr
140   | CmmT_CLOSURE
141   | CmmT_INFO_TABLE
142   | CmmT_INFO_TABLE_RET
143   | CmmT_INFO_TABLE_FUN
144   | CmmT_INFO_TABLE_CONSTR
145   | CmmT_INFO_TABLE_SELECTOR
146   | CmmT_else
147   | CmmT_export
148   | CmmT_section
149   | CmmT_goto
150   | CmmT_if
151   | CmmT_call
152   | CmmT_jump
153   | CmmT_foreign
154   | CmmT_never
155   | CmmT_prim
156   | CmmT_reserve
157   | CmmT_return
158   | CmmT_returns
159   | CmmT_import
160   | CmmT_switch
161   | CmmT_case
162   | CmmT_default
163   | CmmT_push
164   | CmmT_unwind
165   | CmmT_bits8
166   | CmmT_bits16
167   | CmmT_bits32
168   | CmmT_bits64
169   | CmmT_bits128
170   | CmmT_bits256
171   | CmmT_bits512
172   | CmmT_float32
173   | CmmT_float64
174   | CmmT_gcptr
175   | CmmT_GlobalReg GlobalReg
176   | CmmT_Name      FastString
177   | CmmT_String    String
178   | CmmT_Int       Integer
179   | CmmT_Float     Rational
180   | CmmT_EOF
181   deriving (Show)
182
183 -- -----------------------------------------------------------------------------
184 -- Lexer actions
185
186 type Action = RealSrcSpan -> StringBuffer -> Int -> P (RealLocated CmmToken)
187
188 begin :: Int -> Action
189 begin code _span _str _len = do pushLexState code; lexToken
190
191 pop :: Action
192 pop _span _buf _len = popLexState >> lexToken
193
194 special_char :: Action
195 special_char span buf len = return (L span (CmmT_SpecChar (currentChar buf)))
196
197 kw :: CmmToken -> Action
198 kw tok span buf len = return (L span tok)
199
200 global_regN :: (Int -> GlobalReg) -> Action
201 global_regN con span buf len
202   = return (L span (CmmT_GlobalReg (con (fromIntegral n))))
203   where buf' = stepOn buf
204         n = parseUnsignedInteger buf' (len-1) 10 octDecDigit
205
206 global_reg :: GlobalReg -> Action
207 global_reg r span buf len = return (L span (CmmT_GlobalReg r))
208
209 strtoken :: (String -> CmmToken) -> Action
210 strtoken f span buf len =
211   return (L span $! (f $! lexemeToString buf len))
212
213 name :: Action
214 name span buf len =
215   case lookupUFM reservedWordsFM fs of
216         Just tok -> return (L span tok)
217         Nothing  -> return (L span (CmmT_Name fs))
218   where
219         fs = lexemeToFastString buf len
220
221 reservedWordsFM = listToUFM $
222         map (\(x, y) -> (mkFastString x, y)) [
223         ( "CLOSURE",            CmmT_CLOSURE ),
224         ( "INFO_TABLE",         CmmT_INFO_TABLE ),
225         ( "INFO_TABLE_RET",     CmmT_INFO_TABLE_RET ),
226         ( "INFO_TABLE_FUN",     CmmT_INFO_TABLE_FUN ),
227         ( "INFO_TABLE_CONSTR",  CmmT_INFO_TABLE_CONSTR ),
228         ( "INFO_TABLE_SELECTOR",CmmT_INFO_TABLE_SELECTOR ),
229         ( "else",               CmmT_else ),
230         ( "export",             CmmT_export ),
231         ( "section",            CmmT_section ),
232         ( "goto",               CmmT_goto ),
233         ( "if",                 CmmT_if ),
234         ( "call",               CmmT_call ),
235         ( "jump",               CmmT_jump ),
236         ( "foreign",            CmmT_foreign ),
237         ( "never",              CmmT_never ),
238         ( "prim",               CmmT_prim ),
239         ( "reserve",            CmmT_reserve ),
240         ( "return",             CmmT_return ),
241         ( "returns",            CmmT_returns ),
242         ( "import",             CmmT_import ),
243         ( "switch",             CmmT_switch ),
244         ( "case",               CmmT_case ),
245         ( "default",            CmmT_default ),
246         ( "push",               CmmT_push ),
247         ( "unwind",             CmmT_unwind ),
248         ( "bits8",              CmmT_bits8 ),
249         ( "bits16",             CmmT_bits16 ),
250         ( "bits32",             CmmT_bits32 ),
251         ( "bits64",             CmmT_bits64 ),
252         ( "bits128",            CmmT_bits128 ),
253         ( "bits256",            CmmT_bits256 ),
254         ( "bits512",            CmmT_bits512 ),
255         ( "float32",            CmmT_float32 ),
256         ( "float64",            CmmT_float64 ),
257 -- New forms
258         ( "b8",                 CmmT_bits8 ),
259         ( "b16",                CmmT_bits16 ),
260         ( "b32",                CmmT_bits32 ),
261         ( "b64",                CmmT_bits64 ),
262         ( "b128",               CmmT_bits128 ),
263         ( "b256",               CmmT_bits256 ),
264         ( "b512",               CmmT_bits512 ),
265         ( "f32",                CmmT_float32 ),
266         ( "f64",                CmmT_float64 ),
267         ( "gcptr",              CmmT_gcptr )
268         ]
269
270 tok_decimal span buf len
271   = return (L span (CmmT_Int  $! parseUnsignedInteger buf len 10 octDecDigit))
272
273 tok_octal span buf len
274   = return (L span (CmmT_Int  $! parseUnsignedInteger (offsetBytes 1 buf) (len-1) 8 octDecDigit))
275
276 tok_hexadecimal span buf len
277   = return (L span (CmmT_Int  $! parseUnsignedInteger (offsetBytes 2 buf) (len-2) 16 hexDigit))
278
279 tok_float str = CmmT_Float $! readRational str
280
281 tok_string str = CmmT_String (read str)
282                  -- urk, not quite right, but it'll do for now
283
284 -- -----------------------------------------------------------------------------
285 -- Line pragmas
286
287 setLine :: Int -> Action
288 setLine code span buf len = do
289   let line = parseUnsignedInteger buf len 10 octDecDigit
290   setSrcLoc (mkRealSrcLoc (srcSpanFile span) (fromIntegral line - 1) 1)
291         -- subtract one: the line number refers to the *following* line
292   -- trace ("setLine "  ++ show line) $ do
293   popLexState >> pushLexState code
294   lexToken
295
296 setFile :: Int -> Action
297 setFile code span buf len = do
298   let file = lexemeToFastString (stepOn buf) (len-2)
299   setSrcLoc (mkRealSrcLoc file (srcSpanEndLine span) (srcSpanEndCol span))
300   popLexState >> pushLexState code
301   lexToken
302
303 -- -----------------------------------------------------------------------------
304 -- This is the top-level function: called from the parser each time a
305 -- new token is to be read from the input.
306
307 cmmlex :: (Located CmmToken -> P a) -> P a
308 cmmlex cont = do
309   (L span tok) <- lexToken
310   --trace ("token: " ++ show tok) $ do
311   cont (L (RealSrcSpan span) tok)
312
313 lexToken :: P (RealLocated CmmToken)
314 lexToken = do
315   inp@(loc1,buf) <- getInput
316   sc <- getLexState
317   case alexScan inp sc of
318     AlexEOF -> do let span = mkRealSrcSpan loc1 loc1
319                   setLastToken span 0
320                   return (L span CmmT_EOF)
321     AlexError (loc2,_) -> do failLocMsgP loc1 loc2 "lexical error"
322     AlexSkip inp2 _ -> do
323         setInput inp2
324         lexToken
325     AlexToken inp2@(end,buf2) len t -> do
326         setInput inp2
327         let span = mkRealSrcSpan loc1 end
328         span `seq` setLastToken span len
329         t span buf len
330
331 -- -----------------------------------------------------------------------------
332 -- Monad stuff
333
334 -- Stuff that Alex needs to know about our input type:
335 type AlexInput = (RealSrcLoc,StringBuffer)
336
337 alexInputPrevChar :: AlexInput -> Char
338 alexInputPrevChar (_,s) = prevChar s '\n'
339
340 -- backwards compatibility for Alex 2.x
341 alexGetChar :: AlexInput -> Maybe (Char,AlexInput)
342 alexGetChar inp = case alexGetByte inp of
343                     Nothing    -> Nothing
344                     Just (b,i) -> c `seq` Just (c,i)
345                        where c = chr $ fromIntegral b
346
347 alexGetByte :: AlexInput -> Maybe (Word8,AlexInput)
348 alexGetByte (loc,s)
349   | atEnd s   = Nothing
350   | otherwise = b `seq` loc' `seq` s' `seq` Just (b, (loc', s'))
351   where c    = currentChar s
352         b    = fromIntegral $ ord $ c
353         loc' = advanceSrcLoc loc c
354         s'   = stepOn s
355
356 getInput :: P AlexInput
357 getInput = P $ \s@PState{ loc=l, buffer=b } -> POk s (l,b)
358
359 setInput :: AlexInput -> P ()
360 setInput (l,b) = P $ \s -> POk s{ loc=l, buffer=b } ()
361 }