testsuite: Bump expected allocations for T12707
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.7], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'python3 boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl this makes sure `./configure --target=<cross-compile-target>`
37 dnl works as expected, since we're slightly modifying how Autoconf
38 dnl interprets build/host/target and how this interacts with $CC tests
39 test -n "$target_alias" && ac_tool_prefix=$target_alias-
40
41 dnl ----------------------------------------------------------
42 dnl ** Find unixy sort and find commands,
43 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
44
45 dnl ** Find find command (for Win32's benefit)
46 FP_PROG_FIND
47 FP_PROG_SORT
48
49 dnl ----------------------------------------------------------
50 FP_SETUP_PROJECT_VERSION
51
52 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
53 AC_SUBST([release], [1])
54
55 # First off, a distrib sanity check..
56 AC_CONFIG_SRCDIR([mk/config.mk.in])
57
58 dnl * We require autoconf version 2.69 due to
59 dnl   https://bugs.ruby-lang.org/issues/8179. Also see #14910.
60 dnl * We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
61 dnl * We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
62 dnl * Using autoconf 2.59 started to give nonsense like this
63 dnl     #define SIZEOF_CHAR 0
64 dnl   recently.
65 AC_PREREQ([2.69])
66
67 # -------------------------------------------------------------------------
68 # Prepare to generate the following header files
69 #
70 #
71 AC_CONFIG_HEADER(mk/config.h)
72
73 # No, semi-sadly, we don't do `--srcdir'...
74 if test x"$srcdir" != 'x.' ; then
75     echo "This configuration does not support the \`--srcdir' option.."
76     exit 1
77 fi
78
79 dnl --------------------------------------------------------------
80 dnl * Project specific configuration options
81 dnl --------------------------------------------------------------
82 dnl What follows is a bunch of options that can either be configured
83 dnl through command line options to the configure script or by
84 dnl supplying defns in the build tree's mk/build.mk. Having the option to
85 dnl use either is considered a Feature.
86
87 dnl ** What command to use to compile compiler sources ?
88 dnl --------------------------------------------------------------
89
90 AC_ARG_WITH([ghc],
91 [AC_HELP_STRING([--with-ghc=ARG],
92   [Use ARG as the path to GHC  [default=autodetect]])],
93   [WithGhc="$withval"],
94   [if test "$GHC" = ""; then
95     AC_PATH_PROG([GHC], [ghc])
96   fi
97   WithGhc="$GHC"])
98
99 dnl ** Tell the make system which OS we are using
100 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
101 AC_SUBST(OSTYPE)
102
103 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
104 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
105                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
106         EnableBootstrapWithDevelSnaphost=YES,
107         EnableBootstrapWithDevelSnaphost=NO
108 )
109
110 AC_ARG_ENABLE(tarballs-autodownload,
111 [AC_HELP_STRING([--enable-tarballs-autodownload],
112                 [Automatically download Windows distribution binaries if needed.])],
113         TarballsAutodownload=YES,
114         TarballsAutodownload=NO
115 )
116
117 AC_ARG_ENABLE(distro-toolchain,
118 [AC_HELP_STRING([--enable-distro-toolchain],
119                 [Do not use bundled Windows toolchain binaries.])],
120         EnableDistroToolchain=YES,
121         EnableDistroToolchain=NO
122 )
123
124 if test "$EnableDistroToolchain" = "YES"; then
125   TarballsAutodownload=NO
126 fi
127
128 dnl CC_STAGE0 is like the "previous" variable CC (inherited by CC_STAGE[123])
129 dnl but instead used by stage0 for bootstrapping stage1
130 AC_ARG_VAR(CC_STAGE0, [C compiler command (bootstrap)])
131
132 if test "$WithGhc" != ""; then
133   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
134
135   # See #15281
136   if test "$GhcMajVersion" = "8" && test "$GhcMinVersion" = "2" && test "$GhcPatchLevel" = "1"; then
137      AC_MSG_ERROR([GHC 8.2.1 is known to be buggy and cannot bootstrap this GHC release (See Trac 15281); please use GHC 8.2.2 or later.])
138   fi
139
140   if test "$GhcMajVersion" = "unknown" || test "$GhcMinVersion" = "unknown"; then
141      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
142   fi
143
144   AC_SUBST(GhcVersion)dnl
145   AC_SUBST(GhcMajVersion)dnl
146   AC_SUBST(GhcMinVersion)dnl
147   AC_SUBST(GhcPatchLevel)dnl
148   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
149   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
150
151   dnl infer CC_STAGE0 from `ghc --info` unless explicitly set by user
152   if test -z "$CC_STAGE0"; then
153     BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
154   fi
155
156   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
157   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
158   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
159   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
160 fi
161
162 dnl ** Must have GHC to build GHC
163 if test "$WithGhc" = ""
164 then
165     AC_MSG_ERROR([GHC is required.])
166 fi
167 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[8.2],
168     [AC_MSG_ERROR([GHC version 8.2 or later is required to compile GHC.])])
169
170 if test `expr $GhcMinVersion % 2` = "1"
171 then
172     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
173     then
174         AC_MSG_ERROR([
175      $WithGhc is a development snapshot of GHC, version $GhcVersion.
176      Bootstrapping using this version of GHC is not supported, and may not
177      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
178      or --with-ghc to specify a different GHC to use.])
179     fi
180 fi
181
182 GHC_PACKAGE_DB_FLAG=package-db
183 AC_SUBST(GHC_PACKAGE_DB_FLAG)
184
185 # GHC is passed to Cabal, so we need a native path
186 if test "${WithGhc}" != ""
187 then
188     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
189
190     if test "$ghc_host_os" = "mingw32"
191     then
192         if test "${OSTYPE}" = "msys"
193         then
194             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
195         else
196             # Canonicalise to <drive>:/path/to/ghc
197             WithGhc=`cygpath -m "${WithGhc}"`
198         fi
199         echo "GHC path canonicalised to: ${WithGhc}"
200     fi
201 fi
202 AC_SUBST([WithGhc])
203
204 dnl ** Without optimization some INLINE trickery fails for GHCi
205 SRC_CC_OPTS="-O"
206
207 dnl--------------------------------------------------------------------
208 dnl * Choose host(/target/build) platform
209 dnl--------------------------------------------------------------------
210 dnl If we aren't explicitly told what values to use with configure flags,
211 dnl we ask the bootstrapping compiler what platform it is for
212
213 if test "${WithGhc}" != ""
214 then
215         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
216         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
217         if test "$bootstrap_host" != "$bootstrap_target"
218         then
219                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
220         fi
221 fi
222
223 # We have to run these unconditionally, but we may discard their
224 # results in the following code
225 AC_CANONICAL_BUILD
226 AC_CANONICAL_HOST
227 AC_CANONICAL_TARGET
228
229 FPTOOLS_SET_PLATFORM_VARS
230
231 # Verify that the installed (bootstrap) GHC is capable of generating
232 # code for the requested build platform.
233 if test "$BuildPlatform" != "$bootstrap_target"
234 then
235     echo "This GHC (${WithGhc}) does not generate code for the build platform"
236     echo "   GHC target platform    : $bootstrap_target"
237     echo "   Desired build platform : $BuildPlatform"
238     exit 1
239 fi
240
241 # Testing if we shall enable shared libs support on Solaris.
242 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
243
244 SOLARIS_BROKEN_SHLD=NO
245
246 case $host in
247      i386-*-solaris2)
248      # here we go with the test
249      MINOR=`uname -r|cut -d '.' -f 2-`
250      if test "$MINOR" -lt "11"; then
251          SOLARIS_BROKEN_SHLD=YES
252      fi
253      ;;
254 esac
255
256 AC_SUBST(SOLARIS_BROKEN_SHLD)
257
258 dnl ** Do an unregisterised build?
259 dnl --------------------------------------------------------------
260 case "$TargetArch" in
261     i386|x86_64|powerpc|powerpc64|powerpc64le|arm|aarch64)
262         UnregisterisedDefault=NO
263         ;;
264     *)
265         UnregisterisedDefault=YES
266         ;;
267 esac
268 AC_ARG_ENABLE(unregisterised,
269 [AC_HELP_STRING([--enable-unregisterised],
270 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
271 [ if test x"$enableval" = x"yes"; then
272         Unregisterised=YES
273   else
274         Unregisterised=NO
275   fi
276 ],
277 [Unregisterised="$UnregisterisedDefault"]
278 )
279 AC_SUBST(Unregisterised)
280
281 dnl ** Does target have runtime linker support?
282 dnl --------------------------------------------------------------
283 case "$target" in
284     powerpc64-*|powerpc64le-*|powerpc-ibm-aix*)
285         HaskellHaveRTSLinker=NO
286         ;;
287     *)
288         HaskellHaveRTSLinker=YES
289         ;;
290 esac
291 AC_SUBST(HaskellHaveRTSLinker)
292
293 # Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
294 FP_FIND_ROOT
295
296 fail() {
297     echo >&2
298     echo "$1" >&2
299     exit 1
300 }
301
302
303 if test "$HostOS" = "mingw32"
304 then
305     # Find the mingw-w64 7z file to extract.
306     # NB. If you update the tarballs to a new version of gcc, don't
307     # forget to tweak the paths in driver/gcc/gcc.c.
308     if test "$HostArch" = "i386"
309     then
310         mingw_arch="i686"
311         tarball_dest_dir="mingw-w64/x86"
312         tarball_mingw_dir="mingw32"
313     else
314         mingw_arch="x86_64"
315         tarball_dest_dir="mingw-w64/x86_64"
316         tarball_mingw_dir="mingw64"
317     fi
318 fi
319
320 set_up_tarballs() {
321     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
322     local action
323     if test "$TarballsAutodownload" = "NO"
324     then
325         action="verify"
326     else
327         action="download"
328     fi
329     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
330     case $? in
331         0)
332            rm missing-win32-tarballs
333            ;;
334         2)
335            echo
336            echo "Error:"
337            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
338            echo
339            echo "  * run configure with the --enable-tarballs-autodownload option"
340            echo
341            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
342            echo
343            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
344            echo "    them in the ghc-tarballs directory."
345            echo
346            exit 1
347            ;;
348         *)
349            echo
350            echo "Error fetching msys2 tarballs; see errors above."
351            exit 1
352            ;;
353     esac
354
355     # Extract all the tarballs in one go
356     if ! test -d inplace/mingw
357     then
358         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
359         rm -rf inplace/mingw
360         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
361         ( cd inplace &&
362         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
363         rm ".MTREE" &&
364         rm ".PKGINFO" &&
365         cd .. ) || fail "Error: Could not extract Windows toolchains."
366
367         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
368         touch inplace/mingw
369
370         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
371         # make a wrapper around it to give it the proper paths
372         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
373         PATH=`pwd`/inplace/mingw/bin:$PATH
374         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
375
376         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
377     fi
378 }
379
380 if test "$HostOS" = "mingw32" -a "$EnableDistroToolchain" = "NO"
381 then
382     test -d inplace || mkdir inplace
383
384     # NB. Download and extract the MingW-w64 distribution if required
385     set_up_tarballs
386
387     mingwbin="$hardtop/inplace/mingw/bin/"
388     CC="${mingwbin}gcc.exe"
389     LD="${mingwbin}ld.exe"
390     NM="${mingwbin}nm.exe"
391     RANLIB="${mingwbin}ranlib.exe"
392     OBJDUMP="${mingwbin}objdump.exe"
393     fp_prog_ar="${mingwbin}ar.exe"
394
395     AC_PATH_PROG([Genlib],[genlib])
396
397     # NB. Download the perl binaries if required
398     if ! test -d inplace/perl ||
399          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
400     then
401         AC_MSG_NOTICE([Making in-tree perl tree])
402         rm -rf inplace/perl
403         mkdir inplace/perl
404         (
405             cd inplace/perl &&
406             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
407         )
408         AC_MSG_NOTICE([In-tree perl tree created])
409     fi
410 fi
411
412 # We don't want to bundle a MinGW-w64 toolchain
413 # So we have to find these individual tools.
414 if test "$EnableDistroToolchain" = "YES"
415 then
416     # Ideally should use AC_CHECK_TARGET_TOOL but our triples
417     # are screwed up. Configure doesn't think they're ever equal and
418     # so never tried without the prefix.
419     AC_PATH_PROG([CC],[gcc], [clang])
420     AC_PATH_PROG([NM],[nm])
421     AC_PATH_PROG([AR],[ar])
422     AC_PATH_PROG([RANLIB],[ranlib])
423     AC_PATH_PROG([OBJDUMP],[objdump])
424     AC_PATH_PROG([DllWrap],[dllwrap])
425     AC_PATH_PROG([Windres],[windres])
426     AC_PATH_PROG([Genlib],[genlib])
427 else
428     AC_CHECK_TARGET_TOOL([Windres],[windres])
429     AC_CHECK_TARGET_TOOL([DllWrap],[dllwrap])
430     AC_CHECK_TARGET_TOOL([OBJDUMP],[objdump])
431 fi
432
433 DllWrapCmd="$DllWrap"
434 WindresCmd="$Windres"
435
436 HAVE_GENLIB=False
437 if test "$HostOS" = "mingw32"
438 then
439     if test "$Genlib" != ""; then
440         GenlibCmd="$(cygpath -m $Genlib)"
441         HAVE_GENLIB=True
442     fi
443 fi
444
445 AC_SUBST([DllWrapCmd])
446 AC_SUBST([WindresCmd])
447 AC_SUBST([GenlibCmd])
448 AC_SUBST([HAVE_GENLIB])
449
450 FP_ICONV
451 FP_GMP
452 FP_CURSES
453
454 XCODE_VERSION()
455
456
457 dnl ** Building a cross compiler?
458 dnl --------------------------------------------------------------
459 CrossCompiling=NO
460 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
461 if test "$TargetPlatform" != "$HostPlatform" ; then
462     CrossCompiling=YES
463     cross_compiling=yes   # This tells configure that it can accept just 'target',
464                           # otherwise you get
465                           #   configure: error: cannot run C compiled programs.
466                           #   If you meant to cross compile, use `--host'.
467 fi
468 if test "$BuildPlatform" != "$HostPlatform" ; then
469    AC_MSG_ERROR([
470 You've selected:
471
472   BUILD:  $BuildPlatform   (the architecture we're building on)
473   HOST:   $HostPlatform    (the architecture the compiler we're building will execute on)
474   TARGET: $TargetPlatform  (the architecture the compiler we're building will produce code for)
475
476 BUILD must equal HOST; that is, we do not support building GHC itself
477 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
478 1 will be a cross-compiler, and stage 2 will be the cross-compiled
479 GHC.
480 ])
481 fi
482 # Despite its similarity in name to TargetPlatform, TargetPlatformFull is used
483 # in calls to subproject configure scripts and thus must be set to the autoconf
484 # triple, not the normalized GHC triple that TargetPlatform is set to.
485 #
486 # We use the non-canonicalized triple, target_alias, here since the subproject
487 # configure scripts will use this triple to construct the names of the toolchain
488 # executables. If we instead passed down the triple produced by
489 # AC_CANONICAL_TARGET then it may look for the target toolchain under the wrong
490 # name (this is a known problem in the case of the Android NDK, which has
491 # slightly odd triples).
492 #
493 # It may be better to just do away with the GHC triples altogether. This would
494 # all be taken care of for us if we configured the subprojects using
495 # AC_CONFIG_DIR, but unfortunately Cabal needs to be the one to do the
496 # configuration.
497 #
498 # We also use non-canonicalized triple when install stage1 crosscompiler
499 if test -z "${target_alias}"
500 then
501   # --target wasn't given; use result from AC_CANONICAL_TARGET
502   TargetPlatformFull="${target}"
503 else
504   TargetPlatformFull="${target_alias}"
505 fi
506 if test "$CrossCompiling" = "YES"
507 then
508   # Use value passed by user from --target=
509   CrossCompilePrefix="${TargetPlatformFull}-"
510 else
511   CrossCompilePrefix=""
512 fi
513 AC_SUBST(CrossCompiling)
514 AC_SUBST(CrossCompilePrefix)
515 AC_SUBST(TargetPlatformFull)
516 AC_SUBST(EnableDistroToolchain)
517
518 dnl ** Which gcc to use?
519 dnl --------------------------------------------------------------
520
521 AC_ARG_WITH([gcc],
522         AS_HELP_STRING([--with-gcc=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
523         AC_MSG_ERROR([--with-gcc=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
524
525 AC_ARG_WITH([clang],
526         AS_HELP_STRING([--with-clang=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
527         AC_MSG_ERROR([--with-clang=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
528
529 dnl detect compiler (prefer gcc over clang) and set $CC (unless CC already set),
530 dnl later CC is copied to CC_STAGE{1,2,3}
531 AC_PROG_CC([gcc clang])
532
533 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
534
535 dnl make extensions visible to allow feature-tests to detect them lateron
536 AC_USE_SYSTEM_EXTENSIONS
537
538 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
539 AC_PROG_CPP
540
541 # --with-hs-cpp/--with-hs-cpp-flags
542 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
543 AC_SUBST([HaskellCPPCmd])
544 AC_SUBST([HaskellCPPArgs])
545
546 FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
547 FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
548 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
549 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
550
551 dnl ** Which ld to use
552 dnl --------------------------------------------------------------
553 FIND_LD([$target],[GccUseLdOpt])
554 CONF_GCC_LINKER_OPTS_STAGE1="$CONF_GCC_LINKER_OPTS_STAGE1 $GccUseLdOpt"
555 CONF_GCC_LINKER_OPTS_STAGE2="$CONF_GCC_LINKER_OPTS_STAGE2 $GccUseLdOpt"
556 LdCmd="$LD"
557 LdNoGoldCmd="$LD_NO_GOLD"
558 CFLAGS="$CFLAGS $GccUseLdOpt"
559 AC_SUBST([LdCmd])
560 AC_SUBST([LdNoGoldCmd])
561
562 FP_PROG_LD_IS_GNU
563 FP_PROG_LD_BUILD_ID
564 FP_PROG_LD_NO_COMPACT_UNWIND
565 FP_PROG_LD_FILELIST
566
567 dnl ** Which nm to use?
568 dnl --------------------------------------------------------------
569 if test "$HostOS" != "mingw32"; then
570     AC_CHECK_TARGET_TOOL([NM], [nm])
571     if test "$NM" = ":"; then
572         AC_MSG_ERROR([cannot find nm in your PATH])
573     fi
574 fi
575 NmCmd="$NM"
576 AC_SUBST([NmCmd])
577
578 if test "$TargetOS_CPP" = "darwin"
579 then
580     AC_MSG_CHECKING(whether nm program is broken)
581     # Some versions of XCode ship a broken version of `nm`. Detect and work
582     # around this issue. See : https://ghc.haskell.org/trac/ghc/ticket/11744
583     nmver=$(${NM} --version | grep version | sed 's/ //g')
584     case "$nmver" in
585         LLVMversion7.3.0|LLVMversion7.3.1)
586             AC_MSG_RESULT(yes)
587             echo "The detected nm program is broken."
588             echo
589             echo "See: https://ghc.haskell.org/trac/ghc/ticket/11744"
590             echo
591             echo "Try re-running configure with:"
592             echo
593             echo '   NM=$(xcrun --find nm-classic) ./configure'
594             echo
595             exit 1
596             ;;
597         *)
598             AC_MSG_RESULT(no)
599             ;;
600         esac
601 fi
602
603 dnl ** Which objdump to use?
604 dnl --------------------------------------------------------------
605 dnl Note: we may not have objdump on OS X, and we only need it on
606 dnl Windows (for DLL checks), OpenBSD, and AIX
607 case $HostOS_CPP in
608   cygwin32|mingw32|openbsd|aix)
609     AC_CHECK_TARGET_TOOL([OBJDUMP], [objdump])
610     ;;
611 esac
612
613 ObjdumpCmd="$OBJDUMP"
614 AC_SUBST([ObjdumpCmd])
615
616 dnl ** Which ranlib to use?
617 dnl --------------------------------------------------------------
618 AC_PROG_RANLIB
619 if test "$RANLIB" = ":"; then
620     AC_MSG_ERROR([cannot find ranlib in your PATH])
621 fi
622 RanlibCmd="$RANLIB"
623 AC_SUBST([RanlibCmd])
624
625 dnl ** which strip to use?
626 dnl --------------------------------------------------------------
627 AC_CHECK_TARGET_TOOL([STRIP], [strip])
628 StripCmd="$STRIP"
629 AC_SUBST([StripCmd])
630
631
632 dnl ** which libtool to use?
633 dnl --------------------------------------------------------------
634 # The host normalization on Windows breaks autoconf, it no longer
635 # thinks that target == host so it never checks the unqualified
636 # tools for Windows. See #14274.
637 if test "$HostOS" = "mingw32"
638 then
639     AC_PATH_PROG([LIBTOOL],[libtool])
640     LibtoolCmd="$(cygpath -m $LIBTOOL)"
641 else
642     AC_CHECK_TARGET_TOOL([LIBTOOL], [libtool])
643     LibtoolCmd="$LIBTOOL"
644 fi
645 AC_SUBST([LibtoolCmd])
646
647 # Here is where we re-target which specific version of the LLVM
648 # tools we are looking for. In the past, GHC supported a number of
649 # versions of LLVM simultaneously, but that stopped working around
650 # 3.5/3.6 release of LLVM.
651 LlvmVersion=6.0
652 AC_SUBST([LlvmVersion])
653 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
654 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
655
656 dnl ** Which LLVM clang to use?
657 dnl --------------------------------------------------------------
658 AC_CHECK_TARGET_TOOL([CLANG], [clang])
659 ClangCmd="$CLANG"
660 AC_SUBST([ClangCmd])
661
662 dnl ** Which LLVM llc to use?
663 dnl --------------------------------------------------------------
664 FIND_LLVM_PROG([LLC], [llc], [$LlvmVersion])
665 LlcCmd="$LLC"
666 AC_SUBST([LlcCmd])
667
668 dnl ** Which LLVM opt to use?
669 dnl --------------------------------------------------------------
670 FIND_LLVM_PROG([OPT], [opt], [$LlvmVersion])
671 OptCmd="$OPT"
672 AC_SUBST([OptCmd])
673
674 dnl --------------------------------------------------------------
675 dnl End of configure script option section
676 dnl --------------------------------------------------------------
677
678 dnl ** Copy the files from the "fs" utility into the right folders.
679 dnl --------------------------------------------------------------
680 AC_MSG_NOTICE([Creating links for in-tree file handling routines.])
681 ln -f -v utils/fs/fs.* utils/lndir/
682 ln -f -v utils/fs/fs.* utils/unlit/
683 ln -f -v utils/fs/fs.* rts/
684 ln -f -v utils/fs/fs.h libraries/base/include/
685 ln -f -v utils/fs/fs.c libraries/base/cbits/
686 AC_MSG_NOTICE([Routines in place. Packages can now be build normally.])
687
688 dnl --------------------------------------------------------------
689 dnl ** Can the unix package be built?
690 dnl --------------------------------------------------------------
691
692 if test "$TargetOS" = "mingw32"
693 then
694     GhcLibsWithUnix=NO
695 else
696     GhcLibsWithUnix=YES
697 fi
698 AC_SUBST([GhcLibsWithUnix])
699
700 dnl ** does #! work?
701 AC_SYS_INTERPRETER()
702
703 # Check for split-objs
704 SplitObjsBroken=NO
705 dnl ** look for `perl'
706 case $HostOS_CPP in
707 cygwin32|mingw32)
708   if test "$EnableDistroToolchain" = "NO"; then
709     PerlCmd=$hardtop/inplace/perl/perl
710   else
711     AC_PATH_PROG([PerlCmd],[perl])
712   fi
713   # because of Trac #15051 SplitObjs is useless on Windows.  It regresses
714   # build times to days for a build, and this effect is also there for end users
715   # of GHC.  So unfortunately we have to disable it, even without having
716   # split-sections.  Though the compile time hit for split-sections should be
717   # tiny compared to this so maybe we should enable it for x86_64.
718   SplitObjsBroken=YES
719   ;;
720 *)
721     AC_PATH_PROG([PerlCmd],[perl])
722     if test -z "$PerlCmd"
723     then
724         AC_MSG_WARN([No Perl on PATH, disabling split object support])
725         SplitObjsBroken=YES
726     else
727         FPTOOLS_CHECK_PERL_VERSION
728     fi
729     ;;
730 esac
731 AC_SUBST([SplitObjsBroken])
732
733 dnl ** look for GCC and find out which version
734 dnl     Figure out which C compiler to use.  Gcc is preferred.
735 dnl     If gcc, make sure it's at least 3.0
736 dnl
737 FP_GCC_VERSION
738
739 dnl ** See whether gcc supports -no-pie
740 FP_GCC_SUPPORTS_NO_PIE
741
742 dnl ** Used to determine how to compile ghc-prim's atomics.c, used by
743 dnl    unregisterised, Sparc, and PPC backends.
744 FP_GCC_SUPPORTS__ATOMICS
745 AC_DEFINE([HAVE_C11_ATOMICS], [$CONF_GCC_SUPPORTS__ATOMICS], [Does GCC support __atomic primitives?])
746
747 FP_GCC_EXTRA_FLAGS
748
749 dnl ** look to see if we have a C compiler using an llvm back end.
750 dnl
751 FP_CC_LLVM_BACKEND
752
753 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
754 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
755 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
756 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
757 # Stage 3 won't be supported by cross-compilation
758
759 # See rules/distdir-way-opts.mk for details.
760 # Flags passed to the C compiler
761 AC_SUBST(CONF_CC_OPTS_STAGE0)
762 AC_SUBST(CONF_CC_OPTS_STAGE1)
763 AC_SUBST(CONF_CC_OPTS_STAGE2)
764 # Flags passed to the C compiler when we ask it to link
765 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
766 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
767 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
768 # Flags passed to the linker when we ask it to link
769 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
770 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
771 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
772 # Flags passed to the C preprocessor
773 AC_SUBST(CONF_CPP_OPTS_STAGE0)
774 AC_SUBST(CONF_CPP_OPTS_STAGE1)
775 AC_SUBST(CONF_CPP_OPTS_STAGE2)
776 # Flags passed to the Haskell compiler
777 AC_SUBST(CONF_HC_OPTS_STAGE0)
778 AC_SUBST(CONF_HC_OPTS_STAGE1)
779 AC_SUBST(CONF_HC_OPTS_STAGE2)
780
781 dnl ** Set up the variables for the platform in the settings file.
782 dnl May need to use gcc to find platform details.
783 dnl --------------------------------------------------------------
784 FPTOOLS_SET_HASKELL_PLATFORM_VARS
785
786 dnl ** figure out how to do context diffs
787 FP_PROG_CONTEXT_DIFF
788
789 dnl Let's make sure install-sh is executable here.  If we got it from
790 dnl a darcs repo, it might not be (see bug #978).
791 chmod +x install-sh
792 dnl ** figure out how to do a BSD-ish install
793 AC_PROG_INSTALL
794
795 dnl ** how to invoke `ar' and `ranlib'
796 FP_PROG_AR_SUPPORTS_ATFILE
797 FP_PROG_AR_NEEDS_RANLIB
798
799 dnl ** Check to see whether ln -s works
800 AC_PROG_LN_S
801
802 FP_SETTINGS
803
804 dnl ** Find the path to sed
805 AC_PATH_PROGS(SedCmd,gsed sed,sed)
806
807
808 dnl ** check for time command
809 AC_PATH_PROG(TimeCmd,time)
810
811 dnl ** check for tar
812 dnl   if GNU tar is named gtar, look for it first.
813 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
814
815 dnl ** check for compressors
816 AC_PATH_PROGS(Bzip2Cmd,bzip2, bzip2)
817 AC_PATH_PROGS(GzipCmd,gzip, gzip)
818 AC_PATH_PROGS(XzCmd,pxz xz, xz)
819
820 dnl ** check for patch
821 dnl if GNU patch is named gpatch, look for it first
822 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
823
824 dnl ** check for dtrace (currently only implemented for Mac OS X)
825 AC_ARG_ENABLE(dtrace,
826     [AC_HELP_STRING([--enable-dtrace],
827         [Enable DTrace])],
828     EnableDtrace=$enableval,
829     EnableDtrace=yes
830 )
831
832 HaveDtrace=NO
833
834 AC_PATH_PROG(DtraceCmd,dtrace)
835 if test "x$EnableDtrace" = "xyes"; then
836   if test -n "$DtraceCmd"; then
837     if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" \
838       -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xfreebsd-portbld" \
839       -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
840       HaveDtrace=YES
841     fi
842   fi
843 fi
844 AC_SUBST(HaveDtrace)
845
846 AC_PATH_PROG(HSCOLOUR,HsColour)
847 # HsColour is passed to Cabal, so we need a native path
848 if test "$HostOS"      = "mingw32" && \
849    test "${OSTYPE}"   != "msys"    && \
850    test "${HSCOLOUR}" != ""
851 then
852     # Canonicalise to <drive>:/path/to/gcc
853     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
854 fi
855
856 dnl ** check for Sphinx toolchain
857 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
858 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
859 changequote(, )dnl
860 [if test -n "$SPHINXBUILD"; then
861   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/.* v\?\([0-9]\.[0-9]\.[0-9]\)/\1/' | head -n1`;
862 fi;
863 changequote([, ])dnl
864 ])
865 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
866     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
867
868 dnl ** check for xelatex
869 AC_PATH_PROG(XELATEX,xelatex)
870
871 dnl ** check for ghc-pkg command
872 FP_PROG_GHC_PKG
873
874 dnl ** check for installed happy binary + version
875 FPTOOLS_HAPPY
876
877 dnl ** check for installed alex binary + version
878 FPTOOLS_ALEX
879
880 dnl --------------------------------------------------
881 dnl ### program checking section ends here ###
882 dnl --------------------------------------------------
883
884 dnl --------------------------------------------------
885 dnl * Platform header file and syscall feature tests
886 dnl ### checking the state of the local header files and syscalls ###
887
888 dnl ** check for full ANSI header (.h) files
889 AC_HEADER_STDC
890
891 dnl ** Enable large file support.  NB. do this before testing the type of
892 dnl    off_t, because it will affect the result of that test.
893 AC_SYS_LARGEFILE
894
895 dnl ** check for specific header (.h) files that we are interested in
896 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
897
898 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
899 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
900 [[#if HAVE_SYS_PARAM_H
901 # include <sys/param.h>
902 #endif
903 ]])
904
905 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
906 AC_HEADER_TIME
907
908 dnl ** do we have long longs?
909 AC_CHECK_TYPES([long long])
910
911 dnl ** what are the sizes of various types
912 FP_CHECK_SIZEOF_AND_ALIGNMENT(char)
913 FP_CHECK_SIZEOF_AND_ALIGNMENT(double)
914 FP_CHECK_SIZEOF_AND_ALIGNMENT(float)
915 FP_CHECK_SIZEOF_AND_ALIGNMENT(int)
916 FP_CHECK_SIZEOF_AND_ALIGNMENT(long)
917 if test "$ac_cv_type_long_long" = yes; then
918 FP_CHECK_SIZEOF_AND_ALIGNMENT(long long)
919 fi
920 FP_CHECK_SIZEOF_AND_ALIGNMENT(short)
921 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned char)
922 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned int)
923 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long)
924 if test "$ac_cv_type_long_long" = yes; then
925 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long long)
926 fi
927 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned short)
928 FP_CHECK_SIZEOF_AND_ALIGNMENT(void *)
929
930 FP_CHECK_SIZEOF_AND_ALIGNMENT(int8_t)
931 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint8_t)
932 FP_CHECK_SIZEOF_AND_ALIGNMENT(int16_t)
933 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint16_t)
934 FP_CHECK_SIZEOF_AND_ALIGNMENT(int32_t)
935 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint32_t)
936 FP_CHECK_SIZEOF_AND_ALIGNMENT(int64_t)
937 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint64_t)
938
939
940 dnl for use in settings.in
941 TargetWordSize=$ac_cv_sizeof_void_p
942 if test "x$TargetWordSize" == 8; then
943   AC_SUBST([Cabal64bit],[True])
944 else
945   AC_SUBST([Cabal64bit],[False])
946 fi
947 AC_SUBST(TargetWordSize)
948 FP_CHECK_FUNC([WinExec],
949   [@%:@include <windows.h>], [WinExec("",0)])
950
951 FP_CHECK_FUNC([GetModuleFileName],
952   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
953
954 dnl ** check for more functions
955 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
956 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
957
958 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
959 dnl ** _POSIX_C_SOURCE is defined
960 AC_CHECK_DECLS([ctime_r], , ,
961 [#define _POSIX_SOURCE 1
962 #define _POSIX_C_SOURCE 199506L
963 #include <time.h>])
964
965 dnl ** check for mingwex library
966 AC_CHECK_LIB(
967   [mingwex],
968   [closedir],
969   [AC_SUBST([HaveLibMingwEx],[YES])] [AC_SUBST([CabalMingwex],[True])],
970   [AC_SUBST([HaveLibMingwEx],[NO])] [AC_SUBST([CabalMingwex],[False])])
971
972 if test $HaveLibMingwEx = YES ; then
973   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
974 fi
975
976 dnl ** check for math library
977 dnl    Keep that check as early as possible.
978 dnl    as we need to know whether we need libm
979 dnl    for math functions or not
980 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
981 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
982 if test $HaveLibM = YES
983 then
984   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
985   AC_SUBST([CabalHaveLibm],[True])
986 else
987   AC_SUBST([CabalHaveLibm],[False])
988 fi
989
990 FP_BFD_SUPPORT
991
992 dnl ################################################################
993 dnl Check for libraries
994 dnl ################################################################
995
996 # system libffi
997
998 AC_ARG_WITH([system-libffi],
999 [AC_HELP_STRING([--with-system-libffi],
1000   [Use system provided libffi for RTS [default=no]])
1001 ])
1002
1003 AS_IF([test "x$with_system_libffi" = "xyes"],
1004   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
1005 )
1006
1007
1008 AC_SUBST(UseSystemLibFFI)
1009
1010 AC_ARG_WITH([ffi-includes],
1011 [AC_HELP_STRING([--with-ffi-includes=ARG],
1012   [Find includes for libffi in ARG [default=system default]])
1013 ],
1014 [
1015  if test "x$UseSystemLibFFI" != "xYES"; then
1016     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
1017  else
1018     FFIIncludeDir="$withval"
1019     LIBFFI_CFLAGS="-I$withval"
1020  fi
1021 ])
1022
1023 AC_SUBST(FFIIncludeDir)
1024
1025 AC_ARG_WITH([ffi-libraries],
1026 [AC_HELP_STRING([--with-ffi-libraries=ARG],
1027   [Find libffi in ARG [default=system default]])
1028 ],
1029 [
1030  if test "x$UseSystemLibFFI" != "xYES"; then
1031     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
1032  else
1033     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
1034  fi
1035 ])
1036
1037 AC_SUBST(FFILibDir)
1038
1039 AC_SUBST([CabalHaveLibffi],[False])
1040 AS_IF([test "$UseSystemLibFFI" = "YES"], [
1041  CFLAGS2="$CFLAGS"
1042  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
1043  LDFLAGS2="$LDFLAGS"
1044  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
1045  if test "$HostOS" = "openbsd";
1046  then
1047    # OpenBSD's libffi is not directly linked to the libpthread but
1048    # still requires pthread functionality. This means that any client
1049    # binary which links with libffi also needs to link with
1050    # libpthread. If it does not, then linking fails with unresolved
1051    # symbols.
1052    LDFLAGS="$LDFLAGS -lpthread"
1053  fi
1054  AC_CHECK_LIB(ffi, ffi_call,
1055   [AC_CHECK_HEADERS([ffi.h], [break], [])
1056    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])]
1057    AC_SUBST([CabalHaveLibffi],[True]),
1058   [AC_MSG_ERROR([Cannot find system libffi])])
1059  CFLAGS="$CFLAGS2"
1060  LDFLAGS="$LDFLAGS2"
1061 ])
1062
1063 dnl ** check whether we need -ldl to get dlopen()
1064 AC_CHECK_LIB([dl], [dlopen])
1065 AC_CHECK_LIB([dl], [dlopen], [AC_SUBST([CabalHaveLibdl], [True])], [AC_SUBST([CabalHaveLibdl], [False])])
1066
1067 dnl --------------------------------------------------
1068 dnl * Miscellaneous feature tests
1069 dnl --------------------------------------------------
1070
1071 dnl ** can we get alloca?
1072 AC_FUNC_ALLOCA
1073
1074 dnl ** working vfork?
1075 AC_FUNC_FORK
1076
1077 dnl ** determine whether or not const works
1078 AC_C_CONST
1079
1080 dnl ** are we big endian?
1081 AC_C_BIGENDIAN
1082 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
1083
1084 dnl ** check for leading underscores in symbol names
1085 FP_LEADING_UNDERSCORE
1086
1087 FP_VISIBILITY_HIDDEN
1088
1089 dnl ** check for librt
1090 AC_CHECK_LIB([rt], [clock_gettime])
1091 AC_CHECK_LIB([rt], [clock_gettime], [AC_SUBST([CabalHaveLibrt], [True])], [AC_SUBST([CabalHaveLibrt], [False])])
1092 AC_CHECK_FUNCS(clock_gettime timer_settime)
1093 FP_CHECK_TIMER_CREATE
1094
1095 dnl ** check for Apple's "interesting" long double compatibility scheme
1096 AC_MSG_CHECKING(for printf\$LDBLStub)
1097 AC_TRY_LINK_FUNC(printf\$LDBLStub,
1098     [
1099         AC_MSG_RESULT(yes)
1100         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
1101             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
1102     ],
1103     [
1104         AC_MSG_RESULT(no)
1105         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
1106             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
1107     ])
1108
1109 dnl Some platforms (e.g. Android's Bionic) have pthreads support available
1110 dnl without linking against libpthread. Check whether -lpthread is necessary
1111 dnl to use pthreads.
1112 dnl
1113 dnl Note that it is important that this happens before we AC_CHECK_LIB(thread)
1114 AC_MSG_CHECKING(whether -lpthread is needed for pthreads)
1115 AC_CHECK_FUNC(pthread_create,
1116     [
1117         AC_MSG_RESULT(no)
1118         AC_SUBST([CabalNeedLibpthread],[False])
1119         need_lpthread=0
1120     ],
1121     [
1122         AC_CHECK_LIB(pthread, pthread_create,
1123             [
1124                 AC_MSG_RESULT(yes)
1125                 AC_SUBST([CabalNeedLibpthread],[True])
1126                 need_lpthread=1
1127             ],
1128             [
1129                 AC_SUBST([CabalNeedLibpthread],[False])
1130                 AC_MSG_RESULT([no pthreads support found.])
1131                 need_lpthread=0
1132             ])
1133     ])
1134 AC_DEFINE_UNQUOTED([NEED_PTHREAD_LIB], [$need_lpthread],
1135     [Define 1 if we need to link code using pthreads with -lpthread])
1136
1137 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
1138 dnl    a different single-argument version.
1139 AC_CHECK_LIB(pthread, pthread_setname_np)
1140 AC_MSG_CHECKING(for pthread_setname_np)
1141 AC_TRY_LINK(
1142 [
1143 #define _GNU_SOURCE
1144 #include <pthread.h>
1145 ],
1146 [pthread_setname_np(pthread_self(), "name");],
1147     AC_MSG_RESULT(yes)
1148     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
1149       [Define to 1 if you have the glibc version of pthread_setname_np]),
1150     AC_MSG_RESULT(no)
1151 )
1152
1153 dnl ** check for eventfd which is needed by the I/O manager
1154 AC_CHECK_HEADERS([sys/eventfd.h])
1155 AC_CHECK_FUNCS([eventfd])
1156
1157 dnl ** Check for __thread support in the compiler
1158 AC_MSG_CHECKING(for __thread support)
1159 AC_COMPILE_IFELSE(
1160   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1161   [
1162    AC_MSG_RESULT(yes)
1163    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1164   ],
1165   [
1166    AC_MSG_RESULT(no)
1167    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1168   ])
1169
1170 dnl large address space support (see includes/rts/storage/MBlock.h)
1171 dnl
1172 dnl Darwin has vm_allocate/vm_protect
1173 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1174 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1175 dnl (They also have MADV_DONTNEED, but it means something else!)
1176 dnl
1177 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1178 dnl it counts page-table space as committed memory, and so quickly
1179 dnl runs out of paging file when we have multiple processes reserving
1180 dnl 1TB of address space, we get the following error:
1181 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1182 dnl
1183
1184 AC_ARG_ENABLE(large-address-space,
1185     [AC_HELP_STRING([--enable-large-address-space],
1186         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1187     EnableLargeAddressSpace=$enableval,
1188     EnableLargeAddressSpace=yes
1189 )
1190
1191 use_large_address_space=no
1192 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1193     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1194         if test "$ghc_host_os" = "darwin" ; then
1195             use_large_address_space=yes
1196         elif test "$ghc_host_os" = "openbsd" ; then
1197             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1198             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1199             # but is completely ignored by OS mmap
1200             use_large_address_space=no
1201         else
1202             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1203                 [
1204                 #include <unistd.h>
1205                 #include <sys/types.h>
1206                 #include <sys/mman.h>
1207                 #include <fcntl.h>
1208             ])
1209             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1210                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1211                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1212                     use_large_address_space=yes
1213             fi
1214         fi
1215     fi
1216 fi
1217 if test "$use_large_address_space" = "yes" ; then
1218    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1219 fi
1220
1221 dnl ** Use MMAP in the runtime linker?
1222 dnl --------------------------------------------------------------
1223
1224 case ${TargetOS} in
1225     linux|linux-android|freebsd|dragonfly|netbsd|openbsd|kfreebsdgnu|gnu|solaris2)
1226         RtsLinkerUseMmap=1
1227         ;;
1228     darwin|ios|watchos|tvos)
1229         # Don't use mmap on powerpc/darwin as the mmap there doesn't support
1230         # reallocating. Reallocating is needed to allocate jump islands just
1231         # after each object image. Jumps to these jump islands use relative
1232         # branches which are limited to offsets that can be represented in
1233         # 24-bits.
1234         if test "$TargetArch" != "powerpc" ; then
1235             RtsLinkerUseMmap=1
1236         else
1237             RtsLinkerUseMmap=0
1238         fi
1239         ;;
1240     *)
1241         # Windows (which doesn't have mmap) and everything else.
1242         RtsLinkerUseMmap=0
1243         ;;
1244     esac
1245
1246 AC_DEFINE_UNQUOTED([RTS_LINKER_USE_MMAP], [$RtsLinkerUseMmap],
1247                    [Use mmap in the runtime linker])
1248
1249 dnl ** Have libdw?
1250 dnl --------------------------------------------------------------
1251 UseLibdw=NO
1252 USE_LIBDW=0
1253 AC_ARG_ENABLE(dwarf-unwind,
1254     [AC_HELP_STRING([--enable-dwarf-unwind],
1255         [Enable DWARF unwinding support in the runtime system via elfutils' libdw [default=no]])],
1256     [AC_CHECK_LIB(dw, dwfl_attach_state, [UseLibdw=YES], [UseLibdw=NO])],
1257     [UseLibdw=NO]
1258 )
1259 AC_SUBST(UseLibdw)
1260 if test $UseLibdw = "YES" ; then
1261         USE_LIBDW=1
1262   AC_SUBST([CabalHaveLibdw],[True])
1263 else
1264   AC_SUBST([CabalHaveLibdw],[False])
1265 fi
1266 AC_DEFINE_UNQUOTED([USE_LIBDW], [$USE_LIBDW], [Set to 1 to use libdw])
1267
1268 dnl ** Have libnuma?
1269 dnl --------------------------------------------------------------
1270 HaveLibNuma=0
1271 AC_CHECK_HEADERS([numa.h numaif.h])
1272
1273 if test "$ac_cv_header_numa_h$ac_cv_header_numaif_h" = "yesyes" ; then
1274     AC_CHECK_LIB(numa, numa_available,HaveLibNuma=1)
1275 fi
1276 AC_DEFINE_UNQUOTED([HAVE_LIBNUMA], [$HaveLibNuma], [Define to 1 if you have libnuma])
1277 if test $HaveLibNuma = "1" ; then
1278   AC_SUBST([CabalHaveLibNuma],[True])
1279 else
1280   AC_SUBST([CabalHaveLibNuma],[False])
1281 fi
1282
1283
1284 dnl ** Documentation
1285 dnl --------------------------------------------------------------
1286 if test -n "$SPHINXBUILD"; then
1287     BUILD_MAN=YES
1288     BUILD_SPHINX_HTML=YES
1289     if test -n "$XELATEX"; then
1290         BUILD_SPHINX_PDF=YES
1291     else
1292         BUILD_SPHINX_PDF=NO
1293     fi
1294 else
1295     BUILD_MAN=NO
1296     BUILD_SPHINX_HTML=NO
1297     BUILD_SPHINX_PDF=NO
1298 fi
1299 AC_SUBST(BUILD_MAN)
1300 AC_SUBST(BUILD_SPHINX_HTML)
1301 AC_SUBST(BUILD_SPHINX_PDF)
1302
1303 LIBRARY_VERSION(base)
1304 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1305 LIBRARY_VERSION(ghc-prim)
1306 LIBRARY_VERSION(ghc-compact)
1307 LIBRARY_ghc_VERSION="$ProjectVersion"
1308 AC_SUBST(LIBRARY_ghc_VERSION)
1309
1310 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1311    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1312 fi
1313
1314 # Create the configuration for the Hadrian build system if it is present
1315 if test -e hadrian/cfg/system.config.in; then
1316     AC_CONFIG_FILES([hadrian/cfg/system.config])
1317 fi
1318
1319 # We got caught by
1320 #     http://savannah.gnu.org/bugs/index.php?1516
1321 #     $(eval ...) inside conditionals causes errors
1322 # with make 3.80, so warn the user if it looks like they're about to
1323 # try to use it.
1324 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1325 print_make_warning=""
1326 checkMake380() {
1327     make_ver=`$1 --version 2>&1 | head -1`
1328     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1329     then
1330         print_make_warning="true"
1331     fi
1332     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1333     then
1334         MakeCmd=$1
1335         AC_SUBST(MakeCmd)
1336     fi
1337 }
1338
1339 checkMake380 make
1340 checkMake380 gmake
1341
1342 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk rts/rts.cabal compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal utils/gen-dll/gen-dll.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghc-boot-th/ghc-boot-th.cabal libraries/ghci/ghci.cabal libraries/ghc-heap/ghc-heap.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt distrib/configure.ac])
1343 AC_OUTPUT
1344 [
1345 if test "$print_make_warning" = "true"; then
1346    echo
1347    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1348    echo "This version cannot be used to build GHC."
1349    echo "Please use GNU make >= 3.81."
1350 fi
1351
1352 echo "
1353 ----------------------------------------------------------------------
1354 Configure completed successfully.
1355
1356    Building GHC version  : $ProjectVersion
1357           Git commit id  : $ProjectGitCommitId
1358
1359    Build platform        : $BuildPlatform
1360    Host platform         : $HostPlatform
1361    Target platform       : $TargetPlatform
1362 "
1363
1364 echo "\
1365    Bootstrapping using   : $WithGhc
1366       which is version   : $GhcVersion
1367 "
1368
1369 if test "x$CC_LLVM_BACKEND" = "x1"; then
1370     if test "x$CC_CLANG_BACKEND" = "x1"; then
1371         CompilerName="clang        "
1372     else
1373         CompilerName="llvm-gcc     "
1374     fi
1375 else
1376     CompilerName="gcc          "
1377 fi
1378
1379 echo "\
1380    Using (for bootstrapping) : $CC_STAGE0
1381    Using $CompilerName       : $CC
1382       which is version       : $GccVersion
1383    Building a cross compiler : $CrossCompiling
1384    Unregisterised            : $Unregisterised
1385    hs-cpp       : $HaskellCPPCmd
1386    hs-cpp-flags : $HaskellCPPArgs
1387    ar           : $ArCmd
1388    ld           : $LdCmd
1389    nm           : $NmCmd
1390    libtool      : $LibtoolCmd
1391    objdump      : $ObjdumpCmd
1392    ranlib       : $RanlibCmd
1393    windres      : $WindresCmd
1394    dllwrap      : $DllWrapCmd
1395    genlib       : $GenlibCmd
1396    Happy        : $HappyCmd ($HappyVersion)
1397    Alex         : $AlexCmd ($AlexVersion)
1398    Perl         : $PerlCmd
1399    sphinx-build : $SPHINXBUILD
1400    xelatex      : $XELATEX
1401
1402    Using LLVM tools
1403       clang : $ClangCmd
1404       llc   : $LlcCmd
1405       opt   : $OptCmd"
1406
1407 if test "$HSCOLOUR" = ""; then
1408 echo "
1409    HsColour was not found; documentation will not contain source links
1410 "
1411 else
1412 echo "\
1413    HsColour : $HSCOLOUR
1414 "
1415 fi
1416
1417 echo "\
1418    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1419    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"
1420
1421 echo "----------------------------------------------------------------------
1422 "
1423
1424 echo "\
1425 For a standard build of GHC (fully optimised with profiling), type (g)make.
1426
1427 To make changes to the default build configuration, copy the file
1428 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1429
1430 For more information on how to configure your GHC build, see
1431    http://ghc.haskell.org/trac/ghc/wiki/Building
1432 "]