Pass autoconf triplets to sub-project configures
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.1], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl this makes sure `./configure --target=<cross-compile-target>`
37 dnl works as expected, since we're slightly modifying how Autoconf
38 dnl interprets build/host/target and how this interacts with $CC tests
39 test -n "$target_alias" && ac_tool_prefix=$target_alias-
40
41 dnl ----------------------------------------------------------
42 dnl ** Find unixy sort and find commands,
43 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
44
45 dnl ** Find find command (for Win32's benefit)
46 FP_PROG_FIND
47 FP_PROG_SORT
48
49 dnl ----------------------------------------------------------
50 FP_SETUP_PROJECT_VERSION
51
52 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
53 AC_SUBST([release], [1])
54
55 # First off, a distrib sanity check..
56 AC_CONFIG_SRCDIR([mk/config.mk.in])
57
58 dnl * We require autoconf version 2.60
59 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
60 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
61 dnl Using autoconf 2.59 started to give nonsense like this
62 dnl  #define SIZEOF_CHAR 0
63 dnl recently.
64 AC_PREREQ([2.60])
65
66 # -------------------------------------------------------------------------
67 # Prepare to generate the following header files
68 #
69 #
70 AC_CONFIG_HEADER(mk/config.h)
71
72 # No, semi-sadly, we don't do `--srcdir'...
73 if test x"$srcdir" != 'x.' ; then
74     echo "This configuration does not support the \`--srcdir' option.."
75     exit 1
76 fi
77
78 dnl --------------------------------------------------------------
79 dnl * Project specific configuration options
80 dnl --------------------------------------------------------------
81 dnl What follows is a bunch of options that can either be configured
82 dnl through command line options to the configure script or by
83 dnl supplying defns in the build tree's mk/build.mk. Having the option to
84 dnl use either is considered a Feature.
85
86 dnl ** What command to use to compile compiler sources ?
87 dnl --------------------------------------------------------------
88
89 AC_ARG_WITH([ghc],
90 [AC_HELP_STRING([--with-ghc=ARG],
91   [Use ARG as the path to GHC  [default=autodetect]])],
92   [WithGhc="$withval"],
93   [if test "$GHC" = ""; then
94     AC_PATH_PROG([GHC], [ghc])
95   fi
96   WithGhc="$GHC"])
97
98 dnl ** Tell the make system which OS we are using
99 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
100 AC_SUBST(OSTYPE)
101
102 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
103 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
104                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
105         EnableBootstrapWithDevelSnaphost=YES,
106         EnableBootstrapWithDevelSnaphost=NO
107 )
108
109 AC_ARG_ENABLE(tarballs-autodownload,
110 [AC_HELP_STRING([--enable-tarballs-autodownload],
111                 [Automatically download Windows distribution binaries if needed.])],
112         TarballsAutodownload=YES,
113         TarballsAutodownload=NO
114 )
115
116 dnl CC_STAGE0 is like the "previous" variable CC (inherited by CC_STAGE[123])
117 dnl but instead used by stage0 for bootstrapping stage1
118 AC_ARG_VAR(CC_STAGE0, [C compiler command (bootstrap)])
119
120 if test "$WithGhc" != ""; then
121   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
122
123   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
124      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
125   fi
126
127   AC_SUBST(GhcVersion)dnl
128   AC_SUBST(GhcMajVersion)dnl
129   AC_SUBST(GhcMinVersion)dnl
130   AC_SUBST(GhcPatchLevel)dnl
131   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
132   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
133
134   dnl infer CC_STAGE0 from `ghc --info` unless explicitly set by user
135   if test -z "$CC_STAGE0"; then
136     BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
137   fi
138
139   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
140   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
141   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
142   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
143 fi
144
145 dnl ** Must have GHC to build GHC
146 if test "$WithGhc" = ""
147 then
148     AC_MSG_ERROR([GHC is required.])
149 fi
150 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.10],
151     [AC_MSG_ERROR([GHC version 7.10 or later is required to compile GHC.])])
152
153 if test `expr $GhcMinVersion % 2` = "1"
154 then
155     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
156     then
157         AC_MSG_ERROR([
158      $WithGhc is a development snapshot of GHC, version $GhcVersion.
159      Bootstrapping using this version of GHC is not supported, and may not
160      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
161      or --with-ghc to specify a different GHC to use.])
162     fi
163 fi
164
165 GHC_PACKAGE_DB_FLAG=package-db
166 AC_SUBST(GHC_PACKAGE_DB_FLAG)
167
168 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.11],
169                     SUPPORTS_THIS_UNIT_ID=NO,
170                     SUPPORTS_THIS_UNIT_ID=YES)
171 AC_SUBST(SUPPORTS_THIS_UNIT_ID)
172
173 # GHC is passed to Cabal, so we need a native path
174 if test "${WithGhc}" != ""
175 then
176     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
177
178     if test "$ghc_host_os" = "mingw32"
179     then
180         # Canonicalise to <drive>:/path/to/ghc
181         WithGhc=`cygpath -m "${WithGhc}"`
182
183         echo "GHC path canonicalised to: ${WithGhc}"
184     fi
185 fi
186 AC_SUBST([WithGhc])
187
188 dnl ** Without optimization some INLINE trickery fails for GHCi
189 SRC_CC_OPTS="-O"
190
191 dnl--------------------------------------------------------------------
192 dnl * Choose host(/target/build) platform
193 dnl--------------------------------------------------------------------
194 dnl If we aren't explicitly told what values to use with configure flags,
195 dnl we ask the bootstrapping compiler what platform it is for
196
197 if test "${WithGhc}" != ""
198 then
199         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
200         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
201         if test "$bootstrap_host" != "$bootstrap_target"
202         then
203                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
204         fi
205 fi
206
207 # We have to run these unconditionally, but we may discard their
208 # results in the following code
209 AC_CANONICAL_BUILD
210 AC_CANONICAL_HOST
211 AC_CANONICAL_TARGET
212
213 FPTOOLS_SET_PLATFORM_VARS
214
215 # Verify that the installed (bootstrap) GHC is capable of generating
216 # code for the requested build platform.
217 if test "$BuildPlatform" != "$bootstrap_target"
218 then
219     echo "This GHC (${WithGhc}) does not generate code for the build platform"
220     echo "   GHC target platform    : $bootstrap_target"
221     echo "   Desired build platform : $BuildPlatform"
222     exit 1
223 fi
224
225 # Testing if we shall enable shared libs support on Solaris.
226 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
227
228 SOLARIS_BROKEN_SHLD=NO
229
230 case $host in
231      i386-*-solaris2)
232      # here we go with the test
233      MINOR=`uname -r|cut -d '.' -f 2-`
234      if test "$MINOR" -lt "11"; then
235          SOLARIS_BROKEN_SHLD=YES
236      fi
237      ;;
238 esac
239
240 AC_SUBST(SOLARIS_BROKEN_SHLD)
241
242 dnl ** Do an unregisterised build?
243 dnl --------------------------------------------------------------
244 case "$HostArch" in
245     i386|x86_64|powerpc|powerpc64|powerpc64le|arm)
246         UnregisterisedDefault=NO
247         ;;
248     *)
249         UnregisterisedDefault=YES
250         ;;
251 esac
252 AC_ARG_ENABLE(unregisterised,
253 [AC_HELP_STRING([--enable-unregisterised],
254 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
255 [ if test x"$enableval" = x"yes"; then
256         Unregisterised=YES
257   else
258         Unregisterised=NO
259   fi
260 ],
261 [Unregisterised="$UnregisterisedDefault"]
262 )
263 AC_SUBST(Unregisterised)
264
265 # Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
266 FP_FIND_ROOT
267
268 fail() {
269     echo >&2
270     echo "$1" >&2
271     exit 1
272 }
273
274
275 if test "$HostOS" = "mingw32"
276 then
277     # Find the mingw-w64 7z file to extract.
278     # NB. If you update the tarballs to a new version of gcc, don't
279     # forget to tweak the paths in driver/gcc/gcc.c.
280     if test "$HostArch" = "i386"
281     then
282         mingw_arch="i686"
283         tarball_dest_dir="mingw-w64/x86"
284         tarball_mingw_dir="mingw32"
285     else
286         mingw_arch="x86_64"
287         tarball_dest_dir="mingw-w64/x86_64"
288         tarball_mingw_dir="mingw64"
289     fi
290 fi
291
292 set_up_tarballs() {
293     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
294     local action
295     if test "$TarballsAutodownload" = "NO"
296     then
297         action="verify"
298     else
299         action="download"
300     fi
301     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
302     case $? in
303         0)
304            rm missing-win32-tarballs
305            ;;
306         2)
307            echo
308            echo "Error:"
309            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
310            echo
311            echo "  * run configure with the --enable-tarballs-autodownload option"
312            echo
313            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
314            echo
315            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
316            echo "    them in the ghc-tarballs directory."
317            echo
318            exit 1
319            ;;
320         *)
321            echo
322            echo "Error fetching msys2 tarballs; see errors above."
323            exit 1
324            ;;
325     esac
326
327     # Extract all the tarballs in one go
328     if ! test -d inplace/mingw
329     then
330         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
331         rm -rf inplace/mingw
332         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
333         ( cd inplace &&
334         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
335         rm ".MTREE" &&
336         rm ".PKGINFO" &&
337         cd .. ) || fail "Error: Could not extract Windows toolchains."
338
339         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
340         touch inplace/mingw
341
342         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
343         # make a wrapper around it to give it the proper paths
344         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
345         PATH=`pwd`/inplace/mingw/bin:$PATH
346         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
347
348         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
349     fi
350 }
351
352 if test "$HostOS" = "mingw32"
353 then
354     test -d inplace || mkdir inplace
355
356     # NB. Download and extract the MingW-w64 distribution if required
357     set_up_tarballs
358
359     mingwbin="$hardtop/inplace/mingw/bin/"
360     CC="${mingwbin}gcc.exe"
361     LD="${mingwbin}ld.exe"
362     NM="${mingwbin}nm.exe"
363     RANLIB="${mingwbin}ranlib.exe"
364     OBJDUMP="${mingwbin}objdump.exe"
365     Windres="${mingwbin}windres.exe"
366     DllWrap="${mingwbin}dllwrap.exe"
367     fp_prog_ar="${mingwbin}ar.exe"
368
369     # NB. Download the perl binaries if required
370     if ! test -d inplace/perl ||
371          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
372     then
373         AC_MSG_NOTICE([Making in-tree perl tree])
374         rm -rf inplace/perl
375         mkdir inplace/perl
376         (
377             cd inplace/perl &&
378             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
379         )
380         AC_MSG_NOTICE([In-tree perl tree created])
381     fi
382 fi
383
384 FP_ICONV
385 FP_GMP
386 FP_CURSES
387
388 XCODE_VERSION()
389
390 SplitObjsBroken=NO
391 if test "$TargetOS_CPP" = "darwin"
392 then
393     # Split objects is broken (#4013) with XCode < 3.2
394     if test "$XCodeVersion1" -lt 3
395     then
396         SplitObjsBroken=YES
397     else
398         if test "$XCodeVersion1" -eq 3
399         then
400             if test "$XCodeVersion2" -lt 2
401             then
402                 SplitObjsBroken=YES
403             fi
404         fi
405     fi
406 fi
407 AC_SUBST([SplitObjsBroken])
408
409 dnl ** Building a cross compiler?
410 dnl --------------------------------------------------------------
411 CrossCompiling=NO
412 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
413 if test "$TargetPlatform" != "$HostPlatform" ; then
414     CrossCompiling=YES
415     cross_compiling=yes   # This tells configure that it can accept just 'target',
416                           # otherwise you get
417                           #   configure: error: cannot run C compiled programs.
418                           #   If you meant to cross compile, use `--host'.
419 fi
420 if test "$BuildPlatform" != "$HostPlatform" ; then
421    AC_MSG_ERROR([
422 You've selected:
423
424   BUILD:  $BuildPlatform   (the architecture we're building on)
425   HOST:   $HostPlatform    (the architecture the compiler we're building will execute on)
426   TARGET: $TargetPlatform  (the architecture the compiler we're building will produce code for)
427
428 BUILD must equal HOST; that is, we do not support building GHC itself
429 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
430 1 will be a cross-compiler, and stage 2 will be the cross-compiled
431 GHC.
432 ])
433 fi
434 if test "$CrossCompiling" = "YES"
435 then
436   CrossCompilePrefix="${target}-"
437 else
438   CrossCompilePrefix=""
439 fi
440 # Despite its similarity in name to TargetPlatform, TargetPlatformFull is used
441 # in calls to subproject configure scripts and thus must be set to the autoconf
442 # triple, not the normalized GHC triple that TargetPlatform is set to.
443 # It may be better to just do away with the GHC triples all together.
444 TargetPlatformFull="${target}"
445 AC_SUBST(CrossCompiling)
446 AC_SUBST(CrossCompilePrefix)
447 AC_SUBST(TargetPlatformFull)
448
449 dnl ** Which gcc to use?
450 dnl --------------------------------------------------------------
451
452 AC_ARG_WITH([gcc],
453         AS_HELP_STRING([--with-gcc=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
454         AC_MSG_ERROR([--with-gcc=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
455
456 AC_ARG_WITH([clang],
457         AS_HELP_STRING([--with-clang=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
458         AC_MSG_ERROR([--with-clang=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
459
460 dnl detect compiler (prefer gcc over clang) and set $CC (unless CC already set),
461 dnl later CC is copied to CC_STAGE{1,2,3}
462 AC_PROG_CC([gcc clang])
463
464 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
465
466 dnl make extensions visible to allow feature-tests to detect them lateron
467 AC_USE_SYSTEM_EXTENSIONS
468
469 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
470 AC_PROG_CPP
471
472 # --with-hs-cpp/--with-hs-cpp-flags
473 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
474 AC_SUBST([HaskellCPPCmd])
475 AC_SUBST([HaskellCPPArgs])
476
477 FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
478 FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
479 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
480 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
481
482 dnl ** Which ld to use?
483 dnl --------------------------------------------------------------
484 FIND_LD([LdCmd])
485 AC_SUBST([LdCmd])
486
487 dnl ** Which nm to use?
488 dnl --------------------------------------------------------------
489 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
490
491 if test "$TargetOS_CPP" = "darwin"
492 then
493     AC_MSG_CHECKING(whether nm program is broken)
494     # Some versions of XCode ship a broken version of `nm`. Detect and work
495     # around this issue. See : https://ghc.haskell.org/trac/ghc/ticket/11744
496     nmver=$(${NM} --version | grep version | sed 's/ //g')
497     case "$nmver" in
498         LLVMversion7.3.0|LLVMversion7.3.1)
499             AC_MSG_RESULT(yes)
500             echo "The detected nm program is broken."
501             echo
502             echo "See: https://ghc.haskell.org/trac/ghc/ticket/11744"
503             echo
504             echo "Try re-running configure with:"
505             echo
506             echo '   ./configure --with-nm=$(xcrun --find nm-classic)'
507             echo
508             exit 1
509             ;;
510         *)
511             AC_MSG_RESULT(no)
512             ;;
513         esac
514 fi
515
516 NmCmd="$NM"
517 AC_SUBST([NmCmd])
518
519 dnl ** Which objdump to use?
520 dnl --------------------------------------------------------------
521 FP_ARG_WITH_PATH_GNU_PROG_OPTIONAL([OBJDUMP], [objdump], [objdump])
522 ObjdumpCmd="$OBJDUMP"
523 AC_SUBST([ObjdumpCmd])
524
525 dnl ** Which ar to use?
526 dnl --------------------------------------------------------------
527 FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
528 ArCmd="$AR"
529 fp_prog_ar="$AR"
530 AC_SUBST([ArCmd])
531
532 dnl ** Which ranlib to use?
533 dnl --------------------------------------------------------------
534 FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
535 RanlibCmd="$RANLIB"
536 RANLIB="$RanlibCmd"
537
538
539 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
540 case $HostOS_CPP in
541 cygwin32|mingw32)
542     dnl ** Which objdump to use?
543     dnl --------------------------------------------------------------
544     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
545     ObjdumpCmd="$OBJDUMP"
546     AC_SUBST([ObjdumpCmd])
547     ;;
548 esac
549
550 # Here is where we re-target which specific version of the LLVM
551 # tools we are looking for. In the past, GHC supported a number of
552 # versions of LLVM simultaneously, but that stopped working around
553 # 3.5/3.6 release of LLVM.
554 LlvmVersion=3.8
555 AC_SUBST([LlvmVersion])
556 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
557 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
558
559 dnl ** Which LLVM llc to use?
560 dnl --------------------------------------------------------------
561 FIND_LLVM_PROG([LLC], [llc], [llc], [$LlvmVersion])
562 LlcCmd="$LLC"
563 AC_SUBST([LlcCmd])
564
565 dnl ** Which LLVM opt to use?
566 dnl --------------------------------------------------------------
567 FIND_LLVM_PROG([OPT], [opt], [opt], [$LlvmVersion])
568 OptCmd="$OPT"
569 AC_SUBST([OptCmd])
570
571 dnl --------------------------------------------------------------
572 dnl End of configure script option section
573 dnl --------------------------------------------------------------
574
575
576 dnl --------------------------------------------------------------
577 dnl ** Can the unix package be built?
578 dnl --------------------------------------------------------------
579
580 if test "$TargetOS" = "mingw32"
581 then
582     GhcLibsWithUnix=NO
583 else
584     GhcLibsWithUnix=YES
585 fi
586 AC_SUBST([GhcLibsWithUnix])
587
588 dnl ** does #! work?
589 AC_SYS_INTERPRETER()
590
591 dnl ** look for `perl'
592 case $HostOS_CPP in
593 cygwin32|mingw32)
594     PerlCmd=$hardtop/inplace/perl/perl
595     ;;
596 *)
597     AC_PATH_PROG(PerlCmd,perl)
598     if test -z "$PerlCmd"
599     then
600         echo "You must install perl before you can continue"
601         echo "Perhaps it is already installed, but not in your PATH?"
602         exit 1
603     else
604         FPTOOLS_CHECK_PERL_VERSION
605     fi
606     ;;
607 esac
608
609 dnl ** look for GCC and find out which version
610 dnl     Figure out which C compiler to use.  Gcc is preferred.
611 dnl     If gcc, make sure it's at least 3.0
612 dnl
613 FP_GCC_VERSION
614
615 dnl ** See whether gcc supports -no-pie
616 FP_GCC_SUPPORTS_NO_PIE
617
618 dnl ** look to see if we have a C compiler using an llvm back end.
619 dnl
620 FP_CC_LLVM_BACKEND
621
622 FP_PROG_LD_IS_GNU
623 FP_PROG_LD_BUILD_ID
624 FP_PROG_LD_NO_COMPACT_UNWIND
625 FP_PROG_LD_FILELIST
626
627
628 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
629 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
630 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
631 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
632 # Stage 3 won't be supported by cross-compilation
633
634 FP_GCC_EXTRA_FLAGS
635
636 # See rules/distdir-way-opts.mk for details.
637 # Flags passed to the C compiler
638 AC_SUBST(CONF_CC_OPTS_STAGE0)
639 AC_SUBST(CONF_CC_OPTS_STAGE1)
640 AC_SUBST(CONF_CC_OPTS_STAGE2)
641 # Flags passed to the C compiler when we ask it to link
642 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
643 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
644 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
645 # Flags passed to the linker when we ask it to link
646 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
647 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
648 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
649 # Flags passed to the C preprocessor
650 AC_SUBST(CONF_CPP_OPTS_STAGE0)
651 AC_SUBST(CONF_CPP_OPTS_STAGE1)
652 AC_SUBST(CONF_CPP_OPTS_STAGE2)
653 # Flags passed to the Haskell compiler
654 AC_SUBST(CONF_HC_OPTS_STAGE0)
655 AC_SUBST(CONF_HC_OPTS_STAGE1)
656 AC_SUBST(CONF_HC_OPTS_STAGE2)
657
658 dnl ** Set up the variables for the platform in the settings file.
659 dnl May need to use gcc to find platform details.
660 dnl --------------------------------------------------------------
661 FPTOOLS_SET_HASKELL_PLATFORM_VARS
662
663 dnl ** figure out how to do context diffs
664 FP_PROG_CONTEXT_DIFF
665
666 dnl Let's make sure install-sh is executable here.  If we got it from
667 dnl a darcs repo, it might not be (see bug #978).
668 chmod +x install-sh
669 dnl ** figure out how to do a BSD-ish install
670 AC_PROG_INSTALL
671
672 dnl ** how to invoke `ar' and `ranlib'
673 FP_PROG_AR_SUPPORTS_ATFILE
674 FP_PROG_AR_NEEDS_RANLIB
675
676 dnl ** Check to see whether ln -s works
677 AC_PROG_LN_S
678
679 FP_SETTINGS
680
681 dnl ** Find the path to sed
682 AC_PATH_PROGS(SedCmd,gsed sed,sed)
683
684
685 dnl ** check for time command
686 AC_PATH_PROG(TimeCmd,time)
687
688 dnl ** check for tar
689 dnl   if GNU tar is named gtar, look for it first.
690 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
691
692 dnl ** check for patch
693 dnl if GNU patch is named gpatch, look for it first
694 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
695
696 dnl ** check for dtrace (currently only implemented for Mac OS X)
697 HaveDtrace=NO
698 AC_PATH_PROG(DtraceCmd,dtrace)
699 if test -n "$DtraceCmd"; then
700   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
701     HaveDtrace=YES
702   fi
703 fi
704 AC_SUBST(HaveDtrace)
705
706 AC_PATH_PROG(HSCOLOUR,HsColour)
707 # HsColour is passed to Cabal, so we need a native path
708 if test "$HostOS"      = "mingw32" && \
709    test "${HSCOLOUR}" != ""
710 then
711     # Canonicalise to <drive>:/path/to/gcc
712     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
713 fi
714
715 dnl ** check for Sphinx toolchain
716 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
717 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
718 changequote(, )dnl
719 [if test -n "$SPHINXBUILD"; then
720   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
721 fi;
722 changequote([, ])dnl
723 ])
724 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
725     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
726
727 dnl ** check for xelatex
728 AC_PATH_PROG(XELATEX,xelatex)
729
730 dnl ** check for ghc-pkg command
731 FP_PROG_GHC_PKG
732
733 dnl ** check for installed happy binary + version
734 FPTOOLS_HAPPY
735
736 dnl ** check for installed alex binary + version
737 FPTOOLS_ALEX
738
739 dnl --------------------------------------------------
740 dnl ### program checking section ends here ###
741 dnl --------------------------------------------------
742
743 dnl --------------------------------------------------
744 dnl * Platform header file and syscall feature tests
745 dnl ### checking the state of the local header files and syscalls ###
746
747 dnl ** check for full ANSI header (.h) files
748 AC_HEADER_STDC
749
750 dnl ** Enable large file support.  NB. do this before testing the type of
751 dnl    off_t, because it will affect the result of that test.
752 AC_SYS_LARGEFILE
753
754 dnl ** check for specific header (.h) files that we are interested in
755 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
756
757 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
758 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
759 [[#if HAVE_SYS_PARAM_H
760 # include <sys/param.h>
761 #endif
762 ]])
763
764 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
765 AC_HEADER_TIME
766
767 dnl ** do we have long longs?
768 AC_CHECK_TYPES([long long])
769
770 dnl ** what are the sizes of various types
771 FP_CHECK_SIZEOF_AND_ALIGNMENT(char)
772 FP_CHECK_SIZEOF_AND_ALIGNMENT(double)
773 FP_CHECK_SIZEOF_AND_ALIGNMENT(float)
774 FP_CHECK_SIZEOF_AND_ALIGNMENT(int)
775 FP_CHECK_SIZEOF_AND_ALIGNMENT(long)
776 if test "$ac_cv_type_long_long" = yes; then
777 FP_CHECK_SIZEOF_AND_ALIGNMENT(long long)
778 fi
779 FP_CHECK_SIZEOF_AND_ALIGNMENT(short)
780 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned char)
781 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned int)
782 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long)
783 if test "$ac_cv_type_long_long" = yes; then
784 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long long)
785 fi
786 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned short)
787 FP_CHECK_SIZEOF_AND_ALIGNMENT(void *)
788
789 FP_CHECK_SIZEOF_AND_ALIGNMENT(int8_t)
790 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint8_t)
791 FP_CHECK_SIZEOF_AND_ALIGNMENT(int16_t)
792 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint16_t)
793 FP_CHECK_SIZEOF_AND_ALIGNMENT(int32_t)
794 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint32_t)
795 FP_CHECK_SIZEOF_AND_ALIGNMENT(int64_t)
796 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint64_t)
797
798
799 dnl for use in settings.in
800 WordSize=$ac_cv_sizeof_void_p
801 AC_SUBST(WordSize)
802 FP_CHECK_FUNC([WinExec],
803   [@%:@include <windows.h>], [WinExec("",0)])
804
805 FP_CHECK_FUNC([GetModuleFileName],
806   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
807
808 dnl ** check for more functions
809 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
810 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
811
812 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
813 dnl ** _POSIX_C_SOURCE is defined
814 AC_CHECK_DECLS([ctime_r], , ,
815 [#define _POSIX_SOURCE 1
816 #define _POSIX_C_SOURCE 199506L
817 #include <time.h>])
818
819 dnl ** check for mingwex library
820 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
821 AC_SUBST(HaveLibMingwEx)
822
823 if test $HaveLibMingwEx = YES ; then
824   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
825 fi
826
827 dnl ** check for math library
828 dnl    Keep that check as early as possible.
829 dnl    as we need to know whether we need libm
830 dnl    for math functions or not
831 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
832 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
833 if test $HaveLibM = YES
834 then
835   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
836 fi
837
838 FP_BFD_SUPPORT
839
840 dnl ################################################################
841 dnl Check for libraries
842 dnl ################################################################
843
844 # system libffi
845
846 AC_ARG_WITH([system-libffi],
847 [AC_HELP_STRING([--with-system-libffi],
848   [Use system provided libffi for RTS [default=no]])
849 ])
850
851 AS_IF([test "x$with_system_libffi" = "xyes"],
852   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
853 )
854
855
856 AC_SUBST(UseSystemLibFFI)
857
858 AC_ARG_WITH([ffi-includes],
859 [AC_HELP_STRING([--with-ffi-includes=ARG],
860   [Find includes for libffi in ARG [default=system default]])
861 ],
862 [
863  if test "x$UseSystemLibFFI" != "xYES"; then
864     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
865  else
866     FFIIncludeDir="$withval"
867     LIBFFI_CFLAGS="-I$withval"
868  fi
869 ])
870
871 AC_SUBST(FFIIncludeDir)
872
873 AC_ARG_WITH([ffi-libraries],
874 [AC_HELP_STRING([--with-ffi-libraries=ARG],
875   [Find libffi in ARG [default=system default]])
876 ],
877 [
878  if test "x$UseSystemLibFFI" != "xYES"; then
879     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
880  else
881     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
882  fi
883 ])
884
885 AC_SUBST(FFILibDir)
886
887 AS_IF([test "$UseSystemLibFFI" = "YES"], [
888  CFLAGS2="$CFLAGS"
889  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
890  LDFLAGS2="$LDFLAGS"
891  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
892  if test "$HostOS" = "openbsd";
893  then
894    # OpenBSD's libffi is not directly linked to the libpthread but
895    # still requires pthread functionality. This means that any client
896    # binary which links with libffi also needs to link with
897    # libpthread. If it does not, then linking fails with unresolved
898    # symbols.
899    LDFLAGS="$LDFLAGS -lpthread"
900  fi
901  AC_CHECK_LIB(ffi, ffi_call,
902   [AC_CHECK_HEADERS([ffi.h], [break], [])
903    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
904   [AC_MSG_ERROR([Cannot find system libffi])])
905  CFLAGS="$CFLAGS2"
906  LDFLAGS="$LDFLAGS2"
907 ])
908
909 dnl ** check whether we need -ldl to get dlopen()
910 AC_CHECK_LIB(dl, dlopen)
911
912 dnl --------------------------------------------------
913 dnl * Miscellaneous feature tests
914 dnl --------------------------------------------------
915
916 dnl ** can we get alloca?
917 AC_FUNC_ALLOCA
918
919 dnl ** working vfork?
920 AC_FUNC_FORK
921
922 dnl ** determine whether or not const works
923 AC_C_CONST
924
925 dnl ** are we big endian?
926 AC_C_BIGENDIAN
927 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
928
929 dnl ** check for leading underscores in symbol names
930 FP_LEADING_UNDERSCORE
931
932 FP_VISIBILITY_HIDDEN
933
934 dnl ** check for librt
935 AC_CHECK_LIB(rt, clock_gettime)
936 AC_CHECK_FUNCS(clock_gettime timer_settime)
937 FP_CHECK_TIMER_CREATE
938
939 dnl ** check for Apple's "interesting" long double compatibility scheme
940 AC_MSG_CHECKING(for printf\$LDBLStub)
941 AC_TRY_LINK_FUNC(printf\$LDBLStub,
942     [
943         AC_MSG_RESULT(yes)
944         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
945             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
946     ],
947     [
948         AC_MSG_RESULT(no)
949         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
950             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
951     ])
952
953 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
954 dnl    a different single-argument version.
955 AC_CHECK_LIB(pthread, pthread_setname_np)
956 AC_MSG_CHECKING(for pthread_setname_np)
957 AC_TRY_LINK(
958 [
959 #define _GNU_SOURCE
960 #include <pthread.h>
961 ],
962 [pthread_setname_np(pthread_self(), "name");],
963     AC_MSG_RESULT(yes)
964     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
965       [Define to 1 if you have the glibc version of pthread_setname_np]),
966     AC_MSG_RESULT(no)
967 )
968
969 dnl ** check for eventfd which is needed by the I/O manager
970 AC_CHECK_HEADERS([sys/eventfd.h])
971 AC_CHECK_FUNCS([eventfd])
972
973 dnl ** Check for __thread support in the compiler
974 AC_MSG_CHECKING(for __thread support)
975 AC_COMPILE_IFELSE(
976   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
977   [
978    AC_MSG_RESULT(yes)
979    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
980   ],
981   [
982    AC_MSG_RESULT(no)
983    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
984   ])
985
986 dnl large address space support (see includes/rts/storage/MBlock.h)
987 dnl
988 dnl Darwin has vm_allocate/vm_protect
989 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
990 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
991 dnl (They also have MADV_DONTNEED, but it means something else!)
992 dnl
993 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
994 dnl it counts page-table space as committed memory, and so quickly
995 dnl runs out of paging file when we have multiple processes reserving
996 dnl 1TB of address space, we get the following error:
997 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
998 dnl
999
1000 AC_ARG_ENABLE(large-address-space,
1001     [AC_HELP_STRING([--enable-large-address-space],
1002         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1003     EnableLargeAddressSpace=$enableval,
1004     EnableLargeAddressSpace=yes
1005 )
1006
1007 use_large_address_space=no
1008 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1009     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1010         if test "$ghc_host_os" = "darwin" ; then
1011             use_large_address_space=yes
1012         elif test "$ghc_host_os" = "openbsd" ; then
1013             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1014             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1015             # but is completely ignored by OS mmap
1016             use_large_address_space=no
1017         else
1018             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1019                 [
1020                 #include <unistd.h>
1021                 #include <sys/types.h>
1022                 #include <sys/mman.h>
1023                 #include <fcntl.h>
1024             ])
1025             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1026                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1027                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1028                     use_large_address_space=yes
1029             fi
1030         fi
1031     fi
1032 fi
1033 if test "$use_large_address_space" = "yes" ; then
1034    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1035 fi
1036
1037 dnl ** Use MMAP in the runtime linker?
1038 dnl --------------------------------------------------------------
1039
1040 case ${TargetOS} in
1041     linux|freebsd|dragonfly|netbsd|openbsd|kfreebsdgnu|gnu|solaris2)
1042         RtsLinkerUseMmap=1
1043         ;;
1044     darwin)
1045         # Don't use mmap on powerpc/darwin as the mmap there doesn't support
1046         # reallocating. Reallocating is needed to allocate jump islands just
1047         # after each object image. Jumps to these jump islands use relative
1048         # branches which are limited to offsets that can be represented in
1049         # 24-bits.
1050         if test "$TargetArch" != "powerpc" ; then
1051             RtsLinkerUseMmap=1
1052         else
1053             RtsLinkerUseMmap=0
1054         fi
1055         ;;
1056     *)
1057         # Windows (which doesn't have mmap) and everything else.
1058         RtsLinkerUseMmap=0
1059         ;;
1060     esac
1061
1062 AC_DEFINE_UNQUOTED([RTS_LINKER_USE_MMAP], [$RtsLinkerUseMmap],
1063                    [Use mmap in the runtime linker])
1064
1065 dnl ** Have libdw?
1066 dnl --------------------------------------------------------------
1067 UseLibdw=NO
1068 USE_LIBDW=0
1069 AC_ARG_ENABLE(dwarf-unwind,
1070     [AC_HELP_STRING([--enable-dwarf-unwind],
1071         [Enable DWARF unwinding support in the runtime system via elfutils' libdw [default=no]])],
1072     [AC_CHECK_LIB(dw, dwfl_attach_state, [UseLibdw=YES], [UseLibdw=NO])],
1073     [UseLibdw=NO]
1074 )
1075 AC_SUBST(UseLibdw)
1076 if test $UseLibdw = "YES" ; then
1077         USE_LIBDW=1
1078 fi
1079 AC_DEFINE_UNQUOTED([USE_LIBDW], [$USE_LIBDW], [Set to 1 to use libdw])
1080
1081 dnl ** Have libnuma?
1082 dnl --------------------------------------------------------------
1083 HaveLibNuma=0
1084 AC_CHECK_HEADERS([numa.h numaif.h])
1085
1086 if test "$ac_cv_header_numa_h$ac_cv_header_numaif_h" = "yesyes" ; then
1087     AC_CHECK_LIB(numa, numa_available,HaveLibNuma=1)
1088 fi
1089 AC_DEFINE_UNQUOTED([HAVE_LIBNUMA], [$HaveLibNuma], [Define to 1 if you have libnuma])
1090
1091 dnl ** Documentation
1092 dnl --------------------------------------------------------------
1093 if test -n "$SPHINXBUILD"; then
1094     BUILD_MAN=YES
1095     BUILD_SPHINX_HTML=YES
1096     if test -n "$XELATEX"; then
1097         BUILD_SPHINX_PDF=YES
1098     else
1099         BUILD_SPHINX_PDF=NO
1100     fi
1101 else
1102     BUILD_MAN=NO
1103     BUILD_SPHINX_HTML=NO
1104     BUILD_SPHINX_PDF=NO
1105 fi
1106 AC_SUBST(BUILD_MAN)
1107 AC_SUBST(BUILD_SPHINX_HTML)
1108 AC_SUBST(BUILD_SPHINX_PDF)
1109
1110 LIBRARY_VERSION(base)
1111 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1112 LIBRARY_VERSION(ghc-prim)
1113 LIBRARY_ghc_VERSION="$ProjectVersion"
1114 AC_SUBST(LIBRARY_ghc_VERSION)
1115
1116 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1117    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1118 fi
1119
1120 # Create the configuration for the Hadrian build system if it is present
1121 if test -e hadrian/cfg/system.config.in; then
1122     AC_CONFIG_FILES([hadrian/cfg/system.config])
1123 fi
1124
1125 # We got caught by
1126 #     http://savannah.gnu.org/bugs/index.php?1516
1127 #     $(eval ...) inside conditionals causes errors
1128 # with make 3.80, so warn the user if it looks like they're about to
1129 # try to use it.
1130 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1131 print_make_warning=""
1132 checkMake380() {
1133     make_ver=`$1 --version 2>&1 | head -1`
1134     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1135     then
1136         print_make_warning="true"
1137     fi
1138     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1139     then
1140         MakeCmd=$1
1141         AC_SUBST(MakeCmd)
1142     fi
1143 }
1144
1145 checkMake380 make
1146 checkMake380 gmake
1147
1148 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghc-boot-th/ghc-boot-th.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt distrib/configure.ac])
1149 AC_OUTPUT
1150
1151 if test "$print_make_warning" = "true"; then
1152    echo
1153    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1154    echo "This version cannot be used to build GHC."
1155    echo "Please use GNU make >= 3.81."
1156 fi
1157
1158 echo ["
1159 ----------------------------------------------------------------------
1160 Configure completed successfully.
1161
1162    Building GHC version  : $ProjectVersion
1163           Git commit id  : $ProjectGitCommitId
1164
1165    Build platform        : $BuildPlatform
1166    Host platform         : $HostPlatform
1167    Target platform       : $TargetPlatform
1168 "]
1169
1170 echo ["\
1171    Bootstrapping using   : $WithGhc
1172       which is version   : $GhcVersion
1173 "]
1174
1175 if test "x$CC_LLVM_BACKEND" = "x1"; then
1176     if test "x$CC_CLANG_BACKEND" = "x1"; then
1177         CompilerName="clang        "
1178     else
1179         CompilerName="llvm-gcc     "
1180     fi
1181 else
1182     CompilerName="gcc          "
1183 fi
1184
1185 echo ["\
1186    Using (for bootstrapping) : $CC_STAGE0
1187    Using $CompilerName       : $CC
1188       which is version       : $GccVersion
1189    Building a cross compiler : $CrossCompiling
1190    Unregisterised            : $Unregisterised
1191    hs-cpp       : $HaskellCPPCmd
1192    hs-cpp-flags : $HaskellCPPArgs
1193    ld           : $LdCmd
1194    nm           : $NmCmd
1195    objdump      : $ObjdumpCmd
1196    Happy        : $HappyCmd ($HappyVersion)
1197    Alex         : $AlexCmd ($AlexVersion)
1198    Perl         : $PerlCmd
1199    sphinx-build : $SPHINXBUILD
1200    xelatex      : $XELATEX
1201
1202    Using LLVM tools
1203       llc   : $LlcCmd
1204       opt   : $OptCmd"]
1205
1206 if test "$HSCOLOUR" = ""; then
1207 echo ["
1208    HsColour was not found; documentation will not contain source links
1209 "]
1210 else
1211 echo ["\
1212    HsColour : $HSCOLOUR
1213 "]
1214 fi
1215
1216 echo ["\
1217    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1218    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"]
1219
1220 echo ["----------------------------------------------------------------------
1221 "]
1222
1223 echo "\
1224 For a standard build of GHC (fully optimised with profiling), type (g)make.
1225
1226 To make changes to the default build configuration, copy the file
1227 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1228
1229 For more information on how to configure your GHC build, see
1230    http://ghc.haskell.org/trac/ghc/wiki/Building
1231 "