Add 'hadrian/' from commit '45f3bff7016a2a0cd9a5455a882ced984655e90b'
[ghc.git] / libraries / base / Text / ParserCombinators / ReadPrec.hs
1 {-# LANGUAGE Trustworthy #-}
2 {-# LANGUAGE NoImplicitPrelude #-}
3
4 -----------------------------------------------------------------------------
5 -- |
6 -- Module : Text.ParserCombinators.ReadPrec
7 -- Copyright : (c) The University of Glasgow 2002
8 -- License : BSD-style (see the file libraries/base/LICENSE)
9 --
10 -- Maintainer : libraries@haskell.org
11 -- Stability : provisional
12 -- Portability : non-portable (uses Text.ParserCombinators.ReadP)
13 --
14 -- This library defines parser combinators for precedence parsing.
15
16 -----------------------------------------------------------------------------
17
18 module Text.ParserCombinators.ReadPrec
19 (
20 ReadPrec,
21
22 -- * Precedences
23 Prec,
24 minPrec,
25
26 -- * Precedence operations
27 lift,
28 prec,
29 step,
30 reset,
31
32 -- * Other operations
33 -- | All are based directly on their similarly-named 'ReadP' counterparts.
34 get,
35 look,
36 (+++),
37 (<++),
38 pfail,
39 choice,
40
41 -- * Converters
42 readPrec_to_P,
43 readP_to_Prec,
44 readPrec_to_S,
45 readS_to_Prec,
46 )
47 where
48
49
50 import Text.ParserCombinators.ReadP
51 ( ReadP
52 , ReadS
53 , readP_to_S
54 , readS_to_P
55 )
56
57 import qualified Text.ParserCombinators.ReadP as ReadP
58 ( get
59 , look
60 , (+++), (<++)
61 , pfail
62 )
63
64 import GHC.Num( Num(..) )
65 import GHC.Base
66
67 import qualified Control.Monad.Fail as MonadFail
68
69 -- ---------------------------------------------------------------------------
70 -- The readPrec type
71
72 newtype ReadPrec a = P (Prec -> ReadP a)
73
74 -- Functor, Monad, MonadPlus
75
76 -- | @since 2.01
77 instance Functor ReadPrec where
78 fmap h (P f) = P (\n -> fmap h (f n))
79
80 -- | @since 4.6.0.0
81 instance Applicative ReadPrec where
82 pure x = P (\_ -> pure x)
83 (<*>) = ap
84 liftA2 = liftM2
85
86 -- | @since 2.01
87 instance Monad ReadPrec where
88 fail s = P (\_ -> fail s)
89 P f >>= k = P (\n -> do a <- f n; let P f' = k a in f' n)
90
91 -- | @since 4.9.0.0
92 instance MonadFail.MonadFail ReadPrec where
93 fail s = P (\_ -> MonadFail.fail s)
94
95 -- | @since 2.01
96 instance MonadPlus ReadPrec
97
98 -- | @since 4.6.0.0
99 instance Alternative ReadPrec where
100 empty = pfail
101 (<|>) = (+++)
102
103 -- precedences
104 type Prec = Int
105
106 minPrec :: Prec
107 minPrec = 0
108
109 -- ---------------------------------------------------------------------------
110 -- Operations over ReadPrec
111
112 lift :: ReadP a -> ReadPrec a
113 -- ^ Lift a precedence-insensitive 'ReadP' to a 'ReadPrec'.
114 lift m = P (\_ -> m)
115
116 step :: ReadPrec a -> ReadPrec a
117 -- ^ Increases the precedence context by one.
118 step (P f) = P (\n -> f (n+1))
119
120 reset :: ReadPrec a -> ReadPrec a
121 -- ^ Resets the precedence context to zero.
122 reset (P f) = P (\_ -> f minPrec)
123
124 prec :: Prec -> ReadPrec a -> ReadPrec a
125 -- ^ @(prec n p)@ checks whether the precedence context is
126 -- less than or equal to @n@, and
127 --
128 -- * if not, fails
129 --
130 -- * if so, parses @p@ in context @n@.
131 prec n (P f) = P (\c -> if c <= n then f n else ReadP.pfail)
132
133 -- ---------------------------------------------------------------------------
134 -- Derived operations
135
136 get :: ReadPrec Char
137 -- ^ Consumes and returns the next character.
138 -- Fails if there is no input left.
139 get = lift ReadP.get
140
141 look :: ReadPrec String
142 -- ^ Look-ahead: returns the part of the input that is left, without
143 -- consuming it.
144 look = lift ReadP.look
145
146 (+++) :: ReadPrec a -> ReadPrec a -> ReadPrec a
147 -- ^ Symmetric choice.
148 P f1 +++ P f2 = P (\n -> f1 n ReadP.+++ f2 n)
149
150 (<++) :: ReadPrec a -> ReadPrec a -> ReadPrec a
151 -- ^ Local, exclusive, left-biased choice: If left parser
152 -- locally produces any result at all, then right parser is
153 -- not used.
154 P f1 <++ P f2 = P (\n -> f1 n ReadP.<++ f2 n)
155
156 pfail :: ReadPrec a
157 -- ^ Always fails.
158 pfail = lift ReadP.pfail
159
160 choice :: [ReadPrec a] -> ReadPrec a
161 -- ^ Combines all parsers in the specified list.
162 choice ps = foldr (+++) pfail ps
163
164 -- ---------------------------------------------------------------------------
165 -- Converting between ReadPrec and Read
166
167 readPrec_to_P :: ReadPrec a -> (Int -> ReadP a)
168 readPrec_to_P (P f) = f
169
170 readP_to_Prec :: (Int -> ReadP a) -> ReadPrec a
171 readP_to_Prec f = P f
172
173 readPrec_to_S :: ReadPrec a -> (Int -> ReadS a)
174 readPrec_to_S (P f) n = readP_to_S (f n)
175
176 readS_to_Prec :: (Int -> ReadS a) -> ReadPrec a
177 readS_to_Prec f = P (\n -> readS_to_P (f n))
178