Rename SigTv to TyVarTv (#15480)
[ghc.git] / compiler / typecheck / TcUnify.hs
1 {-
2 (c) The University of Glasgow 2006
3 (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4
5
6 Type subsumption and unification
7 -}
8
9 {-# LANGUAGE CPP, MultiWayIf, TupleSections, ScopedTypeVariables #-}
10
11 module TcUnify (
12 -- Full-blown subsumption
13 tcWrapResult, tcWrapResultO, tcSkolemise, tcSkolemiseET,
14 tcSubTypeHR, tcSubTypeO, tcSubType_NC, tcSubTypeDS,
15 tcSubTypeDS_NC_O, tcSubTypeET,
16 checkConstraints, checkTvConstraints,
17 buildImplicationFor,
18
19 -- Various unifications
20 unifyType, unifyKind,
21 uType, promoteTcType,
22 swapOverTyVars, canSolveByUnification,
23
24 --------------------------------
25 -- Holes
26 tcInferInst, tcInferNoInst,
27 matchExpectedListTy,
28 matchExpectedTyConApp,
29 matchExpectedAppTy,
30 matchExpectedFunTys,
31 matchActualFunTys, matchActualFunTysPart,
32 matchExpectedFunKind,
33
34 metaTyVarUpdateOK, occCheckForErrors, OccCheckResult(..)
35
36 ) where
37
38 #include "HsVersions.h"
39
40 import GhcPrelude
41
42 import HsSyn
43 import TyCoRep
44 import TcMType
45 import TcRnMonad
46 import TcType
47 import Type
48 import Coercion
49 import TcEvidence
50 import Name( isSystemName )
51 import Inst
52 import TyCon
53 import TysWiredIn
54 import TysPrim( tYPE )
55 import Var
56 import VarSet
57 import VarEnv
58 import ErrUtils
59 import DynFlags
60 import BasicTypes
61 import Bag
62 import Util
63 import qualified GHC.LanguageExtensions as LangExt
64 import Outputable
65
66 import Control.Monad
67 import Control.Arrow ( second )
68
69 {-
70 ************************************************************************
71 * *
72 matchExpected functions
73 * *
74 ************************************************************************
75
76 Note [Herald for matchExpectedFunTys]
77 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
78 The 'herald' always looks like:
79 "The equation(s) for 'f' have"
80 "The abstraction (\x.e) takes"
81 "The section (+ x) expects"
82 "The function 'f' is applied to"
83
84 This is used to construct a message of form
85
86 The abstraction `\Just 1 -> ...' takes two arguments
87 but its type `Maybe a -> a' has only one
88
89 The equation(s) for `f' have two arguments
90 but its type `Maybe a -> a' has only one
91
92 The section `(f 3)' requires 'f' to take two arguments
93 but its type `Int -> Int' has only one
94
95 The function 'f' is applied to two arguments
96 but its type `Int -> Int' has only one
97
98 When visible type applications (e.g., `f @Int 1 2`, as in #13902) enter the
99 picture, we have a choice in deciding whether to count the type applications as
100 proper arguments:
101
102 The function 'f' is applied to one visible type argument
103 and two value arguments
104 but its type `forall a. a -> a` has only one visible type argument
105 and one value argument
106
107 Or whether to include the type applications as part of the herald itself:
108
109 The expression 'f @Int' is applied to two arguments
110 but its type `Int -> Int` has only one
111
112 The latter is easier to implement and is arguably easier to understand, so we
113 choose to implement that option.
114
115 Note [matchExpectedFunTys]
116 ~~~~~~~~~~~~~~~~~~~~~~~~~~
117 matchExpectedFunTys checks that a sigma has the form
118 of an n-ary function. It passes the decomposed type to the
119 thing_inside, and returns a wrapper to coerce between the two types
120
121 It's used wherever a language construct must have a functional type,
122 namely:
123 A lambda expression
124 A function definition
125 An operator section
126
127 This function must be written CPS'd because it needs to fill in the
128 ExpTypes produced for arguments before it can fill in the ExpType
129 passed in.
130
131 -}
132
133 -- Use this one when you have an "expected" type.
134 matchExpectedFunTys :: forall a.
135 SDoc -- See Note [Herald for matchExpectedFunTys]
136 -> Arity
137 -> ExpRhoType -- deeply skolemised
138 -> ([ExpSigmaType] -> ExpRhoType -> TcM a)
139 -- must fill in these ExpTypes here
140 -> TcM (a, HsWrapper)
141 -- If matchExpectedFunTys n ty = (_, wrap)
142 -- then wrap : (t1 -> ... -> tn -> ty_r) ~> ty,
143 -- where [t1, ..., tn], ty_r are passed to the thing_inside
144 matchExpectedFunTys herald arity orig_ty thing_inside
145 = case orig_ty of
146 Check ty -> go [] arity ty
147 _ -> defer [] arity orig_ty
148 where
149 go acc_arg_tys 0 ty
150 = do { result <- thing_inside (reverse acc_arg_tys) (mkCheckExpType ty)
151 ; return (result, idHsWrapper) }
152
153 go acc_arg_tys n ty
154 | Just ty' <- tcView ty = go acc_arg_tys n ty'
155
156 go acc_arg_tys n (FunTy arg_ty res_ty)
157 = ASSERT( not (isPredTy arg_ty) )
158 do { (result, wrap_res) <- go (mkCheckExpType arg_ty : acc_arg_tys)
159 (n-1) res_ty
160 ; return ( result
161 , mkWpFun idHsWrapper wrap_res arg_ty res_ty doc ) }
162 where
163 doc = text "When inferring the argument type of a function with type" <+>
164 quotes (ppr orig_ty)
165
166 go acc_arg_tys n ty@(TyVarTy tv)
167 | isMetaTyVar tv
168 = do { cts <- readMetaTyVar tv
169 ; case cts of
170 Indirect ty' -> go acc_arg_tys n ty'
171 Flexi -> defer acc_arg_tys n (mkCheckExpType ty) }
172
173 -- In all other cases we bale out into ordinary unification
174 -- However unlike the meta-tyvar case, we are sure that the
175 -- number of arguments doesn't match arity of the original
176 -- type, so we can add a bit more context to the error message
177 -- (cf Trac #7869).
178 --
179 -- It is not always an error, because specialized type may have
180 -- different arity, for example:
181 --
182 -- > f1 = f2 'a'
183 -- > f2 :: Monad m => m Bool
184 -- > f2 = undefined
185 --
186 -- But in that case we add specialized type into error context
187 -- anyway, because it may be useful. See also Trac #9605.
188 go acc_arg_tys n ty = addErrCtxtM mk_ctxt $
189 defer acc_arg_tys n (mkCheckExpType ty)
190
191 ------------
192 defer :: [ExpSigmaType] -> Arity -> ExpRhoType -> TcM (a, HsWrapper)
193 defer acc_arg_tys n fun_ty
194 = do { more_arg_tys <- replicateM n newInferExpTypeNoInst
195 ; res_ty <- newInferExpTypeInst
196 ; result <- thing_inside (reverse acc_arg_tys ++ more_arg_tys) res_ty
197 ; more_arg_tys <- mapM readExpType more_arg_tys
198 ; res_ty <- readExpType res_ty
199 ; let unif_fun_ty = mkFunTys more_arg_tys res_ty
200 ; wrap <- tcSubTypeDS AppOrigin GenSigCtxt unif_fun_ty fun_ty
201 -- Not a good origin at all :-(
202 ; return (result, wrap) }
203
204 ------------
205 mk_ctxt :: TidyEnv -> TcM (TidyEnv, MsgDoc)
206 mk_ctxt env = do { (env', ty) <- zonkTidyTcType env orig_tc_ty
207 ; let (args, _) = tcSplitFunTys ty
208 n_actual = length args
209 (env'', orig_ty') = tidyOpenType env' orig_tc_ty
210 ; return ( env''
211 , mk_fun_tys_msg orig_ty' ty n_actual arity herald) }
212 where
213 orig_tc_ty = checkingExpType "matchExpectedFunTys" orig_ty
214 -- this is safe b/c we're called from "go"
215
216 -- Like 'matchExpectedFunTys', but used when you have an "actual" type,
217 -- for example in function application
218 matchActualFunTys :: SDoc -- See Note [Herald for matchExpectedFunTys]
219 -> CtOrigin
220 -> Maybe (HsExpr GhcRn) -- the thing with type TcSigmaType
221 -> Arity
222 -> TcSigmaType
223 -> TcM (HsWrapper, [TcSigmaType], TcSigmaType)
224 -- If matchActualFunTys n ty = (wrap, [t1,..,tn], ty_r)
225 -- then wrap : ty ~> (t1 -> ... -> tn -> ty_r)
226 matchActualFunTys herald ct_orig mb_thing arity ty
227 = matchActualFunTysPart herald ct_orig mb_thing arity ty [] arity
228
229 -- | Variant of 'matchActualFunTys' that works when supplied only part
230 -- (that is, to the right of some arrows) of the full function type
231 matchActualFunTysPart :: SDoc -- See Note [Herald for matchExpectedFunTys]
232 -> CtOrigin
233 -> Maybe (HsExpr GhcRn) -- the thing with type TcSigmaType
234 -> Arity
235 -> TcSigmaType
236 -> [TcSigmaType] -- reversed args. See (*) below.
237 -> Arity -- overall arity of the function, for errs
238 -> TcM (HsWrapper, [TcSigmaType], TcSigmaType)
239 matchActualFunTysPart herald ct_orig mb_thing arity orig_ty
240 orig_old_args full_arity
241 = go arity orig_old_args orig_ty
242 -- Does not allocate unnecessary meta variables: if the input already is
243 -- a function, we just take it apart. Not only is this efficient,
244 -- it's important for higher rank: the argument might be of form
245 -- (forall a. ty) -> other
246 -- If allocated (fresh-meta-var1 -> fresh-meta-var2) and unified, we'd
247 -- hide the forall inside a meta-variable
248
249 -- (*) Sometimes it's necessary to call matchActualFunTys with only part
250 -- (that is, to the right of some arrows) of the type of the function in
251 -- question. (See TcExpr.tcArgs.) This argument is the reversed list of
252 -- arguments already seen (that is, not part of the TcSigmaType passed
253 -- in elsewhere).
254
255 where
256 -- This function has a bizarre mechanic: it accumulates arguments on
257 -- the way down and also builds an argument list on the way up. Why:
258 -- 1. The returns args list and the accumulated args list might be different.
259 -- The accumulated args include all the arg types for the function,
260 -- including those from before this function was called. The returned
261 -- list should include only those arguments produced by this call of
262 -- matchActualFunTys
263 --
264 -- 2. The HsWrapper can be built only on the way up. It seems (more)
265 -- bizarre to build the HsWrapper but not the arg_tys.
266 --
267 -- Refactoring is welcome.
268 go :: Arity
269 -> [TcSigmaType] -- accumulator of arguments (reversed)
270 -> TcSigmaType -- the remainder of the type as we're processing
271 -> TcM (HsWrapper, [TcSigmaType], TcSigmaType)
272 go 0 _ ty = return (idHsWrapper, [], ty)
273
274 go n acc_args ty
275 | not (null tvs && null theta)
276 = do { (wrap1, rho) <- topInstantiate ct_orig ty
277 ; (wrap2, arg_tys, res_ty) <- go n acc_args rho
278 ; return (wrap2 <.> wrap1, arg_tys, res_ty) }
279 where
280 (tvs, theta, _) = tcSplitSigmaTy ty
281
282 go n acc_args ty
283 | Just ty' <- tcView ty = go n acc_args ty'
284
285 go n acc_args (FunTy arg_ty res_ty)
286 = ASSERT( not (isPredTy arg_ty) )
287 do { (wrap_res, tys, ty_r) <- go (n-1) (arg_ty : acc_args) res_ty
288 ; return ( mkWpFun idHsWrapper wrap_res arg_ty ty_r doc
289 , arg_ty : tys, ty_r ) }
290 where
291 doc = text "When inferring the argument type of a function with type" <+>
292 quotes (ppr orig_ty)
293
294 go n acc_args ty@(TyVarTy tv)
295 | isMetaTyVar tv
296 = do { cts <- readMetaTyVar tv
297 ; case cts of
298 Indirect ty' -> go n acc_args ty'
299 Flexi -> defer n ty }
300
301 -- In all other cases we bale out into ordinary unification
302 -- However unlike the meta-tyvar case, we are sure that the
303 -- number of arguments doesn't match arity of the original
304 -- type, so we can add a bit more context to the error message
305 -- (cf Trac #7869).
306 --
307 -- It is not always an error, because specialized type may have
308 -- different arity, for example:
309 --
310 -- > f1 = f2 'a'
311 -- > f2 :: Monad m => m Bool
312 -- > f2 = undefined
313 --
314 -- But in that case we add specialized type into error context
315 -- anyway, because it may be useful. See also Trac #9605.
316 go n acc_args ty = addErrCtxtM (mk_ctxt (reverse acc_args) ty) $
317 defer n ty
318
319 ------------
320 defer n fun_ty
321 = do { arg_tys <- replicateM n newOpenFlexiTyVarTy
322 ; res_ty <- newOpenFlexiTyVarTy
323 ; let unif_fun_ty = mkFunTys arg_tys res_ty
324 ; co <- unifyType mb_thing fun_ty unif_fun_ty
325 ; return (mkWpCastN co, arg_tys, res_ty) }
326
327 ------------
328 mk_ctxt :: [TcSigmaType] -> TcSigmaType -> TidyEnv -> TcM (TidyEnv, MsgDoc)
329 mk_ctxt arg_tys res_ty env
330 = do { let ty = mkFunTys arg_tys res_ty
331 ; (env1, zonked) <- zonkTidyTcType env ty
332 -- zonking might change # of args
333 ; let (zonked_args, _) = tcSplitFunTys zonked
334 n_actual = length zonked_args
335 (env2, unzonked) = tidyOpenType env1 ty
336 ; return ( env2
337 , mk_fun_tys_msg unzonked zonked n_actual full_arity herald) }
338
339 mk_fun_tys_msg :: TcType -- the full type passed in (unzonked)
340 -> TcType -- the full type passed in (zonked)
341 -> Arity -- the # of args found
342 -> Arity -- the # of args wanted
343 -> SDoc -- overall herald
344 -> SDoc
345 mk_fun_tys_msg full_ty ty n_args full_arity herald
346 = herald <+> speakNOf full_arity (text "argument") <> comma $$
347 if n_args == full_arity
348 then text "its type is" <+> quotes (pprType full_ty) <>
349 comma $$
350 text "it is specialized to" <+> quotes (pprType ty)
351 else sep [text "but its type" <+> quotes (pprType ty),
352 if n_args == 0 then text "has none"
353 else text "has only" <+> speakN n_args]
354
355 ----------------------
356 matchExpectedListTy :: TcRhoType -> TcM (TcCoercionN, TcRhoType)
357 -- Special case for lists
358 matchExpectedListTy exp_ty
359 = do { (co, [elt_ty]) <- matchExpectedTyConApp listTyCon exp_ty
360 ; return (co, elt_ty) }
361
362 ---------------------
363 matchExpectedTyConApp :: TyCon -- T :: forall kv1 ... kvm. k1 -> ... -> kn -> *
364 -> TcRhoType -- orig_ty
365 -> TcM (TcCoercionN, -- T k1 k2 k3 a b c ~N orig_ty
366 [TcSigmaType]) -- Element types, k1 k2 k3 a b c
367
368 -- It's used for wired-in tycons, so we call checkWiredInTyCon
369 -- Precondition: never called with FunTyCon
370 -- Precondition: input type :: *
371 -- Postcondition: (T k1 k2 k3 a b c) is well-kinded
372
373 matchExpectedTyConApp tc orig_ty
374 = ASSERT(tc /= funTyCon) go orig_ty
375 where
376 go ty
377 | Just ty' <- tcView ty
378 = go ty'
379
380 go ty@(TyConApp tycon args)
381 | tc == tycon -- Common case
382 = return (mkTcNomReflCo ty, args)
383
384 go (TyVarTy tv)
385 | isMetaTyVar tv
386 = do { cts <- readMetaTyVar tv
387 ; case cts of
388 Indirect ty -> go ty
389 Flexi -> defer }
390
391 go _ = defer
392
393 -- If the common case does not occur, instantiate a template
394 -- T k1 .. kn t1 .. tm, and unify with the original type
395 -- Doing it this way ensures that the types we return are
396 -- kind-compatible with T. For example, suppose we have
397 -- matchExpectedTyConApp T (f Maybe)
398 -- where data T a = MkT a
399 -- Then we don't want to instantiate T's data constructors with
400 -- (a::*) ~ Maybe
401 -- because that'll make types that are utterly ill-kinded.
402 -- This happened in Trac #7368
403 defer
404 = do { (_, arg_tvs) <- newMetaTyVars (tyConTyVars tc)
405 ; traceTc "matchExpectedTyConApp" (ppr tc $$ ppr (tyConTyVars tc) $$ ppr arg_tvs)
406 ; let args = mkTyVarTys arg_tvs
407 tc_template = mkTyConApp tc args
408 ; co <- unifyType Nothing tc_template orig_ty
409 ; return (co, args) }
410
411 ----------------------
412 matchExpectedAppTy :: TcRhoType -- orig_ty
413 -> TcM (TcCoercion, -- m a ~N orig_ty
414 (TcSigmaType, TcSigmaType)) -- Returns m, a
415 -- If the incoming type is a mutable type variable of kind k, then
416 -- matchExpectedAppTy returns a new type variable (m: * -> k); note the *.
417
418 matchExpectedAppTy orig_ty
419 = go orig_ty
420 where
421 go ty
422 | Just ty' <- tcView ty = go ty'
423
424 | Just (fun_ty, arg_ty) <- tcSplitAppTy_maybe ty
425 = return (mkTcNomReflCo orig_ty, (fun_ty, arg_ty))
426
427 go (TyVarTy tv)
428 | isMetaTyVar tv
429 = do { cts <- readMetaTyVar tv
430 ; case cts of
431 Indirect ty -> go ty
432 Flexi -> defer }
433
434 go _ = defer
435
436 -- Defer splitting by generating an equality constraint
437 defer
438 = do { ty1 <- newFlexiTyVarTy kind1
439 ; ty2 <- newFlexiTyVarTy kind2
440 ; co <- unifyType Nothing (mkAppTy ty1 ty2) orig_ty
441 ; return (co, (ty1, ty2)) }
442
443 orig_kind = typeKind orig_ty
444 kind1 = mkFunTy liftedTypeKind orig_kind
445 kind2 = liftedTypeKind -- m :: * -> k
446 -- arg type :: *
447
448 {-
449 ************************************************************************
450 * *
451 Subsumption checking
452 * *
453 ************************************************************************
454
455 Note [Subsumption checking: tcSubType]
456 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
457 All the tcSubType calls have the form
458 tcSubType actual_ty expected_ty
459 which checks
460 actual_ty <= expected_ty
461
462 That is, that a value of type actual_ty is acceptable in
463 a place expecting a value of type expected_ty. I.e. that
464
465 actual ty is more polymorphic than expected_ty
466
467 It returns a coercion function
468 co_fn :: actual_ty ~ expected_ty
469 which takes an HsExpr of type actual_ty into one of type
470 expected_ty.
471
472 These functions do not actually check for subsumption. They check if
473 expected_ty is an appropriate annotation to use for something of type
474 actual_ty. This difference matters when thinking about visible type
475 application. For example,
476
477 forall a. a -> forall b. b -> b
478 DOES NOT SUBSUME
479 forall a b. a -> b -> b
480
481 because the type arguments appear in a different order. (Neither does
482 it work the other way around.) BUT, these types are appropriate annotations
483 for one another. Because the user directs annotations, it's OK if some
484 arguments shuffle around -- after all, it's what the user wants.
485 Bottom line: none of this changes with visible type application.
486
487 There are a number of wrinkles (below).
488
489 Notice that Wrinkle 1 and 2 both require eta-expansion, which technically
490 may increase termination. We just put up with this, in exchange for getting
491 more predictable type inference.
492
493 Wrinkle 1: Note [Deep skolemisation]
494 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
495 We want (forall a. Int -> a -> a) <= (Int -> forall a. a->a)
496 (see section 4.6 of "Practical type inference for higher rank types")
497 So we must deeply-skolemise the RHS before we instantiate the LHS.
498
499 That is why tc_sub_type starts with a call to tcSkolemise (which does the
500 deep skolemisation), and then calls the DS variant (which assumes
501 that expected_ty is deeply skolemised)
502
503 Wrinkle 2: Note [Co/contra-variance of subsumption checking]
504 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
505 Consider g :: (Int -> Int) -> Int
506 f1 :: (forall a. a -> a) -> Int
507 f1 = g
508
509 f2 :: (forall a. a -> a) -> Int
510 f2 x = g x
511 f2 will typecheck, and it would be odd/fragile if f1 did not.
512 But f1 will only typecheck if we have that
513 (Int->Int) -> Int <= (forall a. a->a) -> Int
514 And that is only true if we do the full co/contravariant thing
515 in the subsumption check. That happens in the FunTy case of
516 tcSubTypeDS_NC_O, and is the sole reason for the WpFun form of
517 HsWrapper.
518
519 Another powerful reason for doing this co/contra stuff is visible
520 in Trac #9569, involving instantiation of constraint variables,
521 and again involving eta-expansion.
522
523 Wrinkle 3: Note [Higher rank types]
524 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
525 Consider tc150:
526 f y = \ (x::forall a. a->a). blah
527 The following happens:
528 * We will infer the type of the RHS, ie with a res_ty = alpha.
529 * Then the lambda will split alpha := beta -> gamma.
530 * And then we'll check tcSubType IsSwapped beta (forall a. a->a)
531
532 So it's important that we unify beta := forall a. a->a, rather than
533 skolemising the type.
534 -}
535
536
537 -- | Call this variant when you are in a higher-rank situation and
538 -- you know the right-hand type is deeply skolemised.
539 tcSubTypeHR :: CtOrigin -- ^ of the actual type
540 -> Maybe (HsExpr GhcRn) -- ^ If present, it has type ty_actual
541 -> TcSigmaType -> ExpRhoType -> TcM HsWrapper
542 tcSubTypeHR orig = tcSubTypeDS_NC_O orig GenSigCtxt
543
544 ------------------------
545 tcSubTypeET :: CtOrigin -> UserTypeCtxt
546 -> ExpSigmaType -> TcSigmaType -> TcM HsWrapper
547 -- If wrap = tc_sub_type_et t1 t2
548 -- => wrap :: t1 ~> t2
549 tcSubTypeET orig ctxt (Check ty_actual) ty_expected
550 = tc_sub_tc_type eq_orig orig ctxt ty_actual ty_expected
551 where
552 eq_orig = TypeEqOrigin { uo_actual = ty_expected
553 , uo_expected = ty_actual
554 , uo_thing = Nothing
555 , uo_visible = True }
556
557 tcSubTypeET _ _ (Infer inf_res) ty_expected
558 = ASSERT2( not (ir_inst inf_res), ppr inf_res $$ ppr ty_expected )
559 -- An (Infer inf_res) ExpSigmaType passed into tcSubTypeET never
560 -- has the ir_inst field set. Reason: in patterns (which is what
561 -- tcSubTypeET is used for) do not aggressively instantiate
562 do { co <- fill_infer_result ty_expected inf_res
563 -- Since ir_inst is false, we can skip fillInferResult
564 -- and go straight to fill_infer_result
565
566 ; return (mkWpCastN (mkTcSymCo co)) }
567
568 ------------------------
569 tcSubTypeO :: CtOrigin -- ^ of the actual type
570 -> UserTypeCtxt -- ^ of the expected type
571 -> TcSigmaType
572 -> ExpRhoType
573 -> TcM HsWrapper
574 tcSubTypeO orig ctxt ty_actual ty_expected
575 = addSubTypeCtxt ty_actual ty_expected $
576 do { traceTc "tcSubTypeDS_O" (vcat [ pprCtOrigin orig
577 , pprUserTypeCtxt ctxt
578 , ppr ty_actual
579 , ppr ty_expected ])
580 ; tcSubTypeDS_NC_O orig ctxt Nothing ty_actual ty_expected }
581
582 addSubTypeCtxt :: TcType -> ExpType -> TcM a -> TcM a
583 addSubTypeCtxt ty_actual ty_expected thing_inside
584 | isRhoTy ty_actual -- If there is no polymorphism involved, the
585 , isRhoExpTy ty_expected -- TypeEqOrigin stuff (added by the _NC functions)
586 = thing_inside -- gives enough context by itself
587 | otherwise
588 = addErrCtxtM mk_msg thing_inside
589 where
590 mk_msg tidy_env
591 = do { (tidy_env, ty_actual) <- zonkTidyTcType tidy_env ty_actual
592 -- might not be filled if we're debugging. ugh.
593 ; mb_ty_expected <- readExpType_maybe ty_expected
594 ; (tidy_env, ty_expected) <- case mb_ty_expected of
595 Just ty -> second mkCheckExpType <$>
596 zonkTidyTcType tidy_env ty
597 Nothing -> return (tidy_env, ty_expected)
598 ; ty_expected <- readExpType ty_expected
599 ; (tidy_env, ty_expected) <- zonkTidyTcType tidy_env ty_expected
600 ; let msg = vcat [ hang (text "When checking that:")
601 4 (ppr ty_actual)
602 , nest 2 (hang (text "is more polymorphic than:")
603 2 (ppr ty_expected)) ]
604 ; return (tidy_env, msg) }
605
606 ---------------
607 -- The "_NC" variants do not add a typechecker-error context;
608 -- the caller is assumed to do that
609
610 tcSubType_NC :: UserTypeCtxt -> TcSigmaType -> TcSigmaType -> TcM HsWrapper
611 -- Checks that actual <= expected
612 -- Returns HsWrapper :: actual ~ expected
613 tcSubType_NC ctxt ty_actual ty_expected
614 = do { traceTc "tcSubType_NC" (vcat [pprUserTypeCtxt ctxt, ppr ty_actual, ppr ty_expected])
615 ; tc_sub_tc_type origin origin ctxt ty_actual ty_expected }
616 where
617 origin = TypeEqOrigin { uo_actual = ty_actual
618 , uo_expected = ty_expected
619 , uo_thing = Nothing
620 , uo_visible = True }
621
622 tcSubTypeDS :: CtOrigin -> UserTypeCtxt -> TcSigmaType -> ExpRhoType -> TcM HsWrapper
623 -- Just like tcSubType, but with the additional precondition that
624 -- ty_expected is deeply skolemised (hence "DS")
625 tcSubTypeDS orig ctxt ty_actual ty_expected
626 = addSubTypeCtxt ty_actual ty_expected $
627 do { traceTc "tcSubTypeDS_NC" (vcat [pprUserTypeCtxt ctxt, ppr ty_actual, ppr ty_expected])
628 ; tcSubTypeDS_NC_O orig ctxt Nothing ty_actual ty_expected }
629
630 tcSubTypeDS_NC_O :: CtOrigin -- origin used for instantiation only
631 -> UserTypeCtxt
632 -> Maybe (HsExpr GhcRn)
633 -> TcSigmaType -> ExpRhoType -> TcM HsWrapper
634 -- Just like tcSubType, but with the additional precondition that
635 -- ty_expected is deeply skolemised
636 tcSubTypeDS_NC_O inst_orig ctxt m_thing ty_actual ty_expected
637 = case ty_expected of
638 Infer inf_res -> fillInferResult inst_orig ty_actual inf_res
639 Check ty -> tc_sub_type_ds eq_orig inst_orig ctxt ty_actual ty
640 where
641 eq_orig = TypeEqOrigin { uo_actual = ty_actual, uo_expected = ty
642 , uo_thing = ppr <$> m_thing
643 , uo_visible = True }
644
645 ---------------
646 tc_sub_tc_type :: CtOrigin -- used when calling uType
647 -> CtOrigin -- used when instantiating
648 -> UserTypeCtxt -> TcSigmaType -> TcSigmaType -> TcM HsWrapper
649 -- If wrap = tc_sub_type t1 t2
650 -- => wrap :: t1 ~> t2
651 tc_sub_tc_type eq_orig inst_orig ctxt ty_actual ty_expected
652 | definitely_poly ty_expected -- See Note [Don't skolemise unnecessarily]
653 , not (possibly_poly ty_actual)
654 = do { traceTc "tc_sub_tc_type (drop to equality)" $
655 vcat [ text "ty_actual =" <+> ppr ty_actual
656 , text "ty_expected =" <+> ppr ty_expected ]
657 ; mkWpCastN <$>
658 uType TypeLevel eq_orig ty_actual ty_expected }
659
660 | otherwise -- This is the general case
661 = do { traceTc "tc_sub_tc_type (general case)" $
662 vcat [ text "ty_actual =" <+> ppr ty_actual
663 , text "ty_expected =" <+> ppr ty_expected ]
664 ; (sk_wrap, inner_wrap) <- tcSkolemise ctxt ty_expected $
665 \ _ sk_rho ->
666 tc_sub_type_ds eq_orig inst_orig ctxt
667 ty_actual sk_rho
668 ; return (sk_wrap <.> inner_wrap) }
669 where
670 possibly_poly ty
671 | isForAllTy ty = True
672 | Just (_, res) <- splitFunTy_maybe ty = possibly_poly res
673 | otherwise = False
674 -- NB *not* tcSplitFunTy, because here we want
675 -- to decompose type-class arguments too
676
677 definitely_poly ty
678 | (tvs, theta, tau) <- tcSplitSigmaTy ty
679 , (tv:_) <- tvs
680 , null theta
681 , isInsolubleOccursCheck NomEq tv tau
682 = True
683 | otherwise
684 = False
685
686 {- Note [Don't skolemise unnecessarily]
687 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
688 Suppose we are trying to solve
689 (Char->Char) <= (forall a. a->a)
690 We could skolemise the 'forall a', and then complain
691 that (Char ~ a) is insoluble; but that's a pretty obscure
692 error. It's better to say that
693 (Char->Char) ~ (forall a. a->a)
694 fails.
695
696 So roughly:
697 * if the ty_expected has an outermost forall
698 (i.e. skolemisation is the next thing we'd do)
699 * and the ty_actual has no top-level polymorphism (but looking deeply)
700 then we can revert to simple equality. But we need to be careful.
701 These examples are all fine:
702
703 * (Char -> forall a. a->a) <= (forall a. Char -> a -> a)
704 Polymorphism is buried in ty_actual
705
706 * (Char->Char) <= (forall a. Char -> Char)
707 ty_expected isn't really polymorphic
708
709 * (Char->Char) <= (forall a. (a~Char) => a -> a)
710 ty_expected isn't really polymorphic
711
712 * (Char->Char) <= (forall a. F [a] Char -> Char)
713 where type instance F [x] t = t
714 ty_expected isn't really polymorphic
715
716 If we prematurely go to equality we'll reject a program we should
717 accept (e.g. Trac #13752). So the test (which is only to improve
718 error message) is very conservative:
719 * ty_actual is /definitely/ monomorphic
720 * ty_expected is /definitely/ polymorphic
721 -}
722
723 ---------------
724 tc_sub_type_ds :: CtOrigin -- used when calling uType
725 -> CtOrigin -- used when instantiating
726 -> UserTypeCtxt -> TcSigmaType -> TcRhoType -> TcM HsWrapper
727 -- If wrap = tc_sub_type_ds t1 t2
728 -- => wrap :: t1 ~> t2
729 -- Here is where the work actually happens!
730 -- Precondition: ty_expected is deeply skolemised
731 tc_sub_type_ds eq_orig inst_orig ctxt ty_actual ty_expected
732 = do { traceTc "tc_sub_type_ds" $
733 vcat [ text "ty_actual =" <+> ppr ty_actual
734 , text "ty_expected =" <+> ppr ty_expected ]
735 ; go ty_actual ty_expected }
736 where
737 go ty_a ty_e | Just ty_a' <- tcView ty_a = go ty_a' ty_e
738 | Just ty_e' <- tcView ty_e = go ty_a ty_e'
739
740 go (TyVarTy tv_a) ty_e
741 = do { lookup_res <- lookupTcTyVar tv_a
742 ; case lookup_res of
743 Filled ty_a' ->
744 do { traceTc "tcSubTypeDS_NC_O following filled act meta-tyvar:"
745 (ppr tv_a <+> text "-->" <+> ppr ty_a')
746 ; tc_sub_type_ds eq_orig inst_orig ctxt ty_a' ty_e }
747 Unfilled _ -> unify }
748
749 -- Historical note (Sept 16): there was a case here for
750 -- go ty_a (TyVarTy alpha)
751 -- which, in the impredicative case unified alpha := ty_a
752 -- where th_a is a polytype. Not only is this probably bogus (we
753 -- simply do not have decent story for impredicative types), but it
754 -- caused Trac #12616 because (also bizarrely) 'deriving' code had
755 -- -XImpredicativeTypes on. I deleted the entire case.
756
757 go (FunTy act_arg act_res) (FunTy exp_arg exp_res)
758 | not (isPredTy act_arg)
759 , not (isPredTy exp_arg)
760 = -- See Note [Co/contra-variance of subsumption checking]
761 do { res_wrap <- tc_sub_type_ds eq_orig inst_orig ctxt act_res exp_res
762 ; arg_wrap <- tc_sub_tc_type eq_orig given_orig GenSigCtxt exp_arg act_arg
763 -- GenSigCtxt: See Note [Setting the argument context]
764 ; return (mkWpFun arg_wrap res_wrap exp_arg exp_res doc) }
765 -- arg_wrap :: exp_arg ~> act_arg
766 -- res_wrap :: act-res ~> exp_res
767 where
768 given_orig = GivenOrigin (SigSkol GenSigCtxt exp_arg [])
769 doc = text "When checking that" <+> quotes (ppr ty_actual) <+>
770 text "is more polymorphic than" <+> quotes (ppr ty_expected)
771
772 go ty_a ty_e
773 | let (tvs, theta, _) = tcSplitSigmaTy ty_a
774 , not (null tvs && null theta)
775 = do { (in_wrap, in_rho) <- topInstantiate inst_orig ty_a
776 ; body_wrap <- tc_sub_type_ds
777 (eq_orig { uo_actual = in_rho
778 , uo_expected = ty_expected })
779 inst_orig ctxt in_rho ty_e
780 ; return (body_wrap <.> in_wrap) }
781
782 | otherwise -- Revert to unification
783 = inst_and_unify
784 -- It's still possible that ty_actual has nested foralls. Instantiate
785 -- these, as there's no way unification will succeed with them in.
786 -- See typecheck/should_compile/T11305 for an example of when this
787 -- is important. The problem is that we're checking something like
788 -- a -> forall b. b -> b <= alpha beta gamma
789 -- where we end up with alpha := (->)
790
791 inst_and_unify = do { (wrap, rho_a) <- deeplyInstantiate inst_orig ty_actual
792
793 -- if we haven't recurred through an arrow, then
794 -- the eq_orig will list ty_actual. In this case,
795 -- we want to update the origin to reflect the
796 -- instantiation. If we *have* recurred through
797 -- an arrow, it's better not to update.
798 ; let eq_orig' = case eq_orig of
799 TypeEqOrigin { uo_actual = orig_ty_actual }
800 | orig_ty_actual `tcEqType` ty_actual
801 , not (isIdHsWrapper wrap)
802 -> eq_orig { uo_actual = rho_a }
803 _ -> eq_orig
804
805 ; cow <- uType TypeLevel eq_orig' rho_a ty_expected
806 ; return (mkWpCastN cow <.> wrap) }
807
808
809 -- use versions without synonyms expanded
810 unify = mkWpCastN <$> uType TypeLevel eq_orig ty_actual ty_expected
811
812 {- Note [Settting the argument context]
813 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
814 Consider we are doing the ambiguity check for the (bogus)
815 f :: (forall a b. C b => a -> a) -> Int
816
817 We'll call
818 tcSubType ((forall a b. C b => a->a) -> Int )
819 ((forall a b. C b => a->a) -> Int )
820
821 with a UserTypeCtxt of (FunSigCtxt "f"). Then we'll do the co/contra thing
822 on the argument type of the (->) -- and at that point we want to switch
823 to a UserTypeCtxt of GenSigCtxt. Why?
824
825 * Error messages. If we stick with FunSigCtxt we get errors like
826 * Could not deduce: C b
827 from the context: C b0
828 bound by the type signature for:
829 f :: forall a b. C b => a->a
830 But of course f does not have that type signature!
831 Example tests: T10508, T7220a, Simple14
832
833 * Implications. We may decide to build an implication for the whole
834 ambiguity check, but we don't need one for each level within it,
835 and TcUnify.alwaysBuildImplication checks the UserTypeCtxt.
836 See Note [When to build an implication]
837 -}
838
839 -----------------
840 -- needs both un-type-checked (for origins) and type-checked (for wrapping)
841 -- expressions
842 tcWrapResult :: HsExpr GhcRn -> HsExpr GhcTcId -> TcSigmaType -> ExpRhoType
843 -> TcM (HsExpr GhcTcId)
844 tcWrapResult rn_expr = tcWrapResultO (exprCtOrigin rn_expr) rn_expr
845
846 -- | Sometimes we don't have a @HsExpr Name@ to hand, and this is more
847 -- convenient.
848 tcWrapResultO :: CtOrigin -> HsExpr GhcRn -> HsExpr GhcTcId -> TcSigmaType -> ExpRhoType
849 -> TcM (HsExpr GhcTcId)
850 tcWrapResultO orig rn_expr expr actual_ty res_ty
851 = do { traceTc "tcWrapResult" (vcat [ text "Actual: " <+> ppr actual_ty
852 , text "Expected:" <+> ppr res_ty ])
853 ; cow <- tcSubTypeDS_NC_O orig GenSigCtxt
854 (Just rn_expr) actual_ty res_ty
855 ; return (mkHsWrap cow expr) }
856
857
858 {- **********************************************************************
859 %* *
860 ExpType functions: tcInfer, fillInferResult
861 %* *
862 %********************************************************************* -}
863
864 -- | Infer a type using a fresh ExpType
865 -- See also Note [ExpType] in TcMType
866 -- Does not attempt to instantiate the inferred type
867 tcInferNoInst :: (ExpSigmaType -> TcM a) -> TcM (a, TcSigmaType)
868 tcInferNoInst = tcInfer False
869
870 tcInferInst :: (ExpRhoType -> TcM a) -> TcM (a, TcRhoType)
871 tcInferInst = tcInfer True
872
873 tcInfer :: Bool -> (ExpSigmaType -> TcM a) -> TcM (a, TcSigmaType)
874 tcInfer instantiate tc_check
875 = do { res_ty <- newInferExpType instantiate
876 ; result <- tc_check res_ty
877 ; res_ty <- readExpType res_ty
878 ; return (result, res_ty) }
879
880 fillInferResult :: CtOrigin -> TcType -> InferResult -> TcM HsWrapper
881 -- If wrap = fillInferResult t1 t2
882 -- => wrap :: t1 ~> t2
883 -- See Note [Deep instantiation of InferResult]
884 fillInferResult orig ty inf_res@(IR { ir_inst = instantiate_me })
885 | instantiate_me
886 = do { (wrap, rho) <- deeplyInstantiate orig ty
887 ; co <- fill_infer_result rho inf_res
888 ; return (mkWpCastN co <.> wrap) }
889
890 | otherwise
891 = do { co <- fill_infer_result ty inf_res
892 ; return (mkWpCastN co) }
893
894 fill_infer_result :: TcType -> InferResult -> TcM TcCoercionN
895 -- If wrap = fill_infer_result t1 t2
896 -- => wrap :: t1 ~> t2
897 fill_infer_result orig_ty (IR { ir_uniq = u, ir_lvl = res_lvl
898 , ir_ref = ref })
899 = do { (ty_co, ty_to_fill_with) <- promoteTcType res_lvl orig_ty
900
901 ; traceTc "Filling ExpType" $
902 ppr u <+> text ":=" <+> ppr ty_to_fill_with
903
904 ; when debugIsOn (check_hole ty_to_fill_with)
905
906 ; writeTcRef ref (Just ty_to_fill_with)
907
908 ; return ty_co }
909 where
910 check_hole ty -- Debug check only
911 = do { let ty_lvl = tcTypeLevel ty
912 ; MASSERT2( not (ty_lvl `strictlyDeeperThan` res_lvl),
913 ppr u $$ ppr res_lvl $$ ppr ty_lvl $$
914 ppr ty <+> dcolon <+> ppr (typeKind ty) $$ ppr orig_ty )
915 ; cts <- readTcRef ref
916 ; case cts of
917 Just already_there -> pprPanic "writeExpType"
918 (vcat [ ppr u
919 , ppr ty
920 , ppr already_there ])
921 Nothing -> return () }
922
923 {- Note [Deep instantiation of InferResult]
924 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
925 In some cases we want to deeply instantiate before filling in
926 an InferResult, and in some cases not. That's why InferReult
927 has the ir_inst flag.
928
929 * ir_inst = True: deeply instantiate
930
931 Consider
932 f x = (*)
933 We want to instantiate the type of (*) before returning, else we
934 will infer the type
935 f :: forall {a}. a -> forall b. Num b => b -> b -> b
936 This is surely confusing for users.
937
938 And worse, the monomorphism restriction won't work properly. The MR is
939 dealt with in simplifyInfer, and simplifyInfer has no way of
940 instantiating. This could perhaps be worked around, but it may be
941 hard to know even when instantiation should happen.
942
943 Another reason. Consider
944 f :: (?x :: Int) => a -> a
945 g y = let ?x = 3::Int in f
946 Here want to instantiate f's type so that the ?x::Int constraint
947 gets discharged by the enclosing implicit-parameter binding.
948
949 * ir_inst = False: do not instantiate
950
951 Consider this (which uses visible type application):
952
953 (let { f :: forall a. a -> a; f x = x } in f) @Int
954
955 We'll call TcExpr.tcInferFun to infer the type of the (let .. in f)
956 And we don't want to instantite the type of 'f' when we reach it,
957 else the outer visible type application won't work
958 -}
959
960 {- *********************************************************************
961 * *
962 Promoting types
963 * *
964 ********************************************************************* -}
965
966 promoteTcType :: TcLevel -> TcType -> TcM (TcCoercion, TcType)
967 -- See Note [Promoting a type]
968 -- promoteTcType level ty = (co, ty')
969 -- * Returns ty' whose max level is just 'level'
970 -- and whose kind is ~# to the kind of 'ty'
971 -- and whose kind has form TYPE rr
972 -- * and co :: ty ~ ty'
973 -- * and emits constraints to justify the coercion
974 promoteTcType dest_lvl ty
975 = do { cur_lvl <- getTcLevel
976 ; if (cur_lvl `sameDepthAs` dest_lvl)
977 then dont_promote_it
978 else promote_it }
979 where
980 promote_it :: TcM (TcCoercion, TcType)
981 promote_it -- Emit a constraint (alpha :: TYPE rr) ~ ty
982 -- where alpha and rr are fresh and from level dest_lvl
983 = do { rr <- newMetaTyVarTyAtLevel dest_lvl runtimeRepTy
984 ; prom_ty <- newMetaTyVarTyAtLevel dest_lvl (tYPE rr)
985 ; let eq_orig = TypeEqOrigin { uo_actual = ty
986 , uo_expected = prom_ty
987 , uo_thing = Nothing
988 , uo_visible = False }
989
990 ; co <- emitWantedEq eq_orig TypeLevel Nominal ty prom_ty
991 ; return (co, prom_ty) }
992
993 dont_promote_it :: TcM (TcCoercion, TcType)
994 dont_promote_it -- Check that ty :: TYPE rr, for some (fresh) rr
995 = do { res_kind <- newOpenTypeKind
996 ; let ty_kind = typeKind ty
997 kind_orig = TypeEqOrigin { uo_actual = ty_kind
998 , uo_expected = res_kind
999 , uo_thing = Nothing
1000 , uo_visible = False }
1001 ; ki_co <- uType KindLevel kind_orig (typeKind ty) res_kind
1002 ; let co = mkTcGReflRightCo Nominal ty ki_co
1003 ; return (co, ty `mkCastTy` ki_co) }
1004
1005 {- Note [Promoting a type]
1006 ~~~~~~~~~~~~~~~~~~~~~~~~~~
1007 Consider (Trac #12427)
1008
1009 data T where
1010 MkT :: (Int -> Int) -> a -> T
1011
1012 h y = case y of MkT v w -> v
1013
1014 We'll infer the RHS type with an expected type ExpType of
1015 (IR { ir_lvl = l, ir_ref = ref, ... )
1016 where 'l' is the TcLevel of the RHS of 'h'. Then the MkT pattern
1017 match will increase the level, so we'll end up in tcSubType, trying to
1018 unify the type of v,
1019 v :: Int -> Int
1020 with the expected type. But this attempt takes place at level (l+1),
1021 rightly so, since v's type could have mentioned existential variables,
1022 (like w's does) and we want to catch that.
1023
1024 So we
1025 - create a new meta-var alpha[l+1]
1026 - fill in the InferRes ref cell 'ref' with alpha
1027 - emit an equality constraint, thus
1028 [W] alpha[l+1] ~ (Int -> Int)
1029
1030 That constraint will float outwards, as it should, unless v's
1031 type mentions a skolem-captured variable.
1032
1033 This approach fails if v has a higher rank type; see
1034 Note [Promotion and higher rank types]
1035
1036
1037 Note [Promotion and higher rank types]
1038 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1039 If v had a higher-rank type, say v :: (forall a. a->a) -> Int,
1040 then we'd emit an equality
1041 [W] alpha[l+1] ~ ((forall a. a->a) -> Int)
1042 which will sadly fail because we can't unify a unification variable
1043 with a polytype. But there is nothing really wrong with the program
1044 here.
1045
1046 We could just about solve this by "promote the type" of v, to expose
1047 its polymorphic "shape" while still leaving constraints that will
1048 prevent existential escape. But we must be careful! Exposing
1049 the "shape" of the type is precisely what we must NOT do under
1050 a GADT pattern match! So in this case we might promote the type
1051 to
1052 (forall a. a->a) -> alpha[l+1]
1053 and emit the constraint
1054 [W] alpha[l+1] ~ Int
1055 Now the promoted type can fill the ref cell, while the emitted
1056 equality can float or not, according to the usual rules.
1057
1058 But that's not quite right! We are exposing the arrow! We could
1059 deal with that too:
1060 (forall a. mu[l+1] a a) -> alpha[l+1]
1061 with constraints
1062 [W] alpha[l+1] ~ Int
1063 [W] mu[l+1] ~ (->)
1064 Here we abstract over the '->' inside the forall, in case that
1065 is subject to an equality constraint from a GADT match.
1066
1067 Note that we kept the outer (->) because that's part of
1068 the polymorphic "shape". And because of impredicativity,
1069 GADT matches can't give equalities that affect polymorphic
1070 shape.
1071
1072 This reasoning just seems too complicated, so I decided not
1073 to do it. These higher-rank notes are just here to record
1074 the thinking.
1075 -}
1076
1077 {- *********************************************************************
1078 * *
1079 Generalisation
1080 * *
1081 ********************************************************************* -}
1082
1083 -- | Take an "expected type" and strip off quantifiers to expose the
1084 -- type underneath, binding the new skolems for the @thing_inside@.
1085 -- The returned 'HsWrapper' has type @specific_ty -> expected_ty@.
1086 tcSkolemise :: UserTypeCtxt -> TcSigmaType
1087 -> ([TcTyVar] -> TcType -> TcM result)
1088 -- ^ These are only ever used for scoped type variables.
1089 -> TcM (HsWrapper, result)
1090 -- ^ The expression has type: spec_ty -> expected_ty
1091
1092 tcSkolemise ctxt expected_ty thing_inside
1093 -- We expect expected_ty to be a forall-type
1094 -- If not, the call is a no-op
1095 = do { traceTc "tcSkolemise" Outputable.empty
1096 ; (wrap, tv_prs, given, rho') <- deeplySkolemise expected_ty
1097
1098 ; lvl <- getTcLevel
1099 ; when debugIsOn $
1100 traceTc "tcSkolemise" $ vcat [
1101 ppr lvl,
1102 text "expected_ty" <+> ppr expected_ty,
1103 text "inst tyvars" <+> ppr tv_prs,
1104 text "given" <+> ppr given,
1105 text "inst type" <+> ppr rho' ]
1106
1107 -- Generally we must check that the "forall_tvs" havn't been constrained
1108 -- The interesting bit here is that we must include the free variables
1109 -- of the expected_ty. Here's an example:
1110 -- runST (newVar True)
1111 -- Here, if we don't make a check, we'll get a type (ST s (MutVar s Bool))
1112 -- for (newVar True), with s fresh. Then we unify with the runST's arg type
1113 -- forall s'. ST s' a. That unifies s' with s, and a with MutVar s Bool.
1114 -- So now s' isn't unconstrained because it's linked to a.
1115 --
1116 -- However [Oct 10] now that the untouchables are a range of
1117 -- TcTyVars, all this is handled automatically with no need for
1118 -- extra faffing around
1119
1120 ; let tvs' = map snd tv_prs
1121 skol_info = SigSkol ctxt expected_ty tv_prs
1122
1123 ; (ev_binds, result) <- checkConstraints skol_info tvs' given $
1124 thing_inside tvs' rho'
1125
1126 ; return (wrap <.> mkWpLet ev_binds, result) }
1127 -- The ev_binds returned by checkConstraints is very
1128 -- often empty, in which case mkWpLet is a no-op
1129
1130 -- | Variant of 'tcSkolemise' that takes an ExpType
1131 tcSkolemiseET :: UserTypeCtxt -> ExpSigmaType
1132 -> (ExpRhoType -> TcM result)
1133 -> TcM (HsWrapper, result)
1134 tcSkolemiseET _ et@(Infer {}) thing_inside
1135 = (idHsWrapper, ) <$> thing_inside et
1136 tcSkolemiseET ctxt (Check ty) thing_inside
1137 = tcSkolemise ctxt ty $ \_ -> thing_inside . mkCheckExpType
1138
1139 checkConstraints :: SkolemInfo
1140 -> [TcTyVar] -- Skolems
1141 -> [EvVar] -- Given
1142 -> TcM result
1143 -> TcM (TcEvBinds, result)
1144
1145 checkConstraints skol_info skol_tvs given thing_inside
1146 = do { implication_needed <- implicationNeeded skol_info skol_tvs given
1147
1148 ; if implication_needed
1149 then do { (tclvl, wanted, result) <- pushLevelAndCaptureConstraints thing_inside
1150 ; (implics, ev_binds) <- buildImplicationFor tclvl skol_info skol_tvs given wanted
1151 ; traceTc "checkConstraints" (ppr tclvl $$ ppr skol_tvs)
1152 ; emitImplications implics
1153 ; return (ev_binds, result) }
1154
1155 else -- Fast path. We check every function argument with
1156 -- tcPolyExpr, which uses tcSkolemise and hence checkConstraints.
1157 -- So this fast path is well-exercised
1158 do { res <- thing_inside
1159 ; return (emptyTcEvBinds, res) } }
1160
1161 checkTvConstraints :: SkolemInfo
1162 -> Maybe SDoc -- User-written telescope, if present
1163 -> TcM ([TcTyVar], result)
1164 -> TcM ([TcTyVar], result)
1165
1166 checkTvConstraints skol_info m_telescope thing_inside
1167 = do { (tclvl, wanted, (skol_tvs, result))
1168 <- pushLevelAndCaptureConstraints thing_inside
1169
1170 ; if isEmptyWC wanted
1171 then return ()
1172 else do { ev_binds <- newNoTcEvBinds
1173 ; implic <- newImplication
1174 ; emitImplication $
1175 implic { ic_tclvl = tclvl
1176 , ic_skols = skol_tvs
1177 , ic_no_eqs = True
1178 , ic_telescope = m_telescope
1179 , ic_wanted = wanted
1180 , ic_binds = ev_binds
1181 , ic_info = skol_info } }
1182 ; return (skol_tvs, result) }
1183
1184
1185 implicationNeeded :: SkolemInfo -> [TcTyVar] -> [EvVar] -> TcM Bool
1186 -- See Note [When to build an implication]
1187 implicationNeeded skol_info skol_tvs given
1188 | null skol_tvs
1189 , null given
1190 , not (alwaysBuildImplication skol_info)
1191 = -- Empty skolems and givens
1192 do { tc_lvl <- getTcLevel
1193 ; if not (isTopTcLevel tc_lvl) -- No implication needed if we are
1194 then return False -- already inside an implication
1195 else
1196 do { dflags <- getDynFlags -- If any deferral can happen,
1197 -- we must build an implication
1198 ; return (gopt Opt_DeferTypeErrors dflags ||
1199 gopt Opt_DeferTypedHoles dflags ||
1200 gopt Opt_DeferOutOfScopeVariables dflags) } }
1201
1202 | otherwise -- Non-empty skolems or givens
1203 = return True -- Definitely need an implication
1204
1205 alwaysBuildImplication :: SkolemInfo -> Bool
1206 -- See Note [When to build an implication]
1207 alwaysBuildImplication _ = False
1208
1209 {- Commmented out for now while I figure out about error messages.
1210 See Trac #14185
1211
1212 alwaysBuildImplication (SigSkol ctxt _ _)
1213 = case ctxt of
1214 FunSigCtxt {} -> True -- RHS of a binding with a signature
1215 _ -> False
1216 alwaysBuildImplication (RuleSkol {}) = True
1217 alwaysBuildImplication (InstSkol {}) = True
1218 alwaysBuildImplication (FamInstSkol {}) = True
1219 alwaysBuildImplication _ = False
1220 -}
1221
1222 buildImplicationFor :: TcLevel -> SkolemInfo -> [TcTyVar]
1223 -> [EvVar] -> WantedConstraints
1224 -> TcM (Bag Implication, TcEvBinds)
1225 buildImplicationFor tclvl skol_info skol_tvs given wanted
1226 | isEmptyWC wanted && null given
1227 -- Optimisation : if there are no wanteds, and no givens
1228 -- don't generate an implication at all.
1229 -- Reason for the (null given): we don't want to lose
1230 -- the "inaccessible alternative" error check
1231 = return (emptyBag, emptyTcEvBinds)
1232
1233 | otherwise
1234 = ASSERT2( all (isSkolemTyVar <||> isTyVarTyVar) skol_tvs, ppr skol_tvs )
1235 -- Why allow TyVarTvs? Because implicitly declared kind variables in
1236 -- non-CUSK type declarations are TyVarTvs, and we need to bring them
1237 -- into scope as a skolem in an implication. This is OK, though,
1238 -- because TyVarTvs will always remain tyvars, even after unification.
1239 do { ev_binds_var <- newTcEvBinds
1240 ; implic <- newImplication
1241 ; let implic' = implic { ic_tclvl = tclvl
1242 , ic_skols = skol_tvs
1243 , ic_given = given
1244 , ic_wanted = wanted
1245 , ic_binds = ev_binds_var
1246 , ic_info = skol_info }
1247
1248 ; return (unitBag implic', TcEvBinds ev_binds_var) }
1249
1250 {- Note [When to build an implication]
1251 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1252 Suppose we have some 'skolems' and some 'givens', and we are
1253 considering whether to wrap the constraints in their scope into an
1254 implication. We must /always/ so if either 'skolems' or 'givens' are
1255 non-empty. But what if both are empty? You might think we could
1256 always drop the implication. Other things being equal, the fewer
1257 implications the better. Less clutter and overhead. But we must
1258 take care:
1259
1260 * If we have an unsolved [W] g :: a ~# b, and -fdefer-type-errors,
1261 we'll make a /term-level/ evidence binding for 'g = error "blah"'.
1262 We must have an EvBindsVar those bindings!, otherwise they end up as
1263 top-level unlifted bindings, which are verboten. This only matters
1264 at top level, so we check for that
1265 See also Note [Deferred errors for coercion holes] in TcErrors.
1266 cf Trac #14149 for an example of what goes wrong.
1267
1268 * If you have
1269 f :: Int; f = f_blah
1270 g :: Bool; g = g_blah
1271 If we don't build an implication for f or g (no tyvars, no givens),
1272 the constraints for f_blah and g_blah are solved together. And that
1273 can yield /very/ confusing error messages, because we can get
1274 [W] C Int b1 -- from f_blah
1275 [W] C Int b2 -- from g_blan
1276 and fundpes can yield [D] b1 ~ b2, even though the two functions have
1277 literally nothing to do with each other. Trac #14185 is an example.
1278 Building an implication keeps them separage.
1279 -}
1280
1281 {-
1282 ************************************************************************
1283 * *
1284 Boxy unification
1285 * *
1286 ************************************************************************
1287
1288 The exported functions are all defined as versions of some
1289 non-exported generic functions.
1290 -}
1291
1292 unifyType :: Maybe (HsExpr GhcRn) -- ^ If present, has type 'ty1'
1293 -> TcTauType -> TcTauType -> TcM TcCoercionN
1294 -- Actual and expected types
1295 -- Returns a coercion : ty1 ~ ty2
1296 unifyType thing ty1 ty2 = traceTc "utype" (ppr ty1 $$ ppr ty2 $$ ppr thing) >>
1297 uType TypeLevel origin ty1 ty2
1298 where
1299 origin = TypeEqOrigin { uo_actual = ty1, uo_expected = ty2
1300 , uo_thing = ppr <$> thing
1301 , uo_visible = True } -- always called from a visible context
1302
1303 unifyKind :: Maybe (HsType GhcRn) -> TcKind -> TcKind -> TcM CoercionN
1304 unifyKind thing ty1 ty2 = traceTc "ukind" (ppr ty1 $$ ppr ty2 $$ ppr thing) >>
1305 uType KindLevel origin ty1 ty2
1306 where origin = TypeEqOrigin { uo_actual = ty1, uo_expected = ty2
1307 , uo_thing = ppr <$> thing
1308 , uo_visible = True } -- also always from a visible context
1309
1310 ---------------
1311
1312 {-
1313 %************************************************************************
1314 %* *
1315 uType and friends
1316 %* *
1317 %************************************************************************
1318
1319 uType is the heart of the unifier.
1320 -}
1321
1322 uType, uType_defer
1323 :: TypeOrKind
1324 -> CtOrigin
1325 -> TcType -- ty1 is the *actual* type
1326 -> TcType -- ty2 is the *expected* type
1327 -> TcM CoercionN
1328
1329 --------------
1330 -- It is always safe to defer unification to the main constraint solver
1331 -- See Note [Deferred unification]
1332 uType_defer t_or_k origin ty1 ty2
1333 = do { co <- emitWantedEq origin t_or_k Nominal ty1 ty2
1334
1335 -- Error trace only
1336 -- NB. do *not* call mkErrInfo unless tracing is on,
1337 -- because it is hugely expensive (#5631)
1338 ; whenDOptM Opt_D_dump_tc_trace $ do
1339 { ctxt <- getErrCtxt
1340 ; doc <- mkErrInfo emptyTidyEnv ctxt
1341 ; traceTc "utype_defer" (vcat [ debugPprType ty1
1342 , debugPprType ty2
1343 , pprCtOrigin origin
1344 , doc])
1345 ; traceTc "utype_defer2" (ppr co)
1346 }
1347 ; return co }
1348
1349 --------------
1350 uType t_or_k origin orig_ty1 orig_ty2
1351 = do { tclvl <- getTcLevel
1352 ; traceTc "u_tys" $ vcat
1353 [ text "tclvl" <+> ppr tclvl
1354 , sep [ ppr orig_ty1, text "~", ppr orig_ty2]
1355 , pprCtOrigin origin]
1356 ; co <- go orig_ty1 orig_ty2
1357 ; if isReflCo co
1358 then traceTc "u_tys yields no coercion" Outputable.empty
1359 else traceTc "u_tys yields coercion:" (ppr co)
1360 ; return co }
1361 where
1362 go :: TcType -> TcType -> TcM CoercionN
1363 -- The arguments to 'go' are always semantically identical
1364 -- to orig_ty{1,2} except for looking through type synonyms
1365
1366 -- Unwrap casts before looking for variables. This way, we can easily
1367 -- recognize (t |> co) ~ (t |> co), which is nice. Previously, we
1368 -- didn't do it this way, and then the unification above was deferred.
1369 go (CastTy t1 co1) t2
1370 = do { co_tys <- uType t_or_k origin t1 t2
1371 ; return (mkCoherenceLeftCo Nominal t1 co1 co_tys) }
1372
1373 go t1 (CastTy t2 co2)
1374 = do { co_tys <- uType t_or_k origin t1 t2
1375 ; return (mkCoherenceRightCo Nominal t2 co2 co_tys) }
1376
1377 -- Variables; go for uVar
1378 -- Note that we pass in *original* (before synonym expansion),
1379 -- so that type variables tend to get filled in with
1380 -- the most informative version of the type
1381 go (TyVarTy tv1) ty2
1382 = do { lookup_res <- lookupTcTyVar tv1
1383 ; case lookup_res of
1384 Filled ty1 -> do { traceTc "found filled tyvar" (ppr tv1 <+> text ":->" <+> ppr ty1)
1385 ; go ty1 ty2 }
1386 Unfilled _ -> uUnfilledVar origin t_or_k NotSwapped tv1 ty2 }
1387 go ty1 (TyVarTy tv2)
1388 = do { lookup_res <- lookupTcTyVar tv2
1389 ; case lookup_res of
1390 Filled ty2 -> do { traceTc "found filled tyvar" (ppr tv2 <+> text ":->" <+> ppr ty2)
1391 ; go ty1 ty2 }
1392 Unfilled _ -> uUnfilledVar origin t_or_k IsSwapped tv2 ty1 }
1393
1394 -- See Note [Expanding synonyms during unification]
1395 go ty1@(TyConApp tc1 []) (TyConApp tc2 [])
1396 | tc1 == tc2
1397 = return $ mkNomReflCo ty1
1398
1399 -- See Note [Expanding synonyms during unification]
1400 --
1401 -- Also NB that we recurse to 'go' so that we don't push a
1402 -- new item on the origin stack. As a result if we have
1403 -- type Foo = Int
1404 -- and we try to unify Foo ~ Bool
1405 -- we'll end up saying "can't match Foo with Bool"
1406 -- rather than "can't match "Int with Bool". See Trac #4535.
1407 go ty1 ty2
1408 | Just ty1' <- tcView ty1 = go ty1' ty2
1409 | Just ty2' <- tcView ty2 = go ty1 ty2'
1410
1411 -- Functions (or predicate functions) just check the two parts
1412 go (FunTy fun1 arg1) (FunTy fun2 arg2)
1413 = do { co_l <- uType t_or_k origin fun1 fun2
1414 ; co_r <- uType t_or_k origin arg1 arg2
1415 ; return $ mkFunCo Nominal co_l co_r }
1416
1417 -- Always defer if a type synonym family (type function)
1418 -- is involved. (Data families behave rigidly.)
1419 go ty1@(TyConApp tc1 _) ty2
1420 | isTypeFamilyTyCon tc1 = defer ty1 ty2
1421 go ty1 ty2@(TyConApp tc2 _)
1422 | isTypeFamilyTyCon tc2 = defer ty1 ty2
1423
1424 go (TyConApp tc1 tys1) (TyConApp tc2 tys2)
1425 -- See Note [Mismatched type lists and application decomposition]
1426 | tc1 == tc2, equalLength tys1 tys2
1427 = ASSERT2( isGenerativeTyCon tc1 Nominal, ppr tc1 )
1428 do { cos <- zipWith3M (uType t_or_k) origins' tys1 tys2
1429 ; return $ mkTyConAppCo Nominal tc1 cos }
1430 where
1431 origins' = map (\is_vis -> if is_vis then origin else toInvisibleOrigin origin)
1432 (tcTyConVisibilities tc1)
1433
1434 go (LitTy m) ty@(LitTy n)
1435 | m == n
1436 = return $ mkNomReflCo ty
1437
1438 -- See Note [Care with type applications]
1439 -- Do not decompose FunTy against App;
1440 -- it's often a type error, so leave it for the constraint solver
1441 go (AppTy s1 t1) (AppTy s2 t2)
1442 = go_app (isNextArgVisible s1) s1 t1 s2 t2
1443
1444 go (AppTy s1 t1) (TyConApp tc2 ts2)
1445 | Just (ts2', t2') <- snocView ts2
1446 = ASSERT( mightBeUnsaturatedTyCon tc2 )
1447 go_app (isNextTyConArgVisible tc2 ts2') s1 t1 (TyConApp tc2 ts2') t2'
1448
1449 go (TyConApp tc1 ts1) (AppTy s2 t2)
1450 | Just (ts1', t1') <- snocView ts1
1451 = ASSERT( mightBeUnsaturatedTyCon tc1 )
1452 go_app (isNextTyConArgVisible tc1 ts1') (TyConApp tc1 ts1') t1' s2 t2
1453
1454 go (CoercionTy co1) (CoercionTy co2)
1455 = do { let ty1 = coercionType co1
1456 ty2 = coercionType co2
1457 ; kco <- uType KindLevel
1458 (KindEqOrigin orig_ty1 (Just orig_ty2) origin
1459 (Just t_or_k))
1460 ty1 ty2
1461 ; return $ mkProofIrrelCo Nominal kco co1 co2 }
1462
1463 -- Anything else fails
1464 -- E.g. unifying for-all types, which is relative unusual
1465 go ty1 ty2 = defer ty1 ty2
1466
1467 ------------------
1468 defer ty1 ty2 -- See Note [Check for equality before deferring]
1469 | ty1 `tcEqType` ty2 = return (mkNomReflCo ty1)
1470 | otherwise = uType_defer t_or_k origin ty1 ty2
1471
1472 ------------------
1473 go_app vis s1 t1 s2 t2
1474 = do { co_s <- uType t_or_k origin s1 s2
1475 ; let arg_origin
1476 | vis = origin
1477 | otherwise = toInvisibleOrigin origin
1478 ; co_t <- uType t_or_k arg_origin t1 t2
1479 ; return $ mkAppCo co_s co_t }
1480
1481 {- Note [Check for equality before deferring]
1482 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1483 Particularly in ambiguity checks we can get equalities like (ty ~ ty).
1484 If ty involves a type function we may defer, which isn't very sensible.
1485 An egregious example of this was in test T9872a, which has a type signature
1486 Proxy :: Proxy (Solutions Cubes)
1487 Doing the ambiguity check on this signature generates the equality
1488 Solutions Cubes ~ Solutions Cubes
1489 and currently the constraint solver normalises both sides at vast cost.
1490 This little short-cut in 'defer' helps quite a bit.
1491
1492 Note [Care with type applications]
1493 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1494 Note: type applications need a bit of care!
1495 They can match FunTy and TyConApp, so use splitAppTy_maybe
1496 NB: we've already dealt with type variables and Notes,
1497 so if one type is an App the other one jolly well better be too
1498
1499 Note [Mismatched type lists and application decomposition]
1500 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1501 When we find two TyConApps, you might think that the argument lists
1502 are guaranteed equal length. But they aren't. Consider matching
1503 w (T x) ~ Foo (T x y)
1504 We do match (w ~ Foo) first, but in some circumstances we simply create
1505 a deferred constraint; and then go ahead and match (T x ~ T x y).
1506 This came up in Trac #3950.
1507
1508 So either
1509 (a) either we must check for identical argument kinds
1510 when decomposing applications,
1511
1512 (b) or we must be prepared for ill-kinded unification sub-problems
1513
1514 Currently we adopt (b) since it seems more robust -- no need to maintain
1515 a global invariant.
1516
1517 Note [Expanding synonyms during unification]
1518 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1519 We expand synonyms during unification, but:
1520 * We expand *after* the variable case so that we tend to unify
1521 variables with un-expanded type synonym. This just makes it
1522 more likely that the inferred types will mention type synonyms
1523 understandable to the user
1524
1525 * Similarly, we expand *after* the CastTy case, just in case the
1526 CastTy wraps a variable.
1527
1528 * We expand *before* the TyConApp case. For example, if we have
1529 type Phantom a = Int
1530 and are unifying
1531 Phantom Int ~ Phantom Char
1532 it is *wrong* to unify Int and Char.
1533
1534 * The problem case immediately above can happen only with arguments
1535 to the tycon. So we check for nullary tycons *before* expanding.
1536 This is particularly helpful when checking (* ~ *), because * is
1537 now a type synonym.
1538
1539 Note [Deferred Unification]
1540 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
1541 We may encounter a unification ty1 ~ ty2 that cannot be performed syntactically,
1542 and yet its consistency is undetermined. Previously, there was no way to still
1543 make it consistent. So a mismatch error was issued.
1544
1545 Now these unifications are deferred until constraint simplification, where type
1546 family instances and given equations may (or may not) establish the consistency.
1547 Deferred unifications are of the form
1548 F ... ~ ...
1549 or x ~ ...
1550 where F is a type function and x is a type variable.
1551 E.g.
1552 id :: x ~ y => x -> y
1553 id e = e
1554
1555 involves the unification x = y. It is deferred until we bring into account the
1556 context x ~ y to establish that it holds.
1557
1558 If available, we defer original types (rather than those where closed type
1559 synonyms have already been expanded via tcCoreView). This is, as usual, to
1560 improve error messages.
1561
1562
1563 ************************************************************************
1564 * *
1565 uVar and friends
1566 * *
1567 ************************************************************************
1568
1569 @uVar@ is called when at least one of the types being unified is a
1570 variable. It does {\em not} assume that the variable is a fixed point
1571 of the substitution; rather, notice that @uVar@ (defined below) nips
1572 back into @uTys@ if it turns out that the variable is already bound.
1573 -}
1574
1575 ----------
1576 uUnfilledVar :: CtOrigin
1577 -> TypeOrKind
1578 -> SwapFlag
1579 -> TcTyVar -- Tyvar 1
1580 -> TcTauType -- Type 2
1581 -> TcM Coercion
1582 -- "Unfilled" means that the variable is definitely not a filled-in meta tyvar
1583 -- It might be a skolem, or untouchable, or meta
1584
1585 uUnfilledVar origin t_or_k swapped tv1 ty2
1586 = do { ty2 <- zonkTcType ty2
1587 -- Zonk to expose things to the
1588 -- occurs check, and so that if ty2
1589 -- looks like a type variable then it
1590 -- /is/ a type variable
1591 ; uUnfilledVar1 origin t_or_k swapped tv1 ty2 }
1592
1593 ----------
1594 uUnfilledVar1 :: CtOrigin
1595 -> TypeOrKind
1596 -> SwapFlag
1597 -> TcTyVar -- Tyvar 1
1598 -> TcTauType -- Type 2, zonked
1599 -> TcM Coercion
1600 uUnfilledVar1 origin t_or_k swapped tv1 ty2
1601 | Just tv2 <- tcGetTyVar_maybe ty2
1602 = go tv2
1603
1604 | otherwise
1605 = uUnfilledVar2 origin t_or_k swapped tv1 ty2
1606
1607 where
1608 -- 'go' handles the case where both are
1609 -- tyvars so we might want to swap
1610 go tv2 | tv1 == tv2 -- Same type variable => no-op
1611 = return (mkNomReflCo (mkTyVarTy tv1))
1612
1613 | swapOverTyVars tv1 tv2 -- Distinct type variables
1614 = uUnfilledVar2 origin t_or_k (flipSwap swapped)
1615 tv2 (mkTyVarTy tv1)
1616
1617 | otherwise
1618 = uUnfilledVar2 origin t_or_k swapped tv1 ty2
1619
1620 ----------
1621 uUnfilledVar2 :: CtOrigin
1622 -> TypeOrKind
1623 -> SwapFlag
1624 -> TcTyVar -- Tyvar 1
1625 -> TcTauType -- Type 2, zonked
1626 -> TcM Coercion
1627 uUnfilledVar2 origin t_or_k swapped tv1 ty2
1628 = do { dflags <- getDynFlags
1629 ; cur_lvl <- getTcLevel
1630 ; go dflags cur_lvl }
1631 where
1632 go dflags cur_lvl
1633 | canSolveByUnification cur_lvl tv1 ty2
1634 , Just ty2' <- metaTyVarUpdateOK dflags tv1 ty2
1635 = do { co_k <- uType KindLevel kind_origin (typeKind ty2') (tyVarKind tv1)
1636 ; traceTc "uUnfilledVar2 ok" $
1637 vcat [ ppr tv1 <+> dcolon <+> ppr (tyVarKind tv1)
1638 , ppr ty2 <+> dcolon <+> ppr (typeKind ty2)
1639 , ppr (isTcReflCo co_k), ppr co_k ]
1640
1641 ; if isTcReflCo co_k -- only proceed if the kinds matched.
1642
1643 then do { writeMetaTyVar tv1 ty2'
1644 ; return (mkTcNomReflCo ty2') }
1645
1646 else defer } -- This cannot be solved now. See TcCanonical
1647 -- Note [Equalities with incompatible kinds]
1648
1649 | otherwise
1650 = do { traceTc "uUnfilledVar2 not ok" (ppr tv1 $$ ppr ty2)
1651 -- Occurs check or an untouchable: just defer
1652 -- NB: occurs check isn't necessarily fatal:
1653 -- eg tv1 occured in type family parameter
1654 ; defer }
1655
1656 ty1 = mkTyVarTy tv1
1657 kind_origin = KindEqOrigin ty1 (Just ty2) origin (Just t_or_k)
1658
1659 defer = unSwap swapped (uType_defer t_or_k origin) ty1 ty2
1660
1661 swapOverTyVars :: TcTyVar -> TcTyVar -> Bool
1662 swapOverTyVars tv1 tv2
1663 -- Level comparison: see Note [TyVar/TyVar orientation]
1664 | lvl1 `strictlyDeeperThan` lvl2 = False
1665 | lvl2 `strictlyDeeperThan` lvl1 = True
1666
1667 -- Priority: see Note [TyVar/TyVar orientation]
1668 | pri1 > pri2 = False
1669 | pri2 > pri1 = True
1670
1671 -- Names: see Note [TyVar/TyVar orientation]
1672 | isSystemName tv2_name, not (isSystemName tv1_name) = True
1673
1674 | otherwise = False
1675
1676 where
1677 lvl1 = tcTyVarLevel tv1
1678 lvl2 = tcTyVarLevel tv2
1679 pri1 = lhsPriority tv1
1680 pri2 = lhsPriority tv2
1681 tv1_name = Var.varName tv1
1682 tv2_name = Var.varName tv2
1683
1684
1685 lhsPriority :: TcTyVar -> Int
1686 -- Higher => more important to be on the LHS
1687 -- See Note [TyVar/TyVar orientation]
1688 lhsPriority tv
1689 = ASSERT2( isTyVar tv, ppr tv)
1690 case tcTyVarDetails tv of
1691 RuntimeUnk -> 0
1692 SkolemTv {} -> 0
1693 MetaTv { mtv_info = info } -> case info of
1694 FlatSkolTv -> 1
1695 TyVarTv -> 2
1696 TauTv -> 3
1697 FlatMetaTv -> 4
1698 {- Note [TyVar/TyVar orientation]
1699 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1700 Given (a ~ b), should we orient the CTyEqCan as (a~b) or (b~a)?
1701 This is a surprisingly tricky question!
1702
1703 First note: only swap if you have to!
1704 See Note [Avoid unnecessary swaps]
1705
1706 So we look for a positive reason to swap, using a three-step test:
1707
1708 * Level comparison. If 'a' has deeper level than 'b',
1709 put 'a' on the left. See Note [Deeper level on the left]
1710
1711 * Priority. If the levels are the same, look at what kind of
1712 type variable it is, using 'lhsPriority'
1713
1714 - FlatMetaTv: Always put on the left.
1715 See Note [Fmv Orientation Invariant]
1716 NB: FlatMetaTvs always have the current level, never an
1717 outer one. So nothing can be deeper than a FlatMetaTv
1718
1719
1720 - TyVarTv/TauTv: if we have tyv_tv ~ tau_tv, put tau_tv
1721 on the left because there are fewer
1722 restrictions on updating TauTvs
1723
1724 - TyVarTv/TauTv: put on the left either
1725 a) Because it's touchable and can be unified, or
1726 b) Even if it's not touchable, TcSimplify.floatEqualities
1727 looks for meta tyvars on the left
1728
1729 - FlatSkolTv: Put on the left in preference to a SkolemTv
1730 See Note [Eliminate flat-skols]
1731
1732 * Names. If the level and priority comparisons are all
1733 equal, try to eliminate a TyVars with a System Name in
1734 favour of ones with a Name derived from a user type signature
1735
1736 * Age. At one point in the past we tried to break any remaining
1737 ties by eliminating the younger type variable, based on their
1738 Uniques. See Note [Eliminate younger unification variables]
1739 (which also explains why we don't do this any more)
1740
1741 Note [Deeper level on the left]
1742 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1743 The most important thing is that we want to put tyvars with
1744 the deepest level on the left. The reason to do so differs for
1745 Wanteds and Givens, but either way, deepest wins! Simple.
1746
1747 * Wanteds. Putting the deepest variable on the left maximise the
1748 chances that it's a touchable meta-tyvar which can be solved.
1749
1750 * Givens. Suppose we have something like
1751 forall a[2]. b[1] ~ a[2] => beta[1] ~ a[2]
1752
1753 If we orient the Given a[2] on the left, we'll rewrite the Wanted to
1754 (beta[1] ~ b[1]), and that can float out of the implication.
1755 Otherwise it can't. By putting the deepest variable on the left
1756 we maximise our changes of eliminating skolem capture.
1757
1758 See also TcSMonad Note [Let-bound skolems] for another reason
1759 to orient with the deepest skolem on the left.
1760
1761 IMPORTANT NOTE: this test does a level-number comparison on
1762 skolems, so it's important that skolems have (accurate) level
1763 numbers.
1764
1765 See Trac #15009 for an further analysis of why "deepest on the left"
1766 is a good plan.
1767
1768 Note [Fmv Orientation Invariant]
1769 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1770 * We always orient a constraint
1771 fmv ~ alpha
1772 with fmv on the left, even if alpha is
1773 a touchable unification variable
1774
1775 Reason: doing it the other way round would unify alpha:=fmv, but that
1776 really doesn't add any info to alpha. But a later constraint alpha ~
1777 Int might unlock everything. Comment:9 of #12526 gives a detailed
1778 example.
1779
1780 WARNING: I've gone to and fro on this one several times.
1781 I'm now pretty sure that unifying alpha:=fmv is a bad idea!
1782 So orienting with fmvs on the left is a good thing.
1783
1784 This example comes from IndTypesPerfMerge. (Others include
1785 T10226, T10009.)
1786 From the ambiguity check for
1787 f :: (F a ~ a) => a
1788 we get:
1789 [G] F a ~ a
1790 [WD] F alpha ~ alpha, alpha ~ a
1791
1792 From Givens we get
1793 [G] F a ~ fsk, fsk ~ a
1794
1795 Now if we flatten we get
1796 [WD] alpha ~ fmv, F alpha ~ fmv, alpha ~ a
1797
1798 Now, if we unified alpha := fmv, we'd get
1799 [WD] F fmv ~ fmv, [WD] fmv ~ a
1800 And now we are stuck.
1801
1802 So instead the Fmv Orientation Invariant puts the fmv on the
1803 left, giving
1804 [WD] fmv ~ alpha, [WD] F alpha ~ fmv, [WD] alpha ~ a
1805
1806 Now we get alpha:=a, and everything works out
1807
1808 Note [Eliminate flat-skols]
1809 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
1810 Suppose we have [G] Num (F [a])
1811 then we flatten to
1812 [G] Num fsk
1813 [G] F [a] ~ fsk
1814 where fsk is a flatten-skolem (FlatSkolTv). Suppose we have
1815 type instance F [a] = a
1816 then we'll reduce the second constraint to
1817 [G] a ~ fsk
1818 and then replace all uses of 'a' with fsk. That's bad because
1819 in error messages instead of saying 'a' we'll say (F [a]). In all
1820 places, including those where the programmer wrote 'a' in the first
1821 place. Very confusing! See Trac #7862.
1822
1823 Solution: re-orient a~fsk to fsk~a, so that we preferentially eliminate
1824 the fsk.
1825
1826 Note [Avoid unnecessary swaps]
1827 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1828 If we swap without actually improving matters, we can get an infinite loop.
1829 Consider
1830 work item: a ~ b
1831 inert item: b ~ c
1832 We canonicalise the work-item to (a ~ c). If we then swap it before
1833 adding to the inert set, we'll add (c ~ a), and therefore kick out the
1834 inert guy, so we get
1835 new work item: b ~ c
1836 inert item: c ~ a
1837 And now the cycle just repeats
1838
1839 Note [Eliminate younger unification variables]
1840 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1841 Given a choice of unifying
1842 alpha := beta or beta := alpha
1843 we try, if possible, to eliminate the "younger" one, as determined
1844 by `ltUnique`. Reason: the younger one is less likely to appear free in
1845 an existing inert constraint, and hence we are less likely to be forced
1846 into kicking out and rewriting inert constraints.
1847
1848 This is a performance optimisation only. It turns out to fix
1849 Trac #14723 all by itself, but clearly not reliably so!
1850
1851 It's simple to implement (see nicer_to_update_tv2 in swapOverTyVars).
1852 But, to my surprise, it didn't seem to make any significant difference
1853 to the compiler's performance, so I didn't take it any further. Still
1854 it seemed to too nice to discard altogether, so I'm leaving these
1855 notes. SLPJ Jan 18.
1856 -}
1857
1858 -- @trySpontaneousSolve wi@ solves equalities where one side is a
1859 -- touchable unification variable.
1860 -- Returns True <=> spontaneous solve happened
1861 canSolveByUnification :: TcLevel -> TcTyVar -> TcType -> Bool
1862 canSolveByUnification tclvl tv xi
1863 | isTouchableMetaTyVar tclvl tv
1864 = case metaTyVarInfo tv of
1865 TyVarTv -> is_tyvar xi
1866 _ -> True
1867
1868 | otherwise -- Untouchable
1869 = False
1870 where
1871 is_tyvar xi
1872 = case tcGetTyVar_maybe xi of
1873 Nothing -> False
1874 Just tv -> case tcTyVarDetails tv of
1875 MetaTv { mtv_info = info }
1876 -> case info of
1877 TyVarTv -> True
1878 _ -> False
1879 SkolemTv {} -> True
1880 RuntimeUnk -> True
1881
1882 {- Note [Prevent unification with type families]
1883 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1884 We prevent unification with type families because of an uneasy compromise.
1885 It's perfectly sound to unify with type families, and it even improves the
1886 error messages in the testsuite. It also modestly improves performance, at
1887 least in some cases. But it's disastrous for test case perf/compiler/T3064.
1888 Here is the problem: Suppose we have (F ty) where we also have [G] F ty ~ a.
1889 What do we do? Do we reduce F? Or do we use the given? Hard to know what's
1890 best. GHC reduces. This is a disaster for T3064, where the type's size
1891 spirals out of control during reduction. (We're not helped by the fact that
1892 the flattener re-flattens all the arguments every time around.) If we prevent
1893 unification with type families, then the solver happens to use the equality
1894 before expanding the type family.
1895
1896 It would be lovely in the future to revisit this problem and remove this
1897 extra, unnecessary check. But we retain it for now as it seems to work
1898 better in practice.
1899
1900 Note [Refactoring hazard: checkTauTvUpdate]
1901 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1902 I (Richard E.) have a sad story about refactoring this code, retained here
1903 to prevent others (or a future me!) from falling into the same traps.
1904
1905 It all started with #11407, which was caused by the fact that the TyVarTy
1906 case of defer_me didn't look in the kind. But it seemed reasonable to
1907 simply remove the defer_me check instead.
1908
1909 It referred to two Notes (since removed) that were out of date, and the
1910 fast_check code in occurCheckExpand seemed to do just about the same thing as
1911 defer_me. The one piece that defer_me did that wasn't repeated by
1912 occurCheckExpand was the type-family check. (See Note [Prevent unification
1913 with type families].) So I checked the result of occurCheckExpand for any
1914 type family occurrences and deferred if there were any. This was done
1915 in commit e9bf7bb5cc9fb3f87dd05111aa23da76b86a8967 .
1916
1917 This approach turned out not to be performant, because the expanded
1918 type was bigger than the original type, and tyConsOfType (needed to
1919 see if there are any type family occurrences) looks through type
1920 synonyms. So it then struck me that we could dispense with the
1921 defer_me check entirely. This simplified the code nicely, and it cut
1922 the allocations in T5030 by half. But, as documented in Note [Prevent
1923 unification with type families], this destroyed performance in
1924 T3064. Regardless, I missed this regression and the change was
1925 committed as 3f5d1a13f112f34d992f6b74656d64d95a3f506d .
1926
1927 Bottom lines:
1928 * defer_me is back, but now fixed w.r.t. #11407.
1929 * Tread carefully before you start to refactor here. There can be
1930 lots of hard-to-predict consequences.
1931
1932 Note [Type synonyms and the occur check]
1933 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1934 Generally speaking we try to update a variable with type synonyms not
1935 expanded, which improves later error messages, unless looking
1936 inside a type synonym may help resolve a spurious occurs check
1937 error. Consider:
1938 type A a = ()
1939
1940 f :: (A a -> a -> ()) -> ()
1941 f = \ _ -> ()
1942
1943 x :: ()
1944 x = f (\ x p -> p x)
1945
1946 We will eventually get a constraint of the form t ~ A t. The ok function above will
1947 properly expand the type (A t) to just (), which is ok to be unified with t. If we had
1948 unified with the original type A t, we would lead the type checker into an infinite loop.
1949
1950 Hence, if the occurs check fails for a type synonym application, then (and *only* then),
1951 the ok function expands the synonym to detect opportunities for occurs check success using
1952 the underlying definition of the type synonym.
1953
1954 The same applies later on in the constraint interaction code; see TcInteract,
1955 function @occ_check_ok@.
1956
1957 Note [Non-TcTyVars in TcUnify]
1958 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1959 Because the same code is now shared between unifying types and unifying
1960 kinds, we sometimes will see proper TyVars floating around the unifier.
1961 Example (from test case polykinds/PolyKinds12):
1962
1963 type family Apply (f :: k1 -> k2) (x :: k1) :: k2
1964 type instance Apply g y = g y
1965
1966 When checking the instance declaration, we first *kind-check* the LHS
1967 and RHS, discovering that the instance really should be
1968
1969 type instance Apply k3 k4 (g :: k3 -> k4) (y :: k3) = g y
1970
1971 During this kind-checking, all the tyvars will be TcTyVars. Then, however,
1972 as a second pass, we desugar the RHS (which is done in functions prefixed
1973 with "tc" in TcTyClsDecls"). By this time, all the kind-vars are proper
1974 TyVars, not TcTyVars, get some kind unification must happen.
1975
1976 Thus, we always check if a TyVar is a TcTyVar before asking if it's a
1977 meta-tyvar.
1978
1979 This used to not be necessary for type-checking (that is, before * :: *)
1980 because expressions get desugared via an algorithm separate from
1981 type-checking (with wrappers, etc.). Types get desugared very differently,
1982 causing this wibble in behavior seen here.
1983 -}
1984
1985 data LookupTyVarResult -- The result of a lookupTcTyVar call
1986 = Unfilled TcTyVarDetails -- SkolemTv or virgin MetaTv
1987 | Filled TcType
1988
1989 lookupTcTyVar :: TcTyVar -> TcM LookupTyVarResult
1990 lookupTcTyVar tyvar
1991 | MetaTv { mtv_ref = ref } <- details
1992 = do { meta_details <- readMutVar ref
1993 ; case meta_details of
1994 Indirect ty -> return (Filled ty)
1995 Flexi -> do { is_touchable <- isTouchableTcM tyvar
1996 -- Note [Unifying untouchables]
1997 ; if is_touchable then
1998 return (Unfilled details)
1999 else
2000 return (Unfilled vanillaSkolemTv) } }
2001 | otherwise
2002 = return (Unfilled details)
2003 where
2004 details = tcTyVarDetails tyvar
2005
2006 {-
2007 Note [Unifying untouchables]
2008 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2009 We treat an untouchable type variable as if it was a skolem. That
2010 ensures it won't unify with anything. It's a slight hack, because
2011 we return a made-up TcTyVarDetails, but I think it works smoothly.
2012 -}
2013
2014 -- | Breaks apart a function kind into its pieces.
2015 matchExpectedFunKind :: Outputable fun
2016 => fun -- ^ type, only for errors
2017 -> TcKind -- ^ function kind
2018 -> TcM (Coercion, TcKind, TcKind)
2019 -- ^ co :: old_kind ~ arg -> res
2020 matchExpectedFunKind hs_ty = go
2021 where
2022 go k | Just k' <- tcView k = go k'
2023
2024 go k@(TyVarTy kvar)
2025 | isMetaTyVar kvar
2026 = do { maybe_kind <- readMetaTyVar kvar
2027 ; case maybe_kind of
2028 Indirect fun_kind -> go fun_kind
2029 Flexi -> defer k }
2030
2031 go k@(FunTy arg res) = return (mkNomReflCo k, arg, res)
2032 go other = defer other
2033
2034 defer k
2035 = do { arg_kind <- newMetaKindVar
2036 ; res_kind <- newMetaKindVar
2037 ; let new_fun = mkFunTy arg_kind res_kind
2038 origin = TypeEqOrigin { uo_actual = k
2039 , uo_expected = new_fun
2040 , uo_thing = Just (ppr hs_ty)
2041 , uo_visible = True
2042 }
2043 ; co <- uType KindLevel origin k new_fun
2044 ; return (co, arg_kind, res_kind) }
2045
2046
2047 {- *********************************************************************
2048 * *
2049 Occurrence checking
2050 * *
2051 ********************************************************************* -}
2052
2053
2054 {- Note [Occurrence checking: look inside kinds]
2055 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2056 Suppose we are considering unifying
2057 (alpha :: *) ~ Int -> (beta :: alpha -> alpha)
2058 This may be an error (what is that alpha doing inside beta's kind?),
2059 but we must not make the mistake of actually unifying or we'll
2060 build an infinite data structure. So when looking for occurrences
2061 of alpha in the rhs, we must look in the kinds of type variables
2062 that occur there.
2063
2064 NB: we may be able to remove the problem via expansion; see
2065 Note [Occurs check expansion]. So we have to try that.
2066
2067 Note [Checking for foralls]
2068 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
2069 Unless we have -XImpredicativeTypes (which is a totally unsupported
2070 feature), we do not want to unify
2071 alpha ~ (forall a. a->a) -> Int
2072 So we look for foralls hidden inside the type, and it's convenient
2073 to do that at the same time as the occurs check (which looks for
2074 occurrences of alpha).
2075
2076 However, it's not just a question of looking for foralls /anywhere/!
2077 Consider
2078 (alpha :: forall k. k->*) ~ (beta :: forall k. k->*)
2079 This is legal; e.g. dependent/should_compile/T11635.
2080
2081 We don't want to reject it because of the forall in beta's kind,
2082 but (see Note [Occurrence checking: look inside kinds]) we do
2083 need to look in beta's kind. So we carry a flag saying if a 'forall'
2084 is OK, and sitch the flag on when stepping inside a kind.
2085
2086 Why is it OK? Why does it not count as impredicative polymorphism?
2087 The reason foralls are bad is because we reply on "seeing" foralls
2088 when doing implicit instantiation. But the forall inside the kind is
2089 fine. We'll generate a kind equality constraint
2090 (forall k. k->*) ~ (forall k. k->*)
2091 to check that the kinds of lhs and rhs are compatible. If alpha's
2092 kind had instead been
2093 (alpha :: kappa)
2094 then this kind equality would rightly complain about unifying kappa
2095 with (forall k. k->*)
2096
2097 -}
2098
2099 data OccCheckResult a
2100 = OC_OK a
2101 | OC_Bad -- Forall or type family
2102 | OC_Occurs
2103
2104 instance Functor OccCheckResult where
2105 fmap = liftM
2106
2107 instance Applicative OccCheckResult where
2108 pure = OC_OK
2109 (<*>) = ap
2110
2111 instance Monad OccCheckResult where
2112 OC_OK x >>= k = k x
2113 OC_Bad >>= _ = OC_Bad
2114 OC_Occurs >>= _ = OC_Occurs
2115
2116 occCheckForErrors :: DynFlags -> TcTyVar -> Type -> OccCheckResult ()
2117 -- Just for error-message generation; so we return OccCheckResult
2118 -- so the caller can report the right kind of error
2119 -- Check whether
2120 -- a) the given variable occurs in the given type.
2121 -- b) there is a forall in the type (unless we have -XImpredicativeTypes)
2122 occCheckForErrors dflags tv ty
2123 = case preCheck dflags True tv ty of
2124 OC_OK _ -> OC_OK ()
2125 OC_Bad -> OC_Bad
2126 OC_Occurs -> case occCheckExpand [tv] ty of
2127 Nothing -> OC_Occurs
2128 Just _ -> OC_OK ()
2129
2130 ----------------
2131 metaTyVarUpdateOK :: DynFlags
2132 -> TcTyVar -- tv :: k1
2133 -> TcType -- ty :: k2
2134 -> Maybe TcType -- possibly-expanded ty
2135 -- (metaTyFVarUpdateOK tv ty)
2136 -- We are about to update the meta-tyvar tv with ty
2137 -- Check (a) that tv doesn't occur in ty (occurs check)
2138 -- (b) that ty does not have any foralls
2139 -- (in the impredicative case), or type functions
2140 --
2141 -- We have two possible outcomes:
2142 -- (1) Return the type to update the type variable with,
2143 -- [we know the update is ok]
2144 -- (2) Return Nothing,
2145 -- [the update might be dodgy]
2146 --
2147 -- Note that "Nothing" does not mean "definite error". For example
2148 -- type family F a
2149 -- type instance F Int = Int
2150 -- consider
2151 -- a ~ F a
2152 -- This is perfectly reasonable, if we later get a ~ Int. For now, though,
2153 -- we return Nothing, leaving it to the later constraint simplifier to
2154 -- sort matters out.
2155 --
2156 -- See Note [Refactoring hazard: checkTauTvUpdate]
2157
2158 metaTyVarUpdateOK dflags tv ty
2159 = case preCheck dflags False tv ty of
2160 -- False <=> type families not ok
2161 -- See Note [Prevent unification with type families]
2162 OC_OK _ -> Just ty
2163 OC_Bad -> Nothing -- forall or type function
2164 OC_Occurs -> occCheckExpand [tv] ty
2165
2166 preCheck :: DynFlags -> Bool -> TcTyVar -> TcType -> OccCheckResult ()
2167 -- A quick check for
2168 -- (a) a forall type (unless -XImpredivativeTypes)
2169 -- (b) a type family
2170 -- (c) an occurrence of the type variable (occurs check)
2171 --
2172 -- For (a) and (b) we check only the top level of the type, NOT
2173 -- inside the kinds of variables it mentions. But for (c) we do
2174 -- look in the kinds of course.
2175
2176 preCheck dflags ty_fam_ok tv ty
2177 = fast_check ty
2178 where
2179 details = tcTyVarDetails tv
2180 impredicative_ok = canUnifyWithPolyType dflags details
2181
2182 ok :: OccCheckResult ()
2183 ok = OC_OK ()
2184
2185 fast_check :: TcType -> OccCheckResult ()
2186 fast_check (TyVarTy tv')
2187 | tv == tv' = OC_Occurs
2188 | otherwise = fast_check_occ (tyVarKind tv')
2189 -- See Note [Occurrence checking: look inside kinds]
2190
2191 fast_check (TyConApp tc tys)
2192 | bad_tc tc = OC_Bad
2193 | otherwise = mapM fast_check tys >> ok
2194 fast_check (LitTy {}) = ok
2195 fast_check (FunTy a r) = fast_check a >> fast_check r
2196 fast_check (AppTy fun arg) = fast_check fun >> fast_check arg
2197 fast_check (CastTy ty co) = fast_check ty >> fast_check_co co
2198 fast_check (CoercionTy co) = fast_check_co co
2199 fast_check (ForAllTy (TvBndr tv' _) ty)
2200 | not impredicative_ok = OC_Bad
2201 | tv == tv' = ok
2202 | otherwise = do { fast_check_occ (tyVarKind tv')
2203 ; fast_check_occ ty }
2204 -- Under a forall we look only for occurrences of
2205 -- the type variable
2206
2207 -- For kinds, we only do an occurs check; we do not worry
2208 -- about type families or foralls
2209 -- See Note [Checking for foralls]
2210 fast_check_occ k | tv `elemVarSet` tyCoVarsOfType k = OC_Occurs
2211 | otherwise = ok
2212
2213 -- For coercions, we are only doing an occurs check here;
2214 -- no bother about impredicativity in coercions, as they're
2215 -- inferred
2216 fast_check_co co | tv `elemVarSet` tyCoVarsOfCo co = OC_Occurs
2217 | otherwise = ok
2218
2219 bad_tc :: TyCon -> Bool
2220 bad_tc tc
2221 | not (impredicative_ok || isTauTyCon tc) = True
2222 | not (ty_fam_ok || isFamFreeTyCon tc) = True
2223 | otherwise = False
2224
2225 canUnifyWithPolyType :: DynFlags -> TcTyVarDetails -> Bool
2226 canUnifyWithPolyType dflags details
2227 = case details of
2228 MetaTv { mtv_info = TyVarTv } -> False
2229 MetaTv { mtv_info = TauTv } -> xopt LangExt.ImpredicativeTypes dflags
2230 _other -> True
2231 -- We can have non-meta tyvars in given constraints