ae5cd6fc161b85e809666d35e5f7526b667ba43a
[ghc.git] / compiler / nativeGen / AsmCodeGen.lhs
1 -- -----------------------------------------------------------------------------
2 --
3 -- (c) The University of Glasgow 1993-2004
4 --
5 -- This is the top-level module in the native code generator.
6 --
7 -- -----------------------------------------------------------------------------
8
9 \begin{code}
10 {-# LANGUAGE GADTs #-}
11 module AsmCodeGen ( nativeCodeGen ) where
12
13 #include "HsVersions.h"
14 #include "nativeGen/NCG.h"
15
16
17 import qualified X86.CodeGen
18 import qualified X86.Regs
19 import qualified X86.Instr
20 import qualified X86.Ppr
21
22 import qualified SPARC.CodeGen
23 import qualified SPARC.Regs
24 import qualified SPARC.Instr
25 import qualified SPARC.Ppr
26 import qualified SPARC.ShortcutJump
27 import qualified SPARC.CodeGen.Expand
28
29 import qualified PPC.CodeGen
30 import qualified PPC.Cond
31 import qualified PPC.Regs
32 import qualified PPC.RegInfo
33 import qualified PPC.Instr
34 import qualified PPC.Ppr
35
36 import RegAlloc.Liveness
37 import qualified RegAlloc.Linear.Main           as Linear
38
39 import qualified GraphColor                     as Color
40 import qualified RegAlloc.Graph.Main            as Color
41 import qualified RegAlloc.Graph.Stats           as Color
42 import qualified RegAlloc.Graph.TrivColorable   as Color
43
44 import TargetReg
45 import Platform
46 import Config
47 import Instruction
48 import PIC
49 import Reg
50 import NCGMonad
51
52 import BlockId
53 import CgUtils          ( fixStgRegisters )
54 import Cmm
55 import CmmUtils
56 import Hoopl
57 import CmmOpt           ( cmmMachOpFold )
58 import PprCmm
59 import CLabel
60
61 import UniqFM
62 import UniqSupply
63 import DynFlags
64 import Util
65
66 import BasicTypes       ( Alignment )
67 import Digraph
68 import qualified Pretty
69 import BufWrite
70 import Outputable
71 import FastString
72 import UniqSet
73 import ErrUtils
74 import Module
75 import Stream (Stream)
76 import qualified Stream
77
78 -- DEBUGGING ONLY
79 --import OrdList
80
81 import Data.List
82 import Data.Maybe
83 import Control.Exception
84 import Control.Monad
85 import System.IO
86
87 {-
88 The native-code generator has machine-independent and
89 machine-dependent modules.
90
91 This module ("AsmCodeGen") is the top-level machine-independent
92 module.  Before entering machine-dependent land, we do some
93 machine-independent optimisations (defined below) on the
94 'CmmStmts's.
95
96 We convert to the machine-specific 'Instr' datatype with
97 'cmmCodeGen', assuming an infinite supply of registers.  We then use
98 a machine-independent register allocator ('regAlloc') to rejoin
99 reality.  Obviously, 'regAlloc' has machine-specific helper
100 functions (see about "RegAllocInfo" below).
101
102 Finally, we order the basic blocks of the function so as to minimise
103 the number of jumps between blocks, by utilising fallthrough wherever
104 possible.
105
106 The machine-dependent bits break down as follows:
107
108   * ["MachRegs"]  Everything about the target platform's machine
109     registers (and immediate operands, and addresses, which tend to
110     intermingle/interact with registers).
111
112   * ["MachInstrs"]  Includes the 'Instr' datatype (possibly should
113     have a module of its own), plus a miscellany of other things
114     (e.g., 'targetDoubleSize', 'smStablePtrTable', ...)
115
116   * ["MachCodeGen"]  is where 'Cmm' stuff turns into
117     machine instructions.
118
119   * ["PprMach"] 'pprInstr' turns an 'Instr' into text (well, really
120     a 'SDoc').
121
122   * ["RegAllocInfo"] In the register allocator, we manipulate
123     'MRegsState's, which are 'BitSet's, one bit per machine register.
124     When we want to say something about a specific machine register
125     (e.g., ``it gets clobbered by this instruction''), we set/unset
126     its bit.  Obviously, we do this 'BitSet' thing for efficiency
127     reasons.
128
129     The 'RegAllocInfo' module collects together the machine-specific
130     info needed to do register allocation.
131
132    * ["RegisterAlloc"] The (machine-independent) register allocator.
133 -}
134
135 -- -----------------------------------------------------------------------------
136 -- Top-level of the native codegen
137
138 data NcgImpl statics instr jumpDest = NcgImpl {
139     cmmTopCodeGen             :: RawCmmDecl -> NatM [NatCmmDecl statics instr],
140     generateJumpTableForInstr :: instr -> Maybe (NatCmmDecl statics instr),
141     getJumpDestBlockId        :: jumpDest -> Maybe BlockId,
142     canShortcut               :: instr -> Maybe jumpDest,
143     shortcutStatics           :: (BlockId -> Maybe jumpDest) -> statics -> statics,
144     shortcutJump              :: (BlockId -> Maybe jumpDest) -> instr -> instr,
145     pprNatCmmDecl             :: NatCmmDecl statics instr -> SDoc,
146     maxSpillSlots             :: Int,
147     allocatableRegs           :: [RealReg],
148     ncg_x86fp_kludge          :: [NatCmmDecl statics instr] -> [NatCmmDecl statics instr],
149     ncgExpandTop              :: [NatCmmDecl statics instr] -> [NatCmmDecl statics instr],
150     ncgAllocMoreStack         :: Int -> NatCmmDecl statics instr -> NatCmmDecl statics instr,
151     ncgMakeFarBranches        :: [NatBasicBlock instr] -> [NatBasicBlock instr]
152     }
153
154 --------------------
155 nativeCodeGen :: DynFlags -> Handle -> UniqSupply -> Stream IO RawCmmGroup ()
156               -> IO UniqSupply
157 nativeCodeGen dflags h us cmms
158  = let platform = targetPlatform dflags
159        nCG' :: (Outputable statics, Outputable instr, Instruction instr) => NcgImpl statics instr jumpDest -> IO UniqSupply
160        nCG' ncgImpl = nativeCodeGen' dflags ncgImpl h us cmms
161        x86NcgImpl = NcgImpl {
162                          cmmTopCodeGen             = X86.CodeGen.cmmTopCodeGen
163                         ,generateJumpTableForInstr = X86.CodeGen.generateJumpTableForInstr dflags
164                         ,getJumpDestBlockId        = X86.Instr.getJumpDestBlockId
165                         ,canShortcut               = X86.Instr.canShortcut
166                         ,shortcutStatics           = X86.Instr.shortcutStatics
167                         ,shortcutJump              = X86.Instr.shortcutJump
168                         ,pprNatCmmDecl              = X86.Ppr.pprNatCmmDecl
169                         ,maxSpillSlots             = X86.Instr.maxSpillSlots dflags
170                         ,allocatableRegs           = X86.Regs.allocatableRegs platform
171                         ,ncg_x86fp_kludge          = id
172                         ,ncgAllocMoreStack         = X86.Instr.allocMoreStack platform
173                         ,ncgExpandTop              = id
174                         ,ncgMakeFarBranches        = id
175                     }
176    in case platformArch platform of
177                  ArchX86    -> nCG' (x86NcgImpl { ncg_x86fp_kludge = map x86fp_kludge })
178                  ArchX86_64 -> nCG' x86NcgImpl
179                  ArchPPC ->
180                      nCG' $ NcgImpl {
181                           cmmTopCodeGen             = PPC.CodeGen.cmmTopCodeGen
182                          ,generateJumpTableForInstr = PPC.CodeGen.generateJumpTableForInstr dflags
183                          ,getJumpDestBlockId        = PPC.RegInfo.getJumpDestBlockId
184                          ,canShortcut               = PPC.RegInfo.canShortcut
185                          ,shortcutStatics           = PPC.RegInfo.shortcutStatics
186                          ,shortcutJump              = PPC.RegInfo.shortcutJump
187                          ,pprNatCmmDecl              = PPC.Ppr.pprNatCmmDecl
188                          ,maxSpillSlots             = PPC.Instr.maxSpillSlots dflags
189                          ,allocatableRegs           = PPC.Regs.allocatableRegs platform
190                          ,ncg_x86fp_kludge          = id
191                          ,ncgAllocMoreStack         = noAllocMoreStack
192                          ,ncgExpandTop              = id
193                          ,ncgMakeFarBranches        = makeFarBranches
194                      }
195                  ArchSPARC ->
196                      nCG' $ NcgImpl {
197                           cmmTopCodeGen             = SPARC.CodeGen.cmmTopCodeGen
198                          ,generateJumpTableForInstr = SPARC.CodeGen.generateJumpTableForInstr dflags
199                          ,getJumpDestBlockId        = SPARC.ShortcutJump.getJumpDestBlockId
200                          ,canShortcut               = SPARC.ShortcutJump.canShortcut
201                          ,shortcutStatics           = SPARC.ShortcutJump.shortcutStatics
202                          ,shortcutJump              = SPARC.ShortcutJump.shortcutJump
203                          ,pprNatCmmDecl              = SPARC.Ppr.pprNatCmmDecl
204                          ,maxSpillSlots             = SPARC.Instr.maxSpillSlots dflags
205                          ,allocatableRegs           = SPARC.Regs.allocatableRegs
206                          ,ncg_x86fp_kludge          = id
207                          ,ncgAllocMoreStack         = noAllocMoreStack
208                          ,ncgExpandTop              = map SPARC.CodeGen.Expand.expandTop
209                          ,ncgMakeFarBranches        = id
210                      }
211                  ArchARM _ _ _ ->
212                      panic "nativeCodeGen: No NCG for ARM"
213                  ArchPPC_64 ->
214                      panic "nativeCodeGen: No NCG for PPC 64"
215                  ArchAlpha ->
216                      panic "nativeCodeGen: No NCG for Alpha"
217                  ArchMipseb ->
218                      panic "nativeCodeGen: No NCG for mipseb"
219                  ArchMipsel ->
220                      panic "nativeCodeGen: No NCG for mipsel"
221                  ArchUnknown ->
222                      panic "nativeCodeGen: No NCG for unknown arch"
223
224
225 --
226 -- Allocating more stack space for spilling is currently only
227 -- supported for the linear register allocator on x86/x86_64, the rest
228 -- default to the panic below.  To support allocating extra stack on
229 -- more platforms provide a definition of ncgAllocMoreStack.
230 --
231 noAllocMoreStack :: Int -> NatCmmDecl statics instr -> NatCmmDecl statics instr
232 noAllocMoreStack amount _
233   = panic $   "Register allocator: out of stack slots (need " ++ show amount ++ ")\n"
234         ++  "   If you are trying to compile SHA1.hs from the crypto library then this\n"
235         ++  "   is a known limitation in the linear allocator.\n"
236         ++  "\n"
237         ++  "   Try enabling the graph colouring allocator with -fregs-graph instead."
238         ++  "   You can still file a bug report if you like.\n"
239
240
241 type NativeGenState statics instr = (BufHandle, NativeGenAcc statics instr)
242 type NativeGenAcc statics instr
243         = ([[CLabel]],
244            [([NatCmmDecl statics instr],
245              Maybe [Color.RegAllocStats statics instr],
246              Maybe [Linear.RegAllocStats])])
247
248 nativeCodeGen' :: (Outputable statics, Outputable instr, Instruction instr)
249                => DynFlags
250                -> NcgImpl statics instr jumpDest
251                -> Handle -> UniqSupply -> Stream IO RawCmmGroup () -> IO UniqSupply
252 nativeCodeGen' dflags ncgImpl h us cmms
253  = do
254         let platform = targetPlatform dflags
255             split_cmms  = Stream.map add_split cmms
256         -- BufHandle is a performance hack.  We could hide it inside
257         -- Pretty if it weren't for the fact that we do lots of little
258         -- printDocs here (in order to do codegen in constant space).
259         bufh <- newBufHandle h
260         ((imports, prof), us') <- cmmNativeGenStream dflags ncgImpl us split_cmms (bufh, ([], [])) 0
261         bFlush bufh
262
263         let (native, colorStats, linearStats)
264                 = unzip3 prof
265
266         -- dump native code
267         dumpIfSet_dyn dflags
268                 Opt_D_dump_asm "Asm code"
269                 (vcat $ map (pprNatCmmDecl ncgImpl) $ concat native)
270
271         -- dump global NCG stats for graph coloring allocator
272         (case concat $ catMaybes colorStats of
273           []    -> return ()
274           stats -> do
275                 -- build the global register conflict graph
276                 let graphGlobal
277                         = foldl Color.union Color.initGraph
278                         $ [ Color.raGraph stat
279                                 | stat@Color.RegAllocStatsStart{} <- stats]
280
281                 dumpSDoc dflags Opt_D_dump_asm_stats "NCG stats"
282                         $ Color.pprStats stats graphGlobal
283
284                 dumpIfSet_dyn dflags
285                         Opt_D_dump_asm_conflicts "Register conflict graph"
286                         $ Color.dotGraph
287                                 (targetRegDotColor platform)
288                                 (Color.trivColorable platform
289                                         (targetVirtualRegSqueeze platform)
290                                         (targetRealRegSqueeze platform))
291                         $ graphGlobal)
292
293
294         -- dump global NCG stats for linear allocator
295         (case concat $ catMaybes linearStats of
296                 []      -> return ()
297                 stats   -> dumpSDoc dflags Opt_D_dump_asm_stats "NCG stats"
298                                 $ Linear.pprStats (concat native) stats)
299
300         -- write out the imports
301         Pretty.printDoc Pretty.LeftMode (pprCols dflags) h
302                 $ withPprStyleDoc dflags (mkCodeStyle AsmStyle)
303                 $ makeImportsDoc dflags (concat imports)
304
305         return us'
306
307  where  add_split tops
308                 | gopt Opt_SplitObjs dflags = split_marker : tops
309                 | otherwise                 = tops
310
311         split_marker = CmmProc mapEmpty mkSplitMarkerLabel []
312                                (ofBlockList (panic "split_marker_entry") [])
313
314 cmmNativeGenStream :: (Outputable statics, Outputable instr, Instruction instr)
315               => DynFlags
316               -> NcgImpl statics instr jumpDest
317               -> UniqSupply
318               -> Stream IO RawCmmGroup ()
319               -> NativeGenState statics instr
320               -> Int
321               -> IO (NativeGenAcc statics instr, UniqSupply)
322
323 cmmNativeGenStream dflags ncgImpl us cmm_stream ngs@(h, nga) count
324  = do
325         r <- Stream.runStream cmm_stream
326         case r of
327           Left () ->
328             case nga of
329             (impAcc, profAcc) ->
330               return ((reverse impAcc, reverse profAcc), us)
331           Right (cmms, cmm_stream') -> do
332             (nga',us') <- cmmNativeGens dflags ncgImpl us cmms ngs count
333             cmmNativeGenStream dflags ncgImpl us' cmm_stream' (h, nga') count
334
335 -- | Do native code generation on all these cmms.
336 --
337 cmmNativeGens :: (Outputable statics, Outputable instr, Instruction instr)
338               => DynFlags
339               -> NcgImpl statics instr jumpDest
340               -> UniqSupply
341               -> [RawCmmDecl]
342               -> NativeGenState statics instr
343               -> Int
344               -> IO (NativeGenAcc statics instr, UniqSupply)
345
346 cmmNativeGens _ _ us [] (_, nga) _
347         = return (nga, us)
348
349 cmmNativeGens dflags ncgImpl us (cmm : cmms) (h, (impAcc, profAcc)) count
350  = do
351         (us', native, imports, colorStats, linearStats)
352                 <- {-# SCC "cmmNativeGen" #-} cmmNativeGen dflags ncgImpl us cmm count
353
354         {-# SCC "pprNativeCode" #-} Pretty.bufLeftRender h
355                 $ withPprStyleDoc dflags (mkCodeStyle AsmStyle)
356                 $ vcat $ map (pprNatCmmDecl ncgImpl) native
357
358         let !lsPprNative =
359                 if  dopt Opt_D_dump_asm       dflags
360                  || dopt Opt_D_dump_asm_stats dflags
361                         then native
362                         else []
363
364         let !count' = count + 1
365
366         -- force evaulation all this stuff to avoid space leaks
367         {-# SCC "seqString" #-} evaluate $ seqString (showSDoc dflags $ vcat $ map ppr imports)
368
369         cmmNativeGens dflags ncgImpl
370             us' cmms (h,
371                       ((imports : impAcc),
372                        ((lsPprNative, colorStats, linearStats) : profAcc)))
373                      count'
374
375  where  seqString []            = ()
376         seqString (x:xs)        = x `seq` seqString xs
377
378
379 -- | Complete native code generation phase for a single top-level chunk of Cmm.
380 --      Dumping the output of each stage along the way.
381 --      Global conflict graph and NGC stats
382 cmmNativeGen
383         :: (Outputable statics, Outputable instr, Instruction instr)
384     => DynFlags
385     -> NcgImpl statics instr jumpDest
386         -> UniqSupply
387         -> RawCmmDecl                                   -- ^ the cmm to generate code for
388         -> Int                                          -- ^ sequence number of this top thing
389         -> IO   ( UniqSupply
390                 , [NatCmmDecl statics instr]                -- native code
391                 , [CLabel]                                  -- things imported by this cmm
392                 , Maybe [Color.RegAllocStats statics instr] -- stats for the coloring register allocator
393                 , Maybe [Linear.RegAllocStats])             -- stats for the linear register allocators
394
395 cmmNativeGen dflags ncgImpl us cmm count
396  = do
397         let platform = targetPlatform dflags
398
399         -- rewrite assignments to global regs
400         let fixed_cmm =
401                 {-# SCC "fixStgRegisters" #-}
402                 fixStgRegisters dflags cmm
403
404         -- cmm to cmm optimisations
405         let (opt_cmm, imports) =
406                 {-# SCC "cmmToCmm" #-}
407                 cmmToCmm dflags fixed_cmm
408
409         dumpIfSet_dyn dflags
410                 Opt_D_dump_opt_cmm "Optimised Cmm"
411                 (pprCmmGroup [opt_cmm])
412
413         -- generate native code from cmm
414         let ((native, lastMinuteImports), usGen) =
415                 {-# SCC "genMachCode" #-}
416                 initUs us $ genMachCode dflags (cmmTopCodeGen ncgImpl) opt_cmm
417
418         dumpIfSet_dyn dflags
419                 Opt_D_dump_asm_native "Native code"
420                 (vcat $ map (pprNatCmmDecl ncgImpl) native)
421
422         -- tag instructions with register liveness information
423         let (withLiveness, usLive) =
424                 {-# SCC "regLiveness" #-}
425                 initUs usGen
426                         $ mapM (regLiveness platform)
427                         $ map natCmmTopToLive native
428
429         dumpIfSet_dyn dflags
430                 Opt_D_dump_asm_liveness "Liveness annotations added"
431                 (vcat $ map ppr withLiveness)
432
433         -- allocate registers
434         (alloced, usAlloc, ppr_raStatsColor, ppr_raStatsLinear) <-
435          if ( gopt Opt_RegsGraph dflags
436            || gopt Opt_RegsIterative dflags)
437           then do
438                 -- the regs usable for allocation
439                 let (alloc_regs :: UniqFM (UniqSet RealReg))
440                         = foldr (\r -> plusUFM_C unionUniqSets
441                                         $ unitUFM (targetClassOfRealReg platform r) (unitUniqSet r))
442                                 emptyUFM
443                         $ allocatableRegs ncgImpl
444
445                 -- do the graph coloring register allocation
446                 let ((alloced, regAllocStats), usAlloc)
447                         = {-# SCC "RegAlloc" #-}
448                           initUs usLive
449                           $ Color.regAlloc
450                                 dflags
451                                 alloc_regs
452                                 (mkUniqSet [0 .. maxSpillSlots ncgImpl])
453                                 withLiveness
454
455                 -- dump out what happened during register allocation
456                 dumpIfSet_dyn dflags
457                         Opt_D_dump_asm_regalloc "Registers allocated"
458                         (vcat $ map (pprNatCmmDecl ncgImpl) alloced)
459
460                 dumpIfSet_dyn dflags
461                         Opt_D_dump_asm_regalloc_stages "Build/spill stages"
462                         (vcat   $ map (\(stage, stats)
463                                         -> text "# --------------------------"
464                                         $$ text "#  cmm " <> int count <> text " Stage " <> int stage
465                                         $$ ppr stats)
466                                 $ zip [0..] regAllocStats)
467
468                 let mPprStats =
469                         if dopt Opt_D_dump_asm_stats dflags
470                          then Just regAllocStats else Nothing
471
472                 -- force evaluation of the Maybe to avoid space leak
473                 mPprStats `seq` return ()
474
475                 return  ( alloced, usAlloc
476                         , mPprStats
477                         , Nothing)
478
479           else do
480                 -- do linear register allocation
481                 let reg_alloc proc = do
482                        (alloced, maybe_more_stack, ra_stats) <-
483                                Linear.regAlloc dflags proc
484                        case maybe_more_stack of
485                          Nothing -> return ( alloced, ra_stats )
486                          Just amount ->
487                            return ( ncgAllocMoreStack ncgImpl amount alloced
488                                   , ra_stats )
489
490                 let ((alloced, regAllocStats), usAlloc)
491                         = {-# SCC "RegAlloc" #-}
492                           initUs usLive
493                           $ liftM unzip
494                           $ mapM reg_alloc withLiveness
495
496                 dumpIfSet_dyn dflags
497                         Opt_D_dump_asm_regalloc "Registers allocated"
498                         (vcat $ map (pprNatCmmDecl ncgImpl) alloced)
499
500                 let mPprStats =
501                         if dopt Opt_D_dump_asm_stats dflags
502                          then Just (catMaybes regAllocStats) else Nothing
503
504                 -- force evaluation of the Maybe to avoid space leak
505                 mPprStats `seq` return ()
506
507                 return  ( alloced, usAlloc
508                         , Nothing
509                         , mPprStats)
510
511         ---- x86fp_kludge.  This pass inserts ffree instructions to clear
512         ---- the FPU stack on x86.  The x86 ABI requires that the FPU stack
513         ---- is clear, and library functions can return odd results if it
514         ---- isn't.
515         ----
516         ---- NB. must happen before shortcutBranches, because that
517         ---- generates JXX_GBLs which we can't fix up in x86fp_kludge.
518         let kludged = {-# SCC "x86fp_kludge" #-} ncg_x86fp_kludge ncgImpl alloced
519
520         ---- generate jump tables
521         let tabled      =
522                 {-# SCC "generateJumpTables" #-}
523                 generateJumpTables ncgImpl kludged
524
525         ---- shortcut branches
526         let shorted     =
527                 {-# SCC "shortcutBranches" #-}
528                 shortcutBranches dflags ncgImpl tabled
529
530         ---- sequence blocks
531         let sequenced   =
532                 {-# SCC "sequenceBlocks" #-}
533                 map (sequenceTop ncgImpl) shorted
534
535         ---- expansion of SPARC synthetic instrs
536         let expanded =
537                 {-# SCC "sparc_expand" #-}
538                 ncgExpandTop ncgImpl sequenced
539
540         dumpIfSet_dyn dflags
541                 Opt_D_dump_asm_expanded "Synthetic instructions expanded"
542                 (vcat $ map (pprNatCmmDecl ncgImpl) expanded)
543
544         return  ( usAlloc
545                 , expanded
546                 , lastMinuteImports ++ imports
547                 , ppr_raStatsColor
548                 , ppr_raStatsLinear)
549
550
551 x86fp_kludge :: NatCmmDecl (Alignment, CmmStatics) X86.Instr.Instr -> NatCmmDecl (Alignment, CmmStatics) X86.Instr.Instr
552 x86fp_kludge top@(CmmData _ _) = top
553 x86fp_kludge (CmmProc info lbl live (ListGraph code)) =
554         CmmProc info lbl live (ListGraph $ X86.Instr.i386_insert_ffrees code)
555
556
557 -- | Build a doc for all the imports.
558 --
559 makeImportsDoc :: DynFlags -> [CLabel] -> SDoc
560 makeImportsDoc dflags imports
561  = dyld_stubs imports
562             $$
563             -- On recent versions of Darwin, the linker supports
564             -- dead-stripping of code and data on a per-symbol basis.
565             -- There's a hack to make this work in PprMach.pprNatCmmDecl.
566             (if platformHasSubsectionsViaSymbols (targetPlatform dflags)
567              then text ".subsections_via_symbols"
568              else empty)
569             $$
570                 -- On recent GNU ELF systems one can mark an object file
571                 -- as not requiring an executable stack. If all objects
572                 -- linked into a program have this note then the program
573                 -- will not use an executable stack, which is good for
574                 -- security. GHC generated code does not need an executable
575                 -- stack so add the note in:
576             (if platformHasGnuNonexecStack (targetPlatform dflags)
577              then text ".section .note.GNU-stack,\"\",@progbits"
578              else empty)
579             $$
580                 -- And just because every other compiler does, lets stick in
581                 -- an identifier directive: .ident "GHC x.y.z"
582             (if platformHasIdentDirective (targetPlatform dflags)
583              then let compilerIdent = text "GHC" <+> text cProjectVersion
584                    in text ".ident" <+> doubleQuotes compilerIdent
585              else empty)
586
587  where
588         -- Generate "symbol stubs" for all external symbols that might
589         -- come from a dynamic library.
590         dyld_stubs :: [CLabel] -> SDoc
591 {-      dyld_stubs imps = vcat $ map pprDyldSymbolStub $
592                                     map head $ group $ sort imps-}
593
594         platform = targetPlatform dflags
595         arch = platformArch platform
596         os   = platformOS   platform
597
598         -- (Hack) sometimes two Labels pretty-print the same, but have
599         -- different uniques; so we compare their text versions...
600         dyld_stubs imps
601                 | needImportedSymbols dflags arch os
602                 = vcat $
603                         (pprGotDeclaration dflags arch os :) $
604                         map ( pprImportedSymbol dflags platform . fst . head) $
605                         groupBy (\(_,a) (_,b) -> a == b) $
606                         sortBy (\(_,a) (_,b) -> compare a b) $
607                         map doPpr $
608                         imps
609                 | otherwise
610                 = empty
611
612         doPpr lbl = (lbl, renderWithStyle dflags (pprCLabel platform lbl) astyle)
613         astyle = mkCodeStyle AsmStyle
614
615
616 -- -----------------------------------------------------------------------------
617 -- Sequencing the basic blocks
618
619 -- Cmm BasicBlocks are self-contained entities: they always end in a
620 -- jump, either non-local or to another basic block in the same proc.
621 -- In this phase, we attempt to place the basic blocks in a sequence
622 -- such that as many of the local jumps as possible turn into
623 -- fallthroughs.
624
625 sequenceTop
626         :: Instruction instr
627     => NcgImpl statics instr jumpDest -> NatCmmDecl statics instr -> NatCmmDecl statics instr
628
629 sequenceTop _       top@(CmmData _ _) = top
630 sequenceTop ncgImpl (CmmProc info lbl live (ListGraph blocks)) =
631   CmmProc info lbl live (ListGraph $ ncgMakeFarBranches ncgImpl $ sequenceBlocks info blocks)
632
633 -- The algorithm is very simple (and stupid): we make a graph out of
634 -- the blocks where there is an edge from one block to another iff the
635 -- first block ends by jumping to the second.  Then we topologically
636 -- sort this graph.  Then traverse the list: for each block, we first
637 -- output the block, then if it has an out edge, we move the
638 -- destination of the out edge to the front of the list, and continue.
639
640 -- FYI, the classic layout for basic blocks uses postorder DFS; this
641 -- algorithm is implemented in Hoopl.
642
643 sequenceBlocks
644         :: Instruction instr
645         => BlockEnv i
646         -> [NatBasicBlock instr]
647         -> [NatBasicBlock instr]
648
649 sequenceBlocks _ [] = []
650 sequenceBlocks infos (entry:blocks) =
651   seqBlocks infos (mkNode entry : reverse (flattenSCCs (sccBlocks blocks)))
652   -- the first block is the entry point ==> it must remain at the start.
653
654
655 sccBlocks
656         :: Instruction instr
657         => [NatBasicBlock instr]
658         -> [SCC ( NatBasicBlock instr
659                 , BlockId
660                 , [BlockId])]
661
662 sccBlocks blocks = stronglyConnCompFromEdgedVerticesR (map mkNode blocks)
663
664 -- we're only interested in the last instruction of
665 -- the block, and only if it has a single destination.
666 getOutEdges
667         :: Instruction instr
668         => [instr] -> [BlockId]
669
670 getOutEdges instrs
671         = case jumpDestsOfInstr (last instrs) of
672                 [one] -> [one]
673                 _many -> []
674
675 mkNode :: (Instruction t)
676        => GenBasicBlock t
677        -> (GenBasicBlock t, BlockId, [BlockId])
678 mkNode block@(BasicBlock id instrs) = (block, id, getOutEdges instrs)
679
680 seqBlocks :: BlockEnv i -> [(GenBasicBlock t1, BlockId, [BlockId])]
681                         -> [GenBasicBlock t1]
682 seqBlocks _ [] = []
683 seqBlocks infos ((block,_,[]) : rest)
684   = block : seqBlocks infos rest
685 seqBlocks infos ((block@(BasicBlock id instrs),_,[next]) : rest)
686   | can_fallthrough = BasicBlock id (init instrs) : seqBlocks infos rest'
687   | otherwise       = block : seqBlocks infos rest'
688   where
689         can_fallthrough = not (mapMember next infos) && can_reorder
690         (can_reorder, rest') = reorder next [] rest
691           -- TODO: we should do a better job for cycles; try to maximise the
692           -- fallthroughs within a loop.
693 seqBlocks _ _ = panic "AsmCodegen:seqBlocks"
694
695 reorder :: (Eq a) => a -> [(t, a, t1)] -> [(t, a, t1)] -> (Bool, [(t, a, t1)])
696 reorder  _ accum [] = (False, reverse accum)
697 reorder id accum (b@(block,id',out) : rest)
698   | id == id'  = (True, (block,id,out) : reverse accum ++ rest)
699   | otherwise  = reorder id (b:accum) rest
700
701
702 -- -----------------------------------------------------------------------------
703 -- Making far branches
704
705 -- Conditional branches on PowerPC are limited to +-32KB; if our Procs get too
706 -- big, we have to work around this limitation.
707
708 makeFarBranches
709         :: [NatBasicBlock PPC.Instr.Instr]
710         -> [NatBasicBlock PPC.Instr.Instr]
711 makeFarBranches blocks
712     | last blockAddresses < nearLimit = blocks
713     | otherwise = zipWith handleBlock blockAddresses blocks
714     where
715         blockAddresses = scanl (+) 0 $ map blockLen blocks
716         blockLen (BasicBlock _ instrs) = length instrs
717
718         handleBlock addr (BasicBlock id instrs)
719                 = BasicBlock id (zipWith makeFar [addr..] instrs)
720
721         makeFar _ (PPC.Instr.BCC PPC.Cond.ALWAYS tgt) = PPC.Instr.BCC PPC.Cond.ALWAYS tgt
722         makeFar addr (PPC.Instr.BCC cond tgt)
723             | abs (addr - targetAddr) >= nearLimit
724             = PPC.Instr.BCCFAR cond tgt
725             | otherwise
726             = PPC.Instr.BCC cond tgt
727             where Just targetAddr = lookupUFM blockAddressMap tgt
728         makeFar _ other            = other
729
730         nearLimit = 7000 -- 8192 instructions are allowed; let's keep some
731                          -- distance, as we have a few pseudo-insns that are
732                          -- pretty-printed as multiple instructions,
733                          -- and it's just not worth the effort to calculate
734                          -- things exactly
735
736         blockAddressMap = listToUFM $ zip (map blockId blocks) blockAddresses
737
738 -- -----------------------------------------------------------------------------
739 -- Generate jump tables
740
741 -- Analyzes all native code and generates data sections for all jump
742 -- table instructions.
743 generateJumpTables
744         :: NcgImpl statics instr jumpDest
745         -> [NatCmmDecl statics instr] -> [NatCmmDecl statics instr]
746 generateJumpTables ncgImpl xs = concatMap f xs
747     where f p@(CmmProc _ _ _ (ListGraph xs)) = p : concatMap g xs
748           f p = [p]
749           g (BasicBlock _ xs) = catMaybes (map (generateJumpTableForInstr ncgImpl) xs)
750
751 -- -----------------------------------------------------------------------------
752 -- Shortcut branches
753
754 shortcutBranches
755         :: DynFlags
756     -> NcgImpl statics instr jumpDest
757         -> [NatCmmDecl statics instr]
758         -> [NatCmmDecl statics instr]
759
760 shortcutBranches dflags ncgImpl tops
761   | optLevel dflags < 1 = tops    -- only with -O or higher
762   | otherwise           = map (apply_mapping ncgImpl mapping) tops'
763   where
764     (tops', mappings) = mapAndUnzip (build_mapping ncgImpl) tops
765     mapping = foldr plusUFM emptyUFM mappings
766
767 build_mapping :: NcgImpl statics instr jumpDest
768               -> GenCmmDecl d (BlockEnv t) (ListGraph instr)
769               -> (GenCmmDecl d (BlockEnv t) (ListGraph instr), UniqFM jumpDest)
770 build_mapping _ top@(CmmData _ _) = (top, emptyUFM)
771 build_mapping _ (CmmProc info lbl live (ListGraph []))
772   = (CmmProc info lbl live (ListGraph []), emptyUFM)
773 build_mapping ncgImpl (CmmProc info lbl live (ListGraph (head:blocks)))
774   = (CmmProc info lbl live (ListGraph (head:others)), mapping)
775         -- drop the shorted blocks, but don't ever drop the first one,
776         -- because it is pointed to by a global label.
777   where
778     -- find all the blocks that just consist of a jump that can be
779     -- shorted.
780     -- Don't completely eliminate loops here -- that can leave a dangling jump!
781     (_, shortcut_blocks, others) = foldl split (emptyBlockSet, [], []) blocks
782     split (s, shortcut_blocks, others) b@(BasicBlock id [insn])
783         | Just jd <- canShortcut ncgImpl insn,
784           Just dest <- getJumpDestBlockId ncgImpl jd,
785           not (has_info id),
786           (setMember dest s) || dest == id -- loop checks
787         = (s, shortcut_blocks, b : others)
788     split (s, shortcut_blocks, others) (BasicBlock id [insn])
789         | Just dest <- canShortcut ncgImpl insn,
790           not (has_info id)
791         = (setInsert id s, (id,dest) : shortcut_blocks, others)
792     split (s, shortcut_blocks, others) other = (s, shortcut_blocks, other : others)
793
794     -- do not eliminate blocks that have an info table
795     has_info l = mapMember l info
796
797     -- build a mapping from BlockId to JumpDest for shorting branches
798     mapping = foldl add emptyUFM shortcut_blocks
799     add ufm (id,dest) = addToUFM ufm id dest
800
801 apply_mapping :: NcgImpl statics instr jumpDest
802               -> UniqFM jumpDest
803               -> GenCmmDecl statics h (ListGraph instr)
804               -> GenCmmDecl statics h (ListGraph instr)
805 apply_mapping ncgImpl ufm (CmmData sec statics)
806   = CmmData sec (shortcutStatics ncgImpl (lookupUFM ufm) statics)
807 apply_mapping ncgImpl ufm (CmmProc info lbl live (ListGraph blocks))
808   = CmmProc info lbl live (ListGraph $ map short_bb blocks)
809   where
810     short_bb (BasicBlock id insns) = BasicBlock id $! map short_insn insns
811     short_insn i = shortcutJump ncgImpl (lookupUFM ufm) i
812                  -- shortcutJump should apply the mapping repeatedly,
813                  -- just in case we can short multiple branches.
814
815 -- -----------------------------------------------------------------------------
816 -- Instruction selection
817
818 -- Native code instruction selection for a chunk of stix code.  For
819 -- this part of the computation, we switch from the UniqSM monad to
820 -- the NatM monad.  The latter carries not only a Unique, but also an
821 -- Int denoting the current C stack pointer offset in the generated
822 -- code; this is needed for creating correct spill offsets on
823 -- architectures which don't offer, or for which it would be
824 -- prohibitively expensive to employ, a frame pointer register.  Viz,
825 -- x86.
826
827 -- The offset is measured in bytes, and indicates the difference
828 -- between the current (simulated) C stack-ptr and the value it was at
829 -- the beginning of the block.  For stacks which grow down, this value
830 -- should be either zero or negative.
831
832 -- Switching between the two monads whilst carrying along the same
833 -- Unique supply breaks abstraction.  Is that bad?
834
835 genMachCode
836         :: DynFlags
837         -> (RawCmmDecl -> NatM [NatCmmDecl statics instr])
838         -> RawCmmDecl
839         -> UniqSM
840                 ( [NatCmmDecl statics instr]
841                 , [CLabel])
842
843 genMachCode dflags cmmTopCodeGen cmm_top
844   = do  { initial_us <- getUs
845         ; let initial_st           = mkNatM_State initial_us 0 dflags
846               (new_tops, final_st) = initNat initial_st (cmmTopCodeGen cmm_top)
847               final_delta          = natm_delta final_st
848               final_imports        = natm_imports final_st
849         ; if   final_delta == 0
850           then return (new_tops, final_imports)
851           else pprPanic "genMachCode: nonzero final delta" (int final_delta)
852     }
853
854 -- -----------------------------------------------------------------------------
855 -- Generic Cmm optimiser
856
857 {-
858 Here we do:
859
860   (a) Constant folding
861   (c) Position independent code and dynamic linking
862         (i)  introduce the appropriate indirections
863              and position independent refs
864         (ii) compile a list of imported symbols
865   (d) Some arch-specific optimizations
866
867 (a) will be moving to the new Hoopl pipeline, however, (c) and
868 (d) are only needed by the native backend and will continue to live
869 here.
870
871 Ideas for other things we could do (put these in Hoopl please!):
872
873   - shortcut jumps-to-jumps
874   - simple CSE: if an expr is assigned to a temp, then replace later occs of
875     that expr with the temp, until the expr is no longer valid (can push through
876     temp assignments, and certain assigns to mem...)
877 -}
878
879 cmmToCmm :: DynFlags -> RawCmmDecl -> (RawCmmDecl, [CLabel])
880 cmmToCmm _ top@(CmmData _ _) = (top, [])
881 cmmToCmm dflags (CmmProc info lbl live graph) = runCmmOpt dflags $ do
882   blocks' <- mapM cmmBlockConFold (toBlockList graph)
883   return $ CmmProc info lbl live (ofBlockList (g_entry graph) blocks')
884
885 newtype CmmOptM a = CmmOptM (([CLabel], DynFlags) -> (# a, [CLabel] #))
886
887 instance Monad CmmOptM where
888   return x = CmmOptM $ \(imports, _) -> (# x,imports #)
889   (CmmOptM f) >>= g =
890     CmmOptM $ \(imports, dflags) ->
891                 case f (imports, dflags) of
892                   (# x, imports' #) ->
893                     case g x of
894                       CmmOptM g' -> g' (imports', dflags)
895
896 addImportCmmOpt :: CLabel -> CmmOptM ()
897 addImportCmmOpt lbl = CmmOptM $ \(imports, _dflags) -> (# (), lbl:imports #)
898
899 instance HasDynFlags CmmOptM where
900     getDynFlags = CmmOptM $ \(imports, dflags) -> (# dflags, imports #)
901
902 runCmmOpt :: DynFlags -> CmmOptM a -> (a, [CLabel])
903 runCmmOpt dflags (CmmOptM f) = case f ([], dflags) of
904                         (# result, imports #) -> (result, imports)
905
906 cmmBlockConFold :: CmmBlock -> CmmOptM CmmBlock
907 cmmBlockConFold block = do
908   let (entry, middle, last) = blockSplit block
909       stmts = blockToList middle
910   stmts' <- mapM cmmStmtConFold stmts
911   last' <- cmmStmtConFold last
912   return $ blockJoin entry (blockFromList stmts') last'
913
914 -- This does three optimizations, but they're very quick to check, so we don't
915 -- bother turning them off even when the Hoopl code is active.  Since
916 -- this is on the old Cmm representation, we can't reuse the code either:
917 --  * reg = reg      --> nop
918 --  * if 0 then jump --> nop
919 --  * if 1 then jump --> jump
920 -- We might be tempted to skip this step entirely of not Opt_PIC, but
921 -- there is some PowerPC code for the non-PIC case, which would also
922 -- have to be separated.
923 cmmStmtConFold :: CmmNode e x -> CmmOptM (CmmNode e x)
924 cmmStmtConFold stmt
925    = case stmt of
926         CmmAssign reg src
927            -> do src' <- cmmExprConFold DataReference src
928                  return $ case src' of
929                    CmmReg reg' | reg == reg' -> CmmComment (fsLit "nop")
930                    new_src -> CmmAssign reg new_src
931
932         CmmStore addr src
933            -> do addr' <- cmmExprConFold DataReference addr
934                  src'  <- cmmExprConFold DataReference src
935                  return $ CmmStore addr' src'
936
937         CmmCall { cml_target = addr }
938            -> do addr' <- cmmExprConFold JumpReference addr
939                  return $ stmt { cml_target = addr' }
940
941         CmmUnsafeForeignCall target regs args
942            -> do target' <- case target of
943                               ForeignTarget e conv -> do
944                                 e' <- cmmExprConFold CallReference e
945                                 return $ ForeignTarget e' conv
946                               PrimTarget _ ->
947                                 return target
948                  args' <- mapM (cmmExprConFold DataReference) args
949                  return $ CmmUnsafeForeignCall target' regs args'
950
951         CmmCondBranch test true false
952            -> do test' <- cmmExprConFold DataReference test
953                  return $ case test' of
954                    CmmLit (CmmInt 0 _) -> CmmBranch false
955                    CmmLit (CmmInt _ _) -> CmmBranch true
956                    _other -> CmmCondBranch test' true false
957
958         CmmSwitch expr ids
959            -> do expr' <- cmmExprConFold DataReference expr
960                  return $ CmmSwitch expr' ids
961
962         other
963            -> return other
964
965 cmmExprConFold :: ReferenceKind -> CmmExpr -> CmmOptM CmmExpr
966 cmmExprConFold referenceKind expr = do
967     dflags <- getDynFlags
968
969     -- With -O1 and greater, the cmmSink pass does constant-folding, so
970     -- we don't need to do it again here.
971     let expr' = if optLevel dflags >= 1
972                     then expr
973                     else cmmExprCon dflags expr
974
975     cmmExprNative referenceKind expr'
976
977 cmmExprCon :: DynFlags -> CmmExpr -> CmmExpr
978 cmmExprCon dflags (CmmLoad addr rep) = CmmLoad (cmmExprCon dflags addr) rep
979 cmmExprCon dflags (CmmMachOp mop args)
980     = cmmMachOpFold dflags mop (map (cmmExprCon dflags) args)
981 cmmExprCon _ other = other
982
983 -- handles both PIC and non-PIC cases... a very strange mixture
984 -- of things to do.
985 cmmExprNative :: ReferenceKind -> CmmExpr -> CmmOptM CmmExpr
986 cmmExprNative referenceKind expr = do
987      dflags <- getDynFlags
988      let platform = targetPlatform dflags
989          arch = platformArch platform
990      case expr of
991         CmmLoad addr rep
992            -> do addr' <- cmmExprNative DataReference addr
993                  return $ CmmLoad addr' rep
994
995         CmmMachOp mop args
996            -> do args' <- mapM (cmmExprNative DataReference) args
997                  return $ CmmMachOp mop args'
998
999         CmmLit (CmmBlock id)
1000            -> cmmExprNative referenceKind (CmmLit (CmmLabel (infoTblLbl id)))
1001            -- we must convert block Ids to CLabels here, because we
1002            -- might have to do the PIC transformation.  Hence we must
1003            -- not modify BlockIds beyond this point.
1004
1005         CmmLit (CmmLabel lbl)
1006            -> do
1007                 cmmMakeDynamicReference dflags addImportCmmOpt referenceKind lbl
1008         CmmLit (CmmLabelOff lbl off)
1009            -> do
1010                  dynRef <- cmmMakeDynamicReference dflags addImportCmmOpt referenceKind lbl
1011                  -- need to optimize here, since it's late
1012                  return $ cmmMachOpFold dflags (MO_Add (wordWidth dflags)) [
1013                      dynRef,
1014                      (CmmLit $ CmmInt (fromIntegral off) (wordWidth dflags))
1015                    ]
1016
1017         -- On powerpc (non-PIC), it's easier to jump directly to a label than
1018         -- to use the register table, so we replace these registers
1019         -- with the corresponding labels:
1020         CmmReg (CmmGlobal EagerBlackholeInfo)
1021           | arch == ArchPPC && not (gopt Opt_PIC dflags)
1022           -> cmmExprNative referenceKind $
1023              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_EAGER_BLACKHOLE_info")))
1024         CmmReg (CmmGlobal GCEnter1)
1025           | arch == ArchPPC && not (gopt Opt_PIC dflags)
1026           -> cmmExprNative referenceKind $
1027              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_gc_enter_1")))
1028         CmmReg (CmmGlobal GCFun)
1029           | arch == ArchPPC && not (gopt Opt_PIC dflags)
1030           -> cmmExprNative referenceKind $
1031              CmmLit (CmmLabel (mkCmmCodeLabel rtsPackageId (fsLit "__stg_gc_fun")))
1032
1033         other
1034            -> return other
1035
1036 \end{code}
1037