9d69493d9e460603dc641e9ca6731d8a7ce29bbf
[ghc.git] / compiler / coreSyn / CoreSubst.hs
1 {-
2 (c) The University of Glasgow 2006
3 (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4
5
6 Utility functions on @Core@ syntax
7 -}
8
9 {-# LANGUAGE CPP #-}
10 module CoreSubst (
11 -- * Main data types
12 Subst(..), -- Implementation exported for supercompiler's Renaming.hs only
13 TvSubstEnv, IdSubstEnv, InScopeSet,
14
15 -- ** Substituting into expressions and related types
16 deShadowBinds, substSpec, substRulesForImportedIds,
17 substTy, substCo, substExpr, substExprSC, substBind, substBindSC,
18 substUnfolding, substUnfoldingSC,
19 lookupIdSubst, lookupTCvSubst, substIdOcc,
20 substTickish, substDVarSet,
21
22 -- ** Operations on substitutions
23 emptySubst, mkEmptySubst, mkSubst, mkOpenSubst, substInScope, isEmptySubst,
24 extendIdSubst, extendIdSubstList, extendTCvSubst, extendTvSubstList,
25 extendSubst, extendSubstList, extendSubstWithVar, zapSubstEnv,
26 addInScopeSet, extendInScope, extendInScopeList, extendInScopeIds,
27 isInScope, setInScope,
28 delBndr, delBndrs,
29
30 -- ** Substituting and cloning binders
31 substBndr, substBndrs, substRecBndrs,
32 cloneBndr, cloneBndrs, cloneIdBndr, cloneIdBndrs, cloneRecIdBndrs,
33
34 -- ** Simple expression optimiser
35 simpleOptPgm, simpleOptExpr, simpleOptExprWith,
36 exprIsConApp_maybe, exprIsLiteral_maybe, exprIsLambda_maybe,
37 pushCoArg, pushCoValArg, pushCoTyArg
38 ) where
39
40 #include "HsVersions.h"
41
42 import {-# SOURCE #-} CoreArity ( etaExpandToJoinPoint )
43 -- Needed for simpleOptPgm to convert bindings to join
44 -- points, but CoreArity uses substitutions throughout
45
46 import CoreSyn
47 import CoreFVs
48 import CoreSeq
49 import CoreUtils
50 import Literal ( Literal(MachStr) )
51 import qualified Data.ByteString as BS
52 import OccurAnal( occurAnalyseExpr, occurAnalysePgm )
53
54 import qualified Type
55 import qualified Coercion
56
57 -- We are defining local versions
58 import Type hiding ( substTy, extendTvSubst, extendCvSubst, extendTvSubstList
59 , isInScope, substTyVarBndr, cloneTyVarBndr )
60 import Coercion hiding ( substCo, substCoVarBndr )
61
62 import TyCon ( tyConArity )
63 import DataCon
64 import PrelNames
65 import OptCoercion ( optCoercion )
66 import PprCore ( pprCoreBindings, pprRules )
67 import Module ( Module )
68 import VarSet
69 import VarEnv
70 import Id
71 import Name ( Name )
72 import Var
73 import IdInfo
74 import UniqSupply
75 import Maybes
76 import ErrUtils
77 import DynFlags
78 import BasicTypes ( isAlwaysActive )
79 import Util
80 import Pair
81 import Outputable
82 import PprCore () -- Instances
83 import FastString
84
85 import Data.List
86
87 import TysWiredIn
88
89
90 {-
91 ************************************************************************
92 * *
93 \subsection{Substitutions}
94 * *
95 ************************************************************************
96 -}
97
98 -- | A substitution environment, containing 'Id', 'TyVar', and 'CoVar'
99 -- substitutions.
100 --
101 -- Some invariants apply to how you use the substitution:
102 --
103 -- 1. #in_scope_invariant# The in-scope set contains at least those 'Id's and 'TyVar's that will be in scope /after/
104 -- applying the substitution to a term. Precisely, the in-scope set must be a superset of the free vars of the
105 -- substitution range that might possibly clash with locally-bound variables in the thing being substituted in.
106 --
107 -- 2. #apply_once# You may apply the substitution only /once/
108 --
109 -- There are various ways of setting up the in-scope set such that the first of these invariants hold:
110 --
111 -- * Arrange that the in-scope set really is all the things in scope
112 --
113 -- * Arrange that it's the free vars of the range of the substitution
114 --
115 -- * Make it empty, if you know that all the free vars of the substitution are fresh, and hence can't possibly clash
116 data Subst
117 = Subst InScopeSet -- Variables in in scope (both Ids and TyVars) /after/
118 -- applying the substitution
119 IdSubstEnv -- Substitution from NcIds to CoreExprs
120 TvSubstEnv -- Substitution from TyVars to Types
121 CvSubstEnv -- Substitution from CoVars to Coercions
122
123 -- INVARIANT 1: See #in_scope_invariant#
124 -- This is what lets us deal with name capture properly
125 -- It's a hard invariant to check...
126 --
127 -- INVARIANT 2: The substitution is apply-once; see Note [Apply once] with
128 -- Types.TvSubstEnv
129 --
130 -- INVARIANT 3: See Note [Extending the Subst]
131
132 {-
133 Note [Extending the Subst]
134 ~~~~~~~~~~~~~~~~~~~~~~~~~~
135 For a core Subst, which binds Ids as well, we make a different choice for Ids
136 than we do for TyVars.
137
138 For TyVars, see Note [Extending the TCvSubst] with Type.TvSubstEnv
139
140 For Ids, we have a different invariant
141 The IdSubstEnv is extended *only* when the Unique on an Id changes
142 Otherwise, we just extend the InScopeSet
143
144 In consequence:
145
146 * If all subst envs are empty, substExpr would be a
147 no-op, so substExprSC ("short cut") does nothing.
148
149 However, substExpr still goes ahead and substitutes. Reason: we may
150 want to replace existing Ids with new ones from the in-scope set, to
151 avoid space leaks.
152
153 * In substIdBndr, we extend the IdSubstEnv only when the unique changes
154
155 * If the CvSubstEnv, TvSubstEnv and IdSubstEnv are all empty,
156 substExpr does nothing (Note that the above rule for substIdBndr
157 maintains this property. If the incoming envts are both empty, then
158 substituting the type and IdInfo can't change anything.)
159
160 * In lookupIdSubst, we *must* look up the Id in the in-scope set, because
161 it may contain non-trivial changes. Example:
162 (/\a. \x:a. ...x...) Int
163 We extend the TvSubstEnv with [a |-> Int]; but x's unique does not change
164 so we only extend the in-scope set. Then we must look up in the in-scope
165 set when we find the occurrence of x.
166
167 * The requirement to look up the Id in the in-scope set means that we
168 must NOT take no-op short cut when the IdSubst is empty.
169 We must still look up every Id in the in-scope set.
170
171 * (However, we don't need to do so for expressions found in the IdSubst
172 itself, whose range is assumed to be correct wrt the in-scope set.)
173
174 Why do we make a different choice for the IdSubstEnv than the
175 TvSubstEnv and CvSubstEnv?
176
177 * For Ids, we change the IdInfo all the time (e.g. deleting the
178 unfolding), and adding it back later, so using the TyVar convention
179 would entail extending the substitution almost all the time
180
181 * The simplifier wants to look up in the in-scope set anyway, in case it
182 can see a better unfolding from an enclosing case expression
183
184 * For TyVars, only coercion variables can possibly change, and they are
185 easy to spot
186 -}
187
188 -- | An environment for substituting for 'Id's
189 type IdSubstEnv = IdEnv CoreExpr -- Domain is NcIds, i.e. not coercions
190
191 ----------------------------
192 isEmptySubst :: Subst -> Bool
193 isEmptySubst (Subst _ id_env tv_env cv_env)
194 = isEmptyVarEnv id_env && isEmptyVarEnv tv_env && isEmptyVarEnv cv_env
195
196 emptySubst :: Subst
197 emptySubst = Subst emptyInScopeSet emptyVarEnv emptyVarEnv emptyVarEnv
198
199 mkEmptySubst :: InScopeSet -> Subst
200 mkEmptySubst in_scope = Subst in_scope emptyVarEnv emptyVarEnv emptyVarEnv
201
202 mkSubst :: InScopeSet -> TvSubstEnv -> CvSubstEnv -> IdSubstEnv -> Subst
203 mkSubst in_scope tvs cvs ids = Subst in_scope ids tvs cvs
204
205 -- | Find the in-scope set: see "CoreSubst#in_scope_invariant"
206 substInScope :: Subst -> InScopeSet
207 substInScope (Subst in_scope _ _ _) = in_scope
208
209 -- | Remove all substitutions for 'Id's and 'Var's that might have been built up
210 -- while preserving the in-scope set
211 zapSubstEnv :: Subst -> Subst
212 zapSubstEnv (Subst in_scope _ _ _) = Subst in_scope emptyVarEnv emptyVarEnv emptyVarEnv
213
214 -- | Add a substitution for an 'Id' to the 'Subst': you must ensure that the in-scope set is
215 -- such that the "CoreSubst#in_scope_invariant" is true after extending the substitution like this
216 extendIdSubst :: Subst -> Id -> CoreExpr -> Subst
217 -- ToDo: add an ASSERT that fvs(subst-result) is already in the in-scope set
218 extendIdSubst (Subst in_scope ids tvs cvs) v r
219 = ASSERT2( isNonCoVarId v, ppr v $$ ppr r )
220 Subst in_scope (extendVarEnv ids v r) tvs cvs
221
222 -- | Adds multiple 'Id' substitutions to the 'Subst': see also 'extendIdSubst'
223 extendIdSubstList :: Subst -> [(Id, CoreExpr)] -> Subst
224 extendIdSubstList (Subst in_scope ids tvs cvs) prs
225 = ASSERT( all (isNonCoVarId . fst) prs )
226 Subst in_scope (extendVarEnvList ids prs) tvs cvs
227
228 -- | Add a substitution for a 'TyVar' to the 'Subst'
229 -- The 'TyVar' *must* be a real TyVar, and not a CoVar
230 -- You must ensure that the in-scope set is such that
231 -- the "CoreSubst#in_scope_invariant" is true after extending
232 -- the substitution like this.
233 extendTvSubst :: Subst -> TyVar -> Type -> Subst
234 extendTvSubst (Subst in_scope ids tvs cvs) tv ty
235 = ASSERT( isTyVar tv )
236 Subst in_scope ids (extendVarEnv tvs tv ty) cvs
237
238 -- | Adds multiple 'TyVar' substitutions to the 'Subst': see also 'extendTvSubst'
239 extendTvSubstList :: Subst -> [(TyVar,Type)] -> Subst
240 extendTvSubstList subst vrs
241 = foldl' extend subst vrs
242 where
243 extend subst (v, r) = extendTvSubst subst v r
244
245 -- | Add a substitution from a 'CoVar' to a 'Coercion' to the 'Subst': you must ensure that the in-scope set is
246 -- such that the "CoreSubst#in_scope_invariant" is true after extending the substitution like this
247 extendCvSubst :: Subst -> CoVar -> Coercion -> Subst
248 extendCvSubst (Subst in_scope ids tvs cvs) v r
249 = ASSERT( isCoVar v )
250 Subst in_scope ids tvs (extendVarEnv cvs v r)
251
252 -- | Add a substitution appropriate to the thing being substituted
253 -- (whether an expression, type, or coercion). See also
254 -- 'extendIdSubst', 'extendTvSubst', 'extendCvSubst'
255 extendSubst :: Subst -> Var -> CoreArg -> Subst
256 extendSubst subst var arg
257 = case arg of
258 Type ty -> ASSERT( isTyVar var ) extendTvSubst subst var ty
259 Coercion co -> ASSERT( isCoVar var ) extendCvSubst subst var co
260 _ -> ASSERT( isId var ) extendIdSubst subst var arg
261
262 extendSubstWithVar :: Subst -> Var -> Var -> Subst
263 extendSubstWithVar subst v1 v2
264 | isTyVar v1 = ASSERT( isTyVar v2 ) extendTvSubst subst v1 (mkTyVarTy v2)
265 | isCoVar v1 = ASSERT( isCoVar v2 ) extendCvSubst subst v1 (mkCoVarCo v2)
266 | otherwise = ASSERT( isId v2 ) extendIdSubst subst v1 (Var v2)
267
268 -- | Add a substitution as appropriate to each of the terms being
269 -- substituted (whether expressions, types, or coercions). See also
270 -- 'extendSubst'.
271 extendSubstList :: Subst -> [(Var,CoreArg)] -> Subst
272 extendSubstList subst [] = subst
273 extendSubstList subst ((var,rhs):prs) = extendSubstList (extendSubst subst var rhs) prs
274
275 -- | Find the substitution for an 'Id' in the 'Subst'
276 lookupIdSubst :: SDoc -> Subst -> Id -> CoreExpr
277 lookupIdSubst doc (Subst in_scope ids _ _) v
278 | not (isLocalId v) = Var v
279 | Just e <- lookupVarEnv ids v = e
280 | Just v' <- lookupInScope in_scope v = Var v'
281 -- Vital! See Note [Extending the Subst]
282 | otherwise = WARN( True, text "CoreSubst.lookupIdSubst" <+> doc <+> ppr v
283 $$ ppr in_scope)
284 Var v
285
286 -- | Find the substitution for a 'TyVar' in the 'Subst'
287 lookupTCvSubst :: Subst -> TyVar -> Type
288 lookupTCvSubst (Subst _ _ tvs cvs) v
289 | isTyVar v
290 = lookupVarEnv tvs v `orElse` Type.mkTyVarTy v
291 | otherwise
292 = mkCoercionTy $ lookupVarEnv cvs v `orElse` mkCoVarCo v
293
294 delBndr :: Subst -> Var -> Subst
295 delBndr (Subst in_scope ids tvs cvs) v
296 | isCoVar v = Subst in_scope ids tvs (delVarEnv cvs v)
297 | isTyVar v = Subst in_scope ids (delVarEnv tvs v) cvs
298 | otherwise = Subst in_scope (delVarEnv ids v) tvs cvs
299
300 delBndrs :: Subst -> [Var] -> Subst
301 delBndrs (Subst in_scope ids tvs cvs) vs
302 = Subst in_scope (delVarEnvList ids vs) (delVarEnvList tvs vs) (delVarEnvList cvs vs)
303 -- Easiest thing is just delete all from all!
304
305 -- | Simultaneously substitute for a bunch of variables
306 -- No left-right shadowing
307 -- ie the substitution for (\x \y. e) a1 a2
308 -- so neither x nor y scope over a1 a2
309 mkOpenSubst :: InScopeSet -> [(Var,CoreArg)] -> Subst
310 mkOpenSubst in_scope pairs = Subst in_scope
311 (mkVarEnv [(id,e) | (id, e) <- pairs, isId id])
312 (mkVarEnv [(tv,ty) | (tv, Type ty) <- pairs])
313 (mkVarEnv [(v,co) | (v, Coercion co) <- pairs])
314
315 ------------------------------
316 isInScope :: Var -> Subst -> Bool
317 isInScope v (Subst in_scope _ _ _) = v `elemInScopeSet` in_scope
318
319 -- | Add the 'Var' to the in-scope set, but do not remove
320 -- any existing substitutions for it
321 addInScopeSet :: Subst -> VarSet -> Subst
322 addInScopeSet (Subst in_scope ids tvs cvs) vs
323 = Subst (in_scope `extendInScopeSetSet` vs) ids tvs cvs
324
325 -- | Add the 'Var' to the in-scope set: as a side effect,
326 -- and remove any existing substitutions for it
327 extendInScope :: Subst -> Var -> Subst
328 extendInScope (Subst in_scope ids tvs cvs) v
329 = Subst (in_scope `extendInScopeSet` v)
330 (ids `delVarEnv` v) (tvs `delVarEnv` v) (cvs `delVarEnv` v)
331
332 -- | Add the 'Var's to the in-scope set: see also 'extendInScope'
333 extendInScopeList :: Subst -> [Var] -> Subst
334 extendInScopeList (Subst in_scope ids tvs cvs) vs
335 = Subst (in_scope `extendInScopeSetList` vs)
336 (ids `delVarEnvList` vs) (tvs `delVarEnvList` vs) (cvs `delVarEnvList` vs)
337
338 -- | Optimized version of 'extendInScopeList' that can be used if you are certain
339 -- all the things being added are 'Id's and hence none are 'TyVar's or 'CoVar's
340 extendInScopeIds :: Subst -> [Id] -> Subst
341 extendInScopeIds (Subst in_scope ids tvs cvs) vs
342 = Subst (in_scope `extendInScopeSetList` vs)
343 (ids `delVarEnvList` vs) tvs cvs
344
345 setInScope :: Subst -> InScopeSet -> Subst
346 setInScope (Subst _ ids tvs cvs) in_scope = Subst in_scope ids tvs cvs
347
348 -- Pretty printing, for debugging only
349
350 instance Outputable Subst where
351 ppr (Subst in_scope ids tvs cvs)
352 = text "<InScope =" <+> in_scope_doc
353 $$ text " IdSubst =" <+> ppr ids
354 $$ text " TvSubst =" <+> ppr tvs
355 $$ text " CvSubst =" <+> ppr cvs
356 <> char '>'
357 where
358 in_scope_doc = pprVarSet (getInScopeVars in_scope) (braces . fsep . map ppr)
359
360 {-
361 ************************************************************************
362 * *
363 Substituting expressions
364 * *
365 ************************************************************************
366 -}
367
368 -- | Apply a substitution to an entire 'CoreExpr'. Remember, you may only
369 -- apply the substitution /once/: see "CoreSubst#apply_once"
370 --
371 -- Do *not* attempt to short-cut in the case of an empty substitution!
372 -- See Note [Extending the Subst]
373 substExprSC :: SDoc -> Subst -> CoreExpr -> CoreExpr
374 substExprSC doc subst orig_expr
375 | isEmptySubst subst = orig_expr
376 | otherwise = -- pprTrace "enter subst-expr" (doc $$ ppr orig_expr) $
377 subst_expr doc subst orig_expr
378
379 substExpr :: SDoc -> Subst -> CoreExpr -> CoreExpr
380 substExpr doc subst orig_expr = subst_expr doc subst orig_expr
381
382 subst_expr :: SDoc -> Subst -> CoreExpr -> CoreExpr
383 subst_expr doc subst expr
384 = go expr
385 where
386 go (Var v) = lookupIdSubst (doc $$ text "subst_expr") subst v
387 go (Type ty) = Type (substTy subst ty)
388 go (Coercion co) = Coercion (substCo subst co)
389 go (Lit lit) = Lit lit
390 go (App fun arg) = App (go fun) (go arg)
391 go (Tick tickish e) = mkTick (substTickish subst tickish) (go e)
392 go (Cast e co) = Cast (go e) (substCo subst co)
393 -- Do not optimise even identity coercions
394 -- Reason: substitution applies to the LHS of RULES, and
395 -- if you "optimise" an identity coercion, you may
396 -- lose a binder. We optimise the LHS of rules at
397 -- construction time
398
399 go (Lam bndr body) = Lam bndr' (subst_expr doc subst' body)
400 where
401 (subst', bndr') = substBndr subst bndr
402
403 go (Let bind body) = Let bind' (subst_expr doc subst' body)
404 where
405 (subst', bind') = substBind subst bind
406
407 go (Case scrut bndr ty alts) = Case (go scrut) bndr' (substTy subst ty) (map (go_alt subst') alts)
408 where
409 (subst', bndr') = substBndr subst bndr
410
411 go_alt subst (con, bndrs, rhs) = (con, bndrs', subst_expr doc subst' rhs)
412 where
413 (subst', bndrs') = substBndrs subst bndrs
414
415 -- | Apply a substitution to an entire 'CoreBind', additionally returning an updated 'Subst'
416 -- that should be used by subsequent substitutions.
417 substBind, substBindSC :: Subst -> CoreBind -> (Subst, CoreBind)
418
419 substBindSC subst bind -- Short-cut if the substitution is empty
420 | not (isEmptySubst subst)
421 = substBind subst bind
422 | otherwise
423 = case bind of
424 NonRec bndr rhs -> (subst', NonRec bndr' rhs)
425 where
426 (subst', bndr') = substBndr subst bndr
427 Rec pairs -> (subst', Rec (bndrs' `zip` rhss'))
428 where
429 (bndrs, rhss) = unzip pairs
430 (subst', bndrs') = substRecBndrs subst bndrs
431 rhss' | isEmptySubst subst'
432 = rhss
433 | otherwise
434 = map (subst_expr (text "substBindSC") subst') rhss
435
436 substBind subst (NonRec bndr rhs)
437 = (subst', NonRec bndr' (subst_expr (text "substBind") subst rhs))
438 where
439 (subst', bndr') = substBndr subst bndr
440
441 substBind subst (Rec pairs)
442 = (subst', Rec (bndrs' `zip` rhss'))
443 where
444 (bndrs, rhss) = unzip pairs
445 (subst', bndrs') = substRecBndrs subst bndrs
446 rhss' = map (subst_expr (text "substBind") subst') rhss
447
448 -- | De-shadowing the program is sometimes a useful pre-pass. It can be done simply
449 -- by running over the bindings with an empty substitution, because substitution
450 -- returns a result that has no-shadowing guaranteed.
451 --
452 -- (Actually, within a single /type/ there might still be shadowing, because
453 -- 'substTy' is a no-op for the empty substitution, but that's probably OK.)
454 --
455 -- [Aug 09] This function is not used in GHC at the moment, but seems so
456 -- short and simple that I'm going to leave it here
457 deShadowBinds :: CoreProgram -> CoreProgram
458 deShadowBinds binds = snd (mapAccumL substBind emptySubst binds)
459
460 {-
461 ************************************************************************
462 * *
463 Substituting binders
464 * *
465 ************************************************************************
466
467 Remember that substBndr and friends are used when doing expression
468 substitution only. Their only business is substitution, so they
469 preserve all IdInfo (suitably substituted). For example, we *want* to
470 preserve occ info in rules.
471 -}
472
473 -- | Substitutes a 'Var' for another one according to the 'Subst' given, returning
474 -- the result and an updated 'Subst' that should be used by subsequent substitutions.
475 -- 'IdInfo' is preserved by this process, although it is substituted into appropriately.
476 substBndr :: Subst -> Var -> (Subst, Var)
477 substBndr subst bndr
478 | isTyVar bndr = substTyVarBndr subst bndr
479 | isCoVar bndr = substCoVarBndr subst bndr
480 | otherwise = substIdBndr (text "var-bndr") subst subst bndr
481
482 -- | Applies 'substBndr' to a number of 'Var's, accumulating a new 'Subst' left-to-right
483 substBndrs :: Subst -> [Var] -> (Subst, [Var])
484 substBndrs subst bndrs = mapAccumL substBndr subst bndrs
485
486 -- | Substitute in a mutually recursive group of 'Id's
487 substRecBndrs :: Subst -> [Id] -> (Subst, [Id])
488 substRecBndrs subst bndrs
489 = (new_subst, new_bndrs)
490 where -- Here's the reason we need to pass rec_subst to subst_id
491 (new_subst, new_bndrs) = mapAccumL (substIdBndr (text "rec-bndr") new_subst) subst bndrs
492
493 substIdBndr :: SDoc
494 -> Subst -- ^ Substitution to use for the IdInfo
495 -> Subst -> Id -- ^ Substitution and Id to transform
496 -> (Subst, Id) -- ^ Transformed pair
497 -- NB: unfolding may be zapped
498
499 substIdBndr _doc rec_subst subst@(Subst in_scope env tvs cvs) old_id
500 = -- pprTrace "substIdBndr" (doc $$ ppr old_id $$ ppr in_scope) $
501 (Subst (in_scope `extendInScopeSet` new_id) new_env tvs cvs, new_id)
502 where
503 id1 = uniqAway in_scope old_id -- id1 is cloned if necessary
504 id2 | no_type_change = id1
505 | otherwise = setIdType id1 (substTy subst old_ty)
506
507 old_ty = idType old_id
508 no_type_change = (isEmptyVarEnv tvs && isEmptyVarEnv cvs) ||
509 noFreeVarsOfType old_ty
510
511 -- new_id has the right IdInfo
512 -- The lazy-set is because we're in a loop here, with
513 -- rec_subst, when dealing with a mutually-recursive group
514 new_id = maybeModifyIdInfo mb_new_info id2
515 mb_new_info = substIdInfo rec_subst id2 (idInfo id2)
516 -- NB: unfolding info may be zapped
517
518 -- Extend the substitution if the unique has changed
519 -- See the notes with substTyVarBndr for the delVarEnv
520 new_env | no_change = delVarEnv env old_id
521 | otherwise = extendVarEnv env old_id (Var new_id)
522
523 no_change = id1 == old_id
524 -- See Note [Extending the Subst]
525 -- it's /not/ necessary to check mb_new_info and no_type_change
526
527 {-
528 Now a variant that unconditionally allocates a new unique.
529 It also unconditionally zaps the OccInfo.
530 -}
531
532 -- | Very similar to 'substBndr', but it always allocates a new 'Unique' for
533 -- each variable in its output. It substitutes the IdInfo though.
534 cloneIdBndr :: Subst -> UniqSupply -> Id -> (Subst, Id)
535 cloneIdBndr subst us old_id
536 = clone_id subst subst (old_id, uniqFromSupply us)
537
538 -- | Applies 'cloneIdBndr' to a number of 'Id's, accumulating a final
539 -- substitution from left to right
540 cloneIdBndrs :: Subst -> UniqSupply -> [Id] -> (Subst, [Id])
541 cloneIdBndrs subst us ids
542 = mapAccumL (clone_id subst) subst (ids `zip` uniqsFromSupply us)
543
544 cloneBndrs :: Subst -> UniqSupply -> [Var] -> (Subst, [Var])
545 -- Works for all kinds of variables (typically case binders)
546 -- not just Ids
547 cloneBndrs subst us vs
548 = mapAccumL (\subst (v, u) -> cloneBndr subst u v) subst (vs `zip` uniqsFromSupply us)
549
550 cloneBndr :: Subst -> Unique -> Var -> (Subst, Var)
551 cloneBndr subst uniq v
552 | isTyVar v = cloneTyVarBndr subst v uniq
553 | otherwise = clone_id subst subst (v,uniq) -- Works for coercion variables too
554
555 -- | Clone a mutually recursive group of 'Id's
556 cloneRecIdBndrs :: Subst -> UniqSupply -> [Id] -> (Subst, [Id])
557 cloneRecIdBndrs subst us ids
558 = (subst', ids')
559 where
560 (subst', ids') = mapAccumL (clone_id subst') subst
561 (ids `zip` uniqsFromSupply us)
562
563 -- Just like substIdBndr, except that it always makes a new unique
564 -- It is given the unique to use
565 clone_id :: Subst -- Substitution for the IdInfo
566 -> Subst -> (Id, Unique) -- Substitution and Id to transform
567 -> (Subst, Id) -- Transformed pair
568
569 clone_id rec_subst subst@(Subst in_scope idvs tvs cvs) (old_id, uniq)
570 = (Subst (in_scope `extendInScopeSet` new_id) new_idvs tvs new_cvs, new_id)
571 where
572 id1 = setVarUnique old_id uniq
573 id2 = substIdType subst id1
574 new_id = maybeModifyIdInfo (substIdInfo rec_subst id2 (idInfo old_id)) id2
575 (new_idvs, new_cvs) | isCoVar old_id = (idvs, extendVarEnv cvs old_id (mkCoVarCo new_id))
576 | otherwise = (extendVarEnv idvs old_id (Var new_id), cvs)
577
578 {-
579 ************************************************************************
580 * *
581 Types and Coercions
582 * *
583 ************************************************************************
584
585 For types and coercions we just call the corresponding functions in
586 Type and Coercion, but we have to repackage the substitution, from a
587 Subst to a TCvSubst.
588 -}
589
590 substTyVarBndr :: Subst -> TyVar -> (Subst, TyVar)
591 substTyVarBndr (Subst in_scope id_env tv_env cv_env) tv
592 = case Type.substTyVarBndr (TCvSubst in_scope tv_env cv_env) tv of
593 (TCvSubst in_scope' tv_env' cv_env', tv')
594 -> (Subst in_scope' id_env tv_env' cv_env', tv')
595
596 cloneTyVarBndr :: Subst -> TyVar -> Unique -> (Subst, TyVar)
597 cloneTyVarBndr (Subst in_scope id_env tv_env cv_env) tv uniq
598 = case Type.cloneTyVarBndr (TCvSubst in_scope tv_env cv_env) tv uniq of
599 (TCvSubst in_scope' tv_env' cv_env', tv')
600 -> (Subst in_scope' id_env tv_env' cv_env', tv')
601
602 substCoVarBndr :: Subst -> TyVar -> (Subst, TyVar)
603 substCoVarBndr (Subst in_scope id_env tv_env cv_env) cv
604 = case Coercion.substCoVarBndr (TCvSubst in_scope tv_env cv_env) cv of
605 (TCvSubst in_scope' tv_env' cv_env', cv')
606 -> (Subst in_scope' id_env tv_env' cv_env', cv')
607
608 -- | See 'Type.substTy'
609 substTy :: Subst -> Type -> Type
610 substTy subst ty = Type.substTyUnchecked (getTCvSubst subst) ty
611
612 getTCvSubst :: Subst -> TCvSubst
613 getTCvSubst (Subst in_scope _ tenv cenv) = TCvSubst in_scope tenv cenv
614
615 -- | See 'Coercion.substCo'
616 substCo :: Subst -> Coercion -> Coercion
617 substCo subst co = Coercion.substCo (getTCvSubst subst) co
618
619 {-
620 ************************************************************************
621 * *
622 \section{IdInfo substitution}
623 * *
624 ************************************************************************
625 -}
626
627 substIdType :: Subst -> Id -> Id
628 substIdType subst@(Subst _ _ tv_env cv_env) id
629 | (isEmptyVarEnv tv_env && isEmptyVarEnv cv_env) || noFreeVarsOfType old_ty = id
630 | otherwise = setIdType id (substTy subst old_ty)
631 -- The tyCoVarsOfType is cheaper than it looks
632 -- because we cache the free tyvars of the type
633 -- in a Note in the id's type itself
634 where
635 old_ty = idType id
636
637 ------------------
638 -- | Substitute into some 'IdInfo' with regard to the supplied new 'Id'.
639 substIdInfo :: Subst -> Id -> IdInfo -> Maybe IdInfo
640 substIdInfo subst new_id info
641 | nothing_to_do = Nothing
642 | otherwise = Just (info `setRuleInfo` substSpec subst new_id old_rules
643 `setUnfoldingInfo` substUnfolding subst old_unf)
644 where
645 old_rules = ruleInfo info
646 old_unf = unfoldingInfo info
647 nothing_to_do = isEmptyRuleInfo old_rules && not (isFragileUnfolding old_unf)
648
649 ------------------
650 -- | Substitutes for the 'Id's within an unfolding
651 substUnfolding, substUnfoldingSC :: Subst -> Unfolding -> Unfolding
652 -- Seq'ing on the returned Unfolding is enough to cause
653 -- all the substitutions to happen completely
654
655 substUnfoldingSC subst unf -- Short-cut version
656 | isEmptySubst subst = unf
657 | otherwise = substUnfolding subst unf
658
659 substUnfolding subst df@(DFunUnfolding { df_bndrs = bndrs, df_args = args })
660 = df { df_bndrs = bndrs', df_args = args' }
661 where
662 (subst',bndrs') = substBndrs subst bndrs
663 args' = map (substExpr (text "subst-unf:dfun") subst') args
664
665 substUnfolding subst unf@(CoreUnfolding { uf_tmpl = tmpl, uf_src = src })
666 -- Retain an InlineRule!
667 | not (isStableSource src) -- Zap an unstable unfolding, to save substitution work
668 = NoUnfolding
669 | otherwise -- But keep a stable one!
670 = seqExpr new_tmpl `seq`
671 unf { uf_tmpl = new_tmpl }
672 where
673 new_tmpl = substExpr (text "subst-unf") subst tmpl
674
675 substUnfolding _ unf = unf -- NoUnfolding, OtherCon
676
677 ------------------
678 substIdOcc :: Subst -> Id -> Id
679 -- These Ids should not be substituted to non-Ids
680 substIdOcc subst v = case lookupIdSubst (text "substIdOcc") subst v of
681 Var v' -> v'
682 other -> pprPanic "substIdOcc" (vcat [ppr v <+> ppr other, ppr subst])
683
684 ------------------
685 -- | Substitutes for the 'Id's within the 'WorkerInfo' given the new function 'Id'
686 substSpec :: Subst -> Id -> RuleInfo -> RuleInfo
687 substSpec subst new_id (RuleInfo rules rhs_fvs)
688 = seqRuleInfo new_spec `seq` new_spec
689 where
690 subst_ru_fn = const (idName new_id)
691 new_spec = RuleInfo (map (substRule subst subst_ru_fn) rules)
692 (substDVarSet subst rhs_fvs)
693
694 ------------------
695 substRulesForImportedIds :: Subst -> [CoreRule] -> [CoreRule]
696 substRulesForImportedIds subst rules
697 = map (substRule subst not_needed) rules
698 where
699 not_needed name = pprPanic "substRulesForImportedIds" (ppr name)
700
701 ------------------
702 substRule :: Subst -> (Name -> Name) -> CoreRule -> CoreRule
703
704 -- The subst_ru_fn argument is applied to substitute the ru_fn field
705 -- of the rule:
706 -- - Rules for *imported* Ids never change ru_fn
707 -- - Rules for *local* Ids are in the IdInfo for that Id,
708 -- and the ru_fn field is simply replaced by the new name
709 -- of the Id
710 substRule _ _ rule@(BuiltinRule {}) = rule
711 substRule subst subst_ru_fn rule@(Rule { ru_bndrs = bndrs, ru_args = args
712 , ru_fn = fn_name, ru_rhs = rhs
713 , ru_local = is_local })
714 = rule { ru_bndrs = bndrs'
715 , ru_fn = if is_local
716 then subst_ru_fn fn_name
717 else fn_name
718 , ru_args = map (substExpr doc subst') args
719 , ru_rhs = substExpr (text "foo") subst' rhs }
720 -- Do NOT optimise the RHS (previously we did simplOptExpr here)
721 -- See Note [Substitute lazily]
722 where
723 doc = text "subst-rule" <+> ppr fn_name
724 (subst', bndrs') = substBndrs subst bndrs
725
726 ------------------
727 substVects :: Subst -> [CoreVect] -> [CoreVect]
728 substVects subst = map (substVect subst)
729
730 ------------------
731 substVect :: Subst -> CoreVect -> CoreVect
732 substVect subst (Vect v rhs) = Vect v (simpleOptExprWith subst rhs)
733 substVect _subst vd@(NoVect _) = vd
734 substVect _subst vd@(VectType _ _ _) = vd
735 substVect _subst vd@(VectClass _) = vd
736 substVect _subst vd@(VectInst _) = vd
737
738 ------------------
739 substDVarSet :: Subst -> DVarSet -> DVarSet
740 substDVarSet subst fvs
741 = mkDVarSet $ fst $ foldr (subst_fv subst) ([], emptyVarSet) $ dVarSetElems fvs
742 where
743 subst_fv subst fv acc
744 | isId fv = expr_fvs (lookupIdSubst (text "substDVarSet") subst fv) isLocalVar emptyVarSet $! acc
745 | otherwise = tyCoFVsOfType (lookupTCvSubst subst fv) (const True) emptyVarSet $! acc
746
747 ------------------
748 substTickish :: Subst -> Tickish Id -> Tickish Id
749 substTickish subst (Breakpoint n ids)
750 = Breakpoint n (map do_one ids)
751 where
752 do_one = getIdFromTrivialExpr . lookupIdSubst (text "subst_tickish") subst
753 substTickish _subst other = other
754
755 {- Note [Substitute lazily]
756 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
757 The functions that substitute over IdInfo must be pretty lazy, because
758 they are knot-tied by substRecBndrs.
759
760 One case in point was Trac #10627 in which a rule for a function 'f'
761 referred to 'f' (at a differnet type) on the RHS. But instead of just
762 substituting in the rhs of the rule, we were calling simpleOptExpr, which
763 looked at the idInfo for 'f'; result <<loop>>.
764
765 In any case we don't need to optimise the RHS of rules, or unfoldings,
766 because the simplifier will do that.
767
768
769 Note [substTickish]
770 ~~~~~~~~~~~~~~~~~~~~~~
771 A Breakpoint contains a list of Ids. What happens if we ever want to
772 substitute an expression for one of these Ids?
773
774 First, we ensure that we only ever substitute trivial expressions for
775 these Ids, by marking them as NoOccInfo in the occurrence analyser.
776 Then, when substituting for the Id, we unwrap any type applications
777 and abstractions to get back to an Id, with getIdFromTrivialExpr.
778
779 Second, we have to ensure that we never try to substitute a literal
780 for an Id in a breakpoint. We ensure this by never storing an Id with
781 an unlifted type in a Breakpoint - see Coverage.mkTickish.
782 Breakpoints can't handle free variables with unlifted types anyway.
783 -}
784
785 {-
786 Note [Worker inlining]
787 ~~~~~~~~~~~~~~~~~~~~~~
788 A worker can get sustituted away entirely.
789 - it might be trivial
790 - it might simply be very small
791 We do not treat an InlWrapper as an 'occurrence' in the occurrence
792 analyser, so it's possible that the worker is not even in scope any more.
793
794 In all all these cases we simply drop the special case, returning to
795 InlVanilla. The WARN is just so I can see if it happens a lot.
796
797
798 ************************************************************************
799 * *
800 The Very Simple Optimiser
801 * *
802 ************************************************************************
803
804 Note [Getting the map/coerce RULE to work]
805 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
806 We wish to allow the "map/coerce" RULE to fire:
807
808 {-# RULES "map/coerce" map coerce = coerce #-}
809
810 The naive core produced for this is
811
812 forall a b (dict :: Coercible * a b).
813 map @a @b (coerce @a @b @dict) = coerce @[a] @[b] @dict'
814
815 where dict' :: Coercible [a] [b]
816 dict' = ...
817
818 This matches literal uses of `map coerce` in code, but that's not what we
819 want. We want it to match, say, `map MkAge` (where newtype Age = MkAge Int)
820 too. Some of this is addressed by compulsorily unfolding coerce on the LHS,
821 yielding
822
823 forall a b (dict :: Coercible * a b).
824 map @a @b (\(x :: a) -> case dict of
825 MkCoercible (co :: a ~R# b) -> x |> co) = ...
826
827 Getting better. But this isn't exactly what gets produced. This is because
828 Coercible essentially has ~R# as a superclass, and superclasses get eagerly
829 extracted during solving. So we get this:
830
831 forall a b (dict :: Coercible * a b).
832 case Coercible_SCSel @* @a @b dict of
833 _ [Dead] -> map @a @b (\(x :: a) -> case dict of
834 MkCoercible (co :: a ~R# b) -> x |> co) = ...
835
836 Unfortunately, this still abstracts over a Coercible dictionary. We really
837 want it to abstract over the ~R# evidence. So, we have Desugar.unfold_coerce,
838 which transforms the above to (see also Note [Desugaring coerce as cast] in
839 Desugar)
840
841 forall a b (co :: a ~R# b).
842 let dict = MkCoercible @* @a @b co in
843 case Coercible_SCSel @* @a @b dict of
844 _ [Dead] -> map @a @b (\(x :: a) -> case dict of
845 MkCoercible (co :: a ~R# b) -> x |> co) = let dict = ... in ...
846
847 Now, we need simpleOptExpr to fix this up. It does so by taking three
848 separate actions:
849 1. Inline certain non-recursive bindings. The choice whether to inline
850 is made in maybe_substitute. Note the rather specific check for
851 MkCoercible in there.
852
853 2. Stripping case expressions like the Coercible_SCSel one.
854 See the `Case` case of simple_opt_expr's `go` function.
855
856 3. Look for case expressions that unpack something that was
857 just packed and inline them. This is also done in simple_opt_expr's
858 `go` function.
859
860 This is all a fair amount of special-purpose hackery, but it's for
861 a good cause. And it won't hurt other RULES and such that it comes across.
862
863 -}
864
865 simpleOptExpr :: CoreExpr -> CoreExpr
866 -- Do simple optimisation on an expression
867 -- The optimisation is very straightforward: just
868 -- inline non-recursive bindings that are used only once,
869 -- or where the RHS is trivial
870 --
871 -- We also inline bindings that bind a Eq# box: see
872 -- See Note [Getting the map/coerce RULE to work].
873 --
874 -- Also we convert functions to join points where possible (as
875 -- the occurrence analyser does most of the work anyway).
876 --
877 -- The result is NOT guaranteed occurrence-analysed, because
878 -- in (let x = y in ....) we substitute for x; so y's occ-info
879 -- may change radically
880
881 simpleOptExpr expr
882 = -- pprTrace "simpleOptExpr" (ppr init_subst $$ ppr expr)
883 simpleOptExprWith init_subst expr
884 where
885 init_subst = mkEmptySubst (mkInScopeSet (exprFreeVars expr))
886 -- It's potentially important to make a proper in-scope set
887 -- Consider let x = ..y.. in \y. ...x...
888 -- Then we should remember to clone y before substituting
889 -- for x. It's very unlikely to occur, because we probably
890 -- won't *be* substituting for x if it occurs inside a
891 -- lambda.
892 --
893 -- It's a bit painful to call exprFreeVars, because it makes
894 -- three passes instead of two (occ-anal, and go)
895
896 simpleOptExprWith :: Subst -> InExpr -> OutExpr
897 simpleOptExprWith subst expr = simple_opt_expr subst (occurAnalyseExpr expr)
898
899 ----------------------
900 simpleOptPgm :: DynFlags -> Module
901 -> CoreProgram -> [CoreRule] -> [CoreVect]
902 -> IO (CoreProgram, [CoreRule], [CoreVect])
903 simpleOptPgm dflags this_mod binds rules vects
904 = do { dumpIfSet_dyn dflags Opt_D_dump_occur_anal "Occurrence analysis"
905 (pprCoreBindings occ_anald_binds $$ pprRules rules );
906
907 ; return (reverse binds', substRulesForImportedIds subst' rules, substVects subst' vects) }
908 where
909 occ_anald_binds = occurAnalysePgm this_mod (\_ -> False) {- No rules active -}
910 rules vects emptyVarEnv binds
911 (subst', binds') = foldl do_one (emptySubst, []) occ_anald_binds
912
913 do_one (subst, binds') bind
914 = case simple_opt_bind subst bind of
915 (subst', Nothing) -> (subst', binds')
916 (subst', Just bind') -> (subst', bind':binds')
917
918 -- In these functions the substitution maps InVar -> OutExpr
919
920 ----------------------
921 simple_opt_expr :: Subst -> InExpr -> OutExpr
922 simple_opt_expr subst expr
923 = go expr
924 where
925 in_scope_env = (substInScope subst, simpleUnfoldingFun)
926
927 go (Var v) = lookupIdSubst (text "simpleOptExpr") subst v
928 go (App e1 e2) = simple_app subst e1 [go e2]
929 go (Type ty) = Type (substTy subst ty)
930 go (Coercion co) = Coercion (optCoercion (getTCvSubst subst) co)
931 go (Lit lit) = Lit lit
932 go (Tick tickish e) = mkTick (substTickish subst tickish) (go e)
933 go (Cast e co) | isReflCo co' = go e
934 | otherwise = Cast (go e) co'
935 where
936 co' = optCoercion (getTCvSubst subst) co
937
938 go (Let bind body) = case simple_opt_bind subst bind of
939 (subst', Nothing) -> simple_opt_expr subst' body
940 (subst', Just bind) -> Let bind (simple_opt_expr subst' body)
941
942 go lam@(Lam {}) = go_lam [] subst lam
943 go (Case e b ty as)
944 -- See Note [Getting the map/coerce RULE to work]
945 | isDeadBinder b
946 , Just (con, _tys, es) <- exprIsConApp_maybe in_scope_env e'
947 , Just (altcon, bs, rhs) <- findAlt (DataAlt con) as
948 = case altcon of
949 DEFAULT -> go rhs
950 _ -> mkLets (catMaybes mb_binds) $ simple_opt_expr subst' rhs
951 where (subst', mb_binds) = mapAccumL simple_opt_out_bind subst
952 (zipEqual "simpleOptExpr" bs es)
953
954 -- Note [Getting the map/coerce RULE to work]
955 | isDeadBinder b
956 , [(DEFAULT, _, rhs)] <- as
957 , isCoercionType (varType b)
958 , (Var fun, _args) <- collectArgs e
959 , fun `hasKey` coercibleSCSelIdKey
960 -- without this last check, we get #11230
961 = go rhs
962
963 | otherwise
964 = Case e' b' (substTy subst ty)
965 (map (go_alt subst') as)
966 where
967 e' = go e
968 (subst', b') = subst_opt_bndr subst b
969
970 ----------------------
971 go_alt subst (con, bndrs, rhs)
972 = (con, bndrs', simple_opt_expr subst' rhs)
973 where
974 (subst', bndrs') = subst_opt_bndrs subst bndrs
975
976 ----------------------
977 -- go_lam tries eta reduction
978 go_lam bs' subst (Lam b e)
979 = go_lam (b':bs') subst' e
980 where
981 (subst', b') = subst_opt_bndr subst b
982 go_lam bs' subst e
983 | Just etad_e <- tryEtaReduce bs e' = etad_e
984 | otherwise = mkLams bs e'
985 where
986 bs = reverse bs'
987 e' = simple_opt_expr subst e
988
989 ----------------------
990 -- simple_app collects arguments for beta reduction
991 simple_app :: Subst -> InExpr -> [OutExpr] -> CoreExpr
992 simple_app subst (App e1 e2) as
993 = simple_app subst e1 (simple_opt_expr subst e2 : as)
994 simple_app subst (Lam b e) (a:as)
995 = case maybe_substitute subst b a of
996 Just ext_subst -> simple_app ext_subst e as
997 Nothing -> Let (NonRec b2 a) (simple_app subst' e as)
998 where
999 (subst', b') = subst_opt_bndr subst b
1000 b2 = add_info subst' b b'
1001 simple_app subst (Var v) as
1002 | isCompulsoryUnfolding (idUnfolding v)
1003 , isAlwaysActive (idInlineActivation v)
1004 -- See Note [Unfold compulsory unfoldings in LHSs]
1005 = simple_app subst (unfoldingTemplate (idUnfolding v)) as
1006 simple_app subst (Tick t e) as
1007 -- Okay to do "(Tick t e) x ==> Tick t (e x)"?
1008 | t `tickishScopesLike` SoftScope
1009 = mkTick t $ simple_app subst e as
1010 simple_app subst e as
1011 = foldl App (simple_opt_expr subst e) as
1012
1013 ----------------------
1014 simple_opt_bind,simple_opt_bind' :: Subst -> CoreBind -> (Subst, Maybe CoreBind)
1015 simple_opt_bind s b -- Can add trace stuff here
1016 = simple_opt_bind' s b
1017
1018 simple_opt_bind' subst (Rec prs)
1019 = (subst'', res_bind)
1020 where
1021 res_bind = Just (Rec (reverse rev_prs'))
1022 prs' = map (uncurry convert_if_marked) prs
1023 (subst', bndrs') = subst_opt_bndrs subst (map fst prs')
1024 (subst'', rev_prs') = foldl do_pr (subst', []) (prs' `zip` bndrs')
1025 do_pr (subst, prs) ((b,r), b')
1026 = case maybe_substitute subst b r2 of
1027 Just subst' -> (subst', prs)
1028 Nothing -> (subst, (b2,r2):prs)
1029 where
1030 b2 = add_info subst b b'
1031 r2 = simple_opt_expr subst r
1032
1033 simple_opt_bind' subst (NonRec b r)
1034 = simple_opt_out_bind subst (b', simple_opt_expr subst r')
1035 where
1036 (b', r') = convert_if_marked b r
1037
1038 convert_if_marked :: InVar -> InExpr -> (InVar, InExpr)
1039 convert_if_marked bndr rhs
1040 | isId bndr
1041 , AlwaysTailCalled ar <- tailCallInfo (idOccInfo bndr)
1042 -- Marked to become a join point
1043 , (bndrs, body) <- etaExpandToJoinPoint ar rhs
1044 = -- Tail call info now unnecessary
1045 (zapIdTailCallInfo (bndr `asJoinId` ar), mkLams bndrs body)
1046 | otherwise
1047 = (bndr, rhs)
1048
1049 ----------------------
1050 simple_opt_out_bind :: Subst -> (InVar, OutExpr) -> (Subst, Maybe CoreBind)
1051 simple_opt_out_bind subst (b, r')
1052 | Just ext_subst <- maybe_substitute subst b r'
1053 = (ext_subst, Nothing)
1054 | otherwise
1055 = (subst', Just (NonRec b2 r'))
1056 where
1057 (subst', b') = subst_opt_bndr subst b
1058 b2 = add_info subst' b b'
1059
1060 ----------------------
1061 maybe_substitute :: Subst -> InVar -> OutExpr -> Maybe Subst
1062 -- (maybe_substitute subst in_var out_rhs)
1063 -- either extends subst with (in_var -> out_rhs)
1064 -- or returns Nothing
1065 maybe_substitute subst b r
1066 | Type ty <- r -- let a::* = TYPE ty in <body>
1067 = ASSERT( isTyVar b )
1068 Just (extendTvSubst subst b ty)
1069
1070 | Coercion co <- r
1071 = ASSERT( isCoVar b )
1072 Just (extendCvSubst subst b co)
1073
1074 | isId b -- let x = e in <body>
1075 , not (isCoVar b) -- See Note [Do not inline CoVars unconditionally]
1076 -- in SimplUtils
1077 , safe_to_inline (idOccInfo b)
1078 , isAlwaysActive (idInlineActivation b) -- Note [Inline prag in simplOpt]
1079 , not (isStableUnfolding (idUnfolding b))
1080 , not (isExportedId b)
1081 , let id_ty = idType b
1082 -- A levity-polymorphic id? Impossible you say?
1083 -- See Note [Levity polymorphism invariants] in CoreSyn
1084 -- Ah, but it *is* possible in the compulsory unfolding of unsafeCoerce#
1085 -- This check prevents the isUnliftedType check from panicking.
1086 , isTypeLevPoly id_ty || not (isUnliftedType (idType b)) || exprOkForSpeculation r
1087 = Just (extendIdSubst subst b r)
1088
1089 | otherwise
1090 = Nothing
1091 where
1092 -- Unconditionally safe to inline
1093 safe_to_inline :: OccInfo -> Bool
1094 safe_to_inline (IAmALoopBreaker {}) = False
1095 safe_to_inline IAmDead = True
1096 safe_to_inline occ@(OneOcc {}) = (not (occ_in_lam occ) &&
1097 occ_one_br occ)
1098 || trivial
1099 safe_to_inline (ManyOccs {}) = trivial
1100
1101 trivial | exprIsTrivial r = True
1102 | (Var fun, args) <- collectArgs r
1103 , Just dc <- isDataConWorkId_maybe fun
1104 , dc `hasKey` heqDataConKey || dc `hasKey` coercibleDataConKey
1105 , all exprIsTrivial args = True
1106 -- See Note [Getting the map/coerce RULE to work]
1107 | otherwise = False
1108
1109 ----------------------
1110 subst_opt_bndr :: Subst -> InVar -> (Subst, OutVar)
1111 subst_opt_bndr subst bndr
1112 | isTyVar bndr = substTyVarBndr subst bndr
1113 | isCoVar bndr = substCoVarBndr subst bndr
1114 | otherwise = subst_opt_id_bndr subst bndr
1115
1116 subst_opt_id_bndr :: Subst -> InId -> (Subst, OutId)
1117 -- Nuke all fragile IdInfo, unfolding, and RULES;
1118 -- it gets added back later by add_info
1119 -- Rather like SimplEnv.substIdBndr
1120 --
1121 -- It's important to zap fragile OccInfo (which CoreSubst.substIdBndr
1122 -- carefully does not do) because simplOptExpr invalidates it
1123
1124 subst_opt_id_bndr subst@(Subst in_scope id_subst tv_subst cv_subst) old_id
1125 = (Subst new_in_scope new_id_subst tv_subst cv_subst, new_id)
1126 where
1127 id1 = uniqAway in_scope old_id
1128 id2 = setIdType id1 (substTy subst (idType old_id))
1129 new_id = zapFragileIdInfo id2
1130 -- Zaps rules, worker-info, unfolding, and fragile OccInfo
1131 -- The unfolding and rules will get added back later, by add_info
1132
1133 new_in_scope = in_scope `extendInScopeSet` new_id
1134
1135 -- Extend the substitution if the unique has changed,
1136 -- or there's some useful occurrence information
1137 -- See the notes with substTyVarBndr for the delSubstEnv
1138 new_id_subst | new_id /= old_id
1139 = extendVarEnv id_subst old_id (Var new_id)
1140 | otherwise
1141 = delVarEnv id_subst old_id
1142
1143 ----------------------
1144 subst_opt_bndrs :: Subst -> [InVar] -> (Subst, [OutVar])
1145 subst_opt_bndrs subst bndrs
1146 = mapAccumL subst_opt_bndr subst bndrs
1147
1148 ----------------------
1149 add_info :: Subst -> InVar -> OutVar -> OutVar
1150 add_info subst old_bndr new_bndr
1151 | isTyVar old_bndr = new_bndr
1152 | otherwise = maybeModifyIdInfo mb_new_info new_bndr
1153 where
1154 mb_new_info = substIdInfo subst new_bndr (idInfo old_bndr)
1155
1156 simpleUnfoldingFun :: IdUnfoldingFun
1157 simpleUnfoldingFun id
1158 | isAlwaysActive (idInlineActivation id) = idUnfolding id
1159 | otherwise = noUnfolding
1160
1161 {-
1162 Note [Inline prag in simplOpt]
1163 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1164 If there's an INLINE/NOINLINE pragma that restricts the phase in
1165 which the binder can be inlined, we don't inline here; after all,
1166 we don't know what phase we're in. Here's an example
1167
1168 foo :: Int -> Int -> Int
1169 {-# INLINE foo #-}
1170 foo m n = inner m
1171 where
1172 {-# INLINE [1] inner #-}
1173 inner m = m+n
1174
1175 bar :: Int -> Int
1176 bar n = foo n 1
1177
1178 When inlining 'foo' in 'bar' we want the let-binding for 'inner'
1179 to remain visible until Phase 1
1180
1181 Note [Unfold compulsory unfoldings in LHSs]
1182 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1183 When the user writes `RULES map coerce = coerce` as a rule, the rule
1184 will only ever match if simpleOptExpr replaces coerce by its unfolding
1185 on the LHS, because that is the core that the rule matching engine
1186 will find. So do that for everything that has a compulsory
1187 unfolding. Also see Note [Desugaring coerce as cast] in Desugar.
1188
1189 However, we don't want to inline 'seq', which happens to also have a
1190 compulsory unfolding, so we only do this unfolding only for things
1191 that are always-active. See Note [User-defined RULES for seq] in MkId.
1192
1193
1194 ************************************************************************
1195 * *
1196 exprIsConApp_maybe
1197 * *
1198 ************************************************************************
1199
1200 Note [exprIsConApp_maybe]
1201 ~~~~~~~~~~~~~~~~~~~~~~~~~
1202 exprIsConApp_maybe is a very important function. There are two principal
1203 uses:
1204 * case e of { .... }
1205 * cls_op e, where cls_op is a class operation
1206
1207 In both cases you want to know if e is of form (C e1..en) where C is
1208 a data constructor.
1209
1210 However e might not *look* as if
1211
1212
1213 Note [exprIsConApp_maybe on literal strings]
1214 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1215 See #9400.
1216
1217 Conceptually, a string literal "abc" is just ('a':'b':'c':[]), but in Core
1218 they are represented as unpackCString# "abc"# by MkCore.mkStringExprFS, or
1219 unpackCStringUtf8# when the literal contains multi-byte UTF8 characters.
1220
1221 For optimizations we want to be able to treat it as a list, so they can be
1222 decomposed when used in a case-statement. exprIsConApp_maybe detects those
1223 calls to unpackCString# and returns:
1224
1225 Just (':', [Char], ['a', unpackCString# "bc"]).
1226
1227 We need to be careful about UTF8 strings here. ""# contains a ByteString, so
1228 we must parse it back into a FastString to split off the first character.
1229 That way we can treat unpackCString# and unpackCStringUtf8# in the same way.
1230
1231 Note [Push coercions in exprIsConApp_maybe]
1232 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1233 In Trac #13025 I found a case where we had
1234 op (df @t1 @t2) -- op is a ClassOp
1235 where
1236 df = (/\a b. K e1 e2) |> g
1237
1238 To get this to come out we need to simplify on the fly
1239 ((/\a b. K e1 e2) |> g) @t1 @t2
1240
1241 Hence the use of pushCoArgs.
1242 -}
1243
1244 data ConCont = CC [CoreExpr] Coercion
1245 -- Substitution already applied
1246
1247 -- | Returns @Just (dc, [t1..tk], [x1..xn])@ if the argument expression is
1248 -- a *saturated* constructor application of the form @dc t1..tk x1 .. xn@,
1249 -- where t1..tk are the *universally-qantified* type args of 'dc'
1250 exprIsConApp_maybe :: InScopeEnv -> CoreExpr -> Maybe (DataCon, [Type], [CoreExpr])
1251 exprIsConApp_maybe (in_scope, id_unf) expr
1252 = go (Left in_scope) expr (CC [] (mkRepReflCo (exprType expr)))
1253 where
1254 go :: Either InScopeSet Subst
1255 -- Left in-scope means "empty substitution"
1256 -- Right subst means "apply this substitution to the CoreExpr"
1257 -> CoreExpr -> ConCont
1258 -> Maybe (DataCon, [Type], [CoreExpr])
1259 go subst (Tick t expr) cont
1260 | not (tickishIsCode t) = go subst expr cont
1261 go subst (Cast expr co1) (CC args co2)
1262 | Just (args', co1') <- pushCoArgs (subst_co subst co1) args
1263 -- See Note [Push coercions in exprIsConApp_maybe]
1264 = go subst expr (CC args' (co1' `mkTransCo` co2))
1265 go subst (App fun arg) (CC args co)
1266 = go subst fun (CC (subst_arg subst arg : args) co)
1267 go subst (Lam var body) (CC (arg:args) co)
1268 | exprIsTrivial arg -- Don't duplicate stuff!
1269 = go (extend subst var arg) body (CC args co)
1270 go (Right sub) (Var v) cont
1271 = go (Left (substInScope sub))
1272 (lookupIdSubst (text "exprIsConApp" <+> ppr expr) sub v)
1273 cont
1274
1275 go (Left in_scope) (Var fun) cont@(CC args co)
1276
1277 | Just con <- isDataConWorkId_maybe fun
1278 , count isValArg args == idArity fun
1279 = pushCoDataCon con args co
1280
1281 -- Look through dictionary functions; see Note [Unfolding DFuns]
1282 | DFunUnfolding { df_bndrs = bndrs, df_con = con, df_args = dfun_args } <- unfolding
1283 , bndrs `equalLength` args -- See Note [DFun arity check]
1284 , let subst = mkOpenSubst in_scope (bndrs `zip` args)
1285 = pushCoDataCon con (map (substExpr (text "exprIsConApp1") subst) dfun_args) co
1286
1287 -- Look through unfoldings, but only arity-zero one;
1288 -- if arity > 0 we are effectively inlining a function call,
1289 -- and that is the business of callSiteInline.
1290 -- In practice, without this test, most of the "hits" were
1291 -- CPR'd workers getting inlined back into their wrappers,
1292 | idArity fun == 0
1293 , Just rhs <- expandUnfolding_maybe unfolding
1294 , let in_scope' = extendInScopeSetSet in_scope (exprFreeVars rhs)
1295 = go (Left in_scope') rhs cont
1296
1297 | (fun `hasKey` unpackCStringIdKey)
1298 || (fun `hasKey` unpackCStringUtf8IdKey)
1299 , [Lit (MachStr str)] <- args
1300 = dealWithStringLiteral fun str co
1301 where
1302 unfolding = id_unf fun
1303
1304 go _ _ _ = Nothing
1305
1306 ----------------------------
1307 -- Operations on the (Either InScopeSet CoreSubst)
1308 -- The Left case is wildly dominant
1309 subst_co (Left {}) co = co
1310 subst_co (Right s) co = CoreSubst.substCo s co
1311
1312 subst_arg (Left {}) e = e
1313 subst_arg (Right s) e = substExpr (text "exprIsConApp2") s e
1314
1315 extend (Left in_scope) v e = Right (extendSubst (mkEmptySubst in_scope) v e)
1316 extend (Right s) v e = Right (extendSubst s v e)
1317
1318
1319 -- See Note [exprIsConApp_maybe on literal strings]
1320 dealWithStringLiteral :: Var -> BS.ByteString -> Coercion
1321 -> Maybe (DataCon, [Type], [CoreExpr])
1322
1323 -- This is not possible with user-supplied empty literals, MkCore.mkStringExprFS
1324 -- turns those into [] automatically, but just in case something else in GHC
1325 -- generates a string literal directly.
1326 dealWithStringLiteral _ str co
1327 | BS.null str
1328 = pushCoDataCon nilDataCon [Type charTy] co
1329
1330 dealWithStringLiteral fun str co
1331 = let strFS = mkFastStringByteString str
1332
1333 char = mkConApp charDataCon [mkCharLit (headFS strFS)]
1334 charTail = fastStringToByteString (tailFS strFS)
1335
1336 -- In singleton strings, just add [] instead of unpackCstring# ""#.
1337 rest = if BS.null charTail
1338 then mkConApp nilDataCon [Type charTy]
1339 else App (Var fun)
1340 (Lit (MachStr charTail))
1341
1342 in pushCoDataCon consDataCon [Type charTy, char, rest] co
1343
1344 {-
1345 Note [Unfolding DFuns]
1346 ~~~~~~~~~~~~~~~~~~~~~~
1347 DFuns look like
1348
1349 df :: forall a b. (Eq a, Eq b) -> Eq (a,b)
1350 df a b d_a d_b = MkEqD (a,b) ($c1 a b d_a d_b)
1351 ($c2 a b d_a d_b)
1352
1353 So to split it up we just need to apply the ops $c1, $c2 etc
1354 to the very same args as the dfun. It takes a little more work
1355 to compute the type arguments to the dictionary constructor.
1356
1357 Note [DFun arity check]
1358 ~~~~~~~~~~~~~~~~~~~~~~~
1359 Here we check that the total number of supplied arguments (inclding
1360 type args) matches what the dfun is expecting. This may be *less*
1361 than the ordinary arity of the dfun: see Note [DFun unfoldings] in CoreSyn
1362 -}
1363
1364 exprIsLiteral_maybe :: InScopeEnv -> CoreExpr -> Maybe Literal
1365 -- Same deal as exprIsConApp_maybe, but much simpler
1366 -- Nevertheless we do need to look through unfoldings for
1367 -- Integer and string literals, which are vigorously hoisted to top level
1368 -- and not subsequently inlined
1369 exprIsLiteral_maybe env@(_, id_unf) e
1370 = case e of
1371 Lit l -> Just l
1372 Tick _ e' -> exprIsLiteral_maybe env e' -- dubious?
1373 Var v | Just rhs <- expandUnfolding_maybe (id_unf v)
1374 -> exprIsLiteral_maybe env rhs
1375 _ -> Nothing
1376
1377 {-
1378 Note [exprIsLambda_maybe]
1379 ~~~~~~~~~~~~~~~~~~~~~~~~~~
1380 exprIsLambda_maybe will, given an expression `e`, try to turn it into the form
1381 `Lam v e'` (returned as `Just (v,e')`). Besides using lambdas, it looks through
1382 casts (using the Push rule), and it unfolds function calls if the unfolding
1383 has a greater arity than arguments are present.
1384
1385 Currently, it is used in Rules.match, and is required to make
1386 "map coerce = coerce" match.
1387 -}
1388
1389 exprIsLambda_maybe :: InScopeEnv -> CoreExpr
1390 -> Maybe (Var, CoreExpr,[Tickish Id])
1391 -- See Note [exprIsLambda_maybe]
1392
1393 -- The simple case: It is a lambda already
1394 exprIsLambda_maybe _ (Lam x e)
1395 = Just (x, e, [])
1396
1397 -- Still straightforward: Ticks that we can float out of the way
1398 exprIsLambda_maybe (in_scope_set, id_unf) (Tick t e)
1399 | tickishFloatable t
1400 , Just (x, e, ts) <- exprIsLambda_maybe (in_scope_set, id_unf) e
1401 = Just (x, e, t:ts)
1402
1403 -- Also possible: A casted lambda. Push the coercion inside
1404 exprIsLambda_maybe (in_scope_set, id_unf) (Cast casted_e co)
1405 | Just (x, e,ts) <- exprIsLambda_maybe (in_scope_set, id_unf) casted_e
1406 -- Only do value lambdas.
1407 -- this implies that x is not in scope in gamma (makes this code simpler)
1408 , not (isTyVar x) && not (isCoVar x)
1409 , ASSERT( not $ x `elemVarSet` tyCoVarsOfCo co) True
1410 , Just (x',e') <- pushCoercionIntoLambda in_scope_set x e co
1411 , let res = Just (x',e',ts)
1412 = --pprTrace "exprIsLambda_maybe:Cast" (vcat [ppr casted_e,ppr co,ppr res)])
1413 res
1414
1415 -- Another attempt: See if we find a partial unfolding
1416 exprIsLambda_maybe (in_scope_set, id_unf) e
1417 | (Var f, as, ts) <- collectArgsTicks tickishFloatable e
1418 , idArity f > count isValArg as
1419 -- Make sure there is hope to get a lambda
1420 , Just rhs <- expandUnfolding_maybe (id_unf f)
1421 -- Optimize, for beta-reduction
1422 , let e' = simpleOptExprWith (mkEmptySubst in_scope_set) (rhs `mkApps` as)
1423 -- Recurse, because of possible casts
1424 , Just (x', e'', ts') <- exprIsLambda_maybe (in_scope_set, id_unf) e'
1425 , let res = Just (x', e'', ts++ts')
1426 = -- pprTrace "exprIsLambda_maybe:Unfold" (vcat [ppr e, ppr (x',e'')])
1427 res
1428
1429 exprIsLambda_maybe _ _e
1430 = -- pprTrace "exprIsLambda_maybe:Fail" (vcat [ppr _e])
1431 Nothing
1432
1433
1434 {- *********************************************************************
1435 * *
1436 The "push rules"
1437 * *
1438 ************************************************************************
1439
1440 Here we implement the "push rules" from FC papers:
1441
1442 * The push-argument ules, where we can move a coercion past an argument.
1443 We have
1444 (fun |> co) arg
1445 and we want to transform it to
1446 (fun arg') |> co'
1447 for some suitable co' and tranformed arg'.
1448
1449 * The PushK rule for data constructors. We have
1450 (K e1 .. en) |> co
1451 and we want to tranform to
1452 (K e1' .. en')
1453 by pushing the coercion into the oarguments
1454 -}
1455
1456 pushCoArgs :: Coercion -> [CoreArg] -> Maybe ([CoreArg], Coercion)
1457 pushCoArgs co [] = return ([], co)
1458 pushCoArgs co (arg:args) = do { (arg', co1) <- pushCoArg co arg
1459 ; (args', co2) <- pushCoArgs co1 args
1460 ; return (arg':args', co2) }
1461
1462 pushCoArg :: Coercion -> CoreArg -> Maybe (CoreArg, Coercion)
1463 -- We have (fun |> co) arg, and we want to transform it to
1464 -- (fun arg) |> co
1465 -- This may fail, e.g. if (fun :: N) where N is a newtype
1466 -- C.f. simplCast in Simplify.hs
1467 -- 'co' is always Representational
1468
1469 pushCoArg co (Type ty) = do { (ty', co') <- pushCoTyArg co ty
1470 ; return (Type ty', co') }
1471 pushCoArg co val_arg = do { (arg_co, co') <- pushCoValArg co
1472 ; return (mkCast val_arg arg_co, co') }
1473
1474 pushCoTyArg :: Coercion -> Type -> Maybe (Type, Coercion)
1475 -- We have (fun |> co) @ty
1476 -- Push the coercion through to return
1477 -- (fun @ty') |> co'
1478 -- 'co' is always Representational
1479 pushCoTyArg co ty
1480 | tyL `eqType` tyR
1481 = Just (ty, mkRepReflCo (piResultTy tyR ty))
1482
1483 | isForAllTy tyL
1484 = ASSERT2( isForAllTy tyR, ppr co $$ ppr ty )
1485 Just (ty `mkCastTy` mkSymCo co1, co2)
1486
1487 | otherwise
1488 = Nothing
1489 where
1490 Pair tyL tyR = coercionKind co
1491 -- co :: tyL ~ tyR
1492 -- tyL = forall (a1 :: k1). ty1
1493 -- tyR = forall (a2 :: k2). ty2
1494
1495 co1 = mkNthCo 0 co
1496 -- co1 :: k1 ~ k2
1497 -- Note that NthCo can extract an equality between the kinds
1498 -- of the types related by a coercion between forall-types.
1499 -- See the NthCo case in CoreLint.
1500
1501 co2 = mkInstCo co (mkCoherenceLeftCo (mkNomReflCo ty) co1)
1502 -- co2 :: ty1[ (ty|>co1)/a1 ] ~ ty2[ ty/a2 ]
1503 -- Arg of mkInstCo is always nominal, hence mkNomReflCo
1504
1505 pushCoValArg :: Coercion -> Maybe (Coercion, Coercion)
1506 -- We have (fun |> co) arg
1507 -- Push the coercion through to return
1508 -- (fun (arg |> co_arg)) |> co_res
1509 -- 'co' is always Representational
1510 pushCoValArg co
1511 | tyL `eqType` tyR
1512 = Just (mkRepReflCo arg, mkRepReflCo res)
1513
1514 | isFunTy tyL
1515 , [co1, co2] <- decomposeCo 2 co
1516 -- If co :: (tyL1 -> tyL2) ~ (tyR1 -> tyR2)
1517 -- then co1 :: tyL1 ~ tyR1
1518 -- co2 :: tyL2 ~ tyR2
1519 = ASSERT2( isFunTy tyR, ppr co $$ ppr arg )
1520 Just (mkSymCo co1, co2)
1521
1522 | otherwise
1523 = Nothing
1524 where
1525 (arg, res) = splitFunTy tyR
1526 Pair tyL tyR = coercionKind co
1527
1528 pushCoercionIntoLambda
1529 :: InScopeSet -> Var -> CoreExpr -> Coercion -> Maybe (Var, CoreExpr)
1530 -- This implements the Push rule from the paper on coercions
1531 -- (\x. e) |> co
1532 -- ===>
1533 -- (\x'. e |> co')
1534 pushCoercionIntoLambda in_scope x e co
1535 | ASSERT(not (isTyVar x) && not (isCoVar x)) True
1536 , Pair s1s2 t1t2 <- coercionKind co
1537 , Just (_s1,_s2) <- splitFunTy_maybe s1s2
1538 , Just (t1,_t2) <- splitFunTy_maybe t1t2
1539 = let [co1, co2] = decomposeCo 2 co
1540 -- Should we optimize the coercions here?
1541 -- Otherwise they might not match too well
1542 x' = x `setIdType` t1
1543 in_scope' = in_scope `extendInScopeSet` x'
1544 subst = extendIdSubst (mkEmptySubst in_scope')
1545 x
1546 (mkCast (Var x') co1)
1547 in Just (x', subst_expr (text "pushCoercionIntoLambda") subst e `mkCast` co2)
1548 | otherwise
1549 = pprTrace "exprIsLambda_maybe: Unexpected lambda in case" (ppr (Lam x e))
1550 Nothing
1551
1552 pushCoDataCon :: DataCon -> [CoreExpr] -> Coercion
1553 -> Maybe (DataCon
1554 , [Type] -- Universal type args
1555 , [CoreExpr]) -- All other args incl existentials
1556 -- Implement the KPush reduction rule as described in "Down with kinds"
1557 -- The transformation applies iff we have
1558 -- (C e1 ... en) `cast` co
1559 -- where co :: (T t1 .. tn) ~ to_ty
1560 -- The left-hand one must be a T, because exprIsConApp returned True
1561 -- but the right-hand one might not be. (Though it usually will.)
1562 pushCoDataCon dc dc_args co
1563 | isReflCo co || from_ty `eqType` to_ty -- try cheap test first
1564 , let (univ_ty_args, rest_args) = splitAtList (dataConUnivTyVars dc) dc_args
1565 = Just (dc, map exprToType univ_ty_args, rest_args)
1566
1567 | Just (to_tc, to_tc_arg_tys) <- splitTyConApp_maybe to_ty
1568 , to_tc == dataConTyCon dc
1569 -- These two tests can fail; we might see
1570 -- (C x y) `cast` (g :: T a ~ S [a]),
1571 -- where S is a type function. In fact, exprIsConApp
1572 -- will probably not be called in such circumstances,
1573 -- but there't nothing wrong with it
1574
1575 = let
1576 tc_arity = tyConArity to_tc
1577 dc_univ_tyvars = dataConUnivTyVars dc
1578 dc_ex_tyvars = dataConExTyVars dc
1579 arg_tys = dataConRepArgTys dc
1580
1581 non_univ_args = dropList dc_univ_tyvars dc_args
1582 (ex_args, val_args) = splitAtList dc_ex_tyvars non_univ_args
1583
1584 -- Make the "Psi" from the paper
1585 omegas = decomposeCo tc_arity co
1586 (psi_subst, to_ex_arg_tys)
1587 = liftCoSubstWithEx Representational
1588 dc_univ_tyvars
1589 omegas
1590 dc_ex_tyvars
1591 (map exprToType ex_args)
1592
1593 -- Cast the value arguments (which include dictionaries)
1594 new_val_args = zipWith cast_arg arg_tys val_args
1595 cast_arg arg_ty arg = mkCast arg (psi_subst arg_ty)
1596
1597 to_ex_args = map Type to_ex_arg_tys
1598
1599 dump_doc = vcat [ppr dc, ppr dc_univ_tyvars, ppr dc_ex_tyvars,
1600 ppr arg_tys, ppr dc_args,
1601 ppr ex_args, ppr val_args, ppr co, ppr from_ty, ppr to_ty, ppr to_tc ]
1602 in
1603 ASSERT2( eqType from_ty (mkTyConApp to_tc (map exprToType $ takeList dc_univ_tyvars dc_args)), dump_doc )
1604 ASSERT2( equalLength val_args arg_tys, dump_doc )
1605 Just (dc, to_tc_arg_tys, to_ex_args ++ new_val_args)
1606
1607 | otherwise
1608 = Nothing
1609
1610 where
1611 Pair from_ty to_ty = coercionKind co