Have validate take into account stat test failures too.
[ghc.git] / libraries / base / GHC / ST.lhs
1 \begin{code}
2 {-# LANGUAGE Unsafe #-}
3 {-# LANGUAGE NoImplicitPrelude, MagicHash, UnboxedTuples, RankNTypes #-}
4 {-# OPTIONS_HADDOCK hide #-}
5 -----------------------------------------------------------------------------
6 -- |
7 -- Module      :  GHC.ST
8 -- Copyright   :  (c) The University of Glasgow, 1992-2002
9 -- License     :  see libraries/base/LICENSE
10 -- 
11 -- Maintainer  :  cvs-ghc@haskell.org
12 -- Stability   :  internal
13 -- Portability :  non-portable (GHC Extensions)
14 --
15 -- The 'ST' Monad.
16 --
17 -----------------------------------------------------------------------------
18
19 module GHC.ST (
20         ST(..), STret(..), STRep,
21         fixST, runST, runSTRep,
22
23         -- * Unsafe functions
24         liftST, unsafeInterleaveST
25     ) where
26
27 import GHC.Base
28 import GHC.Show
29
30 default ()
31 \end{code}
32
33 %*********************************************************
34 %*                                                      *
35 \subsection{The @ST@ monad}
36 %*                                                      *
37 %*********************************************************
38
39 The state-transformer monad proper.  By default the monad is strict;
40 too many people got bitten by space leaks when it was lazy.
41
42 \begin{code}
43 -- | The strict state-transformer monad.
44 -- A computation of type @'ST' s a@ transforms an internal state indexed
45 -- by @s@, and returns a value of type @a@.
46 -- The @s@ parameter is either
47 --
48 -- * an uninstantiated type variable (inside invocations of 'runST'), or
49 --
50 -- * 'RealWorld' (inside invocations of 'Control.Monad.ST.stToIO').
51 --
52 -- It serves to keep the internal states of different invocations
53 -- of 'runST' separate from each other and from invocations of
54 -- 'Control.Monad.ST.stToIO'.
55 --
56 -- The '>>=' and '>>' operations are strict in the state (though not in
57 -- values stored in the state).  For example,
58 --
59 -- @'runST' (writeSTRef _|_ v >>= f) = _|_@
60 newtype ST s a = ST (STRep s a)
61 type STRep s a = State# s -> (# State# s, a #)
62
63 instance Functor (ST s) where
64     fmap f (ST m) = ST $ \ s ->
65       case (m s) of { (# new_s, r #) ->
66       (# new_s, f r #) }
67
68 instance Applicative (ST s) where
69     pure = return
70     (<*>) = ap
71
72 instance Monad (ST s) where
73     {-# INLINE return #-}
74     {-# INLINE (>>)   #-}
75     {-# INLINE (>>=)  #-}
76     return x = ST (\ s -> (# s, x #))
77     m >> k   = m >>= \ _ -> k
78
79     (ST m) >>= k
80       = ST (\ s ->
81         case (m s) of { (# new_s, r #) ->
82         case (k r) of { ST k2 ->
83         (k2 new_s) }})
84
85 data STret s a = STret (State# s) a
86
87 -- liftST is useful when we want a lifted result from an ST computation.  See
88 -- fixST below.
89 liftST :: ST s a -> State# s -> STret s a
90 liftST (ST m) = \s -> case m s of (# s', r #) -> STret s' r
91
92 {-# NOINLINE unsafeInterleaveST #-}
93 unsafeInterleaveST :: ST s a -> ST s a
94 unsafeInterleaveST (ST m) = ST ( \ s ->
95     let
96         r = case m s of (# _, res #) -> res
97     in
98     (# s, r #)
99   )
100
101 -- | Allow the result of a state transformer computation to be used (lazily)
102 -- inside the computation.
103 -- Note that if @f@ is strict, @'fixST' f = _|_@.
104 fixST :: (a -> ST s a) -> ST s a
105 fixST k = ST $ \ s ->
106     let ans       = liftST (k r) s
107         STret _ r = ans
108     in
109     case ans of STret s' x -> (# s', x #)
110
111 instance  Show (ST s a)  where
112     showsPrec _ _  = showString "<<ST action>>"
113     showList       = showList__ (showsPrec 0)
114 \end{code}
115
116 Definition of runST
117 ~~~~~~~~~~~~~~~~~~~
118
119 SLPJ 95/04: Why @runST@ must not have an unfolding; consider:
120 \begin{verbatim}
121 f x =
122   runST ( \ s -> let
123                     (a, s')  = newArray# 100 [] s
124                     (_, s'') = fill_in_array_or_something a x s'
125                   in
126                   freezeArray# a s'' )
127 \end{verbatim}
128 If we inline @runST@, we'll get:
129 \begin{verbatim}
130 f x = let
131         (a, s')  = newArray# 100 [] realWorld#{-NB-}
132         (_, s'') = fill_in_array_or_something a x s'
133       in
134       freezeArray# a s''
135 \end{verbatim}
136 And now the @newArray#@ binding can be floated to become a CAF, which
137 is totally and utterly wrong:
138 \begin{verbatim}
139 f = let
140     (a, s')  = newArray# 100 [] realWorld#{-NB-} -- YIKES!!!
141     in
142     \ x ->
143         let (_, s'') = fill_in_array_or_something a x s' in
144         freezeArray# a s''
145 \end{verbatim}
146 All calls to @f@ will share a {\em single} array!  End SLPJ 95/04.
147
148 \begin{code}
149 {-# INLINE runST #-}
150 -- The INLINE prevents runSTRep getting inlined in *this* module
151 -- so that it is still visible when runST is inlined in an importing
152 -- module.  Regrettably delicate.  runST is behaving like a wrapper.
153
154 -- | Return the value computed by a state transformer computation.
155 -- The @forall@ ensures that the internal state used by the 'ST'
156 -- computation is inaccessible to the rest of the program.
157 runST :: (forall s. ST s a) -> a
158 runST st = runSTRep (case st of { ST st_rep -> st_rep })
159
160 -- I'm only letting runSTRep be inlined right at the end, in particular *after* full laziness
161 -- That's what the "INLINE [0]" says.
162 --              SLPJ Apr 99
163 -- {-# INLINE [0] runSTRep #-}
164
165 -- SDM: further to the above, inline phase 0 is run *before*
166 -- full-laziness at the moment, which means that the above comment is
167 -- invalid.  Inlining runSTRep doesn't make a huge amount of
168 -- difference, anyway.  Hence:
169
170 {-# NOINLINE runSTRep #-}
171 runSTRep :: (forall s. STRep s a) -> a
172 runSTRep st_rep = case st_rep realWorld# of
173                         (# _, r #) -> r
174 \end{code}