configure: Bump minimum bootstrap GHC version to 7.8
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.11], [glasgow-haskell-bugs@haskell.org], [ghc])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands,
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42 FP_PROG_SORT
43
44 dnl ----------------------------------------------------------
45 FP_SETUP_PROJECT_VERSION
46
47 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
48 AC_SUBST([release], [1])
49
50 # First off, a distrib sanity check..
51 AC_CONFIG_SRCDIR([mk/config.mk.in])
52
53 dnl * We require autoconf version 2.60
54 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
55 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
56 dnl Using autoconf 2.59 started to give nonsense like this
57 dnl  #define SIZEOF_CHAR 0
58 dnl recently.
59 AC_PREREQ([2.60])
60
61 # -------------------------------------------------------------------------
62 # Prepare to generate the following header files
63 #
64 #
65 AC_CONFIG_HEADER(mk/config.h)
66
67 # No, semi-sadly, we don't do `--srcdir'...
68 if test x"$srcdir" != 'x.' ; then
69     echo "This configuration does not support the \`--srcdir' option.."
70     exit 1
71 fi
72
73 dnl --------------------------------------------------------------
74 dnl * Project specific configuration options
75 dnl --------------------------------------------------------------
76 dnl What follows is a bunch of options that can either be configured
77 dnl through command line options to the configure script or by
78 dnl supplying defns in the build tree's mk/build.mk. Having the option to
79 dnl use either is considered a Feature.
80
81 dnl ** What command to use to compile compiler sources ?
82 dnl --------------------------------------------------------------
83
84 AC_ARG_WITH([ghc],
85 [AC_HELP_STRING([--with-ghc=ARG],
86   [Use ARG as the path to GHC  [default=autodetect]])],
87   [WithGhc="$withval"],
88   [if test "$GHC" = ""; then
89     AC_PATH_PROG([GHC], [ghc])
90   fi
91   WithGhc="$GHC"])
92
93 dnl ** Tell the make system which OS we are using
94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
95 AC_SUBST(OSTYPE)
96
97 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
98 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
99                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
100         EnableBootstrapWithDevelSnaphost=YES,
101         EnableBootstrapWithDevelSnaphost=NO
102 )
103
104 if test "$WithGhc" != ""; then
105   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
106
107   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
108      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
109   fi
110
111   AC_SUBST(GhcVersion)dnl
112   AC_SUBST(GhcMajVersion)dnl
113   AC_SUBST(GhcMinVersion)dnl
114   AC_SUBST(GhcPatchLevel)dnl
115   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
116   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
117
118   BOOTSTRAPPING_GHC_INFO_FIELD([OS_STAGE0],[target os])
119   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
120   dnl ToDo, once "ld command" is reliably available.
121   dnl Then, we can remove the LD_STAGE0 hack in mk/build-package-date.mk
122   dnl BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
123   if test "x$OS_STAGE0" != "xOSDarwin"; then
124     BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
125     BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
126     BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
127   else
128     AR_STAGE0='$(AR)'
129     AR_OPTS_STAGE0='$(AR_OPTS)'
130     ArSupportsAtFile_STAGE0='$(ArSupportsAtFile)'
131   fi
132 fi
133
134 dnl ** Must have GHC to build GHC
135 if test "$WithGhc" = ""
136 then
137     AC_MSG_ERROR([GHC is required.])
138 fi
139 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.8],
140     [AC_MSG_ERROR([GHC version 7.8 or later is required to compile GHC.])])
141
142 if test `expr $GhcMinVersion % 2` = "1"
143 then
144     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
145     then
146         AC_MSG_ERROR([
147      $WithGhc is a development snapshot of GHC, version $GhcVersion.
148      Bootstrapping using this version of GHC is not supported, and may not
149      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
150      or --with-ghc to specify a different GHC to use.])
151     fi
152 fi
153
154 GHC_PACKAGE_DB_FLAG=package-db
155 AC_SUBST(GHC_PACKAGE_DB_FLAG)
156
157 # GHC 7.7+ needs -fcmm-sink when compiling Parser.hs. See #8182
158 FP_COMPARE_VERSIONS([$GhcVersion],[-gt],[7.7],
159                     CMM_SINK_BOOTSTRAP_IS_NEEDED=YES,
160                     CMM_SINK_BOOTSTRAP_IS_NEEDED=NO)
161 AC_SUBST(CMM_SINK_BOOTSTRAP_IS_NEEDED)
162
163 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.9],
164                     SUPPORTS_PACKAGE_KEY=NO,
165                     SUPPORTS_PACKAGE_KEY=YES)
166 AC_SUBST(SUPPORTS_PACKAGE_KEY)
167
168 # GHC is passed to Cabal, so we need a native path
169 if test "${WithGhc}" != ""
170 then
171     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
172
173     if test "$ghc_host_os" = "mingw32"
174     then
175         if test "${OSTYPE}" = "msys"
176         then
177             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
178         else
179             # Canonicalise to <drive>:/path/to/ghc
180             WithGhc=`cygpath -m "${WithGhc}"`
181         fi
182         echo "GHC path canonicalised to: ${WithGhc}"
183     fi
184 fi
185 AC_SUBST([WithGhc])
186
187 dnl ** Without optimization some INLINE trickery fails for GHCi
188 SRC_CC_OPTS="-O"
189
190 dnl--------------------------------------------------------------------
191 dnl * Choose host(/target/build) platform
192 dnl--------------------------------------------------------------------
193 dnl If we aren't explicitly told what values to use with configure flags,
194 dnl we ask the bootstrapping compiler what platform it is for
195
196 if test "${WithGhc}" != ""
197 then
198         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
199         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
200         if test "$bootstrap_host" != "$bootstrap_target"
201         then
202                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
203         fi
204 fi
205
206 # We have to run these unconditionally, but we may discard their
207 # results in the following code
208 AC_CANONICAL_BUILD
209 AC_CANONICAL_HOST
210 AC_CANONICAL_TARGET
211
212 FPTOOLS_SET_PLATFORM_VARS
213
214 # Verify that the installed (bootstrap) GHC is capable of generating
215 # code for the requested build platform.
216 if test "$BuildPlatform" != "$bootstrap_target"
217 then
218     echo "This GHC (${WithGhc}) does not generate code for the build platform"
219     echo "   GHC target platform    : $bootstrap_target"
220     echo "   Desired build platform : $BuildPlatform"
221     exit 1
222 fi
223
224 # Testing if we shall enable shared libs support on Solaris.
225 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
226
227 SOLARIS_BROKEN_SHLD=NO
228
229 case $host in
230      i386-*-solaris2)
231      # here we go with the test
232      MINOR=`uname -r|cut -d '.' -f 2-`
233      if test "$MINOR" -lt "11"; then
234          SOLARIS_BROKEN_SHLD=YES
235      fi
236      ;;
237 esac
238
239 AC_SUBST(SOLARIS_BROKEN_SHLD)
240
241 dnl ** Do an unregisterised build?
242 dnl --------------------------------------------------------------
243 case "$HostArch" in
244     i386|x86_64|powerpc|powerpc64|powerpc64le|arm)
245         UnregisterisedDefault=NO
246         ;;
247     *)
248         UnregisterisedDefault=YES
249         ;;
250 esac
251 AC_ARG_ENABLE(unregisterised,
252 [AC_HELP_STRING([--enable-unregisterised],
253 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
254 [ if test x"$enableval" = x"yes"; then
255         Unregisterised=YES
256   else
257         Unregisterised=NO
258   fi
259 ],
260 [Unregisterised="$UnregisterisedDefault"]
261 )
262 AC_SUBST(Unregisterised)
263
264 AC_ARG_WITH(hc,
265 [AC_HELP_STRING([--with-hc=ARG],
266         [Use ARG as the path to the compiler for compiling ordinary
267          Haskell code  (default= value of --with-ghc)])],
268 [WithHc="$withval"],
269 [WithHc=$WithGhc]
270 )
271 AC_SUBST(WithHc)
272
273 # This uses GHC, so put it after the "GHC is required" check above:
274 FP_INTREE_GHC_PWD
275 FP_FIND_ROOT
276
277 if test "$HostOS" = "mingw32"
278 then
279     test -d inplace || mkdir inplace
280
281     if test "$HostArch" = "i386"
282     then
283         # NB. If you update the tarballs to a new version of gcc, don't
284         # forget to tweak the paths in driver/gcc/gcc.c.
285         if ! test -d inplace/mingw ||
286              test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
287              test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
288              test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
289              test inplace/mingw -ot ghc-tarballs/mingw/libgcc*.tar.gz      ||
290              test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
291              test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
292              test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
293              test inplace/mingw -ot ghc-tarballs/mingw/libstdc*.tar.lzma   ||
294              test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
295              test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
296              test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
297         then
298             AC_MSG_NOTICE([Making in-tree mingw tree])
299             rm -rf inplace/mingw
300             mkdir inplace/mingw
301             (
302                 cd inplace/mingw &&
303                 tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
304                 tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
305                 tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
306                 tar --lzma -xf ../../ghc-tarballs/mingw/libgcc*.tar.lzma    &&
307                 tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
308                 tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
309                 tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
310                 tar --lzma -xf ../../ghc-tarballs/mingw/libstdc*.tar.lzma   &&
311                 tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
312                 tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
313                 tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
314                 mv bin/gcc.exe bin/realgcc.exe
315             )
316             PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
317             AC_MSG_NOTICE([In-tree mingw tree created])
318         fi
319     else
320         # NB. If you update the tarballs to a new version of gcc, don't
321         # forget to tweak the paths in driver/gcc/gcc.c.
322         if ! test -d inplace/mingw ||
323              test inplace/mingw -ot ghc-tarballs/mingw64/*.tar.bz2
324         then
325             AC_MSG_NOTICE([Making in-tree mingw tree])
326             rm -rf inplace/mingw
327             mkdir inplace/mingw
328             (
329                 cd inplace/mingw &&
330                 tar -jxf ../../ghc-tarballs/mingw64/*.tar.bz2
331             )
332             AC_MSG_NOTICE([In-tree mingw tree created])
333         fi
334     fi
335
336     mingwbin="$hardtop/inplace/mingw/bin/"
337     CC="${mingwbin}gcc.exe"
338     LD="${mingwbin}ld.exe"
339     NM="${mingwbin}nm.exe"
340     RANLIB="${mingwbin}ranlib.exe"
341     OBJDUMP="${mingwbin}objdump.exe"
342     fp_prog_ar="${mingwbin}ar.exe"
343
344     if ! test -d inplace/perl ||
345          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
346     then
347         AC_MSG_NOTICE([Making in-tree perl tree])
348         rm -rf inplace/perl
349         mkdir inplace/perl
350         (
351             cd inplace/perl &&
352             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
353         )
354         AC_MSG_NOTICE([In-tree perl tree created])
355     fi
356 fi
357
358 FP_ICONV
359 FP_GMP
360 FP_CURSES
361
362 XCODE_VERSION()
363
364 SplitObjsBroken=NO
365 if test "$TargetOS_CPP" = "darwin"
366 then
367     # Split objects is broken (#4013) with XCode < 3.2
368     if test "$XCodeVersion1" -lt 3
369     then
370         SplitObjsBroken=YES
371     else
372         if test "$XCodeVersion1" -eq 3
373         then
374             if test "$XCodeVersion2" -lt 2
375             then
376                 SplitObjsBroken=YES
377             fi
378         fi
379     fi
380 fi
381 AC_SUBST([SplitObjsBroken])
382
383 dnl ** Building a cross compiler?
384 dnl --------------------------------------------------------------
385 CrossCompiling=NO
386 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
387 if test "$target" != "$host" ; then
388     CrossCompiling=YES
389     cross_compiling=yes   # This tells configure that it can accept just 'target',
390                           # otherwise you get
391                           #   configure: error: cannot run C compiled programs.
392                           #   If you meant to cross compile, use `--host'.
393 fi
394 if test "$build" != "$host" ; then
395    AC_MSG_ERROR([
396 You've selected:
397
398   BUILD:  $build   (the architecture we're building on)
399   HOST:   $host    (the architecture the compiler we're building will execute on)
400   TARGET: $target  (the architecture the compiler we're building will produce code for)
401
402 BUILD must equal HOST; that is, we do not support building GHC itself
403 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
404 1 will be a cross-compiler, and stage 2 will be the cross-compiled
405 GHC.
406 ])
407 fi
408 if test "$CrossCompiling" = "YES"
409 then
410   CrossCompilePrefix="${target}-"
411 else
412   CrossCompilePrefix=""
413 fi
414 TargetPlatformFull="${target}"
415 AC_SUBST(CrossCompiling)
416 AC_SUBST(CrossCompilePrefix)
417 AC_SUBST(TargetPlatformFull)
418
419 dnl ** Which gcc to use?
420 dnl --------------------------------------------------------------
421 FIND_GCC([WhatGccIsCalled], [gcc], [gcc])
422 CC="$WhatGccIsCalled"
423 export CC
424
425 # If --with-gcc was used, and we're not cross-compiling, then it also
426 # applies to the stage0 compiler.
427 MAYBE_OVERRIDE_STAGE0([gcc],[CC_STAGE0])
428 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
429
430 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
431 AC_PROG_CPP
432
433 # --with-hs-cpp/--with-hs-cpp-flags
434 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
435 AC_SUBST([HaskellCPPCmd])
436 AC_SUBST([HaskellCPPArgs])
437
438 dnl ** Which ld to use?
439 dnl --------------------------------------------------------------
440 FIND_LD([LdCmd])
441 AC_SUBST([LdCmd])
442
443 dnl ** Which nm to use?
444 dnl --------------------------------------------------------------
445 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
446 NmCmd="$NM"
447 AC_SUBST([NmCmd])
448
449 dnl ** Which ar to use?
450 dnl --------------------------------------------------------------
451 FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
452 ArCmd="$AR"
453 fp_prog_ar="$AR"
454 AC_SUBST([ArCmd])
455
456 dnl ** Which ranlib to use?
457 dnl --------------------------------------------------------------
458 FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
459 RanlibCmd="$RANLIB"
460 RANLIB="$RanlibCmd"
461
462
463 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
464 case $HostOS_CPP in
465 cygwin32|mingw32)
466     dnl ** Which objdump to use?
467     dnl --------------------------------------------------------------
468     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
469     ObjdumpCmd="$OBJDUMP"
470     AC_SUBST([ObjdumpCmd])
471     ;;
472 esac
473
474 # Here is where we re-target which specific version of the LLVM
475 # tools we are looking for. In the past, GHC supported a number of
476 # versions of LLVM simultaneously, but that stopped working around
477 # 3.5/3.6 release of LLVM.
478 LlvmVersion=3.6
479 AC_SUBST([LlvmVersion])
480
481 dnl ** Which LLVM llc to use?
482 dnl --------------------------------------------------------------
483 FIND_LLVM_PROG([LLC], [llc], [llc], [$LlvmVersion])
484 LlcCmd="$LLC"
485 AC_SUBST([LlcCmd])
486
487 dnl ** Which LLVM opt to use?
488 dnl --------------------------------------------------------------
489 FIND_LLVM_PROG([OPT], [opt], [opt], [$LlvmVersion])
490 OptCmd="$OPT"
491 AC_SUBST([OptCmd])
492
493 dnl --------------------------------------------------------------
494 dnl End of configure script option section
495 dnl --------------------------------------------------------------
496
497
498 dnl --------------------------------------------------------------
499 dnl * General configuration checks
500 dnl --------------------------------------------------------------
501
502 dnl ** Bug 9439: Some GHC 7.8 releases had broken LLVM code generator.
503 dnl Unfortunately we don't know whether the user is going to request a
504 dnl build with the LLVM backend as this is only given in build.mk.
505 dnl
506 dnl Instead, we try to do as much work as possible here, checking
507 dnl whether -fllvm is the stage 0 compiler's default. If so we
508 dnl fail. If not, we check whether -fllvm is affected explicitly and
509 dnl if so set a flag. The build system will later check this flag
510 dnl after the desired build flags are known.
511
512 dnl This problem is further complicated by the fact that the llvm
513 dnl version used by the bootstrap compiler may be different from the
514 dnl version we arre trying to compile GHC against. Therefore, we need
515 dnl to find the boostrap compiler's `settings` file then check to see
516 dnl if the `opt` and `llc` command strings are non-empty and if these
517 dnl programs exist. Only if they exist to we test for bug #9439.
518
519 FIND_GHC_BOOTSTRAP_PROG([BootstrapLlcCmd], [${WithGhc}], "LLVM llc command")
520 FIND_GHC_BOOTSTRAP_PROG([BootstrapOptCmd], [${WithGhc}], "LLVM opt command")
521
522 if test -n "$BootstrapLlcCmd" && test -n "$BootstrapOptCmd"
523 then
524     AC_MSG_CHECKING(whether bootstrap compiler is affected by bug 9439)
525     echo "main = putStrLn \"%function\"" > conftestghc.hs
526
527     # Check whether LLVM backend is default for this platform
528     "${WithGhc}" -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" conftestghc.hs 2>&1 >/dev/null
529     res=`./conftestghc`
530     if test "x$res" = "x%object"
531     then
532         AC_MSG_RESULT(yes)
533         echo "Buggy bootstrap compiler"
534         echo ""
535         echo "The stage 0 compiler $WithGhc is affected by GHC Bug \#9439"
536         echo "and therefore will miscompile the LLVM backend if -fllvm is"
537         echo "used."
538         echo
539         echo "Please use another bootstrap compiler"
540         exit 1
541     fi
542
543     # -fllvm is not the default, but set a flag so the Makefile can check
544     # -for it in the build flags later on
545     "${WithGhc}" -fforce-recomp -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" -fllvm conftestghc.hs 2>&1 >/dev/null
546     if test $? = 0
547     then
548         res=`./conftestghc`
549         if test "x$res" = "x%object"
550         then
551             AC_MSG_RESULT(yes)
552             GHC_LLVM_AFFECTED_BY_9439=1
553         elif test "x$res" = "x%function"
554         then
555             AC_MSG_RESULT(no)
556             GHC_LLVM_AFFECTED_BY_9439=0
557         else
558             AC_MSG_WARN(unexpected output $res)
559         fi
560     else
561         AC_MSG_RESULT(failed to compile, assuming no)
562     fi
563 fi
564 AC_SUBST([GHC_LLVM_AFFECTED_BY_9439])
565
566 dnl ** Can the unix package be built?
567 dnl --------------------------------------------------------------
568
569 if test "$TargetOS" = "mingw32"
570 then
571     GhcLibsWithUnix=NO
572 else
573     GhcLibsWithUnix=YES
574 fi
575 AC_SUBST([GhcLibsWithUnix])
576
577 dnl ** does #! work?
578 AC_SYS_INTERPRETER()
579
580 dnl ** look for `perl'
581 case $HostOS_CPP in
582 cygwin32|mingw32)
583     PerlCmd=$hardtop/inplace/perl/perl
584     ;;
585 *)
586     AC_PATH_PROG(PerlCmd,perl)
587     if test -z "$PerlCmd"
588     then
589         echo "You must install perl before you can continue"
590         echo "Perhaps it is already installed, but not in your PATH?"
591         exit 1
592     else
593         FPTOOLS_CHECK_PERL_VERSION
594     fi
595     ;;
596 esac
597
598 dnl ** look for GCC and find out which version
599 dnl     Figure out which C compiler to use.  Gcc is preferred.
600 dnl     If gcc, make sure it's at least 3.0
601 dnl
602 FP_GCC_VERSION
603
604 dnl ** look to see if we have a C compiler using an llvm back end.
605 dnl
606 FP_CC_LLVM_BACKEND
607
608 FP_PROG_LD_IS_GNU
609 FP_PROG_LD_BUILD_ID
610 FP_PROG_LD_NO_COMPACT_UNWIND
611 FP_PROG_LD_FILELIST
612
613
614 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
615 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
616 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
617 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
618 # Stage 3 won't be supported by cross-compilation
619
620 FP_GCC_EXTRA_FLAGS
621
622 AC_SUBST(CONF_CC_OPTS_STAGE0)
623 AC_SUBST(CONF_CC_OPTS_STAGE1)
624 AC_SUBST(CONF_CC_OPTS_STAGE2)
625 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
626 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
627 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
628 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
629 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
630 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
631 AC_SUBST(CONF_CPP_OPTS_STAGE0)
632 AC_SUBST(CONF_CPP_OPTS_STAGE1)
633 AC_SUBST(CONF_CPP_OPTS_STAGE2)
634
635 dnl ** Set up the variables for the platform in the settings file.
636 dnl May need to use gcc to find platform details.
637 dnl --------------------------------------------------------------
638 FPTOOLS_SET_HASKELL_PLATFORM_VARS
639
640 dnl ** figure out how to do context diffs
641 FP_PROG_CONTEXT_DIFF
642
643 dnl Let's make sure install-sh is executable here.  If we got it from
644 dnl a darcs repo, it might not be (see bug #978).
645 chmod +x install-sh
646 dnl ** figure out how to do a BSD-ish install
647 AC_PROG_INSTALL
648
649 dnl ** how to invoke `ar' and `ranlib'
650 FP_PROG_AR_SUPPORTS_ATFILE
651 FP_PROG_AR_NEEDS_RANLIB
652
653 dnl ** Check to see whether ln -s works
654 AC_PROG_LN_S
655
656 FP_SETTINGS
657
658 dnl ** Find the path to sed
659 AC_PATH_PROGS(SedCmd,gsed sed,sed)
660
661
662 dnl ** check for time command
663 AC_PATH_PROG(TimeCmd,time)
664
665 dnl ** check for tar
666 dnl   if GNU tar is named gtar, look for it first.
667 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
668
669 dnl ** check for patch
670 dnl if GNU patch is named gpatch, look for it first
671 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
672
673 dnl ** check for dtrace (currently only implemented for Mac OS X)
674 HaveDtrace=NO
675 AC_PATH_PROG(DtraceCmd,dtrace)
676 if test -n "$DtraceCmd"; then
677   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
678     HaveDtrace=YES
679   fi
680 fi
681 AC_SUBST(HaveDtrace)
682
683 AC_PATH_PROG(HSCOLOUR,HsColour)
684 # HsColour is passed to Cabal, so we need a native path
685 if test "$HostOS"      = "mingw32" && \
686    test "${OSTYPE}"   != "msys"    && \
687    test "${HSCOLOUR}" != ""
688 then
689     # Canonicalise to <drive>:/path/to/gcc
690     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
691 fi
692
693 dnl ** check for DocBook toolchain
694 FP_CHECK_DOCBOOK_DTD
695 FP_DOCBOOK_XSL
696 FP_PROG_DBLATEX
697
698 dnl ** check for ghc-pkg command
699 FP_PROG_GHC_PKG
700
701 dnl ** check for installed happy binary + version
702 FPTOOLS_HAPPY
703
704 dnl ** check for installed alex binary + version
705 FPTOOLS_ALEX
706
707 dnl --------------------------------------------------
708 dnl ### program checking section ends here ###
709 dnl --------------------------------------------------
710
711 dnl --------------------------------------------------
712 dnl * Platform header file and syscall feature tests
713 dnl ### checking the state of the local header files and syscalls ###
714
715 dnl ** check for full ANSI header (.h) files
716 AC_HEADER_STDC
717
718 dnl ** Enable large file support.  NB. do this before testing the type of
719 dnl    off_t, because it will affect the result of that test.
720 AC_SYS_LARGEFILE
721
722 dnl ** check for specific header (.h) files that we are interested in
723 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
724
725 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
726 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
727 [[#if HAVE_SYS_PARAM_H
728 # include <sys/param.h>
729 #endif
730 ]])
731
732 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
733 AC_HEADER_TIME
734
735 dnl ** do we have long longs?
736 AC_CHECK_TYPES([long long])
737
738 dnl ** what are the sizes of various types
739 AC_CHECK_SIZEOF(char,               1)
740 AC_CHECK_SIZEOF(double,             8)
741 AC_CHECK_SIZEOF(float,              4)
742 AC_CHECK_SIZEOF(int,                4)
743 AC_CHECK_SIZEOF(long,               4)
744 if test "$ac_cv_type_long_long" = yes; then
745 AC_CHECK_SIZEOF(long long,          8)
746 fi
747 AC_CHECK_SIZEOF(short,              2)
748 AC_CHECK_SIZEOF(unsigned char,      1)
749 AC_CHECK_SIZEOF(unsigned int,       4)
750 AC_CHECK_SIZEOF(unsigned long,      4)
751 if test "$ac_cv_type_long_long" = yes; then
752 AC_CHECK_SIZEOF(unsigned long long, 8)
753 fi
754 AC_CHECK_SIZEOF(unsigned short,     2)
755 AC_CHECK_SIZEOF(void *,             4)
756
757 dnl for use in settings.in
758 WordSize=$ac_cv_sizeof_void_p
759 AC_SUBST(WordSize)
760
761 dnl ** what are alignment constraints on various types
762 FP_CHECK_ALIGNMENT(char)
763 FP_CHECK_ALIGNMENT(double)
764 FP_CHECK_ALIGNMENT(float)
765 FP_CHECK_ALIGNMENT(int)
766 FP_CHECK_ALIGNMENT(long)
767 if test "$ac_cv_type_long_long" = yes; then
768 FP_CHECK_ALIGNMENT(long long)
769 fi
770 FP_CHECK_ALIGNMENT(short)
771 FP_CHECK_ALIGNMENT(unsigned char)
772 FP_CHECK_ALIGNMENT(unsigned int)
773 FP_CHECK_ALIGNMENT(unsigned long)
774 if test "$ac_cv_type_long_long" = yes; then
775 FP_CHECK_ALIGNMENT(unsigned long long)
776 fi
777 FP_CHECK_ALIGNMENT(unsigned short)
778 FP_CHECK_ALIGNMENT(void *)
779
780 FP_CHECK_FUNC([WinExec],
781   [@%:@include <windows.h>], [WinExec("",0)])
782
783 FP_CHECK_FUNC([GetModuleFileName],
784   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
785
786 dnl ** check for more functions
787 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
788 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
789
790 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
791 dnl ** _POSIX_C_SOURCE is defined
792 AC_CHECK_DECLS([ctime_r], , ,
793 [#define _POSIX_SOURCE 1
794 #define _POSIX_C_SOURCE 199506L
795 #include <time.h>])
796
797 dnl ** check for mingwex library
798 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
799 AC_SUBST(HaveLibMingwEx)
800
801 if test $HaveLibMingwEx = YES ; then
802   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
803 fi
804
805 dnl ** check for math library
806 dnl    Keep that check as early as possible.
807 dnl    as we need to know whether we need libm
808 dnl    for math functions or not
809 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
810 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
811 if test $HaveLibM = YES
812 then
813   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
814 fi
815
816 FP_BFD_SUPPORT
817
818 dnl ################################################################
819 dnl Check for libraries
820 dnl ################################################################
821
822 # system libffi
823
824 AC_ARG_WITH([system-libffi],
825 [AC_HELP_STRING([--with-system-libffi],
826   [Use system provided libffi for RTS [default=no]])
827 ])
828
829 AS_IF([test "x$with_system_libffi" = "xyes"],
830   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
831 )
832
833
834 AC_SUBST(UseSystemLibFFI)
835
836 AC_ARG_WITH([ffi-includes],
837 [AC_HELP_STRING([--with-ffi-includes=ARG],
838   [Find includes for libffi in ARG [default=system default]])
839 ],
840 [
841  if test "x$UseSystemLibFFI" != "xYES"; then
842     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
843  else
844     FFIIncludeDir="$withval"
845     LIBFFI_CFLAGS="-I$withval"
846  fi
847 ])
848
849 AC_SUBST(FFIIncludeDir)
850
851 AC_ARG_WITH([ffi-libraries],
852 [AC_HELP_STRING([--with-ffi-libraries=ARG],
853   [Find libffi in ARG [default=system default]])
854 ],
855 [
856  if test "x$UseSystemLibFFI" != "xYES"; then
857     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
858  else
859     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
860  fi
861 ])
862
863 AC_SUBST(FFILibDir)
864
865 AS_IF([test "$UseSystemLibFFI" = "YES"], [
866  CFLAGS2="$CFLAGS"
867  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
868  LDFLAGS2="$LDFLAGS"
869  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
870  AC_CHECK_LIB(ffi, ffi_call,
871   [AC_CHECK_HEADERS([ffi.h], [break], [])
872    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
873   [AC_MSG_ERROR([Cannot find system libffi])])
874  CFLAGS="$CFLAGS2"
875  LDFLAGS="$LDFLAGS2"
876 ])
877
878 dnl ** check whether we need -ldl to get dlopen()
879 AC_CHECK_LIB(dl, dlopen)
880
881 dnl --------------------------------------------------
882 dnl * Miscellaneous feature tests
883 dnl --------------------------------------------------
884
885 dnl ** can we get alloca?
886 AC_FUNC_ALLOCA
887
888 dnl ** working vfork?
889 AC_FUNC_FORK
890
891 dnl ** determine whether or not const works
892 AC_C_CONST
893
894 dnl ** are we big endian?
895 AC_C_BIGENDIAN
896 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
897
898 dnl ** check for leading underscores in symbol names
899 FP_LEADING_UNDERSCORE
900
901 FP_VISIBILITY_HIDDEN
902
903 dnl ** check for librt
904 AC_CHECK_LIB(rt, clock_gettime)
905 AC_CHECK_FUNCS(clock_gettime timer_settime)
906 FP_CHECK_TIMER_CREATE
907
908 dnl ** check for Apple's "interesting" long double compatibility scheme
909 AC_MSG_CHECKING(for printf\$LDBLStub)
910 AC_TRY_LINK_FUNC(printf\$LDBLStub,
911     [
912         AC_MSG_RESULT(yes)
913         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
914             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
915     ],
916     [
917         AC_MSG_RESULT(no)
918         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
919             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
920     ])
921
922 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
923 dnl    a different single-argument version.
924 AC_CHECK_LIB(pthread, pthread_setname_np)
925 AC_MSG_CHECKING(for pthread_setname_np)
926 AC_TRY_LINK(
927 [
928 #define _GNU_SOURCE
929 #include <pthread.h>
930 ],
931 [pthread_setname_np(pthread_self(), "name");],
932     AC_MSG_RESULT(yes)
933     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
934       [Define to 1 if you have the glibc version of pthread_setname_np]),
935     AC_MSG_RESULT(no)
936 )
937
938 dnl ** check for eventfd which is needed by the I/O manager
939 AC_CHECK_HEADERS([sys/eventfd.h])
940 AC_CHECK_FUNCS([eventfd])
941
942 dnl ** Check for __thread support in the compiler
943 AC_MSG_CHECKING(for __thread support)
944 AC_COMPILE_IFELSE(
945   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
946   [
947    AC_MSG_RESULT(yes)
948    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
949   ],
950   [
951    AC_MSG_RESULT(no)
952    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
953   ])
954
955
956 dnl ** checking for PAPI
957 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
958 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
959 AC_SUBST(HavePapiLib)
960 AC_SUBST(HavePapiHeader)
961
962 AC_CHECK_FUNCS(__mingw_vfprintf)
963
964 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
965    HavePapi=YES
966 else
967    HavePapi=NO
968 fi
969 AC_SUBST(HavePapi)
970
971 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
972    test "$XsltprocCmd" = ""
973 then
974     BUILD_DOCBOOK_HTML=NO
975 else
976     BUILD_DOCBOOK_HTML=YES
977 fi
978 AC_SUBST(BUILD_DOCBOOK_HTML)
979
980 if test "$DblatexCmd" = ""
981 then
982     BUILD_DOCBOOK_PS=NO
983     BUILD_DOCBOOK_PDF=NO
984 else
985     BUILD_DOCBOOK_PS=YES
986     BUILD_DOCBOOK_PDF=YES
987 fi
988 AC_SUBST(BUILD_DOCBOOK_PS)
989 AC_SUBST(BUILD_DOCBOOK_PDF)
990
991 LIBRARY_VERSION(base)
992 LIBRARY_VERSION(Cabal, Cabal/Cabal)
993 LIBRARY_VERSION(ghc-prim)
994 LIBRARY_ghc_VERSION="$ProjectVersion"
995 AC_SUBST(LIBRARY_ghc_VERSION)
996
997 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
998    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
999 fi
1000
1001 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal settings docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/configure.ac])
1002 AC_OUTPUT
1003
1004 # We got caught by
1005 #     http://savannah.gnu.org/bugs/index.php?1516
1006 #     $(eval ...) inside conditionals causes errors
1007 # with make 3.80, so warn the user if it looks like they're about to
1008 # try to use it.
1009 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1010 checkMake380() {
1011     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
1012     then
1013         echo
1014         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
1015         echo "This version cannot be used to build GHC."
1016         echo "Please use GNU make >= 3.81."
1017     fi
1018 }
1019
1020 checkMake380 make
1021 checkMake380 gmake
1022
1023 echo ["
1024 ----------------------------------------------------------------------
1025 Configure completed successfully.
1026
1027    Building GHC version  : $ProjectVersion
1028           Git commit id  : $ProjectGitCommitId
1029
1030    Build platform        : $BuildPlatform
1031    Host platform         : $HostPlatform
1032    Target platform       : $TargetPlatform
1033 "]
1034
1035 echo ["\
1036    Bootstrapping using   : $WithGhc
1037       which is version   : $GhcVersion
1038 "]
1039
1040 if test "x$CC_LLVM_BACKEND" = "x1"; then
1041     if test "x$CC_CLANG_BACKEND" = "x1"; then
1042         CompilerName="clang        "
1043     else
1044         CompilerName="llvm-gcc     "
1045     fi
1046 else
1047     CompilerName="gcc          "
1048 fi
1049
1050 echo ["\
1051    Using $CompilerName       : $WhatGccIsCalled
1052       which is version       : $GccVersion
1053    Building a cross compiler : $CrossCompiling
1054    hs-cpp       : $HaskellCPPCmd
1055    hs-cpp-flags : $HaskellCPPArgs
1056    ld           : $LdCmd
1057    Happy        : $HappyCmd ($HappyVersion)
1058    Alex         : $AlexCmd ($AlexVersion)
1059    Perl         : $PerlCmd
1060    dblatex      : $DblatexCmd
1061    xsltproc     : $XsltprocCmd
1062
1063    Using LLVM tools
1064       llc   : $LlcCmd
1065       opt   : $OptCmd"]
1066
1067 if test "$HSCOLOUR" = ""; then
1068 echo ["
1069    HsColour was not found; documentation will not contain source links
1070 "]
1071 else
1072 echo ["\
1073    HsColour : $HSCOLOUR
1074 "]
1075 fi
1076
1077 echo ["\
1078    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
1079    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
1080    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
1081
1082 echo ["----------------------------------------------------------------------
1083 "]
1084
1085 echo "\
1086 For a standard build of GHC (fully optimised with profiling), type (g)make.
1087
1088 To make changes to the default build configuration, copy the file
1089 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1090
1091 For more information on how to configure your GHC build, see
1092    http://ghc.haskell.org/trac/ghc/wiki/Building
1093 "