users-guide: Drop 8.6.1 release notes
[ghc.git] / utils / genprimopcode / Lexer.x
1 {
2 module Lexer (lex_tok) where
3
4 import ParserM (ParserM (..), mkT, mkTv, Token(..), start_code,
5                 set_start_code,
6                 inc_brace_depth, dec_brace_depth,
7                 show_pos, position,
8                 AlexInput, alexGetByte)
9 import qualified ParserM as ParserM (input)
10 }
11
12 words :-
13
14     <0>         $white+             ;
15     <0>         "--" [^\n]* \n      ;
16                 "{"                 { \i -> do {
17                                                 set_start_code in_braces;
18                                                 inc_brace_depth;
19                                                 mkT TOpenBrace i
20                                                }
21                                     }
22                 "}"                 { \i -> do {
23                                                 dec_brace_depth;
24                                                 mkT TCloseBrace i
25                                                }
26                                     }
27     <0>         "->"                { mkT TArrow }
28     <0>         "=>"                { mkT TDArrow }
29     <0>         "="                 { mkT TEquals }
30     <0>         ","                 { mkT TComma }
31     <0>         "("                 { mkT TOpenParen }
32     <0>         ")"                 { mkT TCloseParen }
33     <0>         "(#"                { mkT TOpenParenHash }
34     <0>         "#)"                { mkT THashCloseParen }
35     <0>         "["                 { mkT TOpenBracket }
36     <0>         "]"                 { mkT TCloseBracket }
37     <0>         "<"                 { mkT TOpenAngle }
38     <0>         ">"                 { mkT TCloseAngle }
39     <0>         "section"           { mkT TSection }
40     <0>         "primop"            { mkT TPrimop }
41     <0>         "pseudoop"          { mkT TPseudoop }
42     <0>         "primtype"          { mkT TPrimtype }
43     <0>         "with"              { mkT TWith }
44     <0>         "defaults"          { mkT TDefaults }
45     <0>         "True"              { mkT TTrue }
46     <0>         "False"             { mkT TFalse }
47     <0>         "Dyadic"            { mkT TDyadic }
48     <0>         "Monadic"           { mkT TMonadic }
49     <0>         "Compare"           { mkT TCompare }
50     <0>         "GenPrimOp"         { mkT TGenPrimOp }
51     <0>         "fixity"            { mkT TFixity }
52     <0>         "infix"             { mkT TInfixN }
53     <0>         "infixl"            { mkT TInfixL }
54     <0>         "infixr"            { mkT TInfixR }
55     <0>         "Nothing"           { mkT TNothing }
56     <0>         "vector"            { mkT TVector }
57     <0>         "thats_all_folks"   { mkT TThatsAllFolks }
58     <0>         "SCALAR"            { mkT TSCALAR }
59     <0>         "VECTOR"            { mkT TVECTOR }
60     <0>         "VECTUPLE"          { mkT TVECTUPLE }
61     <0>         [a-z][a-zA-Z0-9\#_]* { mkTv TLowerName }
62     <0>         [A-Z][a-zA-Z0-9\#_]* { mkTv TUpperName }
63     <0>         \-? [0-9][0-9]*     { mkTv (TInteger . read) }
64     <0>         \" [^\"]* \"        { mkTv (TString . tail . init) }
65     <in_braces> [^\{\}]+            { mkTv TNoBraces }
66     <in_braces> \n                  { mkTv TNoBraces }
67
68 {
69 get_tok :: ParserM Token
70 get_tok = ParserM $ \i st ->
71    case alexScan i (start_code st) of
72        AlexEOF -> Right (i, st, TEOF)
73        AlexError _ -> Left ("Lexical error at " ++ show_pos (position i))
74        AlexSkip i' _ -> case get_tok of
75                             ParserM f -> f i' st
76        AlexToken i' l a -> case a $ take l $ ParserM.input i of
77                                ParserM f -> f i' st
78
79 lex_tok :: (Token -> ParserM a) -> ParserM a
80 lex_tok cont = get_tok >>= cont
81 }
82