Minor doc addition as requested in #12774.
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.1], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl this makes sure `./configure --target=<cross-compile-target>`
37 dnl works as expected, since we're slightly modifying how Autoconf
38 dnl interprets build/host/target and how this interacts with $CC tests
39 test -n "$target_alias" && ac_tool_prefix=$target_alias-
40
41 dnl ----------------------------------------------------------
42 dnl ** Find unixy sort and find commands,
43 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
44
45 dnl ** Find find command (for Win32's benefit)
46 FP_PROG_FIND
47 FP_PROG_SORT
48
49 dnl ----------------------------------------------------------
50 FP_SETUP_PROJECT_VERSION
51
52 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
53 AC_SUBST([release], [1])
54
55 # First off, a distrib sanity check..
56 AC_CONFIG_SRCDIR([mk/config.mk.in])
57
58 dnl * We require autoconf version 2.60
59 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
60 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
61 dnl Using autoconf 2.59 started to give nonsense like this
62 dnl  #define SIZEOF_CHAR 0
63 dnl recently.
64 AC_PREREQ([2.60])
65
66 # -------------------------------------------------------------------------
67 # Prepare to generate the following header files
68 #
69 #
70 AC_CONFIG_HEADER(mk/config.h)
71
72 # No, semi-sadly, we don't do `--srcdir'...
73 if test x"$srcdir" != 'x.' ; then
74     echo "This configuration does not support the \`--srcdir' option.."
75     exit 1
76 fi
77
78 dnl --------------------------------------------------------------
79 dnl * Project specific configuration options
80 dnl --------------------------------------------------------------
81 dnl What follows is a bunch of options that can either be configured
82 dnl through command line options to the configure script or by
83 dnl supplying defns in the build tree's mk/build.mk. Having the option to
84 dnl use either is considered a Feature.
85
86 dnl ** What command to use to compile compiler sources ?
87 dnl --------------------------------------------------------------
88
89 AC_ARG_WITH([ghc],
90 [AC_HELP_STRING([--with-ghc=ARG],
91   [Use ARG as the path to GHC  [default=autodetect]])],
92   [WithGhc="$withval"],
93   [if test "$GHC" = ""; then
94     AC_PATH_PROG([GHC], [ghc])
95   fi
96   WithGhc="$GHC"])
97
98 dnl ** Tell the make system which OS we are using
99 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
100 AC_SUBST(OSTYPE)
101
102 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
103 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
104                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
105         EnableBootstrapWithDevelSnaphost=YES,
106         EnableBootstrapWithDevelSnaphost=NO
107 )
108
109 AC_ARG_ENABLE(tarballs-autodownload,
110 [AC_HELP_STRING([--enable-tarballs-autodownload],
111                 [Automatically download Windows distribution binaries if needed.])],
112         TarballsAutodownload=YES,
113         TarballsAutodownload=NO
114 )
115
116 dnl CC_STAGE0 is like the "previous" variable CC (inherited by CC_STAGE[123])
117 dnl but instead used by stage0 for bootstrapping stage1
118 AC_ARG_VAR(CC_STAGE0, [C compiler command (bootstrap)])
119
120 if test "$WithGhc" != ""; then
121   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
122
123   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
124      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
125   fi
126
127   AC_SUBST(GhcVersion)dnl
128   AC_SUBST(GhcMajVersion)dnl
129   AC_SUBST(GhcMinVersion)dnl
130   AC_SUBST(GhcPatchLevel)dnl
131   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
132   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
133
134   dnl infer CC_STAGE0 from `ghc --info` unless explicitly set by user
135   if test -z "$CC_STAGE0"; then
136     BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
137   fi
138
139   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
140   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
141   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
142   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
143 fi
144
145 dnl ** Must have GHC to build GHC
146 if test "$WithGhc" = ""
147 then
148     AC_MSG_ERROR([GHC is required.])
149 fi
150 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.10],
151     [AC_MSG_ERROR([GHC version 7.10 or later is required to compile GHC.])])
152
153 if test `expr $GhcMinVersion % 2` = "1"
154 then
155     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
156     then
157         AC_MSG_ERROR([
158      $WithGhc is a development snapshot of GHC, version $GhcVersion.
159      Bootstrapping using this version of GHC is not supported, and may not
160      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
161      or --with-ghc to specify a different GHC to use.])
162     fi
163 fi
164
165 GHC_PACKAGE_DB_FLAG=package-db
166 AC_SUBST(GHC_PACKAGE_DB_FLAG)
167
168 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.11],
169                     SUPPORTS_THIS_UNIT_ID=NO,
170                     SUPPORTS_THIS_UNIT_ID=YES)
171 AC_SUBST(SUPPORTS_THIS_UNIT_ID)
172
173 # GHC is passed to Cabal, so we need a native path
174 if test "${WithGhc}" != ""
175 then
176     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
177
178     if test "$ghc_host_os" = "mingw32"
179     then
180         # Canonicalise to <drive>:/path/to/ghc
181         WithGhc=`cygpath -m "${WithGhc}"`
182
183         echo "GHC path canonicalised to: ${WithGhc}"
184     fi
185 fi
186 AC_SUBST([WithGhc])
187
188 dnl ** Without optimization some INLINE trickery fails for GHCi
189 SRC_CC_OPTS="-O"
190
191 dnl--------------------------------------------------------------------
192 dnl * Choose host(/target/build) platform
193 dnl--------------------------------------------------------------------
194 dnl If we aren't explicitly told what values to use with configure flags,
195 dnl we ask the bootstrapping compiler what platform it is for
196
197 if test "${WithGhc}" != ""
198 then
199         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
200         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
201         if test "$bootstrap_host" != "$bootstrap_target"
202         then
203                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
204         fi
205 fi
206
207 # We have to run these unconditionally, but we may discard their
208 # results in the following code
209 AC_CANONICAL_BUILD
210 AC_CANONICAL_HOST
211 AC_CANONICAL_TARGET
212
213 FPTOOLS_SET_PLATFORM_VARS
214
215 # Verify that the installed (bootstrap) GHC is capable of generating
216 # code for the requested build platform.
217 if test "$BuildPlatform" != "$bootstrap_target"
218 then
219     echo "This GHC (${WithGhc}) does not generate code for the build platform"
220     echo "   GHC target platform    : $bootstrap_target"
221     echo "   Desired build platform : $BuildPlatform"
222     exit 1
223 fi
224
225 # Testing if we shall enable shared libs support on Solaris.
226 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
227
228 SOLARIS_BROKEN_SHLD=NO
229
230 case $host in
231      i386-*-solaris2)
232      # here we go with the test
233      MINOR=`uname -r|cut -d '.' -f 2-`
234      if test "$MINOR" -lt "11"; then
235          SOLARIS_BROKEN_SHLD=YES
236      fi
237      ;;
238 esac
239
240 AC_SUBST(SOLARIS_BROKEN_SHLD)
241
242 dnl ** Do an unregisterised build?
243 dnl --------------------------------------------------------------
244 case "$HostArch" in
245     i386|x86_64|powerpc|powerpc64|powerpc64le|arm)
246         UnregisterisedDefault=NO
247         ;;
248     *)
249         UnregisterisedDefault=YES
250         ;;
251 esac
252 AC_ARG_ENABLE(unregisterised,
253 [AC_HELP_STRING([--enable-unregisterised],
254 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
255 [ if test x"$enableval" = x"yes"; then
256         Unregisterised=YES
257   else
258         Unregisterised=NO
259   fi
260 ],
261 [Unregisterised="$UnregisterisedDefault"]
262 )
263 AC_SUBST(Unregisterised)
264
265 # Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
266 FP_FIND_ROOT
267
268 fail() {
269     echo >&2
270     echo "$1" >&2
271     exit 1
272 }
273
274
275 if test "$HostOS" = "mingw32"
276 then
277     # Find the mingw-w64 7z file to extract.
278     # NB. If you update the tarballs to a new version of gcc, don't
279     # forget to tweak the paths in driver/gcc/gcc.c.
280     if test "$HostArch" = "i386"
281     then
282         mingw_arch="i686"
283         tarball_dest_dir="mingw-w64/x86"
284         tarball_mingw_dir="mingw32"
285     else
286         mingw_arch="x86_64"
287         tarball_dest_dir="mingw-w64/x86_64"
288         tarball_mingw_dir="mingw64"
289     fi
290 fi
291
292 set_up_tarballs() {
293     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
294     local action
295     if test "$TarballsAutodownload" = "NO"
296     then
297         action="verify"
298     else
299         action="download"
300     fi
301     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
302     case $? in
303         0)
304            rm missing-win32-tarballs
305            ;;
306         2)
307            echo
308            echo "Error:"
309            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
310            echo
311            echo "  * run configure with the --enable-tarballs-autodownload option"
312            echo
313            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
314            echo
315            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
316            echo "    them in the ghc-tarballs directory."
317            echo
318            exit 1
319            ;;
320         *)
321            echo
322            echo "Error fetching msys2 tarballs; see errors above."
323            exit 1
324            ;;
325     esac
326
327     # Extract all the tarballs in one go
328     if ! test -d inplace/mingw
329     then
330         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
331         rm -rf inplace/mingw
332         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
333         ( cd inplace &&
334         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
335         rm ".MTREE" &&
336         rm ".PKGINFO" &&
337         cd .. ) || fail "Error: Could not extract Windows toolchains."
338
339         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
340         touch inplace/mingw
341
342         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
343         # make a wrapper around it to give it the proper paths
344         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
345         PATH=`pwd`/inplace/mingw/bin:$PATH
346         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
347
348         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
349     fi
350 }
351
352 if test "$HostOS" = "mingw32"
353 then
354     test -d inplace || mkdir inplace
355
356     # NB. Download and extract the MingW-w64 distribution if required
357     set_up_tarballs
358
359     mingwbin="$hardtop/inplace/mingw/bin/"
360     CC="${mingwbin}gcc.exe"
361     LD="${mingwbin}ld.exe"
362     NM="${mingwbin}nm.exe"
363     RANLIB="${mingwbin}ranlib.exe"
364     OBJDUMP="${mingwbin}objdump.exe"
365     Windres="${mingwbin}windres.exe"
366     DllWrap="${mingwbin}dllwrap.exe"
367     fp_prog_ar="${mingwbin}ar.exe"
368
369     # NB. Download the perl binaries if required
370     if ! test -d inplace/perl ||
371          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
372     then
373         AC_MSG_NOTICE([Making in-tree perl tree])
374         rm -rf inplace/perl
375         mkdir inplace/perl
376         (
377             cd inplace/perl &&
378             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
379         )
380         AC_MSG_NOTICE([In-tree perl tree created])
381     fi
382 fi
383
384 FP_ICONV
385 FP_GMP
386 FP_CURSES
387
388 XCODE_VERSION()
389
390 SplitObjsBroken=NO
391 if test "$TargetOS_CPP" = "darwin"
392 then
393     # Split objects is broken (#4013) with XCode < 3.2
394     if test "$XCodeVersion1" -lt 3
395     then
396         SplitObjsBroken=YES
397     else
398         if test "$XCodeVersion1" -eq 3
399         then
400             if test "$XCodeVersion2" -lt 2
401             then
402                 SplitObjsBroken=YES
403             fi
404         fi
405     fi
406 fi
407 AC_SUBST([SplitObjsBroken])
408
409 dnl ** Building a cross compiler?
410 dnl --------------------------------------------------------------
411 CrossCompiling=NO
412 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
413 if test "$TargetPlatform" != "$HostPlatform" ; then
414     CrossCompiling=YES
415     cross_compiling=yes   # This tells configure that it can accept just 'target',
416                           # otherwise you get
417                           #   configure: error: cannot run C compiled programs.
418                           #   If you meant to cross compile, use `--host'.
419 fi
420 if test "$BuildPlatform" != "$HostPlatform" ; then
421    AC_MSG_ERROR([
422 You've selected:
423
424   BUILD:  $BuildPlatform   (the architecture we're building on)
425   HOST:   $HostPlatform    (the architecture the compiler we're building will execute on)
426   TARGET: $TargetPlatform  (the architecture the compiler we're building will produce code for)
427
428 BUILD must equal HOST; that is, we do not support building GHC itself
429 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
430 1 will be a cross-compiler, and stage 2 will be the cross-compiled
431 GHC.
432 ])
433 fi
434 if test "$CrossCompiling" = "YES"
435 then
436   CrossCompilePrefix="${target}-"
437 else
438   CrossCompilePrefix=""
439 fi
440 TargetPlatformFull="${TargetPlatform}"
441 AC_SUBST(CrossCompiling)
442 AC_SUBST(CrossCompilePrefix)
443 AC_SUBST(TargetPlatformFull)
444
445 dnl ** Which gcc to use?
446 dnl --------------------------------------------------------------
447
448 AC_ARG_WITH([gcc],
449         AS_HELP_STRING([--with-gcc=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
450         AC_MSG_ERROR([--with-gcc=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
451
452 AC_ARG_WITH([clang],
453         AS_HELP_STRING([--with-clang=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
454         AC_MSG_ERROR([--with-clang=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
455
456 dnl detect compiler (prefer gcc over clang) and set $CC (unless CC already set),
457 dnl later CC is copied to CC_STAGE{1,2,3}
458 AC_PROG_CC([gcc clang])
459
460 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
461
462 dnl make extensions visible to allow feature-tests to detect them lateron
463 AC_USE_SYSTEM_EXTENSIONS
464
465 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
466 AC_PROG_CPP
467
468 # --with-hs-cpp/--with-hs-cpp-flags
469 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
470 AC_SUBST([HaskellCPPCmd])
471 AC_SUBST([HaskellCPPArgs])
472
473 FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
474 FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
475 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
476 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
477
478 dnl ** Which ld to use?
479 dnl --------------------------------------------------------------
480 FIND_LD([LdCmd])
481 AC_SUBST([LdCmd])
482
483 dnl ** Which nm to use?
484 dnl --------------------------------------------------------------
485 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
486
487 if test "$TargetOS_CPP" = "darwin"
488 then
489     AC_MSG_CHECKING(whether nm program is broken)
490     # Some versions of XCode ship a broken version of `nm`. Detect and work
491     # around this issue. See : https://ghc.haskell.org/trac/ghc/ticket/11744
492     nmver=$(${NM} --version | grep version | sed 's/ //g')
493     case "$nmver" in
494         LLVMversion7.3.0|LLVMversion7.3.1)
495             AC_MSG_RESULT(yes)
496             echo "The detected nm program is broken."
497             echo
498             echo "See: https://ghc.haskell.org/trac/ghc/ticket/11744"
499             echo
500             echo "Try re-running configure with:"
501             echo
502             echo '   ./configure --with-nm=$(xcrun --find nm-classic)'
503             echo
504             exit 1
505             ;;
506         *)
507             AC_MSG_RESULT(no)
508             ;;
509         esac
510 fi
511
512 NmCmd="$NM"
513 AC_SUBST([NmCmd])
514
515 dnl ** Which objdump to use?
516 dnl --------------------------------------------------------------
517 FP_ARG_WITH_PATH_GNU_PROG_OPTIONAL([OBJDUMP], [objdump], [objdump])
518 ObjdumpCmd="$OBJDUMP"
519 AC_SUBST([ObjdumpCmd])
520
521 dnl ** Which ar to use?
522 dnl --------------------------------------------------------------
523 FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
524 ArCmd="$AR"
525 fp_prog_ar="$AR"
526 AC_SUBST([ArCmd])
527
528 dnl ** Which ranlib to use?
529 dnl --------------------------------------------------------------
530 FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
531 RanlibCmd="$RANLIB"
532 RANLIB="$RanlibCmd"
533
534
535 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
536 case $HostOS_CPP in
537 cygwin32|mingw32)
538     dnl ** Which objdump to use?
539     dnl --------------------------------------------------------------
540     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
541     ObjdumpCmd="$OBJDUMP"
542     AC_SUBST([ObjdumpCmd])
543     ;;
544 esac
545
546 # Here is where we re-target which specific version of the LLVM
547 # tools we are looking for. In the past, GHC supported a number of
548 # versions of LLVM simultaneously, but that stopped working around
549 # 3.5/3.6 release of LLVM.
550 LlvmVersion=3.8
551 AC_SUBST([LlvmVersion])
552 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
553 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
554
555 dnl ** Which LLVM llc to use?
556 dnl --------------------------------------------------------------
557 FIND_LLVM_PROG([LLC], [llc], [llc], [$LlvmVersion])
558 LlcCmd="$LLC"
559 AC_SUBST([LlcCmd])
560
561 dnl ** Which LLVM opt to use?
562 dnl --------------------------------------------------------------
563 FIND_LLVM_PROG([OPT], [opt], [opt], [$LlvmVersion])
564 OptCmd="$OPT"
565 AC_SUBST([OptCmd])
566
567 dnl --------------------------------------------------------------
568 dnl End of configure script option section
569 dnl --------------------------------------------------------------
570
571
572 dnl --------------------------------------------------------------
573 dnl ** Can the unix package be built?
574 dnl --------------------------------------------------------------
575
576 if test "$TargetOS" = "mingw32"
577 then
578     GhcLibsWithUnix=NO
579 else
580     GhcLibsWithUnix=YES
581 fi
582 AC_SUBST([GhcLibsWithUnix])
583
584 dnl ** does #! work?
585 AC_SYS_INTERPRETER()
586
587 dnl ** look for `perl'
588 case $HostOS_CPP in
589 cygwin32|mingw32)
590     PerlCmd=$hardtop/inplace/perl/perl
591     ;;
592 *)
593     AC_PATH_PROG(PerlCmd,perl)
594     if test -z "$PerlCmd"
595     then
596         echo "You must install perl before you can continue"
597         echo "Perhaps it is already installed, but not in your PATH?"
598         exit 1
599     else
600         FPTOOLS_CHECK_PERL_VERSION
601     fi
602     ;;
603 esac
604
605 dnl ** look for GCC and find out which version
606 dnl     Figure out which C compiler to use.  Gcc is preferred.
607 dnl     If gcc, make sure it's at least 3.0
608 dnl
609 FP_GCC_VERSION
610
611 dnl ** look to see if we have a C compiler using an llvm back end.
612 dnl
613 FP_CC_LLVM_BACKEND
614
615 FP_PROG_LD_IS_GNU
616 FP_PROG_LD_BUILD_ID
617 FP_PROG_LD_NO_COMPACT_UNWIND
618 FP_PROG_LD_FILELIST
619
620
621 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
622 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
623 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
624 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
625 # Stage 3 won't be supported by cross-compilation
626
627 FP_GCC_EXTRA_FLAGS
628
629 AC_SUBST(CONF_CC_OPTS_STAGE0)
630 AC_SUBST(CONF_CC_OPTS_STAGE1)
631 AC_SUBST(CONF_CC_OPTS_STAGE2)
632 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
633 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
634 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
635 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
636 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
637 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
638 AC_SUBST(CONF_CPP_OPTS_STAGE0)
639 AC_SUBST(CONF_CPP_OPTS_STAGE1)
640 AC_SUBST(CONF_CPP_OPTS_STAGE2)
641
642 dnl ** Set up the variables for the platform in the settings file.
643 dnl May need to use gcc to find platform details.
644 dnl --------------------------------------------------------------
645 FPTOOLS_SET_HASKELL_PLATFORM_VARS
646
647 dnl ** figure out how to do context diffs
648 FP_PROG_CONTEXT_DIFF
649
650 dnl Let's make sure install-sh is executable here.  If we got it from
651 dnl a darcs repo, it might not be (see bug #978).
652 chmod +x install-sh
653 dnl ** figure out how to do a BSD-ish install
654 AC_PROG_INSTALL
655
656 dnl ** how to invoke `ar' and `ranlib'
657 FP_PROG_AR_SUPPORTS_ATFILE
658 FP_PROG_AR_NEEDS_RANLIB
659
660 dnl ** Check to see whether ln -s works
661 AC_PROG_LN_S
662
663 FP_SETTINGS
664
665 dnl ** Find the path to sed
666 AC_PATH_PROGS(SedCmd,gsed sed,sed)
667
668
669 dnl ** check for time command
670 AC_PATH_PROG(TimeCmd,time)
671
672 dnl ** check for tar
673 dnl   if GNU tar is named gtar, look for it first.
674 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
675
676 dnl ** check for patch
677 dnl if GNU patch is named gpatch, look for it first
678 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
679
680 dnl ** check for dtrace (currently only implemented for Mac OS X)
681 HaveDtrace=NO
682 AC_PATH_PROG(DtraceCmd,dtrace)
683 if test -n "$DtraceCmd"; then
684   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
685     HaveDtrace=YES
686   fi
687 fi
688 AC_SUBST(HaveDtrace)
689
690 AC_PATH_PROG(HSCOLOUR,HsColour)
691 # HsColour is passed to Cabal, so we need a native path
692 if test "$HostOS"      = "mingw32" && \
693    test "${HSCOLOUR}" != ""
694 then
695     # Canonicalise to <drive>:/path/to/gcc
696     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
697 fi
698
699 dnl ** check for Sphinx toolchain
700 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
701 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
702 changequote(, )dnl
703 [if test -n "$SPHINXBUILD"; then
704   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
705 fi;
706 changequote([, ])dnl
707 ])
708 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
709     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
710
711 dnl ** check for xelatex
712 AC_PATH_PROG(XELATEX,xelatex)
713
714 dnl ** check for ghc-pkg command
715 FP_PROG_GHC_PKG
716
717 dnl ** check for installed happy binary + version
718 FPTOOLS_HAPPY
719
720 dnl ** check for installed alex binary + version
721 FPTOOLS_ALEX
722
723 dnl --------------------------------------------------
724 dnl ### program checking section ends here ###
725 dnl --------------------------------------------------
726
727 dnl --------------------------------------------------
728 dnl * Platform header file and syscall feature tests
729 dnl ### checking the state of the local header files and syscalls ###
730
731 dnl ** check for full ANSI header (.h) files
732 AC_HEADER_STDC
733
734 dnl ** Enable large file support.  NB. do this before testing the type of
735 dnl    off_t, because it will affect the result of that test.
736 AC_SYS_LARGEFILE
737
738 dnl ** check for specific header (.h) files that we are interested in
739 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
740
741 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
742 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
743 [[#if HAVE_SYS_PARAM_H
744 # include <sys/param.h>
745 #endif
746 ]])
747
748 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
749 AC_HEADER_TIME
750
751 dnl ** do we have long longs?
752 AC_CHECK_TYPES([long long])
753
754 dnl ** what are the sizes of various types
755 FP_CHECK_SIZEOF_AND_ALIGNMENT(char)
756 FP_CHECK_SIZEOF_AND_ALIGNMENT(double)
757 FP_CHECK_SIZEOF_AND_ALIGNMENT(float)
758 FP_CHECK_SIZEOF_AND_ALIGNMENT(int)
759 FP_CHECK_SIZEOF_AND_ALIGNMENT(long)
760 if test "$ac_cv_type_long_long" = yes; then
761 FP_CHECK_SIZEOF_AND_ALIGNMENT(long long)
762 fi
763 FP_CHECK_SIZEOF_AND_ALIGNMENT(short)
764 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned char)
765 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned int)
766 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long)
767 if test "$ac_cv_type_long_long" = yes; then
768 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long long)
769 fi
770 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned short)
771 FP_CHECK_SIZEOF_AND_ALIGNMENT(void *)
772
773 FP_CHECK_SIZEOF_AND_ALIGNMENT(int8_t)
774 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint8_t)
775 FP_CHECK_SIZEOF_AND_ALIGNMENT(int16_t)
776 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint16_t)
777 FP_CHECK_SIZEOF_AND_ALIGNMENT(int32_t)
778 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint32_t)
779 FP_CHECK_SIZEOF_AND_ALIGNMENT(int64_t)
780 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint64_t)
781
782
783 dnl for use in settings.in
784 WordSize=$ac_cv_sizeof_void_p
785 AC_SUBST(WordSize)
786 FP_CHECK_FUNC([WinExec],
787   [@%:@include <windows.h>], [WinExec("",0)])
788
789 FP_CHECK_FUNC([GetModuleFileName],
790   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
791
792 dnl ** check for more functions
793 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
794 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
795
796 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
797 dnl ** _POSIX_C_SOURCE is defined
798 AC_CHECK_DECLS([ctime_r], , ,
799 [#define _POSIX_SOURCE 1
800 #define _POSIX_C_SOURCE 199506L
801 #include <time.h>])
802
803 dnl ** check for mingwex library
804 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
805 AC_SUBST(HaveLibMingwEx)
806
807 if test $HaveLibMingwEx = YES ; then
808   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
809 fi
810
811 dnl ** check for math library
812 dnl    Keep that check as early as possible.
813 dnl    as we need to know whether we need libm
814 dnl    for math functions or not
815 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
816 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
817 if test $HaveLibM = YES
818 then
819   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
820 fi
821
822 FP_BFD_SUPPORT
823
824 dnl ################################################################
825 dnl Check for libraries
826 dnl ################################################################
827
828 # system libffi
829
830 AC_ARG_WITH([system-libffi],
831 [AC_HELP_STRING([--with-system-libffi],
832   [Use system provided libffi for RTS [default=no]])
833 ])
834
835 AS_IF([test "x$with_system_libffi" = "xyes"],
836   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
837 )
838
839
840 AC_SUBST(UseSystemLibFFI)
841
842 AC_ARG_WITH([ffi-includes],
843 [AC_HELP_STRING([--with-ffi-includes=ARG],
844   [Find includes for libffi in ARG [default=system default]])
845 ],
846 [
847  if test "x$UseSystemLibFFI" != "xYES"; then
848     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
849  else
850     FFIIncludeDir="$withval"
851     LIBFFI_CFLAGS="-I$withval"
852  fi
853 ])
854
855 AC_SUBST(FFIIncludeDir)
856
857 AC_ARG_WITH([ffi-libraries],
858 [AC_HELP_STRING([--with-ffi-libraries=ARG],
859   [Find libffi in ARG [default=system default]])
860 ],
861 [
862  if test "x$UseSystemLibFFI" != "xYES"; then
863     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
864  else
865     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
866  fi
867 ])
868
869 AC_SUBST(FFILibDir)
870
871 AS_IF([test "$UseSystemLibFFI" = "YES"], [
872  CFLAGS2="$CFLAGS"
873  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
874  LDFLAGS2="$LDFLAGS"
875  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
876  if test "$HostOS" = "openbsd";
877  then
878    # OpenBSD's libffi is not directly linked to the libpthread but
879    # still requires pthread functionality. This means that any client
880    # binary which links with libffi also needs to link with
881    # libpthread. If it does not, then linking fails with unresolved
882    # symbols.
883    LDFLAGS="$LDFLAGS -lpthread"
884  fi
885  AC_CHECK_LIB(ffi, ffi_call,
886   [AC_CHECK_HEADERS([ffi.h], [break], [])
887    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
888   [AC_MSG_ERROR([Cannot find system libffi])])
889  CFLAGS="$CFLAGS2"
890  LDFLAGS="$LDFLAGS2"
891 ])
892
893 dnl ** check whether we need -ldl to get dlopen()
894 AC_CHECK_LIB(dl, dlopen)
895
896 dnl --------------------------------------------------
897 dnl * Miscellaneous feature tests
898 dnl --------------------------------------------------
899
900 dnl ** can we get alloca?
901 AC_FUNC_ALLOCA
902
903 dnl ** working vfork?
904 AC_FUNC_FORK
905
906 dnl ** determine whether or not const works
907 AC_C_CONST
908
909 dnl ** are we big endian?
910 AC_C_BIGENDIAN
911 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
912
913 dnl ** check for leading underscores in symbol names
914 FP_LEADING_UNDERSCORE
915
916 FP_VISIBILITY_HIDDEN
917
918 dnl ** check for librt
919 AC_CHECK_LIB(rt, clock_gettime)
920 AC_CHECK_FUNCS(clock_gettime timer_settime)
921 FP_CHECK_TIMER_CREATE
922
923 dnl ** check for Apple's "interesting" long double compatibility scheme
924 AC_MSG_CHECKING(for printf\$LDBLStub)
925 AC_TRY_LINK_FUNC(printf\$LDBLStub,
926     [
927         AC_MSG_RESULT(yes)
928         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
929             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
930     ],
931     [
932         AC_MSG_RESULT(no)
933         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
934             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
935     ])
936
937 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
938 dnl    a different single-argument version.
939 AC_CHECK_LIB(pthread, pthread_setname_np)
940 AC_MSG_CHECKING(for pthread_setname_np)
941 AC_TRY_LINK(
942 [
943 #define _GNU_SOURCE
944 #include <pthread.h>
945 ],
946 [pthread_setname_np(pthread_self(), "name");],
947     AC_MSG_RESULT(yes)
948     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
949       [Define to 1 if you have the glibc version of pthread_setname_np]),
950     AC_MSG_RESULT(no)
951 )
952
953 dnl ** check for eventfd which is needed by the I/O manager
954 AC_CHECK_HEADERS([sys/eventfd.h])
955 AC_CHECK_FUNCS([eventfd])
956
957 dnl ** Check for __thread support in the compiler
958 AC_MSG_CHECKING(for __thread support)
959 AC_COMPILE_IFELSE(
960   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
961   [
962    AC_MSG_RESULT(yes)
963    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
964   ],
965   [
966    AC_MSG_RESULT(no)
967    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
968   ])
969
970 dnl large address space support (see includes/rts/storage/MBlock.h)
971 dnl
972 dnl Darwin has vm_allocate/vm_protect
973 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
974 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
975 dnl (They also have MADV_DONTNEED, but it means something else!)
976 dnl
977 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
978 dnl it counts page-table space as committed memory, and so quickly
979 dnl runs out of paging file when we have multiple processes reserving
980 dnl 1TB of address space, we get the following error:
981 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
982 dnl
983
984 AC_ARG_ENABLE(large-address-space,
985     [AC_HELP_STRING([--enable-large-address-space],
986         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
987     EnableLargeAddressSpace=$enableval,
988     EnableLargeAddressSpace=yes
989 )
990
991 use_large_address_space=no
992 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
993     if test "x$EnableLargeAddressSpace" = "xyes" ; then
994         if test "$ghc_host_os" = "darwin" ; then
995             use_large_address_space=yes
996         elif test "$ghc_host_os" = "openbsd" ; then
997             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
998             # The flag MAP_NORESERVE is supported for source compatibility reasons,
999             # but is completely ignored by OS mmap
1000             use_large_address_space=no
1001         else
1002             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1003                 [
1004                 #include <unistd.h>
1005                 #include <sys/types.h>
1006                 #include <sys/mman.h>
1007                 #include <fcntl.h>
1008             ])
1009             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1010                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1011                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1012                     use_large_address_space=yes
1013             fi
1014         fi
1015     fi
1016 fi
1017 if test "$use_large_address_space" = "yes" ; then
1018    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1019 fi
1020
1021 dnl ** Use MMAP in the runtime linker?
1022 dnl --------------------------------------------------------------
1023
1024 case ${TargetOS} in
1025     linux|freebsd|dragonfly|netbsd|openbsd|kfreebsdgnu|gnu|solaris2)
1026         RtsLinkerUseMmap=1
1027         ;;
1028     darwin)
1029         # Don't use mmap on powerpc/darwin as the mmap there doesn't support
1030         # reallocating. Reallocating is needed to allocate jump islands just
1031         # after each object image. Jumps to these jump islands use relative
1032         # branches which are limited to offsets that can be represented in
1033         # 24-bits.
1034         if test "$TargetArch" != "powerpc" ; then
1035             RtsLinkerUseMmap=1
1036         else
1037             RtsLinkerUseMmap=0
1038         fi
1039         ;;
1040     *)
1041         # Windows (which doesn't have mmap) and everything else.
1042         RtsLinkerUseMmap=0
1043         ;;
1044     esac
1045
1046 AC_DEFINE_UNQUOTED([RTS_LINKER_USE_MMAP], [$RtsLinkerUseMmap],
1047                    [Use mmap in the runtime linker])
1048
1049 dnl ** Have libdw?
1050 dnl --------------------------------------------------------------
1051 UseLibdw=NO
1052 USE_LIBDW=0
1053 AC_ARG_ENABLE(dwarf-unwind,
1054     [AC_HELP_STRING([--enable-dwarf-unwind],
1055         [Enable DWARF unwinding support in the runtime system via elfutils' libdw [default=no]])],
1056     [AC_CHECK_LIB(dw, dwfl_attach_state, [UseLibdw=YES], [UseLibdw=NO])],
1057     [UseLibdw=NO]
1058 )
1059 AC_SUBST(UseLibdw)
1060 if test $UseLibdw = "YES" ; then
1061         USE_LIBDW=1
1062 fi
1063 AC_DEFINE_UNQUOTED([USE_LIBDW], [$USE_LIBDW], [Set to 1 to use libdw])
1064
1065 dnl ** Have libnuma?
1066 dnl --------------------------------------------------------------
1067 HaveLibNuma=0
1068 AC_CHECK_HEADERS([numa.h numaif.h])
1069
1070 if test "$ac_cv_header_numa_h$ac_cv_header_numaif_h" = "yesyes" ; then
1071     AC_CHECK_LIB(numa, numa_available,HaveLibNuma=1)
1072 fi
1073 AC_DEFINE_UNQUOTED([HAVE_LIBNUMA], [$HaveLibNuma], [Define to 1 if you have libnuma])
1074
1075 dnl ** Documentation
1076 dnl --------------------------------------------------------------
1077 if test -n "$SPHINXBUILD"; then
1078     BUILD_MAN=YES
1079     BUILD_SPHINX_HTML=YES
1080     if test -n "$XELATEX"; then
1081         BUILD_SPHINX_PDF=YES
1082     else
1083         BUILD_SPHINX_PDF=NO
1084     fi
1085 else
1086     BUILD_MAN=NO
1087     BUILD_SPHINX_HTML=NO
1088     BUILD_SPHINX_PDF=NO
1089 fi
1090 AC_SUBST(BUILD_MAN)
1091 AC_SUBST(BUILD_SPHINX_HTML)
1092 AC_SUBST(BUILD_SPHINX_PDF)
1093
1094 LIBRARY_VERSION(base)
1095 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1096 LIBRARY_VERSION(ghc-prim)
1097 LIBRARY_ghc_VERSION="$ProjectVersion"
1098 AC_SUBST(LIBRARY_ghc_VERSION)
1099
1100 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1101    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1102 fi
1103
1104 # Create the configuration for the Hadrian build system if it is present
1105 if test -e hadrian/cfg/system.config.in; then
1106     AC_CONFIG_FILES([hadrian/cfg/system.config])
1107 fi
1108
1109 # We got caught by
1110 #     http://savannah.gnu.org/bugs/index.php?1516
1111 #     $(eval ...) inside conditionals causes errors
1112 # with make 3.80, so warn the user if it looks like they're about to
1113 # try to use it.
1114 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1115 print_make_warning=""
1116 checkMake380() {
1117     make_ver=`$1 --version 2>&1 | head -1`
1118     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1119     then
1120         print_make_warning="true"
1121     fi
1122     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1123     then
1124         MakeCmd=$1
1125         AC_SUBST(MakeCmd)
1126     fi
1127 }
1128
1129 checkMake380 make
1130 checkMake380 gmake
1131
1132 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghc-boot-th/ghc-boot-th.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt distrib/configure.ac])
1133 AC_OUTPUT
1134
1135 if test "$print_make_warning" = "true"; then
1136    echo
1137    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1138    echo "This version cannot be used to build GHC."
1139    echo "Please use GNU make >= 3.81."
1140 fi
1141
1142 echo ["
1143 ----------------------------------------------------------------------
1144 Configure completed successfully.
1145
1146    Building GHC version  : $ProjectVersion
1147           Git commit id  : $ProjectGitCommitId
1148
1149    Build platform        : $BuildPlatform
1150    Host platform         : $HostPlatform
1151    Target platform       : $TargetPlatform
1152 "]
1153
1154 echo ["\
1155    Bootstrapping using   : $WithGhc
1156       which is version   : $GhcVersion
1157 "]
1158
1159 if test "x$CC_LLVM_BACKEND" = "x1"; then
1160     if test "x$CC_CLANG_BACKEND" = "x1"; then
1161         CompilerName="clang        "
1162     else
1163         CompilerName="llvm-gcc     "
1164     fi
1165 else
1166     CompilerName="gcc          "
1167 fi
1168
1169 echo ["\
1170    Using (for bootstrapping) : $CC_STAGE0
1171    Using $CompilerName       : $CC
1172       which is version       : $GccVersion
1173    Building a cross compiler : $CrossCompiling
1174    Unregisterised            : $Unregisterised
1175    hs-cpp       : $HaskellCPPCmd
1176    hs-cpp-flags : $HaskellCPPArgs
1177    ld           : $LdCmd
1178    nm           : $NmCmd
1179    objdump      : $ObjdumpCmd
1180    Happy        : $HappyCmd ($HappyVersion)
1181    Alex         : $AlexCmd ($AlexVersion)
1182    Perl         : $PerlCmd
1183    sphinx-build : $SPHINXBUILD
1184    xelatex      : $XELATEX
1185
1186    Using LLVM tools
1187       llc   : $LlcCmd
1188       opt   : $OptCmd"]
1189
1190 if test "$HSCOLOUR" = ""; then
1191 echo ["
1192    HsColour was not found; documentation will not contain source links
1193 "]
1194 else
1195 echo ["\
1196    HsColour : $HSCOLOUR
1197 "]
1198 fi
1199
1200 echo ["\
1201    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1202    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"]
1203
1204 echo ["----------------------------------------------------------------------
1205 "]
1206
1207 echo "\
1208 For a standard build of GHC (fully optimised with profiling), type (g)make.
1209
1210 To make changes to the default build configuration, copy the file
1211 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1212
1213 For more information on how to configure your GHC build, see
1214    http://ghc.haskell.org/trac/ghc/wiki/Building
1215 "