Merge remote-tracking branch 'origin/master' into newcg
[ghc.git] / compiler / types / OptCoercion.lhs
1 %
2 % (c) The University of Glasgow 2006
3 %
4
5 \begin{code}
6 {-# OPTIONS -fno-warn-tabs #-}
7 -- The above warning supression flag is a temporary kludge.
8 -- While working on this module you are encouraged to remove it and
9 -- detab the module (please do the detabbing in a separate patch). See
10 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#TabsvsSpaces
11 -- for details
12
13 module OptCoercion ( optCoercion ) where 
14
15 #include "HsVersions.h"
16
17 import Coercion
18 import Type hiding( substTyVarBndr, substTy, extendTvSubst )
19 import TcType       ( exactTyVarsOfType )
20 import TyCon
21 import Var
22 import VarSet
23 import VarEnv
24 import StaticFlags      ( opt_NoOptCoercion )
25 import Outputable
26 import Pair
27 import Maybes( allMaybes )
28 import FastString
29 import Util
30 \end{code}
31
32 %************************************************************************
33 %*                                                                      *
34                  Optimising coercions                                                                   
35 %*                                                                      *
36 %************************************************************************
37
38 Note [Subtle shadowing in coercions]
39 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
40 Supose we optimising a coercion
41     optCoercion (forall (co_X5:t1~t2). ...co_B1...)
42 The co_X5 is a wild-card; the bound variable of a coercion for-all
43 should never appear in the body of the forall. Indeed we often
44 write it like this
45     optCoercion ( (t1~t2) => ...co_B1... )
46
47 Just because it's a wild-card doesn't mean we are free to choose
48 whatever variable we like.  For example it'd be wrong for optCoercion
49 to return
50    forall (co_B1:t1~t2). ...co_B1...
51 because now the co_B1 (which is really free) has been captured, and
52 subsequent substitutions will go wrong.  That's why we can't use
53 mkCoPredTy in the ForAll case, where this note appears.  
54
55 \begin{code}
56 optCoercion :: CvSubst -> Coercion -> NormalCo
57 -- ^ optCoercion applies a substitution to a coercion, 
58 --   *and* optimises it to reduce its size
59 optCoercion env co 
60   | opt_NoOptCoercion = substCo env co
61   | otherwise         = opt_co env False co
62
63 type NormalCo = Coercion
64   -- Invariants: 
65   --  * The substitution has been fully applied
66   --  * For trans coercions (co1 `trans` co2)
67   --       co1 is not a trans, and neither co1 nor co2 is identity
68   --  * If the coercion is the identity, it has no CoVars of CoTyCons in it (just types)
69
70 type NormalNonIdCo = NormalCo  -- Extra invariant: not the identity
71
72 opt_co, opt_co' :: CvSubst
73                 -> Bool        -- True <=> return (sym co)
74                 -> Coercion
75                 -> NormalCo     
76 opt_co = opt_co'
77 {-
78 opt_co env sym co
79  = pprTrace "opt_co {" (ppr sym <+> ppr co $$ ppr env) $
80    co1 `seq`
81    pprTrace "opt_co done }" (ppr co1) $
82    (WARN( not same_co_kind, ppr co  <+> dcolon <+> pprEqPred (Pair s1 t1)
83                          $$ ppr co1 <+> dcolon <+> pprEqPred (Pair s2 t2) )
84     WARN( not (coreEqCoercion co1 simple_result),
85            (text "env=" <+> ppr env) $$
86            (text "input=" <+> ppr co) $$
87            (text "simple=" <+> ppr simple_result) $$
88            (text "opt=" <+> ppr co1) )
89    co1)
90  where
91    co1 = opt_co' env sym co
92    same_co_kind = s1 `eqType` s2 && t1 `eqType` t2
93    Pair s t = coercionKind (substCo env co)
94    (s1,t1) | sym = (t,s)
95            | otherwise = (s,t)
96    Pair s2 t2 = coercionKind co1
97
98    simple_result | sym = mkSymCo (substCo env co)
99                  | otherwise = substCo env co
100 -}
101
102 opt_co' env _   (Refl ty)           = Refl (substTy env ty)
103 opt_co' env sym (SymCo co)          = opt_co env (not sym) co
104 opt_co' env sym (TyConAppCo tc cos) = mkTyConAppCo tc (map (opt_co env sym) cos)
105 opt_co' env sym (AppCo co1 co2)     = mkAppCo (opt_co env sym co1) (opt_co env sym co2)
106 opt_co' env sym (ForAllCo tv co)    = case substTyVarBndr env tv of
107                                          (env', tv') -> mkForAllCo tv' (opt_co env' sym co)
108      -- Use the "mk" functions to check for nested Refls
109
110 opt_co' env sym (CoVarCo cv)
111   | Just co <- lookupCoVar env cv
112   = opt_co (zapCvSubstEnv env) sym co
113
114   | Just cv1 <- lookupInScope (getCvInScope env) cv
115   = ASSERT( isCoVar cv1 ) wrapSym sym (CoVarCo cv1)
116                 -- cv1 might have a substituted kind!
117
118   | otherwise = WARN( True, ptext (sLit "opt_co: not in scope:") <+> ppr cv $$ ppr env)
119                 ASSERT( isCoVar cv )
120                 wrapSym sym (CoVarCo cv)
121
122 opt_co' env sym (AxiomInstCo con cos)
123     -- Do *not* push sym inside top-level axioms
124     -- e.g. if g is a top-level axiom
125     --   g a : f a ~ a
126     -- then (sym (g ty)) /= g (sym ty) !!
127   = wrapSym sym $ AxiomInstCo con (map (opt_co env False) cos)
128       -- Note that the_co does *not* have sym pushed into it
129
130 opt_co' env sym (UnsafeCo ty1 ty2)
131   | ty1' `eqType` ty2' = Refl ty1'
132   | sym                = mkUnsafeCo ty2' ty1'
133   | otherwise          = mkUnsafeCo ty1' ty2'
134   where
135     ty1' = substTy env ty1
136     ty2' = substTy env ty2
137
138 opt_co' env sym (TransCo co1 co2)
139   | sym       = opt_trans in_scope opt_co2 opt_co1   -- sym (g `o` h) = sym h `o` sym g
140   | otherwise = opt_trans in_scope opt_co1 opt_co2
141   where
142     opt_co1 = opt_co env sym co1
143     opt_co2 = opt_co env sym co2
144     in_scope = getCvInScope env
145
146 opt_co' env sym (NthCo n co)
147   | TyConAppCo tc cos <- co'
148   , isDecomposableTyCon tc              -- Not synonym families
149   = ASSERT( n < length cos )
150     cos !! n
151   | otherwise
152   = NthCo n co'
153   where
154     co' = opt_co env sym co
155
156 opt_co' env sym (InstCo co ty)
157     -- See if the first arg is already a forall
158     -- ...then we can just extend the current substitution
159   | Just (tv, co_body) <- splitForAllCo_maybe co
160   = opt_co (extendTvSubst env tv ty') sym co_body
161
162      -- See if it is a forall after optimization
163      -- If so, do an inefficient one-variable substitution
164   | Just (tv, co'_body) <- splitForAllCo_maybe co'
165   = substCoWithTy (getCvInScope env) tv ty' co'_body   
166
167   | otherwise = InstCo co' ty'
168
169   where
170     co' = opt_co env sym co
171     ty' = substTy env ty
172
173 -------------
174 opt_transList :: InScopeSet -> [NormalCo] -> [NormalCo] -> [NormalCo]
175 opt_transList is = zipWith (opt_trans is)
176
177 opt_trans :: InScopeSet -> NormalCo -> NormalCo -> NormalCo
178 opt_trans is co1 co2
179   | isReflCo co1 = co2
180   | otherwise    = opt_trans1 is co1 co2
181
182 opt_trans1 :: InScopeSet -> NormalNonIdCo -> NormalCo -> NormalCo
183 -- First arg is not the identity
184 opt_trans1 is co1 co2
185   | isReflCo co2 = co1
186   | otherwise    = opt_trans2 is co1 co2
187
188 opt_trans2 :: InScopeSet -> NormalNonIdCo -> NormalNonIdCo -> NormalCo
189 -- Neither arg is the identity
190 opt_trans2 is (TransCo co1a co1b) co2
191     -- Don't know whether the sub-coercions are the identity
192   = opt_trans is co1a (opt_trans is co1b co2)  
193
194 opt_trans2 is co1 co2 
195   | Just co <- opt_trans_rule is co1 co2
196   = co
197
198 opt_trans2 is co1 (TransCo co2a co2b)
199   | Just co1_2a <- opt_trans_rule is co1 co2a
200   = if isReflCo co1_2a
201     then co2b
202     else opt_trans1 is co1_2a co2b
203
204 opt_trans2 _ co1 co2
205   = mkTransCo co1 co2
206
207 ------
208 -- Optimize coercions with a top-level use of transitivity.
209 opt_trans_rule :: InScopeSet -> NormalNonIdCo -> NormalNonIdCo -> Maybe NormalCo
210
211 -- push transitivity down through matching top-level constructors.
212 opt_trans_rule is in_co1@(TyConAppCo tc1 cos1) in_co2@(TyConAppCo tc2 cos2)
213   | tc1 == tc2 = fireTransRule "PushTyConApp" in_co1 in_co2 $
214                  TyConAppCo tc1 (opt_transList is cos1 cos2)
215
216 -- push transitivity through matching destructors
217 opt_trans_rule is in_co1@(NthCo d1 co1) in_co2@(NthCo d2 co2)
218   | d1 == d2
219   , co1 `compatible_co` co2
220   = fireTransRule "PushNth" in_co1 in_co2 $
221     mkNthCo d1 (opt_trans is co1 co2)
222
223 -- Push transitivity inside instantiation
224 opt_trans_rule is in_co1@(InstCo co1 ty1) in_co2@(InstCo co2 ty2)
225   | ty1 `eqType` ty2
226   , co1 `compatible_co` co2
227   = fireTransRule "TrPushInst" in_co1 in_co2 $
228     mkInstCo (opt_trans is co1 co2) ty1
229  
230 -- Push transitivity inside apply
231 opt_trans_rule is in_co1@(AppCo co1a co1b) in_co2@(AppCo co2a co2b)
232   = fireTransRule "TrPushApp" in_co1 in_co2 $
233     mkAppCo (opt_trans is co1a co2a) (opt_trans is co1b co2b)
234
235 opt_trans_rule is co1@(TyConAppCo tc cos1) co2
236   | Just cos2 <- etaTyConAppCo_maybe tc co2
237   = ASSERT( length cos1 == length cos2 )
238     fireTransRule "EtaCompL" co1 co2 $
239     TyConAppCo tc (opt_transList is cos1 cos2)
240
241 opt_trans_rule is co1 co2@(TyConAppCo tc cos2)
242   | Just cos1 <- etaTyConAppCo_maybe tc co1
243   = ASSERT( length cos1 == length cos2 )
244     fireTransRule "EtaCompR" co1 co2 $
245     TyConAppCo tc (opt_transList is cos1 cos2)
246
247 -- Push transitivity inside forall
248 opt_trans_rule is co1 co2
249   | Just (tv1,r1) <- splitForAllCo_maybe co1
250   , Just (tv2,r2) <- etaForAllCo_maybe co2
251   , let r2' = substCoWithTy is' tv2 (mkTyVarTy tv1) r2
252         is' = is `extendInScopeSet` tv1
253   = fireTransRule "EtaAllL" co1 co2 $
254     mkForAllCo tv1 (opt_trans2 is' r1 r2')
255
256   | Just (tv2,r2) <- splitForAllCo_maybe co2
257   , Just (tv1,r1) <- etaForAllCo_maybe co1
258   , let r1' = substCoWithTy is' tv1 (mkTyVarTy tv2) r1
259         is' = is `extendInScopeSet` tv2
260   = fireTransRule "EtaAllR" co1 co2 $
261     mkForAllCo tv1 (opt_trans2 is' r1' r2)
262
263 -- Push transitivity inside axioms
264 opt_trans_rule is co1 co2
265
266   -- TrPushAxR/TrPushSymAxR
267   | Just (sym, con, cos1) <- co1_is_axiom_maybe
268   , Just cos2 <- matchAxiom sym con co2
269   = fireTransRule "TrPushAxR" co1 co2 $
270     if sym 
271     then SymCo $ AxiomInstCo con (opt_transList is (map mkSymCo cos2) cos1)
272     else         AxiomInstCo con (opt_transList is cos1 cos2)
273
274   -- TrPushAxL/TrPushSymAxL
275   | Just (sym, con, cos2) <- co2_is_axiom_maybe
276   , Just cos1 <- matchAxiom (not sym) con co1
277   = fireTransRule "TrPushAxL" co1 co2 $
278     if sym 
279     then SymCo $ AxiomInstCo con (opt_transList is cos2 (map mkSymCo cos1))
280     else         AxiomInstCo con (opt_transList is cos1 cos2)
281
282   -- TrPushAxSym/TrPushSymAx
283   | Just (sym1, con1, cos1) <- co1_is_axiom_maybe
284   , Just (sym2, con2, cos2) <- co2_is_axiom_maybe
285   , con1 == con2
286   , sym1 == not sym2
287   , let qtvs = co_ax_tvs con1
288         lhs  = co_ax_lhs con1 
289         rhs  = co_ax_rhs con1 
290         pivot_tvs = exactTyVarsOfType (if sym2 then rhs else lhs)
291   , all (`elemVarSet` pivot_tvs) qtvs
292   = fireTransRule "TrPushAxSym" co1 co2 $
293     if sym2
294     then liftCoSubstWith qtvs (opt_transList is cos1 (map mkSymCo cos2)) lhs  -- TrPushAxSym
295     else liftCoSubstWith qtvs (opt_transList is (map mkSymCo cos1) cos2) rhs  -- TrPushSymAx
296   where
297     co1_is_axiom_maybe = isAxiom_maybe co1
298     co2_is_axiom_maybe = isAxiom_maybe co2
299
300 opt_trans_rule _ co1 co2        -- Identity rule
301   | Pair ty1 _ <- coercionKind co1
302   , Pair _ ty2 <- coercionKind co2
303   , ty1 `eqType` ty2
304   = fireTransRule "RedTypeDirRefl" co1 co2 $
305     Refl ty2
306
307 opt_trans_rule _ _ _ = Nothing
308
309 fireTransRule :: String -> Coercion -> Coercion -> Coercion -> Maybe Coercion
310 fireTransRule _rule _co1 _co2 res
311   = -- pprTrace ("Trans rule fired: " ++ _rule) (vcat [ppr _co1, ppr _co2, ppr res]) $
312     Just res
313
314 -----------
315 wrapSym :: Bool -> Coercion -> Coercion
316 wrapSym sym co | sym       = SymCo co
317                | otherwise = co
318
319 -----------
320 isAxiom_maybe :: Coercion -> Maybe (Bool, CoAxiom, [Coercion])
321 isAxiom_maybe (SymCo co) 
322   | Just (sym, con, cos) <- isAxiom_maybe co
323   = Just (not sym, con, cos)
324 isAxiom_maybe (AxiomInstCo con cos)
325   = Just (False, con, cos)
326 isAxiom_maybe _ = Nothing
327
328 matchAxiom :: Bool -- True = match LHS, False = match RHS
329            -> CoAxiom -> Coercion -> Maybe [Coercion]
330 -- If we succeed in matching, then *all the quantified type variables are bound*
331 -- E.g.   if tvs = [a,b], lhs/rhs = [b], we'll fail
332 matchAxiom sym (CoAxiom { co_ax_tvs = qtvs, co_ax_lhs = lhs, co_ax_rhs = rhs }) co
333   = case liftCoMatch (mkVarSet qtvs) (if sym then lhs else rhs) co of
334       Nothing    -> Nothing
335       Just subst -> allMaybes (map (liftCoSubstTyVar subst) qtvs)
336
337 -------------
338 compatible_co :: Coercion -> Coercion -> Bool
339 -- Check whether (co1 . co2) will be well-kinded
340 compatible_co co1 co2
341   = x1 `eqType` x2              
342   where
343     Pair _ x1 = coercionKind co1
344     Pair x2 _ = coercionKind co2
345
346 -------------
347 etaForAllCo_maybe :: Coercion -> Maybe (TyVar, Coercion)
348 -- Try to make the coercion be of form (forall tv. co)
349 etaForAllCo_maybe co
350   | Just (tv, r) <- splitForAllCo_maybe co
351   = Just (tv, r)
352
353   | Pair ty1 ty2  <- coercionKind co
354   , Just (tv1, _) <- splitForAllTy_maybe ty1
355   , Just (tv2, _) <- splitForAllTy_maybe ty2
356   , tyVarKind tv1 `eqKind` tyVarKind tv2
357   = Just (tv1, mkInstCo co (mkTyVarTy tv1))
358
359   | otherwise
360   = Nothing
361
362 etaTyConAppCo_maybe :: TyCon -> Coercion -> Maybe [Coercion]
363 -- If possible, split a coercion 
364 --       g :: T s1 .. sn ~ T t1 .. tn
365 -- into [ Nth 0 g :: s1~t1, ..., Nth (n-1) g :: sn~tn ] 
366 etaTyConAppCo_maybe tc (TyConAppCo tc2 cos2)
367   = ASSERT( tc == tc2 ) Just cos2
368
369 etaTyConAppCo_maybe tc co
370   | isDecomposableTyCon tc
371   , Pair ty1 ty2     <- coercionKind co
372   , Just (tc1, tys1) <- splitTyConApp_maybe ty1
373   , Just (tc2, tys2) <- splitTyConApp_maybe ty2
374   , tc1 == tc2
375   , let n = length tys1
376   = ASSERT( tc == tc1 ) 
377     ASSERT( n == length tys2 )
378     Just (decomposeCo n co)  
379     -- NB: n might be <> tyConArity tc
380     -- e.g.   data family T a :: * -> *
381     --        g :: T a b ~ T c d
382
383   | otherwise
384   = Nothing
385 \end{code}