Deriving Functor-like classes should unify kind variables
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.0.0], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands,
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42 FP_PROG_SORT
43
44 dnl ----------------------------------------------------------
45 FP_SETUP_PROJECT_VERSION
46
47 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
48 AC_SUBST([release], [1])
49
50 # First off, a distrib sanity check..
51 AC_CONFIG_SRCDIR([mk/config.mk.in])
52
53 dnl * We require autoconf version 2.60
54 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
55 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
56 dnl Using autoconf 2.59 started to give nonsense like this
57 dnl  #define SIZEOF_CHAR 0
58 dnl recently.
59 AC_PREREQ([2.60])
60
61 # -------------------------------------------------------------------------
62 # Prepare to generate the following header files
63 #
64 #
65 AC_CONFIG_HEADER(mk/config.h)
66
67 # No, semi-sadly, we don't do `--srcdir'...
68 if test x"$srcdir" != 'x.' ; then
69     echo "This configuration does not support the \`--srcdir' option.."
70     exit 1
71 fi
72
73 dnl --------------------------------------------------------------
74 dnl * Project specific configuration options
75 dnl --------------------------------------------------------------
76 dnl What follows is a bunch of options that can either be configured
77 dnl through command line options to the configure script or by
78 dnl supplying defns in the build tree's mk/build.mk. Having the option to
79 dnl use either is considered a Feature.
80
81 dnl ** What command to use to compile compiler sources ?
82 dnl --------------------------------------------------------------
83
84 AC_ARG_WITH([ghc],
85 [AC_HELP_STRING([--with-ghc=ARG],
86   [Use ARG as the path to GHC  [default=autodetect]])],
87   [WithGhc="$withval"],
88   [if test "$GHC" = ""; then
89     AC_PATH_PROG([GHC], [ghc])
90   fi
91   WithGhc="$GHC"])
92
93 dnl ** Tell the make system which OS we are using
94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
95 AC_SUBST(OSTYPE)
96
97 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
98 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
99                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
100         EnableBootstrapWithDevelSnaphost=YES,
101         EnableBootstrapWithDevelSnaphost=NO
102 )
103
104 AC_ARG_ENABLE(tarballs-autodownload,
105 [AC_HELP_STRING([--enable-tarballs-autodownload],
106                 [Automatically download Windows distribution binaries if needed.])],
107         TarballsAutodownload=YES,
108         TarballsAutodownload=NO
109 )
110 if test "$WithGhc" != ""; then
111   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
112
113   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
114      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
115   fi
116
117   AC_SUBST(GhcVersion)dnl
118   AC_SUBST(GhcMajVersion)dnl
119   AC_SUBST(GhcMinVersion)dnl
120   AC_SUBST(GhcPatchLevel)dnl
121   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
122   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
123
124   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
125   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
126   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
127   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
128   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
129 fi
130
131 dnl ** Must have GHC to build GHC
132 if test "$WithGhc" = ""
133 then
134     AC_MSG_ERROR([GHC is required.])
135 fi
136 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.8],
137     [AC_MSG_ERROR([GHC version 7.8 or later is required to compile GHC.])])
138
139 if test `expr $GhcMinVersion % 2` = "1"
140 then
141     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
142     then
143         AC_MSG_ERROR([
144      $WithGhc is a development snapshot of GHC, version $GhcVersion.
145      Bootstrapping using this version of GHC is not supported, and may not
146      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
147      or --with-ghc to specify a different GHC to use.])
148     fi
149 fi
150
151 GHC_PACKAGE_DB_FLAG=package-db
152 AC_SUBST(GHC_PACKAGE_DB_FLAG)
153
154 # GHC 7.7+ needs -fcmm-sink when compiling Parser.hs. See #8182
155 FP_COMPARE_VERSIONS([$GhcVersion],[-gt],[7.7],
156                     CMM_SINK_BOOTSTRAP_IS_NEEDED=YES,
157                     CMM_SINK_BOOTSTRAP_IS_NEEDED=NO)
158 AC_SUBST(CMM_SINK_BOOTSTRAP_IS_NEEDED)
159
160 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.9],
161                     SUPPORTS_COMPONENT_ID=NO,
162                     SUPPORTS_COMPONENT_ID=YES)
163 AC_SUBST(SUPPORTS_COMPONENT_ID)
164
165 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.11],
166                     SUPPORTS_THIS_UNIT_ID=NO,
167                     SUPPORTS_THIS_UNIT_ID=YES)
168 AC_SUBST(SUPPORTS_THIS_UNIT_ID)
169
170 # GHC is passed to Cabal, so we need a native path
171 if test "${WithGhc}" != ""
172 then
173     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
174
175     if test "$ghc_host_os" = "mingw32"
176     then
177         if test "${OSTYPE}" = "msys"
178         then
179             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
180         else
181             # Canonicalise to <drive>:/path/to/ghc
182             WithGhc=`cygpath -m "${WithGhc}"`
183         fi
184         echo "GHC path canonicalised to: ${WithGhc}"
185     fi
186 fi
187 AC_SUBST([WithGhc])
188
189 dnl ** Without optimization some INLINE trickery fails for GHCi
190 SRC_CC_OPTS="-O"
191
192 dnl--------------------------------------------------------------------
193 dnl * Choose host(/target/build) platform
194 dnl--------------------------------------------------------------------
195 dnl If we aren't explicitly told what values to use with configure flags,
196 dnl we ask the bootstrapping compiler what platform it is for
197
198 if test "${WithGhc}" != ""
199 then
200         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
201         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
202         if test "$bootstrap_host" != "$bootstrap_target"
203         then
204                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
205         fi
206 fi
207
208 # We have to run these unconditionally, but we may discard their
209 # results in the following code
210 AC_CANONICAL_BUILD
211 AC_CANONICAL_HOST
212 AC_CANONICAL_TARGET
213
214 FPTOOLS_SET_PLATFORM_VARS
215
216 # Verify that the installed (bootstrap) GHC is capable of generating
217 # code for the requested build platform.
218 if test "$BuildPlatform" != "$bootstrap_target"
219 then
220     echo "This GHC (${WithGhc}) does not generate code for the build platform"
221     echo "   GHC target platform    : $bootstrap_target"
222     echo "   Desired build platform : $BuildPlatform"
223     exit 1
224 fi
225
226 # Testing if we shall enable shared libs support on Solaris.
227 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
228
229 SOLARIS_BROKEN_SHLD=NO
230
231 case $host in
232      i386-*-solaris2)
233      # here we go with the test
234      MINOR=`uname -r|cut -d '.' -f 2-`
235      if test "$MINOR" -lt "11"; then
236          SOLARIS_BROKEN_SHLD=YES
237      fi
238      ;;
239 esac
240
241 AC_SUBST(SOLARIS_BROKEN_SHLD)
242
243 dnl ** Do an unregisterised build?
244 dnl --------------------------------------------------------------
245 case "$HostArch" in
246     i386|x86_64|powerpc|powerpc64|powerpc64le|arm)
247         UnregisterisedDefault=NO
248         ;;
249     *)
250         UnregisterisedDefault=YES
251         ;;
252 esac
253 AC_ARG_ENABLE(unregisterised,
254 [AC_HELP_STRING([--enable-unregisterised],
255 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
256 [ if test x"$enableval" = x"yes"; then
257         Unregisterised=YES
258   else
259         Unregisterised=NO
260   fi
261 ],
262 [Unregisterised="$UnregisterisedDefault"]
263 )
264 AC_SUBST(Unregisterised)
265
266 AC_ARG_WITH(hc,
267 [AC_HELP_STRING([--with-hc=ARG],
268         [Use ARG as the path to the compiler for compiling ordinary
269          Haskell code  (default= value of --with-ghc)])],
270 [WithHc="$withval"],
271 [WithHc=$WithGhc]
272 )
273 AC_SUBST(WithHc)
274
275 # This uses GHC, so put it after the "GHC is required" check above:
276 FP_INTREE_GHC_PWD
277 FP_FIND_ROOT
278
279 fail() {
280     echo >&2
281     echo "$1" >&2
282     exit 1
283 }
284
285
286 if test "$HostOS" = "mingw32"
287 then
288     # Find the mingw-w64 7z file to extract.
289     # NB. If you update the tarballs to a new version of gcc, don't
290     # forget to tweak the paths in driver/gcc/gcc.c.
291     if test "$HostArch" = "i386"
292     then
293         mingw_arch="i686"
294         tarball_dest_dir="mingw-w64/x86"
295         tarball_mingw_dir="mingw32"
296     else
297         mingw_arch="x86_64"
298         tarball_dest_dir="mingw-w64/x86_64"
299         tarball_mingw_dir="mingw64"
300     fi
301 fi
302
303 set_up_tarballs() {
304     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
305     local action
306     if test "$TarballsAutodownload" = "NO"
307     then
308         action="verify"
309     else
310         action="download"
311     fi
312     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
313     case $? in
314         0)
315            rm missing-win32-tarballs
316            ;;
317         2)
318            echo
319            echo "Error:"
320            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
321            echo
322            echo "  * run configure with the --enable-tarballs-autodownload option"
323            echo
324            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
325            echo
326            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
327            echo "    them in the ghc-tarballs directory."
328            echo
329            exit 1
330            ;;
331         *)
332            echo
333            echo "Error fetching msys2 tarballs; see errors above."
334            exit 1
335            ;;
336     esac
337
338     # Extract all the tarballs in one go
339     if ! test -d inplace/mingw
340     then
341         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
342         rm -rf inplace/mingw
343         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
344         ( cd inplace &&
345         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
346         rm ".MTREE" &&
347         rm ".PKGINFO" &&
348         cd .. ) || fail "Error: Could not extract Windows toolchains."
349
350         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
351         touch inplace/mingw
352
353         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
354         # make a wrapper around it to give it the proper paths
355         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
356         PATH=`pwd`/inplace/mingw/bin:$PATH
357         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
358
359         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
360     fi
361 }
362
363 if test "$HostOS" = "mingw32"
364 then
365     test -d inplace || mkdir inplace
366
367     # NB. Download and extract the MingW-w64 distribution if required
368     set_up_tarballs
369
370     mingwbin="$hardtop/inplace/mingw/bin/"
371     CC="${mingwbin}gcc.exe"
372     LD="${mingwbin}ld.exe"
373     NM="${mingwbin}nm.exe"
374     RANLIB="${mingwbin}ranlib.exe"
375     OBJDUMP="${mingwbin}objdump.exe"
376     fp_prog_ar="${mingwbin}ar.exe"
377
378     # NB. Download the perl binaries if required
379     if ! test -d inplace/perl ||
380          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
381     then
382         AC_MSG_NOTICE([Making in-tree perl tree])
383         rm -rf inplace/perl
384         mkdir inplace/perl
385         (
386             cd inplace/perl &&
387             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
388         )
389         AC_MSG_NOTICE([In-tree perl tree created])
390     fi
391 fi
392
393 FP_ICONV
394 FP_GMP
395 FP_CURSES
396
397 XCODE_VERSION()
398
399 SplitObjsBroken=NO
400 if test "$TargetOS_CPP" = "darwin"
401 then
402     # Split objects is broken (#4013) with XCode < 3.2
403     if test "$XCodeVersion1" -lt 3
404     then
405         SplitObjsBroken=YES
406     else
407         if test "$XCodeVersion1" -eq 3
408         then
409             if test "$XCodeVersion2" -lt 2
410             then
411                 SplitObjsBroken=YES
412             fi
413         fi
414     fi
415 fi
416 AC_SUBST([SplitObjsBroken])
417
418 dnl ** Building a cross compiler?
419 dnl --------------------------------------------------------------
420 CrossCompiling=NO
421 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
422 if test "$target" != "$host" ; then
423     CrossCompiling=YES
424     cross_compiling=yes   # This tells configure that it can accept just 'target',
425                           # otherwise you get
426                           #   configure: error: cannot run C compiled programs.
427                           #   If you meant to cross compile, use `--host'.
428 fi
429 if test "$build" != "$host" ; then
430    AC_MSG_ERROR([
431 You've selected:
432
433   BUILD:  $build   (the architecture we're building on)
434   HOST:   $host    (the architecture the compiler we're building will execute on)
435   TARGET: $target  (the architecture the compiler we're building will produce code for)
436
437 BUILD must equal HOST; that is, we do not support building GHC itself
438 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
439 1 will be a cross-compiler, and stage 2 will be the cross-compiled
440 GHC.
441 ])
442 fi
443 if test "$CrossCompiling" = "YES"
444 then
445   CrossCompilePrefix="${target}-"
446 else
447   CrossCompilePrefix=""
448 fi
449 TargetPlatformFull="${target}"
450 AC_SUBST(CrossCompiling)
451 AC_SUBST(CrossCompilePrefix)
452 AC_SUBST(TargetPlatformFull)
453
454 dnl ** Which gcc to use?
455 dnl --------------------------------------------------------------
456 FIND_GCC([WhatGccIsCalled], [gcc], [gcc])
457 CC="$WhatGccIsCalled"
458 export CC
459
460 # If --with-gcc was used, and we're not cross-compiling, then it also
461 # applies to the stage0 compiler.
462 MAYBE_OVERRIDE_STAGE0([gcc],[CC_STAGE0])
463 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
464
465 dnl make extensions visible to allow feature-tests to detect them lateron
466 AC_USE_SYSTEM_EXTENSIONS
467
468 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
469 AC_PROG_CPP
470
471 # --with-hs-cpp/--with-hs-cpp-flags
472 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
473 AC_SUBST([HaskellCPPCmd])
474 AC_SUBST([HaskellCPPArgs])
475
476 dnl ** Which ld to use?
477 dnl --------------------------------------------------------------
478 FIND_LD([LdCmd])
479 AC_SUBST([LdCmd])
480
481 dnl ** Which nm to use?
482 dnl --------------------------------------------------------------
483 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
484 NmCmd="$NM"
485 AC_SUBST([NmCmd])
486
487 dnl ** Which objdump to use?
488 dnl --------------------------------------------------------------
489 FP_ARG_WITH_PATH_GNU_PROG_OPTIONAL([OBJDUMP], [objdump], [objdump])
490 ObjdumpCmd="$OBJDUMP"
491 AC_SUBST([ObjdumpCmd])
492
493 dnl ** Which ar to use?
494 dnl --------------------------------------------------------------
495 FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
496 ArCmd="$AR"
497 fp_prog_ar="$AR"
498 AC_SUBST([ArCmd])
499
500 dnl ** Which ranlib to use?
501 dnl --------------------------------------------------------------
502 FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
503 RanlibCmd="$RANLIB"
504 RANLIB="$RanlibCmd"
505
506
507 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
508 case $HostOS_CPP in
509 cygwin32|mingw32)
510     dnl ** Which objdump to use?
511     dnl --------------------------------------------------------------
512     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
513     ObjdumpCmd="$OBJDUMP"
514     AC_SUBST([ObjdumpCmd])
515     ;;
516 esac
517
518 # Here is where we re-target which specific version of the LLVM
519 # tools we are looking for. In the past, GHC supported a number of
520 # versions of LLVM simultaneously, but that stopped working around
521 # 3.5/3.6 release of LLVM.
522 LlvmVersion=3.7
523 AC_SUBST([LlvmVersion])
524 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
525 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
526
527 dnl ** Which LLVM llc to use?
528 dnl --------------------------------------------------------------
529 FIND_LLVM_PROG([LLC], [llc], [llc], [$LlvmVersion])
530 LlcCmd="$LLC"
531 AC_SUBST([LlcCmd])
532
533 dnl ** Which LLVM opt to use?
534 dnl --------------------------------------------------------------
535 FIND_LLVM_PROG([OPT], [opt], [opt], [$LlvmVersion])
536 OptCmd="$OPT"
537 AC_SUBST([OptCmd])
538
539 dnl --------------------------------------------------------------
540 dnl End of configure script option section
541 dnl --------------------------------------------------------------
542
543
544 dnl --------------------------------------------------------------
545 dnl * General configuration checks
546 dnl --------------------------------------------------------------
547
548 dnl ** Bug 9439: Some GHC 7.8 releases had broken LLVM code generator.
549 dnl Unfortunately we don't know whether the user is going to request a
550 dnl build with the LLVM backend as this is only given in build.mk.
551 dnl
552 dnl Instead, we try to do as much work as possible here, checking
553 dnl whether -fllvm is the stage 0 compiler's default. If so we
554 dnl fail. If not, we check whether -fllvm is affected explicitly and
555 dnl if so set a flag. The build system will later check this flag
556 dnl after the desired build flags are known.
557
558 dnl This problem is further complicated by the fact that the llvm
559 dnl version used by the bootstrap compiler may be different from the
560 dnl version we arre trying to compile GHC against. Therefore, we need
561 dnl to find the boostrap compiler's `settings` file then check to see
562 dnl if the `opt` and `llc` command strings are non-empty and if these
563 dnl programs exist. Only if they exist to we test for bug #9439.
564
565 FIND_GHC_BOOTSTRAP_PROG([BootstrapLlcCmd], [${WithGhc}], "LLVM llc command")
566 FIND_GHC_BOOTSTRAP_PROG([BootstrapOptCmd], [${WithGhc}], "LLVM opt command")
567
568 if test -n "$BootstrapLlcCmd" && test -n "$BootstrapOptCmd"
569 then
570     AC_MSG_CHECKING(whether bootstrap compiler is affected by bug 9439)
571     echo "main = putStrLn \"%function\"" > conftestghc.hs
572
573     # Check whether LLVM backend is default for this platform
574     "${WithGhc}" -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" conftestghc.hs 2>&1 >/dev/null
575     res=`./conftestghc`
576     if test "x$res" = "x%object"
577     then
578         AC_MSG_RESULT(yes)
579         echo "Buggy bootstrap compiler"
580         echo ""
581         echo "The stage 0 compiler $WithGhc is affected by GHC Bug \#9439"
582         echo "and therefore will miscompile the LLVM backend if -fllvm is"
583         echo "used."
584         echo
585         echo "Please use another bootstrap compiler"
586         exit 1
587     fi
588
589     # -fllvm is not the default, but set a flag so the Makefile can check
590     # -for it in the build flags later on
591     "${WithGhc}" -fforce-recomp -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" -fllvm conftestghc.hs 2>&1 >/dev/null
592     if test $? = 0
593     then
594         res=`./conftestghc`
595         if test "x$res" = "x%object"
596         then
597             AC_MSG_RESULT(yes)
598             GHC_LLVM_AFFECTED_BY_9439=1
599         elif test "x$res" = "x%function"
600         then
601             AC_MSG_RESULT(no)
602             GHC_LLVM_AFFECTED_BY_9439=0
603         else
604             AC_MSG_WARN(unexpected output $res)
605         fi
606     else
607         AC_MSG_RESULT(failed to compile, assuming no)
608     fi
609 fi
610 AC_SUBST([GHC_LLVM_AFFECTED_BY_9439])
611
612 dnl ** Can the unix package be built?
613 dnl --------------------------------------------------------------
614
615 if test "$TargetOS" = "mingw32"
616 then
617     GhcLibsWithUnix=NO
618 else
619     GhcLibsWithUnix=YES
620 fi
621 AC_SUBST([GhcLibsWithUnix])
622
623 dnl ** does #! work?
624 AC_SYS_INTERPRETER()
625
626 dnl ** look for `perl'
627 case $HostOS_CPP in
628 cygwin32|mingw32)
629     PerlCmd=$hardtop/inplace/perl/perl
630     ;;
631 *)
632     AC_PATH_PROG(PerlCmd,perl)
633     if test -z "$PerlCmd"
634     then
635         echo "You must install perl before you can continue"
636         echo "Perhaps it is already installed, but not in your PATH?"
637         exit 1
638     else
639         FPTOOLS_CHECK_PERL_VERSION
640     fi
641     ;;
642 esac
643
644 dnl ** look for GCC and find out which version
645 dnl     Figure out which C compiler to use.  Gcc is preferred.
646 dnl     If gcc, make sure it's at least 3.0
647 dnl
648 FP_GCC_VERSION
649
650 dnl ** look to see if we have a C compiler using an llvm back end.
651 dnl
652 FP_CC_LLVM_BACKEND
653
654 FP_PROG_LD_IS_GNU
655 FP_PROG_LD_BUILD_ID
656 FP_PROG_LD_NO_COMPACT_UNWIND
657 FP_PROG_LD_FILELIST
658
659
660 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
661 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
662 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
663 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
664 # Stage 3 won't be supported by cross-compilation
665
666 FP_GCC_EXTRA_FLAGS
667
668 AC_SUBST(CONF_CC_OPTS_STAGE0)
669 AC_SUBST(CONF_CC_OPTS_STAGE1)
670 AC_SUBST(CONF_CC_OPTS_STAGE2)
671 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
672 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
673 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
674 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
675 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
676 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
677 AC_SUBST(CONF_CPP_OPTS_STAGE0)
678 AC_SUBST(CONF_CPP_OPTS_STAGE1)
679 AC_SUBST(CONF_CPP_OPTS_STAGE2)
680
681 dnl ** Set up the variables for the platform in the settings file.
682 dnl May need to use gcc to find platform details.
683 dnl --------------------------------------------------------------
684 FPTOOLS_SET_HASKELL_PLATFORM_VARS
685
686 dnl ** figure out how to do context diffs
687 FP_PROG_CONTEXT_DIFF
688
689 dnl Let's make sure install-sh is executable here.  If we got it from
690 dnl a darcs repo, it might not be (see bug #978).
691 chmod +x install-sh
692 dnl ** figure out how to do a BSD-ish install
693 AC_PROG_INSTALL
694
695 dnl ** how to invoke `ar' and `ranlib'
696 FP_PROG_AR_SUPPORTS_ATFILE
697 FP_PROG_AR_NEEDS_RANLIB
698
699 dnl ** Check to see whether ln -s works
700 AC_PROG_LN_S
701
702 FP_SETTINGS
703
704 dnl ** Find the path to sed
705 AC_PATH_PROGS(SedCmd,gsed sed,sed)
706
707
708 dnl ** check for time command
709 AC_PATH_PROG(TimeCmd,time)
710
711 dnl ** check for tar
712 dnl   if GNU tar is named gtar, look for it first.
713 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
714
715 dnl ** check for patch
716 dnl if GNU patch is named gpatch, look for it first
717 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
718
719 dnl ** check for dtrace (currently only implemented for Mac OS X)
720 HaveDtrace=NO
721 AC_PATH_PROG(DtraceCmd,dtrace)
722 if test -n "$DtraceCmd"; then
723   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
724     HaveDtrace=YES
725   fi
726 fi
727 AC_SUBST(HaveDtrace)
728
729 AC_PATH_PROG(HSCOLOUR,HsColour)
730 # HsColour is passed to Cabal, so we need a native path
731 if test "$HostOS"      = "mingw32" && \
732    test "${OSTYPE}"   != "msys"    && \
733    test "${HSCOLOUR}" != ""
734 then
735     # Canonicalise to <drive>:/path/to/gcc
736     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
737 fi
738
739 dnl ** check for Sphinx toolchain
740 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
741 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
742 changequote(, )dnl
743 [if test -n "$SPHINXBUILD"; then
744   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
745 fi;
746 changequote([, ])dnl
747 ])
748 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
749     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
750
751 dnl ** check for xelatex
752 AC_PATH_PROG(XELATEX,xelatex)
753
754 dnl ** check for ghc-pkg command
755 FP_PROG_GHC_PKG
756
757 dnl ** check for installed happy binary + version
758 FPTOOLS_HAPPY
759
760 dnl ** check for installed alex binary + version
761 FPTOOLS_ALEX
762
763 dnl --------------------------------------------------
764 dnl ### program checking section ends here ###
765 dnl --------------------------------------------------
766
767 dnl --------------------------------------------------
768 dnl * Platform header file and syscall feature tests
769 dnl ### checking the state of the local header files and syscalls ###
770
771 dnl ** check for full ANSI header (.h) files
772 AC_HEADER_STDC
773
774 dnl ** Enable large file support.  NB. do this before testing the type of
775 dnl    off_t, because it will affect the result of that test.
776 AC_SYS_LARGEFILE
777
778 dnl ** check for specific header (.h) files that we are interested in
779 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
780
781 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
782 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
783 [[#if HAVE_SYS_PARAM_H
784 # include <sys/param.h>
785 #endif
786 ]])
787
788 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
789 AC_HEADER_TIME
790
791 dnl ** do we have long longs?
792 AC_CHECK_TYPES([long long])
793
794 dnl ** what are the sizes of various types
795 AC_CHECK_SIZEOF(char,               1)
796 AC_CHECK_SIZEOF(double,             8)
797 AC_CHECK_SIZEOF(float,              4)
798 AC_CHECK_SIZEOF(int,                4)
799 AC_CHECK_SIZEOF(long,               4)
800 if test "$ac_cv_type_long_long" = yes; then
801 AC_CHECK_SIZEOF(long long,          8)
802 fi
803 AC_CHECK_SIZEOF(short,              2)
804 AC_CHECK_SIZEOF(unsigned char,      1)
805 AC_CHECK_SIZEOF(unsigned int,       4)
806 AC_CHECK_SIZEOF(unsigned long,      4)
807 if test "$ac_cv_type_long_long" = yes; then
808 AC_CHECK_SIZEOF(unsigned long long, 8)
809 fi
810 AC_CHECK_SIZEOF(unsigned short,     2)
811 AC_CHECK_SIZEOF(void *,             4)
812
813 dnl for use in settings.in
814 WordSize=$ac_cv_sizeof_void_p
815 AC_SUBST(WordSize)
816
817 dnl ** what are alignment constraints on various types
818 FP_CHECK_ALIGNMENT(char)
819 FP_CHECK_ALIGNMENT(double)
820 FP_CHECK_ALIGNMENT(float)
821 FP_CHECK_ALIGNMENT(int)
822 FP_CHECK_ALIGNMENT(long)
823 if test "$ac_cv_type_long_long" = yes; then
824 FP_CHECK_ALIGNMENT(long long)
825 fi
826 FP_CHECK_ALIGNMENT(short)
827 FP_CHECK_ALIGNMENT(unsigned char)
828 FP_CHECK_ALIGNMENT(unsigned int)
829 FP_CHECK_ALIGNMENT(unsigned long)
830 if test "$ac_cv_type_long_long" = yes; then
831 FP_CHECK_ALIGNMENT(unsigned long long)
832 fi
833 FP_CHECK_ALIGNMENT(unsigned short)
834 FP_CHECK_ALIGNMENT(void *)
835
836 FP_CHECK_FUNC([WinExec],
837   [@%:@include <windows.h>], [WinExec("",0)])
838
839 FP_CHECK_FUNC([GetModuleFileName],
840   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
841
842 dnl ** check for more functions
843 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
844 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
845
846 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
847 dnl ** _POSIX_C_SOURCE is defined
848 AC_CHECK_DECLS([ctime_r], , ,
849 [#define _POSIX_SOURCE 1
850 #define _POSIX_C_SOURCE 199506L
851 #include <time.h>])
852
853 dnl ** check for mingwex library
854 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
855 AC_SUBST(HaveLibMingwEx)
856
857 if test $HaveLibMingwEx = YES ; then
858   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
859 fi
860
861 dnl ** check for math library
862 dnl    Keep that check as early as possible.
863 dnl    as we need to know whether we need libm
864 dnl    for math functions or not
865 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
866 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
867 if test $HaveLibM = YES
868 then
869   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
870 fi
871
872 FP_BFD_SUPPORT
873
874 dnl ################################################################
875 dnl Check for libraries
876 dnl ################################################################
877
878 # system libffi
879
880 AC_ARG_WITH([system-libffi],
881 [AC_HELP_STRING([--with-system-libffi],
882   [Use system provided libffi for RTS [default=no]])
883 ])
884
885 AS_IF([test "x$with_system_libffi" = "xyes"],
886   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
887 )
888
889
890 AC_SUBST(UseSystemLibFFI)
891
892 AC_ARG_WITH([ffi-includes],
893 [AC_HELP_STRING([--with-ffi-includes=ARG],
894   [Find includes for libffi in ARG [default=system default]])
895 ],
896 [
897  if test "x$UseSystemLibFFI" != "xYES"; then
898     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
899  else
900     FFIIncludeDir="$withval"
901     LIBFFI_CFLAGS="-I$withval"
902  fi
903 ])
904
905 AC_SUBST(FFIIncludeDir)
906
907 AC_ARG_WITH([ffi-libraries],
908 [AC_HELP_STRING([--with-ffi-libraries=ARG],
909   [Find libffi in ARG [default=system default]])
910 ],
911 [
912  if test "x$UseSystemLibFFI" != "xYES"; then
913     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
914  else
915     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
916  fi
917 ])
918
919 AC_SUBST(FFILibDir)
920
921 AS_IF([test "$UseSystemLibFFI" = "YES"], [
922  CFLAGS2="$CFLAGS"
923  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
924  LDFLAGS2="$LDFLAGS"
925  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
926  if test "$HostOS" = "openbsd";
927  then
928    # OpenBSD's libffi is not directly linked to the libpthread but
929    # still requires pthread functionality. This means that any client
930    # binary which links with libffi also needs to link with
931    # libpthread. If it does not, then linking fails with unresolved
932    # symbols.
933    LDFLAGS="$LDFLAGS -lpthread"
934  fi
935  AC_CHECK_LIB(ffi, ffi_call,
936   [AC_CHECK_HEADERS([ffi.h], [break], [])
937    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
938   [AC_MSG_ERROR([Cannot find system libffi])])
939  CFLAGS="$CFLAGS2"
940  LDFLAGS="$LDFLAGS2"
941 ])
942
943 dnl ** check whether we need -ldl to get dlopen()
944 AC_CHECK_LIB(dl, dlopen)
945
946 dnl --------------------------------------------------
947 dnl * Miscellaneous feature tests
948 dnl --------------------------------------------------
949
950 dnl ** can we get alloca?
951 AC_FUNC_ALLOCA
952
953 dnl ** working vfork?
954 AC_FUNC_FORK
955
956 dnl ** determine whether or not const works
957 AC_C_CONST
958
959 dnl ** are we big endian?
960 AC_C_BIGENDIAN
961 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
962
963 dnl ** check for leading underscores in symbol names
964 FP_LEADING_UNDERSCORE
965
966 FP_VISIBILITY_HIDDEN
967
968 dnl ** check for librt
969 AC_CHECK_LIB(rt, clock_gettime)
970 AC_CHECK_FUNCS(clock_gettime timer_settime)
971 FP_CHECK_TIMER_CREATE
972
973 dnl ** check for Apple's "interesting" long double compatibility scheme
974 AC_MSG_CHECKING(for printf\$LDBLStub)
975 AC_TRY_LINK_FUNC(printf\$LDBLStub,
976     [
977         AC_MSG_RESULT(yes)
978         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
979             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
980     ],
981     [
982         AC_MSG_RESULT(no)
983         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
984             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
985     ])
986
987 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
988 dnl    a different single-argument version.
989 AC_CHECK_LIB(pthread, pthread_setname_np)
990 AC_MSG_CHECKING(for pthread_setname_np)
991 AC_TRY_LINK(
992 [
993 #define _GNU_SOURCE
994 #include <pthread.h>
995 ],
996 [pthread_setname_np(pthread_self(), "name");],
997     AC_MSG_RESULT(yes)
998     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
999       [Define to 1 if you have the glibc version of pthread_setname_np]),
1000     AC_MSG_RESULT(no)
1001 )
1002
1003 dnl ** check for eventfd which is needed by the I/O manager
1004 AC_CHECK_HEADERS([sys/eventfd.h])
1005 AC_CHECK_FUNCS([eventfd])
1006
1007 dnl ** Check for __thread support in the compiler
1008 AC_MSG_CHECKING(for __thread support)
1009 AC_COMPILE_IFELSE(
1010   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1011   [
1012    AC_MSG_RESULT(yes)
1013    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1014   ],
1015   [
1016    AC_MSG_RESULT(no)
1017    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1018   ])
1019
1020 dnl large address space support (see includes/rts/storage/MBlock.h)
1021 dnl
1022 dnl Darwin has vm_allocate/vm_protect
1023 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1024 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1025 dnl (They also have MADV_DONTNEED, but it means something else!)
1026 dnl
1027 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1028 dnl it counts page-table space as committed memory, and so quickly
1029 dnl runs out of paging file when we have multiple processes reserving
1030 dnl 1TB of address space, we get the following error:
1031 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1032 dnl
1033
1034 AC_ARG_ENABLE(large-address-space,
1035     [AC_HELP_STRING([--enable-large-address-space],
1036         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1037     EnableLargeAddressSpace=$enableval,
1038     EnableLargeAddressSpace=yes
1039 )
1040
1041 use_large_address_space=no
1042 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1043     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1044         if test "$ghc_host_os" = "darwin" ; then
1045             use_large_address_space=yes
1046         elif test "$ghc_host_os" = "openbsd" ; then
1047             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1048             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1049             # but is completely ignored by OS mmap
1050             use_large_address_space=no
1051         else
1052             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1053                 [
1054                 #include <unistd.h>
1055                 #include <sys/types.h>
1056                 #include <sys/mman.h>
1057                 #include <fcntl.h>
1058             ])
1059             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1060                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1061                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1062                     use_large_address_space=yes
1063             fi
1064         fi
1065     fi
1066 fi
1067 if test "$use_large_address_space" = "yes" ; then
1068    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1069 fi
1070
1071 AC_CHECK_LIB(dw, dwfl_begin, [HaveLibdw=YES], [HaveLibdw=NO])
1072 AC_SUBST(HaveLibdw)
1073
1074 if test -n "$SPHINXBUILD"; then
1075     BUILD_MAN=YES
1076     BUILD_SPHINX_HTML=YES
1077     if test -n "$XELATEX"; then
1078         BUILD_SPHINX_PDF=YES
1079     else
1080         BUILD_SPHINX_PDF=NO
1081     fi
1082 else
1083     BUILD_MAN=NO
1084     BUILD_SPHINX_HTML=NO
1085     BUILD_SPHINX_PDF=NO
1086 fi
1087 AC_SUBST(BUILD_MAN)
1088 AC_SUBST(BUILD_SPHINX_HTML)
1089 AC_SUBST(BUILD_SPHINX_PDF)
1090
1091 LIBRARY_VERSION(base)
1092 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1093 LIBRARY_VERSION(ghc-prim)
1094 LIBRARY_ghc_VERSION="$ProjectVersion"
1095 AC_SUBST(LIBRARY_ghc_VERSION)
1096
1097 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1098    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1099 fi
1100
1101 # Create the configuration for the Shake-based build system if it is present
1102 if test -e shake-build/cfg/system.config.in; then
1103     AC_CONFIG_FILES([shake-build/cfg/system.config])
1104 fi
1105
1106 # We got caught by
1107 #     http://savannah.gnu.org/bugs/index.php?1516
1108 #     $(eval ...) inside conditionals causes errors
1109 # with make 3.80, so warn the user if it looks like they're about to
1110 # try to use it.
1111 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1112 print_make_warning=""
1113 checkMake380() {
1114     make_ver=`$1 --version 2>&1 | head -1`
1115     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1116     then
1117         print_make_warning="true"
1118     fi
1119     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1120     then
1121         MakeCmd=$1
1122         AC_SUBST(MakeCmd)
1123     fi
1124 }
1125
1126 checkMake380 make
1127 checkMake380 gmake
1128
1129 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt distrib/configure.ac])
1130 AC_OUTPUT
1131
1132 if test "$print_make_warning" = "true"; then
1133    echo
1134    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1135    echo "This version cannot be used to build GHC."
1136    echo "Please use GNU make >= 3.81."
1137 fi
1138
1139 echo ["
1140 ----------------------------------------------------------------------
1141 Configure completed successfully.
1142
1143    Building GHC version  : $ProjectVersion
1144           Git commit id  : $ProjectGitCommitId
1145
1146    Build platform        : $BuildPlatform
1147    Host platform         : $HostPlatform
1148    Target platform       : $TargetPlatform
1149 "]
1150
1151 echo ["\
1152    Bootstrapping using   : $WithGhc
1153       which is version   : $GhcVersion
1154 "]
1155
1156 if test "x$CC_LLVM_BACKEND" = "x1"; then
1157     if test "x$CC_CLANG_BACKEND" = "x1"; then
1158         CompilerName="clang        "
1159     else
1160         CompilerName="llvm-gcc     "
1161     fi
1162 else
1163     CompilerName="gcc          "
1164 fi
1165
1166 echo ["\
1167    Using $CompilerName       : $WhatGccIsCalled
1168       which is version       : $GccVersion
1169    Building a cross compiler : $CrossCompiling
1170    hs-cpp       : $HaskellCPPCmd
1171    hs-cpp-flags : $HaskellCPPArgs
1172    ld           : $LdCmd
1173    nm           : $NmCmd
1174    objdump      : $ObjdumpCmd
1175    Happy        : $HappyCmd ($HappyVersion)
1176    Alex         : $AlexCmd ($AlexVersion)
1177    Perl         : $PerlCmd
1178    sphinx-build : $SPHINXBUILD
1179    xelatex      : $XELATEX
1180
1181    Using LLVM tools
1182       llc   : $LlcCmd
1183       opt   : $OptCmd"]
1184
1185 if test "$HSCOLOUR" = ""; then
1186 echo ["
1187    HsColour was not found; documentation will not contain source links
1188 "]
1189 else
1190 echo ["\
1191    HsColour : $HSCOLOUR
1192 "]
1193 fi
1194
1195 echo ["\
1196    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1197    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"]
1198
1199 echo ["----------------------------------------------------------------------
1200 "]
1201
1202 echo "\
1203 For a standard build of GHC (fully optimised with profiling), type (g)make.
1204
1205 To make changes to the default build configuration, copy the file
1206 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1207
1208 For more information on how to configure your GHC build, see
1209    http://ghc.haskell.org/trac/ghc/wiki/Building
1210 "