Typos in error messages and in comments
[ghc.git] / utils / genprimopcode / Parser.y
1 {
2 {-# LANGUAGE BangPatterns #-} -- required for versions of Happy before 1.18.6
3 {-# OPTIONS -w -Wwarn #-}
4 -- The above warning suppression flag is a temporary kludge.
5 -- While working on this module you are encouraged to remove it and fix
6 -- any warnings in the module. See
7 --     http://ghc.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
8 -- for details
9
10 module Parser (parse) where
11
12 import Lexer (lex_tok)
13 import ParserM (Token(..), ParserM, run_parser, get_pos, show_pos,
14                 happyError)
15 import Syntax
16 }
17
18 %name      parsex
19 %expect    0
20 %tokentype { Token }
21 %monad     { ParserM }
22 %lexer     { lex_tok } { TEOF }
23
24 %token
25     '->'            { TArrow }
26     '=>'            { TDArrow }
27     '='             { TEquals }
28     ','             { TComma }
29     '('             { TOpenParen }
30     ')'             { TCloseParen }
31     '(#'            { TOpenParenHash }
32     '#)'            { THashCloseParen }
33     '{'             { TOpenBrace }
34     '}'             { TCloseBrace }
35     '['             { TOpenBracket }
36     ']'             { TCloseBracket }
37     '<'             { TOpenAngle }
38     '>'             { TCloseAngle }
39     section         { TSection }
40     primop          { TPrimop }
41     pseudoop        { TPseudoop }
42     primtype        { TPrimtype }
43     with            { TWith }
44     defaults        { TDefaults }
45     true            { TTrue }
46     false           { TFalse }
47     dyadic          { TDyadic }
48     monadic         { TMonadic }
49     compare         { TCompare }
50     genprimop       { TGenPrimOp }
51     fixity          { TFixity }
52     infix           { TInfixN }
53     infixl          { TInfixL }
54     infixr          { TInfixR }
55     nothing         { TNothing }
56     vector          { TVector }
57     SCALAR          { TSCALAR }
58     VECTOR          { TVECTOR }
59     VECTUPLE        { TVECTUPLE }
60     thats_all_folks { TThatsAllFolks }
61     lowerName       { TLowerName $$ }
62     upperName       { TUpperName $$ }
63     string          { TString $$ }
64     integer         { TInteger $$ }
65     noBraces        { TNoBraces $$ }
66
67 %%
68
69 info :: { Info }
70 info : pDefaults pEntries thats_all_folks { Info $1 $2 }
71
72 pDefaults :: { [Option] }
73 pDefaults : defaults pOptions { $2 }
74
75 pOptions :: { [Option] }
76 pOptions : pOption pOptions { $1 : $2 }
77          | {- empty -}      { [] }
78
79 pOption :: { Option }
80 pOption : lowerName '=' false               { OptionFalse  $1 }
81         | lowerName '=' true                { OptionTrue   $1 }
82         | lowerName '=' pStuffBetweenBraces { OptionString $1 $3 }
83         | lowerName '=' integer             { OptionInteger $1 $3 }
84         | vector    '=' pVectorTemplate     { OptionVector $3 }
85         | fixity    '=' pInfix              { OptionFixity $3 }
86
87 pInfix :: { Maybe Fixity }
88 pInfix : infix  integer { Just $ Fixity $2 InfixN }
89        | infixl integer { Just $ Fixity $2 InfixL }
90        | infixr integer { Just $ Fixity $2 InfixR }
91        | nothing        { Nothing }
92
93
94 pEntries :: { [Entry] }
95 pEntries : pEntry pEntries { $1 : $2 }
96          | {- empty -}   { [] }
97
98 pEntry :: { Entry }
99 pEntry : pPrimOpSpec   { $1 }
100        | pPrimTypeSpec { $1 }
101        | pPseudoOpSpec { $1 }
102        | pSection      { $1 }
103
104 pPrimOpSpec :: { Entry }
105 pPrimOpSpec : primop upperName string pCategory pType
106               pDesc pWithOptions
107               { PrimOpSpec {
108                     cons = $2,
109                     name = $3,
110                     cat = $4,
111                     ty = $5,
112                     desc = $6,
113                     opts = $7
114                 }
115               }
116
117 pPrimTypeSpec :: { Entry }
118 pPrimTypeSpec : primtype pType pDesc pWithOptions
119                 { PrimTypeSpec { ty = $2, desc = $3, opts = $4 } }
120
121 pPseudoOpSpec :: { Entry }
122 pPseudoOpSpec : pseudoop string pType pDesc pWithOptions
123                 { PseudoOpSpec { name = $2, ty = $3, desc = $4, opts = $5 } }
124
125 pSection :: { Entry }
126 pSection : section string pDesc { Section { title = $2, desc = $3 } }
127
128 pWithOptions :: { [Option] }
129 pWithOptions : with pOptions { $2 }
130              | {- empty -}   { [] }
131
132 pCategory :: { Category }
133 pCategory : dyadic { Dyadic }
134           | monadic { Monadic }
135           | compare { Compare }
136           | genprimop { GenPrimOp }
137
138 pDesc :: { String }
139 pDesc : pStuffBetweenBraces { $1 }
140       | {- empty -}         { "" }
141
142 pStuffBetweenBraces :: { String }
143 pStuffBetweenBraces : '{' pInsides '}' { $2 }
144
145 pInsides :: { String }
146 pInsides : pInside pInsides { $1 ++ $2 }
147          | {- empty -}      { "" }
148
149 pInside :: { String }
150 pInside : '{' pInsides '}' { "{" ++ $2 ++ "}" }
151         | noBraces         { $1 }
152
153 pVectorTemplate :: { [(String, String, Int)] }
154 pVectorTemplate : '[' pVectors ']' { $2 }
155
156 pVectors :: { [(String, String, Int)] }
157 pVectors : pVector ',' pVectors { [$1] ++ $3 }
158          | pVector              { [$1] }
159          | {- empty -}          { [] }
160
161 pVector :: { (String, String, Int) }
162 pVector : '<' upperName ',' upperName ',' integer '>' { ($2, $4, $6) }
163  
164 pType :: { Ty }
165 pType : paT '->' pType { TyF $1 $3 }
166       | paT '=>' pType { TyC $1 $3 }
167       | paT            { $1 }
168
169 -- Atomic types
170 paT :: { Ty }
171 paT : pTycon ppTs     { TyApp $1 $2 }
172     | pUnboxedTupleTy { $1 }
173     | '(' pType ')'   { $2 }
174     | lowerName       { TyVar $1 }
175
176 pUnboxedTupleTy :: { Ty }
177 pUnboxedTupleTy : '(#' pCommaTypes '#)' { TyUTup $2 }
178
179 pCommaTypes :: { [Ty] }
180 pCommaTypes : pType ',' pCommaTypes { $1 : $3 }
181             | pType                 { [$1] }
182
183 ppTs :: { [Ty] }
184 ppTs : ppT ppTs    { $1 : $2 }
185      | {- empty -} { [] }
186
187 -- Primitive types
188 ppT :: { Ty }
189 ppT : lowerName { TyVar $1 }
190     | pTycon    { TyApp $1 [] }
191
192 pTycon :: { TyCon }
193 pTycon : upperName { TyCon $1 }
194        | '(' ')'   { TyCon "()" }
195        | SCALAR    { SCALAR }
196        | VECTOR    { VECTOR }
197        | VECTUPLE  { VECTUPLE }
198
199 {
200 parse :: String -> Either String Info
201 parse = run_parser parsex
202 }
203