Add parens in patterns; fix Trac #3899
[ghc.git] / libraries / template-haskell / Language / Haskell / TH / Ppr.hs
1 -- TH.Ppr contains a prettyprinter for the
2 -- Template Haskell datatypes
3
4 module Language.Haskell.TH.Ppr where
5 -- All of the exports from this module should
6 -- be "public" functions. The main module TH
7 -- re-exports them all.
8
9 import Text.PrettyPrint.HughesPJ (render)
10 import Language.Haskell.TH.PprLib
11 import Language.Haskell.TH.Syntax
12 import Data.Char ( toLower )
13
14 nestDepth :: Int
15 nestDepth = 4
16
17 type Precedence = Int
18 appPrec, opPrec, noPrec :: Precedence
19 appPrec = 2 -- Argument of a function application
20 opPrec = 1 -- Argument of an infix operator
21 noPrec = 0 -- Others
22
23 parensIf :: Bool -> Doc -> Doc
24 parensIf True d = parens d
25 parensIf False d = d
26
27 ------------------------------
28
29 pprint :: Ppr a => a -> String
30 pprint x = render $ to_HPJ_Doc $ ppr x
31
32 class Ppr a where
33 ppr :: a -> Doc
34 ppr_list :: [a] -> Doc
35 ppr_list = vcat . map ppr
36
37 instance Ppr a => Ppr [a] where
38 ppr x = ppr_list x
39
40 ------------------------------
41 instance Ppr Name where
42 ppr v = pprName v
43
44 ------------------------------
45 instance Ppr Info where
46 ppr (ClassI d) = ppr d
47 ppr (TyConI d) = ppr d
48 ppr (PrimTyConI name arity is_unlifted)
49 = text "Primitive"
50 <+> (if is_unlifted then text "unlifted" else empty)
51 <+> text "type construtor" <+> quotes (ppr name)
52 <+> parens (text "arity" <+> int arity)
53 ppr (ClassOpI v ty cls fix)
54 = text "Class op from" <+> ppr cls <> colon <+>
55 vcat [ppr_sig v ty, pprFixity v fix]
56 ppr (DataConI v ty tc fix)
57 = text "Constructor from" <+> ppr tc <> colon <+>
58 vcat [ppr_sig v ty, pprFixity v fix]
59 ppr (TyVarI v ty)
60 = text "Type variable" <+> ppr v <+> equals <+> ppr ty
61 ppr (VarI v ty mb_d fix)
62 = vcat [ppr_sig v ty, pprFixity v fix,
63 case mb_d of { Nothing -> empty; Just d -> ppr d }]
64
65 ppr_sig :: Name -> Type -> Doc
66 ppr_sig v ty = ppr v <+> text "::" <+> ppr ty
67
68 pprFixity :: Name -> Fixity -> Doc
69 pprFixity _ f | f == defaultFixity = empty
70 pprFixity v (Fixity i d) = ppr_fix d <+> int i <+> ppr v
71 where ppr_fix InfixR = text "infixr"
72 ppr_fix InfixL = text "infixl"
73 ppr_fix InfixN = text "infix"
74
75
76 ------------------------------
77 instance Ppr Exp where
78 ppr = pprExp noPrec
79
80 pprInfixExp :: Exp -> Doc
81 pprInfixExp (VarE v) = pprName' Infix v
82 pprInfixExp (ConE v) = pprName' Infix v
83 pprInfixExp _ = error "Attempt to pretty-print non-variable or constructor in infix context!"
84
85 pprExp :: Precedence -> Exp -> Doc
86 pprExp _ (VarE v) = pprName' Applied v
87 pprExp _ (ConE c) = pprName' Applied c
88 pprExp i (LitE l) = pprLit i l
89 pprExp i (AppE e1 e2) = parensIf (i >= appPrec) $ pprExp opPrec e1
90 <+> pprExp appPrec e2
91 pprExp i (InfixE (Just e1) op (Just e2))
92 = parensIf (i >= opPrec) $ pprExp opPrec e1
93 <+> pprInfixExp op
94 <+> pprExp opPrec e2
95 pprExp _ (InfixE me1 op me2) = parens $ pprMaybeExp noPrec me1
96 <+> pprInfixExp op
97 <+> pprMaybeExp noPrec me2
98 pprExp i (LamE ps e) = parensIf (i > noPrec) $ char '\\' <> hsep (map (pprPat appPrec) ps)
99 <+> text "->" <+> ppr e
100 pprExp _ (TupE es) = parens $ sep $ punctuate comma $ map ppr es
101 -- Nesting in Cond is to avoid potential problems in do statments
102 pprExp i (CondE guard true false)
103 = parensIf (i > noPrec) $ sep [text "if" <+> ppr guard,
104 nest 1 $ text "then" <+> ppr true,
105 nest 1 $ text "else" <+> ppr false]
106 pprExp i (LetE ds e) = parensIf (i > noPrec) $ text "let" <+> ppr ds
107 $$ text " in" <+> ppr e
108 pprExp i (CaseE e ms)
109 = parensIf (i > noPrec) $ text "case" <+> ppr e <+> text "of"
110 $$ nest nestDepth (ppr ms)
111 pprExp i (DoE ss) = parensIf (i > noPrec) $ text "do" <+> ppr ss
112 pprExp _ (CompE []) = error "Can't happen: pprExp (CompExp [])"
113 -- This will probably break with fixity declarations - would need a ';'
114 pprExp _ (CompE ss) = text "[" <> ppr s
115 <+> text "|"
116 <+> (sep $ punctuate comma $ map ppr ss')
117 <> text "]"
118 where s = last ss
119 ss' = init ss
120 pprExp _ (ArithSeqE d) = ppr d
121 pprExp _ (ListE es) = brackets $ sep $ punctuate comma $ map ppr es
122 pprExp i (SigE e t) = parensIf (i > noPrec) $ ppr e <+> text "::" <+> ppr t
123 pprExp _ (RecConE nm fs) = ppr nm <> braces (pprFields fs)
124 pprExp _ (RecUpdE e fs) = pprExp appPrec e <> braces (pprFields fs)
125
126 pprFields :: [(Name,Exp)] -> Doc
127 pprFields = sep . punctuate comma . map (\(s,e) -> ppr s <+> equals <+> ppr e)
128
129 pprMaybeExp :: Precedence -> Maybe Exp -> Doc
130 pprMaybeExp _ Nothing = empty
131 pprMaybeExp i (Just e) = pprExp i e
132
133 ------------------------------
134 instance Ppr Stmt where
135 ppr (BindS p e) = ppr p <+> text "<-" <+> ppr e
136 ppr (LetS ds) = text "let" <+> ppr ds
137 ppr (NoBindS e) = ppr e
138 ppr (ParS sss) = sep $ punctuate (text "|")
139 $ map (sep . punctuate comma . map ppr) sss
140
141 ------------------------------
142 instance Ppr Match where
143 ppr (Match p rhs ds) = ppr p <+> pprBody False rhs
144 $$ where_clause ds
145
146 ------------------------------
147 pprBody :: Bool -> Body -> Doc
148 pprBody eq (GuardedB xs) = nest nestDepth $ vcat $ map do_guard xs
149 where eqd = if eq then text "=" else text "->"
150 do_guard (NormalG g, e) = text "|" <+> ppr g <+> eqd <+> ppr e
151 do_guard (PatG ss, e) = text "|" <+> vcat (map ppr ss)
152 $$ nest nestDepth (eqd <+> ppr e)
153 pprBody eq (NormalB e) = (if eq then text "=" else text "->") <+> ppr e
154
155 ------------------------------
156 pprLit :: Precedence -> Lit -> Doc
157 pprLit i (IntPrimL x) = parensIf (i > noPrec && x < 0)
158 (integer x <> char '#')
159 pprLit _ (WordPrimL x) = integer x <> text "##"
160 pprLit i (FloatPrimL x) = parensIf (i > noPrec && x < 0)
161 (float (fromRational x) <> char '#')
162 pprLit i (DoublePrimL x) = parensIf (i > noPrec && x < 0)
163 (double (fromRational x) <> text "##")
164 pprLit i (IntegerL x) = parensIf (i > noPrec && x < 0) (integer x)
165 pprLit _ (CharL c) = text (show c)
166 pprLit _ (StringL s) = text (show s)
167 pprLit i (RationalL rat) = parensIf (i > noPrec) $ rational rat
168
169 ------------------------------
170 instance Ppr Pat where
171 ppr = pprPat noPrec
172
173 pprPat :: Precedence -> Pat -> Doc
174 pprPat i (LitP l) = pprLit i l
175 pprPat _ (VarP v) = pprName' Applied v
176 pprPat _ (TupP ps) = parens $ sep $ punctuate comma $ map ppr ps
177 pprPat i (ConP s ps) = parensIf (i >= appPrec) $ pprName' Applied s
178 <+> sep (map (pprPat appPrec) ps)
179 pprPat i (InfixP p1 n p2)
180 = parensIf (i >= opPrec) (pprPat opPrec p1 <+>
181 pprName' Infix n <+>
182 pprPat opPrec p2)
183 pprPat i (TildeP p) = parensIf (i > noPrec) $ char '~' <> pprPat appPrec p
184 pprPat i (BangP p) = parensIf (i > noPrec) $ char '!' <> pprPat appPrec p
185 pprPat i (AsP v p) = parensIf (i > noPrec) $ ppr v <> text "@"
186 <> pprPat appPrec p
187 pprPat _ WildP = text "_"
188 pprPat _ (RecP nm fs)
189 = parens $ ppr nm
190 <+> braces (sep $ punctuate comma $
191 map (\(s,p) -> ppr s <+> equals <+> ppr p) fs)
192 pprPat _ (ListP ps) = brackets $ sep $ punctuate comma $ map ppr ps
193 pprPat i (SigP p t) = parensIf (i > noPrec) $ ppr p <+> text "::" <+> ppr t
194
195 ------------------------------
196 instance Ppr Dec where
197 ppr = ppr_dec True
198
199 ppr_dec :: Bool -- declaration on the toplevel?
200 -> Dec
201 -> Doc
202 ppr_dec _ (FunD f cs) = vcat $ map (\c -> ppr f <+> ppr c) cs
203 ppr_dec _ (ValD p r ds) = ppr p <+> pprBody True r
204 $$ where_clause ds
205 ppr_dec _ (TySynD t xs rhs)
206 = ppr_tySyn empty t (hsep (map ppr xs)) rhs
207 ppr_dec _ (DataD ctxt t xs cs decs)
208 = ppr_data empty ctxt t (hsep (map ppr xs)) cs decs
209 ppr_dec _ (NewtypeD ctxt t xs c decs)
210 = ppr_newtype empty ctxt t (sep (map ppr xs)) c decs
211 ppr_dec _ (ClassD ctxt c xs fds ds)
212 = text "class" <+> pprCxt ctxt <+> ppr c <+> hsep (map ppr xs) <+> ppr fds
213 $$ where_clause ds
214 ppr_dec _ (InstanceD ctxt i ds) = text "instance" <+> pprCxt ctxt <+> ppr i
215 $$ where_clause ds
216 ppr_dec _ (SigD f t) = ppr f <+> text "::" <+> ppr t
217 ppr_dec _ (ForeignD f) = ppr f
218 ppr_dec _ (PragmaD p) = ppr p
219 ppr_dec isTop (FamilyD flav tc tvs k)
220 = ppr flav <+> maybeFamily <+> ppr tc <+> hsep (map ppr tvs) <+> maybeKind
221 where
222 maybeFamily | isTop = text "family"
223 | otherwise = empty
224
225 maybeKind | (Just k') <- k = text "::" <+> ppr k'
226 | otherwise = empty
227 ppr_dec isTop (DataInstD ctxt tc tys cs decs)
228 = ppr_data maybeInst ctxt tc (sep (map pprParendType tys)) cs decs
229 where
230 maybeInst | isTop = text "instance"
231 | otherwise = empty
232 ppr_dec isTop (NewtypeInstD ctxt tc tys c decs)
233 = ppr_newtype maybeInst ctxt tc (sep (map pprParendType tys)) c decs
234 where
235 maybeInst | isTop = text "instance"
236 | otherwise = empty
237 ppr_dec isTop (TySynInstD tc tys rhs)
238 = ppr_tySyn maybeInst tc (sep (map pprParendType tys)) rhs
239 where
240 maybeInst | isTop = text "instance"
241 | otherwise = empty
242
243 ppr_data :: Doc -> Cxt -> Name -> Doc -> [Con] -> [Name] -> Doc
244 ppr_data maybeInst ctxt t argsDoc cs decs
245 = text "data" <+> maybeInst
246 <+> pprCxt ctxt
247 <+> ppr t <+> argsDoc
248 <+> sep (pref $ map ppr cs)
249 $$ if null decs
250 then empty
251 else nest nestDepth
252 $ text "deriving"
253 <+> parens (hsep $ punctuate comma $ map ppr decs)
254 where
255 pref :: [Doc] -> [Doc]
256 pref [] = [] -- No constructors; can't happen in H98
257 pref (d:ds) = (char '=' <+> d):map (char '|' <+>) ds
258
259 ppr_newtype :: Doc -> Cxt -> Name -> Doc -> Con -> [Name] -> Doc
260 ppr_newtype maybeInst ctxt t argsDoc c decs
261 = text "newtype" <+> maybeInst
262 <+> pprCxt ctxt
263 <+> ppr t <+> argsDoc
264 <+> char '=' <+> ppr c
265 $$ if null decs
266 then empty
267 else nest nestDepth
268 $ text "deriving"
269 <+> parens (hsep $ punctuate comma $ map ppr decs)
270
271 ppr_tySyn :: Doc -> Name -> Doc -> Type -> Doc
272 ppr_tySyn maybeInst t argsDoc rhs
273 = text "type" <+> maybeInst <+> ppr t <+> argsDoc <+> text "=" <+> ppr rhs
274
275 ------------------------------
276 instance Ppr FunDep where
277 ppr (FunDep xs ys) = hsep (map ppr xs) <+> text "->" <+> hsep (map ppr ys)
278 ppr_list [] = empty
279 ppr_list xs = char '|' <+> sep (punctuate (text ", ") (map ppr xs))
280
281 ------------------------------
282 instance Ppr FamFlavour where
283 ppr DataFam = text "data"
284 ppr TypeFam = text "type"
285
286 ------------------------------
287 instance Ppr Foreign where
288 ppr (ImportF callconv safety impent as typ)
289 = text "foreign import"
290 <+> showtextl callconv
291 <+> showtextl safety
292 <+> text (show impent)
293 <+> ppr as
294 <+> text "::" <+> ppr typ
295 ppr (ExportF callconv expent as typ)
296 = text "foreign export"
297 <+> showtextl callconv
298 <+> text (show expent)
299 <+> ppr as
300 <+> text "::" <+> ppr typ
301
302 ------------------------------
303 instance Ppr Pragma where
304 ppr (InlineP n (InlineSpec inline conlike activation))
305 = text "{-#"
306 <+> (if inline then text "INLINE" else text "NOINLINE")
307 <+> (if conlike then text "CONLIKE" else empty)
308 <+> ppr_activation activation
309 <+> ppr n
310 <+> text "#-}"
311 ppr (SpecialiseP n ty Nothing)
312 = sep [ text "{-# SPECIALISE"
313 , ppr n <+> text "::"
314 , ppr ty
315 , text "#-}"
316 ]
317 ppr (SpecialiseP n ty (Just (InlineSpec inline _conlike activation)))
318 = sep [ text "{-# SPECIALISE" <+>
319 (if inline then text "INLINE" else text "NOINLINE") <+>
320 ppr_activation activation
321 , ppr n <+> text "::"
322 , ppr ty
323 , text "#-}"
324 ]
325 where
326
327 ppr_activation :: Maybe (Bool, Int) -> Doc
328 ppr_activation (Just (beforeFrom, i))
329 = brackets $ (if beforeFrom then empty else char '~') <+> int i
330 ppr_activation Nothing = empty
331
332 ------------------------------
333 instance Ppr Clause where
334 ppr (Clause ps rhs ds) = hsep (map (pprPat appPrec) ps) <+> pprBody True rhs
335 $$ where_clause ds
336
337 ------------------------------
338 instance Ppr Con where
339 ppr (NormalC c sts) = ppr c <+> sep (map pprStrictType sts)
340 ppr (RecC c vsts)
341 = ppr c <+> braces (sep (punctuate comma $ map pprVarStrictType vsts))
342 ppr (InfixC st1 c st2) = pprStrictType st1
343 <+> pprName' Infix c
344 <+> pprStrictType st2
345 ppr (ForallC ns ctxt con) = text "forall" <+> hsep (map ppr ns)
346 <+> char '.' <+> pprCxt ctxt <+> ppr con
347
348 ------------------------------
349 pprVarStrictType :: (Name, Strict, Type) -> Doc
350 -- Slight infelicity: with print non-atomic type with parens
351 pprVarStrictType (v, str, t) = ppr v <+> text "::" <+> pprStrictType (str, t)
352
353 ------------------------------
354 pprStrictType :: (Strict, Type) -> Doc
355 -- Prints with parens if not already atomic
356 pprStrictType (IsStrict, t) = char '!' <> pprParendType t
357 pprStrictType (NotStrict, t) = pprParendType t
358
359 ------------------------------
360 pprParendType :: Type -> Doc
361 pprParendType (VarT v) = ppr v
362 pprParendType (ConT c) = ppr c
363 pprParendType (TupleT 0) = text "()"
364 pprParendType (TupleT n) = parens (hcat (replicate (n-1) comma))
365 pprParendType ArrowT = parens (text "->")
366 pprParendType ListT = text "[]"
367 pprParendType other = parens (ppr other)
368
369 instance Ppr Type where
370 ppr (ForallT tvars ctxt ty)
371 = text "forall" <+> hsep (map ppr tvars) <+> text "."
372 <+> pprCxt ctxt <+> ppr ty
373 ppr (SigT ty k) = ppr ty <+> text "::" <+> ppr k
374 ppr ty = pprTyApp (split ty)
375
376 pprTyApp :: (Type, [Type]) -> Doc
377 pprTyApp (ArrowT, [arg1,arg2]) = sep [pprFunArgType arg1 <+> text "->", ppr arg2]
378 pprTyApp (ListT, [arg]) = brackets (ppr arg)
379 pprTyApp (TupleT n, args)
380 | length args == n = parens (sep (punctuate comma (map ppr args)))
381 pprTyApp (fun, args) = pprParendType fun <+> sep (map pprParendType args)
382
383 pprFunArgType :: Type -> Doc -- Should really use a precedence argument
384 -- Everything except forall and (->) binds more tightly than (->)
385 pprFunArgType ty@(ForallT {}) = parens (ppr ty)
386 pprFunArgType ty@((ArrowT `AppT` _) `AppT` _) = parens (ppr ty)
387 pprFunArgType ty@(SigT _ _) = parens (ppr ty)
388 pprFunArgType ty = ppr ty
389
390 split :: Type -> (Type, [Type]) -- Split into function and args
391 split t = go t []
392 where go (AppT t1 t2) args = go t1 (t2:args)
393 go ty args = (ty, args)
394
395 ------------------------------
396 instance Ppr TyVarBndr where
397 ppr (PlainTV nm) = ppr nm
398 ppr (KindedTV nm k) = parens (ppr nm <+> text "::" <+> ppr k)
399
400 instance Ppr Kind where
401 ppr StarK = char '*'
402 ppr (ArrowK k1 k2) = pprArrowArgKind k1 <+> text "->" <+> ppr k2
403
404 pprArrowArgKind :: Kind -> Doc
405 pprArrowArgKind k@(ArrowK _ _) = parens (ppr k)
406 pprArrowArgKind k = ppr k
407
408 ------------------------------
409 pprCxt :: Cxt -> Doc
410 pprCxt [] = empty
411 pprCxt [t] = ppr t <+> text "=>"
412 pprCxt ts = parens (hsep $ punctuate comma $ map ppr ts) <+> text "=>"
413
414 ------------------------------
415 instance Ppr Pred where
416 ppr (ClassP cla tys) = ppr cla <+> sep (map pprParendType tys)
417 ppr (EqualP ty1 ty2) = pprFunArgType ty1 <+> char '~' <+> pprFunArgType ty2
418
419 ------------------------------
420 instance Ppr Range where
421 ppr = brackets . pprRange
422 where pprRange :: Range -> Doc
423 pprRange (FromR e) = ppr e <> text ".."
424 pprRange (FromThenR e1 e2) = ppr e1 <> text ","
425 <> ppr e2 <> text ".."
426 pprRange (FromToR e1 e2) = ppr e1 <> text ".." <> ppr e2
427 pprRange (FromThenToR e1 e2 e3) = ppr e1 <> text ","
428 <> ppr e2 <> text ".."
429 <> ppr e3
430
431 ------------------------------
432 where_clause :: [Dec] -> Doc
433 where_clause [] = empty
434 where_clause ds = nest nestDepth $ text "where" <+> vcat (map (ppr_dec False) ds)
435
436 showtextl :: Show a => a -> Doc
437 showtextl = text . map toLower . show
438