Merge branch 'master' of darcs.haskell.org:/srv/darcs//ghc
[ghc.git] / compiler / rename / RnEnv.lhs
1 %
2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-2006
3 %
4 \section[RnEnv]{Environment manipulation for the renamer monad}
5
6 \begin{code}
7 module RnEnv (
8         newTopSrcBinder,
9         lookupLocatedTopBndrRn, lookupTopBndrRn,
10         lookupLocatedOccRn, lookupOccRn,
11         lookupLocalOccRn_maybe,
12         lookupTypeOccRn, lookupKindOccRn,
13         lookupGlobalOccRn, lookupGlobalOccRn_maybe,
14
15         HsSigCtxt(..), lookupLocalTcNames, lookupSigOccRn,
16
17         lookupFixityRn, lookupTyFixityRn,
18         lookupInstDeclBndr, lookupSubBndrOcc, lookupFamInstName,
19         greRdrName,
20         lookupSubBndrGREs, lookupConstructorFields,
21         lookupSyntaxName, lookupSyntaxNames, lookupIfThenElse,
22         lookupGreRn, lookupGreLocalRn, lookupGreRn_maybe,
23         getLookupOccRn, addUsedRdrNames,
24
25         newLocalBndrRn, newLocalBndrsRn,
26         bindLocalName, bindLocalNames, bindLocalNamesFV,
27         MiniFixityEnv, emptyFsEnv, extendFsEnv, lookupFsEnv,
28         addLocalFixities,
29         bindLocatedLocalsFV, bindLocatedLocalsRn,
30         extendTyVarEnvFVRn,
31
32         checkDupRdrNames, checkShadowedRdrNames,
33         checkDupNames, checkDupAndShadowedNames, checkTupSize,
34         addFvRn, mapFvRn, mapMaybeFvRn, mapFvRnCPS,
35         warnUnusedMatches,
36         warnUnusedTopBinds, warnUnusedLocalBinds,
37         dataTcOccs, unknownNameErr, kindSigErr, perhapsForallMsg,
38         HsDocContext(..), docOfHsDocContext
39     ) where
40
41 #include "HsVersions.h"
42
43 import LoadIface        ( loadInterfaceForName, loadSrcInterface )
44 import IfaceEnv
45 import HsSyn
46 import RdrName
47 import HscTypes
48 import TcEnv            ( tcLookupDataCon, tcLookupField, isBrackStage )
49 import TcRnMonad
50 import Id               ( isRecordSelector )
51 import Name
52 import NameSet
53 import NameEnv
54 import Avail
55 import Module           ( ModuleName, moduleName )
56 import UniqFM
57 import DataCon          ( dataConFieldLabels, dataConTyCon )
58 import TyCon            ( isTupleTyCon, tyConArity )
59 import PrelNames        ( mkUnboundName, rOOT_MAIN, forall_tv_RDR )
60 import ErrUtils         ( MsgDoc )
61 import SrcLoc
62 import Outputable
63 import Util
64 import Maybes
65 import ListSetOps       ( removeDups )
66 import DynFlags
67 import FastString
68 import Control.Monad
69 import Data.List
70 import qualified Data.Set as Set
71 import Constants        ( mAX_TUPLE_SIZE )
72 \end{code}
73
74 \begin{code}
75 -- XXX
76 thenM :: Monad a => a b -> (b -> a c) -> a c
77 thenM = (>>=)
78 \end{code}
79
80 %*********************************************************
81 %*                                                      *
82                 Source-code binders
83 %*                                                      *
84 %*********************************************************
85
86 \begin{code}
87 newTopSrcBinder :: Located RdrName -> RnM Name
88 newTopSrcBinder (L loc rdr_name)
89   | Just name <- isExact_maybe rdr_name
90   =     -- This is here to catch
91         --   (a) Exact-name binders created by Template Haskell
92         --   (b) The PrelBase defn of (say) [] and similar, for which
93         --       the parser reads the special syntax and returns an Exact RdrName
94         -- We are at a binding site for the name, so check first that it
95         -- the current module is the correct one; otherwise GHC can get
96         -- very confused indeed. This test rejects code like
97         --      data T = (,) Int Int
98         -- unless we are in GHC.Tup
99     if isExternalName name then
100       do { this_mod <- getModule
101          ; unless (this_mod == nameModule name)
102                   (addErrAt loc (badOrigBinding rdr_name))
103          ; return name }
104     else   -- See Note [Binders in Template Haskell] in Convert.hs
105       do { let occ = nameOccName name
106          ; occ `seq` return ()  -- c.f. seq in newGlobalBinder
107          ; this_mod <- getModule
108          ; updNameCache $ \ ns ->
109            let name' = mkExternalName (nameUnique name) this_mod occ loc
110                ns'   = ns { nsNames = extendNameCache (nsNames ns) this_mod occ name' }
111            in (ns', name') }
112
113   | Just (rdr_mod, rdr_occ) <- isOrig_maybe rdr_name
114   = do  { this_mod <- getModule
115         ; unless (rdr_mod == this_mod || rdr_mod == rOOT_MAIN)
116                  (addErrAt loc (badOrigBinding rdr_name))
117         -- When reading External Core we get Orig names as binders,
118         -- but they should agree with the module gotten from the monad
119         --
120         -- We can get built-in syntax showing up here too, sadly.  If you type
121         --      data T = (,,,)
122         -- the constructor is parsed as a type, and then RdrHsSyn.tyConToDataCon
123         -- uses setRdrNameSpace to make it into a data constructors.  At that point
124         -- the nice Exact name for the TyCon gets swizzled to an Orig name.
125         -- Hence the badOrigBinding error message.
126         --
127         -- Except for the ":Main.main = ..." definition inserted into
128         -- the Main module; ugh!
129
130         -- Because of this latter case, we call newGlobalBinder with a module from
131         -- the RdrName, not from the environment.  In principle, it'd be fine to
132         -- have an arbitrary mixture of external core definitions in a single module,
133         -- (apart from module-initialisation issues, perhaps).
134         ; newGlobalBinder rdr_mod rdr_occ loc }
135                 --TODO, should pass the whole span
136
137   | otherwise
138   = do  { unless (not (isQual rdr_name))
139                  (addErrAt loc (badQualBndrErr rdr_name))
140                 -- Binders should not be qualified; if they are, and with a different
141                 -- module name, we we get a confusing "M.T is not in scope" error later
142
143         ; stage <- getStage
144         ; if isBrackStage stage then
145                 -- We are inside a TH bracket, so make an *Internal* name
146                 -- See Note [Top-level Names in Template Haskell decl quotes] in RnNames
147              do { uniq <- newUnique
148                 ; return (mkInternalName uniq (rdrNameOcc rdr_name) loc) }
149           else
150                 -- Normal case
151              do { this_mod <- getModule
152                 ; newGlobalBinder this_mod (rdrNameOcc rdr_name) loc } }
153 \end{code}
154
155 %*********************************************************
156 %*                                                      *
157         Source code occurrences
158 %*                                                      *
159 %*********************************************************
160
161 Looking up a name in the RnEnv.
162
163 Note [Type and class operator definitions]
164 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
165 We want to reject all of these unless we have -XTypeOperators (Trac #3265)
166    data a :*: b  = ...
167    class a :*: b where ...
168    data (:*:) a b  = ....
169    class (:*:) a b where ...
170 The latter two mean that we are not just looking for a
171 *syntactically-infix* declaration, but one that uses an operator
172 OccName.  We use OccName.isSymOcc to detect that case, which isn't
173 terribly efficient, but there seems to be no better way.
174
175 \begin{code}
176 lookupTopBndrRn :: RdrName -> RnM Name
177 lookupTopBndrRn n = do nopt <- lookupTopBndrRn_maybe n
178                        case nopt of
179                          Just n' -> return n'
180                          Nothing -> do traceRn $ text "lookupTopBndrRn"
181                                        unboundName WL_LocalTop n
182
183 lookupLocatedTopBndrRn :: Located RdrName -> RnM (Located Name)
184 lookupLocatedTopBndrRn = wrapLocM lookupTopBndrRn
185
186 lookupTopBndrRn_maybe :: RdrName -> RnM (Maybe Name)
187 -- Look up a top-level source-code binder.   We may be looking up an unqualified 'f',
188 -- and there may be several imported 'f's too, which must not confuse us.
189 -- For example, this is OK:
190 --      import Foo( f )
191 --      infix 9 f       -- The 'f' here does not need to be qualified
192 --      f x = x         -- Nor here, of course
193 -- So we have to filter out the non-local ones.
194 --
195 -- A separate function (importsFromLocalDecls) reports duplicate top level
196 -- decls, so here it's safe just to choose an arbitrary one.
197 --
198 -- There should never be a qualified name in a binding position in Haskell,
199 -- but there can be if we have read in an external-Core file.
200 -- The Haskell parser checks for the illegal qualified name in Haskell
201 -- source files, so we don't need to do so here.
202
203 lookupTopBndrRn_maybe rdr_name
204   | Just name <- isExact_maybe rdr_name
205   = do { name' <- lookupExactOcc name; return (Just name') }
206
207   | Just (rdr_mod, rdr_occ) <- isOrig_maybe rdr_name
208         -- This deals with the case of derived bindings, where
209         -- we don't bother to call newTopSrcBinder first
210         -- We assume there is no "parent" name
211   = do  { loc <- getSrcSpanM
212         ; n <- newGlobalBinder rdr_mod rdr_occ loc
213         ; return (Just n)}
214
215   | otherwise
216   = do  {  -- Check for operators in type or class declarations
217            -- See Note [Type and class operator definitions]
218           let occ = rdrNameOcc rdr_name
219         ; when (isTcOcc occ && isSymOcc occ)
220                (do { op_ok <- xoptM Opt_TypeOperators
221                    ; unless op_ok (addErr (opDeclErr rdr_name)) })
222
223         ; mb_gre <- lookupGreLocalRn rdr_name
224         ; case mb_gre of
225                 Nothing  -> return Nothing
226                 Just gre -> return (Just $ gre_name gre) }
227
228
229 -----------------------------------------------
230 lookupExactOcc :: Name -> RnM Name
231 -- See Note [Looking up Exact RdrNames]
232 lookupExactOcc name
233   | Just thing <- wiredInNameTyThing_maybe name
234   , Just tycon <- case thing of
235                     ATyCon tc   -> Just tc
236                     ADataCon dc -> Just (dataConTyCon dc)
237                     _           -> Nothing
238   , isTupleTyCon tycon
239   = do { checkTupSize (tyConArity tycon)
240        ; return name }
241
242   | isExternalName name
243   = return name
244
245   | otherwise
246   = do { env <- getGlobalRdrEnv
247        ; let -- See Note [Splicing Exact names]
248              main_occ =  nameOccName name
249              demoted_occs = case demoteOccName main_occ of
250                               Just occ -> [occ]
251                               Nothing  -> []
252              gres = [ gre | occ <- main_occ : demoted_occs
253                           , gre <- lookupGlobalRdrEnv env occ
254                           , gre_name gre == name ]
255        ; case gres of
256            []    -> -- See Note [Splicing Exact names]
257                     do { lcl_env <- getLocalRdrEnv
258                        ; unless (name `inLocalRdrEnvScope` lcl_env)
259                                 (addErr exact_nm_err)
260                        ; return name }
261
262            [gre] -> return (gre_name gre)
263            _     -> pprPanic "lookupExactOcc" (ppr name $$ ppr gres) }
264
265   where
266     exact_nm_err = hang (ptext (sLit "The exact Name") <+> quotes (ppr name) <+> ptext (sLit "is not in scope"))
267                       2 (vcat [ ptext (sLit "Probable cause: you used a unique Template Haskell name (NameU), ")
268                               , ptext (sLit "perhaps via newName, but did not bind it")
269                               , ptext (sLit "If that's it, then -ddump-splices might be useful") ])
270
271 -----------------------------------------------
272 lookupInstDeclBndr :: Name -> SDoc -> RdrName -> RnM Name
273 -- This is called on the method name on the left-hand side of an
274 -- instance declaration binding. eg.  instance Functor T where
275 --                                       fmap = ...
276 --                                       ^^^^ called on this
277 -- Regardless of how many unqualified fmaps are in scope, we want
278 -- the one that comes from the Functor class.
279 --
280 -- Furthermore, note that we take no account of whether the
281 -- name is only in scope qualified.  I.e. even if method op is
282 -- in scope as M.op, we still allow plain 'op' on the LHS of
283 -- an instance decl
284 --
285 -- The "what" parameter says "method" or "associated type",
286 -- depending on what we are looking up
287 lookupInstDeclBndr cls what rdr
288   = do { when (isQual rdr)
289               (addErr (badQualBndrErr rdr))
290                 -- In an instance decl you aren't allowed
291                 -- to use a qualified name for the method
292                 -- (Although it'd make perfect sense.)
293        ; lookupSubBndrOcc False -- False => we don't give deprecated
294                                 -- warnings when a deprecated class
295                                 -- method is defined. We only warn
296                                 -- when it's used
297                           (ParentIs cls) doc rdr }
298   where
299     doc = what <+> ptext (sLit "of class") <+> quotes (ppr cls)
300
301
302 -----------------------------------------------
303 lookupFamInstName :: Maybe Name -> Located RdrName -> RnM (Located Name)
304 -- Used for TyData and TySynonym family instances only,
305 -- See Note [Family instance binders]
306 lookupFamInstName (Just cls) tc_rdr  -- Associated type; c.f RnBinds.rnMethodBind
307   = wrapLocM (lookupInstDeclBndr cls (ptext (sLit "associated type"))) tc_rdr
308 lookupFamInstName Nothing tc_rdr     -- Family instance; tc_rdr is an *occurrence*
309   = lookupLocatedOccRn tc_rdr
310
311 -----------------------------------------------
312 lookupConstructorFields :: Name -> RnM [Name]
313 -- Look up the fields of a given constructor
314 --   *  For constructors from this module, use the record field env,
315 --      which is itself gathered from the (as yet un-typechecked)
316 --      data type decls
317 --
318 --    * For constructors from imported modules, use the *type* environment
319 --      since imported modles are already compiled, the info is conveniently
320 --      right there
321
322 lookupConstructorFields con_name
323   = do  { this_mod <- getModule
324         ; if nameIsLocalOrFrom this_mod con_name then
325           do { RecFields field_env _ <- getRecFieldEnv
326              ; return (lookupNameEnv field_env con_name `orElse` []) }
327           else
328           do { con <- tcLookupDataCon con_name
329              ; return (dataConFieldLabels con) } }
330
331 -----------------------------------------------
332 -- Used for record construction and pattern matching
333 -- When the -XDisambiguateRecordFields flag is on, take account of the
334 -- constructor name to disambiguate which field to use; it's just the
335 -- same as for instance decls
336 --
337 -- NB: Consider this:
338 --      module Foo where { data R = R { fld :: Int } }
339 --      module Odd where { import Foo; fld x = x { fld = 3 } }
340 -- Arguably this should work, because the reference to 'fld' is
341 -- unambiguous because there is only one field id 'fld' in scope.
342 -- But currently it's rejected.
343
344 lookupSubBndrOcc :: Bool
345                  -> Parent  -- NoParent   => just look it up as usual
346                             -- ParentIs p => use p to disambiguate
347                  -> SDoc -> RdrName
348                  -> RnM Name
349 lookupSubBndrOcc warnIfDeprec parent doc rdr_name
350   | Just n <- isExact_maybe rdr_name   -- This happens in derived code
351   = lookupExactOcc n
352
353   | Just (rdr_mod, rdr_occ) <- isOrig_maybe rdr_name
354   = lookupOrig rdr_mod rdr_occ
355
356   | otherwise   -- Find all the things the rdr-name maps to
357   = do  {       -- and pick the one with the right parent namep
358           env <- getGlobalRdrEnv
359         ; case lookupSubBndrGREs env parent rdr_name of
360                 -- NB: lookupGlobalRdrEnv, not lookupGRE_RdrName!
361                 --     The latter does pickGREs, but we want to allow 'x'
362                 --     even if only 'M.x' is in scope
363             [gre] -> do { addUsedRdrName warnIfDeprec gre (used_rdr_name gre)
364                           -- Add a usage; this is an *occurrence* site
365                         ; return (gre_name gre) }
366             []    -> do { addErr (unknownSubordinateErr doc rdr_name)
367                         ; return (mkUnboundName rdr_name) }
368             gres  -> do { addNameClashErrRn rdr_name gres
369                         ; return (gre_name (head gres)) } }
370   where
371     -- Note [Usage for sub-bndrs]
372     used_rdr_name gre
373       | isQual rdr_name = rdr_name
374       | otherwise       = greRdrName gre
375
376 greRdrName :: GlobalRdrElt -> RdrName
377 greRdrName gre
378   = case gre_prov gre of
379       LocalDef    -> unqual_rdr
380       Imported is -> used_rdr_name_from_is is
381
382   where
383     occ = nameOccName (gre_name gre)
384     unqual_rdr = mkRdrUnqual occ
385
386     used_rdr_name_from_is imp_specs     -- rdr_name is unqualified
387       | not (all (is_qual . is_decl) imp_specs)
388       = unqual_rdr  -- An unqualified import is available
389       | otherwise
390       =             -- Only qualified imports available, so make up
391                     -- a suitable qualifed name from the first imp_spec
392         ASSERT( not (null imp_specs) )
393         mkRdrQual (is_as (is_decl (head imp_specs))) occ
394
395 lookupSubBndrGREs :: GlobalRdrEnv -> Parent -> RdrName -> [GlobalRdrElt]
396 -- If Parent = NoParent, just do a normal lookup
397 -- If Parent = Parent p then find all GREs that
398 --   (a) have parent p
399 --   (b) for Unqual, are in scope qualified or unqualified
400 --       for Qual, are in scope with that qualification
401 lookupSubBndrGREs env parent rdr_name
402   = case parent of
403       NoParent   -> pickGREs rdr_name gres
404       ParentIs p
405         | isUnqual rdr_name -> filter (parent_is p) gres
406         | otherwise         -> filter (parent_is p) (pickGREs rdr_name gres)
407
408   where
409     gres = lookupGlobalRdrEnv env (rdrNameOcc rdr_name)
410
411     parent_is p (GRE { gre_par = ParentIs p' }) = p == p'
412     parent_is _ _                               = False
413 \end{code}
414
415 Note [Family instance binders]
416 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
417 Consider
418   data family F a
419   data instance F T = X1 | X2
420
421 The 'data instance' decl has an *occurrence* of F (and T), and *binds*
422 X1 and X2.  (This is unlike a normal data type declaration which would
423 bind F too.)  So we want an AvailTC F [X1,X2].
424
425 Now consider a similar pair:
426   class C a where
427     data G a
428   instance C S where
429     data G S = Y1 | Y2
430
431 The 'data G S' *binds* Y1 and Y2, and has an *occurrence* of G.
432
433 But there is a small complication: in an instance decl, we don't use
434 qualified names on the LHS; instead we use the class to disambiguate.
435 Thus:
436   module M where
437     import Blib( G )
438     class C a where
439       data G a
440     instance C S where
441       data G S = Y1 | Y2
442 Even though there are two G's in scope (M.G and Blib.G), the occurence
443 of 'G' in the 'instance C S' decl is unambiguous, becuase C has only
444 one associated type called G. This is exactly what happens for methods,
445 and it is only consistent to do the same thing for types. That's the
446 role of the function lookupTcdName; the (Maybe Name) give the class of
447 the encloseing instance decl, if any.
448
449 Note [Looking up Exact RdrNames]
450 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
451 Exact RdrNames are generated by Template Haskell.  See Note [Binders
452 in Template Haskell] in Convert.
453
454 For data types and classes have Exact system Names in the binding
455 positions for constructors, TyCons etc.  For example
456     [d| data T = MkT Int |]
457 when we splice in and Convert to HsSyn RdrName, we'll get
458     data (Exact (system Name "T")) = (Exact (system Name "MkT")) ...
459 These System names are generated by Convert.thRdrName
460
461 But, constructors and the like need External Names, not System Names!
462 So we do the following
463
464  * In RnEnv.newGlobalBinder we spot Exact RdrNames that wrap a
465    non-External Name, and make an External name for it. This is
466    the name that goes in the GlobalRdrEnv
467
468  * When looking up an occurrence of an Exact name, done in
469    RnEnv.lookupExactOcc, we find the Name with the right unique in the
470    GlobalRdrEnv, and use the one from the envt -- it will be an
471    External Name in the case of the data type/constructor above.
472
473  * Exact names are also use for purely local binders generated
474    by TH, such as    \x_33. x_33
475    Both binder and occurrence are Exact RdrNames.  The occurrence
476    gets looked up in the LocalRdrEnv by RnEnv.lookupOccRn, and
477    misses, because lookupLocalRdrEnv always returns Nothing for
478    an Exact Name.  Now we fall through to lookupExactOcc, which
479    will find the Name is not in the GlobalRdrEnv, so we just use
480    the Exact supplied Name.
481
482 Note [Splicing Exact names]
483 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
484 Consider the splice $(do { x <- newName "x"; return (VarE x) })
485 This will generate a (HsExpr RdrName) term that mentions the
486 Exact RdrName "x_56" (or whatever), but does not bind it.  So
487 when looking such Exact names we want to check that it's in scope,
488 otherwise the type checker will get confused.  To do this we need to
489 keep track of all the Names in scope, and the LocalRdrEnv does just that;
490 we consult it with RdrName.inLocalRdrEnvScope.
491
492 There is another wrinkle.  With TH and -XDataKinds, consider
493    $( [d| data Nat = Zero
494           data T = MkT (Proxy 'Zero)  |] )
495 After splicing, but before renaming we get this:
496    data Nat_77{tc} = Zero_78{d}
497    data T_79{tc} = MkT_80{d} (Proxy 'Zero_78{tc})  |] )
498 THe occurrence of 'Zero in the data type for T has the right unique,
499 but it has a TcClsName name-space in its OccName.  (This is set by
500 the ctxt_ns argument of Convert.thRdrName.)  When we check that is
501 in scope in the GlobalRdrEnv, we need to look up the DataName namespace
502 too.  (An alternative would be to make the GlobalRdrEnv also have
503 a Name -> GRE mapping.)
504
505 Note [Usage for sub-bndrs]
506 ~~~~~~~~~~~~~~~~~~~~~~~~~~
507 If you have this
508    import qualified M( C( f ) )
509    instance M.C T where
510      f x = x
511 then is the qualified import M.f used?  Obviously yes.
512 But the RdrName used in the instance decl is unqualified.  In effect,
513 we fill in the qualification by looking for f's whose class is M.C
514 But when adding to the UsedRdrNames we must make that qualification
515 explicit (saying "used  M.f"), otherwise we get "Redundant import of M.f".
516
517 So we make up a suitable (fake) RdrName.  But be careful
518    import qualifed M
519    import M( C(f) )
520    instance C T where
521      f x = x
522 Here we want to record a use of 'f', not of 'M.f', otherwise
523 we'll miss the fact that the qualified import is redundant.
524
525 --------------------------------------------------
526 --              Occurrences
527 --------------------------------------------------
528
529 \begin{code}
530 getLookupOccRn :: RnM (Name -> Maybe Name)
531 getLookupOccRn
532   = getLocalRdrEnv                      `thenM` \ local_env ->
533     return (lookupLocalRdrOcc local_env . nameOccName)
534
535 lookupLocatedOccRn :: Located RdrName -> RnM (Located Name)
536 lookupLocatedOccRn = wrapLocM lookupOccRn
537
538 lookupLocalOccRn_maybe :: RdrName -> RnM (Maybe Name)
539 -- Just look in the local environment
540 lookupLocalOccRn_maybe rdr_name
541   = do { local_env <- getLocalRdrEnv
542        ; return (lookupLocalRdrEnv local_env rdr_name) }
543
544 -- lookupOccRn looks up an occurrence of a RdrName
545 lookupOccRn :: RdrName -> RnM Name
546 lookupOccRn rdr_name = do
547   opt_name <- lookupOccRn_maybe rdr_name
548   maybe (unboundName WL_Any rdr_name) return opt_name
549
550 lookupKindOccRn :: RdrName -> RnM Name
551 -- Looking up a name occurring in a kind
552 lookupKindOccRn rdr_name
553   = do { mb_name <- lookupOccRn_maybe rdr_name
554        ; case mb_name of
555            Just name -> return name
556            Nothing -> unboundName WL_Any rdr_name  }
557
558 -- lookupPromotedOccRn looks up an optionally promoted RdrName.
559 lookupTypeOccRn :: RdrName -> RnM Name
560 -- see Note [Demotion]
561 lookupTypeOccRn rdr_name
562   = do { mb_name <- lookupOccRn_maybe rdr_name
563        ; case mb_name of {
564              Just name -> return name ;
565              Nothing   -> lookup_demoted rdr_name } }
566
567 lookup_demoted :: RdrName -> RnM Name
568 lookup_demoted rdr_name
569   | Just demoted_rdr <- demoteRdrName rdr_name
570     -- Maybe it's the name of a *data* constructor
571   = do { data_kinds <- xoptM Opt_DataKinds
572        ; mb_demoted_name <- lookupOccRn_maybe demoted_rdr
573        ; case mb_demoted_name of
574            Nothing -> unboundName WL_Any rdr_name
575            Just demoted_name
576              | data_kinds -> return demoted_name
577              | otherwise  -> unboundNameX WL_Any rdr_name suggest_dk }
578
579   | otherwise
580   = unboundName WL_Any rdr_name
581
582   where
583     suggest_dk = ptext (sLit "A data constructor of that name is in scope; did you mean -XDataKinds?")
584 \end{code}
585
586 Note [Demotion]
587 ~~~~~~~~~~~~~~~
588 When the user writes:
589   data Nat = Zero | Succ Nat
590   foo :: f Zero -> Int
591
592 'Zero' in the type signature of 'foo' is parsed as:
593   HsTyVar ("Zero", TcClsName)
594
595 When the renamer hits this occurence of 'Zero' it's going to realise
596 that it's not in scope. But because it is renaming a type, it knows
597 that 'Zero' might be a promoted data constructor, so it will demote
598 its namespace to DataName and do a second lookup.
599
600 The final result (after the renamer) will be:
601   HsTyVar ("Zero", DataName)
602
603 \begin{code}
604 -- lookupOccRn looks up an occurrence of a RdrName
605 lookupOccRn_maybe :: RdrName -> RnM (Maybe Name)
606 lookupOccRn_maybe rdr_name
607   = do { local_env <- getLocalRdrEnv
608        ; case lookupLocalRdrEnv local_env rdr_name of {
609           Just name -> return (Just name) ;
610           Nothing   -> do
611        { mb_name <- lookupGlobalOccRn_maybe rdr_name
612        ; case mb_name of {
613                 Just name  -> return (Just name) ;
614                 Nothing -> do
615        { -- We allow qualified names on the command line to refer to
616          --  *any* name exported by any module in scope, just as if there
617          -- was an "import qualified M" declaration for every module.
618          -- But we DONT allow it under Safe Haskell as we need to check
619          -- imports. We can and should instead check the qualified import
620          -- but at the moment this requires some refactoring so leave as a TODO
621        ; dflags <- getDynFlags
622        ; let allow_qual = dopt Opt_ImplicitImportQualified dflags &&
623                           not (safeDirectImpsReq dflags)
624        ; is_ghci <- getIsGHCi
625                -- This test is not expensive,
626                -- and only happens for failed lookups
627        ; if isQual rdr_name && allow_qual && is_ghci
628          then lookupQualifiedName rdr_name
629          else do { traceRn (text "lookupOccRn" <+> ppr rdr_name)
630                  ; return Nothing } } } } } }
631
632
633 lookupGlobalOccRn :: RdrName -> RnM Name
634 -- lookupGlobalOccRn is like lookupOccRn, except that it looks in the global
635 -- environment.  Adds an error message if the RdrName is not in scope.
636 lookupGlobalOccRn rdr_name
637   = do { mb_name <- lookupGlobalOccRn_maybe rdr_name
638        ; case mb_name of
639            Just n  -> return n
640            Nothing -> do { traceRn (text "lookupGlobalOccRn" <+> ppr rdr_name)
641                          ; unboundName WL_Global rdr_name } }
642
643 lookupGlobalOccRn_maybe :: RdrName -> RnM (Maybe Name)
644 -- No filter function; does not report an error on failure
645
646 lookupGlobalOccRn_maybe rdr_name
647   | Just n <- isExact_maybe rdr_name   -- This happens in derived code
648   = do { n' <- lookupExactOcc n; return (Just n') }
649
650   | Just (rdr_mod, rdr_occ) <- isOrig_maybe rdr_name
651   = do { n <- lookupOrig rdr_mod rdr_occ
652        ; return (Just n) }
653
654   | otherwise
655   = do  { mb_gre <- lookupGreRn_maybe rdr_name
656         ; case mb_gre of
657                 Nothing  -> return Nothing
658                 Just gre -> return (Just (gre_name gre)) }
659
660
661 --------------------------------------------------
662 --      Lookup in the Global RdrEnv of the module
663 --------------------------------------------------
664
665 lookupGreRn_maybe :: RdrName -> RnM (Maybe GlobalRdrElt)
666 -- Just look up the RdrName in the GlobalRdrEnv
667 lookupGreRn_maybe rdr_name
668   = lookupGreRn_help rdr_name (lookupGRE_RdrName rdr_name)
669
670 lookupGreRn :: RdrName -> RnM GlobalRdrElt
671 -- If not found, add error message, and return a fake GRE
672 lookupGreRn rdr_name
673   = do  { mb_gre <- lookupGreRn_maybe rdr_name
674         ; case mb_gre of {
675             Just gre -> return gre ;
676             Nothing  -> do
677         { traceRn (text "lookupGreRn" <+> ppr rdr_name)
678         ; name <- unboundName WL_Global rdr_name
679         ; return (GRE { gre_name = name, gre_par = NoParent,
680                         gre_prov = LocalDef }) }}}
681
682 lookupGreLocalRn :: RdrName -> RnM (Maybe GlobalRdrElt)
683 -- Similar, but restricted to locally-defined things
684 lookupGreLocalRn rdr_name
685   = lookupGreRn_help rdr_name lookup_fn
686   where
687     lookup_fn env = filter isLocalGRE (lookupGRE_RdrName rdr_name env)
688
689 lookupGreRn_help :: RdrName                     -- Only used in error message
690                  -> (GlobalRdrEnv -> [GlobalRdrElt])    -- Lookup function
691                  -> RnM (Maybe GlobalRdrElt)
692 -- Checks for exactly one match; reports deprecations
693 -- Returns Nothing, without error, if too few
694 lookupGreRn_help rdr_name lookup
695   = do  { env <- getGlobalRdrEnv
696         ; case lookup env of
697             []    -> return Nothing
698             [gre] -> do { addUsedRdrName True gre rdr_name
699                         ; return (Just gre) }
700             gres  -> do { addNameClashErrRn rdr_name gres
701                         ; return (Just (head gres)) } }
702 \end{code}
703
704 %*********************************************************
705 %*                                                      *
706                 Deprecations
707 %*                                                      *
708 %*********************************************************
709
710 Note [Handling of deprecations]
711 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
712 * We report deprecations at each *occurrence* of the deprecated thing
713   (see Trac #5867)
714
715 * We do not report deprectations for locally-definded names. For a
716   start, we may be exporting a deprecated thing. Also we may use a
717   deprecated thing in the defn of another deprecated things.  We may
718   even use a deprecated thing in the defn of a non-deprecated thing,
719   when changing a module's interface.
720
721 * addUsedRdrNames: we do not report deprecations for sub-binders:
722      - the ".." completion for records
723      - the ".." in an export item 'T(..)'
724      - the things exported by a module export 'module M'
725
726 \begin{code}
727 addUsedRdrName :: Bool -> GlobalRdrElt -> RdrName -> RnM ()
728 -- Record usage of imported RdrNames
729 addUsedRdrName warnIfDeprec gre rdr
730   | isLocalGRE gre = return ()  -- No call to warnIfDeprecated
731                                 -- See Note [Handling of deprecations]
732   | otherwise      = do { env <- getGblEnv
733                         ; when warnIfDeprec $ warnIfDeprecated gre
734                         ; updMutVar (tcg_used_rdrnames env)
735                                     (\s -> Set.insert rdr s) }
736
737 addUsedRdrNames :: [RdrName] -> RnM ()
738 -- Record used sub-binders
739 -- We don't check for imported-ness here, because it's inconvenient
740 -- and not stritly necessary.
741 -- NB: no call to warnIfDeprecated; see Note [Handling of deprecations]
742 addUsedRdrNames rdrs
743   = do { env <- getGblEnv
744        ; updMutVar (tcg_used_rdrnames env)
745                    (\s -> foldr Set.insert s rdrs) }
746
747 warnIfDeprecated :: GlobalRdrElt -> RnM ()
748 warnIfDeprecated gre@(GRE { gre_name = name, gre_prov = Imported (imp_spec : _) })
749   = do { dflags <- getDynFlags
750        ; when (wopt Opt_WarnWarningsDeprecations dflags) $
751          do { iface <- loadInterfaceForName doc name
752             ; case lookupImpDeprec iface gre of
753                 Just txt -> addWarn (mk_msg txt)
754                 Nothing  -> return () } }
755   where
756     mk_msg txt = sep [ sep [ ptext (sLit "In the use of")
757                              <+> pprNonVarNameSpace (occNameSpace (nameOccName name))
758                              <+> quotes (ppr name)
759                            , parens imp_msg <> colon ]
760                      , ppr txt ]
761
762     name_mod = ASSERT2( isExternalName name, ppr name ) nameModule name
763     imp_mod  = importSpecModule imp_spec
764     imp_msg  = ptext (sLit "imported from") <+> ppr imp_mod <> extra
765     extra | imp_mod == moduleName name_mod = empty
766           | otherwise = ptext (sLit ", but defined in") <+> ppr name_mod
767
768     doc = ptext (sLit "The name") <+> quotes (ppr name) <+> ptext (sLit "is mentioned explicitly")
769
770 warnIfDeprecated _ = return ()   -- No deprecations for things defined locally
771
772 lookupImpDeprec :: ModIface -> GlobalRdrElt -> Maybe WarningTxt
773 lookupImpDeprec iface gre
774   = mi_warn_fn iface (gre_name gre) `mplus`  -- Bleat if the thing,
775     case gre_par gre of                      -- or its parent, is warn'd
776        ParentIs p -> mi_warn_fn iface p
777        NoParent   -> Nothing
778 \end{code}
779
780 Note [Used names with interface not loaded]
781 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
782 It's (just) possible to to find a used
783 Name whose interface hasn't been loaded:
784
785 a) It might be a WiredInName; in that case we may not load
786    its interface (although we could).
787
788 b) It might be GHC.Real.fromRational, or GHC.Num.fromInteger
789    These are seen as "used" by the renamer (if -XRebindableSyntax)
790    is on), but the typechecker may discard their uses
791    if in fact the in-scope fromRational is GHC.Read.fromRational,
792    (see tcPat.tcOverloadedLit), and the typechecker sees that the type
793    is fixed, say, to GHC.Base.Float (see Inst.lookupSimpleInst).
794    In that obscure case it won't force the interface in.
795
796 In both cases we simply don't permit deprecations;
797 this is, after all, wired-in stuff.
798
799
800 %*********************************************************
801 %*                                                      *
802                 GHCi support
803 %*                                                      *
804 %*********************************************************
805
806 \begin{code}
807 -- A qualified name on the command line can refer to any module at all: we
808 -- try to load the interface if we don't already have it.
809 lookupQualifiedName :: RdrName -> RnM (Maybe Name)
810 lookupQualifiedName rdr_name
811   | Just (mod,occ) <- isQual_maybe rdr_name
812    -- Note: we want to behave as we would for a source file import here,
813    -- and respect hiddenness of modules/packages, hence loadSrcInterface.
814    = loadSrcInterface doc mod False Nothing     `thenM` \ iface ->
815
816    case  [ name
817          | avail <- mi_exports iface,
818            name  <- availNames avail,
819            nameOccName name == occ ] of
820       (n:ns) -> ASSERT (null ns) return (Just n)
821       _ -> do { traceRn (text "lookupQualified" <+> ppr rdr_name)
822               ; return Nothing }
823
824   | otherwise
825   = pprPanic "RnEnv.lookupQualifiedName" (ppr rdr_name)
826   where
827     doc = ptext (sLit "Need to find") <+> ppr rdr_name
828 \end{code}
829
830 Note [Looking up signature names]
831 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
832 lookupSigOccRn is used for type signatures and pragmas
833 Is this valid?
834   module A
835         import M( f )
836         f :: Int -> Int
837         f x = x
838 It's clear that the 'f' in the signature must refer to A.f
839 The Haskell98 report does not stipulate this, but it will!
840 So we must treat the 'f' in the signature in the same way
841 as the binding occurrence of 'f', using lookupBndrRn
842
843 However, consider this case:
844         import M( f )
845         f :: Int -> Int
846         g x = x
847 We don't want to say 'f' is out of scope; instead, we want to
848 return the imported 'f', so that later on the reanamer will
849 correctly report "misplaced type sig".
850
851 Note [Signatures for top level things]
852 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
853 data HsSigCtxt = ... | TopSigCtxt NameSet Bool | ....
854
855 * The NameSet says what is bound in this group of bindings.
856   We can't use isLocalGRE from the GlobalRdrEnv, because of this:
857        f x = x
858        $( ...some TH splice... )
859        f :: Int -> Int
860   When we encounter the signature for 'f', the binding for 'f'
861   will be in the GlobalRdrEnv, and will be a LocalDef. Yet the
862   signature is mis-placed
863
864 * The Bool says whether the signature is ok for a class method
865   or record selector.  Consider
866       infix 3 `f`          -- Yes, ok
867       f :: C a => a -> a   -- No, not ok
868       class C a where
869         f :: a -> a
870
871 \begin{code}
872 data HsSigCtxt
873   = TopSigCtxt NameSet Bool  -- At top level, binding these names
874                              -- See Note [Signatures for top level things]
875                              -- Bool <=> ok to give sig for
876                              --          class method or record selctor
877   | LocalBindCtxt NameSet    -- In a local binding, binding these names
878   | ClsDeclCtxt   Name       -- Class decl for this class
879   | InstDeclCtxt  Name       -- Intsance decl for this class
880   | HsBootCtxt               -- Top level of a hs-boot file
881
882 lookupSigOccRn :: HsSigCtxt
883                -> Sig RdrName
884                -> Located RdrName -> RnM (Located Name)
885 lookupSigOccRn ctxt sig
886   = wrapLocM $ \ rdr_name ->
887     do { mb_name <- lookupBindGroupOcc ctxt (hsSigDoc sig) rdr_name
888        ; case mb_name of
889            Left err   -> do { addErr err; return (mkUnboundName rdr_name) }
890            Right name -> return name }
891
892 lookupBindGroupOcc :: HsSigCtxt
893                    -> SDoc
894                    -> RdrName -> RnM (Either MsgDoc Name)
895 -- Looks up the RdrName, expecting it to resolve to one of the
896 -- bound names passed in.  If not, return an appropriate error message
897 --
898 -- See Note [Looking up signature names]
899 lookupBindGroupOcc ctxt what rdr_name
900   | Just n <- isExact_maybe rdr_name
901   = do { n' <- lookupExactOcc n
902        ; return (Right n') }  -- Maybe we should check the side conditions
903                               -- but it's a pain, and Exact things only show
904                               -- up when you know what you are doing
905
906   | Just (rdr_mod, rdr_occ) <- isOrig_maybe rdr_name
907   = do { n' <- lookupOrig rdr_mod rdr_occ
908        ; return (Right n') }
909
910   | otherwise
911   = case ctxt of
912       HsBootCtxt            -> lookup_top (const True)       True
913       TopSigCtxt ns meth_ok -> lookup_top (`elemNameSet` ns) meth_ok
914       LocalBindCtxt ns      -> lookup_group ns
915       ClsDeclCtxt  cls      -> lookup_cls_op cls
916       InstDeclCtxt cls      -> lookup_cls_op cls
917   where
918     lookup_cls_op cls
919       = do { env <- getGlobalRdrEnv
920            ; let gres = lookupSubBndrGREs env (ParentIs cls) rdr_name
921            ; case gres of
922                []      -> return (Left (unknownSubordinateErr doc rdr_name))
923                (gre:_) -> return (Right (gre_name gre)) }
924                         -- If there is more than one local GRE for the
925                         -- same OccName 'f', that will be reported separately
926                         -- as a duplicate top-level binding for 'f'
927       where
928         doc = ptext (sLit "method of class") <+> quotes (ppr cls)
929
930     lookup_top keep_me meth_ok
931       = do { env <- getGlobalRdrEnv
932            ; let all_gres = lookupGlobalRdrEnv env (rdrNameOcc rdr_name)
933            ; case filter (keep_me . gre_name) all_gres of
934                [] | null all_gres -> bale_out_with empty
935                   | otherwise -> bale_out_with local_msg
936                (gre:_)
937                   | ParentIs {} <- gre_par gre
938                   , not meth_ok
939                   -> bale_out_with sub_msg
940                   | otherwise
941                   -> return (Right (gre_name gre)) }
942
943     lookup_group bound_names  -- Look in the local envt (not top level)
944       = do { local_env <- getLocalRdrEnv
945            ; case lookupLocalRdrEnv local_env rdr_name of
946                Just n
947                  | n `elemNameSet` bound_names -> return (Right n)
948                  | otherwise                   -> bale_out_with local_msg
949                Nothing                         -> bale_out_with empty }
950
951     bale_out_with msg
952         = return (Left (sep [ ptext (sLit "The") <+> what
953                                 <+> ptext (sLit "for") <+> quotes (ppr rdr_name)
954                            , nest 2 $ ptext (sLit "lacks an accompanying binding")]
955                        $$ nest 2 msg))
956
957     local_msg = parens $ ptext (sLit "The")  <+> what <+> ptext (sLit "must be given where")
958                            <+> quotes (ppr rdr_name) <+> ptext (sLit "is declared")
959
960     sub_msg = parens $ ptext (sLit "You cannot give a") <+> what
961                        <+> ptext (sLit "for a record selector or class method")
962
963
964 ---------------
965 lookupLocalTcNames :: HsSigCtxt -> SDoc -> RdrName -> RnM [Name]
966 -- GHC extension: look up both the tycon and data con or variable.
967 -- Used for top-level fixity signatures and deprecations.
968 -- Complain if neither is in scope.
969 -- See Note [Fixity signature lookup]
970 lookupLocalTcNames ctxt what rdr_name
971   = do { mb_gres <- mapM lookup (dataTcOccs rdr_name)
972        ; let (errs, names) = splitEithers mb_gres
973        ; when (null names) $ addErr (head errs) -- Bleat about one only
974        ; return names }
975   where
976     lookup = lookupBindGroupOcc ctxt what
977
978 dataTcOccs :: RdrName -> [RdrName]
979 -- Return both the given name and the same name promoted to the TcClsName
980 -- namespace.  This is useful when we aren't sure which we are looking at.
981 dataTcOccs rdr_name
982   | Just n <- isExact_maybe rdr_name
983   , not (isBuiltInSyntax n)   -- See Note [dataTcOccs and Exact Names]
984   = [rdr_name]
985   | isDataOcc occ || isVarOcc occ
986   = [rdr_name, rdr_name_tc]
987   | otherwise
988   = [rdr_name]
989   where
990     occ = rdrNameOcc rdr_name
991     rdr_name_tc = setRdrNameSpace rdr_name tcName
992 \end{code}
993
994 Note [dataTcOccs and Exact Names]
995 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
996 Exact RdrNames can occur in code generated by Template Haskell, and generally
997 those references are, well, exact, so it's wrong to return the TyClsName too.
998 But there is an awkward exception for built-in syntax. Example in GHCi
999    :info []
1000 This parses as the Exact RdrName for nilDataCon, but we also want
1001 the list type constructor.
1002
1003 Note that setRdrNameSpace on an Exact name requires the Name to be External,
1004 which it always is for built in syntax.
1005
1006 %*********************************************************
1007 %*                                                      *
1008                 Fixities
1009 %*                                                      *
1010 %*********************************************************
1011
1012 Note [Fixity signature lookup]
1013 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1014 A fixity declaration like
1015
1016     infixr 2 ?
1017
1018 can refer to a value-level operator, e.g.:
1019
1020     (?) :: String -> String -> String
1021
1022 or a type-level operator, like:
1023
1024     data (?) a b = A a | B b
1025
1026 so we extend the lookup of the reader name '?' to the TcClsName namespace, as
1027 well as the original namespace.
1028
1029 The extended lookup is also used in other places, like resolution of
1030 deprecation declarations, and lookup of names in GHCi.
1031
1032 \begin{code}
1033 --------------------------------
1034 type FastStringEnv a = UniqFM a         -- Keyed by FastString
1035
1036
1037 emptyFsEnv  :: FastStringEnv a
1038 lookupFsEnv :: FastStringEnv a -> FastString -> Maybe a
1039 extendFsEnv :: FastStringEnv a -> FastString -> a -> FastStringEnv a
1040
1041 emptyFsEnv  = emptyUFM
1042 lookupFsEnv = lookupUFM
1043 extendFsEnv = addToUFM
1044
1045 --------------------------------
1046 type MiniFixityEnv = FastStringEnv (Located Fixity)
1047         -- Mini fixity env for the names we're about
1048         -- to bind, in a single binding group
1049         --
1050         -- It is keyed by the *FastString*, not the *OccName*, because
1051         -- the single fixity decl       infix 3 T
1052         -- affects both the data constructor T and the type constrctor T
1053         --
1054         -- We keep the location so that if we find
1055         -- a duplicate, we can report it sensibly
1056
1057 --------------------------------
1058 -- Used for nested fixity decls to bind names along with their fixities.
1059 -- the fixities are given as a UFM from an OccName's FastString to a fixity decl
1060
1061 addLocalFixities :: MiniFixityEnv -> [Name] -> RnM a -> RnM a
1062 addLocalFixities mini_fix_env names thing_inside
1063   = extendFixityEnv (mapCatMaybes find_fixity names) thing_inside
1064   where
1065     find_fixity name
1066       = case lookupFsEnv mini_fix_env (occNameFS occ) of
1067           Just (L _ fix) -> Just (name, FixItem occ fix)
1068           Nothing        -> Nothing
1069       where
1070         occ = nameOccName name
1071 \end{code}
1072
1073 --------------------------------
1074 lookupFixity is a bit strange.
1075
1076 * Nested local fixity decls are put in the local fixity env, which we
1077   find with getFixtyEnv
1078
1079 * Imported fixities are found in the HIT or PIT
1080
1081 * Top-level fixity decls in this module may be for Names that are
1082     either  Global         (constructors, class operations)
1083     or      Local/Exported (everything else)
1084   (See notes with RnNames.getLocalDeclBinders for why we have this split.)
1085   We put them all in the local fixity environment
1086
1087 \begin{code}
1088 lookupFixityRn :: Name -> RnM Fixity
1089 lookupFixityRn name
1090   = getModule                           `thenM` \ this_mod ->
1091     if nameIsLocalOrFrom this_mod name
1092     then do     -- It's defined in this module
1093       local_fix_env <- getFixityEnv
1094       traceRn (text "lookupFixityRn: looking up name in local environment:" <+>
1095                vcat [ppr name, ppr local_fix_env])
1096       return $ lookupFixity local_fix_env name
1097     else        -- It's imported
1098       -- For imported names, we have to get their fixities by doing a
1099       -- loadInterfaceForName, and consulting the Ifaces that comes back
1100       -- from that, because the interface file for the Name might not
1101       -- have been loaded yet.  Why not?  Suppose you import module A,
1102       -- which exports a function 'f', thus;
1103       --        module CurrentModule where
1104       --          import A( f )
1105       --        module A( f ) where
1106       --          import B( f )
1107       -- Then B isn't loaded right away (after all, it's possible that
1108       -- nothing from B will be used).  When we come across a use of
1109       -- 'f', we need to know its fixity, and it's then, and only
1110       -- then, that we load B.hi.  That is what's happening here.
1111       --
1112       -- loadInterfaceForName will find B.hi even if B is a hidden module,
1113       -- and that's what we want.
1114         loadInterfaceForName doc name   `thenM` \ iface -> do {
1115           traceRn (text "lookupFixityRn: looking up name in iface cache and found:" <+>
1116                    vcat [ppr name, ppr $ mi_fix_fn iface (nameOccName name)]);
1117            return (mi_fix_fn iface (nameOccName name))
1118                                                            }
1119   where
1120     doc = ptext (sLit "Checking fixity for") <+> ppr name
1121
1122 ---------------
1123 lookupTyFixityRn :: Located Name -> RnM Fixity
1124 lookupTyFixityRn (L _ n) = lookupFixityRn n
1125
1126 \end{code}
1127
1128 %************************************************************************
1129 %*                                                                      *
1130                         Rebindable names
1131         Dealing with rebindable syntax is driven by the
1132         Opt_RebindableSyntax dynamic flag.
1133
1134         In "deriving" code we don't want to use rebindable syntax
1135         so we switch off the flag locally
1136
1137 %*                                                                      *
1138 %************************************************************************
1139
1140 Haskell 98 says that when you say "3" you get the "fromInteger" from the
1141 Standard Prelude, regardless of what is in scope.   However, to experiment
1142 with having a language that is less coupled to the standard prelude, we're
1143 trying a non-standard extension that instead gives you whatever "Prelude.fromInteger"
1144 happens to be in scope.  Then you can
1145         import Prelude ()
1146         import MyPrelude as Prelude
1147 to get the desired effect.
1148
1149 At the moment this just happens for
1150   * fromInteger, fromRational on literals (in expressions and patterns)
1151   * negate (in expressions)
1152   * minus  (arising from n+k patterns)
1153   * "do" notation
1154
1155 We store the relevant Name in the HsSyn tree, in
1156   * HsIntegral/HsFractional/HsIsString
1157   * NegApp
1158   * NPlusKPat
1159   * HsDo
1160 respectively.  Initially, we just store the "standard" name (PrelNames.fromIntegralName,
1161 fromRationalName etc), but the renamer changes this to the appropriate user
1162 name if Opt_NoImplicitPrelude is on.  That is what lookupSyntaxName does.
1163
1164 We treat the orignal (standard) names as free-vars too, because the type checker
1165 checks the type of the user thing against the type of the standard thing.
1166
1167 \begin{code}
1168 lookupIfThenElse :: RnM (Maybe (SyntaxExpr Name), FreeVars)
1169 -- Different to lookupSyntaxName because in the non-rebindable
1170 -- case we desugar directly rather than calling an existing function
1171 -- Hence the (Maybe (SyntaxExpr Name)) return type
1172 lookupIfThenElse
1173   = do { rebind <- xoptM Opt_RebindableSyntax
1174        ; if not rebind
1175          then return (Nothing, emptyFVs)
1176          else do { ite <- lookupOccRn (mkVarUnqual (fsLit "ifThenElse"))
1177                  ; return (Just (HsVar ite), unitFV ite) } }
1178
1179 lookupSyntaxName :: Name                                -- The standard name
1180                  -> RnM (SyntaxExpr Name, FreeVars)     -- Possibly a non-standard name
1181 lookupSyntaxName std_name
1182   = do { rebindable_on <- xoptM Opt_RebindableSyntax
1183        ; if not rebindable_on then 
1184            return (HsVar std_name, emptyFVs)
1185          else
1186             -- Get the similarly named thing from the local environment
1187            do { usr_name <- lookupOccRn (mkRdrUnqual (nameOccName std_name))
1188               ; return (HsVar usr_name, unitFV usr_name) } }
1189
1190 lookupSyntaxNames :: [Name]                          -- Standard names
1191                   -> RnM ([HsExpr Name], FreeVars)   -- See comments with HsExpr.ReboundNames
1192 lookupSyntaxNames std_names
1193   = do { rebindable_on <- xoptM Opt_RebindableSyntax
1194        ; if not rebindable_on then 
1195              return (map HsVar std_names, emptyFVs)
1196         else
1197           do { usr_names <- mapM (lookupOccRn . mkRdrUnqual . nameOccName) std_names
1198              ; return (map HsVar usr_names, mkFVs usr_names) } }
1199 \end{code}
1200
1201
1202 %*********************************************************
1203 %*                                                      *
1204 \subsection{Binding}
1205 %*                                                      *
1206 %*********************************************************
1207
1208 \begin{code}
1209 newLocalBndrRn :: Located RdrName -> RnM Name
1210 -- Used for non-top-level binders.  These should
1211 -- never be qualified.
1212 newLocalBndrRn (L loc rdr_name)
1213   | Just name <- isExact_maybe rdr_name
1214   = return name -- This happens in code generated by Template Haskell
1215                 -- See Note [Binders in Template Haskell] in Convert.lhs
1216   | otherwise
1217   = do { unless (isUnqual rdr_name)
1218                 (addErrAt loc (badQualBndrErr rdr_name))
1219        ; uniq <- newUnique
1220        ; return (mkInternalName uniq (rdrNameOcc rdr_name) loc) }
1221
1222 newLocalBndrsRn :: [Located RdrName] -> RnM [Name]
1223 newLocalBndrsRn = mapM newLocalBndrRn
1224
1225 ---------------------
1226 bindLocatedLocalsRn :: [Located RdrName]
1227                     -> ([Name] -> RnM a)
1228                     -> RnM a
1229 bindLocatedLocalsRn rdr_names_w_loc enclosed_scope
1230   = do { checkDupRdrNames rdr_names_w_loc
1231        ; checkShadowedRdrNames rdr_names_w_loc
1232
1233         -- Make fresh Names and extend the environment
1234        ; names <- newLocalBndrsRn rdr_names_w_loc
1235        ; bindLocalNames names (enclosed_scope names) }
1236
1237 bindLocalNames :: [Name] -> RnM a -> RnM a
1238 bindLocalNames names enclosed_scope
1239   = do { name_env <- getLocalRdrEnv
1240        ; setLocalRdrEnv (extendLocalRdrEnvList name_env names)
1241                         enclosed_scope }
1242
1243 bindLocalName :: Name -> RnM a -> RnM a
1244 bindLocalName name enclosed_scope
1245   = do { name_env <- getLocalRdrEnv
1246        ; setLocalRdrEnv (extendLocalRdrEnv name_env name)
1247                         enclosed_scope }
1248
1249 bindLocalNamesFV :: [Name] -> RnM (a, FreeVars) -> RnM (a, FreeVars)
1250 bindLocalNamesFV names enclosed_scope
1251   = do  { (result, fvs) <- bindLocalNames names enclosed_scope
1252         ; return (result, delFVs names fvs) }
1253
1254
1255 -------------------------------------
1256         -- binLocalsFVRn is the same as bindLocalsRn
1257         -- except that it deals with free vars
1258 bindLocatedLocalsFV :: [Located RdrName]
1259                     -> ([Name] -> RnM (a,FreeVars)) -> RnM (a, FreeVars)
1260 bindLocatedLocalsFV rdr_names enclosed_scope
1261   = bindLocatedLocalsRn rdr_names       $ \ names ->
1262     enclosed_scope names                `thenM` \ (thing, fvs) ->
1263     return (thing, delFVs names fvs)
1264
1265 -------------------------------------
1266
1267 extendTyVarEnvFVRn :: [Name] -> RnM (a, FreeVars) -> RnM (a, FreeVars)
1268         -- This function is used only in rnSourceDecl on InstDecl
1269 extendTyVarEnvFVRn tyvars thing_inside = bindLocalNamesFV tyvars thing_inside
1270
1271 -------------------------------------
1272 checkDupRdrNames :: [Located RdrName] -> RnM ()
1273 -- Check for duplicated names in a binding group
1274 checkDupRdrNames rdr_names_w_loc
1275   = mapM_ (dupNamesErr getLoc) dups
1276   where
1277     (_, dups) = removeDups (\n1 n2 -> unLoc n1 `compare` unLoc n2) rdr_names_w_loc
1278
1279 checkDupNames :: [Name] -> RnM ()
1280 -- Check for duplicated names in a binding group
1281 checkDupNames names = check_dup_names (filterOut isSystemName names)
1282                 -- See Note [Binders in Template Haskell] in Convert
1283
1284 check_dup_names :: [Name] -> RnM ()
1285 check_dup_names names
1286   = mapM_ (dupNamesErr nameSrcSpan) dups
1287   where
1288     (_, dups) = removeDups (\n1 n2 -> nameOccName n1 `compare` nameOccName n2) names
1289
1290 ---------------------
1291 checkShadowedRdrNames :: [Located RdrName] -> RnM ()
1292 checkShadowedRdrNames loc_rdr_names
1293   = do { envs <- getRdrEnvs
1294        ; checkShadowedOccs envs loc_occs }
1295   where
1296     loc_occs = [(loc,rdrNameOcc rdr) | L loc rdr <- loc_rdr_names]
1297
1298 checkDupAndShadowedNames :: (GlobalRdrEnv, LocalRdrEnv) -> [Name] -> RnM ()
1299 checkDupAndShadowedNames envs names
1300   = do { check_dup_names filtered_names
1301        ; checkShadowedOccs envs loc_occs }
1302   where
1303     filtered_names = filterOut isSystemName names
1304                 -- See Note [Binders in Template Haskell] in Convert
1305     loc_occs = [(nameSrcSpan name, nameOccName name) | name <- filtered_names]
1306
1307 -------------------------------------
1308 checkShadowedOccs :: (GlobalRdrEnv, LocalRdrEnv) -> [(SrcSpan,OccName)] -> RnM ()
1309 checkShadowedOccs (global_env,local_env) loc_occs
1310   = ifWOptM Opt_WarnNameShadowing $
1311     do  { traceRn (text "shadow" <+> ppr loc_occs)
1312         ; mapM_ check_shadow loc_occs }
1313   where
1314     check_shadow (loc, occ)
1315         | startsWithUnderscore occ = return ()  -- Do not report shadowing for "_x"
1316                                                 -- See Trac #3262
1317         | Just n <- mb_local = complain [ptext (sLit "bound at") <+> ppr (nameSrcLoc n)]
1318         | otherwise = do { gres' <- filterM is_shadowed_gre gres
1319                          ; complain (map pprNameProvenance gres') }
1320         where
1321           complain []      = return ()
1322           complain pp_locs = addWarnAt loc (shadowedNameWarn occ pp_locs)
1323           mb_local = lookupLocalRdrOcc local_env occ
1324           gres     = lookupGRE_RdrName (mkRdrUnqual occ) global_env
1325                 -- Make an Unqualified RdrName and look that up, so that
1326                 -- we don't find any GREs that are in scope qualified-only
1327
1328     is_shadowed_gre :: GlobalRdrElt -> RnM Bool
1329         -- Returns False for record selectors that are shadowed, when
1330         -- punning or wild-cards are on (cf Trac #2723)
1331     is_shadowed_gre gre@(GRE { gre_par = ParentIs _ })
1332         = do { dflags <- getDynFlags
1333              ; if (xopt Opt_RecordPuns dflags || xopt Opt_RecordWildCards dflags)
1334                then do { is_fld <- is_rec_fld gre; return (not is_fld) }
1335                else return True }
1336     is_shadowed_gre _other = return True
1337
1338     is_rec_fld gre      -- Return True for record selector ids
1339         | isLocalGRE gre = do { RecFields _ fld_set <- getRecFieldEnv
1340                               ; return (gre_name gre `elemNameSet` fld_set) }
1341         | otherwise      = do { sel_id <- tcLookupField (gre_name gre)
1342                               ; return (isRecordSelector sel_id) }
1343 \end{code}
1344
1345
1346 %************************************************************************
1347 %*                                                                      *
1348                What to do when a lookup fails
1349 %*                                                                      *
1350 %************************************************************************
1351
1352 \begin{code}
1353 data WhereLooking = WL_Any        -- Any binding
1354                   | WL_Global     -- Any top-level binding (local or imported)
1355                   | WL_LocalTop   -- Any top-level binding in this module
1356
1357 unboundName :: WhereLooking -> RdrName -> RnM Name
1358 unboundName wl rdr = unboundNameX wl rdr empty
1359
1360 unboundNameX :: WhereLooking -> RdrName -> SDoc -> RnM Name
1361 unboundNameX where_look rdr_name extra
1362   = do  { show_helpful_errors <- doptM Opt_HelpfulErrors
1363         ; let what = pprNonVarNameSpace (occNameSpace (rdrNameOcc rdr_name))
1364               err = unknownNameErr what rdr_name $$ extra
1365         ; if not show_helpful_errors
1366           then addErr err
1367           else do { suggestions <- unknownNameSuggestErr where_look rdr_name
1368                   ; addErr (err $$ suggestions) }
1369
1370         ; return (mkUnboundName rdr_name) }
1371
1372 unknownNameErr :: SDoc -> RdrName -> SDoc
1373 unknownNameErr what rdr_name
1374   = vcat [ hang (ptext (sLit "Not in scope:"))
1375               2 (what <+> quotes (ppr rdr_name))
1376          , extra ]
1377   where
1378     extra | rdr_name == forall_tv_RDR = perhapsForallMsg
1379           | otherwise                 = empty
1380
1381 type HowInScope = Either SrcSpan ImpDeclSpec
1382      -- Left loc    =>  locally bound at loc
1383      -- Right ispec =>  imported as specified by ispec
1384
1385 unknownNameSuggestErr :: WhereLooking -> RdrName -> RnM SDoc
1386 unknownNameSuggestErr where_look tried_rdr_name
1387   = do { local_env <- getLocalRdrEnv
1388        ; global_env <- getGlobalRdrEnv
1389        ; dflags <- getDynFlags
1390
1391        ; let all_possibilities :: [(String, (RdrName, HowInScope))]
1392              all_possibilities
1393                 =  [ (showPpr dflags r, (r, Left loc))
1394                    | (r,loc) <- local_possibilities local_env ]
1395                 ++ [ (showPpr dflags r, rp) | (r,rp) <- global_possibilities global_env ]
1396
1397              suggest = fuzzyLookup (showPpr dflags tried_rdr_name) all_possibilities
1398              perhaps = ptext (sLit "Perhaps you meant")
1399              extra_err = case suggest of
1400                            []  -> empty
1401                            [p] -> perhaps <+> pp_item p
1402                            ps  -> sep [ perhaps <+> ptext (sLit "one of these:")
1403                                       , nest 2 (pprWithCommas pp_item ps) ]
1404        ; return extra_err }
1405   where
1406     pp_item :: (RdrName, HowInScope) -> SDoc
1407     pp_item (rdr, Left loc) = quotes (ppr rdr) <+> loc' -- Locally defined
1408         where loc' = case loc of
1409                      UnhelpfulSpan l -> parens (ppr l)
1410                      RealSrcSpan l -> parens (ptext (sLit "line") <+> int (srcSpanStartLine l))
1411     pp_item (rdr, Right is) = quotes (ppr rdr) <+>   -- Imported
1412                               parens (ptext (sLit "imported from") <+> ppr (is_mod is))
1413
1414     tried_occ     = rdrNameOcc tried_rdr_name
1415     tried_is_sym  = isSymOcc tried_occ
1416     tried_ns      = occNameSpace tried_occ
1417     tried_is_qual = isQual tried_rdr_name
1418
1419     correct_name_space occ =  occNameSpace occ == tried_ns
1420                            && isSymOcc occ == tried_is_sym
1421         -- Treat operator and non-operators as non-matching
1422         -- This heuristic avoids things like
1423         --      Not in scope 'f'; perhaps you meant '+' (from Prelude)
1424
1425     local_ok = case where_look of { WL_Any -> True; _ -> False }
1426     local_possibilities :: LocalRdrEnv -> [(RdrName, SrcSpan)]
1427     local_possibilities env
1428       | tried_is_qual = []
1429       | not local_ok  = []
1430       | otherwise     = [ (mkRdrUnqual occ, nameSrcSpan name)
1431                         | name <- localRdrEnvElts env
1432                         , let occ = nameOccName name
1433                         , correct_name_space occ]
1434
1435     gre_ok :: GlobalRdrElt -> Bool
1436     gre_ok = case where_look of
1437                    WL_LocalTop -> isLocalGRE
1438                    _           -> \_ -> True
1439
1440     global_possibilities :: GlobalRdrEnv -> [(RdrName, (RdrName, HowInScope))]
1441     global_possibilities global_env
1442       | tried_is_qual = [ (rdr_qual, (rdr_qual, how))
1443                         | gre <- globalRdrEnvElts global_env
1444                         , gre_ok gre
1445                         , let name = gre_name gre
1446                               occ  = nameOccName name
1447                         , correct_name_space occ
1448                         , (mod, how) <- quals_in_scope name (gre_prov gre)
1449                         , let rdr_qual = mkRdrQual mod occ ]
1450
1451       | otherwise = [ (rdr_unqual, pair)
1452                     | gre <- globalRdrEnvElts global_env
1453                     , gre_ok gre
1454                     , let name = gre_name gre
1455                           prov = gre_prov gre
1456                           occ  = nameOccName name
1457                           rdr_unqual = mkRdrUnqual occ
1458                     , correct_name_space occ
1459                     , pair <- case (unquals_in_scope name prov, quals_only occ prov) of
1460                                 (how:_, _)    -> [ (rdr_unqual, how) ]
1461                                 ([],    pr:_) -> [ pr ]  -- See Note [Only-quals]
1462                                 ([],    [])   -> [] ]
1463
1464               -- Note [Only-quals]
1465               -- The second alternative returns those names with the same
1466               -- OccName as the one we tried, but live in *qualified* imports
1467               -- e.g. if you have:
1468               --
1469               -- > import qualified Data.Map as Map
1470               -- > foo :: Map
1471               --
1472               -- then we suggest @Map.Map@.
1473
1474     --------------------
1475     unquals_in_scope :: Name -> Provenance -> [HowInScope]
1476     unquals_in_scope n LocalDef      = [ Left (nameSrcSpan n) ]
1477     unquals_in_scope _ (Imported is) = [ Right ispec
1478                                        | i <- is, let ispec = is_decl i
1479                                        , not (is_qual ispec) ]
1480
1481     --------------------
1482     quals_in_scope :: Name -> Provenance -> [(ModuleName, HowInScope)]
1483     -- Ones for which the qualified version is in scope
1484     quals_in_scope n LocalDef      = case nameModule_maybe n of
1485                                        Nothing -> []
1486                                        Just m  -> [(moduleName m, Left (nameSrcSpan n))]
1487     quals_in_scope _ (Imported is) = [ (is_as ispec, Right ispec)
1488                                      | i <- is, let ispec = is_decl i ]
1489
1490     --------------------
1491     quals_only :: OccName -> Provenance -> [(RdrName, HowInScope)]
1492     -- Ones for which *only* the qualified version is in scope
1493     quals_only _   LocalDef      = []
1494     quals_only occ (Imported is) = [ (mkRdrQual (is_as ispec) occ, Right ispec)
1495                                    | i <- is, let ispec = is_decl i, is_qual ispec ]
1496 \end{code}
1497
1498 %************************************************************************
1499 %*                                                                      *
1500 \subsection{Free variable manipulation}
1501 %*                                                                      *
1502 %************************************************************************
1503
1504 \begin{code}
1505 -- A useful utility
1506 addFvRn :: FreeVars -> RnM (thing, FreeVars) -> RnM (thing, FreeVars)
1507 addFvRn fvs1 thing_inside = do { (res, fvs2) <- thing_inside
1508                                ; return (res, fvs1 `plusFV` fvs2) }
1509
1510 mapFvRn :: (a -> RnM (b, FreeVars)) -> [a] -> RnM ([b], FreeVars)
1511 mapFvRn f xs = do stuff <- mapM f xs
1512                   case unzip stuff of
1513                       (ys, fvs_s) -> return (ys, plusFVs fvs_s)
1514
1515 mapMaybeFvRn :: (a -> RnM (b, FreeVars)) -> Maybe a -> RnM (Maybe b, FreeVars)
1516 mapMaybeFvRn _ Nothing = return (Nothing, emptyFVs)
1517 mapMaybeFvRn f (Just x) = do { (y, fvs) <- f x; return (Just y, fvs) }
1518
1519 -- because some of the rename functions are CPSed:
1520 -- maps the function across the list from left to right;
1521 -- collects all the free vars into one set
1522 mapFvRnCPS :: (a  -> (b   -> RnM c) -> RnM c)
1523            -> [a] -> ([b] -> RnM c) -> RnM c
1524
1525 mapFvRnCPS _ []     cont = cont []
1526 mapFvRnCPS f (x:xs) cont = f x             $ \ x' ->
1527                            mapFvRnCPS f xs $ \ xs' ->
1528                            cont (x':xs')
1529 \end{code}
1530
1531
1532 %************************************************************************
1533 %*                                                                      *
1534 \subsection{Envt utility functions}
1535 %*                                                                      *
1536 %************************************************************************
1537
1538 \begin{code}
1539 warnUnusedTopBinds :: [GlobalRdrElt] -> RnM ()
1540 warnUnusedTopBinds gres
1541     = ifWOptM Opt_WarnUnusedBinds
1542     $ do isBoot <- tcIsHsBoot
1543          let noParent gre = case gre_par gre of
1544                             NoParent -> True
1545                             ParentIs _ -> False
1546              -- Don't warn about unused bindings with parents in
1547              -- .hs-boot files, as you are sometimes required to give
1548              -- unused bindings (trac #3449).
1549              gres' = if isBoot then filter noParent gres
1550                                else                 gres
1551          warnUnusedGREs gres'
1552
1553 warnUnusedLocalBinds, warnUnusedMatches :: [Name] -> FreeVars -> RnM ()
1554 warnUnusedLocalBinds = check_unused Opt_WarnUnusedBinds
1555 warnUnusedMatches    = check_unused Opt_WarnUnusedMatches
1556
1557 check_unused :: WarningFlag -> [Name] -> FreeVars -> RnM ()
1558 check_unused flag bound_names used_names
1559  = ifWOptM flag (warnUnusedLocals (filterOut (`elemNameSet` used_names) bound_names))
1560
1561 -------------------------
1562 --      Helpers
1563 warnUnusedGREs :: [GlobalRdrElt] -> RnM ()
1564 warnUnusedGREs gres
1565  = warnUnusedBinds [(n,p) | GRE {gre_name = n, gre_prov = p} <- gres]
1566
1567 warnUnusedLocals :: [Name] -> RnM ()
1568 warnUnusedLocals names
1569  = warnUnusedBinds [(n,LocalDef) | n<-names]
1570
1571 warnUnusedBinds :: [(Name,Provenance)] -> RnM ()
1572 warnUnusedBinds names  = mapM_ warnUnusedName (filter reportable names)
1573  where reportable (name,_)
1574         | isWiredInName name = False    -- Don't report unused wired-in names
1575                                         -- Otherwise we get a zillion warnings
1576                                         -- from Data.Tuple
1577         | otherwise = not (startsWithUnderscore (nameOccName name))
1578
1579 -------------------------
1580
1581 warnUnusedName :: (Name, Provenance) -> RnM ()
1582 warnUnusedName (name, LocalDef)
1583   = addUnusedWarning name (nameSrcSpan name)
1584                      (ptext (sLit "Defined but not used"))
1585
1586 warnUnusedName (name, Imported is)
1587   = mapM_ warn is
1588   where
1589     warn spec = addUnusedWarning name span msg
1590         where
1591            span = importSpecLoc spec
1592            pp_mod = quotes (ppr (importSpecModule spec))
1593            msg = ptext (sLit "Imported from") <+> pp_mod <+> ptext (sLit "but not used")
1594
1595 addUnusedWarning :: Name -> SrcSpan -> SDoc -> RnM ()
1596 addUnusedWarning name span msg
1597   = addWarnAt span $
1598     sep [msg <> colon,
1599          nest 2 $ pprNonVarNameSpace (occNameSpace (nameOccName name))
1600                         <+> quotes (ppr name)]
1601 \end{code}
1602
1603 \begin{code}
1604 addNameClashErrRn :: RdrName -> [GlobalRdrElt] -> RnM ()
1605 addNameClashErrRn rdr_name gres
1606   | all isLocalGRE gres  -- If there are two or more *local* defns, we'll have reported
1607   = return ()            -- that already, and we don't want an error cascade
1608   | otherwise
1609   = addErr (vcat [ptext (sLit "Ambiguous occurrence") <+> quotes (ppr rdr_name),
1610                   ptext (sLit "It could refer to") <+> vcat (msg1 : msgs)])
1611   where
1612     (np1:nps) = gres
1613     msg1 = ptext  (sLit "either") <+> mk_ref np1
1614     msgs = [ptext (sLit "    or") <+> mk_ref np | np <- nps]
1615     mk_ref gre = sep [quotes (ppr (gre_name gre)) <> comma, pprNameProvenance gre]
1616
1617 shadowedNameWarn :: OccName -> [SDoc] -> SDoc
1618 shadowedNameWarn occ shadowed_locs
1619   = sep [ptext (sLit "This binding for") <+> quotes (ppr occ)
1620             <+> ptext (sLit "shadows the existing binding") <> plural shadowed_locs,
1621          nest 2 (vcat shadowed_locs)]
1622
1623 perhapsForallMsg :: SDoc
1624 perhapsForallMsg
1625   = vcat [ ptext (sLit "Perhaps you intended to use -XExplicitForAll or similar flag")
1626          , ptext (sLit "to enable explicit-forall syntax: forall <tvs>. <type>")]
1627
1628 unknownSubordinateErr :: SDoc -> RdrName -> SDoc
1629 unknownSubordinateErr doc op    -- Doc is "method of class" or
1630                                 -- "field of constructor"
1631   = quotes (ppr op) <+> ptext (sLit "is not a (visible)") <+> doc
1632
1633 badOrigBinding :: RdrName -> SDoc
1634 badOrigBinding name
1635   = ptext (sLit "Illegal binding of built-in syntax:") <+> ppr (rdrNameOcc name)
1636         -- The rdrNameOcc is because we don't want to print Prelude.(,)
1637
1638 dupNamesErr :: Outputable n => (n -> SrcSpan) -> [n] -> RnM ()
1639 dupNamesErr get_loc names
1640   = addErrAt big_loc $
1641     vcat [ptext (sLit "Conflicting definitions for") <+> quotes (ppr (head names)),
1642           locations]
1643   where
1644     locs      = map get_loc names
1645     big_loc   = foldr1 combineSrcSpans locs
1646     locations = ptext (sLit "Bound at:") <+> vcat (map ppr (sort locs))
1647
1648 kindSigErr :: Outputable a => a -> SDoc
1649 kindSigErr thing
1650   = hang (ptext (sLit "Illegal kind signature for") <+> quotes (ppr thing))
1651        2 (ptext (sLit "Perhaps you intended to use -XKindSignatures"))
1652
1653 badQualBndrErr :: RdrName -> SDoc
1654 badQualBndrErr rdr_name
1655   = ptext (sLit "Qualified name in binding position:") <+> ppr rdr_name
1656
1657 opDeclErr :: RdrName -> SDoc
1658 opDeclErr n
1659   = hang (ptext (sLit "Illegal declaration of a type or class operator") <+> quotes (ppr n))
1660        2 (ptext (sLit "Use -XTypeOperators to declare operators in type and declarations"))
1661
1662 checkTupSize :: Int -> RnM ()
1663 checkTupSize tup_size
1664   | tup_size <= mAX_TUPLE_SIZE
1665   = return ()
1666   | otherwise
1667   = addErr (sep [ptext (sLit "A") <+> int tup_size <> ptext (sLit "-tuple is too large for GHC"),
1668                  nest 2 (parens (ptext (sLit "max size is") <+> int mAX_TUPLE_SIZE)),
1669                  nest 2 (ptext (sLit "Workaround: use nested tuples or define a data type"))])
1670 \end{code}
1671
1672
1673 %************************************************************************
1674 %*                                                                      *
1675 \subsection{Contexts for renaming errors}
1676 %*                                                                      *
1677 %************************************************************************
1678
1679 \begin{code}
1680
1681 data HsDocContext
1682   = TypeSigCtx SDoc
1683   | PatCtx
1684   | SpecInstSigCtx
1685   | DefaultDeclCtx
1686   | ForeignDeclCtx (Located RdrName)
1687   | DerivDeclCtx
1688   | RuleCtx FastString
1689   | TyDataCtx (Located RdrName)
1690   | TySynCtx (Located RdrName)
1691   | TyFamilyCtx (Located RdrName)
1692   | ConDeclCtx (Located RdrName)
1693   | ClassDeclCtx (Located RdrName)
1694   | ExprWithTySigCtx
1695   | TypBrCtx
1696   | HsTypeCtx
1697   | GHCiCtx
1698   | SpliceTypeCtx (LHsType RdrName)
1699   | ClassInstanceCtx
1700   | VectDeclCtx (Located RdrName)
1701   | GenericCtx SDoc   -- Maybe we want to use this more!
1702
1703 docOfHsDocContext :: HsDocContext -> SDoc
1704 docOfHsDocContext (GenericCtx doc) = doc
1705 docOfHsDocContext (TypeSigCtx doc) = text "In the type signature for" <+> doc
1706 docOfHsDocContext PatCtx = text "In a pattern type-signature"
1707 docOfHsDocContext SpecInstSigCtx = text "In a SPECIALISE instance pragma"
1708 docOfHsDocContext DefaultDeclCtx = text "In a `default' declaration"
1709 docOfHsDocContext (ForeignDeclCtx name) = ptext (sLit "In the foreign declaration for") <+> ppr name
1710 docOfHsDocContext DerivDeclCtx = text "In a deriving declaration"
1711 docOfHsDocContext (RuleCtx name) = text "In the transformation rule" <+> ftext name
1712 docOfHsDocContext (TyDataCtx tycon) = text "In the data type declaration for" <+> quotes (ppr tycon)
1713 docOfHsDocContext (TySynCtx name) = text "In the declaration for type synonym" <+> quotes (ppr name)
1714 docOfHsDocContext (TyFamilyCtx name) = text "In the declaration for type family" <+> quotes (ppr name)
1715 docOfHsDocContext (ConDeclCtx name) = text "In the definition of data constructor" <+> quotes (ppr name)
1716 docOfHsDocContext (ClassDeclCtx name) = text "In the declaration for class"     <+> ppr name
1717 docOfHsDocContext ExprWithTySigCtx = text "In an expression type signature"
1718 docOfHsDocContext TypBrCtx = ptext (sLit "In a Template-Haskell quoted type")
1719 docOfHsDocContext HsTypeCtx = text "In a type argument"
1720 docOfHsDocContext GHCiCtx = ptext (sLit "In GHCi input")
1721 docOfHsDocContext (SpliceTypeCtx hs_ty) = ptext (sLit "In the spliced type") <+> ppr hs_ty
1722 docOfHsDocContext ClassInstanceCtx = ptext (sLit "TcSplice.reifyInstances")
1723 docOfHsDocContext (VectDeclCtx tycon) = ptext (sLit "In the VECTORISE pragma for type constructor") <+> quotes (ppr tycon)
1724 \end{code}