95e172c018574d77b9cb5ac1d3343bcbd9102583
[ghc.git] / compiler / typecheck / TcTyClsDecls.lhs
1 %
2 % (c) The AQUA Project, Glasgow University, 1996-1998
3 %
4 \section[TcTyClsDecls]{Typecheck type and class declarations}
5
6 \begin{code}
7 module TcTyClsDecls (
8         tcTyAndClassDecls, tcIdxTyInstDecl
9     ) where
10
11 #include "HsVersions.h"
12
13 import HsSyn            ( TyClDecl(..),  HsConDetails(..), HsTyVarBndr(..),
14                           ConDecl(..),   Sig(..), NewOrData(..), ResType(..),
15                           tyClDeclTyVars, isSynDecl, isClassDecl, isIdxTyDecl,
16                           isKindSigDecl, hsConArgs, LTyClDecl, tcdName,
17                           hsTyVarName, LHsTyVarBndr, LHsType, HsType(..),
18                           mkHsAppTy
19                         )
20 import HsTypes          ( HsBang(..), getBangStrictness, hsLTyVarNames )
21 import BasicTypes       ( RecFlag(..), StrictnessMark(..) )
22 import HscTypes         ( implicitTyThings, ModDetails )
23 import BuildTyCl        ( buildClass, buildAlgTyCon, buildSynTyCon, buildDataCon,
24                           mkDataTyConRhs, mkNewTyConRhs )
25 import TcRnMonad
26 import TcEnv            ( TyThing(..), 
27                           tcLookupLocated, tcLookupLocatedGlobal, 
28                           tcExtendGlobalEnv, tcExtendKindEnv, tcExtendKindEnvTvs,
29                           tcExtendRecEnv, tcLookupTyVar, InstInfo )
30 import TcTyDecls        ( calcRecFlags, calcClassCycles, calcSynCycles )
31 import TcClassDcl       ( tcClassSigs, tcAddDeclCtxt )
32 import TcHsType         ( kcHsTyVars, kcHsLiftedSigType, kcHsType, 
33                           kcHsContext, tcTyVarBndrs, tcHsKindedType, tcHsKindedContext,
34                           kcHsSigType, tcHsBangType, tcLHsConResTy,
35                           tcDataKindSig, kcCheckHsType )
36 import TcMType          ( newKindVar, checkValidTheta, checkValidType, 
37                           -- checkFreeness, 
38                           UserTypeCtxt(..), SourceTyCtxt(..) ) 
39 import TcType           ( TcKind, TcType, Type, tyVarsOfType, mkPhiTy,
40                           mkArrowKind, liftedTypeKind, mkTyVarTys, 
41                           tcSplitSigmaTy, tcEqTypes, tcGetTyVar_maybe )
42 import Type             ( PredType(..), splitTyConApp_maybe, mkTyVarTy,
43                           newTyConInstRhs, isLiftedTypeKind, Kind
44                           -- pprParendType, pprThetaArrow
45                         )
46 import Generics         ( validGenericMethodType, canDoGenerics )
47 import Class            ( Class, className, classTyCon, DefMeth(..), classBigSig, classTyVars )
48 import TyCon            ( TyCon, AlgTyConRhs( AbstractTyCon, OpenDataTyCon, 
49                                               OpenNewTyCon ), 
50                           SynTyConRhs( OpenSynTyCon, SynonymTyCon ),
51                           tyConDataCons, mkForeignTyCon, isProductTyCon,
52                           isRecursiveTyCon, isOpenTyCon,
53                           tyConStupidTheta, synTyConRhs, isSynTyCon, tyConName,
54                           isNewTyCon, isDataTyCon, tyConKind, 
55                           setTyConArgPoss )
56 import DataCon          ( DataCon, dataConUserType, dataConName, 
57                           dataConFieldLabels, dataConTyCon, dataConAllTyVars,
58                           dataConFieldType, dataConResTys )
59 import Var              ( TyVar, idType, idName )
60 import VarSet           ( elemVarSet, mkVarSet )
61 import Name             ( Name, getSrcLoc )
62 import Outputable
63 import Maybe            ( isJust, fromJust, isNothing, catMaybes )
64 import Maybes           ( expectJust )
65 import Monad            ( unless )
66 import Unify            ( tcMatchTys, tcMatchTyX )
67 import Util             ( zipLazy, isSingleton, notNull, sortLe )
68 import List             ( partition, elemIndex )
69 import SrcLoc           ( Located(..), unLoc, getLoc, srcLocSpan )
70 import ListSetOps       ( equivClasses, minusList )
71 import Digraph          ( SCC(..) )
72 import DynFlags         ( DynFlag( Opt_GlasgowExts, Opt_Generics, 
73                                         Opt_UnboxStrictFields ) )
74 \end{code}
75
76
77 %************************************************************************
78 %*                                                                      *
79 \subsection{Type checking for type and class declarations}
80 %*                                                                      *
81 %************************************************************************
82
83 Dealing with a group
84 ~~~~~~~~~~~~~~~~~~~~
85 Consider a mutually-recursive group, binding 
86 a type constructor T and a class C.
87
88 Step 1:         getInitialKind
89         Construct a KindEnv by binding T and C to a kind variable 
90
91 Step 2:         kcTyClDecl
92         In that environment, do a kind check
93
94 Step 3: Zonk the kinds
95
96 Step 4:         buildTyConOrClass
97         Construct an environment binding T to a TyCon and C to a Class.
98         a) Their kinds comes from zonking the relevant kind variable
99         b) Their arity (for synonyms) comes direct from the decl
100         c) The funcional dependencies come from the decl
101         d) The rest comes a knot-tied binding of T and C, returned from Step 4
102         e) The variances of the tycons in the group is calculated from 
103                 the knot-tied stuff
104
105 Step 5:         tcTyClDecl1
106         In this environment, walk over the decls, constructing the TyCons and Classes.
107         This uses in a strict way items (a)-(c) above, which is why they must
108         be constructed in Step 4. Feed the results back to Step 4.
109         For this step, pass the is-recursive flag as the wimp-out flag
110         to tcTyClDecl1.
111         
112
113 Step 6:         Extend environment
114         We extend the type environment with bindings not only for the TyCons and Classes,
115         but also for their "implicit Ids" like data constructors and class selectors
116
117 Step 7:         checkValidTyCl
118         For a recursive group only, check all the decls again, just
119         to check all the side conditions on validity.  We could not
120         do this before because we were in a mutually recursive knot.
121
122 Identification of recursive TyCons
123 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
124 The knot-tying parameters: @rec_details_list@ is an alist mapping @Name@s to
125 @TyThing@s.
126
127 Identifying a TyCon as recursive serves two purposes
128
129 1.  Avoid infinite types.  Non-recursive newtypes are treated as
130 "transparent", like type synonyms, after the type checker.  If we did
131 this for all newtypes, we'd get infinite types.  So we figure out for
132 each newtype whether it is "recursive", and add a coercion if so.  In
133 effect, we are trying to "cut the loops" by identifying a loop-breaker.
134
135 2.  Avoid infinite unboxing.  This is nothing to do with newtypes.
136 Suppose we have
137         data T = MkT Int T
138         f (MkT x t) = f t
139 Well, this function diverges, but we don't want the strictness analyser
140 to diverge.  But the strictness analyser will diverge because it looks
141 deeper and deeper into the structure of T.   (I believe there are
142 examples where the function does something sane, and the strictness
143 analyser still diverges, but I can't see one now.)
144
145 Now, concerning (1), the FC2 branch currently adds a coercion for ALL
146 newtypes.  I did this as an experiment, to try to expose cases in which
147 the coercions got in the way of optimisations.  If it turns out that we
148 can indeed always use a coercion, then we don't risk recursive types,
149 and don't need to figure out what the loop breakers are.
150
151 For newtype *families* though, we will always have a coercion, so they
152 are always loop breakers!  So you can easily adjust the current
153 algorithm by simply treating all newtype families as loop breakers (and
154 indeed type families).  I think.
155
156 \begin{code}
157 tcTyAndClassDecls :: ModDetails -> [LTyClDecl Name]
158                    -> TcM TcGblEnv      -- Input env extended by types and classes 
159                                         -- and their implicit Ids,DataCons
160 tcTyAndClassDecls boot_details allDecls
161   = do  {       -- Omit instances of indexed types; they are handled together
162                 -- with the *heads* of class instances
163         ; let decls = filter (not . isIdxTyDecl . unLoc) allDecls
164
165                 -- First check for cyclic type synonysm or classes
166                 -- See notes with checkCycleErrs
167         ; checkCycleErrs decls
168         ; mod <- getModule
169         ; traceTc (text "tcTyAndCl" <+> ppr mod)
170         ; (syn_tycons, alg_tyclss) <- fixM (\ ~(rec_syn_tycons, rec_alg_tyclss) ->
171           do    { let { -- Seperate ordinary synonyms from all other type and
172                         -- class declarations and add all associated type
173                         -- declarations from type classes.  The latter is
174                         -- required so that the temporary environment for the
175                         -- knot includes all associated family declarations.
176                       ; (syn_decls, alg_decls) = partition (isSynDecl . unLoc)
177                                                    decls
178                       ; alg_at_decls           = concatMap addATs alg_decls
179                       }
180                         -- Extend the global env with the knot-tied results
181                         -- for data types and classes
182                         -- 
183                         -- We must populate the environment with the loop-tied
184                         -- T's right away, because the kind checker may "fault
185                         -- in" some type  constructors that recursively
186                         -- mention T
187                 ; let gbl_things = mkGlobalThings alg_at_decls rec_alg_tyclss
188                 ; tcExtendRecEnv gbl_things $ do
189
190                         -- Kind-check the declarations
191                 { (kc_syn_decls, kc_alg_decls) <- kcTyClDecls syn_decls alg_decls
192
193                 ; let { -- Calculate rec-flag
194                       ; calc_rec  = calcRecFlags boot_details rec_alg_tyclss
195                       ; tc_decl   = addLocM (tcTyClDecl calc_rec) }
196                         -- Type-check the type synonyms, and extend the envt
197                 ; syn_tycons <- tcSynDecls kc_syn_decls
198                 ; tcExtendGlobalEnv syn_tycons $ do
199
200                         -- Type-check the data types and classes
201                 { alg_tyclss <- mappM tc_decl kc_alg_decls
202                 ; return (syn_tycons, concat alg_tyclss)
203             }}})
204         -- Finished with knot-tying now
205         -- Extend the environment with the finished things
206         ; tcExtendGlobalEnv (syn_tycons ++ alg_tyclss) $ do
207
208         -- Perform the validity check
209         { traceTc (text "ready for validity check")
210         ; mappM_ (addLocM checkValidTyCl) decls
211         ; traceTc (text "done")
212    
213         -- Add the implicit things;
214         -- we want them in the environment because 
215         -- they may be mentioned in interface files
216         ; let { implicit_things = concatMap implicitTyThings alg_tyclss }
217         ; traceTc ((text "Adding" <+> ppr alg_tyclss) 
218                    $$ (text "and" <+> ppr implicit_things))
219         ; tcExtendGlobalEnv implicit_things getGblEnv
220     }}
221   where
222     addATs decl@(L _ (ClassDecl {tcdATs = ats})) = decl : ats
223     addATs decl                                  = [decl]
224
225 mkGlobalThings :: [LTyClDecl Name]      -- The decls
226                -> [TyThing]             -- Knot-tied, in 1-1 correspondence with the decls
227                -> [(Name,TyThing)]
228 -- Driven by the Decls, and treating the TyThings lazily
229 -- make a TypeEnv for the new things
230 mkGlobalThings decls things
231   = map mk_thing (decls `zipLazy` things)
232   where
233     mk_thing (L _ (ClassDecl {tcdLName = L _ name}), ~(AClass cl))
234          = (name, AClass cl)
235     mk_thing (L _ decl, ~(ATyCon tc))
236          = (tcdName decl, ATyCon tc)
237 \end{code}
238
239
240 %************************************************************************
241 %*                                                                      *
242 \subsection{Type checking instances of indexed types}
243 %*                                                                      *
244 %************************************************************************
245
246 Instances of indexed types are somewhat of a hybrid.  They are processed
247 together with class instance heads, but can contain data constructors and hence
248 they share a lot of kinding and type checking code with ordinary algebraic
249 data types (and GADTs).
250
251 \begin{code}
252 tcIdxTyInstDecl :: LTyClDecl Name 
253                 -> TcM (Maybe InstInfo, Maybe TyThing)  -- Nothing if error
254 tcIdxTyInstDecl (L loc decl)
255   =     -- Prime error recovery, set source location
256     recoverM (returnM (Nothing, Nothing))       $
257     setSrcSpan loc                              $
258     tcAddDeclCtxt decl                          $
259     do { -- indexed data types require -fglasgow-exts and can't be in an
260          -- hs-boot file
261        ; gla_exts <- doptM Opt_GlasgowExts
262        ; is_boot  <- tcIsHsBoot   -- Are we compiling an hs-boot file?
263        ; checkTc gla_exts      $ badIdxTyDecl (tcdLName decl)
264        ; checkTc (not is_boot) $ badBootTyIdxDeclErr
265
266          -- perform kind and type checking
267        ; tcIdxTyInstDecl1 decl
268        }
269
270 tcIdxTyInstDecl1 :: TyClDecl Name 
271                  -> TcM (Maybe InstInfo, Maybe TyThing) -- Nothing if error
272
273 tcIdxTyInstDecl1 (decl@TySynonym {})
274   = kcIdxTyPats decl $ \k_tvs k_typats resKind family ->
275     do { -- check that the family declaration is for a synonym
276          unless (isSynTyCon family) $
277            addErr (wrongKindOfFamily family)
278
279        ; -- (1) kind check the right hand side of the type equation
280        ; k_rhs <- kcCheckHsType (tcdSynRhs decl) resKind
281
282          -- (2) type check type equation
283        ; tcTyVarBndrs k_tvs $ \t_tvs -> do {  -- turn kinded into proper tyvars
284        ; t_typats <- mappM tcHsKindedType k_typats
285        ; t_rhs    <- tcHsKindedType k_rhs
286
287          -- construct type rewrite rule
288          -- !!!of the form: forall t_tvs. (tcdLName decl) t_typats = t_rhs
289        ; return (Nothing, Nothing) -- !!!TODO: need InstInfo for eq axioms
290        }}
291       
292 tcIdxTyInstDecl1 (decl@TyData {tcdND = new_or_data, tcdLName = L loc tc_name,
293                                tcdCons = cons})
294   = kcIdxTyPats decl $ \k_tvs k_typats resKind family ->
295     do { -- check that the family declaration is for the right kind
296          unless (new_or_data == NewType  && isNewTyCon  family ||
297                  new_or_data == DataType && isDataTyCon family) $
298            addErr (wrongKindOfFamily family)
299
300        ; -- (1) kind check the data declaration as usual
301        ; k_decl <- kcDataDecl decl k_tvs
302        ; let k_ctxt = tcdCtxt k_decl
303              k_cons = tcdCons k_decl
304
305          -- result kind must be '*' (otherwise, we have too few patterns)
306        ; checkTc (isLiftedTypeKind resKind) $ tooFewParmsErr tc_name
307
308          -- (2) type check indexed data type declaration
309        ; tcTyVarBndrs k_tvs $ \t_tvs -> do {  -- turn kinded into proper tyvars
310        ; unbox_strict <- doptM Opt_UnboxStrictFields
311
312          -- Check that we don't use GADT syntax for indexed types
313        ; checkTc h98_syntax (badGadtIdxTyDecl tc_name)
314
315          -- Check that a newtype has exactly one constructor
316        ; checkTc (new_or_data == DataType || isSingleton k_cons) $
317            newtypeConError tc_name (length k_cons)
318
319        ; t_typats     <- mappM tcHsKindedType k_typats
320        ; stupid_theta <- tcHsKindedContext k_ctxt
321
322        ; tycon <- fixM (\ tycon -> do 
323              { data_cons <- mappM (addLocM (tcConDecl unbox_strict new_or_data 
324                                               tycon t_tvs))
325                                   k_cons
326              ; tc_rhs <-
327                  case new_or_data of
328                    DataType -> return (mkDataTyConRhs data_cons)
329                    NewType  -> 
330                             ASSERT( isSingleton data_cons )
331                             mkNewTyConRhs tc_name tycon (head data_cons)
332              ; buildAlgTyCon tc_name t_tvs stupid_theta tc_rhs Recursive
333                              False h98_syntax (Just (family, t_typats))
334                  -- We always assume that indexed types are recursive.  Why?
335                  -- (1) Due to their open nature, we can never be sure that a
336                  -- further instance might not introduce a new recursive
337                  -- dependency.  (2) They are always valid loop breakers as
338                  -- they involve a coercion.
339              })
340
341          -- construct result
342        ; return (Nothing, Just (ATyCon tycon))
343        }}
344        where
345          h98_syntax = case cons of      -- All constructors have same shape
346                         L _ (ConDecl { con_res = ResTyGADT _ }) : _ -> False
347                         other -> True
348
349 -- Kind checking of indexed types
350 -- -
351
352 -- Kind check type patterns and kind annotate the embedded type variables.
353 --
354 -- * Here we check that a type instance matches its kind signature, but we do
355 --   not check whether there is a pattern for each type index; the latter
356 --   check is only required for type functions.
357 --
358 kcIdxTyPats :: TyClDecl Name
359             -> ([LHsTyVarBndr Name] -> [LHsType Name] -> Kind -> TyCon -> TcM a)
360                -- ^^kinded tvs         ^^kinded ty pats  ^^res kind
361             -> TcM a
362 kcIdxTyPats decl thing_inside
363   = kcHsTyVars (tcdTyVars decl) $ \tvs -> 
364     do { tc_ty_thing <- tcLookupLocated (tcdLName decl)
365        ; let { family = case tc_ty_thing of 
366                           AGlobal (ATyCon family) -> family
367              ; (kinds, resKind) = splitKindFunTys (tyConKind family)
368              ; hs_typats        = fromJust $ tcdTyPats decl }
369
370          -- we may not have more parameters than the kind indicates
371        ; checkTc (length kinds >= length hs_typats) $
372            tooManyParmsErr (tcdLName decl)
373
374          -- type functions can have a higher-kinded result
375        ; let resultKind = mkArrowKinds (drop (length hs_typats) kinds) resKind
376        ; typats <- zipWithM kcCheckHsType hs_typats kinds
377        ; thing_inside tvs typats resultKind family
378        }
379   where
380 \end{code}
381
382
383 %************************************************************************
384 %*                                                                      *
385                 Kind checking
386 %*                                                                      *
387 %************************************************************************
388
389 We need to kind check all types in the mutually recursive group
390 before we know the kind of the type variables.  For example:
391
392 class C a where
393    op :: D b => a -> b -> b
394
395 class D c where
396    bop :: (Monad c) => ...
397
398 Here, the kind of the locally-polymorphic type variable "b"
399 depends on *all the uses of class D*.  For example, the use of
400 Monad c in bop's type signature means that D must have kind Type->Type.
401
402 However type synonyms work differently.  They can have kinds which don't
403 just involve (->) and *:
404         type R = Int#           -- Kind #
405         type S a = Array# a     -- Kind * -> #
406         type T a b = (# a,b #)  -- Kind * -> * -> (# a,b #)
407 So we must infer their kinds from their right-hand sides *first* and then
408 use them, whereas for the mutually recursive data types D we bring into
409 scope kind bindings D -> k, where k is a kind variable, and do inference.
410
411 Indexed Types
412 ~~~~~~~~~~~~~
413 This treatment of type synonyms only applies to Haskell 98-style synonyms.
414 General type functions can be recursive, and hence, appear in `alg_decls'.
415
416 The kind of an indexed type is solely determinded by its kind signature;
417 hence, only kind signatures participate in the construction of the initial
418 kind environment (as constructed by `getInitialKind').  In fact, we ignore
419 instances of indexed types altogether in the following.  However, we need to
420 include the kind signatures of associated types into the construction of the
421 initial kind environment.  (This is handled by `allDecls').
422
423 \begin{code}
424 kcTyClDecls syn_decls alg_decls
425   = do  {       -- First extend the kind env with each data type, class, and
426                 -- indexed type, mapping them to a type variable
427           let initialKindDecls = concat [allDecls decl | L _ decl <- alg_decls]
428         ; alg_kinds <- mappM getInitialKind initialKindDecls
429         ; tcExtendKindEnv alg_kinds $ do
430
431                 -- Now kind-check the type synonyms, in dependency order
432                 -- We do these differently to data type and classes,
433                 -- because a type synonym can be an unboxed type
434                 --      type Foo = Int#
435                 -- and a kind variable can't unify with UnboxedTypeKind
436                 -- So we infer their kinds in dependency order
437         { (kc_syn_decls, syn_kinds) <- kcSynDecls (calcSynCycles syn_decls)
438         ; tcExtendKindEnv syn_kinds $  do
439
440                 -- Now kind-check the data type, class, and kind signatures,
441                 -- returning kind-annotated decls; we don't kind-check
442                 -- instances of indexed types yet, but leave this to
443                 -- `tcInstDecls1'
444         { kc_alg_decls <- mappM (wrapLocM kcTyClDecl) 
445                             (filter (not . isIdxTyDecl . unLoc) alg_decls)
446
447         ; return (kc_syn_decls, kc_alg_decls) }}}
448   where
449     -- get all declarations relevant for determining the initial kind
450     -- environment
451     allDecls (decl@ClassDecl {tcdATs = ats}) = decl : [ at 
452                                                       | L _ at <- ats
453                                                       , isKindSigDecl at]
454     allDecls decl | isIdxTyDecl decl         = []
455                   | otherwise                = [decl]
456
457 ------------------------------------------------------------------------
458 getInitialKind :: TyClDecl Name -> TcM (Name, TcKind)
459 -- Only for data type, class, and indexed type declarations
460 -- Get as much info as possible from the data, class, or indexed type decl,
461 -- so as to maximise usefulness of error messages
462 getInitialKind decl
463   = do  { arg_kinds <- mapM (mk_arg_kind . unLoc) (tyClDeclTyVars decl)
464         ; res_kind  <- mk_res_kind decl
465         ; return (tcdName decl, mkArrowKinds arg_kinds res_kind) }
466   where
467     mk_arg_kind (UserTyVar _)        = newKindVar
468     mk_arg_kind (KindedTyVar _ kind) = return kind
469
470     mk_res_kind (TyFunction { tcdKind    = kind      }) = return kind
471     mk_res_kind (TyData     { tcdKindSig = Just kind }) = return kind
472         -- On GADT-style and data signature declarations we allow a kind 
473         -- signature
474         --      data T :: *->* where { ... }
475     mk_res_kind other = return liftedTypeKind
476
477
478 ----------------
479 kcSynDecls :: [SCC (LTyClDecl Name)] 
480            -> TcM ([LTyClDecl Name],    -- Kind-annotated decls
481                    [(Name,TcKind)])     -- Kind bindings
482 kcSynDecls []
483   = return ([], [])
484 kcSynDecls (group : groups)
485   = do  { (decl,  nk)  <- kcSynDecl group
486         ; (decls, nks) <- tcExtendKindEnv [nk] (kcSynDecls groups)
487         ; return (decl:decls, nk:nks) }
488                         
489 ----------------
490 kcSynDecl :: SCC (LTyClDecl Name) 
491            -> TcM (LTyClDecl Name,      -- Kind-annotated decls
492                    (Name,TcKind))       -- Kind bindings
493 kcSynDecl (AcyclicSCC ldecl@(L loc decl))
494   = tcAddDeclCtxt decl  $
495     kcHsTyVars (tcdTyVars decl) (\ k_tvs ->
496     do { traceTc (text "kcd1" <+> ppr (unLoc (tcdLName decl)) <+> brackets (ppr (tcdTyVars decl)) 
497                         <+> brackets (ppr k_tvs))
498        ; (k_rhs, rhs_kind) <- kcHsType (tcdSynRhs decl)
499        ; traceTc (text "kcd2" <+> ppr (unLoc (tcdLName decl)))
500        ; let tc_kind = foldr (mkArrowKind . kindedTyVarKind) rhs_kind k_tvs
501        ; return (L loc (decl { tcdTyVars = k_tvs, tcdSynRhs = k_rhs }),
502                  (unLoc (tcdLName decl), tc_kind)) })
503
504 kcSynDecl (CyclicSCC decls)
505   = do { recSynErr decls; failM }       -- Fail here to avoid error cascade
506                                         -- of out-of-scope tycons
507
508 kindedTyVarKind (L _ (KindedTyVar _ k)) = k
509
510 ------------------------------------------------------------------------
511 kcTyClDecl :: TyClDecl Name -> TcM (TyClDecl Name)
512         -- Not used for type synonyms (see kcSynDecl)
513
514 kcTyClDecl decl@(TyData {})
515   = ASSERT( not . isJust $ tcdTyPats decl )   -- must not be instance of idx ty
516     kcTyClDeclBody decl $
517       kcDataDecl decl
518
519 kcTyClDecl decl@(TyFunction {})
520   = kcTyClDeclBody decl $ \ tvs' ->
521       return (decl {tcdTyVars = tvs'})
522
523 kcTyClDecl decl@(ClassDecl {tcdCtxt = ctxt, tcdSigs = sigs, tcdATs = ats})
524   = kcTyClDeclBody decl $ \ tvs' ->
525     do  { is_boot <- tcIsHsBoot
526         ; ctxt' <- kcHsContext ctxt     
527         ; ats'  <- mappM (wrapLocM kcTyClDecl) ats
528         ; sigs' <- mappM (wrapLocM kc_sig    ) sigs
529         ; return (decl {tcdTyVars = tvs', tcdCtxt = ctxt', tcdSigs = sigs',
530                         tcdATs = ats'}) }
531   where
532     kc_sig (TypeSig nm op_ty) = do { op_ty' <- kcHsLiftedSigType op_ty
533                                    ; return (TypeSig nm op_ty') }
534     kc_sig other_sig          = return other_sig
535
536 kcTyClDecl decl@(ForeignType {})
537   = return decl
538
539 kcTyClDeclBody :: TyClDecl Name
540                -> ([LHsTyVarBndr Name] -> TcM a)
541                -> TcM a
542 -- getInitialKind has made a suitably-shaped kind for the type or class
543 -- Unpack it, and attribute those kinds to the type variables
544 -- Extend the env with bindings for the tyvars, taken from
545 -- the kind of the tycon/class.  Give it to the thing inside, and 
546 -- check the result kind matches
547 kcTyClDeclBody decl thing_inside
548   = tcAddDeclCtxt decl          $
549     do  { tc_ty_thing <- tcLookupLocated (tcdLName decl)
550         ; let tc_kind    = case tc_ty_thing of { AThing k -> k }
551               (kinds, _) = splitKindFunTys tc_kind
552               hs_tvs     = tcdTyVars decl
553               kinded_tvs = ASSERT( length kinds >= length hs_tvs )
554                            [ L loc (KindedTyVar (hsTyVarName tv) k)
555                            | (L loc tv, k) <- zip hs_tvs kinds]
556         ; tcExtendKindEnvTvs kinded_tvs (thing_inside kinded_tvs) }
557
558 -- Kind check a data declaration, assuming that we already extended the
559 -- kind environment with the type variables of the left-hand side (these
560 -- kinded type variables are also passed as the second parameter).
561 --
562 kcDataDecl :: TyClDecl Name -> [LHsTyVarBndr Name] -> TcM (TyClDecl Name)
563 kcDataDecl decl@(TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdCons = cons})
564            tvs
565   = do  { ctxt' <- kcHsContext ctxt     
566         ; cons' <- mappM (wrapLocM kc_con_decl) cons
567         ; return (decl {tcdTyVars = tvs, tcdCtxt = ctxt', tcdCons = cons'}) }
568   where
569     kc_con_decl (ConDecl name expl ex_tvs ex_ctxt details res) = do
570       kcHsTyVars ex_tvs $ \ex_tvs' -> do
571         ex_ctxt' <- kcHsContext ex_ctxt
572         details' <- kc_con_details details 
573         res'     <- case res of
574           ResTyH98 -> return ResTyH98
575           ResTyGADT ty -> do { ty' <- kcHsSigType ty; return (ResTyGADT ty') }
576         return (ConDecl name expl ex_tvs' ex_ctxt' details' res')
577
578     kc_con_details (PrefixCon btys) 
579         = do { btys' <- mappM kc_larg_ty btys ; return (PrefixCon btys') }
580     kc_con_details (InfixCon bty1 bty2) 
581         = do { bty1' <- kc_larg_ty bty1; bty2' <- kc_larg_ty bty2; return (InfixCon bty1' bty2') }
582     kc_con_details (RecCon fields) 
583         = do { fields' <- mappM kc_field fields; return (RecCon fields') }
584
585     kc_field (fld, bty) = do { bty' <- kc_larg_ty bty ; return (fld, bty') }
586
587     kc_larg_ty bty = case new_or_data of
588                         DataType -> kcHsSigType bty
589                         NewType  -> kcHsLiftedSigType bty
590         -- Can't allow an unlifted type for newtypes, because we're effectively
591         -- going to remove the constructor while coercing it to a lifted type.
592         -- And newtypes can't be bang'd
593 \end{code}
594
595
596 %************************************************************************
597 %*                                                                      *
598 \subsection{Type checking}
599 %*                                                                      *
600 %************************************************************************
601
602 \begin{code}
603 tcSynDecls :: [LTyClDecl Name] -> TcM [TyThing]
604 tcSynDecls [] = return []
605 tcSynDecls (decl : decls) 
606   = do { syn_tc <- addLocM tcSynDecl decl
607        ; syn_tcs <- tcExtendGlobalEnv [syn_tc] (tcSynDecls decls)
608        ; return (syn_tc : syn_tcs) }
609
610 tcSynDecl
611   (TySynonym {tcdLName = L _ tc_name, tcdTyVars = tvs, tcdSynRhs = rhs_ty})
612   = tcTyVarBndrs tvs            $ \ tvs' -> do 
613     { traceTc (text "tcd1" <+> ppr tc_name) 
614     ; rhs_ty' <- tcHsKindedType rhs_ty
615     ; return (ATyCon (buildSynTyCon tc_name tvs' (SynonymTyCon rhs_ty'))) }
616
617 --------------------
618 tcTyClDecl :: (Name -> RecFlag) -> TyClDecl Name -> TcM [TyThing]
619
620 tcTyClDecl calc_isrec decl
621   = tcAddDeclCtxt decl (tcTyClDecl1 calc_isrec decl)
622
623   -- kind signature for a type function
624 tcTyClDecl1 _calc_isrec 
625   (TyFunction {tcdLName = L _ tc_name, tcdTyVars = tvs, tcdKind = kind})
626   = tcTyVarBndrs tvs  $ \ tvs' -> do 
627   { traceTc (text "type family: " <+> ppr tc_name) 
628   ; gla_exts <- doptM Opt_GlasgowExts
629
630         -- Check that we don't use kind signatures without Glasgow extensions
631   ; checkTc gla_exts $ badSigTyDecl tc_name
632
633   ; return [ATyCon $ buildSynTyCon tc_name tvs' (OpenSynTyCon kind)]
634   }
635
636   -- kind signature for an indexed data type
637 tcTyClDecl1 _calc_isrec 
638   (TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdTyVars = tvs,
639            tcdLName = L _ tc_name, tcdKindSig = Just ksig, tcdCons = []})
640   = tcTyVarBndrs tvs  $ \ tvs' -> do 
641   { traceTc (text "data/newtype family: " <+> ppr tc_name) 
642   ; extra_tvs <- tcDataKindSig (Just ksig)
643   ; let final_tvs = tvs' ++ extra_tvs    -- we may not need these
644
645   ; checkTc (null . unLoc $ ctxt) $ badKindSigCtxt tc_name
646   ; gla_exts <- doptM Opt_GlasgowExts
647
648         -- Check that we don't use kind signatures without Glasgow extensions
649   ; checkTc gla_exts $ badSigTyDecl tc_name
650
651   ; tycon <- buildAlgTyCon tc_name final_tvs [] 
652                (case new_or_data of
653                   DataType -> OpenDataTyCon
654                   NewType  -> OpenNewTyCon)
655                Recursive False True Nothing
656   ; return [ATyCon tycon]
657   }
658
659 tcTyClDecl1 calc_isrec
660   (TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdTyVars = tvs,
661            tcdLName = L _ tc_name, tcdKindSig = mb_ksig, tcdCons = cons})
662   = tcTyVarBndrs tvs    $ \ tvs' -> do 
663   { extra_tvs <- tcDataKindSig mb_ksig
664   ; let final_tvs = tvs' ++ extra_tvs
665   ; stupid_theta <- tcHsKindedContext ctxt
666   ; want_generic <- doptM Opt_Generics
667   ; unbox_strict <- doptM Opt_UnboxStrictFields
668   ; gla_exts     <- doptM Opt_GlasgowExts
669   ; is_boot      <- tcIsHsBoot  -- Are we compiling an hs-boot file?
670
671         -- Check that we don't use GADT syntax in H98 world
672   ; checkTc (gla_exts || h98_syntax) (badGadtDecl tc_name)
673
674         -- Check that we don't use kind signatures without Glasgow extensions
675   ; checkTc (gla_exts || isNothing mb_ksig) (badSigTyDecl tc_name)
676
677         -- Check that the stupid theta is empty for a GADT-style declaration
678   ; checkTc (null stupid_theta || h98_syntax) (badStupidTheta tc_name)
679
680         -- Check that there's at least one condecl,
681         -- or else we're reading an hs-boot file, or -fglasgow-exts
682   ; checkTc (not (null cons) || gla_exts || is_boot)
683             (emptyConDeclsErr tc_name)
684     
685         -- Check that a newtype has exactly one constructor
686   ; checkTc (new_or_data == DataType || isSingleton cons) 
687             (newtypeConError tc_name (length cons))
688
689   ; tycon <- fixM (\ tycon -> do 
690         { data_cons <- mappM (addLocM (tcConDecl unbox_strict new_or_data 
691                                                  tycon final_tvs)) 
692                              cons
693         ; tc_rhs <-
694             if null cons && is_boot     -- In a hs-boot file, empty cons means
695             then return AbstractTyCon   -- "don't know"; hence Abstract
696             else case new_or_data of
697                    DataType -> return (mkDataTyConRhs data_cons)
698                    NewType  -> 
699                        ASSERT( isSingleton data_cons )
700                        mkNewTyConRhs tc_name tycon (head data_cons)
701         ; buildAlgTyCon tc_name final_tvs stupid_theta tc_rhs is_rec
702             (want_generic && canDoGenerics data_cons) h98_syntax Nothing
703         })
704   ; return [ATyCon tycon]
705   }
706   where
707     is_rec   = calc_isrec tc_name
708     h98_syntax = case cons of   -- All constructors have same shape
709                         L _ (ConDecl { con_res = ResTyGADT _ }) : _ -> False
710                         other -> True
711
712 tcTyClDecl1 calc_isrec 
713   (ClassDecl {tcdLName = L _ class_name, tcdTyVars = tvs, 
714               tcdCtxt = ctxt, tcdMeths = meths,
715               tcdFDs = fundeps, tcdSigs = sigs, tcdATs = ats} )
716   = tcTyVarBndrs tvs            $ \ tvs' -> do 
717   { ctxt' <- tcHsKindedContext ctxt
718   ; fds' <- mappM (addLocM tc_fundep) fundeps
719   ; atss <- mappM (addLocM (tcTyClDecl1 (const Recursive))) ats
720   ; let ats' = zipWith setTyThingPoss atss (map (tcdTyVars . unLoc) ats)
721   ; sig_stuff <- tcClassSigs class_name sigs meths
722   ; clas <- fixM (\ clas ->
723                 let     -- This little knot is just so we can get
724                         -- hold of the name of the class TyCon, which we
725                         -- need to look up its recursiveness
726                     tycon_name = tyConName (classTyCon clas)
727                     tc_isrec = calc_isrec tycon_name
728                 in
729                 buildClass class_name tvs' ctxt' fds' ats'
730                            sig_stuff tc_isrec)
731   ; return (AClass clas : ats')
732       -- NB: Order is important due to the call to `mkGlobalThings' when
733       --     tying the the type and class declaration type checking knot.
734   }
735   where
736     tc_fundep (tvs1, tvs2) = do { tvs1' <- mappM tcLookupTyVar tvs1 ;
737                                 ; tvs2' <- mappM tcLookupTyVar tvs2 ;
738                                 ; return (tvs1', tvs2') }
739
740     -- For each AT argument compute the position of the corresponding class
741     -- parameter in the class head.  This will later serve as a permutation
742     -- vector when checking the validity of instance declarations.
743     setTyThingPoss [ATyCon tycon] atTyVars = 
744       let classTyVars = hsLTyVarNames tvs
745           poss        =   catMaybes 
746                         . map (`elemIndex` classTyVars) 
747                         . hsLTyVarNames 
748                         $ atTyVars
749                      -- There will be no Nothing, as we already passed renaming
750       in 
751       ATyCon (setTyConArgPoss tycon poss)
752     setTyThingPoss _              _ = panic "TcTyClsDecls.setTyThingPoss"
753
754 tcTyClDecl1 calc_isrec 
755   (ForeignType {tcdLName = L _ tc_name, tcdExtName = tc_ext_name})
756   = returnM [ATyCon (mkForeignTyCon tc_name tc_ext_name liftedTypeKind 0)]
757
758 -----------------------------------
759 tcConDecl :: Bool               -- True <=> -funbox-strict_fields
760           -> NewOrData 
761           -> TyCon -> [TyVar] 
762           -> ConDecl Name 
763           -> TcM DataCon
764
765 tcConDecl unbox_strict NewType tycon tc_tvs     -- Newtypes
766           (ConDecl name _ ex_tvs ex_ctxt details ResTyH98)
767   = do  { let tc_datacon field_lbls arg_ty
768                 = do { arg_ty' <- tcHsKindedType arg_ty -- No bang on newtype
769                      ; buildDataCon (unLoc name) False {- Prefix -} 
770                                     [NotMarkedStrict]
771                                     (map unLoc field_lbls)
772                                     tc_tvs []  -- No existentials
773                                     [] []      -- No equalities, predicates
774                                     [arg_ty']
775                                     tycon }
776
777                 -- Check that a newtype has no existential stuff
778         ; checkTc (null ex_tvs && null (unLoc ex_ctxt)) (newtypeExError name)
779
780         ; case details of
781             PrefixCon [arg_ty]           -> tc_datacon [] arg_ty
782             RecCon [(field_lbl, arg_ty)] -> tc_datacon [field_lbl] arg_ty
783             other                        -> 
784               failWithTc (newtypeFieldErr name (length (hsConArgs details)))
785                         -- Check that the constructor has exactly one field
786         }
787
788 tcConDecl unbox_strict DataType tycon tc_tvs    -- Data types
789           (ConDecl name _ tvs ctxt details res_ty)
790   = tcTyVarBndrs tvs            $ \ tvs' -> do 
791     { ctxt' <- tcHsKindedContext ctxt
792     ; (univ_tvs, ex_tvs, eq_preds, data_tc) <- tcResultType tycon tc_tvs tvs' res_ty
793     ; let 
794         tc_datacon is_infix field_lbls btys
795           = do { let bangs = map getBangStrictness btys
796                ; arg_tys <- mappM tcHsBangType btys
797                ; buildDataCon (unLoc name) is_infix
798                     (argStrictness unbox_strict tycon bangs arg_tys)
799                     (map unLoc field_lbls)
800                     univ_tvs ex_tvs eq_preds ctxt' arg_tys
801                     data_tc }
802                 -- NB:  we put data_tc, the type constructor gotten from the
803                 --      constructor type signature into the data constructor;
804                 --      that way checkValidDataCon can complain if it's wrong.
805
806     ; case details of
807         PrefixCon btys     -> tc_datacon False [] btys
808         InfixCon bty1 bty2 -> tc_datacon True  [] [bty1,bty2]
809         RecCon fields      -> tc_datacon False field_names btys
810                            where
811                               (field_names, btys) = unzip fields
812                               
813     }
814
815 tcResultType :: TyCon
816              -> [TyVar]         -- data T a b c = ...
817              -> [TyVar]         -- where MkT :: forall a b c. ...
818              -> ResType Name
819              -> TcM ([TyVar],           -- Universal
820                      [TyVar],           -- Existential
821                      [(TyVar,Type)],    -- Equality predicates
822                      TyCon)             -- TyCon given in the ResTy
823         -- We don't check that the TyCon given in the ResTy is
824         -- the same as the parent tycon, becuase we are in the middle
825         -- of a recursive knot; so it's postponed until checkValidDataCon
826
827 tcResultType decl_tycon tc_tvs dc_tvs ResTyH98
828   = return (tc_tvs, dc_tvs, [], decl_tycon)
829         -- In H98 syntax the dc_tvs are the existential ones
830         --      data T a b c = forall d e. MkT ...
831         -- The {a,b,c} are tc_tvs, and {d,e} are dc_tvs
832
833 tcResultType _ tc_tvs dc_tvs (ResTyGADT res_ty)
834         -- E.g.  data T a b c where
835         --         MkT :: forall x y z. T (x,y) z z
836         -- Then we generate
837         --      ([a,z,c], [x,y], [a:=:(x,y), c:=:z], T)
838
839   = do  { (dc_tycon, res_tys) <- tcLHsConResTy res_ty
840                 -- NB: tc_tvs and dc_tvs are distinct
841         ; let univ_tvs = choose_univs [] tc_tvs res_tys
842                 -- Each univ_tv is either a dc_tv or a tc_tv
843               ex_tvs = dc_tvs `minusList` univ_tvs
844               eq_spec = [ (tv, ty) | (tv,ty) <- univ_tvs `zip` res_tys, 
845                                       tv `elem` tc_tvs]
846         ; return (univ_tvs, ex_tvs, eq_spec, dc_tycon) }
847   where
848         -- choose_univs uses the res_ty itself if it's a type variable
849         -- and hasn't already been used; otherwise it uses one of the tc_tvs
850     choose_univs used tc_tvs []
851         = ASSERT( null tc_tvs ) []
852     choose_univs used (tc_tv:tc_tvs) (res_ty:res_tys) 
853         | Just tv <- tcGetTyVar_maybe res_ty, not (tv `elem` used)
854         = tv    : choose_univs (tv:used) tc_tvs res_tys
855         | otherwise
856         = tc_tv : choose_univs used tc_tvs res_tys
857
858 -------------------
859 argStrictness :: Bool           -- True <=> -funbox-strict_fields
860               -> TyCon -> [HsBang]
861               -> [TcType] -> [StrictnessMark]
862 argStrictness unbox_strict tycon bangs arg_tys
863  = ASSERT( length bangs == length arg_tys )
864    zipWith (chooseBoxingStrategy unbox_strict tycon) arg_tys bangs
865
866 -- We attempt to unbox/unpack a strict field when either:
867 --   (i)  The field is marked '!!', or
868 --   (ii) The field is marked '!', and the -funbox-strict-fields flag is on.
869 --
870 -- We have turned off unboxing of newtypes because coercions make unboxing 
871 -- and reboxing more complicated
872 chooseBoxingStrategy :: Bool -> TyCon -> TcType -> HsBang -> StrictnessMark
873 chooseBoxingStrategy unbox_strict_fields tycon arg_ty bang
874   = case bang of
875         HsNoBang                                    -> NotMarkedStrict
876         HsStrict | unbox_strict_fields 
877                    && can_unbox arg_ty              -> MarkedUnboxed
878         HsUnbox  | can_unbox arg_ty                 -> MarkedUnboxed
879         other                                       -> MarkedStrict
880   where
881     -- we can unbox if the type is a chain of newtypes with a product tycon
882     -- at the end
883     can_unbox arg_ty = case splitTyConApp_maybe arg_ty of
884                    Nothing                      -> False
885                    Just (arg_tycon, tycon_args) -> 
886                        not (isRecursiveTyCon tycon) &&
887                        isProductTyCon arg_tycon &&
888                        (if isNewTyCon arg_tycon then 
889                             can_unbox (newTyConInstRhs arg_tycon tycon_args)
890                         else True)
891 \end{code}
892
893 %************************************************************************
894 %*                                                                      *
895 \subsection{Dependency analysis}
896 %*                                                                      *
897 %************************************************************************
898
899 Validity checking is done once the mutually-recursive knot has been
900 tied, so we can look at things freely.
901
902 \begin{code}
903 checkCycleErrs :: [LTyClDecl Name] -> TcM ()
904 checkCycleErrs tyclss
905   | null cls_cycles
906   = return ()
907   | otherwise
908   = do  { mappM_ recClsErr cls_cycles
909         ; failM }       -- Give up now, because later checkValidTyCl
910                         -- will loop if the synonym is recursive
911   where
912     cls_cycles = calcClassCycles tyclss
913
914 checkValidTyCl :: TyClDecl Name -> TcM ()
915 -- We do the validity check over declarations, rather than TyThings
916 -- only so that we can add a nice context with tcAddDeclCtxt
917 checkValidTyCl decl
918   = tcAddDeclCtxt decl $
919     do  { thing <- tcLookupLocatedGlobal (tcdLName decl)
920         ; traceTc (text "Validity of" <+> ppr thing)    
921         ; case thing of
922             ATyCon tc -> checkValidTyCon tc
923             AClass cl -> checkValidClass cl 
924         ; traceTc (text "Done validity of" <+> ppr thing)       
925         }
926
927 -------------------------
928 -- For data types declared with record syntax, we require
929 -- that each constructor that has a field 'f' 
930 --      (a) has the same result type
931 --      (b) has the same type for 'f'
932 -- module alpha conversion of the quantified type variables
933 -- of the constructor.
934
935 checkValidTyCon :: TyCon -> TcM ()
936 checkValidTyCon tc 
937   | isSynTyCon tc 
938   = case synTyConRhs tc of
939       OpenSynTyCon _  -> return ()
940       SynonymTyCon ty -> checkValidType syn_ctxt ty
941   | otherwise
942   =     -- Check the context on the data decl
943     checkValidTheta (DataTyCtxt name) (tyConStupidTheta tc)     `thenM_` 
944         
945         -- Check arg types of data constructors
946     mappM_ (checkValidDataCon tc) data_cons                     `thenM_`
947
948         -- Check that fields with the same name share a type
949     mappM_ check_fields groups
950
951   where
952     syn_ctxt  = TySynCtxt name
953     name      = tyConName tc
954     data_cons = tyConDataCons tc
955
956     groups = equivClasses cmp_fld (concatMap get_fields data_cons)
957     cmp_fld (f1,_) (f2,_) = f1 `compare` f2
958     get_fields con = dataConFieldLabels con `zip` repeat con
959         -- dataConFieldLabels may return the empty list, which is fine
960
961     -- See Note [GADT record selectors] in MkId.lhs
962     -- We must check (a) that the named field has the same 
963     --                   type in each constructor
964     --               (b) that those constructors have the same result type
965     --
966     -- However, the constructors may have differently named type variable
967     -- and (worse) we don't know how the correspond to each other.  E.g.
968     --     C1 :: forall a b. { f :: a, g :: b } -> T a b
969     --     C2 :: forall d c. { f :: c, g :: c } -> T c d
970     -- 
971     -- So what we do is to ust Unify.tcMatchTys to compare the first candidate's
972     -- result type against other candidates' types BOTH WAYS ROUND.
973     -- If they magically agrees, take the substitution and
974     -- apply them to the latter ones, and see if they match perfectly.
975     check_fields fields@((label, con1) : other_fields)
976         -- These fields all have the same name, but are from
977         -- different constructors in the data type
978         = recoverM (return ()) $ mapM_ checkOne other_fields
979                 -- Check that all the fields in the group have the same type
980                 -- NB: this check assumes that all the constructors of a given
981                 -- data type use the same type variables
982         where
983         tvs1 = mkVarSet (dataConAllTyVars con1)
984         res1 = dataConResTys con1
985         fty1 = dataConFieldType con1 label
986
987         checkOne (_, con2)    -- Do it bothways to ensure they are structurally identical
988             = do { checkFieldCompat label con1 con2 tvs1 res1 res2 fty1 fty2
989                  ; checkFieldCompat label con2 con1 tvs2 res2 res1 fty2 fty1 }
990             where        
991                 tvs2 = mkVarSet (dataConAllTyVars con2)
992                 res2 = dataConResTys con2 
993                 fty2 = dataConFieldType con2 label
994
995 checkFieldCompat fld con1 con2 tvs1 res1 res2 fty1 fty2
996   = do  { checkTc (isJust mb_subst1) (resultTypeMisMatch fld con1 con2)
997         ; checkTc (isJust mb_subst2) (fieldTypeMisMatch fld con1 con2) }
998   where
999     mb_subst1 = tcMatchTys tvs1 res1 res2
1000     mb_subst2 = tcMatchTyX tvs1 (expectJust "checkFieldCompat" mb_subst1) fty1 fty2
1001
1002 -------------------------------
1003 checkValidDataCon :: TyCon -> DataCon -> TcM ()
1004 checkValidDataCon tc con
1005   = setSrcSpan (srcLocSpan (getSrcLoc con))     $
1006     addErrCtxt (dataConCtxt con)                $ 
1007     do  { checkTc (dataConTyCon con == tc) (badDataConTyCon con)
1008         ; checkValidType ctxt (dataConUserType con) }
1009   where
1010     ctxt = ConArgCtxt (dataConName con) 
1011
1012 -------------------------------
1013 checkValidClass :: Class -> TcM ()
1014 checkValidClass cls
1015   = do  {       -- CHECK ARITY 1 FOR HASKELL 1.4
1016           gla_exts <- doptM Opt_GlasgowExts
1017
1018         -- Check that the class is unary, unless GlaExs
1019         ; checkTc (notNull tyvars) (nullaryClassErr cls)
1020         ; checkTc (gla_exts || unary) (classArityErr cls)
1021
1022         -- Check the super-classes
1023         ; checkValidTheta (ClassSCCtxt (className cls)) theta
1024
1025         -- Check the class operations
1026         ; mappM_ (check_op gla_exts) op_stuff
1027
1028         -- Check that if the class has generic methods, then the
1029         -- class has only one parameter.  We can't do generic
1030         -- multi-parameter type classes!
1031         ; checkTc (unary || no_generics) (genericMultiParamErr cls)
1032         }
1033   where
1034     (tyvars, theta, _, op_stuff) = classBigSig cls
1035     unary       = isSingleton tyvars
1036     no_generics = null [() | (_, GenDefMeth) <- op_stuff]
1037
1038     check_op gla_exts (sel_id, dm) 
1039       = addErrCtxt (classOpCtxt sel_id tau) $ do
1040         { checkValidTheta SigmaCtxt (tail theta)
1041                 -- The 'tail' removes the initial (C a) from the
1042                 -- class itself, leaving just the method type
1043
1044         ; checkValidType (FunSigCtxt op_name) tau
1045
1046                 -- Check that the type mentions at least one of
1047                 -- the class type variables
1048         ; checkTc (any (`elemVarSet` tyVarsOfType tau) tyvars)
1049                   (noClassTyVarErr cls sel_id)
1050
1051                 -- Check that for a generic method, the type of 
1052                 -- the method is sufficiently simple
1053         ; checkTc (dm /= GenDefMeth || validGenericMethodType tau)
1054                   (badGenericMethodType op_name op_ty)
1055         }
1056         where
1057           op_name = idName sel_id
1058           op_ty   = idType sel_id
1059           (_,theta1,tau1) = tcSplitSigmaTy op_ty
1060           (_,theta2,tau2)  = tcSplitSigmaTy tau1
1061           (theta,tau) | gla_exts  = (theta1 ++ theta2, tau2)
1062                       | otherwise = (theta1,           mkPhiTy (tail theta1) tau1)
1063                 -- Ugh!  The function might have a type like
1064                 --      op :: forall a. C a => forall b. (Eq b, Eq a) => tau2
1065                 -- With -fglasgow-exts, we want to allow this, even though the inner 
1066                 -- forall has an (Eq a) constraint.  Whereas in general, each constraint 
1067                 -- in the context of a for-all must mention at least one quantified
1068                 -- type variable.  What a mess!
1069
1070
1071 ---------------------------------------------------------------------
1072 resultTypeMisMatch field_name con1 con2
1073   = vcat [sep [ptext SLIT("Constructors") <+> ppr con1 <+> ptext SLIT("and") <+> ppr con2, 
1074                 ptext SLIT("have a common field") <+> quotes (ppr field_name) <> comma],
1075           nest 2 $ ptext SLIT("but have different result types")]
1076 fieldTypeMisMatch field_name con1 con2
1077   = sep [ptext SLIT("Constructors") <+> ppr con1 <+> ptext SLIT("and") <+> ppr con2, 
1078          ptext SLIT("give different types for field"), quotes (ppr field_name)]
1079
1080 dataConCtxt con = ptext SLIT("In the definition of data constructor") <+> quotes (ppr con)
1081
1082 classOpCtxt sel_id tau = sep [ptext SLIT("When checking the class method:"),
1083                               nest 2 (ppr sel_id <+> dcolon <+> ppr tau)]
1084
1085 nullaryClassErr cls
1086   = ptext SLIT("No parameters for class")  <+> quotes (ppr cls)
1087
1088 classArityErr cls
1089   = vcat [ptext SLIT("Too many parameters for class") <+> quotes (ppr cls),
1090           parens (ptext SLIT("Use -fglasgow-exts to allow multi-parameter classes"))]
1091
1092 noClassTyVarErr clas op
1093   = sep [ptext SLIT("The class method") <+> quotes (ppr op),
1094          ptext SLIT("mentions none of the type variables of the class") <+> 
1095                 ppr clas <+> hsep (map ppr (classTyVars clas))]
1096
1097 genericMultiParamErr clas
1098   = ptext SLIT("The multi-parameter class") <+> quotes (ppr clas) <+> 
1099     ptext SLIT("cannot have generic methods")
1100
1101 badGenericMethodType op op_ty
1102   = hang (ptext SLIT("Generic method type is too complex"))
1103        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
1104                 ptext SLIT("You can only use type variables, arrows, lists, and tuples")])
1105
1106 recSynErr syn_decls
1107   = setSrcSpan (getLoc (head sorted_decls)) $
1108     addErr (sep [ptext SLIT("Cycle in type synonym declarations:"),
1109                  nest 2 (vcat (map ppr_decl sorted_decls))])
1110   where
1111     sorted_decls = sortLocated syn_decls
1112     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr decl
1113
1114 recClsErr cls_decls
1115   = setSrcSpan (getLoc (head sorted_decls)) $
1116     addErr (sep [ptext SLIT("Cycle in class declarations (via superclasses):"),
1117                  nest 2 (vcat (map ppr_decl sorted_decls))])
1118   where
1119     sorted_decls = sortLocated cls_decls
1120     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr (decl { tcdSigs = [] })
1121
1122 sortLocated :: [Located a] -> [Located a]
1123 sortLocated things = sortLe le things
1124   where
1125     le (L l1 _) (L l2 _) = l1 <= l2
1126
1127 badDataConTyCon data_con
1128   = hang (ptext SLIT("Data constructor") <+> quotes (ppr data_con) <+>
1129                 ptext SLIT("returns type") <+> quotes (ppr (dataConTyCon data_con)))
1130        2 (ptext SLIT("instead of its parent type"))
1131
1132 badGadtDecl tc_name
1133   = vcat [ ptext SLIT("Illegal generalised algebraic data declaration for") <+> quotes (ppr tc_name)
1134          , nest 2 (parens $ ptext SLIT("Use -fglasgow-exts to allow GADTs")) ]
1135
1136 badStupidTheta tc_name
1137   = ptext SLIT("A data type declared in GADT style cannot have a context:") <+> quotes (ppr tc_name)
1138
1139 newtypeConError tycon n
1140   = sep [ptext SLIT("A newtype must have exactly one constructor,"),
1141          nest 2 $ ptext SLIT("but") <+> quotes (ppr tycon) <+> ptext SLIT("has") <+> speakN n ]
1142
1143 newtypeExError con
1144   = sep [ptext SLIT("A newtype constructor cannot have an existential context,"),
1145          nest 2 $ ptext SLIT("but") <+> quotes (ppr con) <+> ptext SLIT("does")]
1146
1147 newtypeFieldErr con_name n_flds
1148   = sep [ptext SLIT("The constructor of a newtype must have exactly one field"), 
1149          nest 2 $ ptext SLIT("but") <+> quotes (ppr con_name) <+> ptext SLIT("has") <+> speakN n_flds]
1150
1151 badSigTyDecl tc_name
1152   = vcat [ ptext SLIT("Illegal kind signature") <+>
1153            quotes (ppr tc_name)
1154          , nest 2 (parens $ ptext SLIT("Use -fglasgow-exts to allow indexed types")) ]
1155
1156 badKindSigCtxt tc_name
1157   = vcat [ ptext SLIT("Illegal context in kind signature") <+>
1158            quotes (ppr tc_name)
1159          , nest 2 (parens $ ptext SLIT("Currently, kind signatures cannot have a context")) ]
1160
1161 badIdxTyDecl tc_name
1162   = vcat [ ptext SLIT("Illegal indexed type instance for") <+>
1163            quotes (ppr tc_name)
1164          , nest 2 (parens $ ptext SLIT("Use -fglasgow-exts to allow indexed types")) ]
1165
1166 badGadtIdxTyDecl tc_name
1167   = vcat [ ptext SLIT("Illegal generalised algebraic data declaration for") <+>
1168            quotes (ppr tc_name)
1169          , nest 2 (parens $ ptext SLIT("Indexed types cannot use GADT declarations")) ]
1170
1171 tooManyParmsErr tc_name
1172   = ptext SLIT("Indexed type instance has too many parameters:") <+> 
1173     quotes (ppr tc_name)
1174
1175 tooFewParmsErr tc_name
1176   = ptext SLIT("Indexed type instance has too few parameters:") <+> 
1177     quotes (ppr tc_name)
1178
1179 badBootTyIdxDeclErr = 
1180   ptext SLIT("Illegal indexed type instance in hs-boot file")
1181
1182 wrongKindOfFamily family =
1183   ptext SLIT("Wrong category of type instance; declaration was for a") <+>
1184   kindOfFamily
1185   where
1186     kindOfFamily | isSynTyCon  family = ptext SLIT("type synonym")
1187                  | isDataTyCon family = ptext SLIT("data type")
1188                  | isNewTyCon  family = ptext SLIT("newtype")
1189
1190 emptyConDeclsErr tycon
1191   = sep [quotes (ppr tycon) <+> ptext SLIT("has no constructors"),
1192          nest 2 $ ptext SLIT("(-fglasgow-exts permits this)")]
1193 \end{code}