Fix bogus comment
[ghc.git] / compiler / simplCore / Simplify.lhs
1 %
2 % (c) The AQUA Project, Glasgow University, 1993-1998
3 %
4 \section[Simplify]{The main module of the simplifier}
5
6 \begin{code}
7 {-# LANGUAGE CPP #-}
8
9 module Simplify ( simplTopBinds, simplExpr ) where
10
11 #include "HsVersions.h"
12
13 import DynFlags
14 import SimplMonad
15 import Type hiding      ( substTy, extendTvSubst, substTyVar )
16 import SimplEnv
17 import SimplUtils
18 import FamInstEnv       ( FamInstEnv )
19 import Literal          ( litIsLifted ) --, mkMachInt ) -- temporalily commented out. See #8326
20 import Id
21 import MkId             ( seqId, voidPrimId )
22 import MkCore           ( mkImpossibleExpr, castBottomExpr )
23 import IdInfo
24 import Name             ( mkSystemVarName, isExternalName )
25 import Coercion hiding  ( substCo, substTy, substCoVar, extendTvSubst )
26 import OptCoercion      ( optCoercion )
27 import FamInstEnv       ( topNormaliseType_maybe )
28 import DataCon          ( DataCon, dataConWorkId, dataConRepStrictness
29                         , isMarkedStrict ) --, dataConTyCon, dataConTag, fIRST_TAG )
30 --import TyCon            ( isEnumerationTyCon ) -- temporalily commented out. See #8326
31 import CoreMonad        ( Tick(..), SimplifierMode(..) )
32 import CoreSyn
33 import Demand           ( StrictSig(..), dmdTypeDepth, isStrictDmd )
34 import PprCore          ( pprParendExpr, pprCoreExpr )
35 import CoreUnfold
36 import CoreUtils
37 import CoreArity
38 --import PrimOp           ( tagToEnumKey ) -- temporalily commented out. See #8326
39 import Rules            ( lookupRule, getRules )
40 import TysPrim          ( voidPrimTy ) --, intPrimTy ) -- temporalily commented out. See #8326
41 import BasicTypes       ( TopLevelFlag(..), isTopLevel, RecFlag(..) )
42 import MonadUtils       ( foldlM, mapAccumLM, liftIO )
43 import Maybes           ( orElse )
44 --import Unique           ( hasKey ) -- temporalily commented out. See #8326
45 import Control.Monad
46 import Data.List        ( mapAccumL )
47 import Outputable
48 import FastString
49 import Pair
50 import Util
51 import ErrUtils
52 \end{code}
53
54
55 The guts of the simplifier is in this module, but the driver loop for
56 the simplifier is in SimplCore.lhs.
57
58
59 -----------------------------------------
60         *** IMPORTANT NOTE ***
61 -----------------------------------------
62 The simplifier used to guarantee that the output had no shadowing, but
63 it does not do so any more.   (Actually, it never did!)  The reason is
64 documented with simplifyArgs.
65
66
67 -----------------------------------------
68         *** IMPORTANT NOTE ***
69 -----------------------------------------
70 Many parts of the simplifier return a bunch of "floats" as well as an
71 expression. This is wrapped as a datatype SimplUtils.FloatsWith.
72
73 All "floats" are let-binds, not case-binds, but some non-rec lets may
74 be unlifted (with RHS ok-for-speculation).
75
76
77
78 -----------------------------------------
79         ORGANISATION OF FUNCTIONS
80 -----------------------------------------
81 simplTopBinds
82   - simplify all top-level binders
83   - for NonRec, call simplRecOrTopPair
84   - for Rec,    call simplRecBind
85
86
87         ------------------------------
88 simplExpr (applied lambda)      ==> simplNonRecBind
89 simplExpr (Let (NonRec ...) ..) ==> simplNonRecBind
90 simplExpr (Let (Rec ...)    ..) ==> simplify binders; simplRecBind
91
92         ------------------------------
93 simplRecBind    [binders already simplfied]
94   - use simplRecOrTopPair on each pair in turn
95
96 simplRecOrTopPair [binder already simplified]
97   Used for: recursive bindings (top level and nested)
98             top-level non-recursive bindings
99   Returns:
100   - check for PreInlineUnconditionally
101   - simplLazyBind
102
103 simplNonRecBind
104   Used for: non-top-level non-recursive bindings
105             beta reductions (which amount to the same thing)
106   Because it can deal with strict arts, it takes a
107         "thing-inside" and returns an expression
108
109   - check for PreInlineUnconditionally
110   - simplify binder, including its IdInfo
111   - if strict binding
112         simplStrictArg
113         mkAtomicArgs
114         completeNonRecX
115     else
116         simplLazyBind
117         addFloats
118
119 simplNonRecX:   [given a *simplified* RHS, but an *unsimplified* binder]
120   Used for: binding case-binder and constr args in a known-constructor case
121   - check for PreInLineUnconditionally
122   - simplify binder
123   - completeNonRecX
124
125         ------------------------------
126 simplLazyBind:  [binder already simplified, RHS not]
127   Used for: recursive bindings (top level and nested)
128             top-level non-recursive bindings
129             non-top-level, but *lazy* non-recursive bindings
130         [must not be strict or unboxed]
131   Returns floats + an augmented environment, not an expression
132   - substituteIdInfo and add result to in-scope
133         [so that rules are available in rec rhs]
134   - simplify rhs
135   - mkAtomicArgs
136   - float if exposes constructor or PAP
137   - completeBind
138
139
140 completeNonRecX:        [binder and rhs both simplified]
141   - if the the thing needs case binding (unlifted and not ok-for-spec)
142         build a Case
143    else
144         completeBind
145         addFloats
146
147 completeBind:   [given a simplified RHS]
148         [used for both rec and non-rec bindings, top level and not]
149   - try PostInlineUnconditionally
150   - add unfolding [this is the only place we add an unfolding]
151   - add arity
152
153
154
155 Right hand sides and arguments
156 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
157 In many ways we want to treat
158         (a) the right hand side of a let(rec), and
159         (b) a function argument
160 in the same way.  But not always!  In particular, we would
161 like to leave these arguments exactly as they are, so they
162 will match a RULE more easily.
163
164         f (g x, h x)
165         g (+ x)
166
167 It's harder to make the rule match if we ANF-ise the constructor,
168 or eta-expand the PAP:
169
170         f (let { a = g x; b = h x } in (a,b))
171         g (\y. + x y)
172
173 On the other hand if we see the let-defns
174
175         p = (g x, h x)
176         q = + x
177
178 then we *do* want to ANF-ise and eta-expand, so that p and q
179 can be safely inlined.
180
181 Even floating lets out is a bit dubious.  For let RHS's we float lets
182 out if that exposes a value, so that the value can be inlined more vigorously.
183 For example
184
185         r = let x = e in (x,x)
186
187 Here, if we float the let out we'll expose a nice constructor. We did experiments
188 that showed this to be a generally good thing.  But it was a bad thing to float
189 lets out unconditionally, because that meant they got allocated more often.
190
191 For function arguments, there's less reason to expose a constructor (it won't
192 get inlined).  Just possibly it might make a rule match, but I'm pretty skeptical.
193 So for the moment we don't float lets out of function arguments either.
194
195
196 Eta expansion
197 ~~~~~~~~~~~~~~
198 For eta expansion, we want to catch things like
199
200         case e of (a,b) -> \x -> case a of (p,q) -> \y -> r
201
202 If the \x was on the RHS of a let, we'd eta expand to bring the two
203 lambdas together.  And in general that's a good thing to do.  Perhaps
204 we should eta expand wherever we find a (value) lambda?  Then the eta
205 expansion at a let RHS can concentrate solely on the PAP case.
206
207
208 %************************************************************************
209 %*                                                                      *
210 \subsection{Bindings}
211 %*                                                                      *
212 %************************************************************************
213
214 \begin{code}
215 simplTopBinds :: SimplEnv -> [InBind] -> SimplM SimplEnv
216
217 simplTopBinds env0 binds0
218   = do  {       -- Put all the top-level binders into scope at the start
219                 -- so that if a transformation rule has unexpectedly brought
220                 -- anything into scope, then we don't get a complaint about that.
221                 -- It's rather as if the top-level binders were imported.
222                 -- See note [Glomming] in OccurAnal.
223         ; env1 <- simplRecBndrs env0 (bindersOfBinds binds0)
224         ; env2 <- simpl_binds env1 binds0
225         ; freeTick SimplifierDone
226         ; return env2 }
227   where
228         -- We need to track the zapped top-level binders, because
229         -- they should have their fragile IdInfo zapped (notably occurrence info)
230         -- That's why we run down binds and bndrs' simultaneously.
231         --
232     simpl_binds :: SimplEnv -> [InBind] -> SimplM SimplEnv
233     simpl_binds env []           = return env
234     simpl_binds env (bind:binds) = do { env' <- simpl_bind env bind
235                                       ; simpl_binds env' binds }
236
237     simpl_bind env (Rec pairs)  = simplRecBind      env  TopLevel pairs
238     simpl_bind env (NonRec b r) = simplRecOrTopPair env' TopLevel NonRecursive b b' r
239         where
240           (env', b') = addBndrRules env b (lookupRecBndr env b)
241 \end{code}
242
243
244 %************************************************************************
245 %*                                                                      *
246 \subsection{Lazy bindings}
247 %*                                                                      *
248 %************************************************************************
249
250 simplRecBind is used for
251         * recursive bindings only
252
253 \begin{code}
254 simplRecBind :: SimplEnv -> TopLevelFlag
255              -> [(InId, InExpr)]
256              -> SimplM SimplEnv
257 simplRecBind env0 top_lvl pairs0
258   = do  { let (env_with_info, triples) = mapAccumL add_rules env0 pairs0
259         ; env1 <- go (zapFloats env_with_info) triples
260         ; return (env0 `addRecFloats` env1) }
261         -- addFloats adds the floats from env1,
262         -- _and_ updates env0 with the in-scope set from env1
263   where
264     add_rules :: SimplEnv -> (InBndr,InExpr) -> (SimplEnv, (InBndr, OutBndr, InExpr))
265         -- Add the (substituted) rules to the binder
266     add_rules env (bndr, rhs) = (env', (bndr, bndr', rhs))
267         where
268           (env', bndr') = addBndrRules env bndr (lookupRecBndr env bndr)
269
270     go env [] = return env
271
272     go env ((old_bndr, new_bndr, rhs) : pairs)
273         = do { env' <- simplRecOrTopPair env top_lvl Recursive old_bndr new_bndr rhs
274              ; go env' pairs }
275 \end{code}
276
277 simplOrTopPair is used for
278         * recursive bindings (whether top level or not)
279         * top-level non-recursive bindings
280
281 It assumes the binder has already been simplified, but not its IdInfo.
282
283 \begin{code}
284 simplRecOrTopPair :: SimplEnv
285                   -> TopLevelFlag -> RecFlag
286                   -> InId -> OutBndr -> InExpr  -- Binder and rhs
287                   -> SimplM SimplEnv    -- Returns an env that includes the binding
288
289 simplRecOrTopPair env top_lvl is_rec old_bndr new_bndr rhs
290   = do { dflags <- getDynFlags
291        ; trace_bind dflags $
292            if preInlineUnconditionally dflags env top_lvl old_bndr rhs
293                     -- Check for unconditional inline
294            then do tick (PreInlineUnconditionally old_bndr)
295                    return (extendIdSubst env old_bndr (mkContEx env rhs))
296            else simplLazyBind env top_lvl is_rec old_bndr new_bndr rhs env }
297   where
298     trace_bind dflags thing_inside
299       | not (dopt Opt_D_verbose_core2core dflags)
300       = thing_inside
301       | otherwise
302       = pprTrace "SimplBind" (ppr old_bndr) thing_inside
303         -- trace_bind emits a trace for each top-level binding, which
304         -- helps to locate the tracing for inlining and rule firing
305 \end{code}
306
307
308 simplLazyBind is used for
309   * [simplRecOrTopPair] recursive bindings (whether top level or not)
310   * [simplRecOrTopPair] top-level non-recursive bindings
311   * [simplNonRecE]      non-top-level *lazy* non-recursive bindings
312
313 Nota bene:
314     1. It assumes that the binder is *already* simplified,
315        and is in scope, and its IdInfo too, except unfolding
316
317     2. It assumes that the binder type is lifted.
318
319     3. It does not check for pre-inline-unconditionallly;
320        that should have been done already.
321
322 \begin{code}
323 simplLazyBind :: SimplEnv
324               -> TopLevelFlag -> RecFlag
325               -> InId -> OutId          -- Binder, both pre-and post simpl
326                                         -- The OutId has IdInfo, except arity, unfolding
327               -> InExpr -> SimplEnv     -- The RHS and its environment
328               -> SimplM SimplEnv
329 -- Precondition: rhs obeys the let/app invariant
330 simplLazyBind env top_lvl is_rec bndr bndr1 rhs rhs_se
331   = -- pprTrace "simplLazyBind" ((ppr bndr <+> ppr bndr1) $$ ppr rhs $$ ppr (seIdSubst rhs_se)) $
332     do  { let   rhs_env     = rhs_se `setInScope` env
333                 (tvs, body) = case collectTyBinders rhs of
334                                 (tvs, body) | not_lam body -> (tvs,body)
335                                             | otherwise    -> ([], rhs)
336                 not_lam (Lam _ _) = False
337                 not_lam _         = True
338                         -- Do not do the "abstract tyyvar" thing if there's
339                         -- a lambda inside, because it defeats eta-reduction
340                         --    f = /\a. \x. g a x
341                         -- should eta-reduce
342
343
344         ; (body_env, tvs') <- simplBinders rhs_env tvs
345                 -- See Note [Floating and type abstraction] in SimplUtils
346
347         -- Simplify the RHS
348         ; let   rhs_cont = mkRhsStop (substTy body_env (exprType body))
349         ; (body_env1, body1) <- simplExprF body_env body rhs_cont
350         -- ANF-ise a constructor or PAP rhs
351         ; (body_env2, body2) <- prepareRhs top_lvl body_env1 bndr1 body1
352
353         ; (env', rhs')
354             <-  if not (doFloatFromRhs top_lvl is_rec False body2 body_env2)
355                 then                            -- No floating, revert to body1
356                      do { rhs' <- mkLam tvs' (wrapFloats body_env1 body1) rhs_cont
357                         ; return (env, rhs') }
358
359                 else if null tvs then           -- Simple floating
360                      do { tick LetFloatFromLet
361                         ; return (addFloats env body_env2, body2) }
362
363                 else                            -- Do type-abstraction first
364                      do { tick LetFloatFromLet
365                         ; (poly_binds, body3) <- abstractFloats tvs' body_env2 body2
366                         ; rhs' <- mkLam tvs' body3 rhs_cont
367                         ; env' <- foldlM (addPolyBind top_lvl) env poly_binds
368                         ; return (env', rhs') }
369
370         ; completeBind env' top_lvl bndr bndr1 rhs' }
371 \end{code}
372
373 A specialised variant of simplNonRec used when the RHS is already simplified,
374 notably in knownCon.  It uses case-binding where necessary.
375
376 \begin{code}
377 simplNonRecX :: SimplEnv
378              -> InId            -- Old binder
379              -> OutExpr         -- Simplified RHS
380              -> SimplM SimplEnv
381 -- Precondition: rhs satisfies the let/app invariant
382 simplNonRecX env bndr new_rhs
383   | isDeadBinder bndr   -- Not uncommon; e.g. case (a,b) of c { (p,q) -> p }
384   = return env    --  Here c is dead, and we avoid creating
385                   --   the binding c = (a,b)
386
387   | Coercion co <- new_rhs
388   = return (extendCvSubst env bndr co)
389
390   | otherwise
391   = do  { (env', bndr') <- simplBinder env bndr
392         ; completeNonRecX NotTopLevel env' (isStrictId bndr) bndr bndr' new_rhs }
393                 -- simplNonRecX is only used for NotTopLevel things
394
395 completeNonRecX :: TopLevelFlag -> SimplEnv
396                 -> Bool
397                 -> InId                 -- Old binder
398                 -> OutId                -- New binder
399                 -> OutExpr              -- Simplified RHS
400                 -> SimplM SimplEnv
401 -- Precondition: rhs satisfies the let/app invariant
402 --               See Note [CoreSyn let/app invariant] in CoreSyn
403
404 completeNonRecX top_lvl env is_strict old_bndr new_bndr new_rhs
405   = do  { (env1, rhs1) <- prepareRhs top_lvl (zapFloats env) new_bndr new_rhs
406         ; (env2, rhs2) <-
407                 if doFloatFromRhs NotTopLevel NonRecursive is_strict rhs1 env1
408                 then do { tick LetFloatFromLet
409                         ; return (addFloats env env1, rhs1) }   -- Add the floats to the main env
410                 else return (env, wrapFloats env1 rhs1)         -- Wrap the floats around the RHS
411         ; completeBind env2 NotTopLevel old_bndr new_bndr rhs2 }
412 \end{code}
413
414 {- No, no, no!  Do not try preInlineUnconditionally in completeNonRecX
415    Doing so risks exponential behaviour, because new_rhs has been simplified once already
416    In the cases described by the folowing commment, postInlineUnconditionally will
417    catch many of the relevant cases.
418         -- This happens; for example, the case_bndr during case of
419         -- known constructor:  case (a,b) of x { (p,q) -> ... }
420         -- Here x isn't mentioned in the RHS, so we don't want to
421         -- create the (dead) let-binding  let x = (a,b) in ...
422         --
423         -- Similarly, single occurrences can be inlined vigourously
424         -- e.g.  case (f x, g y) of (a,b) -> ....
425         -- If a,b occur once we can avoid constructing the let binding for them.
426
427    Furthermore in the case-binding case preInlineUnconditionally risks extra thunks
428         -- Consider     case I# (quotInt# x y) of
429         --                I# v -> let w = J# v in ...
430         -- If we gaily inline (quotInt# x y) for v, we end up building an
431         -- extra thunk:
432         --                let w = J# (quotInt# x y) in ...
433         -- because quotInt# can fail.
434
435   | preInlineUnconditionally env NotTopLevel bndr new_rhs
436   = thing_inside (extendIdSubst env bndr (DoneEx new_rhs))
437 -}
438
439 ----------------------------------
440 prepareRhs takes a putative RHS, checks whether it's a PAP or
441 constructor application and, if so, converts it to ANF, so that the
442 resulting thing can be inlined more easily.  Thus
443         x = (f a, g b)
444 becomes
445         t1 = f a
446         t2 = g b
447         x = (t1,t2)
448
449 We also want to deal well cases like this
450         v = (f e1 `cast` co) e2
451 Here we want to make e1,e2 trivial and get
452         x1 = e1; x2 = e2; v = (f x1 `cast` co) v2
453 That's what the 'go' loop in prepareRhs does
454
455 \begin{code}
456 prepareRhs :: TopLevelFlag -> SimplEnv -> OutId -> OutExpr -> SimplM (SimplEnv, OutExpr)
457 -- Adds new floats to the env iff that allows us to return a good RHS
458 prepareRhs top_lvl env id (Cast rhs co)    -- Note [Float coercions]
459   | Pair ty1 _ty2 <- coercionKind co       -- Do *not* do this if rhs has an unlifted type
460   , not (isUnLiftedType ty1)            -- see Note [Float coercions (unlifted)]
461   = do  { (env', rhs') <- makeTrivialWithInfo top_lvl env sanitised_info rhs
462         ; return (env', Cast rhs' co) }
463   where
464     sanitised_info = vanillaIdInfo `setStrictnessInfo` strictnessInfo info
465                                    `setDemandInfo` demandInfo info
466     info = idInfo id
467
468 prepareRhs top_lvl env0 _ rhs0
469   = do  { (_is_exp, env1, rhs1) <- go 0 env0 rhs0
470         ; return (env1, rhs1) }
471   where
472     go n_val_args env (Cast rhs co)
473         = do { (is_exp, env', rhs') <- go n_val_args env rhs
474              ; return (is_exp, env', Cast rhs' co) }
475     go n_val_args env (App fun (Type ty))
476         = do { (is_exp, env', rhs') <- go n_val_args env fun
477              ; return (is_exp, env', App rhs' (Type ty)) }
478     go n_val_args env (App fun arg)
479         = do { (is_exp, env', fun') <- go (n_val_args+1) env fun
480              ; case is_exp of
481                 True -> do { (env'', arg') <- makeTrivial top_lvl env' arg
482                            ; return (True, env'', App fun' arg') }
483                 False -> return (False, env, App fun arg) }
484     go n_val_args env (Var fun)
485         = return (is_exp, env, Var fun)
486         where
487           is_exp = isExpandableApp fun n_val_args   -- The fun a constructor or PAP
488                         -- See Note [CONLIKE pragma] in BasicTypes
489                         -- The definition of is_exp should match that in
490                         -- OccurAnal.occAnalApp
491
492     go _ env other
493         = return (False, env, other)
494 \end{code}
495
496
497 Note [Float coercions]
498 ~~~~~~~~~~~~~~~~~~~~~~
499 When we find the binding
500         x = e `cast` co
501 we'd like to transform it to
502         x' = e
503         x = x `cast` co         -- A trivial binding
504 There's a chance that e will be a constructor application or function, or something
505 like that, so moving the coerion to the usage site may well cancel the coersions
506 and lead to further optimisation.  Example:
507
508      data family T a :: *
509      data instance T Int = T Int
510
511      foo :: Int -> Int -> Int
512      foo m n = ...
513         where
514           x = T m
515           go 0 = 0
516           go n = case x of { T m -> go (n-m) }
517                 -- This case should optimise
518
519 Note [Preserve strictness when floating coercions]
520 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
521 In the Note [Float coercions] transformation, keep the strictness info.
522 Eg
523         f = e `cast` co    -- f has strictness SSL
524 When we transform to
525         f' = e             -- f' also has strictness SSL
526         f = f' `cast` co   -- f still has strictness SSL
527
528 Its not wrong to drop it on the floor, but better to keep it.
529
530 Note [Float coercions (unlifted)]
531 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
532 BUT don't do [Float coercions] if 'e' has an unlifted type.
533 This *can* happen:
534
535      foo :: Int = (error (# Int,Int #) "urk")
536                   `cast` CoUnsafe (# Int,Int #) Int
537
538 If do the makeTrivial thing to the error call, we'll get
539     foo = case error (# Int,Int #) "urk" of v -> v `cast` ...
540 But 'v' isn't in scope!
541
542 These strange casts can happen as a result of case-of-case
543         bar = case (case x of { T -> (# 2,3 #); F -> error "urk" }) of
544                 (# p,q #) -> p+q
545
546
547 \begin{code}
548 makeTrivialArg :: SimplEnv -> ArgSpec -> SimplM (SimplEnv, ArgSpec)
549 makeTrivialArg env (ValArg e)  = do { (env', e') <- makeTrivial NotTopLevel env e
550                                     ; return (env', ValArg e') }
551 makeTrivialArg env (CastBy co) = return (env, CastBy co)
552
553 makeTrivial :: TopLevelFlag -> SimplEnv -> OutExpr -> SimplM (SimplEnv, OutExpr)
554 -- Binds the expression to a variable, if it's not trivial, returning the variable
555 makeTrivial top_lvl env expr = makeTrivialWithInfo top_lvl env vanillaIdInfo expr
556
557 makeTrivialWithInfo :: TopLevelFlag -> SimplEnv -> IdInfo
558                     -> OutExpr -> SimplM (SimplEnv, OutExpr)
559 -- Propagate strictness and demand info to the new binder
560 -- Note [Preserve strictness when floating coercions]
561 -- Returned SimplEnv has same substitution as incoming one
562 makeTrivialWithInfo top_lvl env info expr
563   | exprIsTrivial expr                          -- Already trivial
564   || not (bindingOk top_lvl expr expr_ty)       -- Cannot trivialise
565                                                 --   See Note [Cannot trivialise]
566   = return (env, expr)
567   | otherwise           -- See Note [Take care] below
568   = do  { uniq <- getUniqueM
569         ; let name = mkSystemVarName uniq (fsLit "a")
570               var = mkLocalIdWithInfo name expr_ty info
571         ; env'  <- completeNonRecX top_lvl env False var var expr
572         ; expr' <- simplVar env' var
573         ; return (env', expr') }
574         -- The simplVar is needed becase we're constructing a new binding
575         --     a = rhs
576         -- And if rhs is of form (rhs1 |> co), then we might get
577         --     a1 = rhs1
578         --     a = a1 |> co
579         -- and now a's RHS is trivial and can be substituted out, and that
580         -- is what completeNonRecX will do
581         -- To put it another way, it's as if we'd simplified
582         --    let var = e in var
583   where
584     expr_ty = exprType expr
585
586 bindingOk :: TopLevelFlag -> CoreExpr -> Type -> Bool
587 -- True iff we can have a binding of this expression at this level
588 -- Precondition: the type is the type of the expression
589 bindingOk top_lvl _ expr_ty
590   | isTopLevel top_lvl = not (isUnLiftedType expr_ty)
591   | otherwise          = True
592 \end{code}
593
594 Note [Cannot trivialise]
595 ~~~~~~~~~~~~~~~~~~~~~~~~
596 Consider tih
597    f :: Int -> Addr#
598
599    foo :: Bar
600    foo = Bar (f 3)
601
602 Then we can't ANF-ise foo, even though we'd like to, because
603 we can't make a top-level binding for the Addr# (f 3). And if
604 so we don't want to turn it into
605    foo = let x = f 3 in Bar x
606 because we'll just end up inlining x back, and that makes the
607 simplifier loop.  Better not to ANF-ise it at all.
608
609 A case in point is literal strings (a MachStr is not regarded as
610 trivial):
611
612    foo = Ptr "blob"#
613
614 We don't want to ANF-ise this.
615
616 %************************************************************************
617 %*                                                                      *
618 \subsection{Completing a lazy binding}
619 %*                                                                      *
620 %************************************************************************
621
622 completeBind
623   * deals only with Ids, not TyVars
624   * takes an already-simplified binder and RHS
625   * is used for both recursive and non-recursive bindings
626   * is used for both top-level and non-top-level bindings
627
628 It does the following:
629   - tries discarding a dead binding
630   - tries PostInlineUnconditionally
631   - add unfolding [this is the only place we add an unfolding]
632   - add arity
633
634 It does *not* attempt to do let-to-case.  Why?  Because it is used for
635   - top-level bindings (when let-to-case is impossible)
636   - many situations where the "rhs" is known to be a WHNF
637                 (so let-to-case is inappropriate).
638
639 Nor does it do the atomic-argument thing
640
641 \begin{code}
642 completeBind :: SimplEnv
643              -> TopLevelFlag            -- Flag stuck into unfolding
644              -> InId                    -- Old binder
645              -> OutId -> OutExpr        -- New binder and RHS
646              -> SimplM SimplEnv
647 -- completeBind may choose to do its work
648 --      * by extending the substitution (e.g. let x = y in ...)
649 --      * or by adding to the floats in the envt
650 --
651 -- Precondition: rhs obeys the let/app invariant
652 completeBind env top_lvl old_bndr new_bndr new_rhs
653  | isCoVar old_bndr
654  = case new_rhs of
655      Coercion co -> return (extendCvSubst env old_bndr co)
656      _           -> return (addNonRec env new_bndr new_rhs)
657
658  | otherwise
659  = ASSERT( isId new_bndr )
660    do { let old_info = idInfo old_bndr
661             old_unf  = unfoldingInfo old_info
662             occ_info = occInfo old_info
663
664         -- Do eta-expansion on the RHS of the binding
665         -- See Note [Eta-expanding at let bindings] in SimplUtils
666       ; (new_arity, final_rhs) <- tryEtaExpandRhs env new_bndr new_rhs
667
668         -- Simplify the unfolding
669       ; new_unfolding <- simplUnfolding env top_lvl old_bndr final_rhs old_unf
670
671       ; dflags <- getDynFlags
672       ; if postInlineUnconditionally dflags env top_lvl new_bndr occ_info
673                                      final_rhs new_unfolding
674
675                         -- Inline and discard the binding
676         then do  { tick (PostInlineUnconditionally old_bndr)
677                  ; return (extendIdSubst env old_bndr (DoneEx final_rhs)) }
678                 -- Use the substitution to make quite, quite sure that the
679                 -- substitution will happen, since we are going to discard the binding
680         else
681    do { let info1 = idInfo new_bndr `setArityInfo` new_arity
682
683               -- Unfolding info: Note [Setting the new unfolding]
684             info2 = info1 `setUnfoldingInfo` new_unfolding
685
686               -- Demand info: Note [Setting the demand info]
687               --
688               -- We also have to nuke demand info if for some reason
689               -- eta-expansion *reduces* the arity of the binding to less
690               -- than that of the strictness sig. This can happen: see Note [Arity decrease].
691             info3 | isEvaldUnfolding new_unfolding
692                     || (case strictnessInfo info2 of
693                           StrictSig dmd_ty -> new_arity < dmdTypeDepth dmd_ty)
694                   = zapDemandInfo info2 `orElse` info2
695                   | otherwise
696                   = info2
697
698             final_id = new_bndr `setIdInfo` info3
699
700       ; -- pprTrace "Binding" (ppr final_id <+> ppr new_unfolding) $
701         return (addNonRec env final_id final_rhs) } }
702                 -- The addNonRec adds it to the in-scope set too
703
704 ------------------------------
705 addPolyBind :: TopLevelFlag -> SimplEnv -> OutBind -> SimplM SimplEnv
706 -- Add a new binding to the environment, complete with its unfolding
707 -- but *do not* do postInlineUnconditionally, because we have already
708 -- processed some of the scope of the binding
709 -- We still want the unfolding though.  Consider
710 --      let
711 --            x = /\a. let y = ... in Just y
712 --      in body
713 -- Then we float the y-binding out (via abstractFloats and addPolyBind)
714 -- but 'x' may well then be inlined in 'body' in which case we'd like the
715 -- opportunity to inline 'y' too.
716 --
717 -- INVARIANT: the arity is correct on the incoming binders
718
719 addPolyBind top_lvl env (NonRec poly_id rhs)
720   = do  { unfolding <- simplUnfolding env top_lvl poly_id rhs noUnfolding
721                         -- Assumes that poly_id did not have an INLINE prag
722                         -- which is perhaps wrong.  ToDo: think about this
723         ; let final_id = setIdInfo poly_id $
724                          idInfo poly_id `setUnfoldingInfo` unfolding
725
726         ; return (addNonRec env final_id rhs) }
727
728 addPolyBind _ env bind@(Rec _)
729   = return (extendFloats env bind)
730         -- Hack: letrecs are more awkward, so we extend "by steam"
731         -- without adding unfoldings etc.  At worst this leads to
732         -- more simplifier iterations
733
734 ------------------------------
735 simplUnfolding :: SimplEnv-> TopLevelFlag
736                -> InId
737                -> OutExpr
738                -> Unfolding -> SimplM Unfolding
739 -- Note [Setting the new unfolding]
740 simplUnfolding env top_lvl id new_rhs unf
741   = case unf of
742       DFunUnfolding { df_bndrs = bndrs, df_con = con, df_args = args }
743         -> do { (env', bndrs') <- simplBinders rule_env bndrs
744               ; args' <- mapM (simplExpr env') args
745               ; return (mkDFunUnfolding bndrs' con args') }
746
747       CoreUnfolding { uf_tmpl = expr, uf_src = src, uf_guidance = guide }
748         | isStableSource src
749         -> do { expr' <- simplExpr rule_env expr
750               ; case guide of
751                   UnfWhen { ug_arity = arity, ug_unsat_ok = sat_ok }  -- Happens for INLINE things
752                      -> let guide' = UnfWhen { ug_arity = arity, ug_unsat_ok = sat_ok
753                                              , ug_boring_ok = inlineBoringOk expr' }
754                         -- Refresh the boring-ok flag, in case expr'
755                         -- has got small. This happens, notably in the inlinings
756                         -- for dfuns for single-method classes; see
757                         -- Note [Single-method classes] in TcInstDcls.
758                         -- A test case is Trac #4138
759                         in return (mkCoreUnfolding src is_top_lvl expr' guide')
760                             -- See Note [Top-level flag on inline rules] in CoreUnfold
761
762                   _other              -- Happens for INLINABLE things
763                      -> bottoming `seq` -- See Note [Force bottoming field]
764                         do { dflags <- getDynFlags
765                            ; return (mkUnfolding dflags src is_top_lvl bottoming expr') } }
766                 -- If the guidance is UnfIfGoodArgs, this is an INLINABLE
767                 -- unfolding, and we need to make sure the guidance is kept up
768                 -- to date with respect to any changes in the unfolding.
769
770       _other -> bottoming `seq`  -- See Note [Force bottoming field]
771                 do { dflags <- getDynFlags
772                    ; return (mkUnfolding dflags InlineRhs is_top_lvl bottoming new_rhs) }
773                      -- We make an  unfolding *even for loop-breakers*.
774                      -- Reason: (a) It might be useful to know that they are WHNF
775                      --         (b) In TidyPgm we currently assume that, if we want to
776                      --             expose the unfolding then indeed we *have* an unfolding
777                      --             to expose.  (We could instead use the RHS, but currently
778                      --             we don't.)  The simple thing is always to have one.
779   where
780     bottoming = isBottomingId id
781     is_top_lvl = isTopLevel top_lvl
782     act      = idInlineActivation id
783     rule_env = updMode (updModeForStableUnfoldings act) env
784                -- See Note [Simplifying inside stable unfoldings] in SimplUtils
785 \end{code}
786
787 Note [Force bottoming field]
788 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
789 We need to force bottoming, or the new unfolding holds
790 on to the old unfolding (which is part of the id).
791
792 Note [Arity decrease]
793 ~~~~~~~~~~~~~~~~~~~~~
794 Generally speaking the arity of a binding should not decrease.  But it *can*
795 legitimately happen because of RULES.  Eg
796         f = g Int
797 where g has arity 2, will have arity 2.  But if there's a rewrite rule
798         g Int --> h
799 where h has arity 1, then f's arity will decrease.  Here's a real-life example,
800 which is in the output of Specialise:
801
802      Rec {
803         $dm {Arity 2} = \d.\x. op d
804         {-# RULES forall d. $dm Int d = $s$dm #-}
805
806         dInt = MkD .... opInt ...
807         opInt {Arity 1} = $dm dInt
808
809         $s$dm {Arity 0} = \x. op dInt }
810
811 Here opInt has arity 1; but when we apply the rule its arity drops to 0.
812 That's why Specialise goes to a little trouble to pin the right arity
813 on specialised functions too.
814
815 Note [Setting the new unfolding]
816 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
817 * If there's an INLINE pragma, we simplify the RHS gently.  Maybe we
818   should do nothing at all, but simplifying gently might get rid of
819   more crap.
820
821 * If not, we make an unfolding from the new RHS.  But *only* for
822   non-loop-breakers. Making loop breakers not have an unfolding at all
823   means that we can avoid tests in exprIsConApp, for example.  This is
824   important: if exprIsConApp says 'yes' for a recursive thing, then we
825   can get into an infinite loop
826
827 If there's an stable unfolding on a loop breaker (which happens for
828 INLINEABLE), we hang on to the inlining.  It's pretty dodgy, but the
829 user did say 'INLINE'.  May need to revisit this choice.
830
831 Note [Setting the demand info]
832 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
833 If the unfolding is a value, the demand info may
834 go pear-shaped, so we nuke it.  Example:
835      let x = (a,b) in
836      case x of (p,q) -> h p q x
837 Here x is certainly demanded. But after we've nuked
838 the case, we'll get just
839      let x = (a,b) in h a b x
840 and now x is not demanded (I'm assuming h is lazy)
841 This really happens.  Similarly
842      let f = \x -> e in ...f..f...
843 After inlining f at some of its call sites the original binding may
844 (for example) be no longer strictly demanded.
845 The solution here is a bit ad hoc...
846
847
848 %************************************************************************
849 %*                                                                      *
850 \subsection[Simplify-simplExpr]{The main function: simplExpr}
851 %*                                                                      *
852 %************************************************************************
853
854 The reason for this OutExprStuff stuff is that we want to float *after*
855 simplifying a RHS, not before.  If we do so naively we get quadratic
856 behaviour as things float out.
857
858 To see why it's important to do it after, consider this (real) example:
859
860         let t = f x
861         in fst t
862 ==>
863         let t = let a = e1
864                     b = e2
865                 in (a,b)
866         in fst t
867 ==>
868         let a = e1
869             b = e2
870             t = (a,b)
871         in
872         a       -- Can't inline a this round, cos it appears twice
873 ==>
874         e1
875
876 Each of the ==> steps is a round of simplification.  We'd save a
877 whole round if we float first.  This can cascade.  Consider
878
879         let f = g d
880         in \x -> ...f...
881 ==>
882         let f = let d1 = ..d.. in \y -> e
883         in \x -> ...f...
884 ==>
885         let d1 = ..d..
886         in \x -> ...(\y ->e)...
887
888 Only in this second round can the \y be applied, and it
889 might do the same again.
890
891
892 \begin{code}
893 simplExpr :: SimplEnv -> CoreExpr -> SimplM CoreExpr
894 simplExpr env expr = simplExprC env expr (mkBoringStop expr_out_ty)
895   where
896     expr_out_ty :: OutType
897     expr_out_ty = substTy env (exprType expr)
898
899 simplExprC :: SimplEnv -> CoreExpr -> SimplCont -> SimplM CoreExpr
900         -- Simplify an expression, given a continuation
901 simplExprC env expr cont
902   = -- pprTrace "simplExprC" (ppr expr $$ ppr cont {- $$ ppr (seIdSubst env) -} $$ ppr (seFloats env) ) $
903     do  { (env', expr') <- simplExprF (zapFloats env) expr cont
904         ; -- pprTrace "simplExprC ret" (ppr expr $$ ppr expr') $
905           -- pprTrace "simplExprC ret3" (ppr (seInScope env')) $
906           -- pprTrace "simplExprC ret4" (ppr (seFloats env')) $
907           return (wrapFloats env' expr') }
908
909 --------------------------------------------------
910 simplExprF :: SimplEnv -> InExpr -> SimplCont
911            -> SimplM (SimplEnv, OutExpr)
912
913 simplExprF env e cont
914   = {- pprTrace "simplExprF" (vcat
915       [ ppr e
916       , text "cont =" <+> ppr cont
917       , text "inscope =" <+> ppr (seInScope env)
918       , text "tvsubst =" <+> ppr (seTvSubst env)
919       , text "idsubst =" <+> ppr (seIdSubst env)
920       , text "cvsubst =" <+> ppr (seCvSubst env)
921       {- , ppr (seFloats env) -}
922       ]) $ -}
923     simplExprF1 env e cont
924
925 simplExprF1 :: SimplEnv -> InExpr -> SimplCont
926             -> SimplM (SimplEnv, OutExpr)
927 simplExprF1 env (Var v)        cont = simplIdF env v cont
928 simplExprF1 env (Lit lit)      cont = rebuild env (Lit lit) cont
929 simplExprF1 env (Tick t expr)  cont = simplTick env t expr cont
930 simplExprF1 env (Cast body co) cont = simplCast env body co cont
931 simplExprF1 env (Coercion co)  cont = simplCoercionF env co cont
932 simplExprF1 env (Type ty)      cont = ASSERT( contIsRhsOrArg cont )
933                                       rebuild env (Type (substTy env ty)) cont
934 simplExprF1 env (App fun arg)  cont = simplExprF env fun $
935                                       ApplyTo NoDup arg env cont
936
937 simplExprF1 env expr@(Lam {}) cont
938   = simplLam env zapped_bndrs body cont
939         -- The main issue here is under-saturated lambdas
940         --   (\x1. \x2. e) arg1
941         -- Here x1 might have "occurs-once" occ-info, because occ-info
942         -- is computed assuming that a group of lambdas is applied
943         -- all at once.  If there are too few args, we must zap the
944         -- occ-info, UNLESS the remaining binders are one-shot
945   where
946     (bndrs, body) = collectBinders expr
947     zapped_bndrs | need_to_zap = map zap bndrs
948                  | otherwise   = bndrs
949
950     need_to_zap = any zappable_bndr (drop n_args bndrs)
951     n_args = countArgs cont
952         -- NB: countArgs counts all the args (incl type args)
953         -- and likewise drop counts all binders (incl type lambdas)
954
955     zappable_bndr b = isId b && not (isOneShotBndr b)
956     zap b | isTyVar b = b
957           | otherwise = zapLamIdInfo b
958
959 simplExprF1 env (Case scrut bndr _ alts) cont
960   = simplExprF env scrut (Select NoDup bndr alts env cont)
961
962 simplExprF1 env (Let (Rec pairs) body) cont
963   = do  { env' <- simplRecBndrs env (map fst pairs)
964                 -- NB: bndrs' don't have unfoldings or rules
965                 -- We add them as we go down
966
967         ; env'' <- simplRecBind env' NotTopLevel pairs
968         ; simplExprF env'' body cont }
969
970 simplExprF1 env (Let (NonRec bndr rhs) body) cont
971   = simplNonRecE env bndr (rhs, env) ([], body) cont
972
973 ---------------------------------
974 simplType :: SimplEnv -> InType -> SimplM OutType
975         -- Kept monadic just so we can do the seqType
976 simplType env ty
977   = -- pprTrace "simplType" (ppr ty $$ ppr (seTvSubst env)) $
978     seqType new_ty `seq` return new_ty
979   where
980     new_ty = substTy env ty
981
982 ---------------------------------
983 simplCoercionF :: SimplEnv -> InCoercion -> SimplCont
984                -> SimplM (SimplEnv, OutExpr)
985 simplCoercionF env co cont
986   = do { co' <- simplCoercion env co
987        ; rebuild env (Coercion co') cont }
988
989 simplCoercion :: SimplEnv -> InCoercion -> SimplM OutCoercion
990 simplCoercion env co
991   = let opt_co = optCoercion (getCvSubst env) co
992     in seqCo opt_co `seq` return opt_co
993
994 -----------------------------------
995 -- | Push a TickIt context outwards past applications and cases, as
996 -- long as this is a non-scoping tick, to let case and application
997 -- optimisations apply.
998
999 simplTick :: SimplEnv -> Tickish Id -> InExpr -> SimplCont
1000           -> SimplM (SimplEnv, OutExpr)
1001 simplTick env tickish expr cont
1002   -- A scoped tick turns into a continuation, so that we can spot
1003   -- (scc t (\x . e)) in simplLam and eliminate the scc.  If we didn't do
1004   -- it this way, then it would take two passes of the simplifier to
1005   -- reduce ((scc t (\x . e)) e').
1006   -- NB, don't do this with counting ticks, because if the expr is
1007   -- bottom, then rebuildCall will discard the continuation.
1008
1009 -- XXX: we cannot do this, because the simplifier assumes that
1010 -- the context can be pushed into a case with a single branch. e.g.
1011 --    scc<f>  case expensive of p -> e
1012 -- becomes
1013 --    case expensive of p -> scc<f> e
1014 --
1015 -- So I'm disabling this for now.  It just means we will do more
1016 -- simplifier iterations that necessary in some cases.
1017
1018 --  | tickishScoped tickish && not (tickishCounts tickish)
1019 --  = simplExprF env expr (TickIt tickish cont)
1020
1021   -- For non-scoped ticks, we push the continuation inside the
1022   -- tick.  This has the effect of moving the tick to the outside of a
1023   -- case or application context, allowing the normal case and
1024   -- application optimisations to fire.
1025   | not (tickishScoped tickish)
1026   = do { (env', expr') <- simplExprF env expr cont
1027        ; return (env', mkTick tickish expr')
1028        }
1029
1030   -- For breakpoints, we cannot do any floating of bindings around the
1031   -- tick, because breakpoints cannot be split into tick/scope pairs.
1032   | not (tickishCanSplit tickish)
1033   = no_floating_past_tick
1034
1035   | interesting_cont, Just expr' <- push_tick_inside tickish expr
1036     -- see Note [case-of-scc-of-case]
1037   = simplExprF env expr' cont
1038
1039   | otherwise
1040   = no_floating_past_tick -- was: wrap_floats, see below
1041
1042  where
1043   interesting_cont = case cont of
1044                         Select {} -> True
1045                         _ -> False
1046
1047   push_tick_inside t expr0
1048        = ASSERT(tickishScoped t)
1049          case expr0 of
1050            Tick t' expr
1051               -- scc t (tick t' E)
1052               --   Pull the tick to the outside
1053               -- This one is important for #5363
1054               | not (tickishScoped t')
1055                  -> Just (Tick t' (Tick t expr))
1056
1057               -- scc t (scc t' E)
1058               --   Try to push t' into E first, and if that works,
1059               --   try to push t in again
1060               | Just expr' <- push_tick_inside t' expr
1061                  -> push_tick_inside t expr'
1062
1063               | otherwise -> Nothing
1064
1065            Case scrut bndr ty alts
1066               | not (tickishCanSplit t) -> Nothing
1067               | otherwise -> Just (Case (mkTick t scrut) bndr ty alts')
1068              where t_scope = mkNoCount t -- drop the tick on the dup'd ones
1069                    alts'   = [ (c,bs, mkTick t_scope e) | (c,bs,e) <- alts]
1070
1071            _other -> Nothing
1072     where
1073
1074   no_floating_past_tick =
1075     do { let (inc,outc) = splitCont cont
1076        ; (env', expr') <- simplExprF (zapFloats env) expr inc
1077        ; let tickish' = simplTickish env tickish
1078        ; (env'', expr'') <- rebuild (zapFloats env')
1079                                     (wrapFloats env' expr')
1080                                     (TickIt tickish' outc)
1081        ; return (addFloats env env'', expr'')
1082        }
1083
1084 -- Alternative version that wraps outgoing floats with the tick.  This
1085 -- results in ticks being duplicated, as we don't make any attempt to
1086 -- eliminate the tick if we re-inline the binding (because the tick
1087 -- semantics allows unrestricted inlining of HNFs), so I'm not doing
1088 -- this any more.  FloatOut will catch any real opportunities for
1089 -- floating.
1090 --
1091 --  wrap_floats =
1092 --    do { let (inc,outc) = splitCont cont
1093 --       ; (env', expr') <- simplExprF (zapFloats env) expr inc
1094 --       ; let tickish' = simplTickish env tickish
1095 --       ; let wrap_float (b,rhs) = (zapIdStrictness (setIdArity b 0),
1096 --                                   mkTick (mkNoCount tickish') rhs)
1097 --              -- when wrapping a float with mkTick, we better zap the Id's
1098 --              -- strictness info and arity, because it might be wrong now.
1099 --       ; let env'' = addFloats env (mapFloats env' wrap_float)
1100 --       ; rebuild env'' expr' (TickIt tickish' outc)
1101 --       }
1102
1103
1104   simplTickish env tickish
1105     | Breakpoint n ids <- tickish
1106           = Breakpoint n (map (getDoneId . substId env) ids)
1107     | otherwise = tickish
1108
1109   -- push type application and coercion inside a tick
1110   splitCont :: SimplCont -> (SimplCont, SimplCont)
1111   splitCont (ApplyTo f (Type t) env c) = (ApplyTo f (Type t) env inc, outc)
1112     where (inc,outc) = splitCont c
1113   splitCont (CoerceIt co c) = (CoerceIt co inc, outc)
1114     where (inc,outc) = splitCont c
1115   splitCont other = (mkBoringStop (contInputType other), other)
1116
1117   getDoneId (DoneId id) = id
1118   getDoneId (DoneEx e)  = getIdFromTrivialExpr e -- Note [substTickish] in CoreSubst
1119   getDoneId other = pprPanic "getDoneId" (ppr other)
1120
1121 -- Note [case-of-scc-of-case]
1122 -- It's pretty important to be able to transform case-of-case when
1123 -- there's an SCC in the way.  For example, the following comes up
1124 -- in nofib/real/compress/Encode.hs:
1125 --
1126 --        case scctick<code_string.r1>
1127 --             case $wcode_string_r13s wild_XC w1_s137 w2_s138 l_aje
1128 --             of _ { (# ww1_s13f, ww2_s13g, ww3_s13h #) ->
1129 --             (ww1_s13f, ww2_s13g, ww3_s13h)
1130 --             }
1131 --        of _ { (ww_s12Y, ww1_s12Z, ww2_s130) ->
1132 --        tick<code_string.f1>
1133 --        (ww_s12Y,
1134 --         ww1_s12Z,
1135 --         PTTrees.PT
1136 --           @ GHC.Types.Char @ GHC.Types.Int wild2_Xj ww2_s130 r_ajf)
1137 --        }
1138 --
1139 -- We really want this case-of-case to fire, because then the 3-tuple
1140 -- will go away (indeed, the CPR optimisation is relying on this
1141 -- happening).  But the scctick is in the way - we need to push it
1142 -- inside to expose the case-of-case.  So we perform this
1143 -- transformation on the inner case:
1144 --
1145 --   scctick c (case e of { p1 -> e1; ...; pn -> en })
1146 --    ==>
1147 --   case (scctick c e) of { p1 -> scc c e1; ...; pn -> scc c en }
1148 --
1149 -- So we've moved a constant amount of work out of the scc to expose
1150 -- the case.  We only do this when the continuation is interesting: in
1151 -- for now, it has to be another Case (maybe generalise this later).
1152 \end{code}
1153
1154
1155 %************************************************************************
1156 %*                                                                      *
1157 \subsection{The main rebuilder}
1158 %*                                                                      *
1159 %************************************************************************
1160
1161 \begin{code}
1162 rebuild :: SimplEnv -> OutExpr -> SimplCont -> SimplM (SimplEnv, OutExpr)
1163 -- At this point the substitution in the SimplEnv should be irrelevant
1164 -- only the in-scope set and floats should matter
1165 rebuild env expr cont
1166   = case cont of
1167       Stop {}                       -> return (env, expr)
1168       CoerceIt co cont              -> rebuild env (mkCast expr co) cont
1169                                     -- NB: mkCast implements the (Coercion co |> g) optimisation
1170       Select _ bndr alts se cont    -> rebuildCase (se `setFloats` env) expr bndr alts cont
1171       StrictArg info _ cont         -> rebuildCall env (info `addArgTo` expr) cont
1172       StrictBind b bs body se cont  -> do { env' <- simplNonRecX (se `setFloats` env) b expr
1173                                                -- expr satisfies let/app since it started life
1174                                                -- in a call to simplNonRecE
1175                                           ; simplLam env' bs body cont }
1176       ApplyTo dup_flag arg se cont  -- See Note [Avoid redundant simplification]
1177         | isSimplified dup_flag     -> rebuild env (App expr arg) cont
1178         | otherwise                 -> do { arg' <- simplExpr (se `setInScope` env) arg
1179                                           ; rebuild env (App expr arg') cont }
1180       TickIt t cont                 -> rebuild env (mkTick t expr) cont
1181 \end{code}
1182
1183
1184 %************************************************************************
1185 %*                                                                      *
1186 \subsection{Lambdas}
1187 %*                                                                      *
1188 %************************************************************************
1189
1190 \begin{code}
1191 simplCast :: SimplEnv -> InExpr -> Coercion -> SimplCont
1192           -> SimplM (SimplEnv, OutExpr)
1193 simplCast env body co0 cont0
1194   = do  { co1 <- simplCoercion env co0
1195         ; -- pprTrace "simplCast" (ppr co1) $
1196           simplExprF env body (addCoerce co1 cont0) }
1197   where
1198        addCoerce co cont = add_coerce co (coercionKind co) cont
1199
1200        add_coerce _co (Pair s1 k1) cont     -- co :: ty~ty
1201          | s1 `eqType` k1 = cont    -- is a no-op
1202
1203        add_coerce co1 (Pair s1 _k2) (CoerceIt co2 cont)
1204          | (Pair _l1 t1) <- coercionKind co2
1205                 --      e |> (g1 :: S1~L) |> (g2 :: L~T1)
1206                 -- ==>
1207                 --      e,                       if S1=T1
1208                 --      e |> (g1 . g2 :: S1~T1)  otherwise
1209                 --
1210                 -- For example, in the initial form of a worker
1211                 -- we may find  (coerce T (coerce S (\x.e))) y
1212                 -- and we'd like it to simplify to e[y/x] in one round
1213                 -- of simplification
1214          , s1 `eqType` t1  = cont            -- The coerces cancel out
1215          | otherwise       = CoerceIt (mkTransCo co1 co2) cont
1216
1217        add_coerce co (Pair s1s2 _t1t2) (ApplyTo dup (Type arg_ty) arg_se cont)
1218                 -- (f |> g) ty  --->   (f ty) |> (g @ ty)
1219                 -- This implements the PushT rule from the paper
1220          | Just (tyvar,_) <- splitForAllTy_maybe s1s2
1221          = ASSERT( isTyVar tyvar )
1222            ApplyTo Simplified (Type arg_ty') (zapSubstEnv arg_se) (addCoerce new_cast cont)
1223          where
1224            new_cast = mkInstCo co arg_ty'
1225            arg_ty' | isSimplified dup = arg_ty
1226                    | otherwise        = substTy (arg_se `setInScope` env) arg_ty
1227
1228        add_coerce co (Pair s1s2 t1t2) (ApplyTo dup arg arg_se cont)
1229          | isFunTy s1s2   -- This implements the Push rule from the paper
1230          , isFunTy t1t2   -- Check t1t2 to ensure 'arg' is a value arg
1231                 --      (e |> (g :: s1s2 ~ t1->t2)) f
1232                 -- ===>
1233                 --      (e (f |> (arg g :: t1~s1))
1234                 --      |> (res g :: s2->t2)
1235                 --
1236                 -- t1t2 must be a function type, t1->t2, because it's applied
1237                 -- to something but s1s2 might conceivably not be
1238                 --
1239                 -- When we build the ApplyTo we can't mix the out-types
1240                 -- with the InExpr in the argument, so we simply substitute
1241                 -- to make it all consistent.  It's a bit messy.
1242                 -- But it isn't a common case.
1243                 --
1244                 -- Example of use: Trac #995
1245          = ApplyTo dup new_arg (zapSubstEnv arg_se) (addCoerce co2 cont)
1246          where
1247            -- we split coercion t1->t2 ~ s1->s2 into t1 ~ s1 and
1248            -- t2 ~ s2 with left and right on the curried form:
1249            --    (->) t1 t2 ~ (->) s1 s2
1250            [co1, co2] = decomposeCo 2 co
1251            new_arg    = mkCast arg' (mkSymCo co1)
1252            arg'       = substExpr (text "move-cast") arg_se' arg
1253            arg_se'    = arg_se `setInScope` env
1254
1255        add_coerce co _ cont = CoerceIt co cont
1256 \end{code}
1257
1258
1259 %************************************************************************
1260 %*                                                                      *
1261 \subsection{Lambdas}
1262 %*                                                                      *
1263 %************************************************************************
1264
1265 Note [Zap unfolding when beta-reducing]
1266 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1267 Lambda-bound variables can have stable unfoldings, such as
1268    $j = \x. \b{Unf=Just x}. e
1269 See Note [Case binders and join points] below; the unfolding for lets
1270 us optimise e better.  However when we beta-reduce it we want to
1271 revert to using the actual value, otherwise we can end up in the
1272 stupid situation of
1273           let x = blah in
1274           let b{Unf=Just x} = y
1275           in ...b...
1276 Here it'd be far better to drop the unfolding and use the actual RHS.
1277
1278 \begin{code}
1279 simplLam :: SimplEnv -> [InId] -> InExpr -> SimplCont
1280          -> SimplM (SimplEnv, OutExpr)
1281
1282 simplLam env [] body cont = simplExprF env body cont
1283
1284         -- Beta reduction
1285 simplLam env (bndr:bndrs) body (ApplyTo _ arg arg_se cont)
1286   = do  { tick (BetaReduction bndr)
1287         ; simplNonRecE env (zap_unfolding bndr) (arg, arg_se) (bndrs, body) cont }
1288   where
1289     zap_unfolding bndr  -- See Note [Zap unfolding when beta-reducing]
1290       | isId bndr, isStableUnfolding (realIdUnfolding bndr)
1291       = setIdUnfolding bndr NoUnfolding
1292       | otherwise = bndr
1293
1294       -- discard a non-counting tick on a lambda.  This may change the
1295       -- cost attribution slightly (moving the allocation of the
1296       -- lambda elsewhere), but we don't care: optimisation changes
1297       -- cost attribution all the time.
1298 simplLam env bndrs body (TickIt tickish cont)
1299   | not (tickishCounts tickish)
1300   = simplLam env bndrs body cont
1301
1302         -- Not enough args, so there are real lambdas left to put in the result
1303 simplLam env bndrs body cont
1304   = do  { (env', bndrs') <- simplLamBndrs env bndrs
1305         ; body' <- simplExpr env' body
1306         ; new_lam <- mkLam bndrs' body' cont
1307         ; rebuild env' new_lam cont }
1308
1309 ------------------
1310 simplNonRecE :: SimplEnv
1311              -> InBndr                  -- The binder
1312              -> (InExpr, SimplEnv)      -- Rhs of binding (or arg of lambda)
1313              -> ([InBndr], InExpr)      -- Body of the let/lambda
1314                                         --      \xs.e
1315              -> SimplCont
1316              -> SimplM (SimplEnv, OutExpr)
1317
1318 -- simplNonRecE is used for
1319 --  * non-top-level non-recursive lets in expressions
1320 --  * beta reduction
1321 --
1322 -- It deals with strict bindings, via the StrictBind continuation,
1323 -- which may abort the whole process
1324 --
1325 -- Precondition: rhs satisfies the let/app invariant
1326 --               Note [CoreSyn let/app invariant] in CoreSyn
1327 --
1328 -- The "body" of the binding comes as a pair of ([InId],InExpr)
1329 -- representing a lambda; so we recurse back to simplLam
1330 -- Why?  Because of the binder-occ-info-zapping done before
1331 --       the call to simplLam in simplExprF (Lam ...)
1332
1333         -- First deal with type applications and type lets
1334         --   (/\a. e) (Type ty)   and   (let a = Type ty in e)
1335 simplNonRecE env bndr (Type ty_arg, rhs_se) (bndrs, body) cont
1336   = ASSERT( isTyVar bndr )
1337     do  { ty_arg' <- simplType (rhs_se `setInScope` env) ty_arg
1338         ; simplLam (extendTvSubst env bndr ty_arg') bndrs body cont }
1339
1340 simplNonRecE env bndr (rhs, rhs_se) (bndrs, body) cont
1341   = do dflags <- getDynFlags
1342        case () of
1343          _ | preInlineUnconditionally dflags env NotTopLevel bndr rhs
1344            -> do { tick (PreInlineUnconditionally bndr)
1345                  ; -- pprTrace "preInlineUncond" (ppr bndr <+> ppr rhs) $
1346                   simplLam (extendIdSubst env bndr (mkContEx rhs_se rhs)) bndrs body cont }
1347
1348            | isStrictId bndr          -- Includes coercions
1349            -> simplExprF (rhs_se `setFloats` env) rhs
1350                          (StrictBind bndr bndrs body env cont)
1351
1352            | otherwise
1353            -> ASSERT( not (isTyVar bndr) )
1354               do { (env1, bndr1) <- simplNonRecBndr env bndr
1355                  ; let (env2, bndr2) = addBndrRules env1 bndr bndr1
1356                  ; env3 <- simplLazyBind env2 NotTopLevel NonRecursive bndr bndr2 rhs rhs_se
1357                  ; simplLam env3 bndrs body cont }
1358 \end{code}
1359
1360 %************************************************************************
1361 %*                                                                      *
1362                      Variables
1363 %*                                                                      *
1364 %************************************************************************
1365
1366 \begin{code}
1367 simplVar :: SimplEnv -> InVar -> SimplM OutExpr
1368 -- Look up an InVar in the environment
1369 simplVar env var
1370   | isTyVar var = return (Type (substTyVar env var))
1371   | isCoVar var = return (Coercion (substCoVar env var))
1372   | otherwise
1373   = case substId env var of
1374         DoneId var1          -> return (Var var1)
1375         DoneEx e             -> return e
1376         ContEx tvs cvs ids e -> simplExpr (setSubstEnv env tvs cvs ids) e
1377
1378 simplIdF :: SimplEnv -> InId -> SimplCont -> SimplM (SimplEnv, OutExpr)
1379 simplIdF env var cont
1380   = case substId env var of
1381         DoneEx e             -> simplExprF (zapSubstEnv env) e cont
1382         ContEx tvs cvs ids e -> simplExprF (setSubstEnv env tvs cvs ids) e cont
1383         DoneId var1          -> completeCall env var1 cont
1384                 -- Note [zapSubstEnv]
1385                 -- The template is already simplified, so don't re-substitute.
1386                 -- This is VITAL.  Consider
1387                 --      let x = e in
1388                 --      let y = \z -> ...x... in
1389                 --      \ x -> ...y...
1390                 -- We'll clone the inner \x, adding x->x' in the id_subst
1391                 -- Then when we inline y, we must *not* replace x by x' in
1392                 -- the inlined copy!!
1393
1394 ---------------------------------------------------------
1395 --      Dealing with a call site
1396
1397 completeCall :: SimplEnv -> OutId -> SimplCont -> SimplM (SimplEnv, OutExpr)
1398 completeCall env var cont
1399   = do  {   ------------- Try inlining ----------------
1400           dflags <- getDynFlags
1401         ; let  (lone_variable, arg_infos, call_cont) = contArgs cont
1402                n_val_args = length arg_infos
1403                interesting_cont = interestingCallContext call_cont
1404                unfolding    = activeUnfolding env var
1405                maybe_inline = callSiteInline dflags var unfolding
1406                                              lone_variable arg_infos interesting_cont
1407         ; case maybe_inline of {
1408             Just expr      -- There is an inlining!
1409               ->  do { checkedTick (UnfoldingDone var)
1410                      ; dump_inline dflags expr cont
1411                      ; simplExprF (zapSubstEnv env) expr cont }
1412
1413             ; Nothing -> do               -- No inlining!
1414
1415         { rule_base <- getSimplRules
1416         ; let info = mkArgInfo var (getRules rule_base var) n_val_args call_cont
1417         ; rebuildCall env info cont
1418     }}}
1419   where
1420     dump_inline dflags unfolding cont
1421       | not (dopt Opt_D_dump_inlinings dflags) = return ()
1422       | not (dopt Opt_D_verbose_core2core dflags)
1423       = when (isExternalName (idName var)) $
1424             liftIO $ printInfoForUser dflags alwaysQualify $
1425                 sep [text "Inlining done:", nest 4 (ppr var)]
1426       | otherwise
1427       = liftIO $ printInfoForUser dflags alwaysQualify $
1428            sep [text "Inlining done: " <> ppr var,
1429                 nest 4 (vcat [text "Inlined fn: " <+> nest 2 (ppr unfolding),
1430                               text "Cont:  " <+> ppr cont])]
1431
1432 rebuildCall :: SimplEnv
1433             -> ArgInfo
1434             -> SimplCont
1435             -> SimplM (SimplEnv, OutExpr)
1436 rebuildCall env (ArgInfo { ai_fun = fun, ai_args = rev_args, ai_strs = [] }) cont
1437   -- When we run out of strictness args, it means
1438   -- that the call is definitely bottom; see SimplUtils.mkArgInfo
1439   -- Then we want to discard the entire strict continuation.  E.g.
1440   --    * case (error "hello") of { ... }
1441   --    * (error "Hello") arg
1442   --    * f (error "Hello") where f is strict
1443   --    etc
1444   -- Then, especially in the first of these cases, we'd like to discard
1445   -- the continuation, leaving just the bottoming expression.  But the
1446   -- type might not be right, so we may have to add a coerce.
1447   | not (contIsTrivial cont)     -- Only do this if there is a non-trivial
1448   = return (env, castBottomExpr res cont_ty)  -- contination to discard, else we do it
1449   where                                       -- again and again!
1450     res     = argInfoExpr fun rev_args
1451     cont_ty = contResultType cont
1452
1453 rebuildCall env info (CoerceIt co cont)
1454   = rebuildCall env (addCastTo info co) cont
1455
1456 rebuildCall env info (ApplyTo dup_flag (Type arg_ty) se cont)
1457   = do { arg_ty' <- if isSimplified dup_flag then return arg_ty
1458                     else simplType (se `setInScope` env) arg_ty
1459        ; rebuildCall env (info `addArgTo` Type arg_ty') cont }
1460
1461 rebuildCall env info@(ArgInfo { ai_encl = encl_rules, ai_type = fun_ty
1462                               , ai_strs = str:strs, ai_discs = disc:discs })
1463             (ApplyTo dup_flag arg arg_se cont)
1464   | isSimplified dup_flag     -- See Note [Avoid redundant simplification]
1465   = rebuildCall env (addArgTo info' arg) cont
1466
1467   | str                 -- Strict argument
1468   = -- pprTrace "Strict Arg" (ppr arg $$ ppr (seIdSubst env) $$ ppr (seInScope env)) $
1469     simplExprF (arg_se `setFloats` env) arg
1470                (StrictArg info' cci cont)
1471                 -- Note [Shadowing]
1472
1473   | otherwise                           -- Lazy argument
1474         -- DO NOT float anything outside, hence simplExprC
1475         -- There is no benefit (unlike in a let-binding), and we'd
1476         -- have to be very careful about bogus strictness through
1477         -- floating a demanded let.
1478   = do  { arg' <- simplExprC (arg_se `setInScope` env) arg
1479                              (mkLazyArgStop (funArgTy fun_ty) cci)
1480         ; rebuildCall env (addArgTo info' arg') cont }
1481   where
1482     info' = info { ai_strs = strs, ai_discs = discs }
1483     cci | encl_rules = RuleArgCtxt
1484         | disc > 0   = DiscArgCtxt  -- Be keener here
1485         | otherwise  = BoringCtxt   -- Nothing interesting
1486
1487 rebuildCall env (ArgInfo { ai_fun = fun, ai_args = rev_args, ai_rules = rules }) cont
1488   | null rules
1489   = rebuild env (argInfoExpr fun rev_args) cont      -- No rules, common case
1490
1491   | otherwise
1492   = do {  -- We've accumulated a simplified call in <fun,rev_args>
1493           -- so try rewrite rules; see Note [RULEs apply to simplified arguments]
1494           -- See also Note [Rules for recursive functions]
1495         ; let env' = zapSubstEnv env
1496               (args, cont') = argInfoValArgs env' rev_args cont
1497         ; mb_rule <- tryRules env' rules fun args cont'
1498         ; case mb_rule of {
1499              Just (rule_rhs, cont'') -> simplExprF env' rule_rhs cont''
1500
1501                  -- Rules don't match
1502            ; Nothing -> rebuild env (argInfoExpr fun rev_args) cont      -- No rules
1503     } }
1504 \end{code}
1505
1506 Note [RULES apply to simplified arguments]
1507 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1508 It's very desirable to try RULES once the arguments have been simplified, because
1509 doing so ensures that rule cascades work in one pass.  Consider
1510    {-# RULES g (h x) = k x
1511              f (k x) = x #-}
1512    ...f (g (h x))...
1513 Then we want to rewrite (g (h x)) to (k x) and only then try f's rules. If
1514 we match f's rules against the un-simplified RHS, it won't match.  This
1515 makes a particularly big difference when superclass selectors are involved:
1516         op ($p1 ($p2 (df d)))
1517 We want all this to unravel in one sweeep.
1518
1519 Note [Avoid redundant simplification]
1520 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1521 Because RULES apply to simplified arguments, there's a danger of repeatedly
1522 simplifying already-simplified arguments.  An important example is that of
1523         (>>=) d e1 e2
1524 Here e1, e2 are simplified before the rule is applied, but don't really
1525 participate in the rule firing. So we mark them as Simplified to avoid
1526 re-simplifying them.
1527
1528 Note [Shadowing]
1529 ~~~~~~~~~~~~~~~~
1530 This part of the simplifier may break the no-shadowing invariant
1531 Consider
1532         f (...(\a -> e)...) (case y of (a,b) -> e')
1533 where f is strict in its second arg
1534 If we simplify the innermost one first we get (...(\a -> e)...)
1535 Simplifying the second arg makes us float the case out, so we end up with
1536         case y of (a,b) -> f (...(\a -> e)...) e'
1537 So the output does not have the no-shadowing invariant.  However, there is
1538 no danger of getting name-capture, because when the first arg was simplified
1539 we used an in-scope set that at least mentioned all the variables free in its
1540 static environment, and that is enough.
1541
1542 We can't just do innermost first, or we'd end up with a dual problem:
1543         case x of (a,b) -> f e (...(\a -> e')...)
1544
1545 I spent hours trying to recover the no-shadowing invariant, but I just could
1546 not think of an elegant way to do it.  The simplifier is already knee-deep in
1547 continuations.  We have to keep the right in-scope set around; AND we have
1548 to get the effect that finding (error "foo") in a strict arg position will
1549 discard the entire application and replace it with (error "foo").  Getting
1550 all this at once is TOO HARD!
1551
1552
1553 %************************************************************************
1554 %*                                                                      *
1555                 Rewrite rules
1556 %*                                                                      *
1557 %************************************************************************
1558
1559 \begin{code}
1560 tryRules :: SimplEnv -> [CoreRule]
1561          -> Id -> [OutExpr] -> SimplCont
1562          -> SimplM (Maybe (CoreExpr, SimplCont))
1563 -- The SimplEnv already has zapSubstEnv applied to it
1564
1565 tryRules env rules fn args call_cont
1566   | null rules
1567   = return Nothing
1568 {- Disabled until we fix #8326
1569   | fn `hasKey` tagToEnumKey   -- See Note [Optimising tagToEnum#]
1570   , [_type_arg, val_arg] <- args
1571   , Select dup bndr ((_,[],rhs1) : rest_alts) se cont <- call_cont
1572   , isDeadBinder bndr
1573   = do { dflags <- getDynFlags
1574        ; let enum_to_tag :: CoreAlt -> CoreAlt
1575                 -- Takes   K -> e  into   tagK# -> e
1576                 -- where tagK# is the tag of constructor K
1577              enum_to_tag (DataAlt con, [], rhs)
1578                = ASSERT( isEnumerationTyCon (dataConTyCon con) )
1579                 (LitAlt tag, [], rhs)
1580               where
1581                 tag = mkMachInt dflags (toInteger (dataConTag con - fIRST_TAG))
1582              enum_to_tag alt = pprPanic "tryRules: tagToEnum" (ppr alt)
1583
1584              new_alts = (DEFAULT, [], rhs1) : map enum_to_tag rest_alts
1585              new_bndr = setIdType bndr intPrimTy
1586                  -- The binder is dead, but should have the right type
1587       ; return (Just (val_arg, Select dup new_bndr new_alts se cont)) }
1588 -}
1589   | otherwise
1590   = do { dflags <- getDynFlags
1591        ; case lookupRule dflags (getUnfoldingInRuleMatch env) (activeRule env)
1592                          fn args rules of {
1593            Nothing               -> return Nothing ;   -- No rule matches
1594            Just (rule, rule_rhs) ->
1595              do { checkedTick (RuleFired (ru_name rule))
1596                 ; dump dflags rule rule_rhs
1597                 ; let cont' = pushSimplifiedArgs env
1598                                                  (drop (ruleArity rule) args)
1599                                                  call_cont
1600                       -- (ruleArity rule) says how many args the rule consumed
1601                 ; return (Just (rule_rhs, cont')) }}}
1602   where
1603     dump dflags rule rule_rhs
1604       | dopt Opt_D_dump_rule_rewrites dflags
1605       = log_rule dflags Opt_D_dump_rule_rewrites "Rule fired" $ vcat
1606           [ text "Rule:" <+> ftext (ru_name rule)
1607           , text "Before:" <+> hang (ppr fn) 2 (sep (map pprParendExpr args))
1608           , text "After: " <+> pprCoreExpr rule_rhs
1609           , text "Cont:  " <+> ppr call_cont ]
1610
1611       | dopt Opt_D_dump_rule_firings dflags
1612       = log_rule dflags Opt_D_dump_rule_firings "Rule fired:" $
1613           ftext (ru_name rule)
1614
1615       | otherwise
1616       = return ()
1617
1618     log_rule dflags flag hdr details = liftIO . dumpSDoc dflags flag "" $
1619       sep [text hdr, nest 4 details]
1620 \end{code}
1621
1622 Note [Optimising tagToEnum#]
1623 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1624 If we have an enumeration data type:
1625
1626   data Foo = A | B | C
1627
1628 Then we want to transform
1629
1630    case tagToEnum# x of   ==>    case x of
1631      A -> e1                       DEFAULT -> e1
1632      B -> e2                       1#      -> e2
1633      C -> e3                       2#      -> e3
1634
1635 thereby getting rid of the tagToEnum# altogether.  If there was a DEFAULT
1636 alternative we retain it (remember it comes first).  If not the case must
1637 be exhaustive, and we reflect that in the transformed version by adding
1638 a DEFAULT.  Otherwise Lint complains that the new case is not exhaustive.
1639 See #8317.
1640
1641 Note [Rules for recursive functions]
1642 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1643 You might think that we shouldn't apply rules for a loop breaker:
1644 doing so might give rise to an infinite loop, because a RULE is
1645 rather like an extra equation for the function:
1646      RULE:           f (g x) y = x+y
1647      Eqn:            f a     y = a-y
1648
1649 But it's too drastic to disable rules for loop breakers.
1650 Even the foldr/build rule would be disabled, because foldr
1651 is recursive, and hence a loop breaker:
1652      foldr k z (build g) = g k z
1653 So it's up to the programmer: rules can cause divergence
1654
1655
1656 %************************************************************************
1657 %*                                                                      *
1658                 Rebuilding a case expression
1659 %*                                                                      *
1660 %************************************************************************
1661
1662 Note [Case elimination]
1663 ~~~~~~~~~~~~~~~~~~~~~~~
1664 The case-elimination transformation discards redundant case expressions.
1665 Start with a simple situation:
1666
1667         case x# of      ===>   let y# = x# in e
1668           y# -> e
1669
1670 (when x#, y# are of primitive type, of course).  We can't (in general)
1671 do this for algebraic cases, because we might turn bottom into
1672 non-bottom!
1673
1674 The code in SimplUtils.prepareAlts has the effect of generalise this
1675 idea to look for a case where we're scrutinising a variable, and we
1676 know that only the default case can match.  For example:
1677
1678         case x of
1679           0#      -> ...
1680           DEFAULT -> ...(case x of
1681                          0#      -> ...
1682                          DEFAULT -> ...) ...
1683
1684 Here the inner case is first trimmed to have only one alternative, the
1685 DEFAULT, after which it's an instance of the previous case.  This
1686 really only shows up in eliminating error-checking code.
1687
1688 Note that SimplUtils.mkCase combines identical RHSs.  So
1689
1690         case e of       ===> case e of DEFAULT -> r
1691            True  -> r
1692            False -> r
1693
1694 Now again the case may be elminated by the CaseElim transformation.
1695 This includes things like (==# a# b#)::Bool so that we simplify
1696       case ==# a# b# of { True -> x; False -> x }
1697 to just
1698       x
1699 This particular example shows up in default methods for
1700 comparison operations (e.g. in (>=) for Int.Int32)
1701
1702 Note [Case elimination: lifted case]
1703 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1704 If a case over a lifted type has a single alternative, and is being used
1705 as a strict 'let' (all isDeadBinder bndrs), we may want to do this
1706 transformation:
1707
1708     case e of r       ===>   let r = e in ...r...
1709       _ -> ...r...
1710
1711         (a) 'e' is already evaluated (it may so if e is a variable)
1712             Specifically we check (exprIsHNF e).  In this case
1713             we can just allocate the WHNF directly with a let.
1714 or
1715         (b) 'x' is not used at all and e is ok-for-speculation
1716              The ok-for-spec bit checks that we don't lose any
1717              exceptions or divergence.
1718
1719              NB: it'd be *sound* to switch from case to let if the
1720              scrutinee was not yet WHNF but was guaranteed to
1721              converge; but sticking with case means we won't build a
1722              thunk
1723
1724 or
1725         (c) 'x' is used strictly in the body, and 'e' is a variable
1726             Then we can just substitute 'e' for 'x' in the body.
1727             See Note [Eliminating redundant seqs]
1728
1729 For (b), the "not used at all" test is important.  Consider
1730    case (case a ># b of { True -> (p,q); False -> (q,p) }) of
1731      r -> blah
1732 The scrutinee is ok-for-speculation (it looks inside cases), but we do
1733 not want to transform to
1734    let r = case a ># b of { True -> (p,q); False -> (q,p) }
1735    in blah
1736 because that builds an unnecessary thunk.
1737
1738 Note [Eliminating redundant seqs]
1739 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1740 If we have this:
1741    case x of r { _ -> ..r.. }
1742 where 'r' is used strictly in (..r..), the case is effectively a 'seq'
1743 on 'x', but since 'r' is used strictly anyway, we can safely transform to
1744    (...x...)
1745
1746 Note that this can change the error behaviour.  For example, we might
1747 transform
1748     case x of { _ -> error "bad" }
1749     --> error "bad"
1750 which is might be puzzling if 'x' currently lambda-bound, but later gets
1751 let-bound to (error "good").
1752
1753 Nevertheless, the paper "A semantics for imprecise exceptions" allows
1754 this transformation. If you want to fix the evaluation order, use
1755 'pseq'.  See Trac #8900 for an example where the loss of this
1756 transformation bit us in practice. 
1757
1758 See also Note [Empty case alternatives] in CoreSyn.
1759
1760 Just for reference, the original code (added Jan 13) looked like this:
1761      || case_bndr_evald_next rhs
1762
1763     case_bndr_evald_next :: CoreExpr -> Bool
1764       -- See Note [Case binder next]
1765     case_bndr_evald_next (Var v)         = v == case_bndr
1766     case_bndr_evald_next (Cast e _)      = case_bndr_evald_next e
1767     case_bndr_evald_next (App e _)       = case_bndr_evald_next e
1768     case_bndr_evald_next (Case e _ _ _)  = case_bndr_evald_next e
1769     case_bndr_evald_next _               = False
1770
1771 (This came up when fixing Trac #7542. See also Note [Eta reduction of
1772 an eval'd function] in CoreUtils.)
1773
1774
1775 Note [Case elimination: unlifted case]
1776 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1777 Consider
1778    case a +# b of r -> ...r...
1779 Then we do case-elimination (to make a let) followed by inlining,
1780 to get
1781         .....(a +# b)....
1782 If we have
1783    case indexArray# a i of r -> ...r...
1784 we might like to do the same, and inline the (indexArray# a i).
1785 But indexArray# is not okForSpeculation, so we don't build a let
1786 in rebuildCase (lest it get floated *out*), so the inlining doesn't
1787 happen either.
1788
1789 This really isn't a big deal I think. The let can be
1790
1791
1792 Further notes about case elimination
1793 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1794 Consider:       test :: Integer -> IO ()
1795                 test = print
1796
1797 Turns out that this compiles to:
1798     Print.test
1799       = \ eta :: Integer
1800           eta1 :: Void# ->
1801           case PrelNum.< eta PrelNum.zeroInteger of wild { __DEFAULT ->
1802           case hPutStr stdout
1803                  (PrelNum.jtos eta ($w[] @ Char))
1804                  eta1
1805           of wild1 { (# new_s, a4 #) -> PrelIO.lvl23 new_s  }}
1806
1807 Notice the strange '<' which has no effect at all. This is a funny one.
1808 It started like this:
1809
1810 f x y = if x < 0 then jtos x
1811           else if y==0 then "" else jtos x
1812
1813 At a particular call site we have (f v 1).  So we inline to get
1814
1815         if v < 0 then jtos x
1816         else if 1==0 then "" else jtos x
1817
1818 Now simplify the 1==0 conditional:
1819
1820         if v<0 then jtos v else jtos v
1821
1822 Now common-up the two branches of the case:
1823
1824         case (v<0) of DEFAULT -> jtos v
1825
1826 Why don't we drop the case?  Because it's strict in v.  It's technically
1827 wrong to drop even unnecessary evaluations, and in practice they
1828 may be a result of 'seq' so we *definitely* don't want to drop those.
1829 I don't really know how to improve this situation.
1830
1831 \begin{code}
1832 ---------------------------------------------------------
1833 --      Eliminate the case if possible
1834
1835 rebuildCase, reallyRebuildCase
1836    :: SimplEnv
1837    -> OutExpr          -- Scrutinee
1838    -> InId             -- Case binder
1839    -> [InAlt]          -- Alternatives (inceasing order)
1840    -> SimplCont
1841    -> SimplM (SimplEnv, OutExpr)
1842
1843 --------------------------------------------------
1844 --      1. Eliminate the case if there's a known constructor
1845 --------------------------------------------------
1846
1847 rebuildCase env scrut case_bndr alts cont
1848   | Lit lit <- scrut    -- No need for same treatment as constructors
1849                         -- because literals are inlined more vigorously
1850   , not (litIsLifted lit)
1851   = do  { tick (KnownBranch case_bndr)
1852         ; case findAlt (LitAlt lit) alts of
1853             Nothing           -> missingAlt env case_bndr alts cont
1854             Just (_, bs, rhs) -> simple_rhs bs rhs }
1855
1856   | Just (con, ty_args, other_args) <- exprIsConApp_maybe (getUnfoldingInRuleMatch env) scrut
1857         -- Works when the scrutinee is a variable with a known unfolding
1858         -- as well as when it's an explicit constructor application
1859   = do  { tick (KnownBranch case_bndr)
1860         ; case findAlt (DataAlt con) alts of
1861             Nothing  -> missingAlt env case_bndr alts cont
1862             Just (DEFAULT, bs, rhs) -> simple_rhs bs rhs
1863             Just (_, bs, rhs)       -> knownCon env scrut con ty_args other_args
1864                                                 case_bndr bs rhs cont
1865         }
1866   where
1867     simple_rhs bs rhs = ASSERT( null bs )
1868                         do { env' <- simplNonRecX env case_bndr scrut
1869                                -- scrut is a constructor application,
1870                                -- hence satisfies let/app invariant
1871                            ; simplExprF env' rhs cont }
1872
1873
1874 --------------------------------------------------
1875 --      2. Eliminate the case if scrutinee is evaluated
1876 --------------------------------------------------
1877
1878 rebuildCase env scrut case_bndr alts@[(_, bndrs, rhs)] cont
1879   -- See if we can get rid of the case altogether
1880   -- See Note [Case elimination]
1881   -- mkCase made sure that if all the alternatives are equal,
1882   -- then there is now only one (DEFAULT) rhs
1883
1884   -- 2a.  Dropping the case altogether, if
1885   --      a) it binds nothing (so it's really just a 'seq')
1886   --      b) evaluating the scrutinee has no side effects
1887   | is_plain_seq
1888   , exprOkForSideEffects scrut
1889           -- The entire case is dead, so we can drop it
1890           -- if the scrutinee converges without having imperative
1891           -- side effects or raising a Haskell exception
1892           -- See Note [PrimOp can_fail and has_side_effects] in PrimOp
1893    = simplExprF env rhs cont
1894
1895   -- 2b.  Turn the case into a let, if
1896   --      a) it binds only the case-binder
1897   --      b) unlifted case: the scrutinee is ok-for-speculation
1898   --           lifted case: the scrutinee is in HNF (or will later be demanded)
1899   | all_dead_bndrs
1900   , if is_unlifted
1901     then exprOkForSpeculation scrut  -- See Note [Case elimination: unlifted case]
1902     else exprIsHNF scrut             -- See Note [Case elimination: lifted case]
1903       || scrut_is_demanded_var scrut
1904   = do { tick (CaseElim case_bndr)
1905        ; env' <- simplNonRecX env case_bndr scrut
1906        ; simplExprF env' rhs cont }
1907
1908   -- 2c. Try the seq rules if
1909   --     a) it binds only the case binder
1910   --     b) a rule for seq applies
1911   -- See Note [User-defined RULES for seq] in MkId
1912   | is_plain_seq
1913   = do { let rhs' = substExpr (text "rebuild-case") env rhs
1914              env' = zapSubstEnv env
1915              out_args = [Type (substTy env (idType case_bndr)),
1916                          Type (exprType rhs'), scrut, rhs']
1917                       -- Lazily evaluated, so we don't do most of this
1918
1919        ; rule_base <- getSimplRules
1920        ; mb_rule <- tryRules env' (getRules rule_base seqId) seqId out_args cont
1921        ; case mb_rule of
1922            Just (rule_rhs, cont') -> simplExprF env' rule_rhs cont'
1923            Nothing                -> reallyRebuildCase env scrut case_bndr alts cont }
1924   where
1925     is_unlifted        = isUnLiftedType (idType case_bndr)
1926     all_dead_bndrs     = all isDeadBinder bndrs       -- bndrs are [InId]
1927     is_plain_seq       = all_dead_bndrs && isDeadBinder case_bndr -- Evaluation *only* for effect
1928
1929     scrut_is_demanded_var :: CoreExpr -> Bool
1930             -- See Note [Eliminating redundant seqs]
1931     scrut_is_demanded_var (Cast s _) = scrut_is_demanded_var s
1932     scrut_is_demanded_var (Var _)    = isStrictDmd (idDemandInfo case_bndr)
1933     scrut_is_demanded_var _          = False
1934
1935
1936 rebuildCase env scrut case_bndr alts cont
1937   = reallyRebuildCase env scrut case_bndr alts cont
1938
1939 --------------------------------------------------
1940 --      3. Catch-all case
1941 --------------------------------------------------
1942
1943 reallyRebuildCase env scrut case_bndr alts cont
1944   = do  {       -- Prepare the continuation;
1945                 -- The new subst_env is in place
1946           (env', dup_cont, nodup_cont) <- prepareCaseCont env alts cont
1947
1948         -- Simplify the alternatives
1949         ; (scrut', case_bndr', alts') <- simplAlts env' scrut case_bndr alts dup_cont
1950
1951         ; dflags <- getDynFlags
1952         ; let alts_ty' = contResultType dup_cont
1953         ; case_expr <- mkCase dflags scrut' case_bndr' alts_ty' alts'
1954
1955         -- Notice that rebuild gets the in-scope set from env', not alt_env
1956         -- (which in any case is only build in simplAlts)
1957         -- The case binder *not* scope over the whole returned case-expression
1958         ; rebuild env' case_expr nodup_cont }
1959 \end{code}
1960
1961 simplCaseBinder checks whether the scrutinee is a variable, v.  If so,
1962 try to eliminate uses of v in the RHSs in favour of case_bndr; that
1963 way, there's a chance that v will now only be used once, and hence
1964 inlined.
1965
1966 Historical note: we use to do the "case binder swap" in the Simplifier
1967 so there were additional complications if the scrutinee was a variable.
1968 Now the binder-swap stuff is done in the occurrence analyer; see
1969 OccurAnal Note [Binder swap].
1970
1971 Note [knownCon occ info]
1972 ~~~~~~~~~~~~~~~~~~~~~~~~
1973 If the case binder is not dead, then neither are the pattern bound
1974 variables:
1975         case <any> of x { (a,b) ->
1976         case x of { (p,q) -> p } }
1977 Here (a,b) both look dead, but come alive after the inner case is eliminated.
1978 The point is that we bring into the envt a binding
1979         let x = (a,b)
1980 after the outer case, and that makes (a,b) alive.  At least we do unless
1981 the case binder is guaranteed dead.
1982
1983 Note [Case alternative occ info]
1984 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1985 When we are simply reconstructing a case (the common case), we always
1986 zap the occurrence info on the binders in the alternatives.  Even
1987 if the case binder is dead, the scrutinee is usually a variable, and *that*
1988 can bring the case-alternative binders back to life.
1989 See Note [Add unfolding for scrutinee]
1990
1991 Note [Improving seq]
1992 ~~~~~~~~~~~~~~~~~~~
1993 Consider
1994         type family F :: * -> *
1995         type instance F Int = Int
1996
1997         ... case e of x { DEFAULT -> rhs } ...
1998
1999 where x::F Int.  Then we'd like to rewrite (F Int) to Int, getting
2000
2001         case e `cast` co of x'::Int
2002            I# x# -> let x = x' `cast` sym co
2003                     in rhs
2004
2005 so that 'rhs' can take advantage of the form of x'.
2006
2007 Notice that Note [Case of cast] (in OccurAnal) may then apply to the result.
2008
2009 Nota Bene: We only do the [Improving seq] transformation if the
2010 case binder 'x' is actually used in the rhs; that is, if the case
2011 is *not* a *pure* seq.
2012   a) There is no point in adding the cast to a pure seq.
2013   b) There is a good reason not to: doing so would interfere
2014      with seq rules (Note [Built-in RULES for seq] in MkId).
2015      In particular, this [Improving seq] thing *adds* a cast
2016      while [Built-in RULES for seq] *removes* one, so they
2017      just flip-flop.
2018
2019 You might worry about
2020    case v of x { __DEFAULT ->
2021       ... case (v `cast` co) of y { I# -> ... }}
2022 This is a pure seq (since x is unused), so [Improving seq] won't happen.
2023 But it's ok: the simplifier will replace 'v' by 'x' in the rhs to get
2024    case v of x { __DEFAULT ->
2025       ... case (x `cast` co) of y { I# -> ... }}
2026 Now the outer case is not a pure seq, so [Improving seq] will happen,
2027 and then the inner case will disappear.
2028
2029 The need for [Improving seq] showed up in Roman's experiments.  Example:
2030   foo :: F Int -> Int -> Int
2031   foo t n = t `seq` bar n
2032      where
2033        bar 0 = 0
2034        bar n = bar (n - case t of TI i -> i)
2035 Here we'd like to avoid repeated evaluating t inside the loop, by
2036 taking advantage of the `seq`.
2037
2038 At one point I did transformation in LiberateCase, but it's more
2039 robust here.  (Otherwise, there's a danger that we'll simply drop the
2040 'seq' altogether, before LiberateCase gets to see it.)
2041
2042 \begin{code}
2043 simplAlts :: SimplEnv
2044           -> OutExpr
2045           -> InId                       -- Case binder
2046           -> [InAlt]                    -- Non-empty
2047           -> SimplCont
2048           -> SimplM (OutExpr, OutId, [OutAlt])  -- Includes the continuation
2049 -- Like simplExpr, this just returns the simplified alternatives;
2050 -- it does not return an environment
2051 -- The returned alternatives can be empty, none are possible
2052
2053 simplAlts env scrut case_bndr alts cont'
2054   = do  { let env0 = zapFloats env
2055
2056         ; (env1, case_bndr1) <- simplBinder env0 case_bndr
2057
2058         ; fam_envs <- getFamEnvs
2059         ; (alt_env', scrut', case_bndr') <- improveSeq fam_envs env1 scrut
2060                                                        case_bndr case_bndr1 alts
2061
2062         ; (imposs_deflt_cons, in_alts) <- prepareAlts scrut' case_bndr' alts
2063           -- NB: it's possible that the returned in_alts is empty: this is handled
2064           -- by the caller (rebuildCase) in the missingAlt function
2065
2066         ; alts' <- mapM (simplAlt alt_env' (Just scrut') imposs_deflt_cons case_bndr' cont') in_alts
2067         ; -- pprTrace "simplAlts" (ppr case_bndr $$ ppr alts_ty $$ ppr alts_ty' $$ ppr alts $$ ppr cont') $
2068           return (scrut', case_bndr', alts') }
2069
2070
2071 ------------------------------------
2072 improveSeq :: (FamInstEnv, FamInstEnv) -> SimplEnv
2073            -> OutExpr -> InId -> OutId -> [InAlt]
2074            -> SimplM (SimplEnv, OutExpr, OutId)
2075 -- Note [Improving seq]
2076 improveSeq fam_envs env scrut case_bndr case_bndr1 [(DEFAULT,_,_)]
2077   | not (isDeadBinder case_bndr) -- Not a pure seq!  See Note [Improving seq]
2078   , Just (co, ty2) <- topNormaliseType_maybe fam_envs (idType case_bndr1)
2079   = do { case_bndr2 <- newId (fsLit "nt") ty2
2080         ; let rhs  = DoneEx (Var case_bndr2 `Cast` mkSymCo co)
2081               env2 = extendIdSubst env case_bndr rhs
2082         ; return (env2, scrut `Cast` co, case_bndr2) }
2083
2084 improveSeq _ env scrut _ case_bndr1 _
2085   = return (env, scrut, case_bndr1)
2086
2087
2088 ------------------------------------
2089 simplAlt :: SimplEnv
2090          -> Maybe OutExpr  -- The scrutinee
2091          -> [AltCon]       -- These constructors can't be present when
2092                            -- matching the DEFAULT alternative
2093          -> OutId          -- The case binder
2094          -> SimplCont
2095          -> InAlt
2096          -> SimplM OutAlt
2097
2098 simplAlt env _ imposs_deflt_cons case_bndr' cont' (DEFAULT, bndrs, rhs)
2099   = ASSERT( null bndrs )
2100     do  { let env' = addBinderUnfolding env case_bndr'
2101                                         (mkOtherCon imposs_deflt_cons)
2102                 -- Record the constructors that the case-binder *can't* be.
2103         ; rhs' <- simplExprC env' rhs cont'
2104         ; return (DEFAULT, [], rhs') }
2105
2106 simplAlt env scrut' _ case_bndr' cont' (LitAlt lit, bndrs, rhs)
2107   = ASSERT( null bndrs )
2108     do  { env' <- addAltUnfoldings env scrut' case_bndr' (Lit lit)
2109         ; rhs' <- simplExprC env' rhs cont'
2110         ; return (LitAlt lit, [], rhs') }
2111
2112 simplAlt env scrut' _ case_bndr' cont' (DataAlt con, vs, rhs)
2113   = do  {       -- Deal with the pattern-bound variables
2114                 -- Mark the ones that are in ! positions in the
2115                 -- data constructor as certainly-evaluated.
2116                 -- NB: simplLamBinders preserves this eval info
2117         ; let vs_with_evals = add_evals (dataConRepStrictness con)
2118         ; (env', vs') <- simplLamBndrs env vs_with_evals
2119
2120                 -- Bind the case-binder to (con args)
2121         ; let inst_tys' = tyConAppArgs (idType case_bndr')
2122               con_app :: OutExpr
2123               con_app   = mkConApp2 con inst_tys' vs'
2124
2125         ; env'' <- addAltUnfoldings env' scrut' case_bndr' con_app
2126         ; rhs' <- simplExprC env'' rhs cont'
2127         ; return (DataAlt con, vs', rhs') }
2128   where
2129         -- add_evals records the evaluated-ness of the bound variables of
2130         -- a case pattern.  This is *important*.  Consider
2131         --      data T = T !Int !Int
2132         --
2133         --      case x of { T a b -> T (a+1) b }
2134         --
2135         -- We really must record that b is already evaluated so that we don't
2136         -- go and re-evaluate it when constructing the result.
2137         -- See Note [Data-con worker strictness] in MkId.lhs
2138     add_evals the_strs
2139         = go vs the_strs
2140         where
2141           go [] [] = []
2142           go (v:vs') strs | isTyVar v = v : go vs' strs
2143           go (v:vs') (str:strs)
2144             | isMarkedStrict str = evald_v  : go vs' strs
2145             | otherwise          = zapped_v : go vs' strs
2146             where
2147               zapped_v = zapIdOccInfo v   -- See Note [Case alternative occ info]
2148               evald_v  = zapped_v `setIdUnfolding` evaldUnfolding
2149           go _ _ = pprPanic "cat_evals" (ppr con $$ ppr vs $$ ppr the_strs)
2150
2151
2152 addAltUnfoldings :: SimplEnv -> Maybe OutExpr -> OutId -> OutExpr -> SimplM SimplEnv
2153 addAltUnfoldings env scrut case_bndr con_app
2154   = do { dflags <- getDynFlags
2155        ; let con_app_unf = mkSimpleUnfolding dflags con_app
2156              env1 = addBinderUnfolding env case_bndr con_app_unf
2157
2158              -- See Note [Add unfolding for scrutinee]
2159              env2 = case scrut of
2160                       Just (Var v)           -> addBinderUnfolding env1 v con_app_unf
2161                       Just (Cast (Var v) co) -> addBinderUnfolding env1 v $
2162                                                 mkSimpleUnfolding dflags (Cast con_app (mkSymCo co))
2163                       _                      -> env1
2164
2165        ; traceSmpl "addAltUnf" (vcat [ppr case_bndr <+> ppr scrut, ppr con_app])
2166        ; return env2 }
2167
2168 addBinderUnfolding :: SimplEnv -> Id -> Unfolding -> SimplEnv
2169 addBinderUnfolding env bndr unf
2170   | debugIsOn, Just tmpl <- maybeUnfoldingTemplate unf
2171   = WARN( not (eqType (idType bndr) (exprType tmpl)),
2172           ppr bndr $$ ppr (idType bndr) $$ ppr tmpl $$ ppr (exprType tmpl) )
2173     modifyInScope env (bndr `setIdUnfolding` unf)
2174
2175   | otherwise
2176   = modifyInScope env (bndr `setIdUnfolding` unf)
2177
2178 zapBndrOccInfo :: Bool -> Id -> Id
2179 -- Consider  case e of b { (a,b) -> ... }
2180 -- Then if we bind b to (a,b) in "...", and b is not dead,
2181 -- then we must zap the deadness info on a,b
2182 zapBndrOccInfo keep_occ_info pat_id
2183   | keep_occ_info = pat_id
2184   | otherwise     = zapIdOccInfo pat_id
2185 \end{code}
2186
2187 Note [Add unfolding for scrutinee]
2188 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2189 In general it's unlikely that a variable scrutinee will appear
2190 in the case alternatives   case x of { ...x unlikely to appear... }
2191 because the binder-swap in OccAnal has got rid of all such occcurrences
2192 See Note [Binder swap] in OccAnal.
2193
2194 BUT it is still VERY IMPORTANT to add a suitable unfolding for a
2195 variable scrutinee, in simplAlt.  Here's why
2196    case x of y
2197      (a,b) -> case b of c
2198                 I# v -> ...(f y)...
2199 There is no occurrence of 'b' in the (...(f y)...).  But y gets
2200 the unfolding (a,b), and *that* mentions b.  If f has a RULE
2201     RULE f (p, I# q) = ...
2202 we want that rule to match, so we must extend the in-scope env with a
2203 suitable unfolding for 'y'.  It's *essential* for rule matching; but
2204 it's also good for case-elimintation -- suppose that 'f' was inlined
2205 and did multi-level case analysis, then we'd solve it in one
2206 simplifier sweep instead of two.
2207
2208 Exactly the same issue arises in SpecConstr;
2209 see Note [Add scrutinee to ValueEnv too] in SpecConstr
2210
2211 HOWEVER, given
2212   case x of y { Just a -> r1; Nothing -> r2 }
2213 we do not want to add the unfolding x -> y to 'x', which might seem cool,
2214 since 'y' itself has different unfoldings in r1 and r2.  Reason: if we
2215 did that, we'd have to zap y's deadness info and that is a very useful
2216 piece of information.
2217
2218 So instead we add the unfolding x -> Just a, and x -> Nothing in the
2219 respective RHSs.
2220
2221
2222 %************************************************************************
2223 %*                                                                      *
2224 \subsection{Known constructor}
2225 %*                                                                      *
2226 %************************************************************************
2227
2228 We are a bit careful with occurrence info.  Here's an example
2229
2230         (\x* -> case x of (a*, b) -> f a) (h v, e)
2231
2232 where the * means "occurs once".  This effectively becomes
2233         case (h v, e) of (a*, b) -> f a)
2234 and then
2235         let a* = h v; b = e in f a
2236 and then
2237         f (h v)
2238
2239 All this should happen in one sweep.
2240
2241 \begin{code}
2242 knownCon :: SimplEnv
2243          -> OutExpr                             -- The scrutinee
2244          -> DataCon -> [OutType] -> [OutExpr]   -- The scrutinee (in pieces)
2245          -> InId -> [InBndr] -> InExpr          -- The alternative
2246          -> SimplCont
2247          -> SimplM (SimplEnv, OutExpr)
2248
2249 knownCon env scrut dc dc_ty_args dc_args bndr bs rhs cont
2250   = do  { env'  <- bind_args env bs dc_args
2251         ; env'' <- bind_case_bndr env'
2252         ; simplExprF env'' rhs cont }
2253   where
2254     zap_occ = zapBndrOccInfo (isDeadBinder bndr)    -- bndr is an InId
2255
2256                   -- Ugh!
2257     bind_args env' [] _  = return env'
2258
2259     bind_args env' (b:bs') (Type ty : args)
2260       = ASSERT( isTyVar b )
2261         bind_args (extendTvSubst env' b ty) bs' args
2262
2263     bind_args env' (b:bs') (arg : args)
2264       = ASSERT( isId b )
2265         do { let b' = zap_occ b
2266              -- Note that the binder might be "dead", because it doesn't
2267              -- occur in the RHS; and simplNonRecX may therefore discard
2268              -- it via postInlineUnconditionally.
2269              -- Nevertheless we must keep it if the case-binder is alive,
2270              -- because it may be used in the con_app.  See Note [knownCon occ info]
2271            ; env'' <- simplNonRecX env' b' arg  -- arg satisfies let/app invariant
2272            ; bind_args env'' bs' args }
2273
2274     bind_args _ _ _ =
2275       pprPanic "bind_args" $ ppr dc $$ ppr bs $$ ppr dc_args $$
2276                              text "scrut:" <+> ppr scrut
2277
2278        -- It's useful to bind bndr to scrut, rather than to a fresh
2279        -- binding      x = Con arg1 .. argn
2280        -- because very often the scrut is a variable, so we avoid
2281        -- creating, and then subsequently eliminating, a let-binding
2282        -- BUT, if scrut is a not a variable, we must be careful
2283        -- about duplicating the arg redexes; in that case, make
2284        -- a new con-app from the args
2285     bind_case_bndr env
2286       | isDeadBinder bndr   = return env
2287       | exprIsTrivial scrut = return (extendIdSubst env bndr (DoneEx scrut))
2288       | otherwise           = do { dc_args <- mapM (simplVar env) bs
2289                                          -- dc_ty_args are aready OutTypes,
2290                                          -- but bs are InBndrs
2291                                  ; let con_app = Var (dataConWorkId dc)
2292                                                  `mkTyApps` dc_ty_args
2293                                                  `mkApps`   dc_args
2294                                  ; simplNonRecX env bndr con_app }
2295
2296 -------------------
2297 missingAlt :: SimplEnv -> Id -> [InAlt] -> SimplCont -> SimplM (SimplEnv, OutExpr)
2298                 -- This isn't strictly an error, although it is unusual.
2299                 -- It's possible that the simplifer might "see" that
2300                 -- an inner case has no accessible alternatives before
2301                 -- it "sees" that the entire branch of an outer case is
2302                 -- inaccessible.  So we simply put an error case here instead.
2303 missingAlt env case_bndr _ cont
2304   = WARN( True, ptext (sLit "missingAlt") <+> ppr case_bndr )
2305     return (env, mkImpossibleExpr (contResultType cont))
2306 \end{code}
2307
2308
2309 %************************************************************************
2310 %*                                                                      *
2311 \subsection{Duplicating continuations}
2312 %*                                                                      *
2313 %************************************************************************
2314
2315 \begin{code}
2316 prepareCaseCont :: SimplEnv
2317                 -> [InAlt] -> SimplCont
2318                 -> SimplM (SimplEnv,
2319                            SimplCont,   -- Dupable part
2320                            SimplCont)   -- Non-dupable part
2321 -- We are considering
2322 --     K[case _ of { p1 -> r1; ...; pn -> rn }]
2323 -- where K is some enclosing continuation for the case
2324 -- Goal: split K into two pieces Kdup,Knodup so that
2325 --       a) Kdup can be duplicated
2326 --       b) Knodup[Kdup[e]] = K[e]
2327 -- The idea is that we'll transform thus:
2328 --          Knodup[ (case _ of { p1 -> Kdup[r1]; ...; pn -> Kdup[rn] }
2329 --
2330 -- We may also return some extra bindings in SimplEnv (that scope over
2331 -- the entire continuation)
2332 --
2333 -- When case-of-case is off, just make the entire continuation non-dupable
2334
2335 prepareCaseCont env alts cont
2336   | not (sm_case_case (getMode env)) = return (env, mkBoringStop (contInputType cont), cont)
2337   | not (many_alts alts)             = return (env, cont, mkBoringStop (contResultType cont))
2338   | otherwise                        = mkDupableCont env cont
2339   where
2340     many_alts :: [InAlt] -> Bool  -- True iff strictly > 1 non-bottom alternative
2341     many_alts []  = False         -- See Note [Bottom alternatives]
2342     many_alts [_] = False
2343     many_alts (alt:alts)
2344       | is_bot_alt alt = many_alts alts
2345       | otherwise      = not (all is_bot_alt alts)
2346
2347     is_bot_alt (_,_,rhs) = exprIsBottom rhs
2348 \end{code}
2349
2350 Note [Bottom alternatives]
2351 ~~~~~~~~~~~~~~~~~~~~~~~~~~
2352 When we have
2353      case (case x of { A -> error .. ; B -> e; C -> error ..)
2354        of alts
2355 then we can just duplicate those alts because the A and C cases
2356 will disappear immediately.  This is more direct than creating
2357 join points and inlining them away; and in some cases we would
2358 not even create the join points (see Note [Single-alternative case])
2359 and we would keep the case-of-case which is silly.  See Trac #4930.
2360
2361 \begin{code}
2362 mkDupableCont :: SimplEnv -> SimplCont
2363               -> SimplM (SimplEnv, SimplCont, SimplCont)
2364
2365 mkDupableCont env cont
2366   | contIsDupable cont
2367   = return (env, cont, mkBoringStop (contResultType cont))
2368
2369 mkDupableCont _   (Stop {}) = panic "mkDupableCont"     -- Handled by previous eqn
2370
2371 mkDupableCont env (CoerceIt ty cont)
2372   = do  { (env', dup, nodup) <- mkDupableCont env cont
2373         ; return (env', CoerceIt ty dup, nodup) }
2374
2375 -- Duplicating ticks for now, not sure if this is good or not
2376 mkDupableCont env cont@(TickIt{})
2377   = return (env, mkBoringStop (contInputType cont), cont)
2378
2379 mkDupableCont env cont@(StrictBind {})
2380   =  return (env, mkBoringStop (contInputType cont), cont)
2381         -- See Note [Duplicating StrictBind]
2382
2383 mkDupableCont env (StrictArg info cci cont)
2384         -- See Note [Duplicating StrictArg]
2385   = do { (env', dup, nodup) <- mkDupableCont env cont
2386        ; (env'', args')     <- mapAccumLM makeTrivialArg env' (ai_args info)
2387        ; return (env'', StrictArg (info { ai_args = args' }) cci dup, nodup) }
2388
2389 mkDupableCont env (ApplyTo _ arg se cont)
2390   =     -- e.g.         [...hole...] (...arg...)
2391         --      ==>
2392         --              let a = ...arg...
2393         --              in [...hole...] a
2394     do  { (env', dup_cont, nodup_cont) <- mkDupableCont env cont
2395         ; arg' <- simplExpr (se `setInScope` env') arg
2396         ; (env'', arg'') <- makeTrivial NotTopLevel env' arg'
2397         ; let app_cont = ApplyTo OkToDup arg'' (zapSubstEnv env'') dup_cont
2398         ; return (env'', app_cont, nodup_cont) }
2399
2400 mkDupableCont env cont@(Select _ case_bndr [(_, bs, _rhs)] _ _)
2401 --  See Note [Single-alternative case]
2402 --  | not (exprIsDupable rhs && contIsDupable case_cont)
2403 --  | not (isDeadBinder case_bndr)
2404   | all isDeadBinder bs  -- InIds
2405     && not (isUnLiftedType (idType case_bndr))
2406     -- Note [Single-alternative-unlifted]
2407   = return (env, mkBoringStop (contInputType cont), cont)
2408
2409 mkDupableCont env (Select _ case_bndr alts se cont)
2410   =     -- e.g.         (case [...hole...] of { pi -> ei })
2411         --      ===>
2412         --              let ji = \xij -> ei
2413         --              in case [...hole...] of { pi -> ji xij }
2414     do  { tick (CaseOfCase case_bndr)
2415         ; (env', dup_cont, nodup_cont) <- prepareCaseCont env alts cont
2416                 -- NB: We call prepareCaseCont here.  If there is only one
2417                 -- alternative, then dup_cont may be big, but that's ok
2418                 -- because we push it into the single alternative, and then
2419                 -- use mkDupableAlt to turn that simplified alternative into
2420                 -- a join point if it's too big to duplicate.
2421                 -- And this is important: see Note [Fusing case continuations]
2422
2423         ; let alt_env = se `setInScope` env'
2424
2425         ; (alt_env', case_bndr') <- simplBinder alt_env case_bndr
2426         ; alts' <- mapM (simplAlt alt_env' Nothing [] case_bndr' dup_cont) alts
2427         -- Safe to say that there are no handled-cons for the DEFAULT case
2428                 -- NB: simplBinder does not zap deadness occ-info, so
2429                 -- a dead case_bndr' will still advertise its deadness
2430                 -- This is really important because in
2431                 --      case e of b { (# p,q #) -> ... }
2432                 -- b is always dead, and indeed we are not allowed to bind b to (# p,q #),
2433                 -- which might happen if e was an explicit unboxed pair and b wasn't marked dead.
2434                 -- In the new alts we build, we have the new case binder, so it must retain
2435                 -- its deadness.
2436         -- NB: we don't use alt_env further; it has the substEnv for
2437         --     the alternatives, and we don't want that
2438
2439         ; (env'', alts'') <- mkDupableAlts env' case_bndr' alts'
2440         ; return (env'',  -- Note [Duplicated env]
2441                   Select OkToDup case_bndr' alts'' (zapSubstEnv env'')
2442                          (mkBoringStop (contInputType nodup_cont)),
2443                   nodup_cont) }
2444
2445
2446 mkDupableAlts :: SimplEnv -> OutId -> [InAlt]
2447               -> SimplM (SimplEnv, [InAlt])
2448 -- Absorbs the continuation into the new alternatives
2449
2450 mkDupableAlts env case_bndr' the_alts
2451   = go env the_alts
2452   where
2453     go env0 [] = return (env0, [])
2454     go env0 (alt:alts)
2455         = do { (env1, alt') <- mkDupableAlt env0 case_bndr' alt
2456              ; (env2, alts') <- go env1 alts
2457              ; return (env2, alt' : alts' ) }
2458
2459 mkDupableAlt :: SimplEnv -> OutId -> (AltCon, [CoreBndr], CoreExpr)
2460               -> SimplM (SimplEnv, (AltCon, [CoreBndr], CoreExpr))
2461 mkDupableAlt env case_bndr (con, bndrs', rhs') = do
2462   dflags <- getDynFlags
2463   if exprIsDupable dflags rhs'  -- Note [Small alternative rhs]
2464    then return (env, (con, bndrs', rhs'))
2465    else
2466     do  { let rhs_ty'  = exprType rhs'
2467               scrut_ty = idType case_bndr
2468               case_bndr_w_unf
2469                 = case con of
2470                       DEFAULT    -> case_bndr
2471                       DataAlt dc -> setIdUnfolding case_bndr unf
2472                           where
2473                                  -- See Note [Case binders and join points]
2474                              unf = mkInlineUnfolding Nothing rhs
2475                              rhs = mkConApp2 dc (tyConAppArgs scrut_ty) bndrs'
2476
2477                       LitAlt {} -> WARN( True, ptext (sLit "mkDupableAlt")
2478                                                 <+> ppr case_bndr <+> ppr con )
2479                                    case_bndr
2480                            -- The case binder is alive but trivial, so why has
2481                            -- it not been substituted away?
2482
2483               used_bndrs' | isDeadBinder case_bndr = filter abstract_over bndrs'
2484                           | otherwise              = bndrs' ++ [case_bndr_w_unf]
2485
2486               abstract_over bndr
2487                   | isTyVar bndr = True -- Abstract over all type variables just in case
2488                   | otherwise    = not (isDeadBinder bndr)
2489                         -- The deadness info on the new Ids is preserved by simplBinders
2490
2491         ; (final_bndrs', final_args)    -- Note [Join point abstraction]
2492                 <- if (any isId used_bndrs')
2493                    then return (used_bndrs', varsToCoreExprs used_bndrs')
2494                     else do { rw_id <- newId (fsLit "w") voidPrimTy
2495                             ; return ([setOneShotLambda rw_id], [Var voidPrimId]) }
2496
2497         ; join_bndr <- newId (fsLit "$j") (mkPiTypes final_bndrs' rhs_ty')
2498                 -- Note [Funky mkPiTypes]
2499
2500         ; let   -- We make the lambdas into one-shot-lambdas.  The
2501                 -- join point is sure to be applied at most once, and doing so
2502                 -- prevents the body of the join point being floated out by
2503                 -- the full laziness pass
2504                 really_final_bndrs     = map one_shot final_bndrs'
2505                 one_shot v | isId v    = setOneShotLambda v
2506                            | otherwise = v
2507                 join_rhs   = mkLams really_final_bndrs rhs'
2508                 join_arity = exprArity join_rhs
2509                 join_call  = mkApps (Var join_bndr) final_args
2510
2511         ; env' <- addPolyBind NotTopLevel env (NonRec (join_bndr `setIdArity` join_arity) join_rhs)
2512         ; return (env', (con, bndrs', join_call)) }
2513                 -- See Note [Duplicated env]
2514 \end{code}
2515
2516 Note [Fusing case continuations]
2517 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2518 It's important to fuse two successive case continuations when the
2519 first has one alternative.  That's why we call prepareCaseCont here.
2520 Consider this, which arises from thunk splitting (see Note [Thunk
2521 splitting] in WorkWrap):
2522
2523       let
2524         x* = case (case v of {pn -> rn}) of
2525                I# a -> I# a
2526       in body
2527
2528 The simplifier will find
2529     (Var v) with continuation
2530             Select (pn -> rn) (
2531             Select [I# a -> I# a] (
2532             StrictBind body Stop
2533
2534 So we'll call mkDupableCont on
2535    Select [I# a -> I# a] (StrictBind body Stop)
2536 There is just one alternative in the first Select, so we want to
2537 simplify the rhs (I# a) with continuation (StricgtBind body Stop)
2538 Supposing that body is big, we end up with
2539           let $j a = <let x = I# a in body>
2540           in case v of { pn -> case rn of
2541                                  I# a -> $j a }
2542 This is just what we want because the rn produces a box that
2543 the case rn cancels with.
2544
2545 See Trac #4957 a fuller example.
2546
2547 Note [Case binders and join points]
2548 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2549 Consider this
2550    case (case .. ) of c {
2551      I# c# -> ....c....
2552
2553 If we make a join point with c but not c# we get
2554   $j = \c -> ....c....
2555
2556 But if later inlining scrutines the c, thus
2557
2558   $j = \c -> ... case c of { I# y -> ... } ...
2559
2560 we won't see that 'c' has already been scrutinised.  This actually
2561 happens in the 'tabulate' function in wave4main, and makes a significant
2562 difference to allocation.
2563
2564 An alternative plan is this:
2565
2566    $j = \c# -> let c = I# c# in ...c....
2567
2568 but that is bad if 'c' is *not* later scrutinised.
2569
2570 So instead we do both: we pass 'c' and 'c#' , and record in c's inlining
2571 (a stable unfolding) that it's really I# c#, thus
2572
2573    $j = \c# -> \c[=I# c#] -> ...c....
2574
2575 Absence analysis may later discard 'c'.
2576
2577 NB: take great care when doing strictness analysis;
2578     see Note [Lamba-bound unfoldings] in DmdAnal.
2579
2580 Also note that we can still end up passing stuff that isn't used.  Before
2581 strictness analysis we have
2582    let $j x y c{=(x,y)} = (h c, ...)
2583    in ...
2584 After strictness analysis we see that h is strict, we end up with
2585    let $j x y c{=(x,y)} = ($wh x y, ...)
2586 and c is unused.
2587
2588 Note [Duplicated env]
2589 ~~~~~~~~~~~~~~~~~~~~~
2590 Some of the alternatives are simplified, but have not been turned into a join point
2591 So they *must* have an zapped subst-env.  So we can't use completeNonRecX to
2592 bind the join point, because it might to do PostInlineUnconditionally, and
2593 we'd lose that when zapping the subst-env.  We could have a per-alt subst-env,
2594 but zapping it (as we do in mkDupableCont, the Select case) is safe, and
2595 at worst delays the join-point inlining.
2596
2597 Note [Small alternative rhs]
2598 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2599 It is worth checking for a small RHS because otherwise we
2600 get extra let bindings that may cause an extra iteration of the simplifier to
2601 inline back in place.  Quite often the rhs is just a variable or constructor.
2602 The Ord instance of Maybe in PrelMaybe.lhs, for example, took several extra
2603 iterations because the version with the let bindings looked big, and so wasn't
2604 inlined, but after the join points had been inlined it looked smaller, and so
2605 was inlined.
2606
2607 NB: we have to check the size of rhs', not rhs.
2608 Duplicating a small InAlt might invalidate occurrence information
2609 However, if it *is* dupable, we return the *un* simplified alternative,
2610 because otherwise we'd need to pair it up with an empty subst-env....
2611 but we only have one env shared between all the alts.
2612 (Remember we must zap the subst-env before re-simplifying something).
2613 Rather than do this we simply agree to re-simplify the original (small) thing later.
2614
2615 Note [Funky mkPiTypes]
2616 ~~~~~~~~~~~~~~~~~~~~~~
2617 Notice the funky mkPiTypes.  If the contructor has existentials
2618 it's possible that the join point will be abstracted over
2619 type varaibles as well as term variables.
2620  Example:  Suppose we have
2621         data T = forall t.  C [t]
2622  Then faced with
2623         case (case e of ...) of
2624             C t xs::[t] -> rhs
2625  We get the join point
2626         let j :: forall t. [t] -> ...
2627             j = /\t \xs::[t] -> rhs
2628         in
2629         case (case e of ...) of
2630             C t xs::[t] -> j t xs
2631
2632 Note [Join point abstraction]
2633 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2634 Join points always have at least one value argument,
2635 for several reasons
2636
2637 * If we try to lift a primitive-typed something out
2638   for let-binding-purposes, we will *caseify* it (!),
2639   with potentially-disastrous strictness results.  So
2640   instead we turn it into a function: \v -> e
2641   where v::Void#.  The value passed to this function is void,
2642   which generates (almost) no code.
2643
2644 * CPR.  We used to say "&& isUnLiftedType rhs_ty'" here, but now
2645   we make the join point into a function whenever used_bndrs'
2646   is empty.  This makes the join-point more CPR friendly.
2647   Consider:       let j = if .. then I# 3 else I# 4
2648                   in case .. of { A -> j; B -> j; C -> ... }
2649
2650   Now CPR doesn't w/w j because it's a thunk, so
2651   that means that the enclosing function can't w/w either,
2652   which is a lose.  Here's the example that happened in practice:
2653           kgmod :: Int -> Int -> Int
2654           kgmod x y = if x > 0 && y < 0 || x < 0 && y > 0
2655                       then 78
2656                       else 5
2657
2658 * Let-no-escape.  We want a join point to turn into a let-no-escape
2659   so that it is implemented as a jump, and one of the conditions
2660   for LNE is that it's not updatable.  In CoreToStg, see
2661   Note [What is a non-escaping let]
2662
2663 * Floating.  Since a join point will be entered once, no sharing is
2664   gained by floating out, but something might be lost by doing
2665   so because it might be allocated.
2666
2667 I have seen a case alternative like this:
2668         True -> \v -> ...
2669 It's a bit silly to add the realWorld dummy arg in this case, making
2670         $j = \s v -> ...
2671            True -> $j s
2672 (the \v alone is enough to make CPR happy) but I think it's rare
2673
2674 There's a slight infelicity here: we pass the overall
2675 case_bndr to all the join points if it's used in *any* RHS,
2676 because we don't know its usage in each RHS separately
2677
2678
2679 Note [Duplicating StrictArg]
2680 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2681 The original plan had (where E is a big argument)
2682 e.g.    f E [..hole..]
2683         ==>     let $j = \a -> f E a
2684                 in $j [..hole..]
2685
2686 But this is terrible! Here's an example:
2687         && E (case x of { T -> F; F -> T })
2688 Now, && is strict so we end up simplifying the case with
2689
2690 an ArgOf continuation.  If we let-bind it, we get
2691         let $j = \v -> && E v
2692         in simplExpr (case x of { T -> F; F -> T })
2693                      (ArgOf (\r -> $j r)
2694 And after simplifying more we get
2695         let $j = \v -> && E v
2696         in case x of { T -> $j F; F -> $j T }
2697 Which is a Very Bad Thing
2698
2699 What we do now is this
2700         f E [..hole..]
2701         ==>     let a = E
2702                 in f a [..hole..]
2703 Now if the thing in the hole is a case expression (which is when
2704 we'll call mkDupableCont), we'll push the function call into the
2705 branches, which is what we want.  Now RULES for f may fire, and
2706 call-pattern specialisation.  Here's an example from Trac #3116
2707      go (n+1) (case l of
2708                  1  -> bs'
2709                  _  -> Chunk p fpc (o+1) (l-1) bs')
2710 If we can push the call for 'go' inside the case, we get
2711 call-pattern specialisation for 'go', which is *crucial* for
2712 this program.
2713
2714 Here is the (&&) example:
2715         && E (case x of { T -> F; F -> T })
2716   ==>   let a = E in
2717         case x of { T -> && a F; F -> && a T }
2718 Much better!
2719
2720 Notice that
2721   * Arguments to f *after* the strict one are handled by
2722     the ApplyTo case of mkDupableCont.  Eg
2723         f [..hole..] E
2724
2725   * We can only do the let-binding of E because the function
2726     part of a StrictArg continuation is an explicit syntax
2727     tree.  In earlier versions we represented it as a function
2728     (CoreExpr -> CoreEpxr) which we couldn't take apart.
2729
2730 Do *not* duplicate StrictBind and StritArg continuations.  We gain
2731 nothing by propagating them into the expressions, and we do lose a
2732 lot.
2733
2734 The desire not to duplicate is the entire reason that
2735 mkDupableCont returns a pair of continuations.
2736
2737 Note [Duplicating StrictBind]
2738 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2739 Unlike StrictArg, there doesn't seem anything to gain from
2740 duplicating a StrictBind continuation, so we don't.
2741
2742
2743 Note [Single-alternative cases]
2744 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2745 This case is just like the ArgOf case.  Here's an example:
2746         data T a = MkT !a
2747         ...(MkT (abs x))...
2748 Then we get
2749         case (case x of I# x' ->
2750               case x' <# 0# of
2751                 True  -> I# (negate# x')
2752                 False -> I# x') of y {
2753           DEFAULT -> MkT y
2754 Because the (case x) has only one alternative, we'll transform to
2755         case x of I# x' ->
2756         case (case x' <# 0# of
2757                 True  -> I# (negate# x')
2758                 False -> I# x') of y {
2759           DEFAULT -> MkT y
2760 But now we do *NOT* want to make a join point etc, giving
2761         case x of I# x' ->
2762         let $j = \y -> MkT y
2763         in case x' <# 0# of
2764                 True  -> $j (I# (negate# x'))
2765                 False -> $j (I# x')
2766 In this case the $j will inline again, but suppose there was a big
2767 strict computation enclosing the orginal call to MkT.  Then, it won't
2768 "see" the MkT any more, because it's big and won't get duplicated.
2769 And, what is worse, nothing was gained by the case-of-case transform.
2770
2771 So, in circumstances like these, we don't want to build join points
2772 and push the outer case into the branches of the inner one. Instead,
2773 don't duplicate the continuation.
2774
2775 When should we use this strategy?  We should not use it on *every*
2776 single-alternative case:
2777   e.g.  case (case ....) of (a,b) -> (# a,b #)
2778 Here we must push the outer case into the inner one!
2779 Other choices:
2780
2781    * Match [(DEFAULT,_,_)], but in the common case of Int,
2782      the alternative-filling-in code turned the outer case into
2783                 case (...) of y { I# _ -> MkT y }
2784
2785    * Match on single alternative plus (not (isDeadBinder case_bndr))
2786      Rationale: pushing the case inwards won't eliminate the construction.
2787      But there's a risk of
2788                 case (...) of y { (a,b) -> let z=(a,b) in ... }
2789      Now y looks dead, but it'll come alive again.  Still, this
2790      seems like the best option at the moment.
2791
2792    * Match on single alternative plus (all (isDeadBinder bndrs))
2793      Rationale: this is essentially  seq.
2794
2795    * Match when the rhs is *not* duplicable, and hence would lead to a
2796      join point.  This catches the disaster-case above.  We can test
2797      the *un-simplified* rhs, which is fine.  It might get bigger or
2798      smaller after simplification; if it gets smaller, this case might
2799      fire next time round.  NB also that we must test contIsDupable
2800      case_cont *too, because case_cont might be big!
2801
2802      HOWEVER: I found that this version doesn't work well, because
2803      we can get         let x = case (...) of { small } in ...case x...
2804      When x is inlined into its full context, we find that it was a bad
2805      idea to have pushed the outer case inside the (...) case.
2806
2807 Note [Single-alternative-unlifted]
2808 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2809 Here's another single-alternative where we really want to do case-of-case:
2810
2811 data Mk1 = Mk1 Int# | Mk2 Int#
2812
2813 M1.f =
2814     \r [x_s74 y_s6X]
2815         case
2816             case y_s6X of tpl_s7m {
2817               M1.Mk1 ipv_s70 -> ipv_s70;
2818               M1.Mk2 ipv_s72 -> ipv_s72;
2819             }
2820         of
2821         wild_s7c
2822         { __DEFAULT ->
2823               case
2824                   case x_s74 of tpl_s7n {
2825                     M1.Mk1 ipv_s77 -> ipv_s77;
2826                     M1.Mk2 ipv_s79 -> ipv_s79;
2827                   }
2828               of
2829               wild1_s7b
2830               { __DEFAULT -> ==# [wild1_s7b wild_s7c];
2831               };
2832         };
2833
2834 So the outer case is doing *nothing at all*, other than serving as a
2835 join-point.  In this case we really want to do case-of-case and decide
2836 whether to use a real join point or just duplicate the continuation:
2837
2838     let $j s7c = case x of
2839                    Mk1 ipv77 -> (==) s7c ipv77
2840                    Mk1 ipv79 -> (==) s7c ipv79
2841     in
2842     case y of
2843       Mk1 ipv70 -> $j ipv70
2844       Mk2 ipv72 -> $j ipv72
2845
2846 Hence: check whether the case binder's type is unlifted, because then
2847 the outer case is *not* a seq.