configure: Look for objdump on OpenBSD and AIX
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.3], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl this makes sure `./configure --target=<cross-compile-target>`
37 dnl works as expected, since we're slightly modifying how Autoconf
38 dnl interprets build/host/target and how this interacts with $CC tests
39 test -n "$target_alias" && ac_tool_prefix=$target_alias-
40
41 dnl ----------------------------------------------------------
42 dnl ** Find unixy sort and find commands,
43 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
44
45 dnl ** Find find command (for Win32's benefit)
46 FP_PROG_FIND
47 FP_PROG_SORT
48
49 dnl ----------------------------------------------------------
50 FP_SETUP_PROJECT_VERSION
51
52 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
53 AC_SUBST([release], [1])
54
55 # First off, a distrib sanity check..
56 AC_CONFIG_SRCDIR([mk/config.mk.in])
57
58 dnl * We require autoconf version 2.60
59 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
60 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
61 dnl Using autoconf 2.59 started to give nonsense like this
62 dnl  #define SIZEOF_CHAR 0
63 dnl recently.
64 AC_PREREQ([2.60])
65
66 # -------------------------------------------------------------------------
67 # Prepare to generate the following header files
68 #
69 #
70 AC_CONFIG_HEADER(mk/config.h)
71
72 # No, semi-sadly, we don't do `--srcdir'...
73 if test x"$srcdir" != 'x.' ; then
74     echo "This configuration does not support the \`--srcdir' option.."
75     exit 1
76 fi
77
78 dnl --------------------------------------------------------------
79 dnl * Project specific configuration options
80 dnl --------------------------------------------------------------
81 dnl What follows is a bunch of options that can either be configured
82 dnl through command line options to the configure script or by
83 dnl supplying defns in the build tree's mk/build.mk. Having the option to
84 dnl use either is considered a Feature.
85
86 dnl ** What command to use to compile compiler sources ?
87 dnl --------------------------------------------------------------
88
89 AC_ARG_WITH([ghc],
90 [AC_HELP_STRING([--with-ghc=ARG],
91   [Use ARG as the path to GHC  [default=autodetect]])],
92   [WithGhc="$withval"],
93   [if test "$GHC" = ""; then
94     AC_PATH_PROG([GHC], [ghc])
95   fi
96   WithGhc="$GHC"])
97
98 dnl ** Tell the make system which OS we are using
99 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
100 AC_SUBST(OSTYPE)
101
102 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
103 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
104                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
105         EnableBootstrapWithDevelSnaphost=YES,
106         EnableBootstrapWithDevelSnaphost=NO
107 )
108
109 AC_ARG_ENABLE(tarballs-autodownload,
110 [AC_HELP_STRING([--enable-tarballs-autodownload],
111                 [Automatically download Windows distribution binaries if needed.])],
112         TarballsAutodownload=YES,
113         TarballsAutodownload=NO
114 )
115
116 AC_ARG_ENABLE(distro-toolchain,
117 [AC_HELP_STRING([--enable-distro-toolchain],
118                 [Do not use bundled Windows toolchain binaries.])],
119         EnableDistroToolchain=YES,
120         EnableDistroToolchain=NO
121 )
122
123 if test "$EnableDistroToolchain" = "YES"; then
124   TarballsAutodownload=NO
125 fi
126
127 dnl CC_STAGE0 is like the "previous" variable CC (inherited by CC_STAGE[123])
128 dnl but instead used by stage0 for bootstrapping stage1
129 AC_ARG_VAR(CC_STAGE0, [C compiler command (bootstrap)])
130
131 if test "$WithGhc" != ""; then
132   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
133
134   if test "$GhcMajVersion" = "unknown" || test "$GhcMinVersion" = "unknown"; then
135      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
136   fi
137
138   AC_SUBST(GhcVersion)dnl
139   AC_SUBST(GhcMajVersion)dnl
140   AC_SUBST(GhcMinVersion)dnl
141   AC_SUBST(GhcPatchLevel)dnl
142   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
143   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
144
145   dnl infer CC_STAGE0 from `ghc --info` unless explicitly set by user
146   if test -z "$CC_STAGE0"; then
147     BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
148   fi
149
150   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
151   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
152   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
153   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
154 fi
155
156 dnl ** Must have GHC to build GHC
157 if test "$WithGhc" = ""
158 then
159     AC_MSG_ERROR([GHC is required.])
160 fi
161 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.10],
162     [AC_MSG_ERROR([GHC version 7.10 or later is required to compile GHC.])])
163
164 if test `expr $GhcMinVersion % 2` = "1"
165 then
166     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
167     then
168         AC_MSG_ERROR([
169      $WithGhc is a development snapshot of GHC, version $GhcVersion.
170      Bootstrapping using this version of GHC is not supported, and may not
171      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
172      or --with-ghc to specify a different GHC to use.])
173     fi
174 fi
175
176 GHC_PACKAGE_DB_FLAG=package-db
177 AC_SUBST(GHC_PACKAGE_DB_FLAG)
178
179 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.11],
180                     SUPPORTS_THIS_UNIT_ID=NO,
181                     SUPPORTS_THIS_UNIT_ID=YES)
182 AC_SUBST(SUPPORTS_THIS_UNIT_ID)
183
184 # GHC is passed to Cabal, so we need a native path
185 if test "${WithGhc}" != ""
186 then
187     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
188
189     if test "$ghc_host_os" = "mingw32"
190     then
191         if test "${OSTYPE}" = "msys"
192         then
193             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
194         else
195             # Canonicalise to <drive>:/path/to/ghc
196             WithGhc=`cygpath -m "${WithGhc}"`
197         fi
198         echo "GHC path canonicalised to: ${WithGhc}"
199     fi
200 fi
201 AC_SUBST([WithGhc])
202
203 dnl ** Without optimization some INLINE trickery fails for GHCi
204 SRC_CC_OPTS="-O"
205
206 dnl--------------------------------------------------------------------
207 dnl * Choose host(/target/build) platform
208 dnl--------------------------------------------------------------------
209 dnl If we aren't explicitly told what values to use with configure flags,
210 dnl we ask the bootstrapping compiler what platform it is for
211
212 if test "${WithGhc}" != ""
213 then
214         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
215         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
216         if test "$bootstrap_host" != "$bootstrap_target"
217         then
218                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
219         fi
220 fi
221
222 # We have to run these unconditionally, but we may discard their
223 # results in the following code
224 AC_CANONICAL_BUILD
225 AC_CANONICAL_HOST
226 AC_CANONICAL_TARGET
227
228 FPTOOLS_SET_PLATFORM_VARS
229
230 # Verify that the installed (bootstrap) GHC is capable of generating
231 # code for the requested build platform.
232 if test "$BuildPlatform" != "$bootstrap_target"
233 then
234     echo "This GHC (${WithGhc}) does not generate code for the build platform"
235     echo "   GHC target platform    : $bootstrap_target"
236     echo "   Desired build platform : $BuildPlatform"
237     exit 1
238 fi
239
240 # Testing if we shall enable shared libs support on Solaris.
241 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
242
243 SOLARIS_BROKEN_SHLD=NO
244
245 case $host in
246      i386-*-solaris2)
247      # here we go with the test
248      MINOR=`uname -r|cut -d '.' -f 2-`
249      if test "$MINOR" -lt "11"; then
250          SOLARIS_BROKEN_SHLD=YES
251      fi
252      ;;
253 esac
254
255 AC_SUBST(SOLARIS_BROKEN_SHLD)
256
257 dnl ** Do an unregisterised build?
258 dnl --------------------------------------------------------------
259 case "$TargetArch" in
260     i386|x86_64|powerpc|powerpc64|powerpc64le|arm|aarch64)
261         UnregisterisedDefault=NO
262         ;;
263     *)
264         UnregisterisedDefault=YES
265         ;;
266 esac
267 AC_ARG_ENABLE(unregisterised,
268 [AC_HELP_STRING([--enable-unregisterised],
269 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
270 [ if test x"$enableval" = x"yes"; then
271         Unregisterised=YES
272   else
273         Unregisterised=NO
274   fi
275 ],
276 [Unregisterised="$UnregisterisedDefault"]
277 )
278 AC_SUBST(Unregisterised)
279
280 dnl ** Does target have runtime linker support?
281 dnl --------------------------------------------------------------
282 case "$target" in
283     powerpc64-*|powerpc64le-*|powerpc-ibm-aix*)
284         HaskellHaveRTSLinker=NO
285         ;;
286     *)
287         HaskellHaveRTSLinker=YES
288         ;;
289 esac
290 AC_SUBST(HaskellHaveRTSLinker)
291
292 # Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
293 FP_FIND_ROOT
294
295 fail() {
296     echo >&2
297     echo "$1" >&2
298     exit 1
299 }
300
301
302 if test "$HostOS" = "mingw32"
303 then
304     # Find the mingw-w64 7z file to extract.
305     if test "$HostArch" = "i386"
306     then
307         mingw_arch="i686"
308         tarball_dest_dir="mingw-w64/x86"
309         tarball_mingw_dir="mingw32"
310     else
311         mingw_arch="x86_64"
312         tarball_dest_dir="mingw-w64/x86_64"
313         tarball_mingw_dir="mingw64"
314     fi
315 fi
316
317 set_up_tarballs() {
318     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
319     local action
320     if test "$TarballsAutodownload" = "NO"
321     then
322         action="verify"
323     else
324         action="download"
325     fi
326     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
327     case $? in
328         0)
329            rm missing-win32-tarballs
330            ;;
331         2)
332            echo
333            echo "Error:"
334            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
335            echo
336            echo "  * run configure with the --enable-tarballs-autodownload option"
337            echo
338            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
339            echo
340            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
341            echo "    them in the ghc-tarballs directory."
342            echo
343            exit 1
344            ;;
345         *)
346            echo
347            echo "Error fetching msys2 tarballs; see errors above."
348            exit 1
349            ;;
350     esac
351
352     # Extract all the tarballs in one go
353     if ! test -d inplace/mingw
354     then
355         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
356         rm -rf inplace/mingw
357         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
358         ( cd inplace &&
359         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
360         rm ".MTREE" &&
361         rm ".PKGINFO" &&
362         cd .. ) || fail "Error: Could not extract Windows toolchains."
363
364         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
365         touch inplace/mingw
366
367         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
368     fi
369 }
370
371 if test "$HostOS" = "mingw32" -a "$EnableDistroToolchain" = "NO"
372 then
373     test -d inplace || mkdir inplace
374
375     # NB. Download and extract the MingW-w64 distribution if required
376     set_up_tarballs
377
378     mingwbin="$hardtop/inplace/mingw/bin/"
379     CC="${mingwbin}gcc.exe"
380     LD="${mingwbin}ld.exe"
381     NM="${mingwbin}nm.exe"
382     RANLIB="${mingwbin}ranlib.exe"
383     OBJDUMP="${mingwbin}objdump.exe"
384     fp_prog_ar="${mingwbin}ar.exe"
385
386     # NB. Download the perl binaries if required
387     if ! test -d inplace/perl ||
388          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
389     then
390         AC_MSG_NOTICE([Making in-tree perl tree])
391         rm -rf inplace/perl
392         mkdir inplace/perl
393         (
394             cd inplace/perl &&
395             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
396         )
397         AC_MSG_NOTICE([In-tree perl tree created])
398     fi
399 fi
400
401 # We don't want to bundle a MinGW-w64 toolchain
402 # So we have to find these individual tools.
403 if test "$EnableDistroToolchain" = "YES"
404 then
405     # Ideally should use AC_CHECK_TARGET_TOOL but our triples
406     # are screwed up. Configure doesn't think they're ever equal and
407     # so never tried without the prefix.
408     AC_PATH_PROG([CC],[gcc], [clang])
409     AC_PATH_PROG([LD],[ld], [lld])
410     AC_PATH_PROG([NM],[nm])
411     AC_PATH_PROG([AR],[ar])
412     AC_PATH_PROG([RANLIB],[ranlib])
413     AC_PATH_PROG([OBJDUMP],[objdump])
414     AC_PATH_PROG([DllWrap],[dllwrap])
415     AC_PATH_PROG([Windres],[windres])
416
417     DllWrapCmd="$DllWrap"
418     WindresCmd="$Windres"
419
420     AC_SUBST([DllWrapCmd])
421     AC_SUBST([WindresCmd])
422 fi
423
424 FP_ICONV
425 FP_GMP
426 FP_CURSES
427
428 XCODE_VERSION()
429
430
431 dnl ** Building a cross compiler?
432 dnl --------------------------------------------------------------
433 CrossCompiling=NO
434 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
435 if test "$TargetPlatform" != "$HostPlatform" ; then
436     CrossCompiling=YES
437     cross_compiling=yes   # This tells configure that it can accept just 'target',
438                           # otherwise you get
439                           #   configure: error: cannot run C compiled programs.
440                           #   If you meant to cross compile, use `--host'.
441 fi
442 if test "$BuildPlatform" != "$HostPlatform" ; then
443    AC_MSG_ERROR([
444 You've selected:
445
446   BUILD:  $BuildPlatform   (the architecture we're building on)
447   HOST:   $HostPlatform    (the architecture the compiler we're building will execute on)
448   TARGET: $TargetPlatform  (the architecture the compiler we're building will produce code for)
449
450 BUILD must equal HOST; that is, we do not support building GHC itself
451 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
452 1 will be a cross-compiler, and stage 2 will be the cross-compiled
453 GHC.
454 ])
455 fi
456 # Despite its similarity in name to TargetPlatform, TargetPlatformFull is used
457 # in calls to subproject configure scripts and thus must be set to the autoconf
458 # triple, not the normalized GHC triple that TargetPlatform is set to.
459 #
460 # We use the non-canonicalized triple, target_alias, here since the subproject
461 # configure scripts will use this triple to construct the names of the toolchain
462 # executables. If we instead passed down the triple produced by
463 # AC_CANONICAL_TARGET then it may look for the target toolchain under the wrong
464 # name (this is a known problem in the case of the Android NDK, which has
465 # slightly odd triples).
466 #
467 # It may be better to just do away with the GHC triples altogether. This would
468 # all be taken care of for us if we configured the subprojects using
469 # AC_CONFIG_DIR, but unfortunately Cabal needs to be the one to do the
470 # configuration.
471 #
472 # We also use non-canonicalized triple when install stage1 crosscompiler
473 if test -z "${target_alias}"
474 then
475   # --target wasn't given; use result from AC_CANONICAL_TARGET
476   TargetPlatformFull="${target}"
477 else
478   TargetPlatformFull="${target_alias}"
479 fi
480 if test "$CrossCompiling" = "YES"
481 then
482   # Use value passed by user from --target=
483   CrossCompilePrefix="${TargetPlatformFull}-"
484 else
485   CrossCompilePrefix=""
486 fi
487 AC_SUBST(CrossCompiling)
488 AC_SUBST(CrossCompilePrefix)
489 AC_SUBST(TargetPlatformFull)
490 AC_SUBST(EnableDistroToolchain)
491
492 dnl ** Which gcc to use?
493 dnl --------------------------------------------------------------
494
495 AC_ARG_WITH([gcc],
496         AS_HELP_STRING([--with-gcc=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
497         AC_MSG_ERROR([--with-gcc=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
498
499 AC_ARG_WITH([clang],
500         AS_HELP_STRING([--with-clang=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
501         AC_MSG_ERROR([--with-clang=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
502
503 dnl detect compiler (prefer gcc over clang) and set $CC (unless CC already set),
504 dnl later CC is copied to CC_STAGE{1,2,3}
505 AC_PROG_CC([gcc clang])
506
507 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
508
509 dnl make extensions visible to allow feature-tests to detect them lateron
510 AC_USE_SYSTEM_EXTENSIONS
511
512 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
513 AC_PROG_CPP
514
515 # --with-hs-cpp/--with-hs-cpp-flags
516 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
517 AC_SUBST([HaskellCPPCmd])
518 AC_SUBST([HaskellCPPArgs])
519
520 FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
521 FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
522 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
523 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
524
525 dnl ** Which ld to use?
526 dnl --------------------------------------------------------------
527 FIND_LD([$target],[LdCmd])
528 AC_SUBST([LdCmd])
529
530 dnl ** Which nm to use?
531 dnl --------------------------------------------------------------
532 if test "$HostOS" != "mingw32"; then
533     AC_CHECK_TARGET_TOOL([NM], [nm])
534     if test "$NM" = ":"; then
535         AC_MSG_ERROR([cannot find nm in your PATH])
536     fi
537 fi
538 NmCmd="$NM"
539 AC_SUBST([NmCmd])
540
541 if test "$TargetOS_CPP" = "darwin"
542 then
543     AC_MSG_CHECKING(whether nm program is broken)
544     # Some versions of XCode ship a broken version of `nm`. Detect and work
545     # around this issue. See : https://ghc.haskell.org/trac/ghc/ticket/11744
546     nmver=$(${NM} --version | grep version | sed 's/ //g')
547     case "$nmver" in
548         LLVMversion7.3.0|LLVMversion7.3.1)
549             AC_MSG_RESULT(yes)
550             echo "The detected nm program is broken."
551             echo
552             echo "See: https://ghc.haskell.org/trac/ghc/ticket/11744"
553             echo
554             echo "Try re-running configure with:"
555             echo
556             echo '   NM=$(xcrun --find nm-classic) ./configure'
557             echo
558             exit 1
559             ;;
560         *)
561             AC_MSG_RESULT(no)
562             ;;
563         esac
564 fi
565
566 dnl ** Which objdump to use?
567 dnl --------------------------------------------------------------
568 dnl Note: we may not have objdump on OS X, and we only need it on
569 dnl Windows (for DLL checks), OpenBSD, and AIX
570 case $HostOS_CPP in
571   cygwin32|mingw32|openbsd|aix)
572     AC_CHECK_TARGET_TOOL([OBJDUMP], [objdump])
573     ;;
574 esac
575
576 ObjdumpCmd="$OBJDUMP"
577 AC_SUBST([ObjdumpCmd])
578
579 dnl ** Which ar to use?
580 dnl --------------------------------------------------------------
581 if test "$HostOS" != "mingw32"; then
582     AC_CHECK_TARGET_TOOL([AR], [ar])
583     if test "$AR" = ":"; then
584         AC_MSG_ERROR([cannot find ar in your PATH])
585     fi
586 fi
587 ArCmd="$AR"
588 fp_prog_ar="$AR"
589 AC_SUBST([ArCmd])
590
591 dnl ** Which ranlib to use?
592 dnl --------------------------------------------------------------
593 AC_PROG_RANLIB
594 if test "$RANLIB" = ":"; then
595     AC_MSG_ERROR([cannot find ranlib in your PATH])
596 fi
597 RanlibCmd="$RANLIB"
598 RANLIB="$RanlibCmd"
599
600 dnl ** which libtool to use?
601 dnl --------------------------------------------------------------
602 AC_CHECK_TARGET_TOOL([LIBTOOL], [libtool])
603 LibtoolCmd="$LIBTOOL"
604 LIBTOOL="$LibtoolCmd"
605
606 # Here is where we re-target which specific version of the LLVM
607 # tools we are looking for. In the past, GHC supported a number of
608 # versions of LLVM simultaneously, but that stopped working around
609 # 3.5/3.6 release of LLVM.
610 LlvmVersion=4.0
611 AC_SUBST([LlvmVersion])
612 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
613 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
614
615 dnl ** Which LLVM llc to use?
616 dnl --------------------------------------------------------------
617 FIND_LLVM_PROG([LLC], [llc], [$LlvmVersion])
618 LlcCmd="$LLC"
619 AC_SUBST([LlcCmd])
620
621 dnl ** Which LLVM opt to use?
622 dnl --------------------------------------------------------------
623 FIND_LLVM_PROG([OPT], [opt], [$LlvmVersion])
624 OptCmd="$OPT"
625 AC_SUBST([OptCmd])
626
627 dnl --------------------------------------------------------------
628 dnl End of configure script option section
629 dnl --------------------------------------------------------------
630
631
632 dnl --------------------------------------------------------------
633 dnl ** Can the unix package be built?
634 dnl --------------------------------------------------------------
635
636 if test "$TargetOS" = "mingw32"
637 then
638     GhcLibsWithUnix=NO
639 else
640     GhcLibsWithUnix=YES
641 fi
642 AC_SUBST([GhcLibsWithUnix])
643
644 dnl ** does #! work?
645 AC_SYS_INTERPRETER()
646
647 # Check for split-objs
648 SplitObjsBroken=NO
649 dnl ** look for `perl'
650 case $HostOS_CPP in
651 cygwin32|mingw32)
652   if test "$EnableDistroToolchain" = "NO"; then
653     PerlCmd=$hardtop/inplace/perl/perl
654   else
655     AC_PATH_PROG([PerlCmd],[perl])
656   fi
657   ;;
658 *)
659     AC_PATH_PROG([PerlCmd],[perl])
660     if test -z "$PerlCmd"
661     then
662         AC_MSG_WARN([No Perl on PATH, disabling split object support])
663         SplitObjsBroken=YES
664     else
665         FPTOOLS_CHECK_PERL_VERSION
666     fi
667     ;;
668 esac
669 AC_SUBST([SplitObjsBroken])
670
671 dnl ** look for GCC and find out which version
672 dnl     Figure out which C compiler to use.  Gcc is preferred.
673 dnl     If gcc, make sure it's at least 3.0
674 dnl
675 FP_GCC_VERSION
676
677 dnl ** See whether gcc supports -no-pie
678 FP_GCC_SUPPORTS_NO_PIE
679
680 dnl ** look to see if we have a C compiler using an llvm back end.
681 dnl
682 FP_CC_LLVM_BACKEND
683
684 FP_PROG_LD_IS_GNU
685 FP_PROG_LD_BUILD_ID
686 FP_PROG_LD_NO_COMPACT_UNWIND
687 FP_PROG_LD_FILELIST
688
689
690 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
691 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
692 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
693 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
694 # Stage 3 won't be supported by cross-compilation
695
696 FP_GCC_EXTRA_FLAGS
697
698 # See rules/distdir-way-opts.mk for details.
699 # Flags passed to the C compiler
700 AC_SUBST(CONF_CC_OPTS_STAGE0)
701 AC_SUBST(CONF_CC_OPTS_STAGE1)
702 AC_SUBST(CONF_CC_OPTS_STAGE2)
703 # Flags passed to the C compiler when we ask it to link
704 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
705 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
706 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
707 # Flags passed to the linker when we ask it to link
708 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
709 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
710 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
711 # Flags passed to the C preprocessor
712 AC_SUBST(CONF_CPP_OPTS_STAGE0)
713 AC_SUBST(CONF_CPP_OPTS_STAGE1)
714 AC_SUBST(CONF_CPP_OPTS_STAGE2)
715 # Flags passed to the Haskell compiler
716 AC_SUBST(CONF_HC_OPTS_STAGE0)
717 AC_SUBST(CONF_HC_OPTS_STAGE1)
718 AC_SUBST(CONF_HC_OPTS_STAGE2)
719
720 dnl ** Set up the variables for the platform in the settings file.
721 dnl May need to use gcc to find platform details.
722 dnl --------------------------------------------------------------
723 FPTOOLS_SET_HASKELL_PLATFORM_VARS
724
725 dnl ** figure out how to do context diffs
726 FP_PROG_CONTEXT_DIFF
727
728 dnl Let's make sure install-sh is executable here.  If we got it from
729 dnl a darcs repo, it might not be (see bug #978).
730 chmod +x install-sh
731 dnl ** figure out how to do a BSD-ish install
732 AC_PROG_INSTALL
733
734 dnl ** how to invoke `ar' and `ranlib'
735 FP_PROG_AR_SUPPORTS_ATFILE
736 FP_PROG_AR_NEEDS_RANLIB
737
738 dnl ** Check to see whether ln -s works
739 AC_PROG_LN_S
740
741 FP_SETTINGS
742
743 dnl ** Find the path to sed
744 AC_PATH_PROGS(SedCmd,gsed sed,sed)
745
746
747 dnl ** check for time command
748 AC_PATH_PROG(TimeCmd,time)
749
750 dnl ** check for tar
751 dnl   if GNU tar is named gtar, look for it first.
752 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
753
754 dnl ** check for compressors
755 AC_PATH_PROGS(Bzip2Cmd,bzip2, bzip2)
756 AC_PATH_PROGS(GzipCmd,gzip, gzip)
757 AC_PATH_PROGS(XzCmd,pxz xz, xz)
758
759 dnl ** check for patch
760 dnl if GNU patch is named gpatch, look for it first
761 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
762
763 dnl ** check for dtrace (currently only implemented for Mac OS X)
764 HaveDtrace=NO
765 AC_PATH_PROG(DtraceCmd,dtrace)
766 if test -n "$DtraceCmd"; then
767   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
768     HaveDtrace=YES
769   fi
770 fi
771 AC_SUBST(HaveDtrace)
772
773 AC_PATH_PROG(HSCOLOUR,HsColour)
774 # HsColour is passed to Cabal, so we need a native path
775 if test "$HostOS"      = "mingw32" && \
776    test "${OSTYPE}"   != "msys"    && \
777    test "${HSCOLOUR}" != ""
778 then
779     # Canonicalise to <drive>:/path/to/gcc
780     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
781 fi
782
783 dnl ** check for Sphinx toolchain
784 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
785 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
786 changequote(, )dnl
787 [if test -n "$SPHINXBUILD"; then
788   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
789 fi;
790 changequote([, ])dnl
791 ])
792 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
793     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
794
795 dnl ** check for xelatex
796 AC_PATH_PROG(XELATEX,xelatex)
797
798 dnl ** check for ghc-pkg command
799 FP_PROG_GHC_PKG
800
801 dnl ** check for installed happy binary + version
802 FPTOOLS_HAPPY
803
804 dnl ** check for installed alex binary + version
805 FPTOOLS_ALEX
806
807 dnl --------------------------------------------------
808 dnl ### program checking section ends here ###
809 dnl --------------------------------------------------
810
811 dnl --------------------------------------------------
812 dnl * Platform header file and syscall feature tests
813 dnl ### checking the state of the local header files and syscalls ###
814
815 dnl ** check for full ANSI header (.h) files
816 AC_HEADER_STDC
817
818 dnl ** Enable large file support.  NB. do this before testing the type of
819 dnl    off_t, because it will affect the result of that test.
820 AC_SYS_LARGEFILE
821
822 dnl ** check for specific header (.h) files that we are interested in
823 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
824
825 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
826 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
827 [[#if HAVE_SYS_PARAM_H
828 # include <sys/param.h>
829 #endif
830 ]])
831
832 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
833 AC_HEADER_TIME
834
835 dnl ** do we have long longs?
836 AC_CHECK_TYPES([long long])
837
838 dnl ** what are the sizes of various types
839 FP_CHECK_SIZEOF_AND_ALIGNMENT(char)
840 FP_CHECK_SIZEOF_AND_ALIGNMENT(double)
841 FP_CHECK_SIZEOF_AND_ALIGNMENT(float)
842 FP_CHECK_SIZEOF_AND_ALIGNMENT(int)
843 FP_CHECK_SIZEOF_AND_ALIGNMENT(long)
844 if test "$ac_cv_type_long_long" = yes; then
845 FP_CHECK_SIZEOF_AND_ALIGNMENT(long long)
846 fi
847 FP_CHECK_SIZEOF_AND_ALIGNMENT(short)
848 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned char)
849 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned int)
850 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long)
851 if test "$ac_cv_type_long_long" = yes; then
852 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long long)
853 fi
854 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned short)
855 FP_CHECK_SIZEOF_AND_ALIGNMENT(void *)
856
857 FP_CHECK_SIZEOF_AND_ALIGNMENT(int8_t)
858 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint8_t)
859 FP_CHECK_SIZEOF_AND_ALIGNMENT(int16_t)
860 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint16_t)
861 FP_CHECK_SIZEOF_AND_ALIGNMENT(int32_t)
862 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint32_t)
863 FP_CHECK_SIZEOF_AND_ALIGNMENT(int64_t)
864 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint64_t)
865
866
867 dnl for use in settings.in
868 WordSize=$ac_cv_sizeof_void_p
869 AC_SUBST(WordSize)
870 FP_CHECK_FUNC([WinExec],
871   [@%:@include <windows.h>], [WinExec("",0)])
872
873 FP_CHECK_FUNC([GetModuleFileName],
874   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
875
876 dnl ** check for more functions
877 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
878 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
879
880 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
881 dnl ** _POSIX_C_SOURCE is defined
882 AC_CHECK_DECLS([ctime_r], , ,
883 [#define _POSIX_SOURCE 1
884 #define _POSIX_C_SOURCE 199506L
885 #include <time.h>])
886
887 dnl ** check for mingwex library
888 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
889 AC_SUBST(HaveLibMingwEx)
890
891 if test $HaveLibMingwEx = YES ; then
892   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
893 fi
894
895 dnl ** check for math library
896 dnl    Keep that check as early as possible.
897 dnl    as we need to know whether we need libm
898 dnl    for math functions or not
899 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
900 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
901 if test $HaveLibM = YES
902 then
903   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
904 fi
905
906 FP_BFD_SUPPORT
907
908 dnl ################################################################
909 dnl Check for libraries
910 dnl ################################################################
911
912 # system libffi
913
914 AC_ARG_WITH([system-libffi],
915 [AC_HELP_STRING([--with-system-libffi],
916   [Use system provided libffi for RTS [default=no]])
917 ])
918
919 AS_IF([test "x$with_system_libffi" = "xyes"],
920   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
921 )
922
923
924 AC_SUBST(UseSystemLibFFI)
925
926 AC_ARG_WITH([ffi-includes],
927 [AC_HELP_STRING([--with-ffi-includes=ARG],
928   [Find includes for libffi in ARG [default=system default]])
929 ],
930 [
931  if test "x$UseSystemLibFFI" != "xYES"; then
932     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
933  else
934     FFIIncludeDir="$withval"
935     LIBFFI_CFLAGS="-I$withval"
936  fi
937 ])
938
939 AC_SUBST(FFIIncludeDir)
940
941 AC_ARG_WITH([ffi-libraries],
942 [AC_HELP_STRING([--with-ffi-libraries=ARG],
943   [Find libffi in ARG [default=system default]])
944 ],
945 [
946  if test "x$UseSystemLibFFI" != "xYES"; then
947     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
948  else
949     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
950  fi
951 ])
952
953 AC_SUBST(FFILibDir)
954
955 AS_IF([test "$UseSystemLibFFI" = "YES"], [
956  CFLAGS2="$CFLAGS"
957  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
958  LDFLAGS2="$LDFLAGS"
959  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
960  if test "$HostOS" = "openbsd";
961  then
962    # OpenBSD's libffi is not directly linked to the libpthread but
963    # still requires pthread functionality. This means that any client
964    # binary which links with libffi also needs to link with
965    # libpthread. If it does not, then linking fails with unresolved
966    # symbols.
967    LDFLAGS="$LDFLAGS -lpthread"
968  fi
969  AC_CHECK_LIB(ffi, ffi_call,
970   [AC_CHECK_HEADERS([ffi.h], [break], [])
971    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
972   [AC_MSG_ERROR([Cannot find system libffi])])
973  CFLAGS="$CFLAGS2"
974  LDFLAGS="$LDFLAGS2"
975 ])
976
977 dnl ** check whether we need -ldl to get dlopen()
978 AC_CHECK_LIB(dl, dlopen)
979
980 dnl --------------------------------------------------
981 dnl * Miscellaneous feature tests
982 dnl --------------------------------------------------
983
984 dnl ** can we get alloca?
985 AC_FUNC_ALLOCA
986
987 dnl ** working vfork?
988 AC_FUNC_FORK
989
990 dnl ** determine whether or not const works
991 AC_C_CONST
992
993 dnl ** are we big endian?
994 AC_C_BIGENDIAN
995 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
996
997 dnl ** check for leading underscores in symbol names
998 FP_LEADING_UNDERSCORE
999
1000 FP_VISIBILITY_HIDDEN
1001
1002 dnl ** check for librt
1003 AC_CHECK_LIB(rt, clock_gettime)
1004 AC_CHECK_FUNCS(clock_gettime timer_settime)
1005 FP_CHECK_TIMER_CREATE
1006
1007 dnl ** check for Apple's "interesting" long double compatibility scheme
1008 AC_MSG_CHECKING(for printf\$LDBLStub)
1009 AC_TRY_LINK_FUNC(printf\$LDBLStub,
1010     [
1011         AC_MSG_RESULT(yes)
1012         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
1013             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
1014     ],
1015     [
1016         AC_MSG_RESULT(no)
1017         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
1018             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
1019     ])
1020
1021 dnl Some platforms (e.g. Android's Bionic) have pthreads support available
1022 dnl without linking against libpthread. Check whether -lpthread is necessary
1023 dnl to use pthreads.
1024 dnl
1025 dnl Note that it is important that this happens before we AC_CHECK_LIB(thread)
1026 AC_MSG_CHECKING(whether -lpthread is needed for pthreads)
1027 AC_CHECK_FUNC(pthread_create,
1028     [
1029         AC_MSG_RESULT(no)
1030         need_lpthread=0
1031     ],
1032     [
1033         AC_CHECK_LIB(pthread, pthread_create,
1034             [
1035                 AC_MSG_RESULT(yes)
1036                 need_lpthread=1
1037             ],
1038             [
1039                 AC_MSG_RESULT([no pthreads support found.])
1040                 need_lpthread=0
1041             ])
1042     ])
1043 AC_DEFINE_UNQUOTED([NEED_PTHREAD_LIB], [$need_lpthread],
1044     [Define 1 if we need to link code using pthreads with -lpthread])
1045
1046 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
1047 dnl    a different single-argument version.
1048 AC_CHECK_LIB(pthread, pthread_setname_np)
1049 AC_MSG_CHECKING(for pthread_setname_np)
1050 AC_TRY_LINK(
1051 [
1052 #define _GNU_SOURCE
1053 #include <pthread.h>
1054 ],
1055 [pthread_setname_np(pthread_self(), "name");],
1056     AC_MSG_RESULT(yes)
1057     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
1058       [Define to 1 if you have the glibc version of pthread_setname_np]),
1059     AC_MSG_RESULT(no)
1060 )
1061
1062 dnl ** check for eventfd which is needed by the I/O manager
1063 AC_CHECK_HEADERS([sys/eventfd.h])
1064 AC_CHECK_FUNCS([eventfd])
1065
1066 dnl ** Check for __thread support in the compiler
1067 AC_MSG_CHECKING(for __thread support)
1068 AC_COMPILE_IFELSE(
1069   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1070   [
1071    AC_MSG_RESULT(yes)
1072    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1073   ],
1074   [
1075    AC_MSG_RESULT(no)
1076    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1077   ])
1078
1079 dnl large address space support (see includes/rts/storage/MBlock.h)
1080 dnl
1081 dnl Darwin has vm_allocate/vm_protect
1082 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1083 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1084 dnl (They also have MADV_DONTNEED, but it means something else!)
1085 dnl
1086 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1087 dnl it counts page-table space as committed memory, and so quickly
1088 dnl runs out of paging file when we have multiple processes reserving
1089 dnl 1TB of address space, we get the following error:
1090 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1091 dnl
1092
1093 AC_ARG_ENABLE(large-address-space,
1094     [AC_HELP_STRING([--enable-large-address-space],
1095         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1096     EnableLargeAddressSpace=$enableval,
1097     EnableLargeAddressSpace=yes
1098 )
1099
1100 use_large_address_space=no
1101 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1102     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1103         if test "$ghc_host_os" = "darwin" ; then
1104             use_large_address_space=yes
1105         elif test "$ghc_host_os" = "openbsd" ; then
1106             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1107             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1108             # but is completely ignored by OS mmap
1109             use_large_address_space=no
1110         else
1111             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1112                 [
1113                 #include <unistd.h>
1114                 #include <sys/types.h>
1115                 #include <sys/mman.h>
1116                 #include <fcntl.h>
1117             ])
1118             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1119                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1120                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1121                     use_large_address_space=yes
1122             fi
1123         fi
1124     fi
1125 fi
1126 if test "$use_large_address_space" = "yes" ; then
1127    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1128 fi
1129
1130 dnl ** Use MMAP in the runtime linker?
1131 dnl --------------------------------------------------------------
1132
1133 case ${TargetOS} in
1134     linux|linux-android|freebsd|dragonfly|netbsd|openbsd|kfreebsdgnu|gnu|solaris2)
1135         RtsLinkerUseMmap=1
1136         ;;
1137     darwin|ios)
1138         # Don't use mmap on powerpc/darwin as the mmap there doesn't support
1139         # reallocating. Reallocating is needed to allocate jump islands just
1140         # after each object image. Jumps to these jump islands use relative
1141         # branches which are limited to offsets that can be represented in
1142         # 24-bits.
1143         if test "$TargetArch" != "powerpc" ; then
1144             RtsLinkerUseMmap=1
1145         else
1146             RtsLinkerUseMmap=0
1147         fi
1148         ;;
1149     *)
1150         # Windows (which doesn't have mmap) and everything else.
1151         RtsLinkerUseMmap=0
1152         ;;
1153     esac
1154
1155 AC_DEFINE_UNQUOTED([RTS_LINKER_USE_MMAP], [$RtsLinkerUseMmap],
1156                    [Use mmap in the runtime linker])
1157
1158 dnl ** Have libdw?
1159 dnl --------------------------------------------------------------
1160 UseLibdw=NO
1161 USE_LIBDW=0
1162 AC_ARG_ENABLE(dwarf-unwind,
1163     [AC_HELP_STRING([--enable-dwarf-unwind],
1164         [Enable DWARF unwinding support in the runtime system via elfutils' libdw [default=no]])],
1165     [AC_CHECK_LIB(dw, dwfl_attach_state, [UseLibdw=YES], [UseLibdw=NO])],
1166     [UseLibdw=NO]
1167 )
1168 AC_SUBST(UseLibdw)
1169 if test $UseLibdw = "YES" ; then
1170         USE_LIBDW=1
1171 fi
1172 AC_DEFINE_UNQUOTED([USE_LIBDW], [$USE_LIBDW], [Set to 1 to use libdw])
1173
1174 dnl ** Have libnuma?
1175 dnl --------------------------------------------------------------
1176 HaveLibNuma=0
1177 AC_CHECK_HEADERS([numa.h numaif.h])
1178
1179 if test "$ac_cv_header_numa_h$ac_cv_header_numaif_h" = "yesyes" ; then
1180     AC_CHECK_LIB(numa, numa_available,HaveLibNuma=1)
1181 fi
1182 AC_DEFINE_UNQUOTED([HAVE_LIBNUMA], [$HaveLibNuma], [Define to 1 if you have libnuma])
1183
1184 dnl ** Documentation
1185 dnl --------------------------------------------------------------
1186 if test -n "$SPHINXBUILD"; then
1187     BUILD_MAN=YES
1188     BUILD_SPHINX_HTML=YES
1189     if test -n "$XELATEX"; then
1190         BUILD_SPHINX_PDF=YES
1191     else
1192         BUILD_SPHINX_PDF=NO
1193     fi
1194 else
1195     BUILD_MAN=NO
1196     BUILD_SPHINX_HTML=NO
1197     BUILD_SPHINX_PDF=NO
1198 fi
1199 AC_SUBST(BUILD_MAN)
1200 AC_SUBST(BUILD_SPHINX_HTML)
1201 AC_SUBST(BUILD_SPHINX_PDF)
1202
1203 LIBRARY_VERSION(base)
1204 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1205 LIBRARY_VERSION(ghc-prim)
1206 LIBRARY_VERSION(ghc-compact)
1207 LIBRARY_ghc_VERSION="$ProjectVersion"
1208 AC_SUBST(LIBRARY_ghc_VERSION)
1209
1210 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1211    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1212 fi
1213
1214 # Create the configuration for the Hadrian build system if it is present
1215 if test -e hadrian/cfg/system.config.in; then
1216     AC_CONFIG_FILES([hadrian/cfg/system.config])
1217 fi
1218
1219 # We got caught by
1220 #     http://savannah.gnu.org/bugs/index.php?1516
1221 #     $(eval ...) inside conditionals causes errors
1222 # with make 3.80, so warn the user if it looks like they're about to
1223 # try to use it.
1224 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1225 print_make_warning=""
1226 checkMake380() {
1227     make_ver=`$1 --version 2>&1 | head -1`
1228     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1229     then
1230         print_make_warning="true"
1231     fi
1232     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1233     then
1234         MakeCmd=$1
1235         AC_SUBST(MakeCmd)
1236     fi
1237 }
1238
1239 checkMake380 make
1240 checkMake380 gmake
1241
1242 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghc-boot-th/ghc-boot-th.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt utils/mkUserGuidePart/mkUserGuidePart.cabal distrib/configure.ac])
1243 AC_OUTPUT
1244 [
1245 if test "$print_make_warning" = "true"; then
1246    echo
1247    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1248    echo "This version cannot be used to build GHC."
1249    echo "Please use GNU make >= 3.81."
1250 fi
1251
1252 echo "
1253 ----------------------------------------------------------------------
1254 Configure completed successfully.
1255
1256    Building GHC version  : $ProjectVersion
1257           Git commit id  : $ProjectGitCommitId
1258
1259    Build platform        : $BuildPlatform
1260    Host platform         : $HostPlatform
1261    Target platform       : $TargetPlatform
1262 "
1263
1264 echo "\
1265    Bootstrapping using   : $WithGhc
1266       which is version   : $GhcVersion
1267 "
1268
1269 if test "x$CC_LLVM_BACKEND" = "x1"; then
1270     if test "x$CC_CLANG_BACKEND" = "x1"; then
1271         CompilerName="clang        "
1272     else
1273         CompilerName="llvm-gcc     "
1274     fi
1275 else
1276     CompilerName="gcc          "
1277 fi
1278
1279 echo "\
1280    Using (for bootstrapping) : $CC_STAGE0
1281    Using $CompilerName       : $CC
1282       which is version       : $GccVersion
1283    Building a cross compiler : $CrossCompiling
1284    Unregisterised            : $Unregisterised
1285    hs-cpp       : $HaskellCPPCmd
1286    hs-cpp-flags : $HaskellCPPArgs
1287    ar           : $ArCmd
1288    ld           : $LdCmd
1289    nm           : $NmCmd
1290    libtool      : $LibtoolCmd
1291    objdump      : $ObjdumpCmd
1292    ranlib       : $RanlibCmd
1293    windres      : $WindresCmd
1294    dllwrap      : $DllWrapCmd
1295    Happy        : $HappyCmd ($HappyVersion)
1296    Alex         : $AlexCmd ($AlexVersion)
1297    Perl         : $PerlCmd
1298    sphinx-build : $SPHINXBUILD
1299    xelatex      : $XELATEX
1300
1301    Using LLVM tools
1302       llc   : $LlcCmd
1303       opt   : $OptCmd"
1304
1305 if test "$HSCOLOUR" = ""; then
1306 echo "
1307    HsColour was not found; documentation will not contain source links
1308 "
1309 else
1310 echo "\
1311    HsColour : $HSCOLOUR
1312 "
1313 fi
1314
1315 echo "\
1316    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1317    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"
1318
1319 echo "----------------------------------------------------------------------
1320 "
1321
1322 echo "\
1323 For a standard build of GHC (fully optimised with profiling), type (g)make.
1324
1325 To make changes to the default build configuration, copy the file
1326 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1327
1328 For more information on how to configure your GHC build, see
1329    http://ghc.haskell.org/trac/ghc/wiki/Building
1330 "]