Trailing whitespaces
[ghc.git] / libraries / base / GHC / List.lhs
1 \begin{code}
2 {-# LANGUAGE Trustworthy #-}
3 {-# LANGUAGE CPP, NoImplicitPrelude, MagicHash #-}
4 {-# OPTIONS_HADDOCK hide #-}
5
6 -----------------------------------------------------------------------------
7 -- |
8 -- Module      :  GHC.List
9 -- Copyright   :  (c) The University of Glasgow 1994-2002
10 -- License     :  see libraries/base/LICENSE
11 --
12 -- Maintainer  :  cvs-ghc@haskell.org
13 -- Stability   :  internal
14 -- Portability :  non-portable (GHC Extensions)
15 --
16 -- The List data type and its operations
17 --
18 -----------------------------------------------------------------------------
19
20 -- #hide
21 module GHC.List (
22    -- [] (..),          -- built-in syntax; can't be used in export list
23
24    map, (++), filter, concat,
25    head, last, tail, init, null, length, (!!),
26    foldl, scanl, scanl1, foldr, foldr1, scanr, scanr1,
27    iterate, repeat, replicate, cycle,
28    take, drop, splitAt, takeWhile, dropWhile, span, break,
29    reverse, and, or,
30    any, all, elem, notElem, lookup,
31    concatMap,
32    zip, zip3, zipWith, zipWith3, unzip, unzip3,
33    errorEmptyList,
34
35 #ifndef USE_REPORT_PRELUDE
36    -- non-standard, but hidden when creating the Prelude
37    -- export list.
38    takeUInt_append
39 #endif
40
41  ) where
42
43 import Data.Maybe
44 import GHC.Base
45
46 infixl 9  !!
47 infix  4 `elem`, `notElem`
48 \end{code}
49
50 %*********************************************************
51 %*                                                      *
52 \subsection{List-manipulation functions}
53 %*                                                      *
54 %*********************************************************
55
56 \begin{code}
57 -- | Extract the first element of a list, which must be non-empty.
58 head                    :: [a] -> a
59 head (x:_)              =  x
60 head []                 =  badHead
61 {-# NOINLINE [1] head #-}
62
63 badHead :: a
64 badHead = errorEmptyList "head"
65
66 -- This rule is useful in cases like
67 --      head [y | (x,y) <- ps, x==t]
68 {-# RULES
69 "head/build"    forall (g::forall b.(a->b->b)->b->b) .
70                 head (build g) = g (\x _ -> x) badHead
71 "head/augment"  forall xs (g::forall b. (a->b->b) -> b -> b) .
72                 head (augment g xs) = g (\x _ -> x) (head xs)
73  #-}
74
75 -- | Extract the elements after the head of a list, which must be non-empty.
76 tail                    :: [a] -> [a]
77 tail (_:xs)             =  xs
78 tail []                 =  errorEmptyList "tail"
79
80 -- | Extract the last element of a list, which must be finite and non-empty.
81 last                    :: [a] -> a
82 #ifdef USE_REPORT_PRELUDE
83 last [x]                =  x
84 last (_:xs)             =  last xs
85 last []                 =  errorEmptyList "last"
86 #else
87 -- eliminate repeated cases
88 last []                 =  errorEmptyList "last"
89 last (x:xs)             =  last' x xs
90   where last' y []     = y
91         last' _ (y:ys) = last' y ys
92 #endif
93
94 -- | Return all the elements of a list except the last one.
95 -- The list must be non-empty.
96 init                    :: [a] -> [a]
97 #ifdef USE_REPORT_PRELUDE
98 init [x]                =  []
99 init (x:xs)             =  x : init xs
100 init []                 =  errorEmptyList "init"
101 #else
102 -- eliminate repeated cases
103 init []                 =  errorEmptyList "init"
104 init (x:xs)             =  init' x xs
105   where init' _ []     = []
106         init' y (z:zs) = y : init' z zs
107 #endif
108
109 -- | Test whether a list is empty.
110 null                    :: [a] -> Bool
111 null []                 =  True
112 null (_:_)              =  False
113
114 -- | /O(n)/. 'length' returns the length of a finite list as an 'Int'.
115 -- It is an instance of the more general 'Data.List.genericLength',
116 -- the result type of which may be any kind of number.
117 {-# NOINLINE [1] length #-}
118 length                  :: [a] -> Int
119 length l                =  lenAcc l 0#
120
121 lenAcc :: [a] -> Int# -> Int
122 lenAcc []     a# = I# a#
123 lenAcc (_:xs) a# = lenAcc xs (a# +# 1#)
124
125 incLen :: a -> (Int# -> Int) -> Int# -> Int
126 incLen _ g x = g (x +# 1#)
127
128 -- These rules make length into a good consumer
129 -- Note that we use a higher-order-style use of foldr, so that
130 -- the accumulating parameter can be evaluated strictly
131 -- See Trac #876 for what goes wrong otherwise
132 {-# RULES
133 "length"     [~1] forall xs. length xs = foldr incLen I# xs 0#
134 "lengthList" [1]  foldr incLen I# = lenAcc
135  #-}
136
137 -- | 'filter', applied to a predicate and a list, returns the list of
138 -- those elements that satisfy the predicate; i.e.,
139 --
140 -- > filter p xs = [ x | x <- xs, p x]
141
142 {-# NOINLINE [1] filter #-}
143 filter :: (a -> Bool) -> [a] -> [a]
144 filter _pred []    = []
145 filter pred (x:xs)
146   | pred x         = x : filter pred xs
147   | otherwise      = filter pred xs
148
149 {-# NOINLINE [0] filterFB #-}
150 filterFB :: (a -> b -> b) -> (a -> Bool) -> a -> b -> b
151 filterFB c p x r | p x       = x `c` r
152                  | otherwise = r
153
154 {-# RULES
155 "filter"     [~1] forall p xs.  filter p xs = build (\c n -> foldr (filterFB c p) n xs)
156 "filterList" [1]  forall p.     foldr (filterFB (:) p) [] = filter p
157 "filterFB"        forall c p q. filterFB (filterFB c p) q = filterFB c (\x -> q x && p x)
158  #-}
159
160 -- Note the filterFB rule, which has p and q the "wrong way round" in the RHS.
161 --     filterFB (filterFB c p) q a b
162 --   = if q a then filterFB c p a b else b
163 --   = if q a then (if p a then c a b else b) else b
164 --   = if q a && p a then c a b else b
165 --   = filterFB c (\x -> q x && p x) a b
166 -- I originally wrote (\x -> p x && q x), which is wrong, and actually
167 -- gave rise to a live bug report.  SLPJ.
168
169
170 -- | 'foldl', applied to a binary operator, a starting value (typically
171 -- the left-identity of the operator), and a list, reduces the list
172 -- using the binary operator, from left to right:
173 --
174 -- > foldl f z [x1, x2, ..., xn] == (...((z `f` x1) `f` x2) `f`...) `f` xn
175 --
176 -- The list must be finite.
177
178 -- We write foldl as a non-recursive thing, so that it
179 -- can be inlined, and then (often) strictness-analysed,
180 -- and hence the classic space leak on foldl (+) 0 xs
181
182 foldl        :: (b -> a -> b) -> b -> [a] -> b
183 foldl f z0 xs0 = lgo z0 xs0
184              where
185                 lgo z []     =  z
186                 lgo z (x:xs) = lgo (f z x) xs
187
188 -- | 'scanl' is similar to 'foldl', but returns a list of successive
189 -- reduced values from the left:
190 --
191 -- > scanl f z [x1, x2, ...] == [z, z `f` x1, (z `f` x1) `f` x2, ...]
192 --
193 -- Note that
194 --
195 -- > last (scanl f z xs) == foldl f z xs.
196
197 scanl                   :: (b -> a -> b) -> b -> [a] -> [b]
198 scanl f q ls            =  q : (case ls of
199                                 []   -> []
200                                 x:xs -> scanl f (f q x) xs)
201
202 -- | 'scanl1' is a variant of 'scanl' that has no starting value argument:
203 --
204 -- > scanl1 f [x1, x2, ...] == [x1, x1 `f` x2, ...]
205
206 scanl1                  :: (a -> a -> a) -> [a] -> [a]
207 scanl1 f (x:xs)         =  scanl f x xs
208 scanl1 _ []             =  []
209
210 -- foldr, foldr1, scanr, and scanr1 are the right-to-left duals of the
211 -- above functions.
212
213 -- | 'foldr1' is a variant of 'foldr' that has no starting value argument,
214 -- and thus must be applied to non-empty lists.
215
216 foldr1                  :: (a -> a -> a) -> [a] -> a
217 foldr1 _ [x]            =  x
218 foldr1 f (x:xs)         =  f x (foldr1 f xs)
219 foldr1 _ []             =  errorEmptyList "foldr1"
220
221 -- | 'scanr' is the right-to-left dual of 'scanl'.
222 -- Note that
223 --
224 -- > head (scanr f z xs) == foldr f z xs.
225
226 scanr                   :: (a -> b -> b) -> b -> [a] -> [b]
227 scanr _ q0 []           =  [q0]
228 scanr f q0 (x:xs)       =  f x q : qs
229                            where qs@(q:_) = scanr f q0 xs
230
231 -- | 'scanr1' is a variant of 'scanr' that has no starting value argument.
232
233 scanr1                  :: (a -> a -> a) -> [a] -> [a]
234 scanr1 _ []             =  []
235 scanr1 _ [x]            =  [x]
236 scanr1 f (x:xs)         =  f x q : qs
237                            where qs@(q:_) = scanr1 f xs
238
239 -- | 'iterate' @f x@ returns an infinite list of repeated applications
240 -- of @f@ to @x@:
241 --
242 -- > iterate f x == [x, f x, f (f x), ...]
243
244 {-# NOINLINE [1] iterate #-}
245 iterate :: (a -> a) -> a -> [a]
246 iterate f x =  x : iterate f (f x)
247
248 {-# NOINLINE [0] iterateFB #-}
249 iterateFB :: (a -> b -> b) -> (a -> a) -> a -> b
250 iterateFB c f x = x `c` iterateFB c f (f x)
251
252 {-# RULES
253 "iterate"    [~1] forall f x.   iterate f x = build (\c _n -> iterateFB c f x)
254 "iterateFB"  [1]                iterateFB (:) = iterate
255  #-}
256
257
258 -- | 'repeat' @x@ is an infinite list, with @x@ the value of every element.
259 repeat :: a -> [a]
260 {-# INLINE [0] repeat #-}
261 -- The pragma just gives the rules more chance to fire
262 repeat x = xs where xs = x : xs
263
264 {-# INLINE [0] repeatFB #-}     -- ditto
265 repeatFB :: (a -> b -> b) -> a -> b
266 repeatFB c x = xs where xs = x `c` xs
267
268
269 {-# RULES
270 "repeat"    [~1] forall x. repeat x = build (\c _n -> repeatFB c x)
271 "repeatFB"  [1]  repeatFB (:)       = repeat
272  #-}
273
274 -- | 'replicate' @n x@ is a list of length @n@ with @x@ the value of
275 -- every element.
276 -- It is an instance of the more general 'Data.List.genericReplicate',
277 -- in which @n@ may be of any integral type.
278 {-# INLINE replicate #-}
279 replicate               :: Int -> a -> [a]
280 replicate n x           =  take n (repeat x)
281
282 -- | 'cycle' ties a finite list into a circular one, or equivalently,
283 -- the infinite repetition of the original list.  It is the identity
284 -- on infinite lists.
285
286 cycle                   :: [a] -> [a]
287 cycle []                = error "Prelude.cycle: empty list"
288 cycle xs                = xs' where xs' = xs ++ xs'
289
290 -- | 'takeWhile', applied to a predicate @p@ and a list @xs@, returns the
291 -- longest prefix (possibly empty) of @xs@ of elements that satisfy @p@:
292 --
293 -- > takeWhile (< 3) [1,2,3,4,1,2,3,4] == [1,2]
294 -- > takeWhile (< 9) [1,2,3] == [1,2,3]
295 -- > takeWhile (< 0) [1,2,3] == []
296 --
297
298 takeWhile               :: (a -> Bool) -> [a] -> [a]
299 takeWhile _ []          =  []
300 takeWhile p (x:xs)
301             | p x       =  x : takeWhile p xs
302             | otherwise =  []
303
304 -- | 'dropWhile' @p xs@ returns the suffix remaining after 'takeWhile' @p xs@:
305 --
306 -- > dropWhile (< 3) [1,2,3,4,5,1,2,3] == [3,4,5,1,2,3]
307 -- > dropWhile (< 9) [1,2,3] == []
308 -- > dropWhile (< 0) [1,2,3] == [1,2,3]
309 --
310
311 dropWhile               :: (a -> Bool) -> [a] -> [a]
312 dropWhile _ []          =  []
313 dropWhile p xs@(x:xs')
314             | p x       =  dropWhile p xs'
315             | otherwise =  xs
316
317 -- | 'take' @n@, applied to a list @xs@, returns the prefix of @xs@
318 -- of length @n@, or @xs@ itself if @n > 'length' xs@:
319 --
320 -- > take 5 "Hello World!" == "Hello"
321 -- > take 3 [1,2,3,4,5] == [1,2,3]
322 -- > take 3 [1,2] == [1,2]
323 -- > take 3 [] == []
324 -- > take (-1) [1,2] == []
325 -- > take 0 [1,2] == []
326 --
327 -- It is an instance of the more general 'Data.List.genericTake',
328 -- in which @n@ may be of any integral type.
329 take                   :: Int -> [a] -> [a]
330
331 -- | 'drop' @n xs@ returns the suffix of @xs@
332 -- after the first @n@ elements, or @[]@ if @n > 'length' xs@:
333 --
334 -- > drop 6 "Hello World!" == "World!"
335 -- > drop 3 [1,2,3,4,5] == [4,5]
336 -- > drop 3 [1,2] == []
337 -- > drop 3 [] == []
338 -- > drop (-1) [1,2] == [1,2]
339 -- > drop 0 [1,2] == [1,2]
340 --
341 -- It is an instance of the more general 'Data.List.genericDrop',
342 -- in which @n@ may be of any integral type.
343 drop                   :: Int -> [a] -> [a]
344
345 -- | 'splitAt' @n xs@ returns a tuple where first element is @xs@ prefix of
346 -- length @n@ and second element is the remainder of the list:
347 --
348 -- > splitAt 6 "Hello World!" == ("Hello ","World!")
349 -- > splitAt 3 [1,2,3,4,5] == ([1,2,3],[4,5])
350 -- > splitAt 1 [1,2,3] == ([1],[2,3])
351 -- > splitAt 3 [1,2,3] == ([1,2,3],[])
352 -- > splitAt 4 [1,2,3] == ([1,2,3],[])
353 -- > splitAt 0 [1,2,3] == ([],[1,2,3])
354 -- > splitAt (-1) [1,2,3] == ([],[1,2,3])
355 --
356 -- It is equivalent to @('take' n xs, 'drop' n xs)@ when @n@ is not @_|_@
357 -- (@splitAt _|_ xs = _|_@).
358 -- 'splitAt' is an instance of the more general 'Data.List.genericSplitAt',
359 -- in which @n@ may be of any integral type.
360 splitAt                :: Int -> [a] -> ([a],[a])
361
362 #ifdef USE_REPORT_PRELUDE
363 take n _      | n <= 0 =  []
364 take _ []              =  []
365 take n (x:xs)          =  x : take (n-1) xs
366
367 drop n xs     | n <= 0 =  xs
368 drop _ []              =  []
369 drop n (_:xs)          =  drop (n-1) xs
370
371 splitAt n xs           =  (take n xs, drop n xs)
372
373 #else /* hack away */
374 {-# RULES
375 "take"     [~1] forall n xs . take n xs = takeFoldr n xs 
376 "takeList"  [1] forall n xs . foldr (takeFB (:) []) (takeConst []) xs n = takeUInt n xs
377  #-}
378
379 {-# INLINE takeFoldr #-}
380 takeFoldr :: Int -> [a] -> [a]
381 takeFoldr (I# n#) xs
382   = build (\c nil -> if n# <=# 0# then nil else
383                      foldr (takeFB c nil) (takeConst nil) xs n#)
384
385 {-# NOINLINE [0] takeConst #-}
386 -- just a version of const that doesn't get inlined too early, so we
387 -- can spot it in rules.  Also we need a type sig due to the unboxed Int#.
388 takeConst :: a -> Int# -> a
389 takeConst x _ = x
390
391 {-# NOINLINE [0] takeFB #-}
392 takeFB :: (a -> b -> b) -> b -> a -> (Int# -> b) -> Int# -> b
393 takeFB c n x xs m | m <=# 1#  = x `c` n
394                   | otherwise = x `c` xs (m -# 1#)
395
396 {-# INLINE [0] take #-}
397 take (I# n#) xs = takeUInt n# xs
398
399 -- The general code for take, below, checks n <= maxInt
400 -- No need to check for maxInt overflow when specialised
401 -- at type Int or Int# since the Int must be <= maxInt
402
403 takeUInt :: Int# -> [b] -> [b]
404 takeUInt n xs
405   | n >=# 0#  =  take_unsafe_UInt n xs
406   | otherwise =  []
407
408 take_unsafe_UInt :: Int# -> [b] -> [b]
409 take_unsafe_UInt 0#  _  = []
410 take_unsafe_UInt m   ls =
411   case ls of
412     []     -> []
413     (x:xs) -> x : take_unsafe_UInt (m -# 1#) xs
414
415 takeUInt_append :: Int# -> [b] -> [b] -> [b]
416 takeUInt_append n xs rs
417   | n >=# 0#  =  take_unsafe_UInt_append n xs rs
418   | otherwise =  []
419
420 take_unsafe_UInt_append :: Int# -> [b] -> [b] -> [b]
421 take_unsafe_UInt_append 0#  _ rs  = rs
422 take_unsafe_UInt_append m  ls rs  =
423   case ls of
424     []     -> rs
425     (x:xs) -> x : take_unsafe_UInt_append (m -# 1#) xs rs
426
427 drop (I# n#) ls
428   | n# <# 0#    = ls
429   | otherwise   = drop# n# ls
430     where
431         drop# :: Int# -> [a] -> [a]
432         drop# 0# xs      = xs
433         drop# _  xs@[]   = xs
434         drop# m# (_:xs)  = drop# (m# -# 1#) xs
435
436 splitAt (I# n#) ls
437   | n# <# 0#    = ([], ls)
438   | otherwise   = splitAt# n# ls
439     where
440         splitAt# :: Int# -> [a] -> ([a], [a])
441         splitAt# 0# xs     = ([], xs)
442         splitAt# _  xs@[]  = (xs, xs)
443         splitAt# m# (x:xs) = (x:xs', xs'')
444           where
445             (xs', xs'') = splitAt# (m# -# 1#) xs
446
447 #endif /* USE_REPORT_PRELUDE */
448
449 -- | 'span', applied to a predicate @p@ and a list @xs@, returns a tuple where
450 -- first element is longest prefix (possibly empty) of @xs@ of elements that
451 -- satisfy @p@ and second element is the remainder of the list:
452 --
453 -- > span (< 3) [1,2,3,4,1,2,3,4] == ([1,2],[3,4,1,2,3,4])
454 -- > span (< 9) [1,2,3] == ([1,2,3],[])
455 -- > span (< 0) [1,2,3] == ([],[1,2,3])
456 --
457 -- 'span' @p xs@ is equivalent to @('takeWhile' p xs, 'dropWhile' p xs)@
458
459 span                    :: (a -> Bool) -> [a] -> ([a],[a])
460 span _ xs@[]            =  (xs, xs)
461 span p xs@(x:xs')
462          | p x          =  let (ys,zs) = span p xs' in (x:ys,zs)
463          | otherwise    =  ([],xs)
464
465 -- | 'break', applied to a predicate @p@ and a list @xs@, returns a tuple where
466 -- first element is longest prefix (possibly empty) of @xs@ of elements that
467 -- /do not satisfy/ @p@ and second element is the remainder of the list:
468 --
469 -- > break (> 3) [1,2,3,4,1,2,3,4] == ([1,2,3],[4,1,2,3,4])
470 -- > break (< 9) [1,2,3] == ([],[1,2,3])
471 -- > break (> 9) [1,2,3] == ([1,2,3],[])
472 --
473 -- 'break' @p@ is equivalent to @'span' ('not' . p)@.
474
475 break                   :: (a -> Bool) -> [a] -> ([a],[a])
476 #ifdef USE_REPORT_PRELUDE
477 break p                 =  span (not . p)
478 #else
479 -- HBC version (stolen)
480 break _ xs@[]           =  (xs, xs)
481 break p xs@(x:xs')
482            | p x        =  ([],xs)
483            | otherwise  =  let (ys,zs) = break p xs' in (x:ys,zs)
484 #endif
485
486 -- | 'reverse' @xs@ returns the elements of @xs@ in reverse order.
487 -- @xs@ must be finite.
488 reverse                 :: [a] -> [a]
489 #ifdef USE_REPORT_PRELUDE
490 reverse                 =  foldl (flip (:)) []
491 #else
492 reverse l =  rev l []
493   where
494     rev []     a = a
495     rev (x:xs) a = rev xs (x:a)
496 #endif
497
498 -- | 'and' returns the conjunction of a Boolean list.  For the result to be
499 -- 'True', the list must be finite; 'False', however, results from a 'False'
500 -- value at a finite index of a finite or infinite list.
501 and                     :: [Bool] -> Bool
502
503 -- | 'or' returns the disjunction of a Boolean list.  For the result to be
504 -- 'False', the list must be finite; 'True', however, results from a 'True'
505 -- value at a finite index of a finite or infinite list.
506 or                      :: [Bool] -> Bool
507 #ifdef USE_REPORT_PRELUDE
508 and                     =  foldr (&&) True
509 or                      =  foldr (||) False
510 #else
511 and []          =  True
512 and (x:xs)      =  x && and xs
513 or []           =  False
514 or (x:xs)       =  x || or xs
515
516 {-# NOINLINE [1] and #-}
517 {-# NOINLINE [1] or #-}
518
519 {-# RULES
520 "and/build"     forall (g::forall b.(Bool->b->b)->b->b) .
521                 and (build g) = g (&&) True
522 "or/build"      forall (g::forall b.(Bool->b->b)->b->b) .
523                 or (build g) = g (||) False
524  #-}
525 #endif
526
527 -- | Applied to a predicate and a list, 'any' determines if any element
528 -- of the list satisfies the predicate.  For the result to be
529 -- 'False', the list must be finite; 'True', however, results from a 'True'
530 -- value for the predicate applied to an element at a finite index of a finite or infinite list.
531 any                     :: (a -> Bool) -> [a] -> Bool
532
533 -- | Applied to a predicate and a list, 'all' determines if all elements
534 -- of the list satisfy the predicate. For the result to be
535 -- 'True', the list must be finite; 'False', however, results from a 'False'
536 -- value for the predicate applied to an element at a finite index of a finite or infinite list.
537 all                     :: (a -> Bool) -> [a] -> Bool
538 #ifdef USE_REPORT_PRELUDE
539 any p                   =  or . map p
540 all p                   =  and . map p
541 #else
542 any _ []        = False
543 any p (x:xs)    = p x || any p xs
544
545 all _ []        =  True
546 all p (x:xs)    =  p x && all p xs
547
548 {-# NOINLINE [1] any #-}
549 {-# NOINLINE [1] all #-}
550
551 {-# RULES
552 "any/build"     forall p (g::forall b.(a->b->b)->b->b) .
553                 any p (build g) = g ((||) . p) False
554 "all/build"     forall p (g::forall b.(a->b->b)->b->b) .
555                 all p (build g) = g ((&&) . p) True
556  #-}
557 #endif
558
559 -- | 'elem' is the list membership predicate, usually written in infix form,
560 -- e.g., @x \`elem\` xs@.  For the result to be
561 -- 'False', the list must be finite; 'True', however, results from an element equal to @x@ found at a finite index of a finite or infinite list.
562 elem                    :: (Eq a) => a -> [a] -> Bool
563
564 -- | 'notElem' is the negation of 'elem'.
565 notElem                 :: (Eq a) => a -> [a] -> Bool
566 #ifdef USE_REPORT_PRELUDE
567 elem x                  =  any (== x)
568 notElem x               =  all (/= x)
569 #else
570 elem _ []       = False
571 elem x (y:ys)   = x==y || elem x ys
572
573 notElem _ []    =  True
574 notElem x (y:ys)=  x /= y && notElem x ys
575 #endif
576
577 -- | 'lookup' @key assocs@ looks up a key in an association list.
578 lookup                  :: (Eq a) => a -> [(a,b)] -> Maybe b
579 lookup _key []          =  Nothing
580 lookup  key ((x,y):xys)
581     | key == x          =  Just y
582     | otherwise         =  lookup key xys
583
584 -- | Map a function over a list and concatenate the results.
585 concatMap               :: (a -> [b]) -> [a] -> [b]
586 concatMap f             =  foldr ((++) . f) []
587
588 -- | Concatenate a list of lists.
589 concat :: [[a]] -> [a]
590 concat = foldr (++) []
591
592 {-# NOINLINE [1] concat #-}
593
594 {-# RULES
595   "concat" forall xs. concat xs = build (\c n -> foldr (\x y -> foldr c y x) n xs)
596 -- We don't bother to turn non-fusible applications of concat back into concat
597  #-}
598
599 \end{code}
600
601
602 \begin{code}
603 -- | List index (subscript) operator, starting from 0.
604 -- It is an instance of the more general 'Data.List.genericIndex',
605 -- which takes an index of any integral type.
606 (!!)                    :: [a] -> Int -> a
607 #ifdef USE_REPORT_PRELUDE
608 xs     !! n | n < 0 =  error "Prelude.!!: negative index"
609 []     !! _         =  error "Prelude.!!: index too large"
610 (x:_)  !! 0         =  x
611 (_:xs) !! n         =  xs !! (n-1)
612 #else
613 -- HBC version (stolen), then unboxified
614 -- The semantics is not quite the same for error conditions
615 -- in the more efficient version.
616 --
617 xs !! (I# n0) | n0 <# 0#   =  error "Prelude.(!!): negative index\n"
618                | otherwise =  sub xs n0
619                          where
620                             sub :: [a] -> Int# -> a
621                             sub []     _ = error "Prelude.(!!): index too large\n"
622                             sub (y:ys) n = if n ==# 0#
623                                            then y
624                                            else sub ys (n -# 1#)
625 #endif
626 \end{code}
627
628
629 %*********************************************************
630 %*                                                      *
631 \subsection{The zip family}
632 %*                                                      *
633 %*********************************************************
634
635 \begin{code}
636 foldr2 :: (a -> b -> c -> c) -> c -> [a] -> [b] -> c
637 foldr2 _k z []    _ys    = z
638 foldr2 _k z _xs   []     = z
639 foldr2 k z (x:xs) (y:ys) = k x y (foldr2 k z xs ys)
640
641 {-# NOINLINE [1] foldr2 #-}
642
643 foldr2_left :: (a -> b -> c -> d) -> d -> a -> ([b] -> c) -> [b] -> d
644 foldr2_left _k  z _x _r []     = z
645 foldr2_left  k _z  x  r (y:ys) = k x y (r ys)
646
647 foldr2_right :: (a -> b -> c -> d) -> d -> b -> ([a] -> c) -> [a] -> d
648 foldr2_right _k z  _y _r []     = z
649 foldr2_right  k _z  y  r (x:xs) = k x y (r xs)
650
651 -- foldr2 k z xs ys = foldr (foldr2_left k z)  (\_ -> z) xs ys
652 -- foldr2 k z xs ys = foldr (foldr2_right k z) (\_ -> z) ys xs
653 {-# RULES
654 "foldr2/left"   forall k z ys (g::forall b.(a->b->b)->b->b) .
655                   foldr2 k z (build g) ys = g (foldr2_left  k z) (\_ -> z) ys
656
657 "foldr2/right"  forall k z xs (g::forall b.(a->b->b)->b->b) .
658                   foldr2 k z xs (build g) = g (foldr2_right k z) (\_ -> z) xs
659  #-}
660 \end{code}
661
662 The foldr2/right rule isn't exactly right, because it changes
663 the strictness of foldr2 (and thereby zip)
664
665 E.g. main = print (null (zip nonobviousNil (build undefined)))
666           where   nonobviousNil = f 3
667                   f n = if n == 0 then [] else f (n-1)
668
669 I'm going to leave it though.
670
671
672 Zips for larger tuples are in the List module.
673
674 \begin{code}
675 ----------------------------------------------
676 -- | 'zip' takes two lists and returns a list of corresponding pairs.
677 -- If one input list is short, excess elements of the longer list are
678 -- discarded.
679 {-# NOINLINE [1] zip #-}
680 zip :: [a] -> [b] -> [(a,b)]
681 zip (a:as) (b:bs) = (a,b) : zip as bs
682 zip _      _      = []
683
684 {-# INLINE [0] zipFB #-}
685 zipFB :: ((a, b) -> c -> d) -> a -> b -> c -> d
686 zipFB c = \x y r -> (x,y) `c` r
687
688 {-# RULES
689 "zip"      [~1] forall xs ys. zip xs ys = build (\c n -> foldr2 (zipFB c) n xs ys)
690 "zipList"  [1]  foldr2 (zipFB (:)) []   = zip
691  #-}
692 \end{code}
693
694 \begin{code}
695 ----------------------------------------------
696 -- | 'zip3' takes three lists and returns a list of triples, analogous to
697 -- 'zip'.
698 zip3 :: [a] -> [b] -> [c] -> [(a,b,c)]
699 -- Specification
700 -- zip3 =  zipWith3 (,,)
701 zip3 (a:as) (b:bs) (c:cs) = (a,b,c) : zip3 as bs cs
702 zip3 _      _      _      = []
703 \end{code}
704
705
706 -- The zipWith family generalises the zip family by zipping with the
707 -- function given as the first argument, instead of a tupling function.
708
709 \begin{code}
710 ----------------------------------------------
711 -- | 'zipWith' generalises 'zip' by zipping with the function given
712 -- as the first argument, instead of a tupling function.
713 -- For example, @'zipWith' (+)@ is applied to two lists to produce the
714 -- list of corresponding sums.
715 {-# NOINLINE [1] zipWith #-}
716 zipWith :: (a->b->c) -> [a]->[b]->[c]
717 zipWith f (a:as) (b:bs) = f a b : zipWith f as bs
718 zipWith _ _      _      = []
719
720 -- zipWithFB must have arity 2 since it gets two arguments in the "zipWith"
721 -- rule; it might not get inlined otherwise
722 {-# INLINE [0] zipWithFB #-}
723 zipWithFB :: (a -> b -> c) -> (d -> e -> a) -> d -> e -> b -> c
724 zipWithFB c f = \x y r -> (x `f` y) `c` r
725
726 {-# RULES
727 "zipWith"       [~1] forall f xs ys.    zipWith f xs ys = build (\c n -> foldr2 (zipWithFB c f) n xs ys)
728 "zipWithList"   [1]  forall f.  foldr2 (zipWithFB (:) f) [] = zipWith f
729   #-}
730 \end{code}
731
732 \begin{code}
733 -- | The 'zipWith3' function takes a function which combines three
734 -- elements, as well as three lists and returns a list of their point-wise
735 -- combination, analogous to 'zipWith'.
736 zipWith3                :: (a->b->c->d) -> [a]->[b]->[c]->[d]
737 zipWith3 z (a:as) (b:bs) (c:cs)
738                         =  z a b c : zipWith3 z as bs cs
739 zipWith3 _ _ _ _        =  []
740
741 -- | 'unzip' transforms a list of pairs into a list of first components
742 -- and a list of second components.
743 unzip    :: [(a,b)] -> ([a],[b])
744 {-# INLINE unzip #-}
745 unzip    =  foldr (\(a,b) ~(as,bs) -> (a:as,b:bs)) ([],[])
746
747 -- | The 'unzip3' function takes a list of triples and returns three
748 -- lists, analogous to 'unzip'.
749 unzip3   :: [(a,b,c)] -> ([a],[b],[c])
750 {-# INLINE unzip3 #-}
751 unzip3   =  foldr (\(a,b,c) ~(as,bs,cs) -> (a:as,b:bs,c:cs))
752                   ([],[],[])
753 \end{code}
754
755
756 %*********************************************************
757 %*                                                      *
758 \subsection{Error code}
759 %*                                                      *
760 %*********************************************************
761
762 Common up near identical calls to `error' to reduce the number
763 constant strings created when compiled:
764
765 \begin{code}
766 errorEmptyList :: String -> a
767 errorEmptyList fun =
768   error (prel_list_str ++ fun ++ ": empty list")
769
770 prel_list_str :: String
771 prel_list_str = "Prelude."
772 \end{code}