Improve panic printout
[ghc.git] / compiler / cmm / CmmLex.x
1 -----------------------------------------------------------------------------
2 --
3 -- (c) The University of Glasgow, 2004-2006
4 --
5 -- Lexer for concrete Cmm.  We try to stay close to the C-- spec, but there
6 -- are a few minor differences:
7 --
8 --   * extra keywords for our macros, and float32/float64 types
9 --   * global registers (Sp,Hp, etc.)
10 --
11 -----------------------------------------------------------------------------
12
13 {
14 {-# LANGUAGE BangPatterns #-}
15 {-# OPTIONS -Wwarn -w #-}
16 -- The above -Wwarn supression flag is a temporary kludge.
17 -- While working on this module you are encouraged to remove it and fix
18 -- any warnings in the module. See
19 --     http://ghc.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
20 -- for details
21
22 module CmmLex (
23    CmmToken(..), cmmlex,
24   ) where
25
26 import CmmExpr
27
28 import Lexer
29 import SrcLoc
30 import UniqFM
31 import StringBuffer
32 import FastString
33 import Ctype
34 import Util
35 --import TRACE
36
37 import Data.Word
38 import Data.Char
39 }
40
41 $whitechar   = [\ \t\n\r\f\v\xa0] -- \xa0 is Unicode no-break space
42 $white_no_nl = $whitechar # \n
43
44 $ascdigit  = 0-9
45 $unidigit  = \x01 -- Trick Alex into handling Unicode. See alexGetChar.
46 $digit     = [$ascdigit $unidigit]
47 $octit     = 0-7
48 $hexit     = [$digit A-F a-f]
49
50 $unilarge  = \x03 -- Trick Alex into handling Unicode. See alexGetChar.
51 $asclarge  = [A-Z \xc0-\xd6 \xd8-\xde]
52 $large     = [$asclarge $unilarge]
53
54 $unismall  = \x04 -- Trick Alex into handling Unicode. See alexGetChar.
55 $ascsmall  = [a-z \xdf-\xf6 \xf8-\xff]
56 $small     = [$ascsmall $unismall \_]
57
58 $namebegin = [$large $small \. \$ \@]
59 $namechar  = [$namebegin $digit]
60
61 @decimal     = $digit+
62 @octal       = $octit+
63 @hexadecimal = $hexit+
64 @exponent    = [eE] [\-\+]? @decimal
65
66 @floating_point = @decimal \. @decimal @exponent? | @decimal @exponent
67
68 @escape      = \\ ([abfnrt\\\'\"\?] | x $hexit{1,2} | $octit{1,3})
69 @strchar     = ($printable # [\"\\]) | @escape
70
71 cmm :-
72
73 $white_no_nl+           ;
74 ^\# pragma .* \n        ; -- Apple GCC 3.3 CPP generates pragmas in its output
75
76 ^\# (line)?             { begin line_prag }
77
78 -- single-line line pragmas, of the form
79 --    # <line> "<file>" <extra-stuff> \n
80 <line_prag> $digit+                     { setLine line_prag1 }
81 <line_prag1> \" [^\"]* \"       { setFile line_prag2 }
82 <line_prag2> .*                         { pop }
83
84 <0> {
85   \n                    ;
86
87   [\:\;\{\}\[\]\(\)\=\`\~\/\*\%\-\+\&\^\|\>\<\,\!]      { special_char }
88   
89   ".."                  { kw CmmT_DotDot }
90   "::"                  { kw CmmT_DoubleColon }
91   ">>"                  { kw CmmT_Shr }
92   "<<"                  { kw CmmT_Shl }
93   ">="                  { kw CmmT_Ge }
94   "<="                  { kw CmmT_Le }
95   "=="                  { kw CmmT_Eq }
96   "!="                  { kw CmmT_Ne }
97   "&&"                  { kw CmmT_BoolAnd }
98   "||"                  { kw CmmT_BoolOr }
99   
100   P@decimal             { global_regN (\n -> VanillaReg n VGcPtr) }
101   R@decimal             { global_regN (\n -> VanillaReg n VNonGcPtr) }
102   F@decimal             { global_regN FloatReg }
103   D@decimal             { global_regN DoubleReg }
104   L@decimal             { global_regN LongReg }
105   Sp                    { global_reg Sp }
106   SpLim                 { global_reg SpLim }
107   Hp                    { global_reg Hp }
108   HpLim                 { global_reg HpLim }
109   CCCS                  { global_reg CCCS }
110   CurrentTSO            { global_reg CurrentTSO }
111   CurrentNursery        { global_reg CurrentNursery }
112   HpAlloc               { global_reg HpAlloc }
113   BaseReg               { global_reg BaseReg }
114   
115   $namebegin $namechar* { name }
116   
117   0 @octal              { tok_octal }
118   @decimal              { tok_decimal }
119   0[xX] @hexadecimal    { tok_hexadecimal }
120   @floating_point       { strtoken tok_float }
121   
122   \" @strchar* \"       { strtoken tok_string }
123 }
124
125 {
126 data CmmToken
127   = CmmT_SpecChar  Char
128   | CmmT_DotDot
129   | CmmT_DoubleColon
130   | CmmT_Shr
131   | CmmT_Shl
132   | CmmT_Ge
133   | CmmT_Le
134   | CmmT_Eq
135   | CmmT_Ne
136   | CmmT_BoolAnd
137   | CmmT_BoolOr
138   | CmmT_CLOSURE
139   | CmmT_INFO_TABLE
140   | CmmT_INFO_TABLE_RET
141   | CmmT_INFO_TABLE_FUN
142   | CmmT_INFO_TABLE_CONSTR
143   | CmmT_INFO_TABLE_SELECTOR
144   | CmmT_else
145   | CmmT_export
146   | CmmT_section
147   | CmmT_align
148   | CmmT_goto
149   | CmmT_if
150   | CmmT_call
151   | CmmT_jump
152   | CmmT_foreign
153   | CmmT_never
154   | CmmT_prim
155   | CmmT_return
156   | CmmT_returns
157   | CmmT_import
158   | CmmT_switch
159   | CmmT_case
160   | CmmT_default
161   | CmmT_push
162   | CmmT_bits8
163   | CmmT_bits16
164   | CmmT_bits32
165   | CmmT_bits64
166   | CmmT_bits128
167   | CmmT_bits256
168   | CmmT_bits512
169   | CmmT_float32
170   | CmmT_float64
171   | CmmT_gcptr
172   | CmmT_GlobalReg GlobalReg
173   | CmmT_Name      FastString
174   | CmmT_String    String
175   | CmmT_Int       Integer
176   | CmmT_Float     Rational
177   | CmmT_EOF
178   deriving (Show)
179
180 -- -----------------------------------------------------------------------------
181 -- Lexer actions
182
183 type Action = RealSrcSpan -> StringBuffer -> Int -> P (RealLocated CmmToken)
184
185 begin :: Int -> Action
186 begin code _span _str _len = do pushLexState code; lexToken
187
188 pop :: Action
189 pop _span _buf _len = do popLexState; lexToken
190
191 special_char :: Action
192 special_char span buf len = return (L span (CmmT_SpecChar (currentChar buf)))
193
194 kw :: CmmToken -> Action
195 kw tok span buf len = return (L span tok)
196
197 global_regN :: (Int -> GlobalReg) -> Action
198 global_regN con span buf len 
199   = return (L span (CmmT_GlobalReg (con (fromIntegral n))))
200   where buf' = stepOn buf
201         n = parseUnsignedInteger buf' (len-1) 10 octDecDigit
202
203 global_reg :: GlobalReg -> Action
204 global_reg r span buf len = return (L span (CmmT_GlobalReg r))
205
206 strtoken :: (String -> CmmToken) -> Action
207 strtoken f span buf len = 
208   return (L span $! (f $! lexemeToString buf len))
209
210 name :: Action
211 name span buf len = 
212   case lookupUFM reservedWordsFM fs of
213         Just tok -> return (L span tok)
214         Nothing  -> return (L span (CmmT_Name fs))
215   where
216         fs = lexemeToFastString buf len
217
218 reservedWordsFM = listToUFM $
219         map (\(x, y) -> (mkFastString x, y)) [
220         ( "CLOSURE",            CmmT_CLOSURE ),
221         ( "INFO_TABLE",         CmmT_INFO_TABLE ),
222         ( "INFO_TABLE_RET",     CmmT_INFO_TABLE_RET ),
223         ( "INFO_TABLE_FUN",     CmmT_INFO_TABLE_FUN ),
224         ( "INFO_TABLE_CONSTR",  CmmT_INFO_TABLE_CONSTR ),
225         ( "INFO_TABLE_SELECTOR",CmmT_INFO_TABLE_SELECTOR ),
226         ( "else",               CmmT_else ),
227         ( "export",             CmmT_export ),
228         ( "section",            CmmT_section ),
229         ( "align",              CmmT_align ),
230         ( "goto",               CmmT_goto ),
231         ( "if",                 CmmT_if ),
232         ( "call",               CmmT_call ),
233         ( "jump",               CmmT_jump ),
234         ( "foreign",            CmmT_foreign ),
235         ( "never",              CmmT_never ),
236         ( "prim",               CmmT_prim ),
237         ( "return",             CmmT_return ),
238         ( "returns",            CmmT_returns ),
239         ( "import",             CmmT_import ),
240         ( "switch",             CmmT_switch ),
241         ( "case",               CmmT_case ),
242         ( "default",            CmmT_default ),
243         ( "push",               CmmT_push ),
244         ( "bits8",              CmmT_bits8 ),
245         ( "bits16",             CmmT_bits16 ),
246         ( "bits32",             CmmT_bits32 ),
247         ( "bits64",             CmmT_bits64 ),
248         ( "bits128",            CmmT_bits128 ),
249         ( "bits256",            CmmT_bits256 ),
250         ( "bits512",            CmmT_bits512 ),
251         ( "float32",            CmmT_float32 ),
252         ( "float64",            CmmT_float64 ),
253 -- New forms
254         ( "b8",                 CmmT_bits8 ),
255         ( "b16",                CmmT_bits16 ),
256         ( "b32",                CmmT_bits32 ),
257         ( "b64",                CmmT_bits64 ),
258         ( "b128",               CmmT_bits128 ),
259         ( "b256",               CmmT_bits256 ),
260         ( "b512",               CmmT_bits512 ),
261         ( "f32",                CmmT_float32 ),
262         ( "f64",                CmmT_float64 ),
263         ( "gcptr",              CmmT_gcptr )
264         ]
265
266 tok_decimal span buf len 
267   = return (L span (CmmT_Int  $! parseUnsignedInteger buf len 10 octDecDigit))
268
269 tok_octal span buf len 
270   = return (L span (CmmT_Int  $! parseUnsignedInteger (offsetBytes 1 buf) (len-1) 8 octDecDigit))
271
272 tok_hexadecimal span buf len 
273   = return (L span (CmmT_Int  $! parseUnsignedInteger (offsetBytes 2 buf) (len-2) 16 hexDigit))
274
275 tok_float str = CmmT_Float $! readRational str
276
277 tok_string str = CmmT_String (read str)
278                  -- urk, not quite right, but it'll do for now
279
280 -- -----------------------------------------------------------------------------
281 -- Line pragmas
282
283 setLine :: Int -> Action
284 setLine code span buf len = do
285   let line = parseUnsignedInteger buf len 10 octDecDigit
286   setSrcLoc (mkRealSrcLoc (srcSpanFile span) (fromIntegral line - 1) 1)
287         -- subtract one: the line number refers to the *following* line
288   -- trace ("setLine "  ++ show line) $ do
289   popLexState
290   pushLexState code
291   lexToken
292
293 setFile :: Int -> Action
294 setFile code span buf len = do
295   let file = lexemeToFastString (stepOn buf) (len-2)
296   setSrcLoc (mkRealSrcLoc file (srcSpanEndLine span) (srcSpanEndCol span))
297   popLexState
298   pushLexState code
299   lexToken
300
301 -- -----------------------------------------------------------------------------
302 -- This is the top-level function: called from the parser each time a
303 -- new token is to be read from the input.
304
305 cmmlex :: (Located CmmToken -> P a) -> P a
306 cmmlex cont = do
307   (L span tok) <- lexToken
308   --trace ("token: " ++ show tok) $ do
309   cont (L (RealSrcSpan span) tok)
310
311 lexToken :: P (RealLocated CmmToken)
312 lexToken = do
313   inp@(loc1,buf) <- getInput
314   sc <- getLexState
315   case alexScan inp sc of
316     AlexEOF -> do let span = mkRealSrcSpan loc1 loc1
317                   setLastToken span 0
318                   return (L span CmmT_EOF)
319     AlexError (loc2,_) -> do failLocMsgP loc1 loc2 "lexical error"
320     AlexSkip inp2 _ -> do
321         setInput inp2
322         lexToken
323     AlexToken inp2@(end,buf2) len t -> do
324         setInput inp2
325         let span = mkRealSrcSpan loc1 end
326         span `seq` setLastToken span len
327         t span buf len
328
329 -- -----------------------------------------------------------------------------
330 -- Monad stuff
331
332 -- Stuff that Alex needs to know about our input type:
333 type AlexInput = (RealSrcLoc,StringBuffer)
334
335 alexInputPrevChar :: AlexInput -> Char
336 alexInputPrevChar (_,s) = prevChar s '\n'
337
338 -- backwards compatibility for Alex 2.x
339 alexGetChar :: AlexInput -> Maybe (Char,AlexInput)
340 alexGetChar inp = case alexGetByte inp of
341                     Nothing    -> Nothing
342                     Just (b,i) -> c `seq` Just (c,i)
343                        where c = chr $ fromIntegral b
344
345 alexGetByte :: AlexInput -> Maybe (Word8,AlexInput)
346 alexGetByte (loc,s)
347   | atEnd s   = Nothing
348   | otherwise = b `seq` loc' `seq` s' `seq` Just (b, (loc', s'))
349   where c    = currentChar s
350         b    = fromIntegral $ ord $ c
351         loc' = advanceSrcLoc loc c
352         s'   = stepOn s
353
354 getInput :: P AlexInput
355 getInput = P $ \s@PState{ loc=l, buffer=b } -> POk s (l,b)
356
357 setInput :: AlexInput -> P ()
358 setInput (l,b) = P $ \s -> POk s{ loc=l, buffer=b } ()
359 }