Autoconf: detect and set CFLAGS/CPPFLAGS needed for C99 mode
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.1], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands,
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42 FP_PROG_SORT
43
44 dnl ----------------------------------------------------------
45 FP_SETUP_PROJECT_VERSION
46
47 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
48 AC_SUBST([release], [1])
49
50 # First off, a distrib sanity check..
51 AC_CONFIG_SRCDIR([mk/config.mk.in])
52
53 dnl * We require autoconf version 2.60
54 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
55 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
56 dnl Using autoconf 2.59 started to give nonsense like this
57 dnl  #define SIZEOF_CHAR 0
58 dnl recently.
59 AC_PREREQ([2.60])
60
61 # -------------------------------------------------------------------------
62 # Prepare to generate the following header files
63 #
64 #
65 AC_CONFIG_HEADER(mk/config.h)
66
67 # No, semi-sadly, we don't do `--srcdir'...
68 if test x"$srcdir" != 'x.' ; then
69     echo "This configuration does not support the \`--srcdir' option.."
70     exit 1
71 fi
72
73 dnl --------------------------------------------------------------
74 dnl * Project specific configuration options
75 dnl --------------------------------------------------------------
76 dnl What follows is a bunch of options that can either be configured
77 dnl through command line options to the configure script or by
78 dnl supplying defns in the build tree's mk/build.mk. Having the option to
79 dnl use either is considered a Feature.
80
81 dnl ** What command to use to compile compiler sources ?
82 dnl --------------------------------------------------------------
83
84 AC_ARG_WITH([ghc],
85 [AC_HELP_STRING([--with-ghc=ARG],
86   [Use ARG as the path to GHC  [default=autodetect]])],
87   [WithGhc="$withval"],
88   [if test "$GHC" = ""; then
89     AC_PATH_PROG([GHC], [ghc])
90   fi
91   WithGhc="$GHC"])
92
93 dnl ** Tell the make system which OS we are using
94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
95 AC_SUBST(OSTYPE)
96
97 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
98 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
99                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
100         EnableBootstrapWithDevelSnaphost=YES,
101         EnableBootstrapWithDevelSnaphost=NO
102 )
103
104 AC_ARG_ENABLE(tarballs-autodownload,
105 [AC_HELP_STRING([--enable-tarballs-autodownload],
106                 [Automatically download Windows distribution binaries if needed.])],
107         TarballsAutodownload=YES,
108         TarballsAutodownload=NO
109 )
110 if test "$WithGhc" != ""; then
111   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
112
113   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
114      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
115   fi
116
117   AC_SUBST(GhcVersion)dnl
118   AC_SUBST(GhcMajVersion)dnl
119   AC_SUBST(GhcMinVersion)dnl
120   AC_SUBST(GhcPatchLevel)dnl
121   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
122   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
123
124   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
125   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
126   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
127   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
128   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
129 fi
130
131 dnl ** Must have GHC to build GHC
132 if test "$WithGhc" = ""
133 then
134     AC_MSG_ERROR([GHC is required.])
135 fi
136 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.10],
137     [AC_MSG_ERROR([GHC version 7.10 or later is required to compile GHC.])])
138
139 if test `expr $GhcMinVersion % 2` = "1"
140 then
141     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
142     then
143         AC_MSG_ERROR([
144      $WithGhc is a development snapshot of GHC, version $GhcVersion.
145      Bootstrapping using this version of GHC is not supported, and may not
146      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
147      or --with-ghc to specify a different GHC to use.])
148     fi
149 fi
150
151 GHC_PACKAGE_DB_FLAG=package-db
152 AC_SUBST(GHC_PACKAGE_DB_FLAG)
153
154 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.11],
155                     SUPPORTS_THIS_UNIT_ID=NO,
156                     SUPPORTS_THIS_UNIT_ID=YES)
157 AC_SUBST(SUPPORTS_THIS_UNIT_ID)
158
159 # GHC is passed to Cabal, so we need a native path
160 if test "${WithGhc}" != ""
161 then
162     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
163
164     if test "$ghc_host_os" = "mingw32"
165     then
166         if test "${OSTYPE}" = "msys"
167         then
168             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
169         else
170             # Canonicalise to <drive>:/path/to/ghc
171             WithGhc=`cygpath -m "${WithGhc}"`
172         fi
173         echo "GHC path canonicalised to: ${WithGhc}"
174     fi
175 fi
176 AC_SUBST([WithGhc])
177
178 dnl ** Without optimization some INLINE trickery fails for GHCi
179 SRC_CC_OPTS="-O"
180
181 dnl--------------------------------------------------------------------
182 dnl * Choose host(/target/build) platform
183 dnl--------------------------------------------------------------------
184 dnl If we aren't explicitly told what values to use with configure flags,
185 dnl we ask the bootstrapping compiler what platform it is for
186
187 if test "${WithGhc}" != ""
188 then
189         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
190         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
191         if test "$bootstrap_host" != "$bootstrap_target"
192         then
193                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
194         fi
195 fi
196
197 # We have to run these unconditionally, but we may discard their
198 # results in the following code
199 AC_CANONICAL_BUILD
200 AC_CANONICAL_HOST
201 AC_CANONICAL_TARGET
202
203 FPTOOLS_SET_PLATFORM_VARS
204
205 # Verify that the installed (bootstrap) GHC is capable of generating
206 # code for the requested build platform.
207 if test "$BuildPlatform" != "$bootstrap_target"
208 then
209     echo "This GHC (${WithGhc}) does not generate code for the build platform"
210     echo "   GHC target platform    : $bootstrap_target"
211     echo "   Desired build platform : $BuildPlatform"
212     exit 1
213 fi
214
215 # Testing if we shall enable shared libs support on Solaris.
216 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
217
218 SOLARIS_BROKEN_SHLD=NO
219
220 case $host in
221      i386-*-solaris2)
222      # here we go with the test
223      MINOR=`uname -r|cut -d '.' -f 2-`
224      if test "$MINOR" -lt "11"; then
225          SOLARIS_BROKEN_SHLD=YES
226      fi
227      ;;
228 esac
229
230 AC_SUBST(SOLARIS_BROKEN_SHLD)
231
232 dnl ** Do an unregisterised build?
233 dnl --------------------------------------------------------------
234 case "$HostArch" in
235     i386|x86_64|powerpc|powerpc64|powerpc64le|arm)
236         UnregisterisedDefault=NO
237         ;;
238     *)
239         UnregisterisedDefault=YES
240         ;;
241 esac
242 AC_ARG_ENABLE(unregisterised,
243 [AC_HELP_STRING([--enable-unregisterised],
244 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
245 [ if test x"$enableval" = x"yes"; then
246         Unregisterised=YES
247   else
248         Unregisterised=NO
249   fi
250 ],
251 [Unregisterised="$UnregisterisedDefault"]
252 )
253 AC_SUBST(Unregisterised)
254
255 AC_ARG_WITH(hc,
256 [AC_HELP_STRING([--with-hc=ARG],
257         [Use ARG as the path to the compiler for compiling ordinary
258          Haskell code  (default= value of --with-ghc)])],
259 [WithHc="$withval"],
260 [WithHc=$WithGhc]
261 )
262 AC_SUBST(WithHc)
263
264 # Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
265 FP_FIND_ROOT
266
267 fail() {
268     echo >&2
269     echo "$1" >&2
270     exit 1
271 }
272
273
274 if test "$HostOS" = "mingw32"
275 then
276     # Find the mingw-w64 7z file to extract.
277     # NB. If you update the tarballs to a new version of gcc, don't
278     # forget to tweak the paths in driver/gcc/gcc.c.
279     if test "$HostArch" = "i386"
280     then
281         mingw_arch="i686"
282         tarball_dest_dir="mingw-w64/x86"
283         tarball_mingw_dir="mingw32"
284     else
285         mingw_arch="x86_64"
286         tarball_dest_dir="mingw-w64/x86_64"
287         tarball_mingw_dir="mingw64"
288     fi
289 fi
290
291 set_up_tarballs() {
292     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
293     local action
294     if test "$TarballsAutodownload" = "NO"
295     then
296         action="verify"
297     else
298         action="download"
299     fi
300     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
301     case $? in
302         0)
303            rm missing-win32-tarballs
304            ;;
305         2)
306            echo
307            echo "Error:"
308            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
309            echo
310            echo "  * run configure with the --enable-tarballs-autodownload option"
311            echo
312            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
313            echo
314            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
315            echo "    them in the ghc-tarballs directory."
316            echo
317            exit 1
318            ;;
319         *)
320            echo
321            echo "Error fetching msys2 tarballs; see errors above."
322            exit 1
323            ;;
324     esac
325
326     # Extract all the tarballs in one go
327     if ! test -d inplace/mingw
328     then
329         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
330         rm -rf inplace/mingw
331         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
332         ( cd inplace &&
333         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
334         rm ".MTREE" &&
335         rm ".PKGINFO" &&
336         cd .. ) || fail "Error: Could not extract Windows toolchains."
337
338         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
339         touch inplace/mingw
340
341         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
342         # make a wrapper around it to give it the proper paths
343         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
344         PATH=`pwd`/inplace/mingw/bin:$PATH
345         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
346
347         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
348     fi
349 }
350
351 if test "$HostOS" = "mingw32"
352 then
353     test -d inplace || mkdir inplace
354
355     # NB. Download and extract the MingW-w64 distribution if required
356     set_up_tarballs
357
358     mingwbin="$hardtop/inplace/mingw/bin/"
359     CC="${mingwbin}gcc.exe"
360     LD="${mingwbin}ld.exe"
361     NM="${mingwbin}nm.exe"
362     RANLIB="${mingwbin}ranlib.exe"
363     OBJDUMP="${mingwbin}objdump.exe"
364     fp_prog_ar="${mingwbin}ar.exe"
365
366     # NB. Download the perl binaries if required
367     if ! test -d inplace/perl ||
368          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
369     then
370         AC_MSG_NOTICE([Making in-tree perl tree])
371         rm -rf inplace/perl
372         mkdir inplace/perl
373         (
374             cd inplace/perl &&
375             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
376         )
377         AC_MSG_NOTICE([In-tree perl tree created])
378     fi
379 fi
380
381 FP_ICONV
382 FP_GMP
383 FP_CURSES
384
385 XCODE_VERSION()
386
387 SplitObjsBroken=NO
388 if test "$TargetOS_CPP" = "darwin"
389 then
390     # Split objects is broken (#4013) with XCode < 3.2
391     if test "$XCodeVersion1" -lt 3
392     then
393         SplitObjsBroken=YES
394     else
395         if test "$XCodeVersion1" -eq 3
396         then
397             if test "$XCodeVersion2" -lt 2
398             then
399                 SplitObjsBroken=YES
400             fi
401         fi
402     fi
403 fi
404 AC_SUBST([SplitObjsBroken])
405
406 dnl ** Building a cross compiler?
407 dnl --------------------------------------------------------------
408 CrossCompiling=NO
409 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
410 if test "$target" != "$host" ; then
411     CrossCompiling=YES
412     cross_compiling=yes   # This tells configure that it can accept just 'target',
413                           # otherwise you get
414                           #   configure: error: cannot run C compiled programs.
415                           #   If you meant to cross compile, use `--host'.
416 fi
417 if test "$build" != "$host" ; then
418    AC_MSG_ERROR([
419 You've selected:
420
421   BUILD:  $build   (the architecture we're building on)
422   HOST:   $host    (the architecture the compiler we're building will execute on)
423   TARGET: $target  (the architecture the compiler we're building will produce code for)
424
425 BUILD must equal HOST; that is, we do not support building GHC itself
426 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
427 1 will be a cross-compiler, and stage 2 will be the cross-compiled
428 GHC.
429 ])
430 fi
431 if test "$CrossCompiling" = "YES"
432 then
433   CrossCompilePrefix="${target}-"
434 else
435   CrossCompilePrefix=""
436 fi
437 TargetPlatformFull="${target}"
438 AC_SUBST(CrossCompiling)
439 AC_SUBST(CrossCompilePrefix)
440 AC_SUBST(TargetPlatformFull)
441
442 dnl ** Which gcc to use?
443 dnl --------------------------------------------------------------
444 FIND_GCC([WhatGccIsCalled], [gcc], [gcc])
445 CC="$WhatGccIsCalled"
446 export CC
447
448 # If --with-gcc was used, and we're not cross-compiling, then it also
449 # applies to the stage0 compiler.
450 MAYBE_OVERRIDE_STAGE0([gcc],[CC_STAGE0])
451 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
452
453 dnl make extensions visible to allow feature-tests to detect them lateron
454 AC_USE_SYSTEM_EXTENSIONS
455
456 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
457 AC_PROG_CPP
458
459 # --with-hs-cpp/--with-hs-cpp-flags
460 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
461 AC_SUBST([HaskellCPPCmd])
462 AC_SUBST([HaskellCPPArgs])
463
464 FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
465 FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
466 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
467 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
468
469 dnl ** Which ld to use?
470 dnl --------------------------------------------------------------
471 FIND_LD([LdCmd])
472 AC_SUBST([LdCmd])
473
474 dnl ** Which nm to use?
475 dnl --------------------------------------------------------------
476 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
477 NmCmd="$NM"
478 AC_SUBST([NmCmd])
479
480 dnl ** Which objdump to use?
481 dnl --------------------------------------------------------------
482 FP_ARG_WITH_PATH_GNU_PROG_OPTIONAL([OBJDUMP], [objdump], [objdump])
483 ObjdumpCmd="$OBJDUMP"
484 AC_SUBST([ObjdumpCmd])
485
486 dnl ** Which ar to use?
487 dnl --------------------------------------------------------------
488 FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
489 ArCmd="$AR"
490 fp_prog_ar="$AR"
491 AC_SUBST([ArCmd])
492
493 dnl ** Which ranlib to use?
494 dnl --------------------------------------------------------------
495 FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
496 RanlibCmd="$RANLIB"
497 RANLIB="$RanlibCmd"
498
499
500 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
501 case $HostOS_CPP in
502 cygwin32|mingw32)
503     dnl ** Which objdump to use?
504     dnl --------------------------------------------------------------
505     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
506     ObjdumpCmd="$OBJDUMP"
507     AC_SUBST([ObjdumpCmd])
508     ;;
509 esac
510
511 # Here is where we re-target which specific version of the LLVM
512 # tools we are looking for. In the past, GHC supported a number of
513 # versions of LLVM simultaneously, but that stopped working around
514 # 3.5/3.6 release of LLVM.
515 LlvmVersion=3.7
516 AC_SUBST([LlvmVersion])
517 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
518 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
519
520 dnl ** Which LLVM llc to use?
521 dnl --------------------------------------------------------------
522 FIND_LLVM_PROG([LLC], [llc], [llc], [$LlvmVersion])
523 LlcCmd="$LLC"
524 AC_SUBST([LlcCmd])
525
526 dnl ** Which LLVM opt to use?
527 dnl --------------------------------------------------------------
528 FIND_LLVM_PROG([OPT], [opt], [opt], [$LlvmVersion])
529 OptCmd="$OPT"
530 AC_SUBST([OptCmd])
531
532 dnl --------------------------------------------------------------
533 dnl End of configure script option section
534 dnl --------------------------------------------------------------
535
536
537 dnl --------------------------------------------------------------
538 dnl * General configuration checks
539 dnl --------------------------------------------------------------
540
541 dnl ** Bug 9439: Some GHC 7.8 releases had broken LLVM code generator.
542 dnl Unfortunately we don't know whether the user is going to request a
543 dnl build with the LLVM backend as this is only given in build.mk.
544 dnl
545 dnl Instead, we try to do as much work as possible here, checking
546 dnl whether -fllvm is the stage 0 compiler's default. If so we
547 dnl fail. If not, we check whether -fllvm is affected explicitly and
548 dnl if so set a flag. The build system will later check this flag
549 dnl after the desired build flags are known.
550
551 dnl This problem is further complicated by the fact that the llvm
552 dnl version used by the bootstrap compiler may be different from the
553 dnl version we arre trying to compile GHC against. Therefore, we need
554 dnl to find the boostrap compiler's `settings` file then check to see
555 dnl if the `opt` and `llc` command strings are non-empty and if these
556 dnl programs exist. Only if they exist to we test for bug #9439.
557
558 FIND_GHC_BOOTSTRAP_PROG([BootstrapLlcCmd], [${WithGhc}], "LLVM llc command")
559 FIND_GHC_BOOTSTRAP_PROG([BootstrapOptCmd], [${WithGhc}], "LLVM opt command")
560
561 if test -n "$BootstrapLlcCmd" && test -n "$BootstrapOptCmd"
562 then
563     AC_MSG_CHECKING(whether bootstrap compiler is affected by bug 9439)
564     echo "main = putStrLn \"%function\"" > conftestghc.hs
565
566     # Check whether LLVM backend is default for this platform
567     "${WithGhc}" -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" conftestghc.hs 2>&1 >/dev/null
568     res=`./conftestghc`
569     if test "x$res" = "x%object"
570     then
571         AC_MSG_RESULT(yes)
572         echo "Buggy bootstrap compiler"
573         echo ""
574         echo "The stage 0 compiler $WithGhc is affected by GHC Bug \#9439"
575         echo "and therefore will miscompile the LLVM backend if -fllvm is"
576         echo "used."
577         echo
578         echo "Please use another bootstrap compiler"
579         exit 1
580     fi
581
582     # -fllvm is not the default, but set a flag so the Makefile can check
583     # -for it in the build flags later on
584     "${WithGhc}" -fforce-recomp -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" -fllvm conftestghc.hs 2>&1 >/dev/null
585     if test $? = 0
586     then
587         res=`./conftestghc`
588         if test "x$res" = "x%object"
589         then
590             AC_MSG_RESULT(yes)
591             GHC_LLVM_AFFECTED_BY_9439=1
592         elif test "x$res" = "x%function"
593         then
594             AC_MSG_RESULT(no)
595             GHC_LLVM_AFFECTED_BY_9439=0
596         else
597             AC_MSG_WARN(unexpected output $res)
598         fi
599     else
600         AC_MSG_RESULT(failed to compile, assuming no)
601     fi
602 fi
603 AC_SUBST([GHC_LLVM_AFFECTED_BY_9439])
604
605 dnl ** Can the unix package be built?
606 dnl --------------------------------------------------------------
607
608 if test "$TargetOS" = "mingw32"
609 then
610     GhcLibsWithUnix=NO
611 else
612     GhcLibsWithUnix=YES
613 fi
614 AC_SUBST([GhcLibsWithUnix])
615
616 dnl ** does #! work?
617 AC_SYS_INTERPRETER()
618
619 dnl ** look for `perl'
620 case $HostOS_CPP in
621 cygwin32|mingw32)
622     PerlCmd=$hardtop/inplace/perl/perl
623     ;;
624 *)
625     AC_PATH_PROG(PerlCmd,perl)
626     if test -z "$PerlCmd"
627     then
628         echo "You must install perl before you can continue"
629         echo "Perhaps it is already installed, but not in your PATH?"
630         exit 1
631     else
632         FPTOOLS_CHECK_PERL_VERSION
633     fi
634     ;;
635 esac
636
637 dnl ** look for GCC and find out which version
638 dnl     Figure out which C compiler to use.  Gcc is preferred.
639 dnl     If gcc, make sure it's at least 3.0
640 dnl
641 FP_GCC_VERSION
642
643 dnl ** look to see if we have a C compiler using an llvm back end.
644 dnl
645 FP_CC_LLVM_BACKEND
646
647 FP_PROG_LD_IS_GNU
648 FP_PROG_LD_BUILD_ID
649 FP_PROG_LD_NO_COMPACT_UNWIND
650 FP_PROG_LD_FILELIST
651
652
653 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
654 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
655 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
656 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
657 # Stage 3 won't be supported by cross-compilation
658
659 FP_GCC_EXTRA_FLAGS
660
661 AC_SUBST(CONF_CC_OPTS_STAGE0)
662 AC_SUBST(CONF_CC_OPTS_STAGE1)
663 AC_SUBST(CONF_CC_OPTS_STAGE2)
664 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
665 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
666 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
667 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
668 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
669 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
670 AC_SUBST(CONF_CPP_OPTS_STAGE0)
671 AC_SUBST(CONF_CPP_OPTS_STAGE1)
672 AC_SUBST(CONF_CPP_OPTS_STAGE2)
673
674 dnl ** Set up the variables for the platform in the settings file.
675 dnl May need to use gcc to find platform details.
676 dnl --------------------------------------------------------------
677 FPTOOLS_SET_HASKELL_PLATFORM_VARS
678
679 dnl ** figure out how to do context diffs
680 FP_PROG_CONTEXT_DIFF
681
682 dnl Let's make sure install-sh is executable here.  If we got it from
683 dnl a darcs repo, it might not be (see bug #978).
684 chmod +x install-sh
685 dnl ** figure out how to do a BSD-ish install
686 AC_PROG_INSTALL
687
688 dnl ** how to invoke `ar' and `ranlib'
689 FP_PROG_AR_SUPPORTS_ATFILE
690 FP_PROG_AR_NEEDS_RANLIB
691
692 dnl ** Check to see whether ln -s works
693 AC_PROG_LN_S
694
695 FP_SETTINGS
696
697 dnl ** Find the path to sed
698 AC_PATH_PROGS(SedCmd,gsed sed,sed)
699
700
701 dnl ** check for time command
702 AC_PATH_PROG(TimeCmd,time)
703
704 dnl ** check for tar
705 dnl   if GNU tar is named gtar, look for it first.
706 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
707
708 dnl ** check for patch
709 dnl if GNU patch is named gpatch, look for it first
710 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
711
712 dnl ** check for dtrace (currently only implemented for Mac OS X)
713 HaveDtrace=NO
714 AC_PATH_PROG(DtraceCmd,dtrace)
715 if test -n "$DtraceCmd"; then
716   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
717     HaveDtrace=YES
718   fi
719 fi
720 AC_SUBST(HaveDtrace)
721
722 AC_PATH_PROG(HSCOLOUR,HsColour)
723 # HsColour is passed to Cabal, so we need a native path
724 if test "$HostOS"      = "mingw32" && \
725    test "${OSTYPE}"   != "msys"    && \
726    test "${HSCOLOUR}" != ""
727 then
728     # Canonicalise to <drive>:/path/to/gcc
729     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
730 fi
731
732 dnl ** check for Sphinx toolchain
733 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
734 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
735 changequote(, )dnl
736 [if test -n "$SPHINXBUILD"; then
737   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
738 fi;
739 changequote([, ])dnl
740 ])
741 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
742     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
743
744 dnl ** check for xelatex
745 AC_PATH_PROG(XELATEX,xelatex)
746
747 dnl ** check for ghc-pkg command
748 FP_PROG_GHC_PKG
749
750 dnl ** check for installed happy binary + version
751 FPTOOLS_HAPPY
752
753 dnl ** check for installed alex binary + version
754 FPTOOLS_ALEX
755
756 dnl --------------------------------------------------
757 dnl ### program checking section ends here ###
758 dnl --------------------------------------------------
759
760 dnl --------------------------------------------------
761 dnl * Platform header file and syscall feature tests
762 dnl ### checking the state of the local header files and syscalls ###
763
764 dnl ** check for full ANSI header (.h) files
765 AC_HEADER_STDC
766
767 dnl ** Enable large file support.  NB. do this before testing the type of
768 dnl    off_t, because it will affect the result of that test.
769 AC_SYS_LARGEFILE
770
771 dnl ** check for specific header (.h) files that we are interested in
772 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
773
774 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
775 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
776 [[#if HAVE_SYS_PARAM_H
777 # include <sys/param.h>
778 #endif
779 ]])
780
781 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
782 AC_HEADER_TIME
783
784 dnl ** do we have long longs?
785 AC_CHECK_TYPES([long long])
786
787 dnl ** what are the sizes of various types
788 AC_CHECK_SIZEOF(char,               1)
789 AC_CHECK_SIZEOF(double,             8)
790 AC_CHECK_SIZEOF(float,              4)
791 AC_CHECK_SIZEOF(int,                4)
792 AC_CHECK_SIZEOF(long,               4)
793 if test "$ac_cv_type_long_long" = yes; then
794 AC_CHECK_SIZEOF(long long,          8)
795 fi
796 AC_CHECK_SIZEOF(short,              2)
797 AC_CHECK_SIZEOF(unsigned char,      1)
798 AC_CHECK_SIZEOF(unsigned int,       4)
799 AC_CHECK_SIZEOF(unsigned long,      4)
800 if test "$ac_cv_type_long_long" = yes; then
801 AC_CHECK_SIZEOF(unsigned long long, 8)
802 fi
803 AC_CHECK_SIZEOF(unsigned short,     2)
804 AC_CHECK_SIZEOF(void *,             4)
805
806 dnl for use in settings.in
807 WordSize=$ac_cv_sizeof_void_p
808 AC_SUBST(WordSize)
809
810 dnl ** what are alignment constraints on various types
811 FP_CHECK_ALIGNMENT(char)
812 FP_CHECK_ALIGNMENT(double)
813 FP_CHECK_ALIGNMENT(float)
814 FP_CHECK_ALIGNMENT(int)
815 FP_CHECK_ALIGNMENT(long)
816 if test "$ac_cv_type_long_long" = yes; then
817 FP_CHECK_ALIGNMENT(long long)
818 fi
819 FP_CHECK_ALIGNMENT(short)
820 FP_CHECK_ALIGNMENT(unsigned char)
821 FP_CHECK_ALIGNMENT(unsigned int)
822 FP_CHECK_ALIGNMENT(unsigned long)
823 if test "$ac_cv_type_long_long" = yes; then
824 FP_CHECK_ALIGNMENT(unsigned long long)
825 fi
826 FP_CHECK_ALIGNMENT(unsigned short)
827 FP_CHECK_ALIGNMENT(void *)
828
829 FP_CHECK_FUNC([WinExec],
830   [@%:@include <windows.h>], [WinExec("",0)])
831
832 FP_CHECK_FUNC([GetModuleFileName],
833   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
834
835 dnl ** check for more functions
836 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
837 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
838
839 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
840 dnl ** _POSIX_C_SOURCE is defined
841 AC_CHECK_DECLS([ctime_r], , ,
842 [#define _POSIX_SOURCE 1
843 #define _POSIX_C_SOURCE 199506L
844 #include <time.h>])
845
846 dnl ** check for mingwex library
847 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
848 AC_SUBST(HaveLibMingwEx)
849
850 if test $HaveLibMingwEx = YES ; then
851   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
852 fi
853
854 dnl ** check for math library
855 dnl    Keep that check as early as possible.
856 dnl    as we need to know whether we need libm
857 dnl    for math functions or not
858 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
859 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
860 if test $HaveLibM = YES
861 then
862   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
863 fi
864
865 FP_BFD_SUPPORT
866
867 dnl ################################################################
868 dnl Check for libraries
869 dnl ################################################################
870
871 # system libffi
872
873 AC_ARG_WITH([system-libffi],
874 [AC_HELP_STRING([--with-system-libffi],
875   [Use system provided libffi for RTS [default=no]])
876 ])
877
878 AS_IF([test "x$with_system_libffi" = "xyes"],
879   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
880 )
881
882
883 AC_SUBST(UseSystemLibFFI)
884
885 AC_ARG_WITH([ffi-includes],
886 [AC_HELP_STRING([--with-ffi-includes=ARG],
887   [Find includes for libffi in ARG [default=system default]])
888 ],
889 [
890  if test "x$UseSystemLibFFI" != "xYES"; then
891     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
892  else
893     FFIIncludeDir="$withval"
894     LIBFFI_CFLAGS="-I$withval"
895  fi
896 ])
897
898 AC_SUBST(FFIIncludeDir)
899
900 AC_ARG_WITH([ffi-libraries],
901 [AC_HELP_STRING([--with-ffi-libraries=ARG],
902   [Find libffi in ARG [default=system default]])
903 ],
904 [
905  if test "x$UseSystemLibFFI" != "xYES"; then
906     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
907  else
908     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
909  fi
910 ])
911
912 AC_SUBST(FFILibDir)
913
914 AS_IF([test "$UseSystemLibFFI" = "YES"], [
915  CFLAGS2="$CFLAGS"
916  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
917  LDFLAGS2="$LDFLAGS"
918  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
919  if test "$HostOS" = "openbsd";
920  then
921    # OpenBSD's libffi is not directly linked to the libpthread but
922    # still requires pthread functionality. This means that any client
923    # binary which links with libffi also needs to link with
924    # libpthread. If it does not, then linking fails with unresolved
925    # symbols.
926    LDFLAGS="$LDFLAGS -lpthread"
927  fi
928  AC_CHECK_LIB(ffi, ffi_call,
929   [AC_CHECK_HEADERS([ffi.h], [break], [])
930    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
931   [AC_MSG_ERROR([Cannot find system libffi])])
932  CFLAGS="$CFLAGS2"
933  LDFLAGS="$LDFLAGS2"
934 ])
935
936 dnl ** check whether we need -ldl to get dlopen()
937 AC_CHECK_LIB(dl, dlopen)
938
939 dnl --------------------------------------------------
940 dnl * Miscellaneous feature tests
941 dnl --------------------------------------------------
942
943 dnl ** can we get alloca?
944 AC_FUNC_ALLOCA
945
946 dnl ** working vfork?
947 AC_FUNC_FORK
948
949 dnl ** determine whether or not const works
950 AC_C_CONST
951
952 dnl ** are we big endian?
953 AC_C_BIGENDIAN
954 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
955
956 dnl ** check for leading underscores in symbol names
957 FP_LEADING_UNDERSCORE
958
959 FP_VISIBILITY_HIDDEN
960
961 dnl ** check for librt
962 AC_CHECK_LIB(rt, clock_gettime)
963 AC_CHECK_FUNCS(clock_gettime timer_settime)
964 FP_CHECK_TIMER_CREATE
965
966 dnl ** check for Apple's "interesting" long double compatibility scheme
967 AC_MSG_CHECKING(for printf\$LDBLStub)
968 AC_TRY_LINK_FUNC(printf\$LDBLStub,
969     [
970         AC_MSG_RESULT(yes)
971         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
972             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
973     ],
974     [
975         AC_MSG_RESULT(no)
976         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
977             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
978     ])
979
980 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
981 dnl    a different single-argument version.
982 AC_CHECK_LIB(pthread, pthread_setname_np)
983 AC_MSG_CHECKING(for pthread_setname_np)
984 AC_TRY_LINK(
985 [
986 #define _GNU_SOURCE
987 #include <pthread.h>
988 ],
989 [pthread_setname_np(pthread_self(), "name");],
990     AC_MSG_RESULT(yes)
991     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
992       [Define to 1 if you have the glibc version of pthread_setname_np]),
993     AC_MSG_RESULT(no)
994 )
995
996 dnl ** check for eventfd which is needed by the I/O manager
997 AC_CHECK_HEADERS([sys/eventfd.h])
998 AC_CHECK_FUNCS([eventfd])
999
1000 dnl ** Check for __thread support in the compiler
1001 AC_MSG_CHECKING(for __thread support)
1002 AC_COMPILE_IFELSE(
1003   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1004   [
1005    AC_MSG_RESULT(yes)
1006    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1007   ],
1008   [
1009    AC_MSG_RESULT(no)
1010    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1011   ])
1012
1013
1014 AC_CHECK_FUNCS(__mingw_vfprintf)
1015
1016 dnl large address space support (see includes/rts/storage/MBlock.h)
1017 dnl
1018 dnl Darwin has vm_allocate/vm_protect
1019 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1020 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1021 dnl (They also have MADV_DONTNEED, but it means something else!)
1022 dnl
1023 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1024 dnl it counts page-table space as committed memory, and so quickly
1025 dnl runs out of paging file when we have multiple processes reserving
1026 dnl 1TB of address space, we get the following error:
1027 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1028 dnl
1029
1030 AC_ARG_ENABLE(large-address-space,
1031     [AC_HELP_STRING([--enable-large-address-space],
1032         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1033     EnableLargeAddressSpace=$enableval,
1034     EnableLargeAddressSpace=yes
1035 )
1036
1037 use_large_address_space=no
1038 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1039     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1040         if test "$ghc_host_os" = "darwin" ; then
1041             use_large_address_space=yes
1042         elif test "$ghc_host_os" = "openbsd" ; then
1043             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1044             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1045             # but is completely ignored by OS mmap
1046             use_large_address_space=no
1047         else
1048             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1049                 [
1050                 #include <unistd.h>
1051                 #include <sys/types.h>
1052                 #include <sys/mman.h>
1053                 #include <fcntl.h>
1054             ])
1055             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1056                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1057                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1058                     use_large_address_space=yes
1059             fi
1060         fi
1061     fi
1062 fi
1063 if test "$use_large_address_space" = "yes" ; then
1064    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1065 fi
1066
1067 AC_CHECK_LIB(dw, dwfl_begin, [HaveLibdw=YES], [HaveLibdw=NO])
1068 AC_SUBST(HaveLibdw)
1069
1070 if test -n "$SPHINXBUILD"; then
1071     BUILD_MAN=YES
1072     BUILD_SPHINX_HTML=YES
1073     if test -n "$XELATEX"; then
1074         BUILD_SPHINX_PDF=YES
1075     else
1076         BUILD_SPHINX_PDF=NO
1077     fi
1078 else
1079     BUILD_MAN=NO
1080     BUILD_SPHINX_HTML=NO
1081     BUILD_SPHINX_PDF=NO
1082 fi
1083 AC_SUBST(BUILD_MAN)
1084 AC_SUBST(BUILD_SPHINX_HTML)
1085 AC_SUBST(BUILD_SPHINX_PDF)
1086
1087 LIBRARY_VERSION(base)
1088 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1089 LIBRARY_VERSION(ghc-prim)
1090 LIBRARY_ghc_VERSION="$ProjectVersion"
1091 AC_SUBST(LIBRARY_ghc_VERSION)
1092
1093 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1094    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1095 fi
1096
1097 # Create the configuration for the Shake-based build system if it is present
1098 if test -e shake-build/cfg/system.config.in; then
1099     AC_CONFIG_FILES([shake-build/cfg/system.config])
1100 fi
1101
1102 # We got caught by
1103 #     http://savannah.gnu.org/bugs/index.php?1516
1104 #     $(eval ...) inside conditionals causes errors
1105 # with make 3.80, so warn the user if it looks like they're about to
1106 # try to use it.
1107 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1108 print_make_warning=""
1109 checkMake380() {
1110     make_ver=`$1 --version 2>&1 | head -1`
1111     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1112     then
1113         print_make_warning="true"
1114     fi
1115     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1116     then
1117         MakeCmd=$1
1118         AC_SUBST(MakeCmd)
1119     fi
1120 }
1121
1122 checkMake380 make
1123 checkMake380 gmake
1124
1125 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt distrib/configure.ac])
1126 AC_OUTPUT
1127
1128 if test "$print_make_warning" = "true"; then
1129    echo
1130    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1131    echo "This version cannot be used to build GHC."
1132    echo "Please use GNU make >= 3.81."
1133 fi
1134
1135 echo ["
1136 ----------------------------------------------------------------------
1137 Configure completed successfully.
1138
1139    Building GHC version  : $ProjectVersion
1140           Git commit id  : $ProjectGitCommitId
1141
1142    Build platform        : $BuildPlatform
1143    Host platform         : $HostPlatform
1144    Target platform       : $TargetPlatform
1145 "]
1146
1147 echo ["\
1148    Bootstrapping using   : $WithGhc
1149       which is version   : $GhcVersion
1150 "]
1151
1152 if test "x$CC_LLVM_BACKEND" = "x1"; then
1153     if test "x$CC_CLANG_BACKEND" = "x1"; then
1154         CompilerName="clang        "
1155     else
1156         CompilerName="llvm-gcc     "
1157     fi
1158 else
1159     CompilerName="gcc          "
1160 fi
1161
1162 echo ["\
1163    Using $CompilerName       : $WhatGccIsCalled
1164       which is version       : $GccVersion
1165    Building a cross compiler : $CrossCompiling
1166    hs-cpp       : $HaskellCPPCmd
1167    hs-cpp-flags : $HaskellCPPArgs
1168    ld           : $LdCmd
1169    nm           : $NmCmd
1170    objdump      : $ObjdumpCmd
1171    Happy        : $HappyCmd ($HappyVersion)
1172    Alex         : $AlexCmd ($AlexVersion)
1173    Perl         : $PerlCmd
1174    sphinx-build : $SPHINXBUILD
1175    xelatex      : $XELATEX
1176
1177    Using LLVM tools
1178       llc   : $LlcCmd
1179       opt   : $OptCmd"]
1180
1181 if test "$HSCOLOUR" = ""; then
1182 echo ["
1183    HsColour was not found; documentation will not contain source links
1184 "]
1185 else
1186 echo ["\
1187    HsColour : $HSCOLOUR
1188 "]
1189 fi
1190
1191 echo ["\
1192    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1193    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"]
1194
1195 echo ["----------------------------------------------------------------------
1196 "]
1197
1198 echo "\
1199 For a standard build of GHC (fully optimised with profiling), type (g)make.
1200
1201 To make changes to the default build configuration, copy the file
1202 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1203
1204 For more information on how to configure your GHC build, see
1205    http://ghc.haskell.org/trac/ghc/wiki/Building
1206 "