Overhaul of infrastructure for profiling, coverage (HPC) and breakpoints
[ghc.git] / compiler / ghci / ByteCodeGen.lhs
1 %
2 % (c) The University of Glasgow 2002-2006
3 %
4
5 ByteCodeGen: Generate bytecode from Core
6
7 \begin{code}
8 module ByteCodeGen ( UnlinkedBCO, byteCodeGen, coreExprToBCOs ) where
9
10 #include "HsVersions.h"
11
12 import ByteCodeInstr
13 import ByteCodeItbls
14 import ByteCodeAsm
15 import ByteCodeLink
16 import LibFFI
17
18 import Outputable
19 import Name
20 import MkId
21 import Id
22 import ForeignCall
23 import HscTypes
24 import CoreUtils
25 import CoreSyn
26 import PprCore
27 import Literal
28 import PrimOp
29 import CoreFVs
30 import Type
31 import DataCon
32 import TyCon
33 import Util
34 import VarSet
35 import TysPrim
36 import DynFlags
37 import ErrUtils
38 import Unique
39 import FastString
40 import Panic
41 import SMRep
42 import ClosureInfo
43 import Bitmap
44 import OrdList
45 import Constants
46
47 import Data.List
48 import Foreign
49 import Foreign.C
50
51 import Control.Monad
52 import Data.Char
53
54 import UniqSupply
55 import BreakArray
56 import Data.Maybe
57 import Module
58
59 import Data.Map (Map)
60 import qualified Data.Map as Map
61 import qualified FiniteMap as Map
62
63 -- -----------------------------------------------------------------------------
64 -- Generating byte code for a complete module
65
66 byteCodeGen :: DynFlags
67             -> Module
68             -> CoreProgram
69             -> [TyCon]
70             -> ModBreaks
71             -> IO CompiledByteCode
72 byteCodeGen dflags this_mod binds tycs modBreaks
73    = do showPass dflags "ByteCodeGen"
74
75         let flatBinds = [ (bndr, freeVars rhs)
76                         | (bndr, rhs) <- flattenBinds binds]
77
78         us <- mkSplitUniqSupply 'y'
79         (BcM_State _us _this_mod _final_ctr mallocd _, proto_bcos)
80            <- runBc us this_mod modBreaks (mapM schemeTopBind flatBinds)
81
82         when (notNull mallocd)
83              (panic "ByteCodeGen.byteCodeGen: missing final emitBc?")
84
85         dumpIfSet_dyn dflags Opt_D_dump_BCOs
86            "Proto-BCOs" (vcat (intersperse (char ' ') (map ppr proto_bcos)))
87
88         assembleBCOs dflags proto_bcos tycs
89
90 -- -----------------------------------------------------------------------------
91 -- Generating byte code for an expression
92
93 -- Returns: (the root BCO for this expression,
94 --           a list of auxilary BCOs resulting from compiling closures)
95 coreExprToBCOs :: DynFlags
96                -> Module
97                -> CoreExpr
98                -> IO UnlinkedBCO
99 coreExprToBCOs dflags this_mod expr
100  = do showPass dflags "ByteCodeGen"
101
102       -- create a totally bogus name for the top-level BCO; this
103       -- should be harmless, since it's never used for anything
104       let invented_name  = mkSystemVarName (mkPseudoUniqueE 0) (fsLit "ExprTopLevel")
105           invented_id    = Id.mkLocalId invented_name (panic "invented_id's type")
106
107       -- the uniques are needed to generate fresh variables when we introduce new
108       -- let bindings for ticked expressions
109       us <- mkSplitUniqSupply 'y'
110       (BcM_State _us _this_mod _final_ctr mallocd _ , proto_bco)
111          <- runBc us this_mod emptyModBreaks $
112               schemeTopBind (invented_id, freeVars expr)
113
114       when (notNull mallocd)
115            (panic "ByteCodeGen.coreExprToBCOs: missing final emitBc?")
116
117       dumpIfSet_dyn dflags Opt_D_dump_BCOs "Proto-BCOs" (ppr proto_bco)
118
119       assembleBCO dflags proto_bco
120
121
122 -- -----------------------------------------------------------------------------
123 -- Compilation schema for the bytecode generator
124
125 type BCInstrList = OrdList BCInstr
126
127 type Sequel = Word16 -- back off to this depth before ENTER
128
129 -- Maps Ids to the offset from the stack _base_ so we don't have
130 -- to mess with it after each push/pop.
131 type BCEnv = Map Id Word16 -- To find vars on the stack
132
133 {-
134 ppBCEnv :: BCEnv -> SDoc
135 ppBCEnv p
136    = text "begin-env"
137      $$ nest 4 (vcat (map pp_one (sortBy cmp_snd (Map.toList p))))
138      $$ text "end-env"
139      where
140         pp_one (var, offset) = int offset <> colon <+> ppr var <+> ppr (idCgRep var)
141         cmp_snd x y = compare (snd x) (snd y)
142 -}
143
144 -- Create a BCO and do a spot of peephole optimisation on the insns
145 -- at the same time.
146 mkProtoBCO
147    :: name
148    -> BCInstrList
149    -> Either  [AnnAlt Id VarSet] (AnnExpr Id VarSet)
150    -> Int
151    -> Word16
152    -> [StgWord]
153    -> Bool      -- True <=> is a return point, rather than a function
154    -> [BcPtr]
155    -> ProtoBCO name
156 mkProtoBCO nm instrs_ordlist origin arity bitmap_size bitmap is_ret mallocd_blocks
157    = ProtoBCO {
158         protoBCOName = nm,
159         protoBCOInstrs = maybe_with_stack_check,
160         protoBCOBitmap = bitmap,
161         protoBCOBitmapSize = bitmap_size,
162         protoBCOArity = arity,
163         protoBCOExpr = origin,
164         protoBCOPtrs = mallocd_blocks
165       }
166      where
167         -- Overestimate the stack usage (in words) of this BCO,
168         -- and if >= iNTERP_STACK_CHECK_THRESH, add an explicit
169         -- stack check.  (The interpreter always does a stack check
170         -- for iNTERP_STACK_CHECK_THRESH words at the start of each
171         -- BCO anyway, so we only need to add an explicit one in the
172         -- (hopefully rare) cases when the (overestimated) stack use
173         -- exceeds iNTERP_STACK_CHECK_THRESH.
174         maybe_with_stack_check
175            | is_ret && stack_usage < fromIntegral aP_STACK_SPLIM = peep_d
176                 -- don't do stack checks at return points,
177                 -- everything is aggregated up to the top BCO
178                 -- (which must be a function).
179                 -- That is, unless the stack usage is >= AP_STACK_SPLIM,
180                 -- see bug #1466.
181            | stack_usage >= fromIntegral iNTERP_STACK_CHECK_THRESH
182            = STKCHECK stack_usage : peep_d
183            | otherwise
184            = peep_d     -- the supposedly common case
185
186         -- We assume that this sum doesn't wrap
187         stack_usage = sum (map bciStackUse peep_d)
188
189         -- Merge local pushes
190         peep_d = peep (fromOL instrs_ordlist)
191
192         peep (PUSH_L off1 : PUSH_L off2 : PUSH_L off3 : rest)
193            = PUSH_LLL off1 (off2-1) (off3-2) : peep rest
194         peep (PUSH_L off1 : PUSH_L off2 : rest)
195            = PUSH_LL off1 (off2-1) : peep rest
196         peep (i:rest)
197            = i : peep rest
198         peep []
199            = []
200
201 argBits :: [CgRep] -> [Bool]
202 argBits [] = []
203 argBits (rep : args)
204   | isFollowableArg rep = False : argBits args
205   | otherwise = take (cgRepSizeW rep) (repeat True) ++ argBits args
206
207 -- -----------------------------------------------------------------------------
208 -- schemeTopBind
209
210 -- Compile code for the right-hand side of a top-level binding
211
212 schemeTopBind :: (Id, AnnExpr Id VarSet) -> BcM (ProtoBCO Name)
213
214
215 schemeTopBind (id, rhs)
216   | Just data_con <- isDataConWorkId_maybe id,
217     isNullaryRepDataCon data_con = do
218         -- Special case for the worker of a nullary data con.
219         -- It'll look like this:        Nil = /\a -> Nil a
220         -- If we feed it into schemeR, we'll get
221         --      Nil = Nil
222         -- because mkConAppCode treats nullary constructor applications
223         -- by just re-using the single top-level definition.  So
224         -- for the worker itself, we must allocate it directly.
225     -- ioToBc (putStrLn $ "top level BCO")
226     emitBc (mkProtoBCO (getName id) (toOL [PACK data_con 0, ENTER])
227                        (Right rhs) 0 0 [{-no bitmap-}] False{-not alts-})
228
229   | otherwise
230   = schemeR [{- No free variables -}] (id, rhs)
231
232
233 -- -----------------------------------------------------------------------------
234 -- schemeR
235
236 -- Compile code for a right-hand side, to give a BCO that,
237 -- when executed with the free variables and arguments on top of the stack,
238 -- will return with a pointer to the result on top of the stack, after
239 -- removing the free variables and arguments.
240 --
241 -- Park the resulting BCO in the monad.  Also requires the
242 -- variable to which this value was bound, so as to give the
243 -- resulting BCO a name.
244
245 schemeR :: [Id]                 -- Free vars of the RHS, ordered as they
246                                 -- will appear in the thunk.  Empty for
247                                 -- top-level things, which have no free vars.
248         -> (Id, AnnExpr Id VarSet)
249         -> BcM (ProtoBCO Name)
250 schemeR fvs (nm, rhs)
251 {-
252    | trace (showSDoc (
253               (char ' '
254                $$ (ppr.filter (not.isTyVar).varSetElems.fst) rhs
255                $$ pprCoreExpr (deAnnotate rhs)
256                $$ char ' '
257               ))) False
258    = undefined
259    | otherwise
260 -}
261    = schemeR_wrk fvs nm rhs (collect rhs)
262
263 collect :: AnnExpr Id VarSet -> ([Var], AnnExpr' Id VarSet)
264 collect (_, e) = go [] e
265   where
266     go xs e | Just e' <- bcView e = go xs e'
267     go xs (AnnLam x (_,e))        = go (x:xs) e
268     go xs not_lambda              = (reverse xs, not_lambda)
269
270 schemeR_wrk :: [Id] -> Id -> AnnExpr Id VarSet -> ([Var], AnnExpr' Var VarSet) -> BcM (ProtoBCO Name)
271 schemeR_wrk fvs nm original_body (args, body)
272    = let
273          all_args  = reverse args ++ fvs
274          arity     = length all_args
275          -- all_args are the args in reverse order.  We're compiling a function
276          -- \fv1..fvn x1..xn -> e
277          -- i.e. the fvs come first
278
279          szsw_args = map (fromIntegral . idSizeW) all_args
280          szw_args  = sum szsw_args
281          p_init    = Map.fromList (zip all_args (mkStackOffsets 0 szsw_args))
282
283          -- make the arg bitmap
284          bits = argBits (reverse (map idCgRep all_args))
285          bitmap_size = genericLength bits
286          bitmap = mkBitmap bits
287      in do
288      body_code <- schemeER_wrk szw_args p_init body
289
290      emitBc (mkProtoBCO (getName nm) body_code (Right original_body)
291                  arity bitmap_size bitmap False{-not alts-})
292
293 -- introduce break instructions for ticked expressions
294 schemeER_wrk :: Word16 -> BCEnv -> AnnExpr' Id VarSet -> BcM BCInstrList
295 schemeER_wrk d p rhs
296   | AnnTick (Breakpoint tick_no fvs) (_annot, newRhs) <- rhs
297   = do  code <- schemeE d 0 p newRhs
298         arr <- getBreakArray
299         this_mod <- getCurrentModule
300         let idOffSets = getVarOffSets d p fvs
301         let breakInfo = BreakInfo
302                         { breakInfo_module = this_mod
303                         , breakInfo_number = tick_no
304                         , breakInfo_vars = idOffSets
305                         , breakInfo_resty = exprType (deAnnotate' newRhs)
306                         }
307         let breakInstr = case arr of
308                          BA arr# ->
309                              BRK_FUN arr# (fromIntegral tick_no) breakInfo
310         return $ breakInstr `consOL` code
311    | otherwise = schemeE d 0 p rhs
312
313 getVarOffSets :: Word16 -> BCEnv -> [Id] -> [(Id, Word16)]
314 getVarOffSets d p = catMaybes . map (getOffSet d p)
315
316 getOffSet :: Word16 -> BCEnv -> Id -> Maybe (Id, Word16)
317 getOffSet d env id
318    = case lookupBCEnv_maybe id env of
319         Nothing     -> Nothing
320         Just offset -> Just (id, d - offset)
321
322 fvsToEnv :: BCEnv -> VarSet -> [Id]
323 -- Takes the free variables of a right-hand side, and
324 -- delivers an ordered list of the local variables that will
325 -- be captured in the thunk for the RHS
326 -- The BCEnv argument tells which variables are in the local
327 -- environment: these are the ones that should be captured
328 --
329 -- The code that constructs the thunk, and the code that executes
330 -- it, have to agree about this layout
331 fvsToEnv p fvs = [v | v <- varSetElems fvs,
332                       isId v,           -- Could be a type variable
333                       v `Map.member` p]
334
335 -- -----------------------------------------------------------------------------
336 -- schemeE
337
338 returnUnboxedAtom :: Word16 -> Sequel -> BCEnv
339                  -> AnnExpr' Id VarSet -> CgRep
340                  -> BcM BCInstrList
341 -- Returning an unlifted value.
342 -- Heave it on the stack, SLIDE, and RETURN.
343 returnUnboxedAtom d s p e e_rep
344    = do (push, szw) <- pushAtom d p e
345         return (push                       -- value onto stack
346                 `appOL`  mkSLIDE szw (d-s) -- clear to sequel
347                 `snocOL` RETURN_UBX e_rep) -- go
348
349 -- Compile code to apply the given expression to the remaining args
350 -- on the stack, returning a HNF.
351 schemeE :: Word16 -> Sequel -> BCEnv -> AnnExpr' Id VarSet -> BcM BCInstrList
352
353 schemeE d s p e
354    | Just e' <- bcView e
355    = schemeE d s p e'
356
357 -- Delegate tail-calls to schemeT.
358 schemeE d s p e@(AnnApp _ _) = schemeT d s p e
359
360 schemeE d s p e@(AnnLit lit)     = returnUnboxedAtom d s p e (typeCgRep (literalType lit))
361 schemeE d s p e@(AnnCoercion {}) = returnUnboxedAtom d s p e VoidArg
362
363 schemeE d s p e@(AnnVar v)
364    | isUnLiftedType v_type = returnUnboxedAtom d s p e (typeCgRep v_type)
365    | otherwise             = schemeT d s p e
366    where
367      v_type = idType v
368
369 schemeE d s p (AnnLet (AnnNonRec x (_,rhs)) (_,body))
370    | (AnnVar v, args_r_to_l) <- splitApp rhs,
371      Just data_con <- isDataConWorkId_maybe v,
372      dataConRepArity data_con == length args_r_to_l
373    = do -- Special case for a non-recursive let whose RHS is a
374         -- saturatred constructor application.
375         -- Just allocate the constructor and carry on
376         alloc_code <- mkConAppCode d s p data_con args_r_to_l
377         body_code <- schemeE (d+1) s (Map.insert x d p) body
378         return (alloc_code `appOL` body_code)
379
380 -- General case for let.  Generates correct, if inefficient, code in
381 -- all situations.
382 schemeE d s p (AnnLet binds (_,body))
383    = let (xs,rhss) = case binds of AnnNonRec x rhs  -> ([x],[rhs])
384                                    AnnRec xs_n_rhss -> unzip xs_n_rhss
385          n_binds = genericLength xs
386
387          fvss  = map (fvsToEnv p' . fst) rhss
388
389          -- Sizes of free vars
390          sizes = map (\rhs_fvs -> sum (map (fromIntegral . idSizeW) rhs_fvs)) fvss
391
392          -- the arity of each rhs
393          arities = map (genericLength . fst . collect) rhss
394
395          -- This p', d' defn is safe because all the items being pushed
396          -- are ptrs, so all have size 1.  d' and p' reflect the stack
397          -- after the closures have been allocated in the heap (but not
398          -- filled in), and pointers to them parked on the stack.
399          p'    = Map.insertList (zipE xs (mkStackOffsets d (genericReplicate n_binds 1))) p
400          d'    = d + n_binds
401          zipE  = zipEqual "schemeE"
402
403          -- ToDo: don't build thunks for things with no free variables
404          build_thunk _ [] size bco off arity
405             = return (PUSH_BCO bco `consOL` unitOL (mkap (off+size) size))
406            where
407                 mkap | arity == 0 = MKAP
408                      | otherwise  = MKPAP
409          build_thunk dd (fv:fvs) size bco off arity = do
410               (push_code, pushed_szw) <- pushAtom dd p' (AnnVar fv)
411               more_push_code <- build_thunk (dd+pushed_szw) fvs size bco off arity
412               return (push_code `appOL` more_push_code)
413
414          alloc_code = toOL (zipWith mkAlloc sizes arities)
415            where mkAlloc sz 0
416                     | is_tick     = ALLOC_AP_NOUPD sz
417                     | otherwise   = ALLOC_AP sz
418                  mkAlloc sz arity = ALLOC_PAP arity sz
419
420          is_tick = case binds of
421                      AnnNonRec id _ -> occNameFS (getOccName id) == tickFS
422                      _other -> False
423
424          compile_bind d' fvs x rhs size arity off = do
425                 bco <- schemeR fvs (x,rhs)
426                 build_thunk d' fvs size bco off arity
427
428          compile_binds =
429             [ compile_bind d' fvs x rhs size arity n
430             | (fvs, x, rhs, size, arity, n) <-
431                 zip6 fvss xs rhss sizes arities [n_binds, n_binds-1 .. 1]
432             ]
433      in do
434      body_code <- schemeE d' s p' body
435      thunk_codes <- sequence compile_binds
436      return (alloc_code `appOL` concatOL thunk_codes `appOL` body_code)
437
438 -- introduce a let binding for a ticked case expression. This rule
439 -- *should* only fire when the expression was not already let-bound
440 -- (the code gen for let bindings should take care of that).  Todo: we
441 -- call exprFreeVars on a deAnnotated expression, this may not be the
442 -- best way to calculate the free vars but it seemed like the least
443 -- intrusive thing to do
444 schemeE d s p exp@(AnnTick (Breakpoint _id _fvs) _rhs)
445    = if isUnLiftedType ty
446         then do
447           -- If the result type is unlifted, then we must generate
448           --   let f = \s . tick<n> e
449           --   in  f realWorld#
450           -- When we stop at the breakpoint, _result will have an unlifted
451           -- type and hence won't be bound in the environment, but the
452           -- breakpoint will otherwise work fine.
453           id <- newId (mkFunTy realWorldStatePrimTy ty)
454           st <- newId realWorldStatePrimTy
455           let letExp = AnnLet (AnnNonRec id (fvs, AnnLam st (emptyVarSet, exp)))
456                               (emptyVarSet, (AnnApp (emptyVarSet, AnnVar id)
457                                                     (emptyVarSet, AnnVar realWorldPrimId)))
458           schemeE d s p letExp
459         else do
460           id <- newId ty
461           -- Todo: is emptyVarSet correct on the next line?
462           let letExp = AnnLet (AnnNonRec id (fvs, exp)) (emptyVarSet, AnnVar id)
463           schemeE d s p letExp
464    where exp' = deAnnotate' exp
465          fvs  = exprFreeVars exp'
466          ty   = exprType exp'
467
468 -- ignore other kinds of tick
469 schemeE d s p (AnnTick _ (_, rhs)) = schemeE d s p rhs
470
471 schemeE d s p (AnnCase scrut _ _ [(DataAlt dc, [bind1, bind2], rhs)])
472    | isUnboxedTupleCon dc, VoidArg <- typeCgRep (idType bind1)
473         -- Convert
474         --      case .... of x { (# VoidArg'd-thing, a #) -> ... }
475         -- to
476         --      case .... of a { DEFAULT -> ... }
477         -- becuse the return convention for both are identical.
478         --
479         -- Note that it does not matter losing the void-rep thing from the
480         -- envt (it won't be bound now) because we never look such things up.
481
482    = --trace "automagic mashing of case alts (# VoidArg, a #)" $
483      doCase d s p scrut bind2 [(DEFAULT, [], rhs)] True{-unboxed tuple-}
484
485    | isUnboxedTupleCon dc, VoidArg <- typeCgRep (idType bind2)
486    = --trace "automagic mashing of case alts (# a, VoidArg #)" $
487      doCase d s p scrut bind1 [(DEFAULT, [], rhs)] True{-unboxed tuple-}
488
489 schemeE d s p (AnnCase scrut _ _ [(DataAlt dc, [bind1], rhs)])
490    | isUnboxedTupleCon dc
491         -- Similarly, convert
492         --      case .... of x { (# a #) -> ... }
493         -- to
494         --      case .... of a { DEFAULT -> ... }
495    = --trace "automagic mashing of case alts (# a #)"  $
496      doCase d s p scrut bind1 [(DEFAULT, [], rhs)] True{-unboxed tuple-}
497
498 schemeE d s p (AnnCase scrut bndr _ alts)
499    = doCase d s p scrut bndr alts False{-not an unboxed tuple-}
500
501 schemeE _ _ _ expr
502    = pprPanic "ByteCodeGen.schemeE: unhandled case"
503                (pprCoreExpr (deAnnotate' expr))
504
505 {-
506    Ticked Expressions
507    ------------------
508
509   The idea is that the "breakpoint<n,fvs> E" is really just an annotation on
510   the code. When we find such a thing, we pull out the useful information,
511   and then compile the code as if it was just the expression E.
512
513 -}
514
515 -- Compile code to do a tail call.  Specifically, push the fn,
516 -- slide the on-stack app back down to the sequel depth,
517 -- and enter.  Four cases:
518 --
519 -- 0.  (Nasty hack).
520 --     An application "GHC.Prim.tagToEnum# <type> unboxed-int".
521 --     The int will be on the stack.  Generate a code sequence
522 --     to convert it to the relevant constructor, SLIDE and ENTER.
523 --
524 -- 1.  The fn denotes a ccall.  Defer to generateCCall.
525 --
526 -- 2.  (Another nasty hack).  Spot (# a::VoidArg, b #) and treat
527 --     it simply as  b  -- since the representations are identical
528 --     (the VoidArg takes up zero stack space).  Also, spot
529 --     (# b #) and treat it as  b.
530 --
531 -- 3.  Application of a constructor, by defn saturated.
532 --     Split the args into ptrs and non-ptrs, and push the nonptrs,
533 --     then the ptrs, and then do PACK and RETURN.
534 --
535 -- 4.  Otherwise, it must be a function call.  Push the args
536 --     right to left, SLIDE and ENTER.
537
538 schemeT :: Word16       -- Stack depth
539         -> Sequel       -- Sequel depth
540         -> BCEnv        -- stack env
541         -> AnnExpr' Id VarSet
542         -> BcM BCInstrList
543
544 schemeT d s p app
545
546 --   | trace ("schemeT: env in = \n" ++ showSDocDebug (ppBCEnv p)) False
547 --   = panic "schemeT ?!?!"
548
549 --   | trace ("\nschemeT\n" ++ showSDoc (pprCoreExpr (deAnnotate' app)) ++ "\n") False
550 --   = error "?!?!"
551
552    -- Case 0
553    | Just (arg, constr_names) <- maybe_is_tagToEnum_call
554    = do (push, arg_words) <- pushAtom d p arg
555         tagToId_sequence <- implement_tagToId constr_names
556         return (push `appOL`  tagToId_sequence
557                        `appOL`  mkSLIDE 1 (d+arg_words-s)
558                        `snocOL` ENTER)
559
560    -- Case 1
561    | Just (CCall ccall_spec) <- isFCallId_maybe fn
562    = generateCCall d s p ccall_spec fn args_r_to_l
563
564    -- Case 2: Constructor application
565    | Just con <- maybe_saturated_dcon,
566      isUnboxedTupleCon con
567    = case args_r_to_l of
568         [arg1,arg2] | isVoidArgAtom arg1 ->
569                   unboxedTupleReturn d s p arg2
570         [arg1,arg2] | isVoidArgAtom arg2 ->
571                   unboxedTupleReturn d s p arg1
572         _other -> unboxedTupleException
573
574    -- Case 3: Ordinary data constructor
575    | Just con <- maybe_saturated_dcon
576    = do alloc_con <- mkConAppCode d s p con args_r_to_l
577         return (alloc_con         `appOL`
578                 mkSLIDE 1 (d - s) `snocOL`
579                 ENTER)
580
581    -- Case 4: Tail call of function
582    | otherwise
583    = doTailCall d s p fn args_r_to_l
584
585    where
586       -- Detect and extract relevant info for the tagToEnum kludge.
587       maybe_is_tagToEnum_call
588          = let extract_constr_Names ty
589                  | Just tyc <- tyConAppTyCon_maybe (repType ty),
590                    isDataTyCon tyc
591                    = map (getName . dataConWorkId) (tyConDataCons tyc)
592                    -- NOTE: use the worker name, not the source name of
593                    -- the DataCon.  See DataCon.lhs for details.
594                  | otherwise
595                    = pprPanic "maybe_is_tagToEnum_call.extract_constr_Ids" (ppr ty)
596            in
597            case app of
598               (AnnApp (_, AnnApp (_, AnnVar v) (_, AnnType t)) arg)
599                  -> case isPrimOpId_maybe v of
600                        Just TagToEnumOp -> Just (snd arg, extract_constr_Names t)
601                        _                -> Nothing
602               _ -> Nothing
603
604         -- Extract the args (R->L) and fn
605         -- The function will necessarily be a variable,
606         -- because we are compiling a tail call
607       (AnnVar fn, args_r_to_l) = splitApp app
608
609       -- Only consider this to be a constructor application iff it is
610       -- saturated.  Otherwise, we'll call the constructor wrapper.
611       n_args = length args_r_to_l
612       maybe_saturated_dcon
613         = case isDataConWorkId_maybe fn of
614                 Just con | dataConRepArity con == n_args -> Just con
615                 _ -> Nothing
616
617 -- -----------------------------------------------------------------------------
618 -- Generate code to build a constructor application,
619 -- leaving it on top of the stack
620
621 mkConAppCode :: Word16 -> Sequel -> BCEnv
622              -> DataCon                 -- The data constructor
623              -> [AnnExpr' Id VarSet]    -- Args, in *reverse* order
624              -> BcM BCInstrList
625
626 mkConAppCode _ _ _ con []       -- Nullary constructor
627   = ASSERT( isNullaryRepDataCon con )
628     return (unitOL (PUSH_G (getName (dataConWorkId con))))
629         -- Instead of doing a PACK, which would allocate a fresh
630         -- copy of this constructor, use the single shared version.
631
632 mkConAppCode orig_d _ p con args_r_to_l
633   = ASSERT( dataConRepArity con == length args_r_to_l )
634     do_pushery orig_d (non_ptr_args ++ ptr_args)
635  where
636         -- The args are already in reverse order, which is the way PACK
637         -- expects them to be.  We must push the non-ptrs after the ptrs.
638       (ptr_args, non_ptr_args) = partition isPtrAtom args_r_to_l
639
640       do_pushery d (arg:args)
641          = do (push, arg_words) <- pushAtom d p arg
642               more_push_code <- do_pushery (d+arg_words) args
643               return (push `appOL` more_push_code)
644       do_pushery d []
645          = return (unitOL (PACK con n_arg_words))
646          where
647            n_arg_words = d - orig_d
648
649
650 -- -----------------------------------------------------------------------------
651 -- Returning an unboxed tuple with one non-void component (the only
652 -- case we can handle).
653 --
654 -- Remember, we don't want to *evaluate* the component that is being
655 -- returned, even if it is a pointed type.  We always just return.
656
657 unboxedTupleReturn
658         :: Word16 -> Sequel -> BCEnv
659         -> AnnExpr' Id VarSet -> BcM BCInstrList
660 unboxedTupleReturn d s p arg = do
661   (push, sz) <- pushAtom d p arg
662   return (push                      `appOL`
663           mkSLIDE sz (d-s)          `snocOL`
664           RETURN_UBX (atomRep arg))
665
666 -- -----------------------------------------------------------------------------
667 -- Generate code for a tail-call
668
669 doTailCall
670         :: Word16 -> Sequel -> BCEnv
671         -> Id -> [AnnExpr' Id VarSet]
672         -> BcM BCInstrList
673 doTailCall init_d s p fn args
674   = do_pushes init_d args (map atomRep args)
675   where
676   do_pushes d [] reps = do
677         ASSERT( null reps ) return ()
678         (push_fn, sz) <- pushAtom d p (AnnVar fn)
679         ASSERT( sz == 1 ) return ()
680         return (push_fn `appOL` (
681                   mkSLIDE ((d-init_d) + 1) (init_d - s) `appOL`
682                   unitOL ENTER))
683   do_pushes d args reps = do
684       let (push_apply, n, rest_of_reps) = findPushSeq reps
685           (these_args, rest_of_args) = splitAt n args
686       (next_d, push_code) <- push_seq d these_args
687       instrs <- do_pushes (next_d + 1) rest_of_args rest_of_reps
688       --                          ^^^ for the PUSH_APPLY_ instruction
689       return (push_code `appOL` (push_apply `consOL` instrs))
690
691   push_seq d [] = return (d, nilOL)
692   push_seq d (arg:args) = do
693     (push_code, sz) <- pushAtom d p arg
694     (final_d, more_push_code) <- push_seq (d+sz) args
695     return (final_d, push_code `appOL` more_push_code)
696
697 -- v. similar to CgStackery.findMatch, ToDo: merge
698 findPushSeq :: [CgRep] -> (BCInstr, Int, [CgRep])
699 findPushSeq (PtrArg: PtrArg: PtrArg: PtrArg: PtrArg: PtrArg: rest)
700   = (PUSH_APPLY_PPPPPP, 6, rest)
701 findPushSeq (PtrArg: PtrArg: PtrArg: PtrArg: PtrArg: rest)
702   = (PUSH_APPLY_PPPPP, 5, rest)
703 findPushSeq (PtrArg: PtrArg: PtrArg: PtrArg: rest)
704   = (PUSH_APPLY_PPPP, 4, rest)
705 findPushSeq (PtrArg: PtrArg: PtrArg: rest)
706   = (PUSH_APPLY_PPP, 3, rest)
707 findPushSeq (PtrArg: PtrArg: rest)
708   = (PUSH_APPLY_PP, 2, rest)
709 findPushSeq (PtrArg: rest)
710   = (PUSH_APPLY_P, 1, rest)
711 findPushSeq (VoidArg: rest)
712   = (PUSH_APPLY_V, 1, rest)
713 findPushSeq (NonPtrArg: rest)
714   = (PUSH_APPLY_N, 1, rest)
715 findPushSeq (FloatArg: rest)
716   = (PUSH_APPLY_F, 1, rest)
717 findPushSeq (DoubleArg: rest)
718   = (PUSH_APPLY_D, 1, rest)
719 findPushSeq (LongArg: rest)
720   = (PUSH_APPLY_L, 1, rest)
721 findPushSeq _
722   = panic "ByteCodeGen.findPushSeq"
723
724 -- -----------------------------------------------------------------------------
725 -- Case expressions
726
727 doCase  :: Word16 -> Sequel -> BCEnv
728         -> AnnExpr Id VarSet -> Id -> [AnnAlt Id VarSet]
729         -> Bool  -- True <=> is an unboxed tuple case, don't enter the result
730         -> BcM BCInstrList
731 doCase d s p (_,scrut) bndr alts is_unboxed_tuple
732   = let
733         -- Top of stack is the return itbl, as usual.
734         -- underneath it is the pointer to the alt_code BCO.
735         -- When an alt is entered, it assumes the returned value is
736         -- on top of the itbl.
737         ret_frame_sizeW = 2
738
739         -- An unlifted value gets an extra info table pushed on top
740         -- when it is returned.
741         unlifted_itbl_sizeW | isAlgCase = 0
742                             | otherwise = 1
743
744         -- depth of stack after the return value has been pushed
745         d_bndr = d + ret_frame_sizeW + fromIntegral (idSizeW bndr)
746
747         -- depth of stack after the extra info table for an unboxed return
748         -- has been pushed, if any.  This is the stack depth at the
749         -- continuation.
750         d_alts = d_bndr + unlifted_itbl_sizeW
751
752         -- Env in which to compile the alts, not including
753         -- any vars bound by the alts themselves
754         p_alts = Map.insert bndr (d_bndr - 1) p
755
756         bndr_ty = idType bndr
757         isAlgCase = not (isUnLiftedType bndr_ty) && not is_unboxed_tuple
758
759         -- given an alt, return a discr and code for it.
760         codeAlt (DEFAULT, _, (_,rhs))
761            = do rhs_code <- schemeE d_alts s p_alts rhs
762                 return (NoDiscr, rhs_code)
763
764         codeAlt alt@(_, bndrs, (_,rhs))
765            -- primitive or nullary constructor alt: no need to UNPACK
766            | null real_bndrs = do
767                 rhs_code <- schemeE d_alts s p_alts rhs
768                 return (my_discr alt, rhs_code)
769            -- algebraic alt with some binders
770            | otherwise =
771              let
772                  (ptrs,nptrs) = partition (isFollowableArg.idCgRep) real_bndrs
773                  ptr_sizes    = map (fromIntegral . idSizeW) ptrs
774                  nptrs_sizes  = map (fromIntegral . idSizeW) nptrs
775                  bind_sizes   = ptr_sizes ++ nptrs_sizes
776                  size         = sum ptr_sizes + sum nptrs_sizes
777                  -- the UNPACK instruction unpacks in reverse order...
778                  p' = Map.insertList
779                         (zip (reverse (ptrs ++ nptrs))
780                           (mkStackOffsets d_alts (reverse bind_sizes)))
781                         p_alts
782              in do
783              MASSERT(isAlgCase)
784              rhs_code <- schemeE (d_alts+size) s p' rhs
785              return (my_discr alt, unitOL (UNPACK size) `appOL` rhs_code)
786            where
787              real_bndrs = filterOut isTyVar bndrs
788
789         my_discr (DEFAULT, _, _) = NoDiscr {-shouldn't really happen-}
790         my_discr (DataAlt dc, _, _)
791            | isUnboxedTupleCon dc
792            = unboxedTupleException
793            | otherwise
794            = DiscrP (fromIntegral (dataConTag dc - fIRST_TAG))
795         my_discr (LitAlt l, _, _)
796            = case l of MachInt i     -> DiscrI (fromInteger i)
797                        MachWord w    -> DiscrW (fromInteger w)
798                        MachFloat r   -> DiscrF (fromRational r)
799                        MachDouble r  -> DiscrD (fromRational r)
800                        MachChar i    -> DiscrI (ord i)
801                        _ -> pprPanic "schemeE(AnnCase).my_discr" (ppr l)
802
803         maybe_ncons
804            | not isAlgCase = Nothing
805            | otherwise
806            = case [dc | (DataAlt dc, _, _) <- alts] of
807                 []     -> Nothing
808                 (dc:_) -> Just (tyConFamilySize (dataConTyCon dc))
809
810         -- the bitmap is relative to stack depth d, i.e. before the
811         -- BCO, info table and return value are pushed on.
812         -- This bit of code is v. similar to buildLivenessMask in CgBindery,
813         -- except that here we build the bitmap from the known bindings of
814         -- things that are pointers, whereas in CgBindery the code builds the
815         -- bitmap from the free slots and unboxed bindings.
816         -- (ToDo: merge?)
817         --
818         -- NOTE [7/12/2006] bug #1013, testcase ghci/should_run/ghci002.
819         -- The bitmap must cover the portion of the stack up to the sequel only.
820         -- Previously we were building a bitmap for the whole depth (d), but we
821         -- really want a bitmap up to depth (d-s).  This affects compilation of
822         -- case-of-case expressions, which is the only time we can be compiling a
823         -- case expression with s /= 0.
824         bitmap_size = d-s
825         bitmap_size' :: Int
826         bitmap_size' = fromIntegral bitmap_size
827         bitmap = intsToReverseBitmap bitmap_size'{-size-}
828                         (sortLe (<=) (filter (< bitmap_size') rel_slots))
829           where
830           binds = Map.toList p
831           rel_slots = map fromIntegral $ concat (map spread binds)
832           spread (id, offset)
833                 | isFollowableArg (idCgRep id) = [ rel_offset ]
834                 | otherwise = []
835                 where rel_offset = d - offset - 1
836
837      in do
838      alt_stuff <- mapM codeAlt alts
839      alt_final <- mkMultiBranch maybe_ncons alt_stuff
840
841      let
842          alt_bco_name = getName bndr
843          alt_bco = mkProtoBCO alt_bco_name alt_final (Left alts)
844                        0{-no arity-} bitmap_size bitmap True{-is alts-}
845      -- in
846 --     trace ("case: bndr = " ++ showSDocDebug (ppr bndr) ++ "\ndepth = " ++ show d ++ "\nenv = \n" ++ showSDocDebug (ppBCEnv p) ++
847 --            "\n      bitmap = " ++ show bitmap) $ do
848      scrut_code <- schemeE (d + ret_frame_sizeW) (d + ret_frame_sizeW) p scrut
849      alt_bco' <- emitBc alt_bco
850      let push_alts
851             | isAlgCase = PUSH_ALTS alt_bco'
852             | otherwise = PUSH_ALTS_UNLIFTED alt_bco' (typeCgRep bndr_ty)
853      return (push_alts `consOL` scrut_code)
854
855
856 -- -----------------------------------------------------------------------------
857 -- Deal with a CCall.
858
859 -- Taggedly push the args onto the stack R->L,
860 -- deferencing ForeignObj#s and adjusting addrs to point to
861 -- payloads in Ptr/Byte arrays.  Then, generate the marshalling
862 -- (machine) code for the ccall, and create bytecodes to call that and
863 -- then return in the right way.
864
865 generateCCall :: Word16 -> Sequel       -- stack and sequel depths
866               -> BCEnv
867               -> CCallSpec              -- where to call
868               -> Id                     -- of target, for type info
869               -> [AnnExpr' Id VarSet]   -- args (atoms)
870               -> BcM BCInstrList
871
872 generateCCall d0 s p (CCallSpec target cconv safety) fn args_r_to_l
873    = let
874          -- useful constants
875          addr_sizeW :: Word16
876          addr_sizeW = fromIntegral (cgRepSizeW NonPtrArg)
877
878          -- Get the args on the stack, with tags and suitably
879          -- dereferenced for the CCall.  For each arg, return the
880          -- depth to the first word of the bits for that arg, and the
881          -- CgRep of what was actually pushed.
882
883          pargs _ [] = return []
884          pargs d (a:az)
885             = let arg_ty = repType (exprType (deAnnotate' a))
886
887               in case tyConAppTyCon_maybe arg_ty of
888                     -- Don't push the FO; instead push the Addr# it
889                     -- contains.
890                     Just t
891                      | t == arrayPrimTyCon || t == mutableArrayPrimTyCon
892                        -> do rest <- pargs (d + addr_sizeW) az
893                              code <- parg_ArrayishRep (fromIntegral arrPtrsHdrSize) d p a
894                              return ((code,AddrRep):rest)
895
896                      | t == byteArrayPrimTyCon || t == mutableByteArrayPrimTyCon
897                        -> do rest <- pargs (d + addr_sizeW) az
898                              code <- parg_ArrayishRep (fromIntegral arrWordsHdrSize) d p a
899                              return ((code,AddrRep):rest)
900
901                     -- Default case: push taggedly, but otherwise intact.
902                     _
903                        -> do (code_a, sz_a) <- pushAtom d p a
904                              rest <- pargs (d+sz_a) az
905                              return ((code_a, atomPrimRep a) : rest)
906
907          -- Do magic for Ptr/Byte arrays.  Push a ptr to the array on
908          -- the stack but then advance it over the headers, so as to
909          -- point to the payload.
910          parg_ArrayishRep :: Word16 -> Word16 -> BCEnv -> AnnExpr' Id VarSet
911                           -> BcM BCInstrList
912          parg_ArrayishRep hdrSize d p a
913             = do (push_fo, _) <- pushAtom d p a
914                  -- The ptr points at the header.  Advance it over the
915                  -- header and then pretend this is an Addr#.
916                  return (push_fo `snocOL` SWIZZLE 0 hdrSize)
917
918      in do
919      code_n_reps <- pargs d0 args_r_to_l
920      let
921          (pushs_arg, a_reps_pushed_r_to_l) = unzip code_n_reps
922          a_reps_sizeW = fromIntegral (sum (map primRepSizeW a_reps_pushed_r_to_l))
923
924          push_args    = concatOL pushs_arg
925          d_after_args = d0 + a_reps_sizeW
926          a_reps_pushed_RAW
927             | null a_reps_pushed_r_to_l || head a_reps_pushed_r_to_l /= VoidRep
928             = panic "ByteCodeGen.generateCCall: missing or invalid World token?"
929             | otherwise
930             = reverse (tail a_reps_pushed_r_to_l)
931
932          -- Now: a_reps_pushed_RAW are the reps which are actually on the stack.
933          -- push_args is the code to do that.
934          -- d_after_args is the stack depth once the args are on.
935
936          -- Get the result rep.
937          (returns_void, r_rep)
938             = case maybe_getCCallReturnRep (idType fn) of
939                  Nothing -> (True,  VoidRep)
940                  Just rr -> (False, rr)
941          {-
942          Because the Haskell stack grows down, the a_reps refer to
943          lowest to highest addresses in that order.  The args for the call
944          are on the stack.  Now push an unboxed Addr# indicating
945          the C function to call.  Then push a dummy placeholder for the
946          result.  Finally, emit a CCALL insn with an offset pointing to the
947          Addr# just pushed, and a literal field holding the mallocville
948          address of the piece of marshalling code we generate.
949          So, just prior to the CCALL insn, the stack looks like this
950          (growing down, as usual):
951
952             <arg_n>
953             ...
954             <arg_1>
955             Addr# address_of_C_fn
956             <placeholder-for-result#> (must be an unboxed type)
957
958          The interpreter then calls the marshall code mentioned
959          in the CCALL insn, passing it (& <placeholder-for-result#>),
960          that is, the addr of the topmost word in the stack.
961          When this returns, the placeholder will have been
962          filled in.  The placeholder is slid down to the sequel
963          depth, and we RETURN.
964
965          This arrangement makes it simple to do f-i-dynamic since the Addr#
966          value is the first arg anyway.
967
968          The marshalling code is generated specifically for this
969          call site, and so knows exactly the (Haskell) stack
970          offsets of the args, fn address and placeholder.  It
971          copies the args to the C stack, calls the stacked addr,
972          and parks the result back in the placeholder.  The interpreter
973          calls it as a normal C call, assuming it has a signature
974             void marshall_code ( StgWord* ptr_to_top_of_stack )
975          -}
976          -- resolve static address
977          get_target_info
978             = case target of
979                  DynamicTarget
980                     -> return (False, panic "ByteCodeGen.generateCCall(dyn)")
981
982                  StaticTarget target _
983                     -> do res <- ioToBc (lookupStaticPtr stdcall_adj_target)
984                           return (True, res)
985                    where
986                       stdcall_adj_target
987 #ifdef mingw32_TARGET_OS
988                           | StdCallConv <- cconv
989                           = let size = fromIntegral a_reps_sizeW * wORD_SIZE in
990                             mkFastString (unpackFS target ++ '@':show size)
991 #endif
992                           | otherwise
993                           = target
994
995      -- in
996      (is_static, static_target_addr) <- get_target_info
997      let
998
999          -- Get the arg reps, zapping the leading Addr# in the dynamic case
1000          a_reps --  | trace (showSDoc (ppr a_reps_pushed_RAW)) False = error "???"
1001                 | is_static = a_reps_pushed_RAW
1002                 | otherwise = if null a_reps_pushed_RAW
1003                               then panic "ByteCodeGen.generateCCall: dyn with no args"
1004                               else tail a_reps_pushed_RAW
1005
1006          -- push the Addr#
1007          (push_Addr, d_after_Addr)
1008             | is_static
1009             = (toOL [PUSH_UBX (Right static_target_addr) addr_sizeW],
1010                d_after_args + addr_sizeW)
1011             | otherwise -- is already on the stack
1012             = (nilOL, d_after_args)
1013
1014          -- Push the return placeholder.  For a call returning nothing,
1015          -- this is a VoidArg (tag).
1016          r_sizeW   = fromIntegral (primRepSizeW r_rep)
1017          d_after_r = d_after_Addr + r_sizeW
1018          r_lit     = mkDummyLiteral r_rep
1019          push_r    = (if   returns_void
1020                       then nilOL
1021                       else unitOL (PUSH_UBX (Left r_lit) r_sizeW))
1022
1023          -- generate the marshalling code we're going to call
1024
1025          -- Offset of the next stack frame down the stack.  The CCALL
1026          -- instruction needs to describe the chunk of stack containing
1027          -- the ccall args to the GC, so it needs to know how large it
1028          -- is.  See comment in Interpreter.c with the CCALL instruction.
1029          stk_offset   = d_after_r - s
1030
1031      -- in
1032      -- the only difference in libffi mode is that we prepare a cif
1033      -- describing the call type by calling libffi, and we attach the
1034      -- address of this to the CCALL instruction.
1035      token <- ioToBc $ prepForeignCall cconv a_reps r_rep
1036      let addr_of_marshaller = castPtrToFunPtr token
1037
1038      recordItblMallocBc (ItblPtr (castFunPtrToPtr addr_of_marshaller))
1039      let
1040          -- do the call
1041          do_call      = unitOL (CCALL stk_offset (castFunPtrToPtr addr_of_marshaller)
1042                                  (fromIntegral (fromEnum (playInterruptible safety))))
1043          -- slide and return
1044          wrapup       = mkSLIDE r_sizeW (d_after_r - r_sizeW - s)
1045                         `snocOL` RETURN_UBX (primRepToCgRep r_rep)
1046      --in
1047          --trace (show (arg1_offW, args_offW  ,  (map cgRepSizeW a_reps) )) $
1048      return (
1049          push_args `appOL`
1050          push_Addr `appOL` push_r `appOL` do_call `appOL` wrapup
1051          )
1052
1053 -- Make a dummy literal, to be used as a placeholder for FFI return
1054 -- values on the stack.
1055 mkDummyLiteral :: PrimRep -> Literal
1056 mkDummyLiteral pr
1057    = case pr of
1058         IntRep    -> MachInt 0
1059         WordRep   -> MachWord 0
1060         AddrRep   -> MachNullAddr
1061         DoubleRep -> MachDouble 0
1062         FloatRep  -> MachFloat 0
1063         Int64Rep  -> MachInt64 0
1064         Word64Rep -> MachWord64 0
1065         _         -> panic "mkDummyLiteral"
1066
1067
1068 -- Convert (eg)
1069 --     GHC.Prim.Char# -> GHC.Prim.State# GHC.Prim.RealWorld
1070 --                   -> (# GHC.Prim.State# GHC.Prim.RealWorld, GHC.Prim.Int# #)
1071 --
1072 -- to  Just IntRep
1073 -- and check that an unboxed pair is returned wherein the first arg is VoidArg'd.
1074 --
1075 -- Alternatively, for call-targets returning nothing, convert
1076 --
1077 --     GHC.Prim.Char# -> GHC.Prim.State# GHC.Prim.RealWorld
1078 --                   -> (# GHC.Prim.State# GHC.Prim.RealWorld #)
1079 --
1080 -- to  Nothing
1081
1082 maybe_getCCallReturnRep :: Type -> Maybe PrimRep
1083 maybe_getCCallReturnRep fn_ty
1084    = let (_a_tys, r_ty) = splitFunTys (dropForAlls fn_ty)
1085          maybe_r_rep_to_go
1086             = if isSingleton r_reps then Nothing else Just (r_reps !! 1)
1087          (r_tycon, r_reps)
1088             = case splitTyConApp_maybe (repType r_ty) of
1089                       (Just (tyc, tys)) -> (tyc, map typePrimRep tys)
1090                       Nothing -> blargh
1091          ok = ( ( r_reps `lengthIs` 2 && VoidRep == head r_reps)
1092                 || r_reps == [VoidRep] )
1093               && isUnboxedTupleTyCon r_tycon
1094               && case maybe_r_rep_to_go of
1095                     Nothing    -> True
1096                     Just r_rep -> r_rep /= PtrRep
1097                                   -- if it was, it would be impossible
1098                                   -- to create a valid return value
1099                                   -- placeholder on the stack
1100
1101          blargh :: a -- Used at more than one type
1102          blargh = pprPanic "maybe_getCCallReturn: can't handle:"
1103                            (pprType fn_ty)
1104      in
1105      --trace (showSDoc (ppr (a_reps, r_reps))) $
1106      if ok then maybe_r_rep_to_go else blargh
1107
1108 -- Compile code which expects an unboxed Int on the top of stack,
1109 -- (call it i), and pushes the i'th closure in the supplied list
1110 -- as a consequence.
1111 implement_tagToId :: [Name] -> BcM BCInstrList
1112 implement_tagToId names
1113    = ASSERT( notNull names )
1114      do labels <- getLabelsBc (genericLength names)
1115         label_fail <- getLabelBc
1116         label_exit <- getLabelBc
1117         let infos = zip4 labels (tail labels ++ [label_fail])
1118                                 [0 ..] names
1119             steps = map (mkStep label_exit) infos
1120         return (concatOL steps
1121                   `appOL`
1122                   toOL [LABEL label_fail, CASEFAIL, LABEL label_exit])
1123      where
1124         mkStep l_exit (my_label, next_label, n, name_for_n)
1125            = toOL [LABEL my_label,
1126                    TESTEQ_I n next_label,
1127                    PUSH_G name_for_n,
1128                    JMP l_exit]
1129
1130
1131 -- -----------------------------------------------------------------------------
1132 -- pushAtom
1133
1134 -- Push an atom onto the stack, returning suitable code & number of
1135 -- stack words used.
1136 --
1137 -- The env p must map each variable to the highest- numbered stack
1138 -- slot for it.  For example, if the stack has depth 4 and we
1139 -- tagged-ly push (v :: Int#) on it, the value will be in stack[4],
1140 -- the tag in stack[5], the stack will have depth 6, and p must map v
1141 -- to 5 and not to 4.  Stack locations are numbered from zero, so a
1142 -- depth 6 stack has valid words 0 .. 5.
1143
1144 pushAtom :: Word16 -> BCEnv -> AnnExpr' Id VarSet -> BcM (BCInstrList, Word16)
1145
1146 pushAtom d p e
1147    | Just e' <- bcView e
1148    = pushAtom d p e'
1149
1150 pushAtom _ _ (AnnCoercion {})   -- Coercions are zero-width things, 
1151    = return (nilOL, 0)          -- treated just like a variable VoidArg
1152
1153 pushAtom d p (AnnVar v)
1154    | idCgRep v == VoidArg
1155    = return (nilOL, 0)
1156
1157    | isFCallId v
1158    = pprPanic "pushAtom: shouldn't get an FCallId here" (ppr v)
1159
1160    | Just primop <- isPrimOpId_maybe v
1161    = return (unitOL (PUSH_PRIMOP primop), 1)
1162
1163    | Just d_v <- lookupBCEnv_maybe v p  -- v is a local variable
1164    = let l = d - d_v + sz - 2
1165      in return (toOL (genericReplicate sz (PUSH_L l)), sz)
1166          -- d - d_v                 the number of words between the TOS
1167          --                         and the 1st slot of the object
1168          --
1169          -- d - d_v - 1             the offset from the TOS of the 1st slot
1170          --
1171          -- d - d_v - 1 + sz - 1    the offset from the TOS of the last slot
1172          --                         of the object.
1173          --
1174          -- Having found the last slot, we proceed to copy the right number of
1175          -- slots on to the top of the stack.
1176
1177     | otherwise  -- v must be a global variable
1178     = ASSERT(sz == 1)
1179       return (unitOL (PUSH_G (getName v)), sz)
1180
1181     where
1182          sz :: Word16
1183          sz = fromIntegral (idSizeW v)
1184
1185
1186 pushAtom _ _ (AnnLit lit)
1187    = case lit of
1188         MachLabel _ _ _ -> code NonPtrArg
1189         MachWord _    -> code NonPtrArg
1190         MachInt _     -> code NonPtrArg
1191         MachWord64 _  -> code LongArg
1192         MachInt64 _   -> code LongArg
1193         MachFloat _   -> code FloatArg
1194         MachDouble _  -> code DoubleArg
1195         MachChar _    -> code NonPtrArg
1196         MachNullAddr  -> code NonPtrArg
1197         MachStr s     -> pushStr s
1198         -- No LitInteger's should be left by the time this is called.
1199         -- CorePrep should have converted them all to a real core
1200         -- representation.
1201         LitInteger {} -> panic "pushAtom: LitInteger"
1202      where
1203         code rep
1204            = let size_host_words = fromIntegral (cgRepSizeW rep)
1205              in  return (unitOL (PUSH_UBX (Left lit) size_host_words),
1206                            size_host_words)
1207
1208         pushStr s
1209            = let getMallocvilleAddr
1210                     = case s of
1211                          FastString _ n _ fp _ ->
1212                             -- we could grab the Ptr from the ForeignPtr,
1213                             -- but then we have no way to control its lifetime.
1214                             -- In reality it'll probably stay alive long enoungh
1215                             -- by virtue of the global FastString table, but
1216                             -- to be on the safe side we copy the string into
1217                             -- a malloc'd area of memory.
1218                                 do ptr <- ioToBc (mallocBytes (n+1))
1219                                    recordMallocBc ptr
1220                                    ioToBc (
1221                                       withForeignPtr fp $ \p -> do
1222                                          memcpy ptr p (fromIntegral n)
1223                                          pokeByteOff ptr n (fromIntegral (ord '\0') :: Word8)
1224                                          return ptr
1225                                       )
1226              in do
1227                 addr <- getMallocvilleAddr
1228                 -- Get the addr on the stack, untaggedly
1229                 return (unitOL (PUSH_UBX (Right addr) 1), 1)
1230
1231 pushAtom _ _ expr
1232    = pprPanic "ByteCodeGen.pushAtom"
1233               (pprCoreExpr (deAnnotate (undefined, expr)))
1234
1235 foreign import ccall unsafe "memcpy"
1236  memcpy :: Ptr a -> Ptr b -> CSize -> IO ()
1237
1238
1239 -- -----------------------------------------------------------------------------
1240 -- Given a bunch of alts code and their discrs, do the donkey work
1241 -- of making a multiway branch using a switch tree.
1242 -- What a load of hassle!
1243
1244 mkMultiBranch :: Maybe Int      -- # datacons in tycon, if alg alt
1245                                 -- a hint; generates better code
1246                                 -- Nothing is always safe
1247               -> [(Discr, BCInstrList)]
1248               -> BcM BCInstrList
1249 mkMultiBranch maybe_ncons raw_ways
1250    = let d_way     = filter (isNoDiscr.fst) raw_ways
1251          notd_ways = sortLe
1252                         (\w1 w2 -> leAlt (fst w1) (fst w2))
1253                         (filter (not.isNoDiscr.fst) raw_ways)
1254
1255          mkTree :: [(Discr, BCInstrList)] -> Discr -> Discr -> BcM BCInstrList
1256          mkTree [] _range_lo _range_hi = return the_default
1257
1258          mkTree [val] range_lo range_hi
1259             | range_lo `eqAlt` range_hi
1260             = return (snd val)
1261             | otherwise
1262             = do label_neq <- getLabelBc
1263                  return (testEQ (fst val) label_neq
1264                          `consOL` (snd val
1265                          `appOL`   unitOL (LABEL label_neq)
1266                          `appOL`   the_default))
1267
1268          mkTree vals range_lo range_hi
1269             = let n = length vals `div` 2
1270                   vals_lo = take n vals
1271                   vals_hi = drop n vals
1272                   v_mid = fst (head vals_hi)
1273               in do
1274               label_geq <- getLabelBc
1275               code_lo <- mkTree vals_lo range_lo (dec v_mid)
1276               code_hi <- mkTree vals_hi v_mid range_hi
1277               return (testLT v_mid label_geq
1278                       `consOL` (code_lo
1279                       `appOL`   unitOL (LABEL label_geq)
1280                       `appOL`   code_hi))
1281
1282          the_default
1283             = case d_way of [] -> unitOL CASEFAIL
1284                             [(_, def)] -> def
1285                             _ -> panic "mkMultiBranch/the_default"
1286
1287          testLT (DiscrI i) fail_label = TESTLT_I i fail_label
1288          testLT (DiscrW i) fail_label = TESTLT_W i fail_label
1289          testLT (DiscrF i) fail_label = TESTLT_F i fail_label
1290          testLT (DiscrD i) fail_label = TESTLT_D i fail_label
1291          testLT (DiscrP i) fail_label = TESTLT_P i fail_label
1292          testLT NoDiscr    _          = panic "mkMultiBranch NoDiscr"
1293
1294          testEQ (DiscrI i) fail_label = TESTEQ_I i fail_label
1295          testEQ (DiscrW i) fail_label = TESTEQ_W i fail_label
1296          testEQ (DiscrF i) fail_label = TESTEQ_F i fail_label
1297          testEQ (DiscrD i) fail_label = TESTEQ_D i fail_label
1298          testEQ (DiscrP i) fail_label = TESTEQ_P i fail_label
1299          testEQ NoDiscr    _          = panic "mkMultiBranch NoDiscr"
1300
1301          -- None of these will be needed if there are no non-default alts
1302          (init_lo, init_hi)
1303             | null notd_ways
1304             = panic "mkMultiBranch: awesome foursome"
1305             | otherwise
1306             = case fst (head notd_ways) of
1307                 DiscrI _ -> ( DiscrI minBound,  DiscrI maxBound )
1308                 DiscrW _ -> ( DiscrW minBound,  DiscrW maxBound )
1309                 DiscrF _ -> ( DiscrF minF,      DiscrF maxF )
1310                 DiscrD _ -> ( DiscrD minD,      DiscrD maxD )
1311                 DiscrP _ -> ( DiscrP algMinBound, DiscrP algMaxBound )
1312                 NoDiscr -> panic "mkMultiBranch NoDiscr"
1313
1314          (algMinBound, algMaxBound)
1315             = case maybe_ncons of
1316                  -- XXX What happens when n == 0?
1317                  Just n  -> (0, fromIntegral n - 1)
1318                  Nothing -> (minBound, maxBound)
1319
1320          (DiscrI i1) `eqAlt` (DiscrI i2) = i1 == i2
1321          (DiscrW w1) `eqAlt` (DiscrW w2) = w1 == w2
1322          (DiscrF f1) `eqAlt` (DiscrF f2) = f1 == f2
1323          (DiscrD d1) `eqAlt` (DiscrD d2) = d1 == d2
1324          (DiscrP i1) `eqAlt` (DiscrP i2) = i1 == i2
1325          NoDiscr     `eqAlt` NoDiscr     = True
1326          _           `eqAlt` _           = False
1327
1328          (DiscrI i1) `leAlt` (DiscrI i2) = i1 <= i2
1329          (DiscrW w1) `leAlt` (DiscrW w2) = w1 <= w2
1330          (DiscrF f1) `leAlt` (DiscrF f2) = f1 <= f2
1331          (DiscrD d1) `leAlt` (DiscrD d2) = d1 <= d2
1332          (DiscrP i1) `leAlt` (DiscrP i2) = i1 <= i2
1333          NoDiscr     `leAlt` NoDiscr     = True
1334          _           `leAlt` _           = False
1335
1336          isNoDiscr NoDiscr = True
1337          isNoDiscr _       = False
1338
1339          dec (DiscrI i) = DiscrI (i-1)
1340          dec (DiscrW w) = DiscrW (w-1)
1341          dec (DiscrP i) = DiscrP (i-1)
1342          dec other      = other         -- not really right, but if you
1343                 -- do cases on floating values, you'll get what you deserve
1344
1345          -- same snotty comment applies to the following
1346          minF, maxF :: Float
1347          minD, maxD :: Double
1348          minF = -1.0e37
1349          maxF =  1.0e37
1350          minD = -1.0e308
1351          maxD =  1.0e308
1352      in
1353          mkTree notd_ways init_lo init_hi
1354
1355
1356 -- -----------------------------------------------------------------------------
1357 -- Supporting junk for the compilation schemes
1358
1359 -- Describes case alts
1360 data Discr
1361    = DiscrI Int
1362    | DiscrW Word
1363    | DiscrF Float
1364    | DiscrD Double
1365    | DiscrP Word16
1366    | NoDiscr
1367
1368 instance Outputable Discr where
1369    ppr (DiscrI i) = int i
1370    ppr (DiscrW w) = text (show w)
1371    ppr (DiscrF f) = text (show f)
1372    ppr (DiscrD d) = text (show d)
1373    ppr (DiscrP i) = ppr i
1374    ppr NoDiscr    = text "DEF"
1375
1376
1377 lookupBCEnv_maybe :: Id -> BCEnv -> Maybe Word16
1378 lookupBCEnv_maybe = Map.lookup
1379
1380 idSizeW :: Id -> Int
1381 idSizeW id = cgRepSizeW (typeCgRep (idType id))
1382
1383 -- See bug #1257
1384 unboxedTupleException :: a
1385 unboxedTupleException
1386    = ghcError
1387         (ProgramError
1388            ("Error: bytecode compiler can't handle unboxed tuples.\n"++
1389             "  Possibly due to foreign import/export decls in source.\n"++
1390             "  Workaround: use -fobject-code, or compile this module to .o separately."))
1391
1392
1393 mkSLIDE :: Word16 -> Word16 -> OrdList BCInstr
1394 mkSLIDE n d = if d == 0 then nilOL else unitOL (SLIDE n d)
1395
1396 splitApp :: AnnExpr' Var ann -> (AnnExpr' Var ann, [AnnExpr' Var ann])
1397         -- The arguments are returned in *right-to-left* order
1398 splitApp e | Just e' <- bcView e = splitApp e'
1399 splitApp (AnnApp (_,f) (_,a))    = case splitApp f of
1400                                       (f', as) -> (f', a:as)
1401 splitApp e                       = (e, [])
1402
1403
1404 bcView :: AnnExpr' Var ann -> Maybe (AnnExpr' Var ann)
1405 -- The "bytecode view" of a term discards
1406 --  a) type abstractions
1407 --  b) type applications
1408 --  c) casts
1409 --  d) ticks (but not breakpoints)
1410 -- Type lambdas *can* occur in random expressions,
1411 -- whereas value lambdas cannot; that is why they are nuked here
1412 bcView (AnnCast (_,e) _)             = Just e
1413 bcView (AnnLam v (_,e)) | isTyVar v  = Just e
1414 bcView (AnnApp (_,e) (_, AnnType _)) = Just e
1415 bcView (AnnTick Breakpoint{} _)      = Nothing
1416 bcView (AnnTick _other_tick (_,e))   = Just e
1417 bcView _                             = Nothing
1418
1419 isVoidArgAtom :: AnnExpr' Var ann -> Bool
1420 isVoidArgAtom e | Just e' <- bcView e = isVoidArgAtom e'
1421 isVoidArgAtom (AnnVar v)              = typePrimRep (idType v) == VoidRep
1422 isVoidArgAtom (AnnCoercion {})        = True
1423 isVoidArgAtom _                       = False
1424
1425 atomPrimRep :: AnnExpr' Id ann -> PrimRep
1426 atomPrimRep e | Just e' <- bcView e = atomPrimRep e'
1427 atomPrimRep (AnnVar v)              = typePrimRep (idType v)
1428 atomPrimRep (AnnLit l)              = typePrimRep (literalType l)
1429 atomPrimRep (AnnCoercion {})        = VoidRep
1430 atomPrimRep other = pprPanic "atomPrimRep" (ppr (deAnnotate (undefined,other)))
1431
1432 atomRep :: AnnExpr' Id ann -> CgRep
1433 atomRep e = primRepToCgRep (atomPrimRep e)
1434
1435 isPtrAtom :: AnnExpr' Id ann -> Bool
1436 isPtrAtom e = atomRep e == PtrArg
1437
1438 -- Let szsw be the sizes in words of some items pushed onto the stack,
1439 -- which has initial depth d'.  Return the values which the stack environment
1440 -- should map these items to.
1441 mkStackOffsets :: Word16 -> [Word16] -> [Word16]
1442 mkStackOffsets original_depth szsw
1443    = map (subtract 1) (tail (scanl (+) original_depth szsw))
1444
1445 -- -----------------------------------------------------------------------------
1446 -- The bytecode generator's monad
1447
1448 type BcPtr = Either ItblPtr (Ptr ())
1449
1450 data BcM_State
1451    = BcM_State
1452         { uniqSupply :: UniqSupply       -- for generating fresh variable names
1453         , thisModule :: Module           -- current module (for breakpoints)
1454         , nextlabel :: Word16            -- for generating local labels
1455         , malloced  :: [BcPtr]           -- thunks malloced for current BCO
1456                                          -- Should be free()d when it is GCd
1457         , breakArray :: BreakArray       -- array of breakpoint flags
1458         }
1459
1460 newtype BcM r = BcM (BcM_State -> IO (BcM_State, r))
1461
1462 ioToBc :: IO a -> BcM a
1463 ioToBc io = BcM $ \st -> do
1464   x <- io
1465   return (st, x)
1466
1467 runBc :: UniqSupply -> Module -> ModBreaks -> BcM r -> IO (BcM_State, r)
1468 runBc us this_mod modBreaks (BcM m)
1469    = m (BcM_State us this_mod 0 [] breakArray)
1470    where
1471    breakArray = modBreaks_flags modBreaks
1472
1473 thenBc :: BcM a -> (a -> BcM b) -> BcM b
1474 thenBc (BcM expr) cont = BcM $ \st0 -> do
1475   (st1, q) <- expr st0
1476   let BcM k = cont q
1477   (st2, r) <- k st1
1478   return (st2, r)
1479
1480 thenBc_ :: BcM a -> BcM b -> BcM b
1481 thenBc_ (BcM expr) (BcM cont) = BcM $ \st0 -> do
1482   (st1, _) <- expr st0
1483   (st2, r) <- cont st1
1484   return (st2, r)
1485
1486 returnBc :: a -> BcM a
1487 returnBc result = BcM $ \st -> (return (st, result))
1488
1489 instance Monad BcM where
1490   (>>=) = thenBc
1491   (>>)  = thenBc_
1492   return = returnBc
1493
1494 emitBc :: ([BcPtr] -> ProtoBCO Name) -> BcM (ProtoBCO Name)
1495 emitBc bco
1496   = BcM $ \st -> return (st{malloced=[]}, bco (malloced st))
1497
1498 recordMallocBc :: Ptr a -> BcM ()
1499 recordMallocBc a
1500   = BcM $ \st -> return (st{malloced = Right (castPtr a) : malloced st}, ())
1501
1502 recordItblMallocBc :: ItblPtr -> BcM ()
1503 recordItblMallocBc a
1504   = BcM $ \st -> return (st{malloced = Left a : malloced st}, ())
1505
1506 getLabelBc :: BcM Word16
1507 getLabelBc
1508   = BcM $ \st -> do let nl = nextlabel st
1509                     when (nl == maxBound) $
1510                         panic "getLabelBc: Ran out of labels"
1511                     return (st{nextlabel = nl + 1}, nl)
1512
1513 getLabelsBc :: Word16 -> BcM [Word16]
1514 getLabelsBc n
1515   = BcM $ \st -> let ctr = nextlabel st
1516                  in return (st{nextlabel = ctr+n}, [ctr .. ctr+n-1])
1517
1518 getBreakArray :: BcM BreakArray
1519 getBreakArray = BcM $ \st -> return (st, breakArray st)
1520
1521 newUnique :: BcM Unique
1522 newUnique = BcM $
1523    \st -> case takeUniqFromSupply (uniqSupply st) of
1524              (uniq, us) -> let newState = st { uniqSupply = us }
1525                            in  return (newState, uniq)
1526
1527 getCurrentModule :: BcM Module
1528 getCurrentModule = BcM $ \st -> return (st, thisModule st)
1529
1530 newId :: Type -> BcM Id
1531 newId ty = do
1532     uniq <- newUnique
1533     return $ mkSysLocal tickFS uniq ty
1534
1535 tickFS :: FastString
1536 tickFS = fsLit "ticked"
1537 \end{code}