More clarification in docs for implicit quantification
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.0.0], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands,
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42 FP_PROG_SORT
43
44 dnl ----------------------------------------------------------
45 FP_SETUP_PROJECT_VERSION
46
47 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
48 AC_SUBST([release], [1])
49
50 # First off, a distrib sanity check..
51 AC_CONFIG_SRCDIR([mk/config.mk.in])
52
53 dnl * We require autoconf version 2.60
54 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
55 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
56 dnl Using autoconf 2.59 started to give nonsense like this
57 dnl  #define SIZEOF_CHAR 0
58 dnl recently.
59 AC_PREREQ([2.60])
60
61 # -------------------------------------------------------------------------
62 # Prepare to generate the following header files
63 #
64 #
65 AC_CONFIG_HEADER(mk/config.h)
66
67 # No, semi-sadly, we don't do `--srcdir'...
68 if test x"$srcdir" != 'x.' ; then
69     echo "This configuration does not support the \`--srcdir' option.."
70     exit 1
71 fi
72
73 dnl --------------------------------------------------------------
74 dnl * Project specific configuration options
75 dnl --------------------------------------------------------------
76 dnl What follows is a bunch of options that can either be configured
77 dnl through command line options to the configure script or by
78 dnl supplying defns in the build tree's mk/build.mk. Having the option to
79 dnl use either is considered a Feature.
80
81 dnl ** What command to use to compile compiler sources ?
82 dnl --------------------------------------------------------------
83
84 AC_ARG_WITH([ghc],
85 [AC_HELP_STRING([--with-ghc=ARG],
86   [Use ARG as the path to GHC  [default=autodetect]])],
87   [WithGhc="$withval"],
88   [if test "$GHC" = ""; then
89     AC_PATH_PROG([GHC], [ghc])
90   fi
91   WithGhc="$GHC"])
92
93 dnl ** Tell the make system which OS we are using
94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
95 AC_SUBST(OSTYPE)
96
97 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
98 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
99                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
100         EnableBootstrapWithDevelSnaphost=YES,
101         EnableBootstrapWithDevelSnaphost=NO
102 )
103
104 AC_ARG_ENABLE(tarballs-autodownload,
105 [AC_HELP_STRING([--enable-tarballs-autodownload],
106                 [Automatically download Windows distribution binaries if needed.])],
107         TarballsAutodownload=YES,
108         TarballsAutodownload=NO
109 )
110 if test "$WithGhc" != ""; then
111   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
112
113   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
114      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
115   fi
116
117   AC_SUBST(GhcVersion)dnl
118   AC_SUBST(GhcMajVersion)dnl
119   AC_SUBST(GhcMinVersion)dnl
120   AC_SUBST(GhcPatchLevel)dnl
121   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
122   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
123
124   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
125   dnl ToDo, once "ld command" is reliably available.
126   dnl Then, we can remove the LD_STAGE0 hack in mk/build-package-date.mk
127   dnl BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
128   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
129   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
130   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
131 fi
132
133 dnl ** Must have GHC to build GHC
134 if test "$WithGhc" = ""
135 then
136     AC_MSG_ERROR([GHC is required.])
137 fi
138 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.8],
139     [AC_MSG_ERROR([GHC version 7.8 or later is required to compile GHC.])])
140
141 if test `expr $GhcMinVersion % 2` = "1"
142 then
143     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
144     then
145         AC_MSG_ERROR([
146      $WithGhc is a development snapshot of GHC, version $GhcVersion.
147      Bootstrapping using this version of GHC is not supported, and may not
148      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
149      or --with-ghc to specify a different GHC to use.])
150     fi
151 fi
152
153 GHC_PACKAGE_DB_FLAG=package-db
154 AC_SUBST(GHC_PACKAGE_DB_FLAG)
155
156 # GHC 7.7+ needs -fcmm-sink when compiling Parser.hs. See #8182
157 FP_COMPARE_VERSIONS([$GhcVersion],[-gt],[7.7],
158                     CMM_SINK_BOOTSTRAP_IS_NEEDED=YES,
159                     CMM_SINK_BOOTSTRAP_IS_NEEDED=NO)
160 AC_SUBST(CMM_SINK_BOOTSTRAP_IS_NEEDED)
161
162 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.9],
163                     SUPPORTS_COMPONENT_ID=NO,
164                     SUPPORTS_COMPONENT_ID=YES)
165 AC_SUBST(SUPPORTS_COMPONENT_ID)
166
167 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.11],
168                     SUPPORTS_THIS_UNIT_ID=NO,
169                     SUPPORTS_THIS_UNIT_ID=YES)
170 AC_SUBST(SUPPORTS_THIS_UNIT_ID)
171
172 # GHC is passed to Cabal, so we need a native path
173 if test "${WithGhc}" != ""
174 then
175     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
176
177     if test "$ghc_host_os" = "mingw32"
178     then
179         if test "${OSTYPE}" = "msys"
180         then
181             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
182         else
183             # Canonicalise to <drive>:/path/to/ghc
184             WithGhc=`cygpath -m "${WithGhc}"`
185         fi
186         echo "GHC path canonicalised to: ${WithGhc}"
187     fi
188 fi
189 AC_SUBST([WithGhc])
190
191 dnl ** Without optimization some INLINE trickery fails for GHCi
192 SRC_CC_OPTS="-O"
193
194 dnl--------------------------------------------------------------------
195 dnl * Choose host(/target/build) platform
196 dnl--------------------------------------------------------------------
197 dnl If we aren't explicitly told what values to use with configure flags,
198 dnl we ask the bootstrapping compiler what platform it is for
199
200 if test "${WithGhc}" != ""
201 then
202         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
203         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
204         if test "$bootstrap_host" != "$bootstrap_target"
205         then
206                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
207         fi
208 fi
209
210 # We have to run these unconditionally, but we may discard their
211 # results in the following code
212 AC_CANONICAL_BUILD
213 AC_CANONICAL_HOST
214 AC_CANONICAL_TARGET
215
216 FPTOOLS_SET_PLATFORM_VARS
217
218 # Verify that the installed (bootstrap) GHC is capable of generating
219 # code for the requested build platform.
220 if test "$BuildPlatform" != "$bootstrap_target"
221 then
222     echo "This GHC (${WithGhc}) does not generate code for the build platform"
223     echo "   GHC target platform    : $bootstrap_target"
224     echo "   Desired build platform : $BuildPlatform"
225     exit 1
226 fi
227
228 # Testing if we shall enable shared libs support on Solaris.
229 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
230
231 SOLARIS_BROKEN_SHLD=NO
232
233 case $host in
234      i386-*-solaris2)
235      # here we go with the test
236      MINOR=`uname -r|cut -d '.' -f 2-`
237      if test "$MINOR" -lt "11"; then
238          SOLARIS_BROKEN_SHLD=YES
239      fi
240      ;;
241 esac
242
243 AC_SUBST(SOLARIS_BROKEN_SHLD)
244
245 dnl ** Do an unregisterised build?
246 dnl --------------------------------------------------------------
247 case "$HostArch" in
248     i386|x86_64|powerpc|powerpc64|powerpc64le|arm)
249         UnregisterisedDefault=NO
250         ;;
251     *)
252         UnregisterisedDefault=YES
253         ;;
254 esac
255 AC_ARG_ENABLE(unregisterised,
256 [AC_HELP_STRING([--enable-unregisterised],
257 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
258 [ if test x"$enableval" = x"yes"; then
259         Unregisterised=YES
260   else
261         Unregisterised=NO
262   fi
263 ],
264 [Unregisterised="$UnregisterisedDefault"]
265 )
266 AC_SUBST(Unregisterised)
267
268 AC_ARG_WITH(hc,
269 [AC_HELP_STRING([--with-hc=ARG],
270         [Use ARG as the path to the compiler for compiling ordinary
271          Haskell code  (default= value of --with-ghc)])],
272 [WithHc="$withval"],
273 [WithHc=$WithGhc]
274 )
275 AC_SUBST(WithHc)
276
277 # This uses GHC, so put it after the "GHC is required" check above:
278 FP_INTREE_GHC_PWD
279 FP_FIND_ROOT
280
281 fail() {
282     echo >&2
283     echo "$1" >&2
284     exit 1
285 }
286
287
288 if test "$HostOS" = "mingw32"
289 then
290     # Find the mingw-w64 7z file to extract.
291     # NB. If you update the tarballs to a new version of gcc, don't
292     # forget to tweak the paths in driver/gcc/gcc.c.
293     if test "$HostArch" = "i386"
294     then
295         mingw_arch="i686"
296         tarball_dest_dir="mingw-w64/x86"
297         tarball_mingw_dir="mingw32"
298     else
299         mingw_arch="x86_64"
300         tarball_dest_dir="mingw-w64/x86_64"
301         tarball_mingw_dir="mingw64"
302     fi
303 fi
304
305 set_up_tarballs() {
306     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
307     local action
308     if test "$TarballsAutodownload" = "NO"
309     then
310         action="verify"
311     else
312         action="download"
313     fi
314     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
315     case $? in
316         0)
317            rm missing-win32-tarballs
318            ;;
319         2)
320            echo
321            echo "Error:"
322            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
323            echo
324            echo "  * run configure with the --enable-tarballs-autodownload option"
325            echo
326            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
327            echo
328            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
329            echo "    them in the ghc-tarballs directory."
330            echo
331            exit 1
332            ;;
333         *)
334            echo
335            echo "Error fetching msys2 tarballs; see errors above."
336            exit 1
337            ;;
338     esac
339
340     # Extract all the tarballs in one go
341     if ! test -d inplace/mingw
342     then
343         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
344         rm -rf inplace/mingw
345         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
346         ( cd inplace &&
347         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
348         rm ".MTREE" &&
349         rm ".PKGINFO" &&
350         cd .. ) || fail "Error: Could not extract Windows toolchains."
351
352         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
353         touch inplace/mingw
354
355         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
356         # make a wrapper around it to give it the proper paths
357         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
358         PATH=`pwd`/inplace/mingw/bin:$PATH
359         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
360
361         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
362     fi
363 }
364
365 if test "$HostOS" = "mingw32"
366 then
367     test -d inplace || mkdir inplace
368
369     # NB. Download and extract the MingW-w64 distribution if required
370     set_up_tarballs
371
372     mingwbin="$hardtop/inplace/mingw/bin/"
373     CC="${mingwbin}gcc.exe"
374     LD="${mingwbin}ld.exe"
375     NM="${mingwbin}nm.exe"
376     RANLIB="${mingwbin}ranlib.exe"
377     OBJDUMP="${mingwbin}objdump.exe"
378     fp_prog_ar="${mingwbin}ar.exe"
379
380     # NB. Download the perl binaries if required
381     if ! test -d inplace/perl ||
382          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
383     then
384         AC_MSG_NOTICE([Making in-tree perl tree])
385         rm -rf inplace/perl
386         mkdir inplace/perl
387         (
388             cd inplace/perl &&
389             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
390         )
391         AC_MSG_NOTICE([In-tree perl tree created])
392     fi
393 fi
394
395 FP_ICONV
396 FP_GMP
397 FP_CURSES
398
399 XCODE_VERSION()
400
401 SplitObjsBroken=NO
402 if test "$TargetOS_CPP" = "darwin"
403 then
404     # Split objects is broken (#4013) with XCode < 3.2
405     if test "$XCodeVersion1" -lt 3
406     then
407         SplitObjsBroken=YES
408     else
409         if test "$XCodeVersion1" -eq 3
410         then
411             if test "$XCodeVersion2" -lt 2
412             then
413                 SplitObjsBroken=YES
414             fi
415         fi
416     fi
417 fi
418 AC_SUBST([SplitObjsBroken])
419
420 dnl ** Building a cross compiler?
421 dnl --------------------------------------------------------------
422 CrossCompiling=NO
423 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
424 if test "$target" != "$host" ; then
425     CrossCompiling=YES
426     cross_compiling=yes   # This tells configure that it can accept just 'target',
427                           # otherwise you get
428                           #   configure: error: cannot run C compiled programs.
429                           #   If you meant to cross compile, use `--host'.
430 fi
431 if test "$build" != "$host" ; then
432    AC_MSG_ERROR([
433 You've selected:
434
435   BUILD:  $build   (the architecture we're building on)
436   HOST:   $host    (the architecture the compiler we're building will execute on)
437   TARGET: $target  (the architecture the compiler we're building will produce code for)
438
439 BUILD must equal HOST; that is, we do not support building GHC itself
440 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
441 1 will be a cross-compiler, and stage 2 will be the cross-compiled
442 GHC.
443 ])
444 fi
445 if test "$CrossCompiling" = "YES"
446 then
447   CrossCompilePrefix="${target}-"
448 else
449   CrossCompilePrefix=""
450 fi
451 TargetPlatformFull="${target}"
452 AC_SUBST(CrossCompiling)
453 AC_SUBST(CrossCompilePrefix)
454 AC_SUBST(TargetPlatformFull)
455
456 dnl ** Which gcc to use?
457 dnl --------------------------------------------------------------
458 FIND_GCC([WhatGccIsCalled], [gcc], [gcc])
459 CC="$WhatGccIsCalled"
460 export CC
461
462 # If --with-gcc was used, and we're not cross-compiling, then it also
463 # applies to the stage0 compiler.
464 MAYBE_OVERRIDE_STAGE0([gcc],[CC_STAGE0])
465 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
466
467 dnl make extensions visible to allow feature-tests to detect them lateron
468 AC_USE_SYSTEM_EXTENSIONS
469
470 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
471 AC_PROG_CPP
472
473 # --with-hs-cpp/--with-hs-cpp-flags
474 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
475 AC_SUBST([HaskellCPPCmd])
476 AC_SUBST([HaskellCPPArgs])
477
478 dnl ** Which ld to use?
479 dnl --------------------------------------------------------------
480 FIND_LD([LdCmd])
481 AC_SUBST([LdCmd])
482
483 dnl ** Which nm to use?
484 dnl --------------------------------------------------------------
485 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
486 NmCmd="$NM"
487 AC_SUBST([NmCmd])
488
489 dnl ** Which objdump to use?
490 dnl --------------------------------------------------------------
491 FP_ARG_WITH_PATH_GNU_PROG_OPTIONAL([OBJDUMP], [objdump], [objdump])
492 ObjdumpCmd="$OBJDUMP"
493 AC_SUBST([ObjdumpCmd])
494
495 dnl ** Which ar to use?
496 dnl --------------------------------------------------------------
497 FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
498 ArCmd="$AR"
499 fp_prog_ar="$AR"
500 AC_SUBST([ArCmd])
501
502 dnl ** Which ranlib to use?
503 dnl --------------------------------------------------------------
504 FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
505 RanlibCmd="$RANLIB"
506 RANLIB="$RanlibCmd"
507
508
509 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
510 case $HostOS_CPP in
511 cygwin32|mingw32)
512     dnl ** Which objdump to use?
513     dnl --------------------------------------------------------------
514     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
515     ObjdumpCmd="$OBJDUMP"
516     AC_SUBST([ObjdumpCmd])
517     ;;
518 esac
519
520 # Here is where we re-target which specific version of the LLVM
521 # tools we are looking for. In the past, GHC supported a number of
522 # versions of LLVM simultaneously, but that stopped working around
523 # 3.5/3.6 release of LLVM.
524 LlvmVersion=3.7
525 AC_SUBST([LlvmVersion])
526 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
527 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
528
529 dnl ** Which LLVM llc to use?
530 dnl --------------------------------------------------------------
531 FIND_LLVM_PROG([LLC], [llc], [llc], [$LlvmVersion])
532 LlcCmd="$LLC"
533 AC_SUBST([LlcCmd])
534
535 dnl ** Which LLVM opt to use?
536 dnl --------------------------------------------------------------
537 FIND_LLVM_PROG([OPT], [opt], [opt], [$LlvmVersion])
538 OptCmd="$OPT"
539 AC_SUBST([OptCmd])
540
541 dnl --------------------------------------------------------------
542 dnl End of configure script option section
543 dnl --------------------------------------------------------------
544
545
546 dnl --------------------------------------------------------------
547 dnl * General configuration checks
548 dnl --------------------------------------------------------------
549
550 dnl ** Bug 9439: Some GHC 7.8 releases had broken LLVM code generator.
551 dnl Unfortunately we don't know whether the user is going to request a
552 dnl build with the LLVM backend as this is only given in build.mk.
553 dnl
554 dnl Instead, we try to do as much work as possible here, checking
555 dnl whether -fllvm is the stage 0 compiler's default. If so we
556 dnl fail. If not, we check whether -fllvm is affected explicitly and
557 dnl if so set a flag. The build system will later check this flag
558 dnl after the desired build flags are known.
559
560 dnl This problem is further complicated by the fact that the llvm
561 dnl version used by the bootstrap compiler may be different from the
562 dnl version we arre trying to compile GHC against. Therefore, we need
563 dnl to find the boostrap compiler's `settings` file then check to see
564 dnl if the `opt` and `llc` command strings are non-empty and if these
565 dnl programs exist. Only if they exist to we test for bug #9439.
566
567 FIND_GHC_BOOTSTRAP_PROG([BootstrapLlcCmd], [${WithGhc}], "LLVM llc command")
568 FIND_GHC_BOOTSTRAP_PROG([BootstrapOptCmd], [${WithGhc}], "LLVM opt command")
569
570 if test -n "$BootstrapLlcCmd" && test -n "$BootstrapOptCmd"
571 then
572     AC_MSG_CHECKING(whether bootstrap compiler is affected by bug 9439)
573     echo "main = putStrLn \"%function\"" > conftestghc.hs
574
575     # Check whether LLVM backend is default for this platform
576     "${WithGhc}" -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" conftestghc.hs 2>&1 >/dev/null
577     res=`./conftestghc`
578     if test "x$res" = "x%object"
579     then
580         AC_MSG_RESULT(yes)
581         echo "Buggy bootstrap compiler"
582         echo ""
583         echo "The stage 0 compiler $WithGhc is affected by GHC Bug \#9439"
584         echo "and therefore will miscompile the LLVM backend if -fllvm is"
585         echo "used."
586         echo
587         echo "Please use another bootstrap compiler"
588         exit 1
589     fi
590
591     # -fllvm is not the default, but set a flag so the Makefile can check
592     # -for it in the build flags later on
593     "${WithGhc}" -fforce-recomp -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" -fllvm conftestghc.hs 2>&1 >/dev/null
594     if test $? = 0
595     then
596         res=`./conftestghc`
597         if test "x$res" = "x%object"
598         then
599             AC_MSG_RESULT(yes)
600             GHC_LLVM_AFFECTED_BY_9439=1
601         elif test "x$res" = "x%function"
602         then
603             AC_MSG_RESULT(no)
604             GHC_LLVM_AFFECTED_BY_9439=0
605         else
606             AC_MSG_WARN(unexpected output $res)
607         fi
608     else
609         AC_MSG_RESULT(failed to compile, assuming no)
610     fi
611 fi
612 AC_SUBST([GHC_LLVM_AFFECTED_BY_9439])
613
614 dnl ** Can the unix package be built?
615 dnl --------------------------------------------------------------
616
617 if test "$TargetOS" = "mingw32"
618 then
619     GhcLibsWithUnix=NO
620 else
621     GhcLibsWithUnix=YES
622 fi
623 AC_SUBST([GhcLibsWithUnix])
624
625 dnl ** does #! work?
626 AC_SYS_INTERPRETER()
627
628 dnl ** look for `perl'
629 case $HostOS_CPP in
630 cygwin32|mingw32)
631     PerlCmd=$hardtop/inplace/perl/perl
632     ;;
633 *)
634     AC_PATH_PROG(PerlCmd,perl)
635     if test -z "$PerlCmd"
636     then
637         echo "You must install perl before you can continue"
638         echo "Perhaps it is already installed, but not in your PATH?"
639         exit 1
640     else
641         FPTOOLS_CHECK_PERL_VERSION
642     fi
643     ;;
644 esac
645
646 dnl ** look for GCC and find out which version
647 dnl     Figure out which C compiler to use.  Gcc is preferred.
648 dnl     If gcc, make sure it's at least 3.0
649 dnl
650 FP_GCC_VERSION
651
652 dnl ** look to see if we have a C compiler using an llvm back end.
653 dnl
654 FP_CC_LLVM_BACKEND
655
656 FP_PROG_LD_IS_GNU
657 FP_PROG_LD_BUILD_ID
658 FP_PROG_LD_NO_COMPACT_UNWIND
659 FP_PROG_LD_FILELIST
660
661
662 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
663 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
664 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
665 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
666 # Stage 3 won't be supported by cross-compilation
667
668 FP_GCC_EXTRA_FLAGS
669
670 AC_SUBST(CONF_CC_OPTS_STAGE0)
671 AC_SUBST(CONF_CC_OPTS_STAGE1)
672 AC_SUBST(CONF_CC_OPTS_STAGE2)
673 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
674 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
675 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
676 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
677 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
678 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
679 AC_SUBST(CONF_CPP_OPTS_STAGE0)
680 AC_SUBST(CONF_CPP_OPTS_STAGE1)
681 AC_SUBST(CONF_CPP_OPTS_STAGE2)
682
683 dnl ** Set up the variables for the platform in the settings file.
684 dnl May need to use gcc to find platform details.
685 dnl --------------------------------------------------------------
686 FPTOOLS_SET_HASKELL_PLATFORM_VARS
687
688 dnl ** figure out how to do context diffs
689 FP_PROG_CONTEXT_DIFF
690
691 dnl Let's make sure install-sh is executable here.  If we got it from
692 dnl a darcs repo, it might not be (see bug #978).
693 chmod +x install-sh
694 dnl ** figure out how to do a BSD-ish install
695 AC_PROG_INSTALL
696
697 dnl ** how to invoke `ar' and `ranlib'
698 FP_PROG_AR_SUPPORTS_ATFILE
699 FP_PROG_AR_NEEDS_RANLIB
700
701 dnl ** Check to see whether ln -s works
702 AC_PROG_LN_S
703
704 FP_SETTINGS
705
706 dnl ** Find the path to sed
707 AC_PATH_PROGS(SedCmd,gsed sed,sed)
708
709
710 dnl ** check for time command
711 AC_PATH_PROG(TimeCmd,time)
712
713 dnl ** check for tar
714 dnl   if GNU tar is named gtar, look for it first.
715 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
716
717 dnl ** check for patch
718 dnl if GNU patch is named gpatch, look for it first
719 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
720
721 dnl ** check for dtrace (currently only implemented for Mac OS X)
722 HaveDtrace=NO
723 AC_PATH_PROG(DtraceCmd,dtrace)
724 if test -n "$DtraceCmd"; then
725   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
726     HaveDtrace=YES
727   fi
728 fi
729 AC_SUBST(HaveDtrace)
730
731 AC_PATH_PROG(HSCOLOUR,HsColour)
732 # HsColour is passed to Cabal, so we need a native path
733 if test "$HostOS"      = "mingw32" && \
734    test "${OSTYPE}"   != "msys"    && \
735    test "${HSCOLOUR}" != ""
736 then
737     # Canonicalise to <drive>:/path/to/gcc
738     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
739 fi
740
741 dnl ** check for Sphinx toolchain
742 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
743 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
744 changequote(, )dnl
745 [if test -n "$SPHINXBUILD"; then
746   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
747 fi;
748 changequote([, ])dnl
749 ])
750 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
751     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
752
753 dnl ** check for xelatex
754 AC_PATH_PROG(XELATEX,xelatex)
755
756 dnl ** check for ghc-pkg command
757 FP_PROG_GHC_PKG
758
759 dnl ** check for installed happy binary + version
760 FPTOOLS_HAPPY
761
762 dnl ** check for installed alex binary + version
763 FPTOOLS_ALEX
764
765 dnl --------------------------------------------------
766 dnl ### program checking section ends here ###
767 dnl --------------------------------------------------
768
769 dnl --------------------------------------------------
770 dnl * Platform header file and syscall feature tests
771 dnl ### checking the state of the local header files and syscalls ###
772
773 dnl ** check for full ANSI header (.h) files
774 AC_HEADER_STDC
775
776 dnl ** Enable large file support.  NB. do this before testing the type of
777 dnl    off_t, because it will affect the result of that test.
778 AC_SYS_LARGEFILE
779
780 dnl ** check for specific header (.h) files that we are interested in
781 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
782
783 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
784 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
785 [[#if HAVE_SYS_PARAM_H
786 # include <sys/param.h>
787 #endif
788 ]])
789
790 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
791 AC_HEADER_TIME
792
793 dnl ** do we have long longs?
794 AC_CHECK_TYPES([long long])
795
796 dnl ** what are the sizes of various types
797 AC_CHECK_SIZEOF(char,               1)
798 AC_CHECK_SIZEOF(double,             8)
799 AC_CHECK_SIZEOF(float,              4)
800 AC_CHECK_SIZEOF(int,                4)
801 AC_CHECK_SIZEOF(long,               4)
802 if test "$ac_cv_type_long_long" = yes; then
803 AC_CHECK_SIZEOF(long long,          8)
804 fi
805 AC_CHECK_SIZEOF(short,              2)
806 AC_CHECK_SIZEOF(unsigned char,      1)
807 AC_CHECK_SIZEOF(unsigned int,       4)
808 AC_CHECK_SIZEOF(unsigned long,      4)
809 if test "$ac_cv_type_long_long" = yes; then
810 AC_CHECK_SIZEOF(unsigned long long, 8)
811 fi
812 AC_CHECK_SIZEOF(unsigned short,     2)
813 AC_CHECK_SIZEOF(void *,             4)
814
815 dnl for use in settings.in
816 WordSize=$ac_cv_sizeof_void_p
817 AC_SUBST(WordSize)
818
819 dnl ** what are alignment constraints on various types
820 FP_CHECK_ALIGNMENT(char)
821 FP_CHECK_ALIGNMENT(double)
822 FP_CHECK_ALIGNMENT(float)
823 FP_CHECK_ALIGNMENT(int)
824 FP_CHECK_ALIGNMENT(long)
825 if test "$ac_cv_type_long_long" = yes; then
826 FP_CHECK_ALIGNMENT(long long)
827 fi
828 FP_CHECK_ALIGNMENT(short)
829 FP_CHECK_ALIGNMENT(unsigned char)
830 FP_CHECK_ALIGNMENT(unsigned int)
831 FP_CHECK_ALIGNMENT(unsigned long)
832 if test "$ac_cv_type_long_long" = yes; then
833 FP_CHECK_ALIGNMENT(unsigned long long)
834 fi
835 FP_CHECK_ALIGNMENT(unsigned short)
836 FP_CHECK_ALIGNMENT(void *)
837
838 FP_CHECK_FUNC([WinExec],
839   [@%:@include <windows.h>], [WinExec("",0)])
840
841 FP_CHECK_FUNC([GetModuleFileName],
842   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
843
844 dnl ** check for more functions
845 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
846 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
847
848 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
849 dnl ** _POSIX_C_SOURCE is defined
850 AC_CHECK_DECLS([ctime_r], , ,
851 [#define _POSIX_SOURCE 1
852 #define _POSIX_C_SOURCE 199506L
853 #include <time.h>])
854
855 dnl ** check for mingwex library
856 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
857 AC_SUBST(HaveLibMingwEx)
858
859 if test $HaveLibMingwEx = YES ; then
860   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
861 fi
862
863 dnl ** check for math library
864 dnl    Keep that check as early as possible.
865 dnl    as we need to know whether we need libm
866 dnl    for math functions or not
867 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
868 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
869 if test $HaveLibM = YES
870 then
871   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
872 fi
873
874 FP_BFD_SUPPORT
875
876 dnl ################################################################
877 dnl Check for libraries
878 dnl ################################################################
879
880 # system libffi
881
882 AC_ARG_WITH([system-libffi],
883 [AC_HELP_STRING([--with-system-libffi],
884   [Use system provided libffi for RTS [default=no]])
885 ])
886
887 AS_IF([test "x$with_system_libffi" = "xyes"],
888   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
889 )
890
891
892 AC_SUBST(UseSystemLibFFI)
893
894 AC_ARG_WITH([ffi-includes],
895 [AC_HELP_STRING([--with-ffi-includes=ARG],
896   [Find includes for libffi in ARG [default=system default]])
897 ],
898 [
899  if test "x$UseSystemLibFFI" != "xYES"; then
900     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
901  else
902     FFIIncludeDir="$withval"
903     LIBFFI_CFLAGS="-I$withval"
904  fi
905 ])
906
907 AC_SUBST(FFIIncludeDir)
908
909 AC_ARG_WITH([ffi-libraries],
910 [AC_HELP_STRING([--with-ffi-libraries=ARG],
911   [Find libffi in ARG [default=system default]])
912 ],
913 [
914  if test "x$UseSystemLibFFI" != "xYES"; then
915     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
916  else
917     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
918  fi
919 ])
920
921 AC_SUBST(FFILibDir)
922
923 AS_IF([test "$UseSystemLibFFI" = "YES"], [
924  CFLAGS2="$CFLAGS"
925  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
926  LDFLAGS2="$LDFLAGS"
927  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
928  if test "$HostOS" = "openbsd";
929  then
930    # OpenBSD's libffi is not directly linked to the libpthread but
931    # still requires pthread functionality. This means that any client
932    # binary which links with libffi also needs to link with
933    # libpthread. If it does not, then linking fails with unresolved
934    # symbols.
935    LDFLAGS="$LDFLAGS -lpthread"
936  fi
937  AC_CHECK_LIB(ffi, ffi_call,
938   [AC_CHECK_HEADERS([ffi.h], [break], [])
939    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
940   [AC_MSG_ERROR([Cannot find system libffi])])
941  CFLAGS="$CFLAGS2"
942  LDFLAGS="$LDFLAGS2"
943 ])
944
945 dnl ** check whether we need -ldl to get dlopen()
946 AC_CHECK_LIB(dl, dlopen)
947
948 dnl --------------------------------------------------
949 dnl * Miscellaneous feature tests
950 dnl --------------------------------------------------
951
952 dnl ** can we get alloca?
953 AC_FUNC_ALLOCA
954
955 dnl ** working vfork?
956 AC_FUNC_FORK
957
958 dnl ** determine whether or not const works
959 AC_C_CONST
960
961 dnl ** are we big endian?
962 AC_C_BIGENDIAN
963 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
964
965 dnl ** check for leading underscores in symbol names
966 FP_LEADING_UNDERSCORE
967
968 FP_VISIBILITY_HIDDEN
969
970 dnl ** check for librt
971 AC_CHECK_LIB(rt, clock_gettime)
972 AC_CHECK_FUNCS(clock_gettime timer_settime)
973 FP_CHECK_TIMER_CREATE
974
975 dnl ** check for Apple's "interesting" long double compatibility scheme
976 AC_MSG_CHECKING(for printf\$LDBLStub)
977 AC_TRY_LINK_FUNC(printf\$LDBLStub,
978     [
979         AC_MSG_RESULT(yes)
980         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
981             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
982     ],
983     [
984         AC_MSG_RESULT(no)
985         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
986             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
987     ])
988
989 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
990 dnl    a different single-argument version.
991 AC_CHECK_LIB(pthread, pthread_setname_np)
992 AC_MSG_CHECKING(for pthread_setname_np)
993 AC_TRY_LINK(
994 [
995 #define _GNU_SOURCE
996 #include <pthread.h>
997 ],
998 [pthread_setname_np(pthread_self(), "name");],
999     AC_MSG_RESULT(yes)
1000     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
1001       [Define to 1 if you have the glibc version of pthread_setname_np]),
1002     AC_MSG_RESULT(no)
1003 )
1004
1005 dnl ** check for eventfd which is needed by the I/O manager
1006 AC_CHECK_HEADERS([sys/eventfd.h])
1007 AC_CHECK_FUNCS([eventfd])
1008
1009 dnl ** Check for __thread support in the compiler
1010 AC_MSG_CHECKING(for __thread support)
1011 AC_COMPILE_IFELSE(
1012   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1013   [
1014    AC_MSG_RESULT(yes)
1015    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1016   ],
1017   [
1018    AC_MSG_RESULT(no)
1019    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1020   ])
1021
1022
1023 AC_CHECK_FUNCS(__mingw_vfprintf)
1024
1025 dnl large address space support (see includes/rts/storage/MBlock.h)
1026 dnl
1027 dnl Darwin has vm_allocate/vm_protect
1028 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1029 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1030 dnl (They also have MADV_DONTNEED, but it means something else!)
1031 dnl
1032 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1033 dnl it counts page-table space as committed memory, and so quickly
1034 dnl runs out of paging file when we have multiple processes reserving
1035 dnl 1TB of address space, we get the following error:
1036 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1037 dnl
1038
1039 AC_ARG_ENABLE(large-address-space,
1040     [AC_HELP_STRING([--enable-large-address-space],
1041         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1042     EnableLargeAddressSpace=$enableval,
1043     EnableLargeAddressSpace=yes
1044 )
1045
1046 use_large_address_space=no
1047 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1048     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1049         if test "$ghc_host_os" = "darwin" ; then
1050             use_large_address_space=yes
1051         elif test "$ghc_host_os" = "openbsd" ; then
1052             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1053             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1054             # but is completely ignored by OS mmap
1055             use_large_address_space=no
1056         else
1057             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1058                 [
1059                 #include <unistd.h>
1060                 #include <sys/types.h>
1061                 #include <sys/mman.h>
1062                 #include <fcntl.h>
1063             ])
1064             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1065                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1066                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1067                     use_large_address_space=yes
1068             fi
1069         fi
1070     fi
1071 fi
1072 if test "$use_large_address_space" = "yes" ; then
1073    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1074 fi
1075
1076 AC_CHECK_LIB(dw, dwfl_begin, [HaveLibdw=YES], [HaveLibdw=NO])
1077 AC_SUBST(HaveLibdw)
1078
1079 if test -n "$SPHINXBUILD"; then
1080     BUILD_MAN=YES
1081     BUILD_SPHINX_HTML=YES
1082     if test -n "$XELATEX"; then
1083         BUILD_SPHINX_PDF=YES
1084     else
1085         BUILD_SPHINX_PDF=NO
1086     fi
1087 else
1088     BUILD_MAN=NO
1089     BUILD_SPHINX_HTML=NO
1090     BUILD_SPHINX_PDF=NO
1091 fi
1092 AC_SUBST(BUILD_MAN)
1093 AC_SUBST(BUILD_SPHINX_HTML)
1094 AC_SUBST(BUILD_SPHINX_PDF)
1095
1096 LIBRARY_VERSION(base)
1097 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1098 LIBRARY_VERSION(ghc-prim)
1099 LIBRARY_ghc_VERSION="$ProjectVersion"
1100 AC_SUBST(LIBRARY_ghc_VERSION)
1101
1102 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1103    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1104 fi
1105
1106 # Create the configuration for the Shake-based build system if it is present
1107 if test -e shake-build/cfg/system.config.in; then
1108     AC_CONFIG_FILES([shake-build/cfg/system.config])
1109 fi
1110
1111 # We got caught by
1112 #     http://savannah.gnu.org/bugs/index.php?1516
1113 #     $(eval ...) inside conditionals causes errors
1114 # with make 3.80, so warn the user if it looks like they're about to
1115 # try to use it.
1116 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1117 print_make_warning=""
1118 checkMake380() {
1119     make_ver=`$1 --version 2>&1 | head -1`
1120     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1121     then
1122         print_make_warning="true"
1123     fi
1124     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1125     then
1126         MakeCmd=$1
1127         AC_SUBST(MakeCmd)
1128     fi
1129 }
1130
1131 checkMake380 make
1132 checkMake380 gmake
1133
1134 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt distrib/configure.ac])
1135 AC_OUTPUT
1136
1137 if test "$print_make_warning" = "true"; then
1138    echo
1139    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1140    echo "This version cannot be used to build GHC."
1141    echo "Please use GNU make >= 3.81."
1142 fi
1143
1144 echo ["
1145 ----------------------------------------------------------------------
1146 Configure completed successfully.
1147
1148    Building GHC version  : $ProjectVersion
1149           Git commit id  : $ProjectGitCommitId
1150
1151    Build platform        : $BuildPlatform
1152    Host platform         : $HostPlatform
1153    Target platform       : $TargetPlatform
1154 "]
1155
1156 echo ["\
1157    Bootstrapping using   : $WithGhc
1158       which is version   : $GhcVersion
1159 "]
1160
1161 if test "x$CC_LLVM_BACKEND" = "x1"; then
1162     if test "x$CC_CLANG_BACKEND" = "x1"; then
1163         CompilerName="clang        "
1164     else
1165         CompilerName="llvm-gcc     "
1166     fi
1167 else
1168     CompilerName="gcc          "
1169 fi
1170
1171 echo ["\
1172    Using $CompilerName       : $WhatGccIsCalled
1173       which is version       : $GccVersion
1174    Building a cross compiler : $CrossCompiling
1175    hs-cpp       : $HaskellCPPCmd
1176    hs-cpp-flags : $HaskellCPPArgs
1177    ld           : $LdCmd
1178    nm           : $NmCmd
1179    objdump      : $ObjdumpCmd
1180    Happy        : $HappyCmd ($HappyVersion)
1181    Alex         : $AlexCmd ($AlexVersion)
1182    Perl         : $PerlCmd
1183    sphinx-build : $SPHINXBUILD
1184    xelatex      : $XELATEX
1185
1186    Using LLVM tools
1187       llc   : $LlcCmd
1188       opt   : $OptCmd"]
1189
1190 if test "$HSCOLOUR" = ""; then
1191 echo ["
1192    HsColour was not found; documentation will not contain source links
1193 "]
1194 else
1195 echo ["\
1196    HsColour : $HSCOLOUR
1197 "]
1198 fi
1199
1200 echo ["\
1201    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1202    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"]
1203
1204 echo ["----------------------------------------------------------------------
1205 "]
1206
1207 echo "\
1208 For a standard build of GHC (fully optimised with profiling), type (g)make.
1209
1210 To make changes to the default build configuration, copy the file
1211 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1212
1213 For more information on how to configure your GHC build, see
1214    http://ghc.haskell.org/trac/ghc/wiki/Building
1215 "