Merge remote-tracking branch 'origin/master' into type-nats
[ghc.git] / utils / genprimopcode / Parser.y
1 {
2 {-# LANGUAGE BangPatterns #-} -- required for versions of Happy before 1.18.6
3 {-# OPTIONS -w -Wwarn #-}
4 -- The above warning supression flag is a temporary kludge.
5 -- While working on this module you are encouraged to remove it and fix
6 -- any warnings in the module. See
7 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
8 -- for details
9
10 module Parser (parse) where
11
12 import Lexer (lex_tok)
13 import ParserM (Token(..), ParserM, run_parser, get_pos, show_pos,
14                 happyError)
15 import Syntax
16 }
17
18 %name      parsex
19 %expect    0
20 %tokentype { Token }
21 %monad     { ParserM }
22 %lexer     { lex_tok } { TEOF }
23
24 %token
25     '->'            { TArrow }
26     '='             { TEquals }
27     ','             { TComma }
28     '('             { TOpenParen }
29     ')'             { TCloseParen }
30     '(#'            { TOpenParenHash }
31     '#)'            { THashCloseParen }
32     '{'             { TOpenBrace }
33     '}'             { TCloseBrace }
34     section         { TSection }
35     primop          { TPrimop }
36     pseudoop        { TPseudoop }
37     primtype        { TPrimtype }
38     with            { TWith }
39     defaults        { TDefaults }
40     true            { TTrue }
41     false           { TFalse }
42     dyadic          { TDyadic }
43     monadic         { TMonadic }
44     compare         { TCompare }
45     genprimop       { TGenPrimOp }
46     thats_all_folks { TThatsAllFolks }
47     lowerName       { TLowerName $$ }
48     upperName       { TUpperName $$ }
49     string          { TString $$ }
50     integer         { TInteger $$ }
51     noBraces        { TNoBraces $$ }
52
53 %%
54
55 info :: { Info }
56 info : pDefaults pEntries thats_all_folks { Info $1 $2 }
57
58 pDefaults :: { [Option] }
59 pDefaults : defaults pOptions { $2 }
60
61 pOptions :: { [Option] }
62 pOptions : pOption pOptions { $1 : $2 }
63          | {- empty -}      { [] }
64
65 pOption :: { Option }
66 pOption : lowerName '=' false               { OptionFalse  $1 }
67         | lowerName '=' true                { OptionTrue   $1 }
68         | lowerName '=' pStuffBetweenBraces { OptionString $1 $3 }
69         | lowerName '=' integer             { OptionInteger $1 $3 }
70
71 pEntries :: { [Entry] }
72 pEntries : pEntry pEntries { $1 : $2 }
73          | {- empty -}   { [] }
74
75 pEntry :: { Entry }
76 pEntry : pPrimOpSpec   { $1 }
77        | pPrimTypeSpec { $1 }
78        | pPseudoOpSpec { $1 }
79        | pSection      { $1 }
80
81 pPrimOpSpec :: { Entry }
82 pPrimOpSpec : primop upperName string pCategory pType
83               pDesc pWithOptions
84               { PrimOpSpec {
85                     cons = $2,
86                     name = $3,
87                     cat = $4,
88                     ty = $5,
89                     desc = $6,
90                     opts = $7
91                 }
92               }
93
94 pPrimTypeSpec :: { Entry }
95 pPrimTypeSpec : primtype pType pDesc pWithOptions
96                 { PrimTypeSpec { ty = $2, desc = $3, opts = $4 } }
97
98 pPseudoOpSpec :: { Entry }
99 pPseudoOpSpec : pseudoop string pType pDesc pWithOptions
100                 { PseudoOpSpec { name = $2, ty = $3, desc = $4, opts = $5 } }
101
102 pSection :: { Entry }
103 pSection : section string pDesc { Section { title = $2, desc = $3 } }
104
105 pWithOptions :: { [Option] }
106 pWithOptions : with pOptions { $2 }
107              | {- empty -}   { [] }
108
109 pCategory :: { Category }
110 pCategory : dyadic { Dyadic }
111           | monadic { Monadic }
112           | compare { Compare }
113           | genprimop { GenPrimOp }
114
115 pDesc :: { String }
116 pDesc : pStuffBetweenBraces { $1 }
117       | {- empty -}         { "" }
118
119 pStuffBetweenBraces :: { String }
120 pStuffBetweenBraces : '{' pInsides '}' { $2 }
121
122 pInsides :: { String }
123 pInsides : pInside pInsides { $1 ++ $2 }
124          | {- empty -}      { "" }
125
126 pInside :: { String }
127 pInside : '{' pInsides '}' { "{" ++ $2 ++ "}" }
128         | noBraces         { $1 }
129
130 pType :: { Ty }
131 pType : paT '->' pType { TyF $1 $3 }
132       | paT            { $1 }
133
134 -- Atomic types
135 paT :: { Ty }
136 paT : pTycon ppTs     { TyApp $1 $2 }
137     | pUnboxedTupleTy { $1 }
138     | '(' pType ')'   { $2 }
139     | lowerName       { TyVar $1 }
140
141 pUnboxedTupleTy :: { Ty }
142 pUnboxedTupleTy : '(#' pCommaTypes '#)' { TyUTup $2 }
143
144 pCommaTypes :: { [Ty] }
145 pCommaTypes : pType ',' pCommaTypes { $1 : $3 }
146             | pType                 { [$1] }
147
148 ppTs :: { [Ty] }
149 ppTs : ppT ppTs    { $1 : $2 }
150      | {- empty -} { [] }
151
152 -- Primitive types
153 ppT :: { Ty }
154 ppT : lowerName { TyVar $1 }
155     | pTycon    { TyApp $1 [] }
156
157 pTycon :: { String }
158 pTycon : upperName { $1 }
159        | '(' ')'   { "()" }
160
161 {
162 parse :: String -> Either String Info
163 parse = run_parser parsex
164 }
165