build system: Include CONF_LD_LINKER_OPTS in ALL_LD_OPTS
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.0.1], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands,
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42 FP_PROG_SORT
43
44 dnl ----------------------------------------------------------
45 FP_SETUP_PROJECT_VERSION
46
47 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
48 AC_SUBST([release], [1])
49
50 # First off, a distrib sanity check..
51 AC_CONFIG_SRCDIR([mk/config.mk.in])
52
53 dnl * We require autoconf version 2.60
54 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
55 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
56 dnl Using autoconf 2.59 started to give nonsense like this
57 dnl  #define SIZEOF_CHAR 0
58 dnl recently.
59 AC_PREREQ([2.60])
60
61 # -------------------------------------------------------------------------
62 # Prepare to generate the following header files
63 #
64 #
65 AC_CONFIG_HEADER(mk/config.h)
66
67 # No, semi-sadly, we don't do `--srcdir'...
68 if test x"$srcdir" != 'x.' ; then
69     echo "This configuration does not support the \`--srcdir' option.."
70     exit 1
71 fi
72
73 dnl --------------------------------------------------------------
74 dnl * Project specific configuration options
75 dnl --------------------------------------------------------------
76 dnl What follows is a bunch of options that can either be configured
77 dnl through command line options to the configure script or by
78 dnl supplying defns in the build tree's mk/build.mk. Having the option to
79 dnl use either is considered a Feature.
80
81 dnl ** What command to use to compile compiler sources ?
82 dnl --------------------------------------------------------------
83
84 AC_ARG_WITH([ghc],
85 [AC_HELP_STRING([--with-ghc=ARG],
86   [Use ARG as the path to GHC  [default=autodetect]])],
87   [WithGhc="$withval"],
88   [if test "$GHC" = ""; then
89     AC_PATH_PROG([GHC], [ghc])
90   fi
91   WithGhc="$GHC"])
92
93 dnl ** Tell the make system which OS we are using
94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
95 AC_SUBST(OSTYPE)
96
97 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
98 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
99                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
100         EnableBootstrapWithDevelSnaphost=YES,
101         EnableBootstrapWithDevelSnaphost=NO
102 )
103
104 AC_ARG_ENABLE(tarballs-autodownload,
105 [AC_HELP_STRING([--enable-tarballs-autodownload],
106                 [Automatically download Windows distribution binaries if needed.])],
107         TarballsAutodownload=YES,
108         TarballsAutodownload=NO
109 )
110 if test "$WithGhc" != ""; then
111   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
112
113   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
114      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
115   fi
116
117   AC_SUBST(GhcVersion)dnl
118   AC_SUBST(GhcMajVersion)dnl
119   AC_SUBST(GhcMinVersion)dnl
120   AC_SUBST(GhcPatchLevel)dnl
121   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
122   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
123
124   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
125   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
126   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
127   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
128   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
129 fi
130
131 dnl ** Must have GHC to build GHC
132 if test "$WithGhc" = ""
133 then
134     AC_MSG_ERROR([GHC is required.])
135 fi
136 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.8],
137     [AC_MSG_ERROR([GHC version 7.8 or later is required to compile GHC.])])
138
139 if test `expr $GhcMinVersion % 2` = "1"
140 then
141     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
142     then
143         AC_MSG_ERROR([
144      $WithGhc is a development snapshot of GHC, version $GhcVersion.
145      Bootstrapping using this version of GHC is not supported, and may not
146      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
147      or --with-ghc to specify a different GHC to use.])
148     fi
149 fi
150
151 GHC_PACKAGE_DB_FLAG=package-db
152 AC_SUBST(GHC_PACKAGE_DB_FLAG)
153
154 # GHC 7.7+ needs -fcmm-sink when compiling Parser.hs. See #8182
155 FP_COMPARE_VERSIONS([$GhcVersion],[-gt],[7.7],
156                     CMM_SINK_BOOTSTRAP_IS_NEEDED=YES,
157                     CMM_SINK_BOOTSTRAP_IS_NEEDED=NO)
158 AC_SUBST(CMM_SINK_BOOTSTRAP_IS_NEEDED)
159
160 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.9],
161                     SUPPORTS_COMPONENT_ID=NO,
162                     SUPPORTS_COMPONENT_ID=YES)
163 AC_SUBST(SUPPORTS_COMPONENT_ID)
164
165 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[7.11],
166                     SUPPORTS_THIS_UNIT_ID=NO,
167                     SUPPORTS_THIS_UNIT_ID=YES)
168 AC_SUBST(SUPPORTS_THIS_UNIT_ID)
169
170 # GHC is passed to Cabal, so we need a native path
171 if test "${WithGhc}" != ""
172 then
173     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
174
175     if test "$ghc_host_os" = "mingw32"
176     then
177         if test "${OSTYPE}" = "msys"
178         then
179             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
180         else
181             # Canonicalise to <drive>:/path/to/ghc
182             WithGhc=`cygpath -m "${WithGhc}"`
183         fi
184         echo "GHC path canonicalised to: ${WithGhc}"
185     fi
186 fi
187 AC_SUBST([WithGhc])
188
189 dnl ** Without optimization some INLINE trickery fails for GHCi
190 SRC_CC_OPTS="-O"
191
192 dnl--------------------------------------------------------------------
193 dnl * Choose host(/target/build) platform
194 dnl--------------------------------------------------------------------
195 dnl If we aren't explicitly told what values to use with configure flags,
196 dnl we ask the bootstrapping compiler what platform it is for
197
198 if test "${WithGhc}" != ""
199 then
200         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
201         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
202         if test "$bootstrap_host" != "$bootstrap_target"
203         then
204                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
205         fi
206 fi
207
208 # We have to run these unconditionally, but we may discard their
209 # results in the following code
210 AC_CANONICAL_BUILD
211 AC_CANONICAL_HOST
212 AC_CANONICAL_TARGET
213
214 FPTOOLS_SET_PLATFORM_VARS
215
216 # Verify that the installed (bootstrap) GHC is capable of generating
217 # code for the requested build platform.
218 if test "$BuildPlatform" != "$bootstrap_target"
219 then
220     echo "This GHC (${WithGhc}) does not generate code for the build platform"
221     echo "   GHC target platform    : $bootstrap_target"
222     echo "   Desired build platform : $BuildPlatform"
223     exit 1
224 fi
225
226 # Testing if we shall enable shared libs support on Solaris.
227 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
228
229 SOLARIS_BROKEN_SHLD=NO
230
231 case $host in
232      i386-*-solaris2)
233      # here we go with the test
234      MINOR=`uname -r|cut -d '.' -f 2-`
235      if test "$MINOR" -lt "11"; then
236          SOLARIS_BROKEN_SHLD=YES
237      fi
238      ;;
239 esac
240
241 AC_SUBST(SOLARIS_BROKEN_SHLD)
242
243 dnl ** Do an unregisterised build?
244 dnl --------------------------------------------------------------
245 case "$HostArch" in
246     i386|x86_64|powerpc|powerpc64|powerpc64le|arm)
247         UnregisterisedDefault=NO
248         ;;
249     *)
250         UnregisterisedDefault=YES
251         ;;
252 esac
253 AC_ARG_ENABLE(unregisterised,
254 [AC_HELP_STRING([--enable-unregisterised],
255 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
256 [ if test x"$enableval" = x"yes"; then
257         Unregisterised=YES
258   else
259         Unregisterised=NO
260   fi
261 ],
262 [Unregisterised="$UnregisterisedDefault"]
263 )
264 AC_SUBST(Unregisterised)
265
266 AC_ARG_WITH(hc,
267 [AC_HELP_STRING([--with-hc=ARG],
268         [Use ARG as the path to the compiler for compiling ordinary
269          Haskell code  (default= value of --with-ghc)])],
270 [WithHc="$withval"],
271 [WithHc=$WithGhc]
272 )
273 AC_SUBST(WithHc)
274
275 # This uses GHC, so put it after the "GHC is required" check above:
276 FP_INTREE_GHC_PWD
277 FP_FIND_ROOT
278
279 fail() {
280     echo >&2
281     echo "$1" >&2
282     exit 1
283 }
284
285
286 if test "$HostOS" = "mingw32"
287 then
288     # Find the mingw-w64 7z file to extract.
289     # NB. If you update the tarballs to a new version of gcc, don't
290     # forget to tweak the paths in driver/gcc/gcc.c.
291     if test "$HostArch" = "i386"
292     then
293         mingw_arch="i686"
294         tarball_dest_dir="mingw-w64/x86"
295         tarball_mingw_dir="mingw32"
296     else
297         mingw_arch="x86_64"
298         tarball_dest_dir="mingw-w64/x86_64"
299         tarball_mingw_dir="mingw64"
300     fi
301 fi
302
303 set_up_tarballs() {
304     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
305     local action
306     if test "$TarballsAutodownload" = "NO"
307     then
308         action="verify"
309     else
310         action="download"
311     fi
312     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
313     case $? in
314         0)
315            rm missing-win32-tarballs
316            ;;
317         2)
318            echo
319            echo "Error:"
320            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
321            echo
322            echo "  * run configure with the --enable-tarballs-autodownload option"
323            echo
324            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
325            echo
326            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
327            echo "    them in the ghc-tarballs directory."
328            echo
329            exit 1
330            ;;
331         *)
332            echo
333            echo "Error fetching msys2 tarballs; see errors above."
334            exit 1
335            ;;
336     esac
337
338     # Extract all the tarballs in one go
339     if ! test -d inplace/mingw
340     then
341         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
342         rm -rf inplace/mingw
343         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
344         ( cd inplace &&
345         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
346         rm ".MTREE" &&
347         rm ".PKGINFO" &&
348         cd .. ) || fail "Error: Could not extract Windows toolchains."
349
350         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
351         touch inplace/mingw
352
353         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
354         # make a wrapper around it to give it the proper paths
355         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
356         PATH=`pwd`/inplace/mingw/bin:$PATH
357         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
358
359         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
360     fi
361 }
362
363 if test "$HostOS" = "mingw32"
364 then
365     test -d inplace || mkdir inplace
366
367     # NB. Download and extract the MingW-w64 distribution if required
368     set_up_tarballs
369
370     mingwbin="$hardtop/inplace/mingw/bin/"
371     CC="${mingwbin}gcc.exe"
372     LD="${mingwbin}ld.exe"
373     NM="${mingwbin}nm.exe"
374     RANLIB="${mingwbin}ranlib.exe"
375     OBJDUMP="${mingwbin}objdump.exe"
376     fp_prog_ar="${mingwbin}ar.exe"
377
378     # NB. Download the perl binaries if required
379     if ! test -d inplace/perl ||
380          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
381     then
382         AC_MSG_NOTICE([Making in-tree perl tree])
383         rm -rf inplace/perl
384         mkdir inplace/perl
385         (
386             cd inplace/perl &&
387             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
388         )
389         AC_MSG_NOTICE([In-tree perl tree created])
390     fi
391 fi
392
393 FP_ICONV
394 FP_GMP
395 FP_CURSES
396
397 XCODE_VERSION()
398
399 SplitObjsBroken=NO
400 if test "$TargetOS_CPP" = "darwin"
401 then
402     # Split objects is broken (#4013) with XCode < 3.2
403     if test "$XCodeVersion1" -lt 3
404     then
405         SplitObjsBroken=YES
406     else
407         if test "$XCodeVersion1" -eq 3
408         then
409             if test "$XCodeVersion2" -lt 2
410             then
411                 SplitObjsBroken=YES
412             fi
413         fi
414     fi
415 fi
416 AC_SUBST([SplitObjsBroken])
417
418 dnl ** Building a cross compiler?
419 dnl --------------------------------------------------------------
420 CrossCompiling=NO
421 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
422 if test "$TargetPlatform" != "$HostPlatform" ; then
423     CrossCompiling=YES
424     cross_compiling=yes   # This tells configure that it can accept just 'target',
425                           # otherwise you get
426                           #   configure: error: cannot run C compiled programs.
427                           #   If you meant to cross compile, use `--host'.
428 fi
429 if test "$BuildPlatform" != "$HostPlatform" ; then
430    AC_MSG_ERROR([
431 You've selected:
432
433   BUILD:  $BuildPlatform   (the architecture we're building on)
434   HOST:   $HostPlatform    (the architecture the compiler we're building will execute on)
435   TARGET: $TargetPlatform  (the architecture the compiler we're building will produce code for)
436
437 BUILD must equal HOST; that is, we do not support building GHC itself
438 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
439 1 will be a cross-compiler, and stage 2 will be the cross-compiled
440 GHC.
441 ])
442 fi
443 if test "$CrossCompiling" = "YES"
444 then
445   CrossCompilePrefix="${target}-"
446 else
447   CrossCompilePrefix=""
448 fi
449 TargetPlatformFull="${TargetPlatform}"
450 AC_SUBST(CrossCompiling)
451 AC_SUBST(CrossCompilePrefix)
452 AC_SUBST(TargetPlatformFull)
453
454 dnl ** Which gcc to use?
455 dnl --------------------------------------------------------------
456 FIND_GCC([WhatGccIsCalled], [gcc], [gcc])
457 CC="$WhatGccIsCalled"
458 export CC
459
460 # If --with-gcc was used, and we're not cross-compiling, then it also
461 # applies to the stage0 compiler.
462 MAYBE_OVERRIDE_STAGE0([gcc],[CC_STAGE0])
463 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
464
465 dnl make extensions visible to allow feature-tests to detect them lateron
466 AC_USE_SYSTEM_EXTENSIONS
467
468 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
469 AC_PROG_CPP
470
471 # --with-hs-cpp/--with-hs-cpp-flags
472 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
473 AC_SUBST([HaskellCPPCmd])
474 AC_SUBST([HaskellCPPArgs])
475
476 dnl ** Which ld to use?
477 dnl --------------------------------------------------------------
478 FIND_LD([LdCmd])
479 AC_SUBST([LdCmd])
480
481 dnl ** Which nm to use?
482 dnl --------------------------------------------------------------
483 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm], [nm])
484 NmCmd="$NM"
485 AC_SUBST([NmCmd])
486
487 dnl ** Which objdump to use?
488 dnl --------------------------------------------------------------
489 FP_ARG_WITH_PATH_GNU_PROG_OPTIONAL([OBJDUMP], [objdump], [objdump])
490 ObjdumpCmd="$OBJDUMP"
491 AC_SUBST([ObjdumpCmd])
492
493 dnl ** Which ar to use?
494 dnl --------------------------------------------------------------
495 FP_ARG_WITH_PATH_GNU_PROG([AR], [ar], [ar])
496 ArCmd="$AR"
497 fp_prog_ar="$AR"
498 AC_SUBST([ArCmd])
499
500 dnl ** Which ranlib to use?
501 dnl --------------------------------------------------------------
502 FP_ARG_WITH_PATH_GNU_PROG([RANLIB], [ranlib], [ranlib])
503 RanlibCmd="$RANLIB"
504 RANLIB="$RanlibCmd"
505
506
507 # Note: we may not have objdump on OS X, and we only need it on Windows (for DLL checks)
508 case $HostOS_CPP in
509 cygwin32|mingw32)
510     dnl ** Which objdump to use?
511     dnl --------------------------------------------------------------
512     FP_ARG_WITH_PATH_GNU_PROG([OBJDUMP], [objdump], [objdump])
513     ObjdumpCmd="$OBJDUMP"
514     AC_SUBST([ObjdumpCmd])
515     ;;
516 esac
517
518 # Here is where we re-target which specific version of the LLVM
519 # tools we are looking for. In the past, GHC supported a number of
520 # versions of LLVM simultaneously, but that stopped working around
521 # 3.5/3.6 release of LLVM.
522 LlvmVersion=3.7
523 AC_SUBST([LlvmVersion])
524 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
525 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
526
527 dnl ** Which LLVM llc to use?
528 dnl --------------------------------------------------------------
529 FIND_LLVM_PROG([LLC], [llc], [llc], [$LlvmVersion])
530 LlcCmd="$LLC"
531 AC_SUBST([LlcCmd])
532
533 dnl ** Which LLVM opt to use?
534 dnl --------------------------------------------------------------
535 FIND_LLVM_PROG([OPT], [opt], [opt], [$LlvmVersion])
536 OptCmd="$OPT"
537 AC_SUBST([OptCmd])
538
539 dnl --------------------------------------------------------------
540 dnl End of configure script option section
541 dnl --------------------------------------------------------------
542
543
544 dnl --------------------------------------------------------------
545 dnl * General configuration checks
546 dnl --------------------------------------------------------------
547
548 dnl ** Bug 9439: Some GHC 7.8 releases had broken LLVM code generator.
549 dnl Unfortunately we don't know whether the user is going to request a
550 dnl build with the LLVM backend as this is only given in build.mk.
551 dnl
552 dnl Instead, we try to do as much work as possible here, checking
553 dnl whether -fllvm is the stage 0 compiler's default. If so we
554 dnl fail. If not, we check whether -fllvm is affected explicitly and
555 dnl if so set a flag. The build system will later check this flag
556 dnl after the desired build flags are known.
557
558 dnl This problem is further complicated by the fact that the llvm
559 dnl version used by the bootstrap compiler may be different from the
560 dnl version we arre trying to compile GHC against. Therefore, we need
561 dnl to find the boostrap compiler's `settings` file then check to see
562 dnl if the `opt` and `llc` command strings are non-empty and if these
563 dnl programs exist. Only if they exist to we test for bug #9439.
564
565 FIND_GHC_BOOTSTRAP_PROG([BootstrapLlcCmd], [${WithGhc}], "LLVM llc command")
566 FIND_GHC_BOOTSTRAP_PROG([BootstrapOptCmd], [${WithGhc}], "LLVM opt command")
567
568 if test -n "$BootstrapLlcCmd" && test -n "$BootstrapOptCmd"
569 then
570     AC_MSG_CHECKING(whether bootstrap compiler is affected by bug 9439)
571     echo "main = putStrLn \"%function\"" > conftestghc.hs
572
573     # Check whether LLVM backend is default for this platform
574     "${WithGhc}" -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" conftestghc.hs 2>&1 >/dev/null
575     res=`./conftestghc`
576     if test "x$res" = "x%object"
577     then
578         AC_MSG_RESULT(yes)
579         echo "Buggy bootstrap compiler"
580         echo ""
581         echo "The stage 0 compiler $WithGhc is affected by GHC Bug \#9439"
582         echo "and therefore will miscompile the LLVM backend if -fllvm is"
583         echo "used."
584         echo
585         echo "Please use another bootstrap compiler"
586         exit 1
587     fi
588
589     # -fllvm is not the default, but set a flag so the Makefile can check
590     # -for it in the build flags later on
591     "${WithGhc}" -fforce-recomp -pgmlc="${BootstrapLlcCmd}" -pgmlo="${BootstrapOptCmd}" -fllvm conftestghc.hs 2>&1 >/dev/null
592     if test $? = 0
593     then
594         res=`./conftestghc`
595         if test "x$res" = "x%object"
596         then
597             AC_MSG_RESULT(yes)
598             GHC_LLVM_AFFECTED_BY_9439=1
599         elif test "x$res" = "x%function"
600         then
601             AC_MSG_RESULT(no)
602             GHC_LLVM_AFFECTED_BY_9439=0
603         else
604             AC_MSG_WARN(unexpected output $res)
605         fi
606     else
607         AC_MSG_RESULT(failed to compile, assuming no)
608     fi
609 fi
610 AC_SUBST([GHC_LLVM_AFFECTED_BY_9439])
611
612 dnl ** Can the unix package be built?
613 dnl --------------------------------------------------------------
614
615 if test "$TargetOS" = "mingw32"
616 then
617     GhcLibsWithUnix=NO
618 else
619     GhcLibsWithUnix=YES
620 fi
621 AC_SUBST([GhcLibsWithUnix])
622
623 dnl ** does #! work?
624 AC_SYS_INTERPRETER()
625
626 dnl ** look for `perl'
627 case $HostOS_CPP in
628 cygwin32|mingw32)
629     PerlCmd=$hardtop/inplace/perl/perl
630     ;;
631 *)
632     AC_PATH_PROG(PerlCmd,perl)
633     if test -z "$PerlCmd"
634     then
635         echo "You must install perl before you can continue"
636         echo "Perhaps it is already installed, but not in your PATH?"
637         exit 1
638     else
639         FPTOOLS_CHECK_PERL_VERSION
640     fi
641     ;;
642 esac
643
644 dnl ** look for GCC and find out which version
645 dnl     Figure out which C compiler to use.  Gcc is preferred.
646 dnl     If gcc, make sure it's at least 3.0
647 dnl
648 FP_GCC_VERSION
649
650 dnl ** look to see if we have a C compiler using an llvm back end.
651 dnl
652 FP_CC_LLVM_BACKEND
653
654 FP_PROG_LD_IS_GNU
655 FP_PROG_LD_BUILD_ID
656 FP_PROG_LD_NO_COMPACT_UNWIND
657 FP_PROG_LD_FILELIST
658
659
660 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
661 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
662 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
663 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
664 # Stage 3 won't be supported by cross-compilation
665
666 FP_GCC_EXTRA_FLAGS
667
668 # See rules/distdir-way-opts.mk for details.
669 # Flags passed to the C compiler
670 AC_SUBST(CONF_CC_OPTS_STAGE0)
671 AC_SUBST(CONF_CC_OPTS_STAGE1)
672 AC_SUBST(CONF_CC_OPTS_STAGE2)
673 # Flags passed to the C compiler when we ask it to link
674 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
675 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
676 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
677 # Flags passed to the linker when we ask it to link
678 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
679 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
680 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
681 # Flags passed to the C preprocessor
682 AC_SUBST(CONF_CPP_OPTS_STAGE0)
683 AC_SUBST(CONF_CPP_OPTS_STAGE1)
684 AC_SUBST(CONF_CPP_OPTS_STAGE2)
685
686 dnl ** Set up the variables for the platform in the settings file.
687 dnl May need to use gcc to find platform details.
688 dnl --------------------------------------------------------------
689 FPTOOLS_SET_HASKELL_PLATFORM_VARS
690
691 dnl ** figure out how to do context diffs
692 FP_PROG_CONTEXT_DIFF
693
694 dnl Let's make sure install-sh is executable here.  If we got it from
695 dnl a darcs repo, it might not be (see bug #978).
696 chmod +x install-sh
697 dnl ** figure out how to do a BSD-ish install
698 AC_PROG_INSTALL
699
700 dnl ** how to invoke `ar' and `ranlib'
701 FP_PROG_AR_SUPPORTS_ATFILE
702 FP_PROG_AR_NEEDS_RANLIB
703
704 dnl ** Check to see whether ln -s works
705 AC_PROG_LN_S
706
707 FP_SETTINGS
708
709 dnl ** Find the path to sed
710 AC_PATH_PROGS(SedCmd,gsed sed,sed)
711
712
713 dnl ** check for time command
714 AC_PATH_PROG(TimeCmd,time)
715
716 dnl ** check for tar
717 dnl   if GNU tar is named gtar, look for it first.
718 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
719
720 dnl ** check for patch
721 dnl if GNU patch is named gpatch, look for it first
722 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
723
724 dnl ** check for dtrace (currently only implemented for Mac OS X)
725 HaveDtrace=NO
726 AC_PATH_PROG(DtraceCmd,dtrace)
727 if test -n "$DtraceCmd"; then
728   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
729     HaveDtrace=YES
730   fi
731 fi
732 AC_SUBST(HaveDtrace)
733
734 AC_PATH_PROG(HSCOLOUR,HsColour)
735 # HsColour is passed to Cabal, so we need a native path
736 if test "$HostOS"      = "mingw32" && \
737    test "${OSTYPE}"   != "msys"    && \
738    test "${HSCOLOUR}" != ""
739 then
740     # Canonicalise to <drive>:/path/to/gcc
741     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
742 fi
743
744 dnl ** check for Sphinx toolchain
745 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
746 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
747 changequote(, )dnl
748 [if test -n "$SPHINXBUILD"; then
749   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
750 fi;
751 changequote([, ])dnl
752 ])
753 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
754     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
755
756 dnl ** check for xelatex
757 AC_PATH_PROG(XELATEX,xelatex)
758
759 dnl ** check for ghc-pkg command
760 FP_PROG_GHC_PKG
761
762 dnl ** check for installed happy binary + version
763 FPTOOLS_HAPPY
764
765 dnl ** check for installed alex binary + version
766 FPTOOLS_ALEX
767
768 dnl --------------------------------------------------
769 dnl ### program checking section ends here ###
770 dnl --------------------------------------------------
771
772 dnl --------------------------------------------------
773 dnl * Platform header file and syscall feature tests
774 dnl ### checking the state of the local header files and syscalls ###
775
776 dnl ** check for full ANSI header (.h) files
777 AC_HEADER_STDC
778
779 dnl ** Enable large file support.  NB. do this before testing the type of
780 dnl    off_t, because it will affect the result of that test.
781 AC_SYS_LARGEFILE
782
783 dnl ** check for specific header (.h) files that we are interested in
784 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
785
786 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
787 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
788 [[#if HAVE_SYS_PARAM_H
789 # include <sys/param.h>
790 #endif
791 ]])
792
793 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
794 AC_HEADER_TIME
795
796 dnl ** do we have long longs?
797 AC_CHECK_TYPES([long long])
798
799 dnl ** what are the sizes of various types
800 AC_CHECK_SIZEOF(char,               1)
801 AC_CHECK_SIZEOF(double,             8)
802 AC_CHECK_SIZEOF(float,              4)
803 AC_CHECK_SIZEOF(int,                4)
804 AC_CHECK_SIZEOF(long,               4)
805 if test "$ac_cv_type_long_long" = yes; then
806 AC_CHECK_SIZEOF(long long,          8)
807 fi
808 AC_CHECK_SIZEOF(short,              2)
809 AC_CHECK_SIZEOF(unsigned char,      1)
810 AC_CHECK_SIZEOF(unsigned int,       4)
811 AC_CHECK_SIZEOF(unsigned long,      4)
812 if test "$ac_cv_type_long_long" = yes; then
813 AC_CHECK_SIZEOF(unsigned long long, 8)
814 fi
815 AC_CHECK_SIZEOF(unsigned short,     2)
816 AC_CHECK_SIZEOF(void *,             4)
817
818 dnl for use in settings.in
819 WordSize=$ac_cv_sizeof_void_p
820 AC_SUBST(WordSize)
821
822 dnl ** what are alignment constraints on various types
823 FP_CHECK_ALIGNMENT(char)
824 FP_CHECK_ALIGNMENT(double)
825 FP_CHECK_ALIGNMENT(float)
826 FP_CHECK_ALIGNMENT(int)
827 FP_CHECK_ALIGNMENT(long)
828 if test "$ac_cv_type_long_long" = yes; then
829 FP_CHECK_ALIGNMENT(long long)
830 fi
831 FP_CHECK_ALIGNMENT(short)
832 FP_CHECK_ALIGNMENT(unsigned char)
833 FP_CHECK_ALIGNMENT(unsigned int)
834 FP_CHECK_ALIGNMENT(unsigned long)
835 if test "$ac_cv_type_long_long" = yes; then
836 FP_CHECK_ALIGNMENT(unsigned long long)
837 fi
838 FP_CHECK_ALIGNMENT(unsigned short)
839 FP_CHECK_ALIGNMENT(void *)
840
841 FP_CHECK_FUNC([WinExec],
842   [@%:@include <windows.h>], [WinExec("",0)])
843
844 FP_CHECK_FUNC([GetModuleFileName],
845   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
846
847 dnl ** check for more functions
848 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
849 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
850
851 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
852 dnl ** _POSIX_C_SOURCE is defined
853 AC_CHECK_DECLS([ctime_r], , ,
854 [#define _POSIX_SOURCE 1
855 #define _POSIX_C_SOURCE 199506L
856 #include <time.h>])
857
858 dnl ** check for mingwex library
859 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
860 AC_SUBST(HaveLibMingwEx)
861
862 if test $HaveLibMingwEx = YES ; then
863   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
864 fi
865
866 dnl ** check for math library
867 dnl    Keep that check as early as possible.
868 dnl    as we need to know whether we need libm
869 dnl    for math functions or not
870 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
871 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
872 if test $HaveLibM = YES
873 then
874   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
875 fi
876
877 FP_BFD_SUPPORT
878
879 dnl ################################################################
880 dnl Check for libraries
881 dnl ################################################################
882
883 # system libffi
884
885 AC_ARG_WITH([system-libffi],
886 [AC_HELP_STRING([--with-system-libffi],
887   [Use system provided libffi for RTS [default=no]])
888 ])
889
890 AS_IF([test "x$with_system_libffi" = "xyes"],
891   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
892 )
893
894
895 AC_SUBST(UseSystemLibFFI)
896
897 AC_ARG_WITH([ffi-includes],
898 [AC_HELP_STRING([--with-ffi-includes=ARG],
899   [Find includes for libffi in ARG [default=system default]])
900 ],
901 [
902  if test "x$UseSystemLibFFI" != "xYES"; then
903     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
904  else
905     FFIIncludeDir="$withval"
906     LIBFFI_CFLAGS="-I$withval"
907  fi
908 ])
909
910 AC_SUBST(FFIIncludeDir)
911
912 AC_ARG_WITH([ffi-libraries],
913 [AC_HELP_STRING([--with-ffi-libraries=ARG],
914   [Find libffi in ARG [default=system default]])
915 ],
916 [
917  if test "x$UseSystemLibFFI" != "xYES"; then
918     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
919  else
920     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
921  fi
922 ])
923
924 AC_SUBST(FFILibDir)
925
926 AS_IF([test "$UseSystemLibFFI" = "YES"], [
927  CFLAGS2="$CFLAGS"
928  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
929  LDFLAGS2="$LDFLAGS"
930  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
931  if test "$HostOS" = "openbsd";
932  then
933    # OpenBSD's libffi is not directly linked to the libpthread but
934    # still requires pthread functionality. This means that any client
935    # binary which links with libffi also needs to link with
936    # libpthread. If it does not, then linking fails with unresolved
937    # symbols.
938    LDFLAGS="$LDFLAGS -lpthread"
939  fi
940  AC_CHECK_LIB(ffi, ffi_call,
941   [AC_CHECK_HEADERS([ffi.h], [break], [])
942    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])],
943   [AC_MSG_ERROR([Cannot find system libffi])])
944  CFLAGS="$CFLAGS2"
945  LDFLAGS="$LDFLAGS2"
946 ])
947
948 dnl ** check whether we need -ldl to get dlopen()
949 AC_CHECK_LIB(dl, dlopen)
950
951 dnl --------------------------------------------------
952 dnl * Miscellaneous feature tests
953 dnl --------------------------------------------------
954
955 dnl ** can we get alloca?
956 AC_FUNC_ALLOCA
957
958 dnl ** working vfork?
959 AC_FUNC_FORK
960
961 dnl ** determine whether or not const works
962 AC_C_CONST
963
964 dnl ** are we big endian?
965 AC_C_BIGENDIAN
966 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
967
968 dnl ** check for leading underscores in symbol names
969 FP_LEADING_UNDERSCORE
970
971 FP_VISIBILITY_HIDDEN
972
973 dnl ** check for librt
974 AC_CHECK_LIB(rt, clock_gettime)
975 AC_CHECK_FUNCS(clock_gettime timer_settime)
976 FP_CHECK_TIMER_CREATE
977
978 dnl ** check for Apple's "interesting" long double compatibility scheme
979 AC_MSG_CHECKING(for printf\$LDBLStub)
980 AC_TRY_LINK_FUNC(printf\$LDBLStub,
981     [
982         AC_MSG_RESULT(yes)
983         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
984             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
985     ],
986     [
987         AC_MSG_RESULT(no)
988         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
989             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
990     ])
991
992 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
993 dnl    a different single-argument version.
994 AC_CHECK_LIB(pthread, pthread_setname_np)
995 AC_MSG_CHECKING(for pthread_setname_np)
996 AC_TRY_LINK(
997 [
998 #define _GNU_SOURCE
999 #include <pthread.h>
1000 ],
1001 [pthread_setname_np(pthread_self(), "name");],
1002     AC_MSG_RESULT(yes)
1003     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
1004       [Define to 1 if you have the glibc version of pthread_setname_np]),
1005     AC_MSG_RESULT(no)
1006 )
1007
1008 dnl ** check for eventfd which is needed by the I/O manager
1009 AC_CHECK_HEADERS([sys/eventfd.h])
1010 AC_CHECK_FUNCS([eventfd])
1011
1012 dnl ** Check for __thread support in the compiler
1013 AC_MSG_CHECKING(for __thread support)
1014 AC_COMPILE_IFELSE(
1015   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1016   [
1017    AC_MSG_RESULT(yes)
1018    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1019   ],
1020   [
1021    AC_MSG_RESULT(no)
1022    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1023   ])
1024
1025 dnl large address space support (see includes/rts/storage/MBlock.h)
1026 dnl
1027 dnl Darwin has vm_allocate/vm_protect
1028 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1029 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1030 dnl (They also have MADV_DONTNEED, but it means something else!)
1031 dnl
1032 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1033 dnl it counts page-table space as committed memory, and so quickly
1034 dnl runs out of paging file when we have multiple processes reserving
1035 dnl 1TB of address space, we get the following error:
1036 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1037 dnl
1038
1039 AC_ARG_ENABLE(large-address-space,
1040     [AC_HELP_STRING([--enable-large-address-space],
1041         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1042     EnableLargeAddressSpace=$enableval,
1043     EnableLargeAddressSpace=yes
1044 )
1045
1046 use_large_address_space=no
1047 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1048     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1049         if test "$ghc_host_os" = "darwin" ; then
1050             use_large_address_space=yes
1051         elif test "$ghc_host_os" = "openbsd" ; then
1052             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1053             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1054             # but is completely ignored by OS mmap
1055             use_large_address_space=no
1056         else
1057             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1058                 [
1059                 #include <unistd.h>
1060                 #include <sys/types.h>
1061                 #include <sys/mman.h>
1062                 #include <fcntl.h>
1063             ])
1064             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1065                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1066                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1067                     use_large_address_space=yes
1068             fi
1069         fi
1070     fi
1071 fi
1072 if test "$use_large_address_space" = "yes" ; then
1073    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1074 fi
1075
1076 dnl ** Have libdw?
1077 dnl --------------------------------------------------------------
1078 AC_ARG_ENABLE(libdw,
1079     [AC_HELP_STRING([--enable-dwarf-unwind],
1080         [Enable DWARF unwinding support in the runtime system via elfutils' libdw [default=no]])],
1081     [AC_CHECK_LIB(dw, dwfl_attach_state, [HaveLibdw=YES], [HaveLibdw=NO])],
1082     [HaveLibdw=NO]
1083 )
1084 AC_SUBST(HaveLibdw)
1085
1086 if test -n "$SPHINXBUILD"; then
1087     BUILD_MAN=YES
1088     BUILD_SPHINX_HTML=YES
1089     if test -n "$XELATEX"; then
1090         BUILD_SPHINX_PDF=YES
1091     else
1092         BUILD_SPHINX_PDF=NO
1093     fi
1094 else
1095     BUILD_MAN=NO
1096     BUILD_SPHINX_HTML=NO
1097     BUILD_SPHINX_PDF=NO
1098 fi
1099 AC_SUBST(BUILD_MAN)
1100 AC_SUBST(BUILD_SPHINX_HTML)
1101 AC_SUBST(BUILD_SPHINX_PDF)
1102
1103 LIBRARY_VERSION(base)
1104 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1105 LIBRARY_VERSION(ghc-prim)
1106 LIBRARY_ghc_VERSION="$ProjectVersion"
1107 AC_SUBST(LIBRARY_ghc_VERSION)
1108
1109 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1110    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1111 fi
1112
1113 # Create the configuration for the Shake-based build system if it is present
1114 if test -e shake-build/cfg/system.config.in; then
1115     AC_CONFIG_FILES([shake-build/cfg/system.config])
1116 fi
1117
1118 # We got caught by
1119 #     http://savannah.gnu.org/bugs/index.php?1516
1120 #     $(eval ...) inside conditionals causes errors
1121 # with make 3.80, so warn the user if it looks like they're about to
1122 # try to use it.
1123 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1124 print_make_warning=""
1125 checkMake380() {
1126     make_ver=`$1 --version 2>&1 | head -1`
1127     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1128     then
1129         print_make_warning="true"
1130     fi
1131     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1132     then
1133         MakeCmd=$1
1134         AC_SUBST(MakeCmd)
1135     fi
1136 }
1137
1138 checkMake380 make
1139 checkMake380 gmake
1140
1141 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghc-boot-th/ghc-boot-th.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt distrib/configure.ac])
1142 AC_OUTPUT
1143
1144 if test "$print_make_warning" = "true"; then
1145    echo
1146    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1147    echo "This version cannot be used to build GHC."
1148    echo "Please use GNU make >= 3.81."
1149 fi
1150
1151 echo ["
1152 ----------------------------------------------------------------------
1153 Configure completed successfully.
1154
1155    Building GHC version  : $ProjectVersion
1156           Git commit id  : $ProjectGitCommitId
1157
1158    Build platform        : $BuildPlatform
1159    Host platform         : $HostPlatform
1160    Target platform       : $TargetPlatform
1161 "]
1162
1163 echo ["\
1164    Bootstrapping using   : $WithGhc
1165       which is version   : $GhcVersion
1166 "]
1167
1168 if test "x$CC_LLVM_BACKEND" = "x1"; then
1169     if test "x$CC_CLANG_BACKEND" = "x1"; then
1170         CompilerName="clang        "
1171     else
1172         CompilerName="llvm-gcc     "
1173     fi
1174 else
1175     CompilerName="gcc          "
1176 fi
1177
1178 echo ["\
1179    Using $CompilerName       : $WhatGccIsCalled
1180       which is version       : $GccVersion
1181    Building a cross compiler : $CrossCompiling
1182    hs-cpp       : $HaskellCPPCmd
1183    hs-cpp-flags : $HaskellCPPArgs
1184    ld           : $LdCmd
1185    nm           : $NmCmd
1186    objdump      : $ObjdumpCmd
1187    Happy        : $HappyCmd ($HappyVersion)
1188    Alex         : $AlexCmd ($AlexVersion)
1189    Perl         : $PerlCmd
1190    sphinx-build : $SPHINXBUILD
1191    xelatex      : $XELATEX
1192
1193    Using LLVM tools
1194       llc   : $LlcCmd
1195       opt   : $OptCmd"]
1196
1197 if test "$HSCOLOUR" = ""; then
1198 echo ["
1199    HsColour was not found; documentation will not contain source links
1200 "]
1201 else
1202 echo ["\
1203    HsColour : $HSCOLOUR
1204 "]
1205 fi
1206
1207 echo ["\
1208    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1209    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"]
1210
1211 echo ["----------------------------------------------------------------------
1212 "]
1213
1214 echo "\
1215 For a standard build of GHC (fully optimised with profiling), type (g)make.
1216
1217 To make changes to the default build configuration, copy the file
1218 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1219
1220 For more information on how to configure your GHC build, see
1221    http://ghc.haskell.org/trac/ghc/wiki/Building
1222 "