Merge branch 'no-pred-ty'
[ghc.git] / compiler / basicTypes / Unique.lhs
1 %
2 % (c) The University of Glasgow 2006
3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4 %
5
6 @Uniques@ are used to distinguish entities in the compiler (@Ids@,
7 @Classes@, etc.) from each other.  Thus, @Uniques@ are the basic
8 comparison key in the compiler.
9
10 If there is any single operation that needs to be fast, it is @Unique@
11 comparison.  Unsurprisingly, there is quite a bit of huff-and-puff
12 directed to that end.
13
14 Some of the other hair in this code is to be able to use a
15 ``splittable @UniqueSupply@'' if requested/possible (not standard
16 Haskell).
17
18 \begin{code}
19 {-# LANGUAGE BangPatterns #-}
20 module Unique (
21         -- * Main data types
22         Unique, Uniquable(..), 
23         
24         -- ** Constructors, desctructors and operations on 'Unique's
25         hasKey,
26
27         pprUnique, 
28
29         mkUniqueGrimily,                -- Used in UniqSupply only!
30         getKey, getKeyFastInt,          -- Used in Var, UniqFM, Name only!
31
32         incrUnique,                     -- Used for renumbering
33         deriveUnique,                   -- Ditto
34         newTagUnique,                   -- Used in CgCase
35         initTyVarUnique,
36
37         -- ** Making built-in uniques
38
39         -- now all the built-in Uniques (and functions to make them)
40         -- [the Oh-So-Wonderful Haskell module system wins again...]
41         mkAlphaTyVarUnique,
42         mkPrimOpIdUnique,
43         mkTupleTyConUnique, mkTupleDataConUnique,
44         mkPreludeMiscIdUnique, mkPreludeDataConUnique,
45         mkPreludeTyConUnique, mkPreludeClassUnique,
46         mkPArrDataConUnique,
47
48     mkVarOccUnique, mkDataOccUnique, mkTvOccUnique, mkTcOccUnique,
49         mkRegSingleUnique, mkRegPairUnique, mkRegClassUnique, mkRegSubUnique,
50
51         mkBuiltinUnique,
52         mkPseudoUniqueC,
53         mkPseudoUniqueD,
54         mkPseudoUniqueE,
55         mkPseudoUniqueH
56     ) where
57
58 #include "HsVersions.h"
59
60 import BasicTypes
61 import FastTypes
62 import FastString
63 import Outputable
64 -- import StaticFlags
65
66 #if defined(__GLASGOW_HASKELL__)
67 --just for implementing a fast [0,61) -> Char function
68 import GHC.Exts (indexCharOffAddr#, Char(..))
69 #else
70 import Data.Array
71 #endif
72 import Data.Char        ( chr, ord )
73 \end{code}
74
75 %************************************************************************
76 %*                                                                      *
77 \subsection[Unique-type]{@Unique@ type and operations}
78 %*                                                                      *
79 %************************************************************************
80
81 The @Chars@ are ``tag letters'' that identify the @UniqueSupply@.
82 Fast comparison is everything on @Uniques@:
83
84 \begin{code}
85 --why not newtype Int?
86
87 -- | The type of unique identifiers that are used in many places in GHC
88 -- for fast ordering and equality tests. You should generate these with
89 -- the functions from the 'UniqSupply' module
90 data Unique = MkUnique FastInt
91 \end{code}
92
93 Now come the functions which construct uniques from their pieces, and vice versa.
94 The stuff about unique *supplies* is handled further down this module.
95
96 \begin{code}
97 unpkUnique      :: Unique -> (Char, Int)        -- The reverse
98
99 mkUniqueGrimily :: Int -> Unique                -- A trap-door for UniqSupply
100 getKey          :: Unique -> Int                -- for Var
101 getKeyFastInt   :: Unique -> FastInt            -- for Var
102
103 incrUnique      :: Unique -> Unique
104 deriveUnique    :: Unique -> Int -> Unique
105 newTagUnique    :: Unique -> Char -> Unique
106 \end{code}
107
108
109 \begin{code}
110 mkUniqueGrimily x = MkUnique (iUnbox x)
111
112 {-# INLINE getKey #-}
113 getKey (MkUnique x) = iBox x
114 {-# INLINE getKeyFastInt #-}
115 getKeyFastInt (MkUnique x) = x
116
117 incrUnique (MkUnique i) = MkUnique (i +# _ILIT(1))
118
119 -- deriveUnique uses an 'X' tag so that it won't clash with
120 -- any of the uniques produced any other way
121 deriveUnique (MkUnique i) delta = mkUnique 'X' (iBox i + delta)
122
123 -- newTagUnique changes the "domain" of a unique to a different char
124 newTagUnique u c = mkUnique c i where (_,i) = unpkUnique u
125
126 -- pop the Char in the top 8 bits of the Unique(Supply)
127
128 -- No 64-bit bugs here, as long as we have at least 32 bits. --JSM
129
130 -- and as long as the Char fits in 8 bits, which we assume anyway!
131
132 mkUnique :: Char -> Int -> Unique       -- Builds a unique from pieces
133 -- NOT EXPORTED, so that we can see all the Chars that 
134 --               are used in this one module
135 mkUnique c i
136   = MkUnique (tag `bitOrFastInt` bits)
137   where
138     !tag  = fastOrd (cUnbox c) `shiftLFastInt` _ILIT(24)
139     !bits = iUnbox i `bitAndFastInt` _ILIT(16777215){-``0x00ffffff''-}
140
141 unpkUnique (MkUnique u)
142   = let
143         -- as long as the Char may have its eighth bit set, we
144         -- really do need the logical right-shift here!
145         tag = cBox (fastChr (u `shiftRLFastInt` _ILIT(24)))
146         i   = iBox (u `bitAndFastInt` _ILIT(16777215){-``0x00ffffff''-})
147     in
148     (tag, i)
149 \end{code}
150
151
152
153 %************************************************************************
154 %*                                                                      *
155 \subsection[Uniquable-class]{The @Uniquable@ class}
156 %*                                                                      *
157 %************************************************************************
158
159 \begin{code}
160 -- | Class of things that we can obtain a 'Unique' from
161 class Uniquable a where
162     getUnique :: a -> Unique
163
164 hasKey          :: Uniquable a => a -> Unique -> Bool
165 x `hasKey` k    = getUnique x == k
166
167 instance Uniquable FastString where
168  getUnique fs = mkUniqueGrimily (iBox (uniqueOfFS fs))
169
170 instance Uniquable Int where
171  getUnique i = mkUniqueGrimily i
172
173 instance Uniquable n => Uniquable (IPName n) where
174   getUnique (IPName n) = getUnique n
175 \end{code}
176
177
178 %************************************************************************
179 %*                                                                      *
180 \subsection[Unique-instances]{Instance declarations for @Unique@}
181 %*                                                                      *
182 %************************************************************************
183
184 And the whole point (besides uniqueness) is fast equality.  We don't
185 use `deriving' because we want {\em precise} control of ordering
186 (equality on @Uniques@ is v common).
187
188 \begin{code}
189 eqUnique, ltUnique, leUnique :: Unique -> Unique -> Bool
190 eqUnique (MkUnique u1) (MkUnique u2) = u1 ==# u2
191 ltUnique (MkUnique u1) (MkUnique u2) = u1 <#  u2
192 leUnique (MkUnique u1) (MkUnique u2) = u1 <=# u2
193
194 cmpUnique :: Unique -> Unique -> Ordering
195 cmpUnique (MkUnique u1) (MkUnique u2)
196   = if u1 ==# u2 then EQ else if u1 <# u2 then LT else GT
197
198 instance Eq Unique where
199     a == b = eqUnique a b
200     a /= b = not (eqUnique a b)
201
202 instance Ord Unique where
203     a  < b = ltUnique a b
204     a <= b = leUnique a b
205     a  > b = not (leUnique a b)
206     a >= b = not (ltUnique a b)
207     compare a b = cmpUnique a b
208
209 -----------------
210 instance Uniquable Unique where
211     getUnique u = u
212 \end{code}
213
214 We do sometimes make strings with @Uniques@ in them:
215 \begin{code}
216 pprUnique :: Unique -> SDoc
217 pprUnique uniq
218 --   | opt_SuppressUniques
219 --  = empty     -- Used exclusively to suppress uniques so you 
220 --  | otherwise -- can compare output easily
221   = case unpkUnique uniq of
222       (tag, u) -> finish_ppr tag u (text (iToBase62 u))
223
224 #ifdef UNUSED
225 pprUnique10 :: Unique -> SDoc
226 pprUnique10 uniq        -- in base-10, dudes
227   = case unpkUnique uniq of
228       (tag, u) -> finish_ppr tag u (int u)
229 #endif
230
231 finish_ppr :: Char -> Int -> SDoc -> SDoc
232 finish_ppr 't' u _pp_u | u < 26
233   =     -- Special case to make v common tyvars, t1, t2, ...
234         -- come out as a, b, ... (shorter, easier to read)
235     char (chr (ord 'a' + u))
236 finish_ppr tag _ pp_u = char tag <> pp_u
237
238 instance Outputable Unique where
239     ppr u = pprUnique u
240
241 instance Show Unique where
242     showsPrec p uniq = showsPrecSDoc p (pprUnique uniq)
243 \end{code}
244
245 %************************************************************************
246 %*                                                                      *
247 \subsection[Utils-base62]{Base-62 numbers}
248 %*                                                                      *
249 %************************************************************************
250
251 A character-stingy way to read/write numbers (notably Uniques).
252 The ``62-its'' are \tr{[0-9a-zA-Z]}.  We don't handle negative Ints.
253 Code stolen from Lennart.
254
255 \begin{code}
256 iToBase62 :: Int -> String
257 iToBase62 n_
258   = ASSERT(n_ >= 0) go (iUnbox n_) ""
259   where
260     go n cs | n <# _ILIT(62)
261              = case chooseChar62 n of { c -> c `seq` (c : cs) }
262              | otherwise
263              =  case (quotRem (iBox n) 62) of { (q_, r_) ->
264                 case iUnbox q_ of { q -> case iUnbox r_ of { r ->
265                 case (chooseChar62 r) of { c -> c `seq`
266                 (go q (c : cs)) }}}}
267
268     chooseChar62 :: FastInt -> Char
269     {-# INLINE chooseChar62 #-}
270 #if defined(__GLASGOW_HASKELL__)
271     --then FastInt == Int#
272     chooseChar62 n = C# (indexCharOffAddr# chars62 n)
273     !chars62 = "0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ"#
274 #else
275     --Haskell98 arrays are portable
276     chooseChar62 n = (!) chars62 n
277     chars62 = listArray (0,61) "0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ"
278 #endif
279 \end{code}
280
281 %************************************************************************
282 %*                                                                      *
283 \subsection[Uniques-prelude]{@Uniques@ for wired-in Prelude things}
284 %*                                                                      *
285 %************************************************************************
286
287 Allocation of unique supply characters:
288         v,t,u : for renumbering value-, type- and usage- vars.
289         B:   builtin
290         C-E: pseudo uniques     (used in native-code generator)
291         X:   uniques derived by deriveUnique
292         _:   unifiable tyvars   (above)
293         0-9: prelude things below
294              (no numbers left any more..)
295         ::   (prelude) parallel array data constructors
296
297         other a-z: lower case chars for unique supplies.  Used so far:
298
299         d       desugarer
300         f       AbsC flattener
301         g       SimplStg
302         n       Native codegen
303         r       Hsc name cache
304         s       simplifier
305
306 \begin{code}
307 mkAlphaTyVarUnique     :: Int -> Unique
308 mkPreludeClassUnique   :: Int -> Unique
309 mkPreludeTyConUnique   :: Int -> Unique
310 mkTupleTyConUnique     :: TupleSort -> Int -> Unique
311 mkPreludeDataConUnique :: Int -> Unique
312 mkTupleDataConUnique   :: TupleSort -> Int -> Unique
313 mkPrimOpIdUnique       :: Int -> Unique
314 mkPreludeMiscIdUnique  :: Int -> Unique
315 mkPArrDataConUnique    :: Int -> Unique
316
317 mkAlphaTyVarUnique i            = mkUnique '1' i
318
319 mkPreludeClassUnique i          = mkUnique '2' i
320
321 -- Prelude type constructors occupy *three* slots.
322 -- The first is for the tycon itself; the latter two
323 -- are for the generic to/from Ids.  See TysWiredIn.mk_tc_gen_info.
324
325 mkPreludeTyConUnique i          = mkUnique '3' (3*i)
326 mkTupleTyConUnique BoxedTuple   a       = mkUnique '4' (3*a)
327 mkTupleTyConUnique UnboxedTuple a       = mkUnique '5' (3*a)
328 mkTupleTyConUnique ConstraintTuple a    = mkUnique 'k' (3*a)
329
330 -- Data constructor keys occupy *two* slots.  The first is used for the
331 -- data constructor itself and its wrapper function (the function that
332 -- evaluates arguments as necessary and calls the worker). The second is
333 -- used for the worker function (the function that builds the constructor
334 -- representation).
335
336 mkPreludeDataConUnique i        = mkUnique '6' (2*i)    -- Must be alphabetic
337 mkTupleDataConUnique BoxedTuple   a = mkUnique '7' (2*a)        -- ditto (*may* be used in C labels)
338 mkTupleDataConUnique UnboxedTuple    a = mkUnique '8' (2*a)
339 mkTupleDataConUnique ConstraintTuple a = mkUnique 'h' (2*a)
340
341 mkPrimOpIdUnique op         = mkUnique '9' op
342 mkPreludeMiscIdUnique  i    = mkUnique '0' i
343
344 -- No numbers left anymore, so I pick something different for the character tag 
345 mkPArrDataConUnique a           = mkUnique ':' (2*a)
346
347 -- The "tyvar uniques" print specially nicely: a, b, c, etc.
348 -- See pprUnique for details
349
350 initTyVarUnique :: Unique
351 initTyVarUnique = mkUnique 't' 0
352
353 mkPseudoUniqueC, mkPseudoUniqueD, mkPseudoUniqueE, mkPseudoUniqueH,
354    mkBuiltinUnique :: Int -> Unique
355
356 mkBuiltinUnique i = mkUnique 'B' i
357 mkPseudoUniqueC i = mkUnique 'C' i -- used for getUnique on Regs
358 mkPseudoUniqueD i = mkUnique 'D' i -- used in NCG for getUnique on RealRegs
359 mkPseudoUniqueE i = mkUnique 'E' i -- used in NCG spiller to create spill VirtualRegs
360 mkPseudoUniqueH i = mkUnique 'H' i -- used in NCG spiller to create spill VirtualRegs
361
362 mkRegSingleUnique, mkRegPairUnique, mkRegSubUnique, mkRegClassUnique :: Int -> Unique
363 mkRegSingleUnique = mkUnique 'R'
364 mkRegSubUnique    = mkUnique 'S'
365 mkRegPairUnique   = mkUnique 'P'
366 mkRegClassUnique  = mkUnique 'L'
367
368 mkVarOccUnique, mkDataOccUnique, mkTvOccUnique, mkTcOccUnique :: FastString -> Unique
369 -- See Note [The Unique of an OccName] in OccName
370 mkVarOccUnique  fs = mkUnique 'i' (iBox (uniqueOfFS fs))
371 mkDataOccUnique fs = mkUnique 'd' (iBox (uniqueOfFS fs))
372 mkTvOccUnique   fs = mkUnique 'v' (iBox (uniqueOfFS fs))
373 mkTcOccUnique   fs = mkUnique 'c' (iBox (uniqueOfFS fs))
374 \end{code}
375