Include usg_file_hash in ghc --show-iface output
[ghc.git] / aclocal.m4
1 # Extra autoconf macros for the Glasgow fptools
2 #
3 # To be a good autoconf citizen, names of local macros have prefixed with FP_ to
4 # ensure we don't clash with any pre-supplied autoconf ones.
5
6
7 AC_DEFUN([GHC_SELECT_FILE_EXTENSIONS],
8 [
9     $2=''
10     $3='.so'
11     case $1 in
12     *-unknown-cygwin32)
13         AC_MSG_WARN([GHC does not support the Cygwin target at the moment])
14         AC_MSG_WARN([I'm assuming you wanted to build for i386-unknown-mingw32])
15         exit 1
16         ;;
17     # examples: i386-unknown-mingw32, i686-w64-mingw32, x86_64-w64-mingw32
18     *-mingw32)
19         windows=YES
20         $2='.exe'
21         $3='.dll'
22         ;;
23     # apple platform uses .dylib (macOS, iOS, ...)
24     *-apple-*)
25         $3='.dylib'
26         ;;
27     esac
28 ])
29
30 # FPTOOLS_SET_PLATFORM_VARS
31 # ----------------------------------
32 # Set the platform variables
33 AC_DEFUN([FPTOOLS_SET_PLATFORM_VARS],
34 [
35     # If no argument was given for a configuration variable, then discard
36     # the guessed canonical system and use the configuration of the
37     # bootstrapping ghc. If an argument was given, map it from gnu format
38     # to ghc format.
39     #
40     # For why we do it this way, see: #3637, #1717, #2951
41     #
42     # In bindists, we haven't called AC_CANONICAL_{BUILD,HOST,TARGET}
43     # so this justs uses $bootstrap_target.
44
45     if test "$build_alias" = ""
46     then
47         if test "$bootstrap_target" != ""
48         then
49             build=$bootstrap_target
50             echo "Build platform inferred as: $build"
51         else
52             echo "Can't work out build platform"
53             exit 1
54         fi
55
56         BuildArch=`echo "$build" | sed 's/-.*//'`
57         BuildVendor=`echo "$build" | sed -e 's/.*-\(.*\)-.*/\1/'`
58         BuildOS=`echo "$build" | sed 's/.*-//'`
59     else
60         GHC_CONVERT_CPU([$build_cpu], [BuildArch])
61         GHC_CONVERT_VENDOR([$build_vendor], [BuildVendor])
62         GHC_CONVERT_OS([$build_os], [$BuildArch], [BuildOS])
63     fi
64
65     if test "$host_alias" = ""
66     then
67         if test "$bootstrap_target" != ""
68         then
69             host=$bootstrap_target
70             echo "Host platform inferred as: $host"
71         else
72             echo "Can't work out host platform"
73             exit 1
74         fi
75
76         HostArch=`echo "$host" | sed 's/-.*//'`
77         HostVendor=`echo "$host" | sed -e 's/.*-\(.*\)-.*/\1/'`
78         HostOS=`echo "$host" | sed 's/.*-//'`
79     else
80         GHC_CONVERT_CPU([$host_cpu], [HostArch])
81         GHC_CONVERT_VENDOR([$host_vendor], [HostVendor])
82         GHC_CONVERT_OS([$host_os], [$HostArch], [HostOS])
83     fi
84
85     if test "$target_alias" = ""
86     then
87         if test "$host_alias" != ""
88         then
89             GHC_CONVERT_CPU([$host_cpu], [TargetArch])
90             GHC_CONVERT_VENDOR([$host_vendor], [TargetVendor])
91             GHC_CONVERT_OS([$host_os], [$TargetArch],[TargetOS])
92         else
93             if test "$bootstrap_target" != ""
94             then
95                 target=$bootstrap_target
96                 echo "Target platform inferred as: $target"
97             else
98                 echo "Can't work out target platform"
99                 exit 1
100             fi
101
102             TargetArch=`echo "$target" | sed 's/-.*//'`
103             TargetVendor=`echo "$target" | sed -e 's/.*-\(.*\)-.*/\1/'`
104             TargetOS=`echo "$target" | sed 's/.*-//'`
105         fi
106     else
107         GHC_CONVERT_CPU([$target_cpu], [TargetArch])
108         GHC_CONVERT_VENDOR([$target_vendor], [TargetVendor])
109         GHC_CONVERT_OS([$target_os], [$TargetArch], [TargetOS])
110     fi
111
112     GHC_LLVM_TARGET([$target_cpu],[$target_vendor],[$target_os],[LlvmTarget])
113
114     GHC_SELECT_FILE_EXTENSIONS([$host], [exeext_host], [soext_host])
115     GHC_SELECT_FILE_EXTENSIONS([$target], [exeext_target], [soext_target])
116     windows=NO
117     case $host in
118     *-unknown-mingw32)
119         windows=YES
120         ;;
121     esac
122
123     BuildPlatform="$BuildArch-$BuildVendor-$BuildOS"
124     BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
125     BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
126     BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
127     BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
128
129     HostPlatform="$HostArch-$HostVendor-$HostOS"
130     HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
131     HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
132     HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
133     HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
134
135     TargetPlatform="$TargetArch-$TargetVendor-$TargetOS"
136     TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
137     TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
138     TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
139     TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
140
141     # we intend to pass trough --targets to llvm as is.
142     LLVMTarget_CPP=`    echo "$LlvmTarget"`
143
144     echo "GHC build  : $BuildPlatform"
145     echo "GHC host   : $HostPlatform"
146     echo "GHC target : $TargetPlatform"
147     echo "LLVM target: $LlvmTarget"
148
149     AC_SUBST(BuildPlatform)
150     AC_SUBST(HostPlatform)
151     AC_SUBST(TargetPlatform)
152     AC_SUBST(HostPlatform_CPP)
153     AC_SUBST(BuildPlatform_CPP)
154     AC_SUBST(TargetPlatform_CPP)
155
156     AC_SUBST(HostArch_CPP)
157     AC_SUBST(BuildArch_CPP)
158     AC_SUBST(TargetArch_CPP)
159
160     AC_SUBST(HostOS_CPP)
161     AC_SUBST(BuildOS_CPP)
162     AC_SUBST(TargetOS_CPP)
163     AC_SUBST(LLVMTarget_CPP)
164
165     AC_SUBST(HostVendor_CPP)
166     AC_SUBST(BuildVendor_CPP)
167     AC_SUBST(TargetVendor_CPP)
168
169     AC_SUBST(exeext_host)
170     AC_SUBST(exeext_target)
171     AC_SUBST(soext_host)
172     AC_SUBST(soext_target)
173 ])
174
175
176 # FPTOOLS_SET_HASKELL_PLATFORM_VARS
177 # ----------------------------------
178 # Set the Haskell platform variables
179 AC_DEFUN([FPTOOLS_SET_HASKELL_PLATFORM_VARS],
180 [
181     checkArch() {
182         case [$]1 in
183         i386)
184             test -z "[$]2" || eval "[$]2=ArchX86"
185             ;;
186         x86_64|amd64)
187             test -z "[$]2" || eval "[$]2=ArchX86_64"
188             ;;
189         powerpc)
190             test -z "[$]2" || eval "[$]2=ArchPPC"
191             ;;
192         powerpc64)
193             test -z "[$]2" || eval "[$]2=\"ArchPPC_64 {ppc_64ABI = ELF_V1}\""
194             ;;
195         powerpc64le)
196             test -z "[$]2" || eval "[$]2=\"ArchPPC_64 {ppc_64ABI = ELF_V2}\""
197             ;;
198         sparc)
199             test -z "[$]2" || eval "[$]2=ArchSPARC"
200             ;;
201         sparc64)
202             test -z "[$]2" || eval "[$]2=ArchSPARC64"
203             ;;
204         arm)
205             GET_ARM_ISA()
206             test -z "[$]2" || eval "[$]2=\"ArchARM {armISA = \$ARM_ISA, armISAExt = \$ARM_ISA_EXT, armABI = \$ARM_ABI}\""
207             ;;
208         aarch64)
209             test -z "[$]2" || eval "[$]2=ArchARM64"
210             ;;
211         alpha)
212             test -z "[$]2" || eval "[$]2=ArchAlpha"
213             ;;
214         mips|mipseb)
215             test -z "[$]2" || eval "[$]2=ArchMipseb"
216             ;;
217         mipsel)
218             test -z "[$]2" || eval "[$]2=ArchMipsel"
219             ;;
220         hppa|hppa1_1|ia64|m68k|rs6000|s390|s390x|sh4|vax)
221             test -z "[$]2" || eval "[$]2=ArchUnknown"
222             ;;
223         *)
224             echo "Unknown arch [$]1"
225             exit 1
226             ;;
227         esac
228     }
229
230     checkVendor() {
231         case [$]1 in
232         dec|none|unknown|hp|apple|next|sun|sgi|ibm|montavista|portbld)
233             ;;
234         *)
235             AC_MSG_WARN([Unknown vendor [$]1])
236             ;;
237         esac
238     }
239
240     checkOS() {
241         case [$]1 in
242         linux|linux-android)
243             test -z "[$]2" || eval "[$]2=OSLinux"
244             ;;
245         darwin|ios)
246             test -z "[$]2" || eval "[$]2=OSDarwin"
247             ;;
248         solaris2)
249             test -z "[$]2" || eval "[$]2=OSSolaris2"
250             ;;
251         mingw32)
252             test -z "[$]2" || eval "[$]2=OSMinGW32"
253             ;;
254         freebsd)
255             test -z "[$]2" || eval "[$]2=OSFreeBSD"
256             ;;
257         dragonfly)
258             test -z "[$]2" || eval "[$]2=OSDragonFly"
259             ;;
260         kfreebsdgnu)
261             test -z "[$]2" || eval "[$]2=OSKFreeBSD"
262             ;;
263         openbsd)
264             test -z "[$]2" || eval "[$]2=OSOpenBSD"
265             ;;
266         netbsd)
267             test -z "[$]2" || eval "[$]2=OSNetBSD"
268             ;;
269         haiku)
270             test -z "[$]2" || eval "[$]2=OSHaiku"
271             ;;
272         nto-qnx)
273             test -z "[$]2" || eval "[$]2=OSQNXNTO"
274             ;;
275         dragonfly|hpux|linuxaout|freebsd2|gnu|nextstep2|nextstep3|sunos4|ultrix)
276             test -z "[$]2" || eval "[$]2=OSUnknown"
277             ;;
278         aix)
279             test -z "[$]2" || eval "[$]2=OSAIX"
280             ;;
281         *)
282             echo "Unknown OS '[$]1'"
283             exit 1
284             ;;
285         esac
286     }
287
288     dnl ** check for Apple-style dead-stripping support
289     dnl    (.subsections-via-symbols assembler directive)
290
291     AC_MSG_CHECKING(for .subsections_via_symbols)
292     AC_COMPILE_IFELSE(
293         [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
294         [AC_MSG_RESULT(yes)
295          HaskellHaveSubsectionsViaSymbols=True
296          AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
297                    [Define to 1 if Apple-style dead-stripping is supported.])
298         ],
299         [HaskellHaveSubsectionsViaSymbols=False
300          AC_MSG_RESULT(no)])
301
302     dnl ** check for .ident assembler directive
303
304     AC_MSG_CHECKING(whether your assembler supports .ident directive)
305     AC_COMPILE_IFELSE(
306         [AC_LANG_SOURCE([__asm__ (".ident \"GHC x.y.z\"");])],
307         [AC_MSG_RESULT(yes)
308          HaskellHaveIdentDirective=True],
309         [AC_MSG_RESULT(no)
310          HaskellHaveIdentDirective=False])
311
312     dnl *** check for GNU non-executable stack note support (ELF only)
313     dnl     (.section .note.GNU-stack,"",@progbits)
314
315     dnl This test doesn't work with "gcc -g" in gcc 4.4 (GHC trac #3889:
316     dnl     Error: can't resolve `.note.GNU-stack' {.note.GNU-stack section} - `.Ltext0' {.text section}
317     dnl so we empty CFLAGS while running this test
318     CFLAGS2="$CFLAGS"
319     CFLAGS=
320     case $TargetArch in
321       arm)
322         dnl See #13937.
323         progbits="%progbits"
324         ;;
325       *)
326         progbits="@progbits"
327         ;;
328     esac
329     AC_MSG_CHECKING(for GNU non-executable stack support)
330     AC_COMPILE_IFELSE(
331         [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",$progbits");], [0])],
332         [AC_MSG_RESULT(yes)
333          HaskellHaveGnuNonexecStack=True],
334         [AC_MSG_RESULT(no)
335          HaskellHaveGnuNonexecStack=False])
336     CFLAGS="$CFLAGS2"
337
338     checkArch "$BuildArch" "HaskellBuildArch"
339     checkVendor "$BuildVendor"
340     checkOS "$BuildOS" ""
341
342     checkArch "$HostArch" "HaskellHostArch"
343     checkVendor "$HostVendor"
344     checkOS "$HostOS" ""
345
346     checkArch "$TargetArch" "HaskellTargetArch"
347     checkVendor "$TargetVendor"
348     checkOS "$TargetOS" "HaskellTargetOs"
349
350     AC_SUBST(HaskellTargetArch)
351     AC_SUBST(HaskellTargetOs)
352     AC_SUBST(HaskellHaveSubsectionsViaSymbols)
353     AC_SUBST(HaskellHaveIdentDirective)
354     AC_SUBST(HaskellHaveGnuNonexecStack)
355 ])
356
357
358 # GET_ARM_ISA
359 # ----------------------------------
360 # Get info about the ISA on the ARM arch
361 AC_DEFUN([GET_ARM_ISA],
362 [
363     AC_COMPILE_IFELSE([
364         AC_LANG_PROGRAM(
365             [],
366             [#if defined(__ARM_ARCH_2__)  || \
367                  defined(__ARM_ARCH_3__)  || \
368                  defined(__ARM_ARCH_3M__) || \
369                  defined(__ARM_ARCH_4__)  || \
370                  defined(__ARM_ARCH_4T__) || \
371                  defined(__ARM_ARCH_5__)  || \
372                  defined(__ARM_ARCH_5T__) || \
373                  defined(__ARM_ARCH_5E__) || \
374                  defined(__ARM_ARCH_5TE__)
375                  return 0;
376              #else
377                  not pre arm v6
378              #endif]
379         )],
380         [AC_DEFINE(arm_HOST_ARCH_PRE_ARMv6, 1, [ARM pre v6])
381          AC_DEFINE(arm_HOST_ARCH_PRE_ARMv7, 1, [ARM pre v7])
382          changequote(, )dnl
383          ARM_ISA=ARMv5
384          ARM_ISA_EXT="[]"
385          changequote([, ])dnl
386         ],
387         [
388             AC_COMPILE_IFELSE([
389                 AC_LANG_PROGRAM(
390                     [],
391                     [#if defined(__ARM_ARCH_6__)   || \
392                          defined(__ARM_ARCH_6J__)  || \
393                          defined(__ARM_ARCH_6T2__) || \
394                          defined(__ARM_ARCH_6Z__)  || \
395                          defined(__ARM_ARCH_6ZK__) || \
396                          defined(__ARM_ARCH_6K__)  || \
397                          defined(__ARM_ARCH_6KZ__) || \
398                          defined(__ARM_ARCH_6M__)
399                          return 0;
400                      #else
401                          not pre arm v7
402                      #endif]
403                 )],
404                 [AC_DEFINE(arm_HOST_ARCH_PRE_ARMv7, 1, [ARM pre v7])
405                  ARM_ISA=ARMv6
406                  AC_COMPILE_IFELSE([
407                         AC_LANG_PROGRAM(
408                                 [],
409                                 [#if defined(__VFP_FP__)
410                                      return 0;
411                                 #else
412                                      no vfp
413                                 #endif]
414                         )],
415                         [changequote(, )dnl
416                          ARM_ISA_EXT="[VFPv2]"
417                          changequote([, ])dnl
418                         ],
419                         [changequote(, )dnl
420                          ARM_ISA_EXT="[]"
421                          changequote([, ])dnl
422                         ]
423                 )],
424                 [changequote(, )dnl
425                  ARM_ISA=ARMv7
426                  ARM_ISA_EXT="[VFPv3,NEON]"
427                  changequote([, ])dnl
428                 ])
429         ])
430
431         AC_COMPILE_IFELSE(
432                [AC_LANG_PROGRAM(
433                        [],
434                        [#if defined(__SOFTFP__)
435                             return 0;
436                        #else
437                             not softfp
438                        #endif]
439                )],
440                [changequote(, )dnl
441                 ARM_ABI="SOFT"
442                 changequote([, ])dnl
443                ],
444                [AC_COMPILE_IFELSE(
445                     [AC_LANG_PROGRAM(
446                        [],
447                        [#if defined(__ARM_PCS_VFP)
448                             return 0;
449                        #else
450                             no hard float ABI
451                        #endif]
452                     )],
453                     [ARM_ABI="HARD"],
454                     [ARM_ABI="SOFTFP"]
455                )]
456         )
457
458         AC_SUBST(ARM_ISA)
459 ])
460
461
462 # FP_SETTINGS
463 # ----------------------------------
464 # Set the variables used in the settings file
465 AC_DEFUN([FP_SETTINGS],
466 [
467     if test "$windows" = YES -a "$EnableDistroToolchain" = "NO"
468     then
469         mingw_bin_prefix=mingw/bin/
470         SettingsCCompilerCommand="\$topdir/../${mingw_bin_prefix}gcc.exe"
471         SettingsHaskellCPPCommand="\$topdir/../${mingw_bin_prefix}gcc.exe"
472         SettingsHaskellCPPFlags="$HaskellCPPArgs"
473         SettingsLdCommand="\$topdir/../${mingw_bin_prefix}ld.exe"
474         SettingsArCommand="\$topdir/../${mingw_bin_prefix}ar.exe"
475         SettingsRanlibCommand="\$topdir/../${mingw_bin_prefix}ranlib.exe"
476         SettingsPerlCommand='$topdir/../perl/perl.exe'
477         SettingsDllWrapCommand="\$topdir/../${mingw_bin_prefix}dllwrap.exe"
478         SettingsWindresCommand="\$topdir/../${mingw_bin_prefix}windres.exe"
479         SettingsTouchCommand='$topdir/bin/touchy.exe'
480     elif test "$EnableDistroToolchain" = "YES"
481     then
482         SettingsCCompilerCommand="$(basename $CC)"
483         SettingsCCompilerFlags="$CONF_CC_OPTS_STAGE2"
484         SettingsHaskellCPPCommand="$(basename $HaskellCPPCmd)"
485         SettingsHaskellCPPFlags="$HaskellCPPArgs"
486         SettingsLdCommand="$(basename $LdCmd)"
487         SettingsArCommand="$(basename $ArCmd)"
488         SettingsPerlCommand="$(basename $PerlCmd)"
489         SettingsDllWrapCommand="$(basename $DllWrapCmd)"
490         SettingsWindresCommand="$(basename $WindresCmd)"
491         SettingsTouchCommand='$topdir/bin/touchy.exe'
492     else
493         SettingsCCompilerCommand="$CC"
494         SettingsHaskellCPPCommand="$HaskellCPPCmd"
495         SettingsHaskellCPPFlags="$HaskellCPPArgs"
496         SettingsLdCommand="$LdCmd"
497         SettingsArCommand="$ArCmd"
498         SettingsRanlibCommand="$RanlibCmd"
499         SettingsPerlCommand="$PerlCmd"
500         if test -z "$DllWrapCmd"
501         then
502             SettingsDllWrapCommand="/bin/false"
503         else
504             SettingsDllWrapCommand="$DllWrapCmd"
505         fi
506         if test -z "$WindresCmd"
507         then
508             SettingsWindresCommand="/bin/false"
509         else
510             SettingsWindresCommand="$WindresCmd"
511         fi
512        SettingsTouchCommand='touch'
513     fi
514     if test -z "$LibtoolCmd"
515     then
516       SettingsLibtoolCommand="libtool"
517     else
518       SettingsLibtoolCommand="$LibtoolCmd"
519     fi
520     if test -z "$ClangCmd"
521     then
522         SettingsClangCommand="clang"
523     else
524         SettingsClangCommand="$ClangCmd"
525     fi
526     if test -z "$LlcCmd"
527     then
528       SettingsLlcCommand="llc"
529     else
530       SettingsLlcCommand="$LlcCmd"
531     fi
532     if test -z "$OptCmd"
533     then
534       SettingsOptCommand="opt"
535     else
536       SettingsOptCommand="$OptCmd"
537     fi
538     SettingsCCompilerFlags="$CONF_CC_OPTS_STAGE2"
539     SettingsCCompilerLinkFlags="$CONF_GCC_LINKER_OPTS_STAGE2"
540     SettingsCCompilerSupportsNoPie="$CONF_GCC_SUPPORTS_NO_PIE"
541     SettingsLdFlags="$CONF_LD_LINKER_OPTS_STAGE2"
542     AC_SUBST(SettingsCCompilerCommand)
543     AC_SUBST(SettingsHaskellCPPCommand)
544     AC_SUBST(SettingsHaskellCPPFlags)
545     AC_SUBST(SettingsCCompilerFlags)
546     AC_SUBST(SettingsCCompilerLinkFlags)
547     AC_SUBST(SettingsCCompilerSupportsNoPie)
548     AC_SUBST(SettingsLdCommand)
549     AC_SUBST(SettingsLdFlags)
550     AC_SUBST(SettingsArCommand)
551     AC_SUBST(SettingsRanlibCommand)
552     AC_SUBST(SettingsPerlCommand)
553     AC_SUBST(SettingsDllWrapCommand)
554     AC_SUBST(SettingsWindresCommand)
555     AC_SUBST(SettingsLibtoolCommand)
556     AC_SUBST(SettingsTouchCommand)
557     AC_SUBST(SettingsClangCommand)
558     AC_SUBST(SettingsLlcCommand)
559     AC_SUBST(SettingsOptCommand)
560 ])
561
562 # Helper for cloning a shell variable's state
563 AC_DEFUN([FP_COPY_SHELLVAR],
564 [if test -n "${$1+set}"; then $2="$$1"; else unset $2; fi ])
565
566 # FP_SET_CFLAGS_C99
567 # ----------------------------------
568 # figure out which CFLAGS are needed to place the compiler into C99 mode
569 # $1 is name of CC variable (unmodified)
570 # $2 is name of CC flags variable (augmented if needed)
571 # $3 is name of CPP flags variable (augmented if needed)
572 AC_DEFUN([FP_SET_CFLAGS_C99],
573 [
574     dnl save current state of AC_PROG_CC_C99
575     FP_COPY_SHELLVAR([CC],[fp_save_CC])
576     FP_COPY_SHELLVAR([CFLAGS],[fp_save_CFLAGS])
577     FP_COPY_SHELLVAR([CPPFLAGS],[fp_save_CPPFLAGS])
578     FP_COPY_SHELLVAR([ac_cv_prog_cc_c99],[fp_save_cc_c99])
579     dnl set local state
580     CC="$$1"
581     CFLAGS="$$2"
582     CPPFLAGS="$$3"
583     unset ac_cv_prog_cc_c99
584     dnl perform detection
585     _AC_PROG_CC_C99
586     fp_cc_c99="$ac_cv_prog_cc_c99"
587     case "x$ac_cv_prog_cc_c99" in
588       x)   ;; # noop
589       xno) AC_MSG_ERROR([C99-compatible compiler needed]) ;;
590       *)   $2="$$2 $ac_cv_prog_cc_c99"
591            $3="$$3 $ac_cv_prog_cc_c99"
592            ;;
593     esac
594     dnl restore saved state
595     FP_COPY_SHELLVAR([fp_save_CC],[CC])
596     FP_COPY_SHELLVAR([fp_save_CFLAGS],[CFLAGS])
597     FP_COPY_SHELLVAR([fp_save_CPPFLAGS],[CPPFLAGS])
598     FP_COPY_SHELLVAR([fp_save_cc_c99],[ac_cv_prog_cc_c99])
599     dnl cleanup
600     unset fp_save_CC
601     unset fp_save_CFLAGS
602     unset fp_save_cc_c99
603 ])
604
605 # FPTOOLS_SET_C_LD_FLAGS
606 # ----------------------------------
607 # Set the C, LD and CPP flags for a given platform.
608 # $1 is the platform
609 # $2 is the name of the CC flags variable
610 # $3 is the name of the linker flags variable when linking with gcc
611 # $4 is the name of the linker flags variable when linking with ld
612 # $5 is the name of the CPP flags variable
613 AC_DEFUN([FPTOOLS_SET_C_LD_FLAGS],
614 [
615     AC_MSG_CHECKING([Setting up $2, $3, $4 and $5])
616     case $$1 in
617     i386-*)
618         # Workaround for #7799
619         $2="$$2 -U__i686"
620         ;;
621     esac
622
623     case $$1 in
624     i386-unknown-mingw32)
625         $2="$$2 -march=i686"
626         ;;
627     i386-portbld-freebsd*)
628         $2="$$2 -march=i686"
629         ;;
630     x86_64-unknown-solaris2)
631         $2="$$2 -m64"
632         $3="$$3 -m64"
633         $4="$$4 -m64"
634         $5="$$5 -m64"
635         ;;
636     alpha-*)
637         # For now, to suppress the gcc warning "call-clobbered
638         # register used for global register variable", we simply
639         # disable all warnings altogether using the -w flag. Oh well.
640         $2="$$2 -w -mieee -D_REENTRANT"
641         $3="$$3 -w -mieee -D_REENTRANT"
642         $5="$$5 -w -mieee -D_REENTRANT"
643         ;;
644     hppa*)
645         # ___HPUX_SOURCE, not _HPUX_SOURCE, is #defined if -ansi!
646         # (very nice, but too bad the HP /usr/include files don't agree.)
647         $2="$$2 -D_HPUX_SOURCE"
648         $3="$$3 -D_HPUX_SOURCE"
649         $5="$$5 -D_HPUX_SOURCE"
650         ;;
651     arm*linux*)
652         # On arm/linux and arm/android, tell gcc to generate Arm
653         # instructions (ie not Thumb).
654         $2="$$2 -marm"
655         $3="$$3 -Wl,-z,noexecstack"
656         $4="$$4 -z noexecstack"
657         ;;
658
659     aarch64*linux*)
660         $3="$$3 -Wl,-z,noexecstack"
661         $4="$$4 -z noexecstack"
662         ;;
663
664     powerpc-ibm-aix*)
665         # We need `-D_THREAD_SAFE` to unlock the thread-local `errno`.
666         $2="$$2 -D_THREAD_SAFE"
667         $3="$$3 -D_THREAD_SAFE -Wl,-bnotextro"
668         $4="$$4 -bnotextro"
669         $5="$$5 -D_THREAD_SAFE"
670         ;;
671
672     x86_64-*-openbsd*)
673         # We need -z wxneeded at least to link ghc-stage2 to workaround
674         # W^X issue in GHCi on OpenBSD current (as of Aug 2016)
675         $3="$$3 -Wl,-z,wxneeded"
676         $4="$$4 -z wxneeded"
677         ;;
678
679     esac
680
681     # If gcc knows about the stack protector, turn it off.
682     # Otherwise the stack-smash handler gets triggered.
683     echo 'int main(void) {return 0;}' > conftest.c
684     if $CC -c conftest.c -fno-stack-protector > /dev/null 2>&1
685     then
686         $2="$$2 -fno-stack-protector"
687     fi
688
689     rm -f conftest.c conftest.o
690     AC_MSG_RESULT([done])
691 ])
692
693
694 # FP_VISIBILITY_HIDDEN
695 # ----------------------------------
696 # Is the visibility hidden attribute supported?
697 AC_DEFUN([FP_VISIBILITY_HIDDEN],
698 [
699     AC_MSG_CHECKING([whether __attribute__((visibility("hidden"))) is supported])
700     echo '__attribute__((visibility("hidden"))) void foo(void) {}' > conftest.c
701     if $CC -Wall -Werror -c conftest.c > /dev/null 2>&1
702     then
703         AC_MSG_RESULT([yes])
704         AC_DEFINE(HAS_VISIBILITY_HIDDEN, 1, [Has visibility hidden])
705     else
706         AC_MSG_RESULT([no])
707     fi
708     rm -f conftest.c conftest.o
709 ])
710
711
712 # FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
713 # ----------------------------------
714 # Little endian ARM on Linux with some ABIs has big endian word order
715 # in doubles. Define FLOAT_WORDS_BIGENDIAN if this is the case.
716 AC_DEFUN([FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN],
717   [AC_CACHE_CHECK([whether float word order is big endian], [fptools_cv_float_word_order_bigendian],
718     [AC_COMPILE_IFELSE(
719       [AC_LANG_PROGRAM(
720         [#include <endian.h>],
721         [#if defined(__FLOAT_WORD_ORDER) && __FLOAT_WORD_ORDER == BIG_ENDIAN
722              return 0;
723          #else
724              not float word order big endian
725          #endif]
726       )],
727       [fptools_cv_float_word_order_bigendian=yes],
728       [fptools_cv_float_word_order_bigendian=no])
729     ])
730   case $fptools_cv_float_word_order_bigendian in
731       yes)
732           AC_DEFINE([FLOAT_WORDS_BIGENDIAN], 1,
733           [Define to 1 if your processor stores words of floats with
734            the most significant byte first]) ;;
735   esac
736 ])
737
738
739 # FP_PROG_CONTEXT_DIFF
740 # --------------------
741 # Figure out how to do context diffs. Sets the output variable ContextDiffCmd.
742 #
743 # Note: NeXTStep thinks diff'ing a file against itself is "trouble".
744 AC_DEFUN([FP_PROG_CONTEXT_DIFF],
745 [AC_CACHE_CHECK([for a working context diff], [fp_cv_context_diff],
746 [echo foo > conftest1
747 echo foo > conftest2
748 fp_cv_context_diff=no
749 for fp_var in '-U 1' '-u1' '-C 1' '-c1'
750 do
751   if diff $fp_var conftest1 conftest2 > /dev/null 2>&1; then
752     fp_cv_context_diff="diff $fp_var"
753     break
754   fi
755 done])
756 if test x"$fp_cv_context_diff" = xno; then
757    AC_MSG_ERROR([cannot figure out how to do context diffs])
758 fi
759 AC_SUBST(ContextDiffCmd, [$fp_cv_context_diff])
760 ])# FP_PROG_CONTEXT_DIFF
761
762
763 # FP_COMPUTE_INT(EXPRESSION, VARIABLE, INCLUDES, IF-FAILS)
764 # --------------------------------------------------------
765 # Assign VARIABLE the value of the compile-time EXPRESSION using INCLUDES for
766 # compilation. Execute IF-FAILS when unable to determine the value. Works for
767 # cross-compilation, too.
768 #
769 # Implementation note: We are lazy and use an internal autoconf macro, but it
770 # is supported in autoconf versions 2.50 up to the actual 2.57, so there is
771 # little risk.
772 AC_DEFUN([FP_COMPUTE_INT],
773 [_AC_COMPUTE_INT([$1], [$2], [$3], [$4])[]dnl
774 ])# FP_COMPUTE_INT
775
776
777 # FP_CHECK_ALIGNMENT(TYPE, [IGNORED], [INCLUDES = DEFAULT-INCLUDES])
778 # ------------------------------------------------------------------
779 # A variation of AC_CHECK_SIZEOF for computing the alignment restrictions of a
780 # given type. Defines ALIGNMENT_TYPE.
781 AC_DEFUN([FP_CHECK_ALIGNMENT],
782 [AS_LITERAL_IF(m4_translit([[$1]], [*], [p]), [],
783                [AC_FATAL([$0: requires literal arguments])])[]dnl
784 AC_CHECK_TYPE([$1], [], [], [$3])[]dnl
785 m4_pushdef([fp_Cache], [AS_TR_SH([fp_cv_alignment_$1])])[]dnl
786 AC_CACHE_CHECK([alignment of $1], [fp_Cache],
787 [if test "$AS_TR_SH([ac_cv_type_$1])" = yes; then
788   FP_COMPUTE_INT([offsetof(struct { char c; $1 ty; },ty)],
789                  [fp_Cache],
790                  [AC_INCLUDES_DEFAULT([$3])],
791                  [AC_MSG_ERROR([cannot compute alignment ($1)
792 See `config.log' for more details.], [77])])
793 else
794   fp_Cache=0
795 fi])[]dnl
796 AC_DEFINE_UNQUOTED(AS_TR_CPP(alignment_$1), $fp_Cache, [The alignment of a `$1'.])[]dnl
797 m4_popdef([fp_Cache])[]dnl
798 ])# FP_CHECK_ALIGNMENT
799
800
801
802 # FP_CHECK_SIZEOF_AND_ALIGNMENT(TYPE)
803 # ------------------------------------------------------------------
804 # Combines AC_CHECK_SIZEOF and FP_CHECK_ALIGNMENT.
805 AC_DEFUN([FP_CHECK_SIZEOF_AND_ALIGNMENT],
806 [AC_CHECK_SIZEOF([$1])
807 FP_CHECK_ALIGNMENT([$1])
808 ])# FP_CHECK_SIZEOF_AND_ALIGNMENT
809
810
811 # FP_LEADING_UNDERSCORE
812 # ---------------------
813 # Test for determining whether symbol names have a leading underscore. We assume
814 # that they _haven't_ if anything goes wrong. Sets the output variable
815 # LeadingUnderscore to YES or NO and defines LEADING_UNDERSCORE correspondingly.
816 #
817 # Some nlist implementations seem to try to be compatible by ignoring a leading
818 # underscore sometimes (eg. FreeBSD). We therefore have to work around this by
819 # checking for *no* leading underscore first. Sigh.  --SDM
820 #
821 # Similarly on OpenBSD, but this test doesn't help. -- dons
822 #
823 AC_DEFUN([FP_LEADING_UNDERSCORE],
824 [AC_CHECK_LIB([elf], [nlist], [LIBS="-lelf $LIBS"])
825 AC_CACHE_CHECK([leading underscore in symbol names], [fptools_cv_leading_underscore], [
826 # Hack!: nlist() under Digital UNIX insist on there being an _,
827 # but symbol table listings shows none. What is going on here?!?
828 case $TargetPlatform in
829     # Apples mach-o platforms use leading underscores
830     *-apple-*) fptools_cv_leading_underscore=yes;;
831     *linux-android*) fptools_cv_leading_underscore=no;;
832     *openbsd*) # x86 openbsd is ELF from 3.4 >, meaning no leading uscore
833       case $build in
834         i386-*2\.@<:@0-9@:>@ | i386-*3\.@<:@0-3@:>@ ) fptools_cv_leading_underscore=yes ;;
835         *) fptools_cv_leading_underscore=no ;;
836       esac ;;
837     i386-unknown-mingw32) fptools_cv_leading_underscore=yes;;
838     x86_64-unknown-mingw32) fptools_cv_leading_underscore=no;;
839     *) AC_RUN_IFELSE([AC_LANG_SOURCE([[#ifdef HAVE_NLIST_H
840 #include <nlist.h>
841 struct nlist xYzzY1[] = {{"xYzzY1", 0},{0}};
842 struct nlist xYzzY2[] = {{"_xYzzY2", 0},{0}};
843 #endif
844
845 int main(argc, argv)
846 int argc;
847 char **argv;
848 {
849 #ifdef HAVE_NLIST_H
850     if(nlist(argv[0], xYzzY1) == 0 && xYzzY1[0].n_value != 0)
851         exit(1);
852     if(nlist(argv[0], xYzzY2) == 0 && xYzzY2[0].n_value != 0)
853         exit(0);
854 #endif
855     exit(1);
856 }]])],[fptools_cv_leading_underscore=yes],[fptools_cv_leading_underscore=no],[fptools_cv_leading_underscore=no])
857 ;;
858 esac]);
859 AC_SUBST([LeadingUnderscore], [`echo $fptools_cv_leading_underscore | sed 'y/yesno/YESNO/'`])
860 if test x"$fptools_cv_leading_underscore" = xyes; then
861    AC_DEFINE([LEADING_UNDERSCORE], [1], [Define to 1 if C symbols have a leading underscore added by the compiler.])
862 fi])# FP_LEADING_UNDERSCORE
863
864
865 # FP_COMPARE_VERSIONS(VERSION1, TEST, VERSION2, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
866 # ----------------------------------------------------------------------------------
867 # Compare dotted version numbers VERSION1 and VERSION2 lexicographically according
868 # to TEST (one of -eq, -ne, -lt, -le, -gt, or -ge).
869 AC_DEFUN([FP_COMPARE_VERSIONS],
870 [fp_version1=$1; fp_version2=$3
871 fp_save_IFS=$IFS; IFS='.'
872 while test x"$fp_version1" != x || test x"$fp_version2" != x
873 do
874
875   set dummy $fp_version1; shift
876   fp_num1=""
877   test $[@%:@] = 0 || { fp_num1="[$]1"; shift; }
878   test x"$fp_num1" = x && fp_num1="0"
879   fp_version1="[$]*"
880
881   set dummy $fp_version2; shift
882   fp_num2=""
883   test $[@%:@] = 0 || { fp_num2="[$]1"; shift; }
884   test x"$fp_num2" = x && fp_num2="0"
885   fp_version2="[$]*"
886
887   test "$fp_num1" = "$fp_num2" || break;
888 done
889 IFS=$fp_save_IFS
890 AS_IF([test "$fp_num1" $2 "$fp_num2"], [$4], [$5])[]dnl
891 ])# FP_COMPARE_VERSIONS
892
893
894 dnl
895 dnl Check for Happy and version.
896 dnl If there's no installed Happy, we look
897 dnl for a happy source tree and point the build system at that instead.
898 dnl If you increase the minimum version requirement, please also update:
899 dnl https://ghc.haskell.org/trac/ghc/wiki/Building/Preparation/Tools
900 dnl
901 AC_DEFUN([FPTOOLS_HAPPY],
902 [AC_PATH_PROG(HappyCmd,happy,)
903
904 AC_CACHE_CHECK([for version of happy], fptools_cv_happy_version,
905 changequote(, )dnl
906 [if test x"$HappyCmd" != x; then
907    fptools_cv_happy_version=`"$HappyCmd" -v |
908               grep 'Happy Version' | sed -e 's/Happy Version \([^ ]*\).*/\1/g'` ;
909 else
910    fptools_cv_happy_version="";
911 fi;
912 changequote([, ])dnl
913 ])
914 if test ! -f compiler/parser/Parser.hs || test ! -f compiler/cmm/CmmParse.hs
915 then
916     FP_COMPARE_VERSIONS([$fptools_cv_happy_version],[-lt],[1.19.4],
917       [AC_MSG_ERROR([Happy version 1.19.4 or later is required to compile GHC.])])[]
918 fi
919 HappyVersion=$fptools_cv_happy_version;
920 AC_SUBST(HappyVersion)
921 ])
922
923 dnl
924 dnl Check for Alex and version.
925 dnl If you increase the minimum version requirement, please also update:
926 dnl https://ghc.haskell.org/trac/ghc/wiki/Building/Preparation/Tools
927 dnl
928 AC_DEFUN([FPTOOLS_ALEX],
929 [
930 AC_PATH_PROG(AlexCmd,alex,)
931
932 AC_CACHE_CHECK([for version of alex], fptools_cv_alex_version,
933 changequote(, )dnl
934 [if test x"$AlexCmd" != x; then
935    fptools_cv_alex_version=`"$AlexCmd" -v |
936               grep 'Alex [Vv]ersion' | sed -e 's/Alex [Vv]ersion \([0-9\.]*\).*/\1/g'` ;
937 else
938    fptools_cv_alex_version="";
939 fi;
940 changequote([, ])dnl
941 ])
942 FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-ge],[3.0],
943   [Alex3=YES],[Alex3=NO])
944 if test ! -f compiler/cmm/CmmLex.hs || test ! -f compiler/parser/Lexer.hs
945 then
946     FP_COMPARE_VERSIONS([$fptools_cv_alex_version],[-lt],[3.1.0],
947       [AC_MSG_ERROR([Alex version 3.1.0 or later is required to compile GHC.])])[]
948 fi
949 AlexVersion=$fptools_cv_alex_version;
950 AC_SUBST(AlexVersion)
951 AC_SUBST(Alex3)
952 ])
953
954
955 # FP_PROG_LD_FLAG
956 # ---------------
957 # Sets the output variable $2 to $1 if ld supports the $1 flag.
958 # Otherwise the variable's value is empty.
959 AC_DEFUN([FP_PROG_LD_FLAG],
960 [
961 AC_CACHE_CHECK([whether ld understands $1], [fp_cv_$2],
962 [echo 'int foo() { return 0; }' > conftest.c
963 ${CC-cc} -c conftest.c
964 if ${LdCmd} -r $1 -o conftest2.o conftest.o > /dev/null 2>&1; then
965    fp_cv_$2=$1
966 else
967    fp_cv_$2=
968 fi
969 rm -rf conftest*])
970 $2=$fp_cv_$2
971 ])# FP_PROG_LD_FLAG
972
973
974 # FP_PROG_LD_BUILD_ID
975 # ------------
976
977 # Sets the output variable LdHasBuildId to YES if ld supports
978 # --build-id, or NO otherwise.
979 AC_DEFUN([FP_PROG_LD_BUILD_ID],
980 [
981 AC_CACHE_CHECK([whether ld understands --build-id], [fp_cv_ld_build_id],
982 [echo 'int foo() { return 0; }' > conftest.c
983 ${CC-cc} -c conftest.c
984 if ${LdCmd} -r --build-id=none -o conftest2.o conftest.o > /dev/null 2>&1; then
985    fp_cv_ld_build_id=yes
986 else
987    fp_cv_ld_build_id=no
988 fi
989 rm -rf conftest*])
990 if test "$fp_cv_ld_build_id" = yes; then
991   LdHasBuildId=YES
992 else
993   LdHasBuildId=NO
994 fi
995 AC_SUBST([LdHasBuildId])
996 ])# FP_PROG_LD_BUILD_ID
997
998
999 # FP_PROG_LD_IS_GNU
1000 # -----------------
1001 # Sets the output variable LdIsGNULd to YES or NO, depending on whether it is
1002 # GNU ld or not.
1003 AC_DEFUN([FP_PROG_LD_IS_GNU],[
1004 AC_CACHE_CHECK([whether ld is GNU ld], [fp_cv_gnu_ld],
1005 [[if ${LdCmd} --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
1006   fp_cv_gnu_ld=YES
1007 else
1008   fp_cv_gnu_ld=NO
1009 fi]])
1010 AC_SUBST([LdIsGNULd],["$fp_cv_gnu_ld"])
1011 ])# FP_PROG_LD_IS_GNU
1012
1013
1014 # FP_PROG_LD_NO_COMPACT_UNWIND
1015 # ----------------------------
1016
1017 # Sets the output variable LdHasNoCompactUnwind to YES if ld supports
1018 # -no_compact_unwind, or NO otherwise.
1019 AC_DEFUN([FP_PROG_LD_NO_COMPACT_UNWIND],
1020 [
1021 AC_CACHE_CHECK([whether ld understands -no_compact_unwind], [fp_cv_ld_no_compact_unwind],
1022 [echo 'int foo() { return 0; }' > conftest.c
1023 ${CC-cc} -c conftest.c
1024 if ${LdCmd} -r -no_compact_unwind -o conftest2.o conftest.o > /dev/null 2>&1; then
1025    fp_cv_ld_no_compact_unwind=yes
1026 else
1027    fp_cv_ld_no_compact_unwind=no
1028 fi
1029 rm -rf conftest*])
1030 if test "$fp_cv_ld_no_compact_unwind" = yes; then
1031   LdHasNoCompactUnwind=YES
1032 else
1033   LdHasNoCompactUnwind=NO
1034 fi
1035 AC_SUBST([LdHasNoCompactUnwind])
1036 ])# FP_PROG_LD_NO_COMPACT_UNWIND
1037
1038
1039 # FP_PROG_LD_FILELIST
1040 # -------------------
1041
1042 # Sets the output variable LdHasFilelist to YES if ld supports
1043 # -filelist, or NO otherwise.
1044 AC_DEFUN([FP_PROG_LD_FILELIST],
1045 [
1046 AC_CACHE_CHECK([whether ld understands -filelist], [fp_cv_ld_has_filelist],
1047 [
1048     echo 'int foo() { return 0; }' > conftest1.c
1049     echo 'int bar() { return 0; }' > conftest2.c
1050     ${CC-cc} -c conftest1.c
1051     ${CC-cc} -c conftest2.c
1052     echo conftest1.o  > conftest.o-files
1053     echo conftest2.o >> conftest.o-files
1054     if ${LdCmd} -r -filelist conftest.o-files -o conftest.o > /dev/null 2>&1
1055     then
1056         fp_cv_ld_has_filelist=yes
1057     else
1058         fp_cv_ld_has_filelist=no
1059     fi
1060     rm -rf conftest*
1061 ])
1062 if test "$fp_cv_ld_has_filelist" = yes; then
1063     LdHasFilelist=YES
1064 else
1065     LdHasFilelist=NO
1066 fi
1067 AC_SUBST([LdHasFilelist])
1068 ])# FP_PROG_LD_FILELIST
1069
1070
1071 # FP_PROG_AR
1072 # ----------
1073 # Sets fp_prog_ar to a path to ar. Exits if no ar can be found
1074 # The host normalization on Windows breaks autoconf, it no longer
1075 # thinks that target == host so it never checks the unqualified
1076 # tools for Windows. See #14274.
1077 AC_DEFUN([FP_PROG_AR],
1078 [if test -z "$fp_prog_ar"; then
1079   if test "$HostOS" = "mingw32"
1080   then
1081     AC_PATH_PROG([fp_prog_ar], [ar])
1082     if test -n "$fp_prog_ar"; then
1083       fp_prog_ar=$(cygpath -m $fp_prog_ar)
1084     fi
1085   else
1086     AC_CHECK_TARGET_TOOL([fp_prog_ar], [ar])
1087   fi
1088 fi
1089 if test -z "$fp_prog_ar"; then
1090   AC_MSG_ERROR([cannot find ar in your PATH, no idea how to make a library])
1091 fi
1092 ])# FP_PROG_AR
1093
1094
1095 # FP_PROG_AR_IS_GNU
1096 # -----------------
1097 # Sets fp_prog_ar_is_gnu to yes or no, depending on whether it is GNU ar or not.
1098 AC_DEFUN([FP_PROG_AR_IS_GNU],
1099 [AC_REQUIRE([FP_PROG_AR])
1100 AC_CACHE_CHECK([whether $fp_prog_ar is GNU ar], [fp_cv_prog_ar_is_gnu],
1101 [if "$fp_prog_ar" --version 2> /dev/null | grep "GNU" > /dev/null 2>&1; then
1102   fp_cv_prog_ar_is_gnu=yes
1103 else
1104   fp_cv_prog_ar_is_gnu=no
1105 fi])
1106 fp_prog_ar_is_gnu=$fp_cv_prog_ar_is_gnu
1107 AC_SUBST([ArIsGNUAr], [`echo $fp_prog_ar_is_gnu | tr 'a-z' 'A-Z'`])
1108 ])# FP_PROG_AR_IS_GNU
1109
1110
1111 # FP_PROG_AR_SUPPORTS_ATFILE
1112 # -----------------
1113 # Sets fp_prog_ar_supports_atfile to yes or no, depending on whether
1114 # or not it supports the @file syntax
1115 AC_DEFUN([FP_PROG_AR_SUPPORTS_ATFILE],
1116 [AC_REQUIRE([FP_PROG_AR])
1117  AC_REQUIRE([FP_PROG_AR_ARGS])
1118 AC_CACHE_CHECK([whether $fp_prog_ar supports @file], [fp_cv_prog_ar_supports_atfile],
1119 [
1120 rm -f conftest*
1121 touch conftest.file
1122 echo conftest.file  > conftest.atfile
1123 echo conftest.file >> conftest.atfile
1124 "$fp_prog_ar" $fp_prog_ar_args conftest.a @conftest.atfile > /dev/null 2>&1
1125 fp_prog_ar_supports_atfile_tmp=`"$fp_prog_ar" t conftest.a 2> /dev/null | grep -c conftest.file`
1126 rm -f conftest*
1127 if test "$fp_prog_ar_supports_atfile_tmp" -eq 2
1128 then
1129   fp_cv_prog_ar_supports_atfile=yes
1130 else
1131   fp_cv_prog_ar_supports_atfile=no
1132 fi])
1133 fp_prog_ar_supports_atfile=$fp_cv_prog_ar_supports_atfile
1134 AC_SUBST([ArSupportsAtFile], [`echo $fp_prog_ar_supports_atfile | tr 'a-z' 'A-Z'`])
1135 ])# FP_PROG_AR_SUPPORTS_ATFILE
1136
1137 # FP_PROG_AR_ARGS
1138 # ---------------
1139 # Sets fp_prog_ar_args to the arguments for ar and the output variable ArCmd
1140 # to an invocation of ar including these arguments.
1141 AC_DEFUN([FP_PROG_AR_ARGS],
1142 [AC_REQUIRE([FP_PROG_AR_IS_GNU])
1143 AC_CACHE_CHECK([for ar arguments], [fp_cv_prog_ar_args],
1144 [
1145 # GNU ar needs special treatment: it appears to have problems with
1146 # object files with the same name if you use the 's' modifier, but
1147 # simple 'ar q' works fine, and doesn't need a separate ranlib.
1148 if test $fp_prog_ar_is_gnu = yes; then
1149   fp_cv_prog_ar_args="q"
1150 else
1151   touch conftest.dummy
1152   for fp_var in clqsZ clqs cqs clq cq ; do
1153      rm -f conftest.a
1154      if "$fp_prog_ar" $fp_var conftest.a conftest.dummy > /dev/null 2> /dev/null; then
1155         fp_cv_prog_ar_args=$fp_var
1156         break
1157      fi
1158   done
1159   rm -f conftest*
1160   if test -z "$fp_cv_prog_ar_args"; then
1161     AC_MSG_ERROR([cannot figure out how to use your $fp_prog_ar])
1162   fi
1163 fi])
1164 fp_prog_ar_args=$fp_cv_prog_ar_args
1165 AC_SUBST([ArCmd], ["$fp_prog_ar"])
1166 AC_SUBST([ArArgs], ["$fp_prog_ar_args"])
1167
1168 ])# FP_PROG_AR_ARGS
1169
1170
1171 # FP_PROG_AR_NEEDS_RANLIB
1172 # -----------------------
1173 # Sets the output variable RANLIB_CMD to "ranlib" if it is needed and
1174 # found, to "true" otherwise. Sets REAL_RANLIB_CMD to the ranlib program,
1175 # even if we don't need ranlib (libffi might still need it).
1176 AC_DEFUN([FP_PROG_AR_NEEDS_RANLIB],[
1177     AC_REQUIRE([FP_PROG_AR_IS_GNU])
1178     AC_REQUIRE([FP_PROG_AR_ARGS])
1179     AC_REQUIRE([AC_PROG_CC])
1180
1181     AC_PROG_RANLIB
1182
1183     if test $fp_prog_ar_is_gnu = yes
1184     then
1185         fp_cv_prog_ar_needs_ranlib=no
1186     elif test "$TargetVendor_CPP" = "apple"
1187     then
1188         # It's quite tedious to check for Apple's crazy timestamps in
1189         # .a files, so we hardcode it.
1190         fp_cv_prog_ar_needs_ranlib=yes
1191     else
1192         case $fp_prog_ar_args in
1193         *s*)
1194             fp_cv_prog_ar_needs_ranlib=no;;
1195         *)
1196             fp_cv_prog_ar_needs_ranlib=yes;;
1197         esac
1198     fi
1199
1200     # workaround for AC_PROG_RANLIB which sets RANLIB to `:' when
1201     # ranlib is missing on the target OS. The problem is that
1202     # ghc-cabal cannot execute `:' which is a shell built-in but can
1203     # execute `true' which is usually simple program supported by the
1204     # OS.
1205     # Fixes #8795
1206     if test "$RANLIB" = ":"
1207     then
1208         RANLIB="true"
1209     fi
1210     REAL_RANLIB_CMD="$RANLIB"
1211     if test $fp_cv_prog_ar_needs_ranlib = yes
1212     then
1213         RANLIB_CMD="$RANLIB"
1214     else
1215         RANLIB_CMD="true"
1216     fi
1217     AC_SUBST([REAL_RANLIB_CMD])
1218     AC_SUBST([RANLIB_CMD])
1219 ])# FP_PROG_AR_NEEDS_RANLIB
1220
1221
1222 # FP_GCC_VERSION
1223 # -----------
1224 # Extra testing of the result AC_PROG_CC, testing the gcc version no. Sets the
1225 # output variable GccVersion.
1226 AC_DEFUN([FP_GCC_VERSION],
1227 [AC_REQUIRE([AC_PROG_CC])
1228 if test -z "$CC"
1229 then
1230   AC_MSG_ERROR([gcc is required])
1231 fi
1232 GccLT34=NO
1233 GccLT44=NO
1234 GccLT46=NO
1235 AC_CACHE_CHECK([version of gcc], [fp_cv_gcc_version],
1236 [
1237     # Be sure only to look at the first occurrence of the "version " string;
1238     # Some Apple compilers emit multiple messages containing this string.
1239     fp_cv_gcc_version="`$CC -v 2>&1 | sed -n -e '1,/version /s/.*version [[^0-9]]*\([[0-9.]]*\).*/\1/p'`"
1240     FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-lt], [3.0],
1241                         [AC_MSG_ERROR([Need at least gcc version 3.0 (3.4+ recommended)])])
1242     # See #2770: gcc 2.95 doesn't work any more, apparently.  There probably
1243     # isn't a very good reason for that, but for now just make configure
1244     # fail.
1245     FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-lt], [3.4], GccLT34=YES)
1246     FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-lt], [4.4], GccLT44=YES)
1247     FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-lt], [4.6], GccLT46=YES)
1248 ])
1249 AC_SUBST([GccVersion], [$fp_cv_gcc_version])
1250 AC_SUBST(GccLT34)
1251 AC_SUBST(GccLT44)
1252 AC_SUBST(GccLT46)
1253 ])# FP_GCC_VERSION
1254
1255 dnl Check to see if the C compiler is clang or llvm-gcc
1256 dnl
1257 GccIsClang=NO
1258 AC_DEFUN([FP_CC_LLVM_BACKEND],
1259 [AC_REQUIRE([AC_PROG_CC])
1260 AC_MSG_CHECKING([whether C compiler is clang])
1261 $CC -x c /dev/null -dM -E > conftest.txt 2>&1
1262 if grep "__clang__" conftest.txt >/dev/null 2>&1; then
1263   AC_SUBST([CC_CLANG_BACKEND], [1])
1264   AC_SUBST([CC_LLVM_BACKEND], [1])
1265   GccIsClang=YES
1266   AC_MSG_RESULT([yes])
1267 else
1268   AC_MSG_RESULT([no])
1269   AC_MSG_CHECKING([whether C compiler has an LLVM back end])
1270   if grep "__llvm__" conftest.txt >/dev/null 2>&1; then
1271     AC_SUBST([CC_CLANG_BACKEND], [0])
1272     AC_SUBST([CC_LLVM_BACKEND], [1])
1273     AC_MSG_RESULT([yes])
1274   else
1275     AC_SUBST([CC_CLANG_BACKEND], [0])
1276     AC_SUBST([CC_LLVM_BACKEND], [0])
1277     AC_MSG_RESULT([no])
1278   fi
1279 fi
1280 AC_SUBST(GccIsClang)
1281
1282 rm -f conftest.txt
1283 ])
1284
1285 # FP_GCC_SUPPORTS_NO_PIE
1286 # ----------------------
1287 # Does gcc support the -no-pie option? If so we should pass it to gcc when
1288 # joining objects since -pie may be enabled by default.
1289 AC_DEFUN([FP_GCC_SUPPORTS_NO_PIE],
1290 [
1291    AC_REQUIRE([AC_PROG_CC])
1292    AC_MSG_CHECKING([whether GCC supports -no-pie])
1293    echo 'int main() { return 0; }' > conftest.c
1294    # Some GCC versions only warn when passed an unrecognized flag.
1295    if $CC -no-pie -x c /dev/null -dM -E > conftest.txt 2>&1 && ! grep -i unrecognized conftest.txt > /dev/null 2>&1; then
1296        CONF_GCC_SUPPORTS_NO_PIE=YES
1297        AC_MSG_RESULT([yes])
1298    else
1299        CONF_GCC_SUPPORTS_NO_PIE=NO
1300        AC_MSG_RESULT([no])
1301    fi
1302    rm -f conftest.c conftest.o conftest
1303 ])
1304
1305 dnl Small feature test for perl version. Assumes PerlCmd
1306 dnl contains path to perl binary.
1307 dnl
1308 dnl (Perl versions prior to v5.6 does not contain the string "v5";
1309 dnl instead they display version strings such as "version 5.005".)
1310 dnl
1311 AC_DEFUN([FPTOOLS_CHECK_PERL_VERSION],
1312 [$PerlCmd -v >conftest.out 2>&1
1313    if grep "v5" conftest.out >/dev/null 2>&1; then
1314       :
1315    else
1316       AC_MSG_ERROR([your version of perl probably won't work, try upgrading it.])
1317    fi
1318 rm -fr conftest*
1319 ])
1320
1321
1322 # FP_CHECK_PROG(VARIABLE, PROG-TO-CHECK-FOR,
1323 #               [VALUE-IF-NOT-FOUND], [PATH], [REJECT])
1324 # -----------------------------------------------------
1325 # HACK: A small wrapper around AC_CHECK_PROG, setting VARIABLE to the full path
1326 # of PROG-TO-CHECK-FOR when found.
1327 AC_DEFUN([FP_CHECK_PROG],
1328 [AC_CHECK_PROG([$1], [$2], [$as_dir/$ac_word$ac_exec_ext], [$3], [$4], [$5])][]dnl
1329 )# FP_CHECK_PROC
1330
1331
1332 # FP_PROG_FIND
1333 # ------------
1334 # Find a non-WinDoze version of the "find" utility.
1335 AC_DEFUN([FP_PROG_FIND],
1336 [AC_PATH_PROGS([fp_prog_find], [gfind find], find)
1337 echo foo > conftest.txt
1338 $fp_prog_find conftest.txt -print > conftest.out 2>&1
1339 if grep '^conftest.txt$' conftest.out > /dev/null 2>&1 ; then
1340   # OK, looks like a real "find".
1341   FindCmd="$fp_prog_find"
1342 else
1343   # Found a poor WinDoze version of "find", ignore it.
1344   AC_MSG_WARN([$fp_prog_find looks like a non-*nix find, ignoring it])
1345   FP_CHECK_PROG([FindCmd], [find], [], [], [$fp_prog_find])
1346 fi
1347 rm -f conftest.txt conftest.out
1348 AC_SUBST([FindCmd])[]dnl
1349 ])# FP_PROG_FIND
1350
1351
1352 # FP_PROG_SORT
1353 # ------------
1354 # Find a Unix-like sort
1355 AC_DEFUN([FP_PROG_SORT],
1356 [AC_PATH_PROG([fp_prog_sort], [sort])
1357 echo conwip > conftest.txt
1358 $fp_prog_sort -f conftest.txt > conftest.out 2>&1
1359 if grep 'conwip' conftest.out > /dev/null 2>&1 ; then
1360   # The goods
1361   SortCmd="$fp_prog_sort"
1362 else
1363   # Summink else..pick next one.
1364   AC_MSG_WARN([$fp_prog_sort looks like a non-*nix sort, ignoring it])
1365   FP_CHECK_PROG([SortCmd], [sort], [], [], [$fp_prog_sort])
1366 fi
1367 rm -f conftest.txt conftest.out
1368 AC_SUBST([SortCmd])[]dnl
1369 ])# FP_PROG_SORT
1370
1371
1372 dnl
1373 dnl FPTOOLS_NOCACHE_CHECK prints a message, then sets the
1374 dnl values of the second argument to the result of running
1375 dnl the commands given by the third. It does not cache its
1376 dnl result, so it is suitable for checks which should be
1377 dnl run every time.
1378 dnl
1379 AC_DEFUN([FPTOOLS_NOCACHE_CHECK],
1380 [AC_MSG_CHECKING([$1])
1381  $3
1382  AC_MSG_RESULT([$][$2])
1383 ])
1384
1385 dnl
1386 dnl FPTOOLS_GHC_VERSION(version)
1387 dnl FPTOOLS_GHC_VERSION(major, minor [, patchlevel])
1388 dnl FPTOOLS_GHC_VERSION(version, major, minor, patchlevel)
1389 dnl
1390 dnl Test for version of installed ghc.  Uses $GHC.
1391 dnl [original version pinched from c2hs]
1392 dnl
1393 AC_DEFUN([FPTOOLS_GHC_VERSION],
1394 [FPTOOLS_NOCACHE_CHECK([version of ghc], [fptools_version_of_ghc],
1395 ["${WithGhc-ghc}" --version > conftestghc 2>&1
1396   cat conftestghc >&AS_MESSAGE_LOG_FD
1397 #Useless Use Of cat award...
1398   fptools_version_of_ghc=`cat conftestghc | sed -n -e 's/, patchlevel *\([[0-9]]\)/.\1/;s/.* version \([[0-9]][[0-9.]]*\).*/\1/p'`
1399   rm -fr conftest*
1400   if test "[$]fptools_version_of_ghc" = ""
1401   then
1402     fptools_version_of_ghc='unknown'
1403   fi
1404 fptools_version_of_ghc[_major]=`echo [$]fptools_version_of_ghc | sed -e 's/^\([[0-9]]\).*/\1/'`
1405 fptools_version_of_ghc[_minor]=`echo [$]fptools_version_of_ghc | sed -e 's/^[[0-9]]\.\([[0-9]]*\).*/\1/'`
1406 fptools_version_of_ghc[_pl]=`echo [$]fptools_version_of_ghc | sed -n -e 's/^[[0-9]]\.[[0-9]]*\.\([[0-9]]*\)/\1/p'`
1407 #
1408 if test "[$]fptools_version_of_ghc[_pl]" = ""
1409 then
1410   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor]"
1411   fptools_version_of_ghc[_pl]="0"
1412 else
1413   fptools_version_of_ghc[_all]="[$]fptools_version_of_ghc[_major].[$]fptools_version_of_ghc[_minor].[$]fptools_version_of_ghc[_pl]"
1414 fi
1415 #
1416 ifelse($#, [1], [dnl
1417 [$1]="[$]fptools_version_of_ghc[_all]"
1418 ], $#, [2], [dnl
1419 [$1]="[$]fptools_version_of_ghc[_major]"
1420 [$2]="[$]fptools_version_of_ghc[_minor]"
1421 ], $#, [3], [dnl
1422 [$1]="[$]fptools_version_of_ghc[_major]"
1423 [$2]="[$]fptools_version_of_ghc[_minor]"
1424 [$3]="[$]fptools_version_of_ghc[_pl]"
1425 ], $#, [4], [dnl
1426 [$1]="[$]fptools_version_of_ghc[_all]"
1427 [$2]="[$]fptools_version_of_ghc[_major]"
1428 [$3]="[$]fptools_version_of_ghc[_minor]"
1429 [$4]="[$]fptools_version_of_ghc[_pl]"
1430 ])
1431 ])
1432 ])dnl
1433
1434
1435 # FP_CHECK_FUNC(FUNCTION, PROLOGUE, BODY, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
1436 # ---------------------------------------------------------------------------------
1437 # A variant of AC_CHECK_FUNCS, limited to a single FUNCTION, but with the
1438 # additional flexibility of specifying the PROLOGUE and BODY.
1439 AC_DEFUN([FP_CHECK_FUNC],
1440 [AS_VAR_PUSHDEF([fp_func], [fp_cv_func_$1])dnl
1441 AC_CACHE_CHECK([for $1], fp_func,
1442 [AC_LINK_IFELSE([AC_LANG_PROGRAM([$2], [$3])],
1443                 [AS_VAR_SET(fp_func, yes)],
1444                 [AS_VAR_SET(fp_func, no)])])
1445 AS_IF([test AS_VAR_GET(fp_func) = yes],
1446       [AC_DEFINE(AS_TR_CPP(HAVE_$1), [1],
1447                 [Define to 1 if you have the `]$1[' function.]) $4],
1448       [$5])dnl
1449 AS_VAR_POPDEF([fp_func])dnl
1450 ])# FP_CHECK_FUNC
1451
1452 # FP_PROG_GHC_PKG
1453 # ----------------
1454 # Try to find a ghc-pkg matching the ghc mentioned in the environment variable
1455 # WithGhc. Sets the output variable GhcPkgCmd.
1456 AC_DEFUN([FP_PROG_GHC_PKG],
1457 [AC_CACHE_CHECK([for ghc-pkg matching $WithGhc], fp_cv_matching_ghc_pkg,
1458 [
1459 # If we are told to use ghc-stage2, then we're using an in-tree
1460 # compiler. In this case, we just want ghc-pkg, not ghc-pkg-stage2,
1461 # so we sed off -stage[0-9]$. However, if we are told to use
1462 # ghc-6.12.1 then we want to use ghc-pkg-6.12.1, so we keep any
1463 # other suffix.
1464 fp_ghc_pkg_guess=`echo "$WithGhc" | sed -e 's/-stage@<:@0-9@:>@$//' -e 's,ghc\(@<:@^/\\@:>@*\)$,ghc-pkg\1,'`
1465 if "$fp_ghc_pkg_guess" list > /dev/null 2>&1; then
1466   fp_cv_matching_ghc_pkg=$fp_ghc_pkg_guess
1467 else
1468   AC_MSG_ERROR([Cannot find matching ghc-pkg])
1469 fi])
1470 GhcPkgCmd=$fp_cv_matching_ghc_pkg
1471 AC_SUBST([GhcPkgCmd])
1472 ])# FP_PROG_GHC_PKG
1473
1474
1475 # FP_GCC_EXTRA_FLAGS
1476 # ------------------
1477 # Determine which extra flags we need to pass gcc when we invoke it
1478 # to compile .hc code.
1479 #
1480 # -fwrapv is needed for gcc to emit well-behaved code in the presence of
1481 # integer wrap around. (Trac #952)
1482 #
1483 AC_DEFUN([FP_GCC_EXTRA_FLAGS],
1484 [AC_REQUIRE([FP_GCC_VERSION])
1485 AC_CACHE_CHECK([for extra options to pass gcc when compiling via C], [fp_cv_gcc_extra_opts],
1486 [fp_cv_gcc_extra_opts=
1487  FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [3.4],
1488   [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fwrapv"],
1489   [])
1490  FP_COMPARE_VERSIONS([$fp_cv_gcc_version], [-ge], [4.0],
1491   [fp_cv_gcc_extra_opts="$fp_cv_gcc_extra_opts -fno-builtin"],
1492   [])
1493 ])
1494 AC_SUBST([GccExtraViaCOpts],$fp_cv_gcc_extra_opts)
1495 ])
1496
1497
1498 # FP_SETUP_PROJECT_VERSION
1499 # ---------------------
1500 AC_DEFUN([FP_SETUP_PROJECT_VERSION],
1501 [
1502 if test "$RELEASE" = "NO"; then
1503     AC_MSG_CHECKING([for GHC version date])
1504     if test -f VERSION_DATE; then
1505         PACKAGE_VERSION=${PACKAGE_VERSION}.`cat VERSION_DATE`
1506         AC_MSG_RESULT(given $PACKAGE_VERSION)
1507     elif test -d .git; then
1508         changequote(, )dnl
1509         ver_posixtime=`git log -1 --pretty=format:%ct`
1510         ver_date=`perl -MPOSIX -e "print strftime('%Y%m%d', gmtime($ver_posixtime));"`
1511         if echo $ver_date | grep '^[0-9][0-9][0-9][0-9][0-9][0-9][0-9][0-9]$' 2>&1 >/dev/null; then true; else
1512         changequote([, ])dnl
1513                 AC_MSG_ERROR([failed to detect version date: check that git and perl are in your path])
1514         fi
1515         PACKAGE_VERSION=${PACKAGE_VERSION}.$ver_date
1516         AC_MSG_RESULT(inferred $PACKAGE_VERSION)
1517     elif test -f VERSION; then
1518         PACKAGE_VERSION=`cat VERSION`
1519         AC_MSG_RESULT(given $PACKAGE_VERSION)
1520     else
1521         AC_MSG_WARN([cannot determine snapshot version: no .git directory and no VERSION file])
1522         dnl We'd really rather this case didn't happen, but it might
1523         dnl do (in particular, people using lndir trees may find that
1524         dnl the build system can't find any other date). If it does
1525         dnl happen, then we use the current date.
1526         dnl This way we get some idea about how recent a build is.
1527         dnl It also means that packages built for 2 different builds
1528         dnl will probably use different version numbers, so things are
1529         dnl less likely to go wrong.
1530         PACKAGE_VERSION=${PACKAGE_VERSION}.`date +%Y%m%d`
1531     fi
1532 fi
1533
1534     AC_MSG_CHECKING([for GHC Git commit id])
1535     if test -d .git; then
1536         git_commit_id=`git rev-parse HEAD`
1537         if test -n "$git_commit_id" 2>&1 >/dev/null; then true; else
1538             AC_MSG_ERROR([failed to detect revision: check that git is in your path])
1539         fi
1540         PACKAGE_GIT_COMMIT_ID=$git_commit_id
1541         AC_MSG_RESULT(inferred $PACKAGE_GIT_COMMIT_ID)
1542     elif test -f GIT_COMMIT_ID; then
1543         PACKAGE_GIT_COMMIT_ID=`cat GIT_COMMIT_ID`
1544         AC_MSG_RESULT(given $PACKAGE_GIT_COMMIT_ID)
1545     else
1546         AC_MSG_WARN([cannot determine snapshot revision: no .git directory and no 'GIT_COMMIT_ID' file])
1547         PACKAGE_GIT_COMMIT_ID="0000000000000000000000000000000000000000"
1548     fi
1549
1550
1551 # Some renamings
1552 AC_SUBST([ProjectName], [$PACKAGE_NAME])
1553 AC_SUBST([ProjectVersion], [$PACKAGE_VERSION])
1554 AC_SUBST([ProjectGitCommitId], [$PACKAGE_GIT_COMMIT_ID])
1555
1556 # Split PACKAGE_VERSION into (possibly empty) parts
1557 VERSION_MAJOR=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
1558 VERSION_TMP=`echo $PACKAGE_VERSION | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
1559 VERSION_MINOR=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1'/`
1560 ProjectPatchLevel=`echo $VERSION_TMP | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3'/`
1561
1562 # Calculate project version as an integer, using 2 digits for minor version
1563 case $VERSION_MINOR in
1564   ?) ProjectVersionInt=${VERSION_MAJOR}0${VERSION_MINOR} ;;
1565   ??) ProjectVersionInt=${VERSION_MAJOR}${VERSION_MINOR} ;;
1566   *) AC_MSG_ERROR([bad minor version in $PACKAGE_VERSION]) ;;
1567 esac
1568 AC_SUBST([ProjectVersionInt])
1569
1570 # The project patchlevel is zero unless stated otherwise
1571 test -z "$ProjectPatchLevel" && ProjectPatchLevel=0
1572
1573 # Save split version of ProjectPatchLevel
1574 ProjectPatchLevel1=`echo $ProjectPatchLevel | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\1/'`
1575 ProjectPatchLevel2=`echo $ProjectPatchLevel | sed 's/^\(@<:@^.@:>@*\)\(\.\{0,1\}\(.*\)\)$/\3/'`
1576
1577 AC_SUBST([ProjectPatchLevel1])
1578 AC_SUBST([ProjectPatchLevel2])
1579
1580 # Remove dots from the patch level; this allows us to have versions like 6.4.1.20050508
1581 ProjectPatchLevel=`echo $ProjectPatchLevel | sed 's/\.//'`
1582
1583 AC_SUBST([ProjectPatchLevel])
1584
1585 # The version of the GHC package changes every day, since the
1586 # patchlevel is the current date.  We don't want to force
1587 # recompilation of the entire compiler when this happens, so for
1588 # GHC HEAD we omit the patchlevel from the package version number.
1589 #
1590 # The ProjectPatchLevel1 > 20000000 iff GHC HEAD. If it's for a stable
1591 # release like 7.10.1 or for a release candidate such as 7.10.1.20141224
1592 # then we don't omit the patchlevel components.
1593
1594 ProjectVersionMunged="$ProjectVersion"
1595 if test "$ProjectPatchLevel1" -gt 20000000; then
1596   ProjectVersionMunged="${VERSION_MAJOR}.${VERSION_MINOR}"
1597 fi
1598 AC_SUBST([ProjectVersionMunged])
1599 ])# FP_SETUP_PROJECT_VERSION
1600
1601 # Check for a working timer_create().  We need a pretty detailed check
1602 # here, because there exist partially-working implementations of
1603 # timer_create() in certain versions of Linux (see bug #1933).
1604 #
1605 AC_DEFUN([FP_CHECK_TIMER_CREATE],[
1606 AC_CHECK_FUNC([timer_create],[HAVE_timer_create=yes],[HAVE_timer_create=no])
1607
1608 if test "$HAVE_timer_create" = "yes"
1609 then
1610   if test "$cross_compiling" = "yes"
1611   then
1612     # We can't test timer_create when we're cross-compiling, so we
1613     # optimistiaclly assume that it actually works properly.
1614     AC_DEFINE([USE_TIMER_CREATE], 1,  [Define to 1 if we can use timer_create(CLOCK_REALTIME,...)])
1615   else
1616   AC_CACHE_CHECK([for a working timer_create(CLOCK_REALTIME)],
1617     [fptools_cv_timer_create_works],
1618     [AC_TRY_RUN([
1619 #include <stdio.h>
1620 #ifdef HAVE_STDLIB_H
1621 #include <stdlib.h>
1622 #endif
1623 #ifdef HAVE_TIME_H
1624 #include <time.h>
1625 #endif
1626 #ifdef HAVE_SIGNAL_H
1627 #include <signal.h>
1628 #endif
1629 #ifdef HAVE_UNISTD_H
1630 #include <unistd.h>
1631 #endif
1632
1633 static volatile int tock = 0;
1634 static void handler(int i)
1635 {
1636    tock = 1;
1637 }
1638
1639 static void timeout(int i)
1640 {
1641   // timer_settime() has been known to hang, so just in case
1642   // we install a 1-second timeout (see #2257)
1643   exit(99);
1644 }
1645
1646 int main(int argc, char *argv[])
1647 {
1648
1649     struct sigevent ev;
1650     timer_t timer;
1651     struct itimerspec it;
1652     struct sigaction action;
1653     int m,n,count = 0;
1654
1655     ev.sigev_notify = SIGEV_SIGNAL;
1656     ev.sigev_signo  = SIGVTALRM;
1657
1658     action.sa_handler = handler;
1659     action.sa_flags = 0;
1660     sigemptyset(&action.sa_mask);
1661     if (sigaction(SIGVTALRM, &action, NULL) == -1) {
1662         fprintf(stderr,"SIGVTALRM problem\n");
1663         exit(3);
1664     }
1665
1666     action.sa_handler = timeout;
1667     action.sa_flags = 0;
1668     sigemptyset(&action.sa_mask);
1669     if (sigaction(SIGALRM, &action, NULL) == -1) {
1670       fprintf(stderr,"SIGALRM problem\n");
1671       exit(3);
1672     }
1673     alarm(1);
1674
1675     if (timer_create(CLOCK_REALTIME, &ev, &timer) != 0) {
1676         fprintf(stderr,"No CLOCK_REALTIME timer\n");
1677         exit(2);
1678     }
1679
1680     tock = 0;
1681
1682     it.it_value.tv_sec = 0;
1683     it.it_value.tv_nsec = 1000000; // 1ms
1684     it.it_interval = it.it_value;
1685     if (timer_settime(timer, 0, &it, NULL) != 0) {
1686         fprintf(stderr,"settime problem\n");
1687         exit(4);
1688     }
1689
1690     // some environments have coarse scheduler/timer granularity of ~10ms and worse
1691     usleep(100000); // 100ms
1692
1693     if (!tock) {
1694         fprintf(stderr,"no CLOCK_REALTIME signal\n");
1695         exit(5);
1696     }
1697
1698     timer_delete(timer);
1699
1700     exit(0);
1701 }
1702      ],
1703      [fptools_cv_timer_create_works=yes],
1704      [fptools_cv_timer_create_works=no])
1705   ])
1706 case $fptools_cv_timer_create_works in
1707     yes) AC_DEFINE([USE_TIMER_CREATE], 1,
1708                    [Define to 1 if we can use timer_create(CLOCK_REALTIME,...)]);;
1709 esac
1710   fi
1711 fi
1712 ])
1713
1714 # FP_ICONV
1715 # -------------
1716 AC_DEFUN([FP_ICONV],
1717 [
1718   dnl--------------------------------------------------------------------
1719   dnl * Deal with arguments telling us iconv is somewhere odd
1720   dnl--------------------------------------------------------------------
1721
1722   dnl Note: ICONV_LIB_DIRS and ICONV_INCLUDE_DIRS are not predefined
1723   dnl to the empty string to allow them to be overridden from the
1724   dnl environment.
1725
1726   AC_ARG_WITH([iconv-includes],
1727     [AC_HELP_STRING([--with-iconv-includes],
1728       [directory containing iconv.h])],
1729       [ICONV_INCLUDE_DIRS=$withval])
1730
1731   AC_ARG_WITH([iconv-libraries],
1732     [AC_HELP_STRING([--with-iconv-libraries],
1733       [directory containing iconv library])],
1734       [ICONV_LIB_DIRS=$withval])
1735
1736   AC_SUBST(ICONV_INCLUDE_DIRS)
1737   AC_SUBST(ICONV_LIB_DIRS)
1738 ])# FP_ICONV
1739
1740 # FP_GMP
1741 # -------------
1742 AC_DEFUN([FP_GMP],
1743 [
1744   dnl--------------------------------------------------------------------
1745   dnl * Deal with arguments telling us gmp is somewhere odd
1746   dnl--------------------------------------------------------------------
1747
1748   AC_ARG_WITH([gmp-includes],
1749     [AC_HELP_STRING([--with-gmp-includes],
1750       [directory containing gmp.h])],
1751       [GMP_INCLUDE_DIRS=$withval])
1752
1753   AC_ARG_WITH([gmp-libraries],
1754     [AC_HELP_STRING([--with-gmp-libraries],
1755       [directory containing gmp library])],
1756       [GMP_LIB_DIRS=$withval])
1757
1758   AC_SUBST(GMP_INCLUDE_DIRS)
1759   AC_SUBST(GMP_LIB_DIRS)
1760 ])# FP_GMP
1761
1762 # FP_CURSES
1763 # -------------
1764 AC_DEFUN([FP_CURSES],
1765 [
1766   dnl--------------------------------------------------------------------
1767   dnl * Deal with arguments telling us curses is somewhere odd
1768   dnl--------------------------------------------------------------------
1769
1770   AC_ARG_WITH([curses-libraries],
1771     [AC_HELP_STRING([--with-curses-libraries],
1772       [directory containing curses libraries])],
1773       [CURSES_LIB_DIRS=$withval])
1774
1775   AC_SUBST(CURSES_INCLUDE_DIRS)
1776   AC_SUBST(CURSES_LIB_DIRS)
1777 ])# FP_CURSES
1778
1779 # --------------------------------------------------------------
1780 # Calculate absolute path to build tree
1781 # --------------------------------------------------------------
1782
1783 AC_DEFUN([FP_FIND_ROOT],[
1784 AC_MSG_CHECKING(for path to top of build tree)
1785     if test "$windows" = YES
1786     then
1787       dnl Make sure this is a c:/foo/bar (mixed) style path. Some parts of
1788       dnl the build system might depend on it (such as the sed expression
1789       dnl `"s|$(TOP)/||i"` in addCFileDeps in rules/build-dependencies.mk).
1790       hardtop=$(cygpath -m "$(pwd)")
1791     else
1792       hardtop=$(pwd)
1793     fi
1794
1795     dnl Remove common automounter nonsense
1796     hardtop=`echo $hardtop | sed 's|^/tmp_mnt.*\(/local/.*\)$|\1|' | sed 's|^/tmp_mnt/|/|'`
1797
1798     if ! test -d "$hardtop"; then
1799         AC_MSG_ERROR([cannot determine current directory])
1800     fi
1801
1802     dnl We don't support building in directories with spaces.
1803     case "$hardtop" in
1804     *' '*)
1805         AC_MSG_ERROR([
1806         The build system does not support building in a directory
1807         containing space characters.
1808         Suggestion: move the build tree somewhere else.])
1809         ;;
1810     esac
1811
1812     AC_SUBST(hardtop)
1813
1814     AC_MSG_RESULT($hardtop)
1815 ])
1816
1817 # GHC_CONVERT_CPU(cpu, target_var)
1818 # --------------------------------
1819 # converts cpu from gnu to ghc naming, and assigns the result to $target_var
1820 AC_DEFUN([GHC_CONVERT_CPU],[
1821 case "$1" in
1822   aarch64*)
1823     $2="aarch64"
1824     ;;
1825   alpha*)
1826     $2="alpha"
1827     ;;
1828   arm*)
1829     $2="arm"
1830     ;;
1831   hppa1.1*)
1832     $2="hppa1_1"
1833     ;;
1834   hppa*)
1835     $2="hppa"
1836     ;;
1837   i386|i486|i586|i686)
1838     $2="i386"
1839     ;;
1840   ia64)
1841     $2="ia64"
1842     ;;
1843   m68k*)
1844     $2="m68k"
1845     ;;
1846   mipseb*)
1847     $2="mipseb"
1848     ;;
1849   mipsel*)
1850     $2="mipsel"
1851     ;;
1852   mips*)
1853     $2="mips"
1854     ;;
1855   powerpc64le*)
1856     $2="powerpc64le"
1857     ;;
1858   powerpc64*)
1859     $2="powerpc64"
1860     ;;
1861   powerpc*)
1862     $2="powerpc"
1863     ;;
1864   rs6000)
1865     $2="rs6000"
1866     ;;
1867   s390x*)
1868     $2="s390x"
1869     ;;
1870   s390*)
1871     $2="s390"
1872     ;;
1873   sh4)
1874     $2="sh4"
1875     ;;
1876   sparc64*)
1877     $2="sparc64"
1878     ;;
1879   sparc*)
1880     $2="sparc"
1881     ;;
1882   vax)
1883     $2="vax"
1884     ;;
1885   x86_64|amd64)
1886     $2="x86_64"
1887     ;;
1888   *)
1889     echo "Unknown CPU $1"
1890     exit 1
1891     ;;
1892   esac
1893 ])
1894
1895 # GHC_LLVM_TARGET(target_cpu, target_vendor, target_os, llvm_target_var)
1896 # --------------------------------
1897 # converts the canonicalized target into someting llvm can understand
1898 AC_DEFUN([GHC_LLVM_TARGET], [
1899   case "$2-$3" in
1900     hardfloat-*eabi)
1901       llvm_target_vendor="unknown"
1902       llvm_target_os="$3""hf"
1903       ;;
1904     *-mingw32|*-mingw64|*-msys)
1905       llvm_target_vendor="unknown"
1906       llvm_target_os="windows"
1907       ;;
1908     # retain any android and gnueabi linux flavours
1909     # for the LLVM Target. Otherwise these would be
1910     # turned into just `-linux` and fail to be found
1911     # in the `llvm-targets` file.
1912     *-android*|*-gnueabi*)
1913       GHC_CONVERT_VENDOR([$2],[llvm_target_vendor])
1914       llvm_target_os="$3"
1915       ;;
1916     *)
1917       GHC_CONVERT_VENDOR([$2],[llvm_target_vendor])
1918       GHC_CONVERT_OS([$3],[$1],[llvm_target_os])
1919       ;;
1920   esac
1921   $4="$1-$llvm_target_vendor-$llvm_target_os"
1922 ])
1923
1924
1925 # GHC_CONVERT_VENDOR(vendor, target_var)
1926 # --------------------------------
1927 # converts vendor from gnu to ghc naming, and assigns the result to $target_var
1928 AC_DEFUN([GHC_CONVERT_VENDOR],[
1929   case "$1" in
1930   pc|gentoo|w64) # like i686-pc-linux-gnu, i686-gentoo-freebsd8, x86_64-w64-mingw32
1931     $2="unknown"
1932     ;;
1933   softfloat) # like armv5tel-softfloat-linux-gnueabi
1934     $2="unknown"
1935     ;;
1936   hardfloat) # like armv7a-hardfloat-linux-gnueabi
1937     $2="unknown"
1938     ;;
1939   *)
1940     #pass thru by default
1941     $2="$1"
1942     ;;
1943   esac
1944 ])
1945
1946 # GHC_CONVERT_OS(os, converted_cpu, target_var)
1947 # --------------------------------
1948 # converts os from gnu to ghc naming, and assigns the result to $target_var
1949 AC_DEFUN([GHC_CONVERT_OS],[
1950     case "$1" in
1951       # watchos and tvos are ios variants as of May 2017.
1952       ios|watchos|tvos)
1953         $3="ios"
1954         ;;
1955       linux-android*)
1956         $3="linux-android"
1957         ;;
1958       linux-*|linux)
1959         $3="linux"
1960         ;;
1961       # As far as I'm aware, none of these have relevant variants
1962       freebsd|netbsd|openbsd|dragonfly|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|haiku)
1963         $3="$1"
1964         ;;
1965       aix*) # e.g. powerpc-ibm-aix7.1.3.0
1966         $3="aix"
1967         ;;
1968       darwin*) # e.g. aarch64-apple-darwin14
1969         $3="darwin"
1970         ;;
1971       freebsd*) # like i686-gentoo-freebsd7
1972                 #      i686-gentoo-freebsd8
1973                 #      i686-gentoo-freebsd8.2
1974         $3="freebsd"
1975         ;;
1976       nto-qnx*)
1977         $3="nto-qnx"
1978         ;;
1979       *)
1980         echo "Unknown OS $1"
1981         exit 1
1982         ;;
1983       esac
1984 ])
1985
1986 # BOOTSTRAPPING_GHC_INFO_FIELD
1987 # --------------------------------
1988 # Set the variable $1 to the value of the ghc --info field $2.
1989 AC_DEFUN([BOOTSTRAPPING_GHC_INFO_FIELD],[
1990 $1=`"$WithGhc" --info | grep "^ ,(\"$2\"," | sed -e 's/.*","//' -e 's/")$//'`
1991 tmp=${$1#\$topdir/}
1992 if test "${$1}" != "$tmp"
1993 then
1994     topdir=`"$WithGhc" --print-libdir | sed 's#\\\\#/#g'`
1995     $1="$topdir/$tmp"
1996 fi
1997 AC_SUBST($1)
1998 ])
1999
2000 # LIBRARY_VERSION(lib, [dir])
2001 # --------------------------------
2002 # Gets the version number of a library.
2003 # If $1 is ghc-prim, then we define LIBRARY_ghc_prim_VERSION as 1.2.3
2004 # $2 points to the directory under libraries/
2005 AC_DEFUN([LIBRARY_VERSION],[
2006 dir=m4_default([$2],[$1])
2007 LIBRARY_[]translit([$1], [-], [_])[]_VERSION=`grep -i "^version:" libraries/${dir}/$1.cabal | sed "s/.* //"`
2008 AC_SUBST(LIBRARY_[]translit([$1], [-], [_])[]_VERSION)
2009 ])
2010
2011 # XCODE_VERSION()
2012 # --------------------------------
2013 # Gets the version number of XCode, if on a Mac
2014 AC_DEFUN([XCODE_VERSION],[
2015     if test "$TargetVendor_CPP" = "apple"
2016     then
2017         AC_MSG_CHECKING(XCode version)
2018         XCodeVersion=`xcodebuild -version | grep Xcode | sed "s/Xcode //"`
2019         # Old XCode versions don't actually give the XCode version
2020         if test "$XCodeVersion" = ""
2021         then
2022             AC_MSG_RESULT(not found (too old?))
2023             XCodeVersion1=0
2024             XCodeVersion2=0
2025         else
2026             AC_MSG_RESULT($XCodeVersion)
2027             XCodeVersion1=`echo "$XCodeVersion" | sed 's/\..*//'`
2028             changequote(, )dnl
2029             XCodeVersion2=`echo "$XCodeVersion" | sed 's/[^.]*\.\([^.]*\).*/\1/'`
2030             changequote([, ])dnl
2031             AC_MSG_NOTICE(XCode version component 1: $XCodeVersion1)
2032             AC_MSG_NOTICE(XCode version component 2: $XCodeVersion2)
2033         fi
2034     fi
2035 ])
2036
2037 # FIND_LLVM_PROG()
2038 # --------------------------------
2039 # Find where the llvm tools are. We have a special function to handle when they
2040 # are installed with a version suffix (e.g., llc-3.1).
2041 #
2042 # $1 = the variable to set
2043 # $2 = the command to look for
2044 # $3 = the version of the command to look for
2045 #
2046 AC_DEFUN([FIND_LLVM_PROG],[
2047     # Test for program with and without version name.
2048     AC_CHECK_TOOLS([$1], [$2-$3 $2], [:])
2049     if test "$$1" != ":"; then
2050         AC_MSG_CHECKING([$$1 is version $3])
2051         if test `$$1 --version | grep -c "version $3"` -gt 0 ; then
2052             AC_MSG_RESULT(yes)
2053         else
2054             AC_MSG_RESULT(no)
2055             $1=""
2056         fi
2057     else
2058         $1=""
2059     fi
2060 ])
2061
2062 # CHECK_LD_COPY_BUG()
2063 # -------------------
2064 # Check for binutils bug #16177 present in some versions of the bfd ld
2065 # implementation affecting ARM relocations.
2066 # https://sourceware.org/bugzilla/show_bug.cgi?id=16177
2067 #
2068 # $1 = the platform
2069 #
2070 AC_DEFUN([CHECK_LD_COPY_BUG],[
2071     case $1 in
2072       arm*linux*)
2073         AC_CHECK_TARGET_TOOL([READELF], [readelf])
2074         AC_CHECK_TARGET_TOOL([AS], [as])
2075         AC_MSG_CHECKING([for ld bug 16177])
2076         cat >actest.s <<-EOF
2077           .globl _start
2078           .p2align 4
2079         _start:
2080           bkpt
2081
2082         .data
2083           .globl data_object
2084         object_reference:
2085           .long data_object
2086           .size object_reference, 4
2087 EOF
2088
2089         cat >aclib.s <<-EOF
2090           .data
2091           .globl data_object
2092           .type data_object, %object
2093           .size data_object, 4
2094         data_object:
2095             .long 123
2096 EOF
2097
2098         $AS -o aclib.o aclib.s
2099         $LD -shared -o aclib.so aclib.o
2100
2101         $AS -o actest.o actest.s
2102         $LD -o actest actest.o aclib.so
2103
2104         if $READELF -r actest | grep R_ARM_COPY > /dev/null; then
2105             AC_MSG_RESULT([affected])
2106             AC_MSG_ERROR(
2107               [Your linker is affected by binutils #16177, which
2108                critically breaks linkage of GHC objects. Please either upgrade
2109                binutils or supply a different linker with the LD environment
2110                variable.])
2111         else
2112             AC_MSG_RESULT([unaffected])
2113         fi
2114
2115         rm -f aclib.s aclib.o aclib.so actest.s actest.o actest
2116         ;;
2117       *)
2118         ;;
2119     esac
2120 ])
2121
2122 # FIND_GHC_BOOTSTRAP_PROG()
2123 # --------------------------------
2124 # Parse the bootstrap GHC's compier settings file for the location of things
2125 # like the `llc` and `opt` commands.
2126 #
2127 # $1 = the variable to set
2128 # $2 = The bootstrap compiler.
2129 # $3 = The string to grep for to find the correct line.
2130 #
2131 AC_DEFUN([FIND_GHC_BOOTSTRAP_PROG],[
2132     BootstrapTmpCmd=`grep $3 $($2 --print-libdir)/settings 2>/dev/null | sed 's/.*", "//;s/".*//'`
2133     if test -n "$BootstrapTmpCmd" && test `basename $BootstrapTmpCmd` = $BootstrapTmpCmd ; then
2134         AC_PATH_PROG([$1], [$BootstrapTmpCmd], "")
2135     else
2136         $1=$BootstrapTmpCmd
2137     fi
2138 ])
2139
2140
2141 AC_DEFUN([MAYBE_OVERRIDE_STAGE0],[
2142   if test ! -z "$With_$1" -a "$CrossCompiling" != "YES"; then
2143       AC_MSG_NOTICE([Not cross-compiling, so --with-$1 also sets $2])
2144       $2=$With_$1
2145   fi
2146 ])
2147
2148
2149 # FP_CPP_CMD_WITH_ARGS()
2150 # ----------------------
2151 # sets CPP command and its arguments
2152 #
2153 # $1 = the variable to set to CPP command
2154 # $2 = the variable to set to CPP command arguments
2155
2156 AC_DEFUN([FP_CPP_CMD_WITH_ARGS],[
2157 dnl ** what cpp to use?
2158 dnl --------------------------------------------------------------
2159 AC_ARG_WITH(hs-cpp,
2160 [AC_HELP_STRING([--with-hs-cpp=ARG],
2161       [Path to the (C) preprocessor for Haskell files [default=autodetect]])],
2162 [
2163     if test "$HostOS" = "mingw32"
2164     then
2165         AC_MSG_WARN([Request to use $withval will be ignored])
2166     else
2167         HS_CPP_CMD=$withval
2168     fi
2169 ],
2170 [
2171
2172     # We can't use $CPP here, since HS_CPP_CMD is expected to be a single
2173     # command (no flags), and AC_PROG_CPP defines CPP as "/usr/bin/gcc -E".
2174     HS_CPP_CMD=$CC
2175
2176     SOLARIS_GCC_CPP_BROKEN=NO
2177     SOLARIS_FOUND_GOOD_CPP=NO
2178     case $host in
2179         i386-*-solaris2)
2180         GCC_MAJOR_MINOR=`$CC --version|grep "gcc (GCC)"|cut -d ' ' -f 3-3|cut -d '.' -f 1-2`
2181         if test "$GCC_MAJOR_MINOR" != "3.4"; then
2182           # this is not 3.4.x release so with broken CPP
2183           SOLARIS_GCC_CPP_BROKEN=YES
2184         fi
2185         ;;
2186     esac
2187
2188     if test "$SOLARIS_GCC_CPP_BROKEN" = "YES"; then
2189       # let's try to find if GNU C 3.4.x is installed
2190       if test -x /usr/sfw/bin/gcc; then
2191         # something executable is in expected path so let's
2192         # see if it's really GNU C
2193         NEW_GCC_MAJOR_MINOR=`/usr/sfw/bin/gcc --version|grep "gcc (GCC)"|cut -d ' ' -f 3-3|cut -d '.' -f 1-2`
2194         if test "$NEW_GCC_MAJOR_MINOR" = "3.4"; then
2195           # this is GNU C 3.4.x which provides non-broken CPP on Solaris
2196           # let's use it as CPP then.
2197           HS_CPP_CMD=/usr/sfw/bin/gcc
2198           SOLARIS_FOUND_GOOD_CPP=YES
2199         fi
2200       fi
2201       if test "$SOLARIS_FOUND_GOOD_CPP" = "NO"; then
2202         AC_MSG_WARN([Your GNU C provides broken CPP and you do not have GNU C 3.4.x installed.])
2203         AC_MSG_WARN([Please install GNU C 3.4.x to solve this issue. It will be used as CPP only.])
2204       fi
2205     fi
2206 ]
2207 )
2208
2209
2210
2211 dnl ** what cpp flags to use?
2212 dnl -----------------------------------------------------------
2213 AC_ARG_WITH(hs-cpp-flags,
2214   [AC_HELP_STRING([--with-hs-cpp-flags=ARG],
2215       [Flags to the (C) preprocessor for Haskell files [default=autodetect]])],
2216   [
2217       if test "$HostOS" = "mingw32"
2218       then
2219           AC_MSG_WARN([Request to use $withval will be ignored])
2220       else
2221           HS_CPP_ARGS=$withval
2222       fi
2223   ],
2224 [
2225   $HS_CPP_CMD -x c /dev/null -dM -E > conftest.txt 2>&1
2226   if grep "__clang__" conftest.txt >/dev/null 2>&1; then
2227     HS_CPP_ARGS="-E -undef -traditional -Wno-invalid-pp-token -Wno-unicode -Wno-trigraphs"
2228   else
2229       $HS_CPP_CMD  -v > conftest.txt 2>&1
2230       if  grep "gcc" conftest.txt >/dev/null 2>&1; then
2231           HS_CPP_ARGS="-E -undef -traditional"
2232         else
2233           $HS_CPP_CMD  --version > conftest.txt 2>&1
2234           if grep "cpphs" conftest.txt >/dev/null 2>&1; then
2235             HS_CPP_ARGS="--cpp -traditional"
2236           else
2237             AC_MSG_WARN([configure can't recognize your CPP program, you may need to set --with-hs-cpp-flags=FLAGS explicitly])
2238             HS_CPP_ARGS=""
2239           fi
2240       fi
2241   fi
2242   ]
2243 )
2244
2245 $1=$HS_CPP_CMD
2246 $2=$HS_CPP_ARGS
2247
2248 ])
2249
2250 # FP_BFD_SUPPORT()
2251 # ----------------------
2252 # whether to use libbfd for debugging RTS
2253 AC_DEFUN([FP_BFD_SUPPORT], [
2254     AC_ARG_ENABLE(bfd-debug,
2255         [AC_HELP_STRING([--enable-bfd-debug],
2256               [Enable symbol resolution for -debug rts ('+RTS -Di') via binutils' libbfd [default=no]])],
2257         [
2258             # don't pollute general LIBS environment
2259             save_LIBS="$LIBS"
2260             AC_CHECK_HEADERS([bfd.h])
2261             dnl ** check whether this machine has BFD and libiberty installed (used for debugging)
2262             dnl    the order of these tests matters: bfd needs libiberty
2263             AC_CHECK_LIB(iberty, xmalloc)
2264             dnl 'bfd_init' is a rare non-macro in libbfd
2265             AC_CHECK_LIB(bfd,    bfd_init)
2266
2267             AC_TRY_LINK([#include <bfd.h>],
2268                         [
2269                                 /* mimic our rts/Printer.c */
2270                                 bfd* abfd;
2271                                 const char * name;
2272                                 char **matching;
2273
2274                                 name = "some.executable";
2275                                 bfd_init();
2276                                 abfd = bfd_openr(name, "default");
2277                                 bfd_check_format_matches (abfd, bfd_object, &matching);
2278                                 {
2279                                     long storage_needed;
2280                                     storage_needed = bfd_get_symtab_upper_bound (abfd);
2281                                 }
2282                                 {
2283                                     asymbol **symbol_table;
2284                                     long number_of_symbols;
2285                                     symbol_info info;
2286
2287                                     number_of_symbols = bfd_canonicalize_symtab (abfd, symbol_table);
2288                                     bfd_get_symbol_info(abfd,symbol_table[0],&info);
2289                                 }
2290                         ],
2291                         [],dnl bfd seems to work
2292                         [AC_MSG_ERROR([can't use 'bfd' library])])
2293             LIBS="$save_LIBS"
2294         ]
2295     )
2296 ])
2297
2298
2299 # FP_CC_LINKER_FLAG_TRY()
2300 # --------------------
2301 # Try a particular linker to see whether we can use it. In particular, determine
2302 # whether we can convince gcc to use it via a -fuse-ld=... flag.
2303 #
2304 # $1 = the name of the linker to try
2305 # $2 = the variable to set with the appropriate GHC flag if the linker is
2306 # found to be usable
2307 AC_DEFUN([FP_CC_LINKER_FLAG_TRY], [
2308     AC_MSG_CHECKING([whether C compiler supports -fuse-ld=$1])
2309     echo 'int main(void) {return 0;}' > conftest.c
2310     if $CC -o conftest.o -fuse-ld=$1 conftest.c > /dev/null 2>&1
2311     then
2312         $2="-fuse-ld=$1"
2313         AC_MSG_RESULT([yes])
2314     else
2315         AC_MSG_RESULT([no])
2316     fi
2317     rm -f conftest.c conftest.o
2318 ])
2319
2320 # FIND_LD
2321 # ---------
2322 # Find the version of `ld` to use and figure out how to get gcc to use it for
2323 # linking (if --enable-ld-override is enabled). This is used in both in the top
2324 # level configure.ac and in distrib/configure.ac.in.
2325 #
2326 # $1 = the platform
2327 # $2 = the variable to set with GHC options to configure gcc to use the chosen linker
2328 #
2329 AC_DEFUN([FIND_LD],[
2330     AC_ARG_ENABLE(ld-override,
2331       [AC_HELP_STRING([--disable-ld-override],
2332         [Prevent GHC from overriding the default linker used by gcc. If ld-override is enabled GHC will try to tell gcc to use whichever linker is selected by the LD environment variable. [default=override enabled]])],
2333       [],
2334       [enable_ld_override=yes])
2335
2336     find_ld() {
2337         # Make sure the user didn't specify LD manually.
2338         if test "z$LD" != "z"; then
2339             AC_CHECK_TARGET_TOOL([LD], [ld])
2340             return
2341         fi
2342
2343         # Manually iterate over possible names since we want to ensure that, e.g.,
2344         # if ld.lld is installed but gcc doesn't support -fuse-ld=lld, that we
2345         # then still try ld.gold and -fuse-ld=gold.
2346         for possible_ld in ld.lld ld.gold ld; do
2347             TmpLd="" # In case the user set LD
2348             AC_CHECK_TARGET_TOOL([TmpLd], [$possible_ld])
2349             if test "x$TmpLd" = "x"; then continue; fi
2350
2351             out=`$TmpLd --version`
2352             case $out in
2353               "GNU ld"*)   FP_CC_LINKER_FLAG_TRY(bfd, $2) ;;
2354               "GNU gold"*) FP_CC_LINKER_FLAG_TRY(gold, $2) ;;
2355               "LLD"*)      FP_CC_LINKER_FLAG_TRY(lld, $2) ;;
2356               *) AC_MSG_NOTICE([unknown linker version $out]) ;;
2357             esac
2358             if test "z$$2" = "z"; then
2359                 AC_MSG_NOTICE([unable to convince '$CC' to use linker '$TmpLd'])
2360                 # a terrible hack to prevent autoconf from caching the previous
2361                 # AC_CHECK_TARGET_TOOL result since next time we'll be looking
2362                 # for another ld variant.
2363                 $as_unset ac_cv_prog_ac_ct_TmpLd
2364             else
2365                 LD="$TmpLd"
2366                 return
2367             fi
2368         done
2369
2370         # Fallback
2371         AC_CHECK_TARGET_TOOL([LD], [ld])
2372     }
2373
2374     if test "x$enable_ld_override" = "xyes"; then
2375         find_ld
2376     else
2377         AC_CHECK_TARGET_TOOL([LD], [ld])
2378     fi
2379
2380     CHECK_LD_COPY_BUG([$1])
2381 ])
2382
2383 # LocalWords:  fi