a02f449f322c2dee8c9ce43c60d5a5f3715890f2
[ghc.git] / compiler / iface / MkIface.lhs
1 %
2 % (c) The University of Glasgow 2006
3 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
4 %
5
6 \begin{code}
7 module MkIface ( 
8         mkUsageInfo,    -- Construct the usage info for a module
9
10         mkIface,        -- Build a ModIface from a ModGuts, 
11                         -- including computing version information
12
13         writeIfaceFile, -- Write the interface file
14
15         checkOldIface,  -- See if recompilation is required, by
16                         -- comparing version information
17
18         tyThingToIfaceDecl -- Converting things to their Iface equivalents
19  ) where
20 \end{code}
21
22         -----------------------------------------------
23                 MkIface.lhs deals with versioning
24         -----------------------------------------------
25
26 Here's the version-related info in an interface file
27
28   module Foo 8          -- module-version 
29              3          -- export-list-version
30              2          -- rule-version
31     Usages:     -- Version info for what this compilation of Foo imported
32         Baz 3           -- Module version
33             [4]         -- The export-list version if Foo depended on it
34             (g,2)       -- Function and its version
35             (T,1)       -- Type and its version
36
37     <version> f :: Int -> Int {- Unfolding: \x -> Wib.t[2] x -}
38                 -- The [2] says that f's unfolding 
39                 -- mentions verison 2 of Wib.t
40         
41         -----------------------------------------------
42                         Basic idea
43         -----------------------------------------------
44
45 Basic idea: 
46   * In the mi_usages information in an interface, we record the 
47     version number of each free variable of the module
48
49   * In mkIface, we compute the version number of each exported thing A.f
50     by comparing its A.f's info with its new info, and bumping its 
51     version number if it differs.  If A.f mentions B.g, and B.g's version
52     number has changed, then we count A.f as having changed too.
53
54   * In checkOldIface we compare the mi_usages for the module with
55     the actual version info for all each thing recorded in mi_usages
56
57
58 Fixities
59 ~~~~~~~~
60 We count A.f as changing if its fixity changes
61
62 Rules
63 ~~~~~
64 If a rule changes, we want to recompile any module that might be
65 affected by that rule.  For non-orphan rules, this is relatively easy.
66 If module M defines f, and a rule for f, just arrange that the version
67 number for M.f changes if any of the rules for M.f change.  Any module
68 that does not depend on M.f can't be affected by the rule-change
69 either.
70
71 Orphan rules (ones whose 'head function' is not defined in M) are
72 harder.  Here's what we do.
73
74   * We have a per-module orphan-rule version number which changes if 
75     any orphan rule changes. (It's unaffected by non-orphan rules.)
76
77   * We record usage info for any orphan module 'below' this one,
78     giving the orphan-rule version number.  We recompile if this 
79     changes. 
80
81 The net effect is that if an orphan rule changes, we recompile every
82 module above it.  That's very conservative, but it's devilishly hard
83 to know what it might affect, so we just have to be conservative.
84
85 Instance decls
86 ~~~~~~~~~~~~~~
87 In an iface file we have
88      module A where
89         instance Eq a => Eq [a]  =  dfun29
90         dfun29 :: ... 
91
92 We have a version number for dfun29, covering its unfolding
93 etc. Suppose we are compiling a module M that imports A only
94 indirectly.  If typechecking M uses this instance decl, we record the
95 dependency on A.dfun29 as if it were a free variable of the module
96 (via the tcg_inst_usages accumulator).  That means that A will appear
97 in M's usage list.  If the shape of the instance declaration changes,
98 then so will dfun29's version, triggering a recompilation.
99
100 Adding an instance declaration, or changing an instance decl that is
101 not currently used, is more tricky.  (This really only makes a
102 difference when we have overlapping instance decls, because then the
103 new instance decl might kick in to override the old one.)  We handle
104 this in a very similar way that we handle rules above.
105
106   * For non-orphan instance decls, identify one locally-defined tycon/class
107     mentioned in the decl.  Treat the instance decl as part of the defn of that
108     tycon/class, so that if the shape of the instance decl changes, so does the
109     tycon/class; that in turn will force recompilation of anything that uses
110     that tycon/class.
111
112   * For orphan instance decls, act the same way as for orphan rules.
113     Indeed, we use the same global orphan-rule version number.
114
115 mkUsageInfo
116 ~~~~~~~~~~~
117 mkUsageInfo figures out what the ``usage information'' for this
118 moudule is; that is, what it must record in its interface file as the
119 things it uses.  
120
121 We produce a line for every module B below the module, A, currently being
122 compiled:
123         import B <n> ;
124 to record the fact that A does import B indirectly.  This is used to decide
125 to look to look for B.hi rather than B.hi-boot when compiling a module that
126 imports A.  This line says that A imports B, but uses nothing in it.
127 So we'll get an early bale-out when compiling A if B's version changes.
128
129 The usage information records:
130
131 \begin{itemize}
132 \item   (a) anything reachable from its body code
133 \item   (b) any module exported with a @module Foo@
134 \item   (c) anything reachable from an exported item
135 \end{itemize}
136
137 Why (b)?  Because if @Foo@ changes then this module's export list
138 will change, so we must recompile this module at least as far as
139 making a new interface file --- but in practice that means complete
140 recompilation.
141
142 Why (c)?  Consider this:
143 \begin{verbatim}
144         module A( f, g ) where  |       module B( f ) where
145           import B( f )         |         f = h 3
146           g = ...               |         h = ...
147 \end{verbatim}
148
149 Here, @B.f@ isn't used in A.  Should we nevertheless record @B.f@ in
150 @A@'s usages?  Our idea is that we aren't going to touch A.hi if it is
151 *identical* to what it was before.  If anything about @B.f@ changes
152 than anyone who imports @A@ should be recompiled in case they use
153 @B.f@ (they'll get an early exit if they don't).  So, if anything
154 about @B.f@ changes we'd better make sure that something in A.hi
155 changes, and the convenient way to do that is to record the version
156 number @B.f@ in A.hi in the usage list.  If B.f changes that'll force a
157 complete recompiation of A, which is overkill but it's the only way to 
158 write a new, slightly different, A.hi.
159
160 But the example is tricker.  Even if @B.f@ doesn't change at all,
161 @B.h@ may do so, and this change may not be reflected in @f@'s version
162 number.  But with -O, a module that imports A must be recompiled if
163 @B.h@ changes!  So A must record a dependency on @B.h@.  So we treat
164 the occurrence of @B.f@ in the export list *just as if* it were in the
165 code of A, and thereby haul in all the stuff reachable from it.
166
167         *** Conclusion: if A mentions B.f in its export list,
168             behave just as if A mentioned B.f in its source code,
169             and slurp in B.f and all its transitive closure ***
170
171 [NB: If B was compiled with -O, but A isn't, we should really *still*
172 haul in all the unfoldings for B, in case the module that imports A *is*
173 compiled with -O.  I think this is the case.]
174
175
176 \begin{code}
177 #include "HsVersions.h"
178
179 import IfaceSyn
180 import IfaceType
181 import LoadIface
182 import Id
183 import IdInfo
184 import NewDemand
185 import CoreSyn
186 import CoreFVs
187 import Class
188 import TyCon
189 import DataCon
190 import Type
191 import TcType
192 import InstEnv
193 import FamInstEnv
194 import TcRnMonad
195 import HscTypes
196
197 import DynFlags
198 import Name
199 import NameEnv
200 import NameSet
201 import OccName
202 import Module
203 import BinIface
204 import Unique
205 import ErrUtils
206 import Digraph
207 import SrcLoc
208 import PackageConfig    hiding ( Version )
209 import Outputable
210 import BasicTypes       hiding ( SuccessFlag(..) )
211 import UniqFM
212 import Util             hiding ( eqListBy )
213 import FiniteMap
214 import FastString
215 import Maybes
216
217 import Control.Monad
218 import Data.List
219 \end{code}
220
221
222
223 %************************************************************************
224 %*                                                                      *
225 \subsection{Completing an interface}
226 %*                                                                      *
227 %************************************************************************
228
229 \begin{code}
230 mkIface :: HscEnv
231         -> Maybe ModIface       -- The old interface, if we have it
232         -> ModGuts              -- Usages, deprecations, etc
233         -> ModDetails           -- The trimmed, tidied interface
234         -> IO (ModIface,        -- The new one, complete with decls and versions
235                Bool)            -- True <=> there was an old Iface, and the new one
236                                 --          is identical, so no need to write it
237
238 mkIface hsc_env maybe_old_iface 
239         (ModGuts{     mg_module    = this_mod,
240                       mg_boot      = is_boot,
241                       mg_usages    = usages,
242                       mg_deps      = deps,
243                       mg_rdr_env   = rdr_env,
244                       mg_fix_env   = fix_env,
245                       mg_deprecs   = src_deprecs })
246         (ModDetails{  md_insts     = insts, 
247                       md_fam_insts = fam_insts,
248                       md_rules     = rules,
249                       md_types     = type_env,
250                       md_exports   = exports })
251         
252 -- NB:  notice that mkIface does not look at the bindings
253 --      only at the TypeEnv.  The previous Tidy phase has
254 --      put exactly the info into the TypeEnv that we want
255 --      to expose in the interface
256
257   = do  { eps <- hscEPS hsc_env
258         ; let   { entities = typeEnvElts type_env ;
259                   decls  = [ tyThingToIfaceDecl entity
260                            | entity <- entities,
261                              let name = getName entity,
262                              not (isImplicitTyThing entity),
263                                 -- No implicit Ids and class tycons in the interface file
264                              not (isWiredInName name),
265                                 -- Nor wired-in things; the compiler knows about them anyhow
266                              nameIsLocalOrFrom this_mod name  ]
267                                 -- Sigh: see Note [Root-main Id] in TcRnDriver
268
269                 ; fixities    = [(occ,fix) | FixItem occ fix _ <- nameEnvElts fix_env]
270                 ; deprecs     = mkIfaceDeprec src_deprecs
271                 ; iface_rules = map (coreRuleToIfaceRule this_mod) rules
272                 ; iface_insts = map instanceToIfaceInst insts
273                 ; iface_fam_insts = map famInstToIfaceFamInst fam_insts
274
275                 ; intermediate_iface = ModIface { 
276                         mi_module   = this_mod,
277                         mi_boot     = is_boot,
278                         mi_deps     = deps,
279                         mi_usages   = usages,
280                         mi_exports  = mkIfaceExports exports,
281         
282                         -- Sort these lexicographically, so that
283                         -- the result is stable across compilations
284                         mi_insts    = sortLe le_inst iface_insts,
285                         mi_fam_insts= sortLe le_fam_inst iface_fam_insts,
286                         mi_rules    = sortLe le_rule iface_rules,
287
288                         mi_fixities = fixities,
289                         mi_deprecs  = deprecs,
290                         mi_globals  = Just rdr_env,
291
292                         -- Left out deliberately: filled in by addVersionInfo
293                         mi_mod_vers  = initialVersion,
294                         mi_exp_vers  = initialVersion,
295                         mi_rule_vers = initialVersion,
296                         mi_orphan    = False,   -- Always set by addVersionInfo, but
297                                                 -- it's a strict field, so we can't omit it.
298                         mi_finsts    = False,   -- Ditto
299                         mi_decls     = deliberatelyOmitted "decls",
300                         mi_ver_fn    = deliberatelyOmitted "ver_fn",
301
302                         -- And build the cached values
303                         mi_dep_fn = mkIfaceDepCache deprecs,
304                         mi_fix_fn = mkIfaceFixCache fixities }
305
306                 -- Add version information
307                 ; ext_ver_fn = mkParentVerFun hsc_env eps
308                 ; (new_iface, no_change_at_all, pp_diffs, pp_orphs) 
309                         = _scc_ "versioninfo" 
310                          addVersionInfo ext_ver_fn maybe_old_iface
311                                          intermediate_iface decls
312                 }
313
314                 -- Debug printing
315         ; when (isJust pp_orphs && dopt Opt_WarnOrphans dflags) 
316                (printDump (expectJust "mkIface" pp_orphs))
317         ; when (dopt Opt_D_dump_hi_diffs dflags) (printDump pp_diffs)
318         ; dumpIfSet_dyn dflags Opt_D_dump_hi "FINAL INTERFACE" 
319                         (pprModIface new_iface)
320
321         ; return (new_iface, no_change_at_all) }
322   where
323      r1 `le_rule`     r2 = ifRuleName      r1    <=    ifRuleName      r2
324      i1 `le_inst`     i2 = ifDFun          i1 `le_occ` ifDFun          i2  
325      i1 `le_fam_inst` i2 = ifFamInstTcName i1 `le_occ` ifFamInstTcName i2
326
327      le_occ :: Name -> Name -> Bool
328         -- Compare lexicographically by OccName, *not* by unique, because 
329         -- the latter is not stable across compilations
330      le_occ n1 n2 = nameOccName n1 <= nameOccName n2
331
332      dflags = hsc_dflags hsc_env
333      deliberatelyOmitted x = panic ("Deliberately omitted: " ++ x)
334      ifFamInstTcName = ifaceTyConName . ifFamInstTyCon
335
336 -----------------------------
337 writeIfaceFile :: DynFlags -> ModLocation -> ModIface -> IO ()
338 writeIfaceFile dflags location new_iface
339     = do createDirectoryHierarchy (directoryOf hi_file_path)
340          writeBinIface dflags hi_file_path new_iface
341     where hi_file_path = ml_hi_file location
342
343
344 -- -----------------------------------------------------------------------------
345 -- Look up parents and versions of Names
346
347 -- This is like a global version of the mi_ver_fn field in each ModIface.
348 -- Given a Name, it finds the ModIface, and then uses mi_ver_fn to get
349 -- the parent and version info.
350
351 mkParentVerFun
352         :: HscEnv                       -- needed to look up versions
353         -> ExternalPackageState         -- ditto
354         -> (Name -> (OccName,Version))
355 mkParentVerFun hsc_env eps
356   = \name -> 
357       let 
358         mod = nameModule name
359         occ = nameOccName name
360         iface = lookupIfaceByModule (hsc_dflags hsc_env) hpt pit mod `orElse` 
361                    pprPanic "lookupVers2" (ppr mod <+> ppr occ)
362       in  
363         mi_ver_fn iface occ `orElse` 
364                  pprPanic "lookupVers1" (ppr mod <+> ppr occ)
365   where
366       hpt = hsc_HPT hsc_env
367       pit = eps_PIT eps
368
369 -----------------------------------------------------------------------------
370 -- Compute version numbers for local decls
371
372 addVersionInfo
373         :: (Name -> (OccName,Version))  -- lookup parents and versions of names
374         -> Maybe ModIface  -- The old interface, read from M.hi
375         -> ModIface        -- The new interface (lacking decls)
376         -> [IfaceDecl]     -- The new decls
377         -> (ModIface,   -- Updated interface
378             Bool,          -- True <=> no changes at all; no need to write Iface
379             SDoc,          -- Differences
380             Maybe SDoc) -- Warnings about orphans
381
382 addVersionInfo ver_fn Nothing new_iface new_decls
383 -- No old interface, so definitely write a new one!
384   = (new_iface { mi_orphan = not (null orph_insts && null orph_rules)
385                , mi_finsts = not . null $ mi_fam_insts new_iface
386                , mi_decls  = [(initialVersion, decl) | decl <- new_decls]
387                , mi_ver_fn = mkIfaceVerCache (zip (repeat initialVersion) 
388                                                   new_decls)
389                },
390      False, 
391      ptext SLIT("No old interface file"),
392      pprOrphans orph_insts orph_rules)
393   where
394     orph_insts = filter (isNothing . ifInstOrph) (mi_insts new_iface)
395     orph_rules = filter (isNothing . ifRuleOrph) (mi_rules new_iface)
396
397 addVersionInfo ver_fn (Just old_iface@(ModIface { 
398                                            mi_mod_vers  = old_mod_vers, 
399                                            mi_exp_vers  = old_exp_vers, 
400                                            mi_rule_vers = old_rule_vers, 
401                                            mi_decls     = old_decls,
402                                            mi_ver_fn    = old_decl_vers,
403                                            mi_fix_fn    = old_fixities }))
404                new_iface@(ModIface { mi_fix_fn = new_fixities })
405                new_decls
406  | no_change_at_all
407  = (old_iface,  True,   ptext SLIT("Interface file unchanged"), pp_orphs)
408  | otherwise
409  = (final_iface, False, vcat [ptext SLIT("Interface file has changed"),
410                               nest 2 pp_diffs], pp_orphs)
411  where
412     final_iface = new_iface { 
413                 mi_mod_vers  = bump_unless no_output_change old_mod_vers,
414                 mi_exp_vers  = bump_unless no_export_change old_exp_vers,
415                 mi_rule_vers = bump_unless no_rule_change   old_rule_vers,
416                 mi_orphan    = not (null new_orph_rules && null new_orph_insts),
417                 mi_finsts    = not . null $ mi_fam_insts new_iface,
418                 mi_decls     = decls_w_vers,
419                 mi_ver_fn    = mkIfaceVerCache decls_w_vers }
420
421     decls_w_vers = [(add_vers decl, decl) | decl <- new_decls]
422
423     -------------------
424     (old_non_orph_insts, old_orph_insts) = 
425         mkOrphMap ifInstOrph (mi_insts old_iface)
426     (new_non_orph_insts, new_orph_insts) = 
427         mkOrphMap ifInstOrph (mi_insts new_iface)
428     old_fam_insts = mi_fam_insts old_iface
429     new_fam_insts = mi_fam_insts new_iface
430     same_insts occ = eqMaybeBy  (eqListBy eqIfInst) 
431                                 (lookupOccEnv old_non_orph_insts occ)
432                                 (lookupOccEnv new_non_orph_insts occ)
433   
434     (old_non_orph_rules, old_orph_rules) = 
435         mkOrphMap ifRuleOrph (mi_rules old_iface)
436     (new_non_orph_rules, new_orph_rules) = 
437         mkOrphMap ifRuleOrph (mi_rules new_iface)
438     same_rules occ = eqMaybeBy  (eqListBy eqIfRule)
439                                 (lookupOccEnv old_non_orph_rules occ)
440                                 (lookupOccEnv new_non_orph_rules occ)
441     -------------------
442     -- Computing what changed
443     no_output_change = no_decl_change   && no_rule_change && 
444                        no_export_change && no_deprec_change
445     no_export_change = mi_exports new_iface == mi_exports old_iface
446                                 -- Kept sorted
447     no_decl_change   = isEmptyOccSet changed_occs
448     no_rule_change   = not (changedWrtNames changed_occs (eqListBy eqIfRule old_orph_rules new_orph_rules)
449                          || changedWrtNames changed_occs (eqListBy eqIfInst old_orph_insts new_orph_insts)
450                          || changedWrtNames changed_occs (eqListBy eqIfFamInst old_fam_insts new_fam_insts))
451     no_deprec_change = mi_deprecs new_iface == mi_deprecs old_iface
452
453         -- If the usages havn't changed either, we don't need to write the interface file
454     no_other_changes = mi_usages new_iface == mi_usages old_iface && 
455                        mi_deps new_iface == mi_deps old_iface
456     no_change_at_all = no_output_change && no_other_changes
457  
458     pp_diffs = vcat [pp_change no_export_change "Export list" 
459                         (ppr old_exp_vers <+> arrow <+> ppr (mi_exp_vers final_iface)),
460                      pp_change no_rule_change "Rules"
461                         (ppr old_rule_vers <+> arrow <+> ppr (mi_rule_vers final_iface)),
462                      pp_change no_deprec_change "Deprecations" empty,
463                      pp_change no_other_changes  "Usages" empty,
464                      pp_decl_diffs]
465     pp_change True  what info = empty
466     pp_change False what info = text what <+> ptext SLIT("changed") <+> info
467
468     -------------------
469     old_decl_env = mkOccEnv [(ifName decl, decl) | (_,decl) <- old_decls]
470     same_fixity n = bool (old_fixities n == new_fixities n)
471
472     -------------------
473     -- Adding version info
474     new_version = bumpVersion old_mod_vers
475                         -- Start from the old module version, not from
476                         -- zero so that if you remove f, and then add
477                         -- it again, you don't thereby reduce f's
478                         -- version number
479
480     add_vers decl | occ `elemOccSet` changed_occs = new_version
481                   | otherwise = snd (expectJust "add_vers" (old_decl_vers occ))
482                                 -- If it's unchanged, there jolly well 
483                   where         -- should be an old version number
484                     occ = ifName decl
485
486     -------------------
487     -- Deciding which declarations have changed
488             
489     -- For each local decl, the IfaceEq gives the list of things that
490     -- must be unchanged for the declaration as a whole to be unchanged.
491     eq_info :: [(OccName, IfaceEq)]
492     eq_info = map check_eq new_decls
493     check_eq new_decl
494          | Just old_decl <- lookupOccEnv old_decl_env occ 
495          = (occ, new_decl `eqIfDecl` old_decl &&& eq_indirects new_decl)
496          | otherwise {- No corresponding old decl -}      
497          = (occ, NotEqual)      
498         where
499           occ = ifName new_decl
500
501     eq_indirects :: IfaceDecl -> IfaceEq
502                 -- When seeing if two decls are the same, remember to
503                 -- check whether any relevant fixity or rules have changed
504     eq_indirects (IfaceId {ifName = occ}) = eq_ind_occ occ
505     eq_indirects (IfaceClass {ifName = cls_occ, ifSigs = sigs})
506         = same_insts cls_occ &&& 
507           eq_ind_occs [op | IfaceClassOp op _ _ <- sigs] 
508     eq_indirects (IfaceData {ifName = tc_occ, ifCons = cons})
509         = same_insts tc_occ &&& same_fixity tc_occ &&&  -- The TyCon can have a fixity too
510           eq_ind_occs (map ifConOcc (visibleIfConDecls cons))
511     eq_indirects other = Equal  -- Synonyms and foreign declarations
512
513     eq_ind_occ :: OccName -> IfaceEq    -- For class ops and Ids; check fixity and rules
514     eq_ind_occ occ = same_fixity occ &&& same_rules occ
515     eq_ind_occs = foldr ((&&&) . eq_ind_occ) Equal 
516      
517     -- The Occs of declarations that changed.
518     changed_occs :: OccSet
519     changed_occs = computeChangedOccs ver_fn (mi_module new_iface)
520                          (mi_usages old_iface) eq_info
521
522     -------------------
523     -- Diffs
524     pp_decl_diffs :: SDoc       -- Nothing => no changes
525     pp_decl_diffs 
526         | isEmptyOccSet changed_occs = empty
527         | otherwise 
528         = vcat [ptext SLIT("Changed occs:") <+> ppr (occSetElts changed_occs),
529                 ptext SLIT("Version change for these decls:"),
530                 nest 2 (vcat (map show_change new_decls))]
531
532     eq_env = mkOccEnv eq_info
533     show_change new_decl
534         | not (occ `elemOccSet` changed_occs) = empty
535         | otherwise
536         = vcat [ppr occ <+> ppr (old_decl_vers occ) <+> arrow <+> ppr new_version, 
537                 nest 2 why]
538         where
539           occ = ifName new_decl
540           why = case lookupOccEnv eq_env occ of
541                     Just (EqBut names) -> sep [ppr occ <> colon, ptext SLIT("Free vars (only) changed:") <> ppr names,
542                                               nest 2 (braces (fsep (map ppr (occSetElts 
543                                                 (occs `intersectOccSet` changed_occs)))))]
544                            where occs = mkOccSet (map nameOccName (nameSetToList names))
545                     Just NotEqual  
546                         | Just old_decl <- lookupOccEnv old_decl_env occ 
547                         -> vcat [ptext SLIT("Old:") <+> ppr old_decl,
548                          ptext SLIT("New:") <+> ppr new_decl]
549                         | otherwise 
550                         -> ppr occ <+> ptext SLIT("only in new interface")
551                     other -> pprPanic "MkIface.show_change" (ppr occ)
552         
553     pp_orphs = pprOrphans new_orph_insts new_orph_rules
554
555
556 pprOrphans insts rules
557   | null insts && null rules = Nothing
558   | otherwise
559   = Just $ vcat [
560         if null insts then empty else
561              hang (ptext SLIT("Warning: orphan instances:"))
562                 2 (vcat (map ppr insts)),
563         if null rules then empty else
564              hang (ptext SLIT("Warning: orphan rules:"))
565                 2 (vcat (map ppr rules))
566     ]
567
568 computeChangedOccs
569         :: (Name -> (OccName,Version))     -- get parents and versions
570         -> Module                       -- This module
571         -> [Usage]                      -- Usages from old iface
572         -> [(OccName, IfaceEq)]         -- decl names, equality conditions
573         -> OccSet                       -- set of things that have changed
574 computeChangedOccs ver_fn this_module old_usages eq_info
575   = foldl add_changes emptyOccSet (stronglyConnComp edges)
576   where
577
578     -- return True if an external name has changed
579     name_changed :: Name -> Bool
580     name_changed nm
581         | Just ents <- lookupUFM usg_modmap (moduleName mod) 
582         = case lookupUFM ents parent_occ of
583                 Nothing -> pprPanic "computeChangedOccs" (ppr nm)
584                 Just v  -> v < new_version
585         | otherwise = False -- must be in another package
586       where
587          mod = nameModule nm
588          (parent_occ, new_version) = ver_fn nm
589
590     -- Turn the usages from the old ModIface into a mapping
591     usg_modmap = listToUFM [ (usg_mod usg, listToUFM (usg_entities usg))
592                            | usg <- old_usages ]
593
594     get_local_eq_info :: GenIfaceEq NameSet -> GenIfaceEq OccSet
595     get_local_eq_info Equal = Equal
596     get_local_eq_info NotEqual = NotEqual
597     get_local_eq_info (EqBut ns) = foldNameSet f Equal ns
598         where f name eq | nameModule name == this_module =         
599                           EqBut (unitOccSet (nameOccName name)) `and_occifeq` eq
600                         | name_changed name = NotEqual
601                         | otherwise = eq
602
603     local_eq_infos = mapSnd get_local_eq_info eq_info
604
605     edges :: [((OccName, OccIfaceEq), Unique, [Unique])]
606     edges = [ (node, getUnique occ, map getUnique occs)
607             | node@(occ, iface_eq) <- local_eq_infos
608             , let occs = case iface_eq of
609                            EqBut occ_set -> occSetElts occ_set
610                            other -> [] ]
611
612     -- Changes in declarations
613     add_changes :: OccSet -> SCC (OccName, OccIfaceEq) -> OccSet
614     add_changes so_far (AcyclicSCC (occ, iface_eq)) 
615         | changedWrt so_far iface_eq -- This one has changed
616         = extendOccSet so_far occ
617     add_changes so_far (CyclicSCC pairs)
618         | changedWrt so_far (foldr1 and_occifeq iface_eqs)
619                 -- One of this group has changed
620         = extendOccSetList so_far occs
621         where (occs, iface_eqs) = unzip pairs
622     add_changes so_far other = so_far
623
624 type OccIfaceEq = GenIfaceEq OccSet
625
626 changedWrt :: OccSet -> OccIfaceEq -> Bool
627 changedWrt so_far Equal        = False
628 changedWrt so_far NotEqual     = True
629 changedWrt so_far (EqBut kids) = so_far `intersectsOccSet` kids
630
631 changedWrtNames :: OccSet -> IfaceEq -> Bool
632 changedWrtNames so_far Equal        = False
633 changedWrtNames so_far NotEqual     = True
634 changedWrtNames so_far (EqBut kids) = 
635   so_far `intersectsOccSet` mkOccSet (map nameOccName (nameSetToList kids))
636
637 and_occifeq :: OccIfaceEq -> OccIfaceEq -> OccIfaceEq
638 Equal       `and_occifeq` x         = x
639 NotEqual    `and_occifeq` x         = NotEqual
640 EqBut nms   `and_occifeq` Equal       = EqBut nms
641 EqBut nms   `and_occifeq` NotEqual    = NotEqual
642 EqBut nms1  `and_occifeq` EqBut nms2  = EqBut (nms1 `unionOccSets` nms2)
643
644 ----------------------
645 -- mkOrphMap partitions instance decls or rules into
646 --      (a) an OccEnv for ones that are not orphans, 
647 --          mapping the local OccName to a list of its decls
648 --      (b) a list of orphan decls
649 mkOrphMap :: (decl -> Maybe OccName)    -- (Just occ) for a non-orphan decl, keyed by occ
650                                         -- Nothing for an orphan decl
651           -> [decl]                     -- Sorted into canonical order
652           -> (OccEnv [decl],            -- Non-orphan decls associated with their key;
653                                         --      each sublist in canonical order
654               [decl])                   -- Orphan decls; in canonical order
655 mkOrphMap get_key decls
656   = foldl go (emptyOccEnv, []) decls
657   where
658     go (non_orphs, orphs) d
659         | Just occ <- get_key d
660         = (extendOccEnv_C (\ ds _ -> d:ds) non_orphs occ [d], orphs)
661         | otherwise = (non_orphs, d:orphs)
662
663 ----------------------
664 mkIfaceDeprec :: Deprecations -> IfaceDeprecs
665 mkIfaceDeprec NoDeprecs        = NoDeprecs
666 mkIfaceDeprec (DeprecAll t)    = DeprecAll t
667 mkIfaceDeprec (DeprecSome env) = DeprecSome (sortLe (<=) (nameEnvElts env))
668
669 ----------------------
670 bump_unless :: Bool -> Version -> Version
671 bump_unless True  v = v -- True <=> no change
672 bump_unless False v = bumpVersion v
673 \end{code}
674
675
676 %*********************************************************
677 %*                                                      *
678 \subsection{Keeping track of what we've slurped, and version numbers}
679 %*                                                      *
680 %*********************************************************
681
682
683 \begin{code}
684 mkUsageInfo :: HscEnv 
685             -> ModuleEnv (Module, Bool, SrcSpan)
686             -> [(ModuleName, IsBootInterface)]
687             -> NameSet -> IO [Usage]
688 mkUsageInfo hsc_env dir_imp_mods dep_mods used_names
689   = do  { eps <- hscEPS hsc_env
690         ; let usages = mk_usage_info (eps_PIT eps) hsc_env 
691                                      dir_imp_mods dep_mods used_names
692         ; usages `seqList`  return usages }
693          -- seq the list of Usages returned: occasionally these
694          -- don't get evaluated for a while and we can end up hanging on to
695          -- the entire collection of Ifaces.
696
697 mk_usage_info pit hsc_env dir_imp_mods dep_mods used_names
698   = mapCatMaybes mkUsage dep_mods
699         -- ToDo: do we need to sort into canonical order?
700   where
701     hpt = hsc_HPT hsc_env
702     dflags = hsc_dflags hsc_env
703
704     -- ent_map groups together all the things imported and used
705     -- from a particular module in this package
706     ent_map :: ModuleEnv [OccName]
707     ent_map  = foldNameSet add_mv emptyModuleEnv used_names
708     add_mv name mv_map
709         | isWiredInName name = mv_map  -- ignore wired-in names
710         | otherwise
711         = case nameModule_maybe name of
712              Nothing  -> mv_map         -- ignore internal names
713              Just mod -> extendModuleEnv_C add_item mv_map mod [occ]
714                    where
715                      occ = nameOccName name
716                      add_item occs _ = occ:occs
717     
718     depend_on_exports mod = case lookupModuleEnv dir_imp_mods mod of
719                                 Just (_,no_imp,_) -> not no_imp
720                                 Nothing           -> True
721     
722     -- We want to create a Usage for a home module if 
723     --  a) we used something from; has something in used_names
724     --  b) we imported all of it, even if we used nothing from it
725     --          (need to recompile if its export list changes: export_vers)
726     --  c) is a home-package orphan or family-instance module (need to
727     --          recompile if its instance decls change: rules_vers)
728     mkUsage :: (ModuleName, IsBootInterface) -> Maybe Usage
729     mkUsage (mod_name, _)
730       |  isNothing maybe_iface          -- We can't depend on it if we didn't
731       || (null used_occs                -- load its interface.
732           && isNothing export_vers
733           && not orphan_mod
734           && not finsts_mod)
735       = Nothing                 -- Record no usage info
736     
737       | otherwise       
738       = Just (Usage { usg_name     = mod_name,
739                       usg_mod      = mod_vers,
740                       usg_exports  = export_vers,
741                       usg_entities = fmToList ent_vers,
742                       usg_rules    = rules_vers })
743       where
744         maybe_iface  = lookupIfaceByModule dflags hpt pit mod
745                 -- In one-shot mode, the interfaces for home-package 
746                 -- modules accumulate in the PIT not HPT.  Sigh.
747
748         mod = mkModule (thisPackage dflags) mod_name
749
750         Just iface   = maybe_iface
751         orphan_mod   = mi_orphan    iface
752         finsts_mod   = mi_finsts    iface
753         version_env  = mi_ver_fn    iface
754         mod_vers     = mi_mod_vers  iface
755         rules_vers   = mi_rule_vers iface
756         export_vers | depend_on_exports mod = Just (mi_exp_vers iface)
757                     | otherwise             = Nothing
758     
759         used_occs = lookupModuleEnv ent_map mod `orElse` []
760
761         -- Making a FiniteMap here ensures that (a) we remove duplicates
762         -- when we have usages on several subordinates of a single parent,
763         -- and (b) that the usages emerge in a canonical order, which
764         -- is why we use FiniteMap rather than OccEnv: FiniteMap works
765         -- using Ord on the OccNames, which is a lexicographic ordering.
766         ent_vers :: FiniteMap OccName Version
767         ent_vers = listToFM (map lookup_occ used_occs)
768         
769         lookup_occ occ = 
770             case version_env occ of
771                 Nothing -> pprTrace "hmm, strange" (ppr mod <+> ppr occ) $
772                            (occ, initialVersion) -- does this ever happen?
773                 Just (parent, version) -> (parent, version)
774 \end{code}
775
776 \begin{code}
777 mkIfaceExports :: [AvailInfo]
778                -> [(Module, [GenAvailInfo OccName])]
779   -- Group by module and sort by occurrence
780   -- This keeps the list in canonical order
781 mkIfaceExports exports
782   = [ (mod, eltsFM avails)
783     | (mod, avails) <- fmToList groupFM
784     ]
785   where
786         -- Deliberately use FiniteMap rather than UniqFM so we
787         -- get a canonical ordering
788     groupFM :: ModuleEnv (FiniteMap FastString (GenAvailInfo OccName))
789     groupFM = foldl add emptyModuleEnv exports
790
791     add env avail
792       = extendModuleEnv_C add_avail env mod (unitFM avail_fs avail_occ)
793       where
794         avail_occ = availToOccs avail
795         mod  = nameModule (availName avail)
796         avail_fs = occNameFS (availName avail_occ)
797         add_avail avail_fm _ = addToFM avail_fm avail_fs avail_occ
798
799     availToOccs (Avail n) = Avail (nameOccName n)
800     availToOccs (AvailTC tc ns) = AvailTC (nameOccName tc) (map nameOccName ns)
801 \end{code}
802
803
804 %************************************************************************
805 %*                                                                      *
806         Load the old interface file for this module (unless
807         we have it aleady), and check whether it is up to date
808         
809 %*                                                                      *
810 %************************************************************************
811
812 \begin{code}
813 checkOldIface :: HscEnv
814               -> ModSummary
815               -> Bool                   -- Source unchanged
816               -> Maybe ModIface         -- Old interface from compilation manager, if any
817               -> IO (RecompileRequired, Maybe ModIface)
818
819 checkOldIface hsc_env mod_summary source_unchanged maybe_iface
820   = do  { showPass (hsc_dflags hsc_env) 
821                    ("Checking old interface for " ++ 
822                         showSDoc (ppr (ms_mod mod_summary))) ;
823
824         ; initIfaceCheck hsc_env $
825           check_old_iface hsc_env mod_summary source_unchanged maybe_iface
826      }
827
828 check_old_iface hsc_env mod_summary source_unchanged maybe_iface
829  =  do  -- CHECK WHETHER THE SOURCE HAS CHANGED
830     { ifM (not source_unchanged)
831            (traceHiDiffs (nest 4 (text "Source file changed or recompilation check turned off")))
832
833      -- If the source has changed and we're in interactive mode, avoid reading
834      -- an interface; just return the one we might have been supplied with.
835     ; ghc_mode <- getGhcMode
836     ; if (ghc_mode == Interactive || ghc_mode == JustTypecheck) 
837          && not source_unchanged then
838          return (outOfDate, maybe_iface)
839       else
840       case maybe_iface of {
841         Just old_iface -> do -- Use the one we already have
842           { traceIf (text "We already have the old interface for" <+> ppr (ms_mod mod_summary))
843           ; recomp <- checkVersions hsc_env source_unchanged old_iface
844           ; return (recomp, Just old_iface) }
845
846       ; Nothing -> do
847
848         -- Try and read the old interface for the current module
849         -- from the .hi file left from the last time we compiled it
850     { let iface_path = msHiFilePath mod_summary
851     ; read_result <- readIface (ms_mod mod_summary) iface_path False
852     ; case read_result of {
853          Failed err -> do       -- Old interface file not found, or garbled; give up
854                 { traceIf (text "FYI: cannot read old interface file:"
855                                  $$ nest 4 err)
856                 ; return (outOfDate, Nothing) }
857
858       ;  Succeeded iface -> do
859
860         -- We have got the old iface; check its versions
861     { traceIf (text "Read the interface file" <+> text iface_path)
862     ; recomp <- checkVersions hsc_env source_unchanged iface
863     ; returnM (recomp, Just iface)
864     }}}}}
865 \end{code}
866
867 @recompileRequired@ is called from the HscMain.   It checks whether
868 a recompilation is required.  It needs access to the persistent state,
869 finder, etc, because it may have to load lots of interface files to
870 check their versions.
871
872 \begin{code}
873 type RecompileRequired = Bool
874 upToDate  = False       -- Recompile not required
875 outOfDate = True        -- Recompile required
876
877 checkVersions :: HscEnv
878               -> Bool           -- True <=> source unchanged
879               -> ModIface       -- Old interface
880               -> IfG RecompileRequired
881 checkVersions hsc_env source_unchanged iface
882   | not source_unchanged
883   = returnM outOfDate
884   | otherwise
885   = do  { traceHiDiffs (text "Considering whether compilation is required for" <+> 
886                         ppr (mi_module iface) <> colon)
887
888         -- Source code unchanged and no errors yet... carry on 
889
890         -- First put the dependent-module info, read from the old interface, into the envt, 
891         -- so that when we look for interfaces we look for the right one (.hi or .hi-boot)
892         -- 
893         -- It's just temporary because either the usage check will succeed 
894         -- (in which case we are done with this module) or it'll fail (in which
895         -- case we'll compile the module from scratch anyhow).
896         --      
897         -- We do this regardless of compilation mode, although in --make mode
898         -- all the dependent modules should be in the HPT already, so it's
899         -- quite redundant
900         ; updateEps_ $ \eps  -> eps { eps_is_boot = mod_deps }
901
902         ; let this_pkg = thisPackage (hsc_dflags hsc_env)
903         ; checkList [checkModUsage this_pkg u | u <- mi_usages iface]
904     }
905   where
906         -- This is a bit of a hack really
907     mod_deps :: ModuleNameEnv (ModuleName, IsBootInterface)
908     mod_deps = mkModDeps (dep_mods (mi_deps iface))
909
910 checkModUsage :: PackageId ->Usage -> IfG RecompileRequired
911 -- Given the usage information extracted from the old
912 -- M.hi file for the module being compiled, figure out
913 -- whether M needs to be recompiled.
914
915 checkModUsage this_pkg (Usage { usg_name = mod_name, usg_mod = old_mod_vers,
916                                 usg_rules = old_rule_vers,
917                                 usg_exports = maybe_old_export_vers, 
918                                 usg_entities = old_decl_vers })
919   =     -- Load the imported interface is possible
920     let
921         doc_str = sep [ptext SLIT("need version info for"), ppr mod_name]
922     in
923     traceHiDiffs (text "Checking usages for module" <+> ppr mod_name) `thenM_`
924
925     let
926         mod = mkModule this_pkg mod_name
927     in
928     loadInterface doc_str mod ImportBySystem            `thenM` \ mb_iface ->
929         -- Load the interface, but don't complain on failure;
930         -- Instead, get an Either back which we can test
931
932     case mb_iface of {
933         Failed exn ->  (out_of_date (sep [ptext SLIT("Can't find version number for module"), 
934                                        ppr mod_name]));
935                 -- Couldn't find or parse a module mentioned in the
936                 -- old interface file.  Don't complain -- it might just be that
937                 -- the current module doesn't need that import and it's been deleted
938
939         Succeeded iface -> 
940     let
941         new_mod_vers    = mi_mod_vers  iface
942         new_decl_vers   = mi_ver_fn    iface
943         new_export_vers = mi_exp_vers  iface
944         new_rule_vers   = mi_rule_vers iface
945     in
946         -- CHECK MODULE
947     checkModuleVersion old_mod_vers new_mod_vers        `thenM` \ recompile ->
948     if not recompile then
949         returnM upToDate
950     else
951                                  
952         -- CHECK EXPORT LIST
953     if checkExportList maybe_old_export_vers new_export_vers then
954         out_of_date_vers (ptext SLIT("  Export list changed"))
955                          (expectJust "checkModUsage" maybe_old_export_vers) 
956                          new_export_vers
957     else
958
959         -- CHECK RULES
960     if old_rule_vers /= new_rule_vers then
961         out_of_date_vers (ptext SLIT("  Rules changed")) 
962                          old_rule_vers new_rule_vers
963     else
964
965         -- CHECK ITEMS ONE BY ONE
966     checkList [checkEntityUsage new_decl_vers u | u <- old_decl_vers]   `thenM` \ recompile ->
967     if recompile then
968         returnM outOfDate       -- This one failed, so just bail out now
969     else
970         up_to_date (ptext SLIT("  Great!  The bits I use are up to date"))
971     }
972
973 ------------------------
974 checkModuleVersion old_mod_vers new_mod_vers
975   | new_mod_vers == old_mod_vers
976   = up_to_date (ptext SLIT("Module version unchanged"))
977
978   | otherwise
979   = out_of_date_vers (ptext SLIT("  Module version has changed"))
980                      old_mod_vers new_mod_vers
981
982 ------------------------
983 checkExportList Nothing  new_vers = upToDate
984 checkExportList (Just v) new_vers = v /= new_vers
985
986 ------------------------
987 checkEntityUsage new_vers (name,old_vers)
988   = case new_vers name of
989
990         Nothing       ->        -- We used it before, but it ain't there now
991                           out_of_date (sep [ptext SLIT("No longer exported:"), ppr name])
992
993         Just (_, new_vers)      -- It's there, but is it up to date?
994           | new_vers == old_vers -> traceHiDiffs (text "  Up to date" <+> ppr name <+> parens (ppr new_vers)) `thenM_`
995                                     returnM upToDate
996           | otherwise            -> out_of_date_vers (ptext SLIT("  Out of date:") <+> ppr name)
997                                                      old_vers new_vers
998
999 up_to_date  msg = traceHiDiffs msg `thenM_` returnM upToDate
1000 out_of_date msg = traceHiDiffs msg `thenM_` returnM outOfDate
1001 out_of_date_vers msg old_vers new_vers 
1002   = out_of_date (hsep [msg, ppr old_vers, ptext SLIT("->"), ppr new_vers])
1003
1004 ----------------------
1005 checkList :: [IfG RecompileRequired] -> IfG RecompileRequired
1006 -- This helper is used in two places
1007 checkList []             = returnM upToDate
1008 checkList (check:checks) = check        `thenM` \ recompile ->
1009                            if recompile then 
1010                                 returnM outOfDate
1011                            else
1012                                 checkList checks
1013 \end{code}
1014
1015 %************************************************************************
1016 %*                                                                      *
1017                 Converting things to their Iface equivalents
1018 %*                                                                      *
1019 %************************************************************************
1020
1021 \begin{code}
1022 tyThingToIfaceDecl :: TyThing -> IfaceDecl
1023 -- Assumption: the thing is already tidied, so that locally-bound names
1024 --             (lambdas, for-alls) already have non-clashing OccNames
1025 -- Reason: Iface stuff uses OccNames, and the conversion here does
1026 --         not do tidying on the way
1027 tyThingToIfaceDecl (AnId id)
1028   = IfaceId { ifName   = getOccName id,
1029               ifType   = toIfaceType (idType id),
1030               ifIdInfo = info }
1031   where
1032     info = case toIfaceIdInfo (idInfo id) of
1033                 []    -> NoInfo
1034                 items -> HasInfo items
1035
1036 tyThingToIfaceDecl (AClass clas)
1037   = IfaceClass { ifCtxt   = toIfaceContext sc_theta,
1038                  ifName   = getOccName clas,
1039                  ifTyVars = toIfaceTvBndrs clas_tyvars,
1040                  ifFDs    = map toIfaceFD clas_fds,
1041                  ifATs    = map (tyThingToIfaceDecl . ATyCon) clas_ats,
1042                  ifSigs   = map toIfaceClassOp op_stuff,
1043                  ifRec    = boolToRecFlag (isRecursiveTyCon tycon) }
1044   where
1045     (clas_tyvars, clas_fds, sc_theta, _, clas_ats, op_stuff) 
1046       = classExtraBigSig clas
1047     tycon = classTyCon clas
1048
1049     toIfaceClassOp (sel_id, def_meth)
1050         = ASSERT(sel_tyvars == clas_tyvars)
1051           IfaceClassOp (getOccName sel_id) def_meth (toIfaceType op_ty)
1052         where
1053                 -- Be careful when splitting the type, because of things
1054                 -- like         class Foo a where
1055                 --                op :: (?x :: String) => a -> a
1056                 -- and          class Baz a where
1057                 --                op :: (Ord a) => a -> a
1058           (sel_tyvars, rho_ty) = splitForAllTys (idType sel_id)
1059           op_ty                = funResultTy rho_ty
1060
1061     toIfaceFD (tvs1, tvs2) = (map getFS tvs1, map getFS tvs2)
1062
1063 tyThingToIfaceDecl (ATyCon tycon)
1064   | isSynTyCon tycon
1065   = IfaceSyn {  ifName   = getOccName tycon,
1066                 ifTyVars = toIfaceTvBndrs tyvars,
1067                 ifOpenSyn = syn_isOpen,
1068                 ifSynRhs  = toIfaceType syn_tyki }
1069
1070   | isAlgTyCon tycon
1071   = IfaceData { ifName    = getOccName tycon,
1072                 ifTyVars  = toIfaceTvBndrs tyvars,
1073                 ifCtxt    = toIfaceContext (tyConStupidTheta tycon),
1074                 ifCons    = ifaceConDecls (algTyConRhs tycon),
1075                 ifRec     = boolToRecFlag (isRecursiveTyCon tycon),
1076                 ifGadtSyntax = isGadtSyntaxTyCon tycon,
1077                 ifGeneric = tyConHasGenerics tycon,
1078                 ifFamInst = famInstToIface (tyConFamInst_maybe tycon)}
1079
1080   | isForeignTyCon tycon
1081   = IfaceForeign { ifName    = getOccName tycon,
1082                    ifExtName = tyConExtName tycon }
1083
1084   | otherwise = pprPanic "toIfaceDecl" (ppr tycon)
1085   where
1086     tyvars = tyConTyVars tycon
1087     (syn_isOpen, syn_tyki) = case synTyConRhs tycon of
1088                                OpenSynTyCon ki _ -> (True , ki)
1089                                SynonymTyCon ty   -> (False, ty)
1090
1091     ifaceConDecls (NewTyCon { data_con = con })     = 
1092       IfNewTyCon  (ifaceConDecl con)
1093     ifaceConDecls (DataTyCon { data_cons = cons })  = 
1094       IfDataTyCon (map ifaceConDecl cons)
1095     ifaceConDecls OpenTyCon { otIsNewtype = False } = IfOpenDataTyCon
1096     ifaceConDecls OpenTyCon { otIsNewtype = True  } = IfOpenNewTyCon
1097     ifaceConDecls AbstractTyCon                     = IfAbstractTyCon
1098         -- The last case happens when a TyCon has been trimmed during tidying
1099         -- Furthermore, tyThingToIfaceDecl is also used
1100         -- in TcRnDriver for GHCi, when browsing a module, in which case the
1101         -- AbstractTyCon case is perfectly sensible.
1102
1103     ifaceConDecl data_con 
1104         = IfCon   { ifConOcc     = getOccName (dataConName data_con),
1105                     ifConInfix   = dataConIsInfix data_con,
1106                     ifConUnivTvs = toIfaceTvBndrs (dataConUnivTyVars data_con),
1107                     ifConExTvs   = toIfaceTvBndrs (dataConExTyVars data_con),
1108                     ifConEqSpec  = to_eq_spec (dataConEqSpec data_con),
1109                     ifConCtxt    = toIfaceContext (dataConTheta data_con),
1110                     ifConArgTys  = map toIfaceType (dataConOrigArgTys data_con),
1111                     ifConFields  = map getOccName 
1112                                        (dataConFieldLabels data_con),
1113                     ifConStricts = dataConStrictMarks data_con }
1114
1115     to_eq_spec spec = [(getOccName tv, toIfaceType ty) | (tv,ty) <- spec]
1116
1117     famInstToIface Nothing                    = Nothing
1118     famInstToIface (Just (famTyCon, instTys)) = 
1119       Just (toIfaceTyCon famTyCon, map toIfaceType instTys)
1120
1121 tyThingToIfaceDecl (ADataCon dc)
1122  = pprPanic "toIfaceDecl" (ppr dc)      -- Should be trimmed out earlier
1123
1124
1125 getFS x = occNameFS (getOccName x)
1126
1127 --------------------------
1128 instanceToIfaceInst :: Instance -> IfaceInst
1129 instanceToIfaceInst ispec@(Instance { is_dfun = dfun_id, is_flag = oflag,
1130                                       is_cls = cls_name, is_tcs = mb_tcs })
1131   = ASSERT( cls_name == className cls )
1132     IfaceInst { ifDFun    = dfun_name,
1133                 ifOFlag   = oflag,
1134                 ifInstCls = cls_name,
1135                 ifInstTys = map do_rough mb_tcs,
1136                 ifInstOrph = orph }
1137   where
1138     do_rough Nothing  = Nothing
1139     do_rough (Just n) = Just (toIfaceTyCon_name n)
1140
1141     dfun_name = idName dfun_id
1142     mod       = nameModule dfun_name
1143     is_local name = nameIsLocalOrFrom mod name
1144
1145         -- Compute orphanhood.  See Note [Orphans] in IfaceSyn
1146     (_, _, cls, tys) = tcSplitDFunTy (idType dfun_id)
1147                 -- Slightly awkward: we need the Class to get the fundeps
1148     (tvs, fds) = classTvsFds cls
1149     arg_names = [filterNameSet is_local (tyClsNamesOfType ty) | ty <- tys]
1150     orph | is_local cls_name = Just (nameOccName cls_name)
1151          | all isJust mb_ns  = head mb_ns
1152          | otherwise         = Nothing
1153     
1154     mb_ns :: [Maybe OccName]    -- One for each fundep; a locally-defined name
1155                                 -- that is not in the "determined" arguments
1156     mb_ns | null fds   = [choose_one arg_names]
1157           | otherwise  = map do_one fds
1158     do_one (ltvs,rtvs) = choose_one [ns | (tv,ns) <- tvs `zip` arg_names
1159                                         , not (tv `elem` rtvs)]
1160
1161     choose_one :: [NameSet] -> Maybe OccName
1162     choose_one nss = case nameSetToList (unionManyNameSets nss) of
1163                         []     -> Nothing
1164                         (n:ns) -> Just (nameOccName n)
1165
1166 --------------------------
1167 famInstToIfaceFamInst :: FamInst -> IfaceFamInst
1168 famInstToIfaceFamInst fi@(FamInst { fi_tycon = tycon,
1169                                             fi_fam = fam, fi_tcs = mb_tcs })
1170   = IfaceFamInst { ifFamInstTyCon  = toIfaceTyCon tycon
1171                  , ifFamInstFam    = fam
1172                  , ifFamInstTys    = map do_rough mb_tcs }
1173   where
1174     do_rough Nothing  = Nothing
1175     do_rough (Just n) = Just (toIfaceTyCon_name n)
1176
1177 --------------------------
1178 toIfaceIdInfo :: IdInfo -> [IfaceInfoItem]
1179 toIfaceIdInfo id_info
1180   = catMaybes [arity_hsinfo, caf_hsinfo, strict_hsinfo, 
1181                inline_hsinfo, wrkr_hsinfo,  unfold_hsinfo] 
1182   where
1183     ------------  Arity  --------------
1184     arity_info = arityInfo id_info
1185     arity_hsinfo | arity_info == 0 = Nothing
1186                  | otherwise       = Just (HsArity arity_info)
1187
1188     ------------ Caf Info --------------
1189     caf_info   = cafInfo id_info
1190     caf_hsinfo = case caf_info of
1191                    NoCafRefs -> Just HsNoCafRefs
1192                    _other    -> Nothing
1193
1194     ------------  Strictness  --------------
1195         -- No point in explicitly exporting TopSig
1196     strict_hsinfo = case newStrictnessInfo id_info of
1197                         Just sig | not (isTopSig sig) -> Just (HsStrictness sig)
1198                         _other                        -> Nothing
1199
1200     ------------  Worker  --------------
1201     work_info   = workerInfo id_info
1202     has_worker  = case work_info of { HasWorker _ _ -> True; other -> False }
1203     wrkr_hsinfo = case work_info of
1204                     HasWorker work_id wrap_arity -> 
1205                         Just (HsWorker ((idName work_id)) wrap_arity)
1206                     NoWorker -> Nothing
1207
1208     ------------  Unfolding  --------------
1209     -- The unfolding is redundant if there is a worker
1210     unfold_info  = unfoldingInfo id_info
1211     rhs          = unfoldingTemplate unfold_info
1212     no_unfolding = neverUnfold unfold_info
1213                         -- The CoreTidy phase retains unfolding info iff
1214                         -- we want to expose the unfolding, taking into account
1215                         -- unconditional NOINLINE, etc.  See TidyPgm.addExternal
1216     unfold_hsinfo | no_unfolding = Nothing                      
1217                   | has_worker   = Nothing      -- Unfolding is implicit
1218                   | otherwise    = Just (HsUnfold (toIfaceExpr rhs))
1219                                         
1220     ------------  Inline prag  --------------
1221     inline_prag = inlinePragInfo id_info
1222     inline_hsinfo | isAlwaysActive inline_prag     = Nothing
1223                   | no_unfolding && not has_worker = Nothing
1224                         -- If the iface file give no unfolding info, we 
1225                         -- don't need to say when inlining is OK!
1226                   | otherwise                      = Just (HsInline inline_prag)
1227
1228 --------------------------
1229 coreRuleToIfaceRule :: Module -> CoreRule -> IfaceRule
1230 coreRuleToIfaceRule mod (BuiltinRule { ru_fn = fn})
1231   = pprTrace "toHsRule: builtin" (ppr fn) $
1232     bogusIfaceRule fn
1233
1234 coreRuleToIfaceRule mod (Rule { ru_name = name, ru_fn = fn, 
1235                                 ru_act = act, ru_bndrs = bndrs,
1236                                 ru_args = args, ru_rhs = rhs })
1237   = IfaceRule { ifRuleName  = name, ifActivation = act, 
1238                 ifRuleBndrs = map toIfaceBndr bndrs,
1239                 ifRuleHead  = fn, 
1240                 ifRuleArgs  = map do_arg args,
1241                 ifRuleRhs   = toIfaceExpr rhs,
1242                 ifRuleOrph  = orph }
1243   where
1244         -- For type args we must remove synonyms from the outermost
1245         -- level.  Reason: so that when we read it back in we'll
1246         -- construct the same ru_rough field as we have right now;
1247         -- see tcIfaceRule
1248     do_arg (Type ty) = IfaceType (toIfaceType (deNoteType ty))
1249     do_arg arg       = toIfaceExpr arg
1250
1251         -- Compute orphanhood.  See Note [Orphans] in IfaceSyn
1252         -- A rule is an orphan only if none of the variables
1253         -- mentioned on its left-hand side are locally defined
1254     lhs_names = fn : nameSetToList (exprsFreeNames args)
1255                 -- No need to delete bndrs, because
1256                 -- exprsFreeNames finds only External names
1257
1258     orph = case filter (nameIsLocalOrFrom mod) lhs_names of
1259                         (n:ns) -> Just (nameOccName n)
1260                         []     -> Nothing
1261
1262 bogusIfaceRule :: Name -> IfaceRule
1263 bogusIfaceRule id_name
1264   = IfaceRule { ifRuleName = FSLIT("bogus"), ifActivation = NeverActive,  
1265         ifRuleBndrs = [], ifRuleHead = id_name, ifRuleArgs = [], 
1266         ifRuleRhs = IfaceExt id_name, ifRuleOrph = Nothing }
1267
1268 ---------------------
1269 toIfaceExpr :: CoreExpr -> IfaceExpr
1270 toIfaceExpr (Var v)       = toIfaceVar v
1271 toIfaceExpr (Lit l)       = IfaceLit l
1272 toIfaceExpr (Type ty)     = IfaceType (toIfaceType ty)
1273 toIfaceExpr (Lam x b)     = IfaceLam (toIfaceBndr x) (toIfaceExpr b)
1274 toIfaceExpr (App f a)     = toIfaceApp f [a]
1275 toIfaceExpr (Case s x ty as) = IfaceCase (toIfaceExpr s) (getFS x) (toIfaceType ty) (map toIfaceAlt as)
1276 toIfaceExpr (Let b e)     = IfaceLet (toIfaceBind b) (toIfaceExpr e)
1277 toIfaceExpr (Cast e co)   = IfaceCast (toIfaceExpr e) (toIfaceType co)
1278 toIfaceExpr (Note n e)    = IfaceNote (toIfaceNote n) (toIfaceExpr e)
1279
1280 ---------------------
1281 toIfaceNote (SCC cc)      = IfaceSCC cc
1282 toIfaceNote InlineMe      = IfaceInlineMe
1283 toIfaceNote (CoreNote s)  = IfaceCoreNote s
1284
1285 ---------------------
1286 toIfaceBind (NonRec b r) = IfaceNonRec (toIfaceIdBndr b) (toIfaceExpr r)
1287 toIfaceBind (Rec prs)    = IfaceRec [(toIfaceIdBndr b, toIfaceExpr r) | (b,r) <- prs]
1288
1289 ---------------------
1290 toIfaceAlt (c,bs,r) = (toIfaceCon c, map getFS bs, toIfaceExpr r)
1291
1292 ---------------------
1293 toIfaceCon (DataAlt dc) | isTupleTyCon tc = IfaceTupleAlt (tupleTyConBoxity tc)
1294                         | otherwise       = IfaceDataAlt (getName dc)
1295                         where
1296                           tc = dataConTyCon dc
1297            
1298 toIfaceCon (LitAlt l) = IfaceLitAlt l
1299 toIfaceCon DEFAULT    = IfaceDefault
1300
1301 ---------------------
1302 toIfaceApp (App f a) as = toIfaceApp f (a:as)
1303 toIfaceApp (Var v) as
1304   = case isDataConWorkId_maybe v of
1305         -- We convert the *worker* for tuples into IfaceTuples
1306         Just dc |  isTupleTyCon tc && saturated 
1307                 -> IfaceTuple (tupleTyConBoxity tc) tup_args
1308           where
1309             val_args  = dropWhile isTypeArg as
1310             saturated = val_args `lengthIs` idArity v
1311             tup_args  = map toIfaceExpr val_args
1312             tc        = dataConTyCon dc
1313
1314         other -> mkIfaceApps (toIfaceVar v) as
1315
1316 toIfaceApp e as = mkIfaceApps (toIfaceExpr e) as
1317
1318 mkIfaceApps f as = foldl (\f a -> IfaceApp f (toIfaceExpr a)) f as
1319
1320 ---------------------
1321 toIfaceVar :: Id -> IfaceExpr
1322 toIfaceVar v 
1323   | Just fcall <- isFCallId_maybe v = IfaceFCall fcall (toIfaceType (idType v))
1324           -- Foreign calls have special syntax
1325   | isExternalName name             = IfaceExt name
1326   | otherwise                       = IfaceLcl (getFS name)
1327   where
1328     name = idName v
1329 \end{code}