Don't infer CallStacks
[ghc.git] / compiler / typecheck / TcBinds.hs
1 {-
2 (c) The University of Glasgow 2006
3 (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4
5 \section[TcBinds]{TcBinds}
6 -}
7
8 {-# LANGUAGE CPP, RankNTypes, ScopedTypeVariables #-}
9
10 module TcBinds ( tcLocalBinds, tcTopBinds, tcRecSelBinds,
11 tcValBinds, tcHsBootSigs, tcPolyCheck,
12 tcSpecPrags, tcSpecWrapper,
13 tcVectDecls, addTypecheckedBinds,
14 TcSigInfo(..), TcSigFun,
15 TcPragEnv, mkPragEnv,
16 tcUserTypeSig, instTcTySig, chooseInferredQuantifiers,
17 instTcTySigFromId, tcExtendTyVarEnvFromSig,
18 badBootDeclErr ) where
19
20 import {-# SOURCE #-} TcMatches ( tcGRHSsPat, tcMatchesFun )
21 import {-# SOURCE #-} TcExpr ( tcMonoExpr )
22 import {-# SOURCE #-} TcPatSyn ( tcInferPatSynDecl, tcCheckPatSynDecl
23 , tcPatSynBuilderBind, tcPatSynSig )
24 import DynFlags
25 import HsSyn
26 import HscTypes( isHsBootOrSig )
27 import TcRnMonad
28 import TcEnv
29 import TcUnify
30 import TcSimplify
31 import TcEvidence
32 import TcHsType
33 import TcPat
34 import TcMType
35 import Inst( topInstantiate, deeplyInstantiate )
36 import FamInstEnv( normaliseType )
37 import FamInst( tcGetFamInstEnvs )
38 import TyCon
39 import TcType
40 import TysPrim
41 import Id
42 import Var
43 import VarSet
44 import VarEnv( TidyEnv )
45 import Module
46 import Name
47 import NameSet
48 import NameEnv
49 import SrcLoc
50 import Bag
51 import ListSetOps
52 import ErrUtils
53 import Digraph
54 import Maybes
55 import Util
56 import BasicTypes
57 import Outputable
58 import Type(mkStrLitTy, tidyOpenType)
59 import PrelNames( mkUnboundName, gHC_PRIM, ipClassName )
60 import TcValidity (checkValidType)
61 import qualified GHC.LanguageExtensions as LangExt
62
63 import Control.Monad
64
65 #include "HsVersions.h"
66
67 {- *********************************************************************
68 * *
69 A useful helper function
70 * *
71 ********************************************************************* -}
72
73 addTypecheckedBinds :: TcGblEnv -> [LHsBinds Id] -> TcGblEnv
74 addTypecheckedBinds tcg_env binds
75 | isHsBootOrSig (tcg_src tcg_env) = tcg_env
76 -- Do not add the code for record-selector bindings
77 -- when compiling hs-boot files
78 | otherwise = tcg_env { tcg_binds = foldr unionBags
79 (tcg_binds tcg_env)
80 binds }
81
82 {-
83 ************************************************************************
84 * *
85 \subsection{Type-checking bindings}
86 * *
87 ************************************************************************
88
89 @tcBindsAndThen@ typechecks a @HsBinds@. The "and then" part is because
90 it needs to know something about the {\em usage} of the things bound,
91 so that it can create specialisations of them. So @tcBindsAndThen@
92 takes a function which, given an extended environment, E, typechecks
93 the scope of the bindings returning a typechecked thing and (most
94 important) an LIE. It is this LIE which is then used as the basis for
95 specialising the things bound.
96
97 @tcBindsAndThen@ also takes a "combiner" which glues together the
98 bindings and the "thing" to make a new "thing".
99
100 The real work is done by @tcBindWithSigsAndThen@.
101
102 Recursive and non-recursive binds are handled in essentially the same
103 way: because of uniques there are no scoping issues left. The only
104 difference is that non-recursive bindings can bind primitive values.
105
106 Even for non-recursive binding groups we add typings for each binder
107 to the LVE for the following reason. When each individual binding is
108 checked the type of its LHS is unified with that of its RHS; and
109 type-checking the LHS of course requires that the binder is in scope.
110
111 At the top-level the LIE is sure to contain nothing but constant
112 dictionaries, which we resolve at the module level.
113
114 Note [Polymorphic recursion]
115 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
116 The game plan for polymorphic recursion in the code above is
117
118 * Bind any variable for which we have a type signature
119 to an Id with a polymorphic type. Then when type-checking
120 the RHSs we'll make a full polymorphic call.
121
122 This fine, but if you aren't a bit careful you end up with a horrendous
123 amount of partial application and (worse) a huge space leak. For example:
124
125 f :: Eq a => [a] -> [a]
126 f xs = ...f...
127
128 If we don't take care, after typechecking we get
129
130 f = /\a -> \d::Eq a -> let f' = f a d
131 in
132 \ys:[a] -> ...f'...
133
134 Notice the the stupid construction of (f a d), which is of course
135 identical to the function we're executing. In this case, the
136 polymorphic recursion isn't being used (but that's a very common case).
137 This can lead to a massive space leak, from the following top-level defn
138 (post-typechecking)
139
140 ff :: [Int] -> [Int]
141 ff = f Int dEqInt
142
143 Now (f dEqInt) evaluates to a lambda that has f' as a free variable; but
144 f' is another thunk which evaluates to the same thing... and you end
145 up with a chain of identical values all hung onto by the CAF ff.
146
147 ff = f Int dEqInt
148
149 = let f' = f Int dEqInt in \ys. ...f'...
150
151 = let f' = let f' = f Int dEqInt in \ys. ...f'...
152 in \ys. ...f'...
153
154 Etc.
155
156 NOTE: a bit of arity anaysis would push the (f a d) inside the (\ys...),
157 which would make the space leak go away in this case
158
159 Solution: when typechecking the RHSs we always have in hand the
160 *monomorphic* Ids for each binding. So we just need to make sure that
161 if (Method f a d) shows up in the constraints emerging from (...f...)
162 we just use the monomorphic Id. We achieve this by adding monomorphic Ids
163 to the "givens" when simplifying constraints. That's what the "lies_avail"
164 is doing.
165
166 Then we get
167
168 f = /\a -> \d::Eq a -> letrec
169 fm = \ys:[a] -> ...fm...
170 in
171 fm
172 -}
173
174 tcTopBinds :: [(RecFlag, LHsBinds Name)] -> [LSig Name] -> TcM (TcGblEnv, TcLclEnv)
175 -- The TcGblEnv contains the new tcg_binds and tcg_spects
176 -- The TcLclEnv has an extended type envt for the new bindings
177 tcTopBinds binds sigs
178 = do { -- Pattern synonym bindings populate the global environment
179 (binds', (tcg_env, tcl_env)) <- tcValBinds TopLevel binds sigs $
180 do { gbl <- getGblEnv
181 ; lcl <- getLclEnv
182 ; return (gbl, lcl) }
183 ; specs <- tcImpPrags sigs -- SPECIALISE prags for imported Ids
184
185 ; let { tcg_env' = tcg_env { tcg_imp_specs = specs ++ tcg_imp_specs tcg_env }
186 `addTypecheckedBinds` map snd binds' }
187
188 ; return (tcg_env', tcl_env) }
189 -- The top level bindings are flattened into a giant
190 -- implicitly-mutually-recursive LHsBinds
191
192 tcRecSelBinds :: HsValBinds Name -> TcM TcGblEnv
193 tcRecSelBinds (ValBindsOut binds sigs)
194 = tcExtendGlobalValEnv [sel_id | L _ (IdSig sel_id) <- sigs] $
195 do { (rec_sel_binds, tcg_env) <- discardWarnings $
196 tcValBinds TopLevel binds sigs getGblEnv
197 ; let tcg_env' = tcg_env `addTypecheckedBinds` map snd rec_sel_binds
198 ; return tcg_env' }
199 tcRecSelBinds (ValBindsIn {}) = panic "tcRecSelBinds"
200
201 tcHsBootSigs :: [(RecFlag, LHsBinds Name)] -> [LSig Name] -> TcM [Id]
202 -- A hs-boot file has only one BindGroup, and it only has type
203 -- signatures in it. The renamer checked all this
204 tcHsBootSigs binds sigs
205 = do { checkTc (null binds) badBootDeclErr
206 ; concat <$> mapM (addLocM tc_boot_sig) (filter isTypeLSig sigs) }
207 where
208 tc_boot_sig (TypeSig lnames hs_ty) = mapM f lnames
209 where
210 f (L _ name)
211 = do { sigma_ty <- solveEqualities $
212 tcHsSigWcType (FunSigCtxt name False) hs_ty
213 ; return (mkVanillaGlobal name sigma_ty) }
214 -- Notice that we make GlobalIds, not LocalIds
215 tc_boot_sig s = pprPanic "tcHsBootSigs/tc_boot_sig" (ppr s)
216
217 badBootDeclErr :: MsgDoc
218 badBootDeclErr = text "Illegal declarations in an hs-boot file"
219
220 ------------------------
221 tcLocalBinds :: HsLocalBinds Name -> TcM thing
222 -> TcM (HsLocalBinds TcId, thing)
223
224 tcLocalBinds EmptyLocalBinds thing_inside
225 = do { thing <- thing_inside
226 ; return (EmptyLocalBinds, thing) }
227
228 tcLocalBinds (HsValBinds (ValBindsOut binds sigs)) thing_inside
229 = do { (binds', thing) <- tcValBinds NotTopLevel binds sigs thing_inside
230 ; return (HsValBinds (ValBindsOut binds' sigs), thing) }
231 tcLocalBinds (HsValBinds (ValBindsIn {})) _ = panic "tcLocalBinds"
232
233 tcLocalBinds (HsIPBinds (IPBinds ip_binds _)) thing_inside
234 = do { ipClass <- tcLookupClass ipClassName
235 ; (given_ips, ip_binds') <-
236 mapAndUnzipM (wrapLocSndM (tc_ip_bind ipClass)) ip_binds
237
238 -- If the binding binds ?x = E, we must now
239 -- discharge any ?x constraints in expr_lie
240 -- See Note [Implicit parameter untouchables]
241 ; (ev_binds, result) <- checkConstraints (IPSkol ips)
242 [] given_ips thing_inside
243
244 ; return (HsIPBinds (IPBinds ip_binds' ev_binds), result) }
245 where
246 ips = [ip | L _ (IPBind (Left (L _ ip)) _) <- ip_binds]
247
248 -- I wonder if we should do these one at at time
249 -- Consider ?x = 4
250 -- ?y = ?x + 1
251 tc_ip_bind ipClass (IPBind (Left (L _ ip)) expr)
252 = do { ty <- newOpenFlexiTyVarTy
253 ; let p = mkStrLitTy $ hsIPNameFS ip
254 ; ip_id <- newDict ipClass [ p, ty ]
255 ; expr' <- tcMonoExpr expr (mkCheckExpType ty)
256 ; let d = toDict ipClass p ty `fmap` expr'
257 ; return (ip_id, (IPBind (Right ip_id) d)) }
258 tc_ip_bind _ (IPBind (Right {}) _) = panic "tc_ip_bind"
259
260 -- Coerces a `t` into a dictionry for `IP "x" t`.
261 -- co : t -> IP "x" t
262 toDict ipClass x ty = HsWrap $ mkWpCastR $
263 wrapIP $ mkClassPred ipClass [x,ty]
264
265 {- Note [Implicit parameter untouchables]
266 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
267 We add the type variables in the types of the implicit parameters
268 as untouchables, not so much because we really must not unify them,
269 but rather because we otherwise end up with constraints like this
270 Num alpha, Implic { wanted = alpha ~ Int }
271 The constraint solver solves alpha~Int by unification, but then
272 doesn't float that solved constraint out (it's not an unsolved
273 wanted). Result disaster: the (Num alpha) is again solved, this
274 time by defaulting. No no no.
275
276 However [Oct 10] this is all handled automatically by the
277 untouchable-range idea.
278
279 Note [Inlining and hs-boot files]
280 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
281 Consider this example (Trac #10083):
282
283 ---------- RSR.hs-boot ------------
284 module RSR where
285 data RSR
286 eqRSR :: RSR -> RSR -> Bool
287
288 ---------- SR.hs ------------
289 module SR where
290 import {-# SOURCE #-} RSR
291 data SR = MkSR RSR
292 eqSR (MkSR r1) (MkSR r2) = eqRSR r1 r2
293
294 ---------- RSR.hs ------------
295 module RSR where
296 import SR
297 data RSR = MkRSR SR -- deriving( Eq )
298 eqRSR (MkRSR s1) (MkRSR s2) = (eqSR s1 s2)
299 foo x y = not (eqRSR x y)
300
301 When compiling RSR we get this code
302
303 RSR.eqRSR :: RSR -> RSR -> Bool
304 RSR.eqRSR = \ (ds1 :: RSR.RSR) (ds2 :: RSR.RSR) ->
305 case ds1 of _ { RSR.MkRSR s1 ->
306 case ds2 of _ { RSR.MkRSR s2 ->
307 SR.eqSR s1 s2 }}
308
309 RSR.foo :: RSR -> RSR -> Bool
310 RSR.foo = \ (x :: RSR) (y :: RSR) -> not (RSR.eqRSR x y)
311
312 Now, when optimising foo:
313 Inline eqRSR (small, non-rec)
314 Inline eqSR (small, non-rec)
315 but the result of inlining eqSR from SR is another call to eqRSR, so
316 everything repeats. Neither eqSR nor eqRSR are (apparently) loop
317 breakers.
318
319 Solution: when compiling RSR, add a NOINLINE pragma to every function
320 exported by the boot-file for RSR (if it exists).
321
322 ALAS: doing so makes the boostrappted GHC itself slower by 8% overall
323 (on Trac #9872a-d, and T1969. So I un-did this change, and
324 parked it for now. Sigh.
325 -}
326
327 tcValBinds :: TopLevelFlag
328 -> [(RecFlag, LHsBinds Name)] -> [LSig Name]
329 -> TcM thing
330 -> TcM ([(RecFlag, LHsBinds TcId)], thing)
331
332 tcValBinds top_lvl binds sigs thing_inside
333 = do { let patsyns = getPatSynBinds binds
334
335 -- Typecheck the signature
336 ; (poly_ids, sig_fn) <- tcAddPatSynPlaceholders patsyns $
337 tcTySigs sigs
338
339 ; _self_boot <- tcSelfBootInfo
340 ; let prag_fn = mkPragEnv sigs (foldr (unionBags . snd) emptyBag binds)
341
342 -- ------- See Note [Inlining and hs-boot files] (change parked) --------
343 -- prag_fn | isTopLevel top_lvl -- See Note [Inlining and hs-boot files]
344 -- , SelfBoot { sb_ids = boot_id_names } <- self_boot
345 -- = foldNameSet add_no_inl prag_fn1 boot_id_names
346 -- | otherwise
347 -- = prag_fn1
348 -- add_no_inl boot_id_name prag_fn
349 -- = extendPragEnv prag_fn (boot_id_name, no_inl_sig boot_id_name)
350 -- no_inl_sig name = L boot_loc (InlineSig (L boot_loc name) neverInlinePragma)
351 -- boot_loc = mkGeneralSrcSpan (fsLit "The hs-boot file for this module")
352
353 -- Extend the envt right away with all the Ids
354 -- declared with complete type signatures
355 -- Do not extend the TcIdBinderStack; instead
356 -- we extend it on a per-rhs basis in tcExtendForRhs
357 ; tcExtendLetEnvIds top_lvl [(idName id, id) | id <- poly_ids] $ do
358 { (binds', (extra_binds', thing)) <- tcBindGroups top_lvl sig_fn prag_fn binds $ do
359 { thing <- thing_inside
360 -- See Note [Pattern synonym builders don't yield dependencies]
361 ; patsyn_builders <- mapM (tcPatSynBuilderBind sig_fn) patsyns
362 ; let extra_binds = [ (NonRecursive, builder) | builder <- patsyn_builders ]
363 ; return (extra_binds, thing) }
364 ; return (binds' ++ extra_binds', thing) }}
365
366 ------------------------
367 tcBindGroups :: TopLevelFlag -> TcSigFun -> TcPragEnv
368 -> [(RecFlag, LHsBinds Name)] -> TcM thing
369 -> TcM ([(RecFlag, LHsBinds TcId)], thing)
370 -- Typecheck a whole lot of value bindings,
371 -- one strongly-connected component at a time
372 -- Here a "strongly connected component" has the strightforward
373 -- meaning of a group of bindings that mention each other,
374 -- ignoring type signatures (that part comes later)
375
376 tcBindGroups _ _ _ [] thing_inside
377 = do { thing <- thing_inside
378 ; return ([], thing) }
379
380 tcBindGroups top_lvl sig_fn prag_fn (group : groups) thing_inside
381 = do { (group', (groups', thing))
382 <- tc_group top_lvl sig_fn prag_fn group $
383 tcBindGroups top_lvl sig_fn prag_fn groups thing_inside
384 ; return (group' ++ groups', thing) }
385
386 ------------------------
387 tc_group :: forall thing.
388 TopLevelFlag -> TcSigFun -> TcPragEnv
389 -> (RecFlag, LHsBinds Name) -> TcM thing
390 -> TcM ([(RecFlag, LHsBinds TcId)], thing)
391
392 -- Typecheck one strongly-connected component of the original program.
393 -- We get a list of groups back, because there may
394 -- be specialisations etc as well
395
396 tc_group top_lvl sig_fn prag_fn (NonRecursive, binds) thing_inside
397 -- A single non-recursive binding
398 -- We want to keep non-recursive things non-recursive
399 -- so that we desugar unlifted bindings correctly
400 = do { let bind = case bagToList binds of
401 [bind] -> bind
402 [] -> panic "tc_group: empty list of binds"
403 _ -> panic "tc_group: NonRecursive binds is not a singleton bag"
404 ; (bind', thing) <- tc_single top_lvl sig_fn prag_fn bind thing_inside
405 ; return ( [(NonRecursive, bind')], thing) }
406
407 tc_group top_lvl sig_fn prag_fn (Recursive, binds) thing_inside
408 = -- To maximise polymorphism, we do a new
409 -- strongly-connected-component analysis, this time omitting
410 -- any references to variables with type signatures.
411 -- (This used to be optional, but isn't now.)
412 -- See Note [Polymorphic recursion] in HsBinds.
413 do { traceTc "tc_group rec" (pprLHsBinds binds)
414 ; when hasPatSyn $ recursivePatSynErr binds
415 ; (binds1, thing) <- go sccs
416 ; return ([(Recursive, binds1)], thing) }
417 -- Rec them all together
418 where
419 hasPatSyn = anyBag (isPatSyn . unLoc) binds
420 isPatSyn PatSynBind{} = True
421 isPatSyn _ = False
422
423 sccs :: [SCC (LHsBind Name)]
424 sccs = stronglyConnCompFromEdgedVertices (mkEdges sig_fn binds)
425
426 go :: [SCC (LHsBind Name)] -> TcM (LHsBinds TcId, thing)
427 go (scc:sccs) = do { (binds1, ids1) <- tc_scc scc
428 ; (binds2, thing) <- tcExtendLetEnv top_lvl ids1 $
429 go sccs
430 ; return (binds1 `unionBags` binds2, thing) }
431 go [] = do { thing <- thing_inside; return (emptyBag, thing) }
432
433 tc_scc (AcyclicSCC bind) = tc_sub_group NonRecursive [bind]
434 tc_scc (CyclicSCC binds) = tc_sub_group Recursive binds
435
436 tc_sub_group = tcPolyBinds top_lvl sig_fn prag_fn Recursive
437
438 recursivePatSynErr :: OutputableBndr name => LHsBinds name -> TcM a
439 recursivePatSynErr binds
440 = failWithTc $
441 hang (text "Recursive pattern synonym definition with following bindings:")
442 2 (vcat $ map pprLBind . bagToList $ binds)
443 where
444 pprLoc loc = parens (text "defined at" <+> ppr loc)
445 pprLBind (L loc bind) = pprWithCommas ppr (collectHsBindBinders bind) <+>
446 pprLoc loc
447
448 tc_single :: forall thing.
449 TopLevelFlag -> TcSigFun -> TcPragEnv
450 -> LHsBind Name -> TcM thing
451 -> TcM (LHsBinds TcId, thing)
452 tc_single _top_lvl sig_fn _prag_fn (L _ (PatSynBind psb@PSB{ psb_id = L _ name })) thing_inside
453 = do { (aux_binds, tcg_env) <- tc_pat_syn_decl
454 ; thing <- setGblEnv tcg_env thing_inside
455 ; return (aux_binds, thing)
456 }
457 where
458 tc_pat_syn_decl :: TcM (LHsBinds TcId, TcGblEnv)
459 tc_pat_syn_decl = case sig_fn name of
460 Nothing -> tcInferPatSynDecl psb
461 Just (TcPatSynSig tpsi) -> tcCheckPatSynDecl psb tpsi
462 Just _ -> panic "tc_single"
463
464 tc_single top_lvl sig_fn prag_fn lbind thing_inside
465 = do { (binds1, ids) <- tcPolyBinds top_lvl sig_fn prag_fn
466 NonRecursive NonRecursive
467 [lbind]
468 ; thing <- tcExtendLetEnv top_lvl ids thing_inside
469 ; return (binds1, thing) }
470
471 ------------------------
472 type BKey = Int -- Just number off the bindings
473
474 mkEdges :: TcSigFun -> LHsBinds Name -> [Node BKey (LHsBind Name)]
475 -- See Note [Polymorphic recursion] in HsBinds.
476 mkEdges sig_fn binds
477 = [ (bind, key, [key | n <- nameSetElems (bind_fvs (unLoc bind)),
478 Just key <- [lookupNameEnv key_map n], no_sig n ])
479 | (bind, key) <- keyd_binds
480 ]
481 where
482 no_sig :: Name -> Bool
483 no_sig n = noCompleteSig (sig_fn n)
484
485 keyd_binds = bagToList binds `zip` [0::BKey ..]
486
487 key_map :: NameEnv BKey -- Which binding it comes from
488 key_map = mkNameEnv [(bndr, key) | (L _ bind, key) <- keyd_binds
489 , bndr <- collectHsBindBinders bind ]
490
491 ------------------------
492 tcPolyBinds :: TopLevelFlag -> TcSigFun -> TcPragEnv
493 -> RecFlag -- Whether the group is really recursive
494 -> RecFlag -- Whether it's recursive after breaking
495 -- dependencies based on type signatures
496 -> [LHsBind Name] -- None are PatSynBind
497 -> TcM (LHsBinds TcId, [TcId])
498
499 -- Typechecks a single bunch of values bindings all together,
500 -- and generalises them. The bunch may be only part of a recursive
501 -- group, because we use type signatures to maximise polymorphism
502 --
503 -- Returns a list because the input may be a single non-recursive binding,
504 -- in which case the dependency order of the resulting bindings is
505 -- important.
506 --
507 -- Knows nothing about the scope of the bindings
508 -- None of the bindings are pattern synonyms
509
510 tcPolyBinds top_lvl sig_fn prag_fn rec_group rec_tc bind_list
511 = setSrcSpan loc $
512 recoverM (recoveryCode binder_names sig_fn) $ do
513 -- Set up main recover; take advantage of any type sigs
514
515 { traceTc "------------------------------------------------" Outputable.empty
516 ; traceTc "Bindings for {" (ppr binder_names)
517 ; dflags <- getDynFlags
518 ; type_env <- getLclTypeEnv
519 ; let plan = decideGeneralisationPlan dflags type_env
520 binder_names bind_list sig_fn
521 ; traceTc "Generalisation plan" (ppr plan)
522 ; result@(tc_binds, poly_ids) <- case plan of
523 NoGen -> tcPolyNoGen rec_tc prag_fn sig_fn bind_list
524 InferGen mn -> tcPolyInfer rec_tc prag_fn sig_fn mn bind_list
525 CheckGen lbind sig -> tcPolyCheck rec_tc prag_fn sig lbind
526
527 -- Check whether strict bindings are ok
528 -- These must be non-recursive etc, and are not generalised
529 -- They desugar to a case expression in the end
530 ; checkStrictBinds top_lvl rec_group bind_list tc_binds poly_ids
531 ; traceTc "} End of bindings for" (vcat [ ppr binder_names, ppr rec_group
532 , vcat [ppr id <+> ppr (idType id) | id <- poly_ids]
533 ])
534
535 ; return result }
536 where
537 binder_names = collectHsBindListBinders bind_list
538 loc = foldr1 combineSrcSpans (map getLoc bind_list)
539 -- The mbinds have been dependency analysed and
540 -- may no longer be adjacent; so find the narrowest
541 -- span that includes them all
542
543 ------------------
544 tcPolyNoGen -- No generalisation whatsoever
545 :: RecFlag -- Whether it's recursive after breaking
546 -- dependencies based on type signatures
547 -> TcPragEnv -> TcSigFun
548 -> [LHsBind Name]
549 -> TcM (LHsBinds TcId, [TcId])
550
551 tcPolyNoGen rec_tc prag_fn tc_sig_fn bind_list
552 = do { (binds', mono_infos) <- tcMonoBinds rec_tc tc_sig_fn
553 (LetGblBndr prag_fn)
554 bind_list
555 ; mono_ids' <- mapM tc_mono_info mono_infos
556 ; return (binds', mono_ids') }
557 where
558 tc_mono_info (MBI { mbi_poly_name = name, mbi_mono_id = mono_id })
559 = do { mono_ty' <- zonkTcType (idType mono_id)
560 -- Zonk, mainly to expose unboxed types to checkStrictBinds
561 ; let mono_id' = setIdType mono_id mono_ty'
562 ; _specs <- tcSpecPrags mono_id' (lookupPragEnv prag_fn name)
563 ; return mono_id' }
564 -- NB: tcPrags generates error messages for
565 -- specialisation pragmas for non-overloaded sigs
566 -- Indeed that is why we call it here!
567 -- So we can safely ignore _specs
568
569 ------------------
570 tcPolyCheck :: RecFlag -- Whether it's recursive after breaking
571 -- dependencies based on type signatures
572 -> TcPragEnv
573 -> TcIdSigInfo
574 -> LHsBind Name
575 -> TcM (LHsBinds TcId, [TcId])
576 -- There is just one binding,
577 -- it binds a single variable,
578 -- it has a complete type signature,
579 tcPolyCheck rec_tc prag_fn
580 sig@(TISI { sig_bndr = CompleteSig poly_id
581 , sig_skols = skol_prs
582 , sig_theta = theta
583 , sig_tau = tau
584 , sig_ctxt = ctxt
585 , sig_loc = loc })
586 bind
587 = do { ev_vars <- newEvVars theta
588 ; let skol_info = SigSkol ctxt (mkPhiTy theta tau)
589 prag_sigs = lookupPragEnv prag_fn name
590 skol_tvs = map snd skol_prs
591 -- Find the location of the original source type sig, if
592 -- there is was one. This will appear in messages like
593 -- "type variable x is bound by .. at <loc>"
594 name = idName poly_id
595 ; (ev_binds, (binds', _))
596 <- setSrcSpan loc $
597 checkConstraints skol_info skol_tvs ev_vars $
598 tcMonoBinds rec_tc (\_ -> Just (TcIdSig sig)) LetLclBndr [bind]
599
600 ; spec_prags <- tcSpecPrags poly_id prag_sigs
601 ; poly_id <- addInlinePrags poly_id prag_sigs
602
603 ; let bind' = case bagToList binds' of
604 [b] -> b
605 _ -> pprPanic "tcPolyCheck" (ppr binds')
606 abs_bind = L loc $ AbsBindsSig
607 { abs_tvs = skol_tvs
608 , abs_ev_vars = ev_vars
609 , abs_sig_export = poly_id
610 , abs_sig_prags = SpecPrags spec_prags
611 , abs_sig_ev_bind = ev_binds
612 , abs_sig_bind = bind' }
613
614 ; return (unitBag abs_bind, [poly_id]) }
615
616 tcPolyCheck _rec_tc _prag_fn sig _bind
617 = pprPanic "tcPolyCheck" (ppr sig)
618
619 ------------------
620 tcPolyInfer
621 :: RecFlag -- Whether it's recursive after breaking
622 -- dependencies based on type signatures
623 -> TcPragEnv -> TcSigFun
624 -> Bool -- True <=> apply the monomorphism restriction
625 -> [LHsBind Name]
626 -> TcM (LHsBinds TcId, [TcId])
627 tcPolyInfer rec_tc prag_fn tc_sig_fn mono bind_list
628 = do { (tclvl, wanted, (binds', mono_infos))
629 <- pushLevelAndCaptureConstraints $
630 tcMonoBinds rec_tc tc_sig_fn LetLclBndr bind_list
631
632 ; let name_taus = [ (mbi_poly_name info, idType (mbi_mono_id info))
633 | info <- mono_infos ]
634 sigs = [ sig | MBI { mbi_sig = Just sig } <- mono_infos ]
635
636 ; traceTc "simplifyInfer call" (ppr tclvl $$ ppr name_taus $$ ppr wanted)
637 ; (qtvs, givens, ev_binds)
638 <- simplifyInfer tclvl mono sigs name_taus wanted
639
640 ; let inferred_theta = map evVarPred givens
641 ; exports <- checkNoErrs $
642 mapM (mkExport prag_fn qtvs inferred_theta) mono_infos
643
644 ; loc <- getSrcSpanM
645 ; let poly_ids = map abe_poly exports
646 abs_bind = L loc $
647 AbsBinds { abs_tvs = qtvs
648 , abs_ev_vars = givens, abs_ev_binds = [ev_binds]
649 , abs_exports = exports, abs_binds = binds' }
650
651 ; traceTc "Binding:" (ppr (poly_ids `zip` map idType poly_ids))
652 ; return (unitBag abs_bind, poly_ids) }
653 -- poly_ids are guaranteed zonked by mkExport
654
655 --------------
656 mkExport :: TcPragEnv
657 -> [TyVar] -> TcThetaType -- Both already zonked
658 -> MonoBindInfo
659 -> TcM (ABExport Id)
660 -- Only called for generalisation plan InferGen, not by CheckGen or NoGen
661 --
662 -- mkExport generates exports with
663 -- zonked type variables,
664 -- zonked poly_ids
665 -- The former is just because no further unifications will change
666 -- the quantified type variables, so we can fix their final form
667 -- right now.
668 -- The latter is needed because the poly_ids are used to extend the
669 -- type environment; see the invariant on TcEnv.tcExtendIdEnv
670
671 -- Pre-condition: the qtvs and theta are already zonked
672
673 mkExport prag_fn qtvs theta
674 mono_info@(MBI { mbi_poly_name = poly_name
675 , mbi_sig = mb_sig
676 , mbi_mono_id = mono_id })
677 = do { mono_ty <- zonkTcType (idType mono_id)
678 ; poly_id <- mkInferredPolyId qtvs theta poly_name mb_sig mono_ty
679
680 -- NB: poly_id has a zonked type
681 ; poly_id <- addInlinePrags poly_id prag_sigs
682 ; spec_prags <- tcSpecPrags poly_id prag_sigs
683 -- tcPrags requires a zonked poly_id
684
685 -- See Note [Impedence matching]
686 -- NB: we have already done checkValidType, including an ambiguity check,
687 -- on the type; either when we checked the sig or in mkInferredPolyId
688 ; let sel_poly_ty = mkInvSigmaTy qtvs theta mono_ty
689 -- this type is just going into tcSubType, so Inv vs. Spec doesn't
690 -- matter
691
692 poly_ty = idType poly_id
693 ; wrap <- if sel_poly_ty `eqType` poly_ty -- NB: eqType ignores visibility
694 then return idHsWrapper -- Fast path; also avoids complaint when we infer
695 -- an ambiguouse type and have AllowAmbiguousType
696 -- e..g infer x :: forall a. F a -> Int
697 else addErrCtxtM (mk_impedence_match_msg mono_info sel_poly_ty poly_ty) $
698 tcSubType_NC sig_ctxt sel_poly_ty (mkCheckExpType poly_ty)
699
700 ; warn_missing_sigs <- woptM Opt_WarnMissingLocalSignatures
701 ; when warn_missing_sigs $
702 localSigWarn Opt_WarnMissingLocalSignatures poly_id mb_sig
703
704 ; return (ABE { abe_wrap = wrap
705 -- abe_wrap :: idType poly_id ~ (forall qtvs. theta => mono_ty)
706 , abe_poly = poly_id
707 , abe_mono = mono_id
708 , abe_prags = SpecPrags spec_prags}) }
709 where
710 prag_sigs = lookupPragEnv prag_fn poly_name
711 sig_ctxt = InfSigCtxt poly_name
712
713 mkInferredPolyId :: [TyVar] -> TcThetaType
714 -> Name -> Maybe TcIdSigInfo -> TcType
715 -> TcM TcId
716 mkInferredPolyId qtvs inferred_theta poly_name mb_sig mono_ty
717 | Just sig <- mb_sig
718 , Just poly_id <- completeIdSigPolyId_maybe sig
719 = return poly_id
720
721 | otherwise -- Either no type sig or partial type sig
722 = checkNoErrs $ -- The checkNoErrs ensures that if the type is ambiguous
723 -- we don't carry on to the impedence matching, and generate
724 -- a duplicate ambiguity error. There is a similar
725 -- checkNoErrs for complete type signatures too.
726 do { fam_envs <- tcGetFamInstEnvs
727 ; let (_co, mono_ty') = normaliseType fam_envs Nominal mono_ty
728 -- Unification may not have normalised the type,
729 -- (see Note [Lazy flattening] in TcFlatten) so do it
730 -- here to make it as uncomplicated as possible.
731 -- Example: f :: [F Int] -> Bool
732 -- should be rewritten to f :: [Char] -> Bool, if possible
733 --
734 -- We can discard the coercion _co, because we'll reconstruct
735 -- it in the call to tcSubType below
736
737 ; (binders, theta') <- chooseInferredQuantifiers inferred_theta
738 (tyCoVarsOfType mono_ty') qtvs mb_sig
739
740 ; let inferred_poly_ty = mkForAllTys binders (mkPhiTy theta' mono_ty')
741
742 ; traceTc "mkInferredPolyId" (vcat [ppr poly_name, ppr qtvs, ppr theta'
743 , ppr inferred_poly_ty])
744 ; addErrCtxtM (mk_inf_msg poly_name inferred_poly_ty) $
745 checkValidType (InfSigCtxt poly_name) inferred_poly_ty
746 -- See Note [Validity of inferred types]
747
748 ; return (mkLocalIdOrCoVar poly_name inferred_poly_ty) }
749
750
751 chooseInferredQuantifiers :: TcThetaType -- inferred
752 -> TcTyVarSet -- tvs free in tau type
753 -> [TcTyVar] -- inferred quantified tvs
754 -> Maybe TcIdSigInfo
755 -> TcM ([TcTyBinder], TcThetaType)
756 chooseInferredQuantifiers inferred_theta tau_tvs qtvs Nothing
757 = -- No type signature for this binder
758 do { let free_tvs = closeOverKinds (growThetaTyVars inferred_theta tau_tvs)
759 -- Include kind variables! Trac #7916
760 my_theta = pickQuantifiablePreds free_tvs [] inferred_theta
761 binders = [ mkNamedBinder Invisible tv
762 | tv <- qtvs
763 , tv `elemVarSet` free_tvs ]
764 ; return (binders, my_theta) }
765
766 chooseInferredQuantifiers inferred_theta tau_tvs qtvs
767 (Just (TISI { sig_bndr = bndr_info -- Always PartialSig
768 , sig_ctxt = ctxt
769 , sig_theta = annotated_theta
770 , sig_skols = annotated_tvs }))
771 | PartialSig { sig_cts = extra } <- bndr_info
772 , Nothing <- extra
773 = do { annotated_theta <- zonkTcTypes annotated_theta
774 ; let free_tvs = closeOverKinds (tyCoVarsOfTypes annotated_theta
775 `unionVarSet` tau_tvs)
776 ; traceTc "ciq" (vcat [ ppr bndr_info, ppr annotated_theta, ppr free_tvs])
777 ; return (mk_binders free_tvs, annotated_theta) }
778
779 | PartialSig { sig_cts = extra } <- bndr_info
780 , Just loc <- extra
781 = do { annotated_theta <- zonkTcTypes annotated_theta
782 ; let free_tvs = closeOverKinds (tyCoVarsOfTypes annotated_theta
783 `unionVarSet` tau_tvs)
784 my_theta = pickQuantifiablePreds free_tvs annotated_theta inferred_theta
785
786 -- Report the inferred constraints for an extra-constraints wildcard/hole as
787 -- an error message, unless the PartialTypeSignatures flag is enabled. In this
788 -- case, the extra inferred constraints are accepted without complaining.
789 -- Returns the annotated constraints combined with the inferred constraints.
790 inferred_diff = [ pred
791 | pred <- my_theta
792 , all (not . (`eqType` pred)) annotated_theta ]
793 final_theta = annotated_theta ++ inferred_diff
794 ; partial_sigs <- xoptM LangExt.PartialTypeSignatures
795 ; warn_partial_sigs <- woptM Opt_WarnPartialTypeSignatures
796 ; msg <- mkLongErrAt loc (mk_msg inferred_diff partial_sigs) empty
797 ; traceTc "completeTheta" $
798 vcat [ ppr bndr_info
799 , ppr annotated_theta, ppr inferred_theta
800 , ppr inferred_diff ]
801 ; case partial_sigs of
802 True | warn_partial_sigs ->
803 reportWarning (Reason Opt_WarnPartialTypeSignatures) msg
804 | otherwise -> return ()
805 False -> reportError msg
806
807 ; return (mk_binders free_tvs, final_theta) }
808
809 | otherwise -- A complete type signature is dealt with in mkInferredPolyId
810 = pprPanic "chooseInferredQuantifiers" (ppr bndr_info)
811
812 where
813 pts_hint = text "To use the inferred type, enable PartialTypeSignatures"
814 mk_msg inferred_diff suppress_hint
815 = vcat [ hang ((text "Found constraint wildcard") <+> quotes (char '_'))
816 2 (text "standing for") <+> quotes (pprTheta inferred_diff)
817 , if suppress_hint then empty else pts_hint
818 , typeSigCtxt ctxt bndr_info ]
819
820 spec_tv_set = mkVarSet $ map snd annotated_tvs
821 mk_binders free_tvs
822 = [ mkNamedBinder vis tv
823 | tv <- qtvs
824 , tv `elemVarSet` free_tvs
825 , let vis | tv `elemVarSet` spec_tv_set = Specified
826 | otherwise = Invisible ]
827 -- Pulling from qtvs maintains original order
828
829 mk_impedence_match_msg :: MonoBindInfo
830 -> TcType -> TcType
831 -> TidyEnv -> TcM (TidyEnv, SDoc)
832 -- This is a rare but rather awkward error messages
833 mk_impedence_match_msg (MBI { mbi_poly_name = name, mbi_sig = mb_sig })
834 inf_ty sig_ty tidy_env
835 = do { (tidy_env1, inf_ty) <- zonkTidyTcType tidy_env inf_ty
836 ; (tidy_env2, sig_ty) <- zonkTidyTcType tidy_env1 sig_ty
837 ; let msg = vcat [ text "When checking that the inferred type"
838 , nest 2 $ ppr name <+> dcolon <+> ppr inf_ty
839 , text "is as general as its" <+> what <+> text "signature"
840 , nest 2 $ ppr name <+> dcolon <+> ppr sig_ty ]
841 ; return (tidy_env2, msg) }
842 where
843 what = case mb_sig of
844 Nothing -> text "inferred"
845 Just sig | isPartialSig sig -> text "(partial)"
846 | otherwise -> empty
847
848
849 mk_inf_msg :: Name -> TcType -> TidyEnv -> TcM (TidyEnv, SDoc)
850 mk_inf_msg poly_name poly_ty tidy_env
851 = do { (tidy_env1, poly_ty) <- zonkTidyTcType tidy_env poly_ty
852 ; let msg = vcat [ text "When checking the inferred type"
853 , nest 2 $ ppr poly_name <+> dcolon <+> ppr poly_ty ]
854 ; return (tidy_env1, msg) }
855
856
857 -- | Warn the user about polymorphic local binders that lack type signatures.
858 localSigWarn :: WarningFlag -> Id -> Maybe TcIdSigInfo -> TcM ()
859 localSigWarn flag id mb_sig
860 | Just _ <- mb_sig = return ()
861 | not (isSigmaTy (idType id)) = return ()
862 | otherwise = warnMissingSignatures flag msg id
863 where
864 msg = text "Polymorphic local binding with no type signature:"
865
866 warnMissingSignatures :: WarningFlag -> SDoc -> Id -> TcM ()
867 warnMissingSignatures flag msg id
868 = do { env0 <- tcInitTidyEnv
869 ; let (env1, tidy_ty) = tidyOpenType env0 (idType id)
870 ; addWarnTcM (Reason flag) (env1, mk_msg tidy_ty) }
871 where
872 mk_msg ty = sep [ msg, nest 2 $ pprPrefixName (idName id) <+> dcolon <+> ppr ty ]
873
874 {-
875 Note [Partial type signatures and generalisation]
876 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
877 When we have a partial type signature, like
878 f :: _ -> Int
879 then we *always* use the InferGen plan, and hence tcPolyInfer.
880 We do this even for a local binding with -XMonoLocalBinds.
881 Reasons:
882 * The TcSigInfo for 'f' has a unification variable for the '_',
883 whose TcLevel is one level deeper than the current level.
884 (See pushTcLevelM in tcTySig.) But NoGen doesn't increase
885 the TcLevel like InferGen, so we lose the level invariant.
886
887 * The signature might be f :: forall a. _ -> a
888 so it really is polymorphic. It's not clear what it would
889 mean to use NoGen on this, and indeed the ASSERT in tcLhs,
890 in the (Just sig) case, checks that if there is a signature
891 then we are using LetLclBndr, and hence a nested AbsBinds with
892 increased TcLevel
893
894 It might be possible to fix these difficulties somehow, but there
895 doesn't seem much point. Indeed, adding a partial type signature is a
896 way to get per-binding inferred generalisation.
897
898 Note [Validity of inferred types]
899 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
900 We need to check inferred type for validity, in case it uses language
901 extensions that are not turned on. The principle is that if the user
902 simply adds the inferred type to the program source, it'll compile fine.
903 See #8883.
904
905 Examples that might fail:
906 - the type might be ambiguous
907
908 - an inferred theta that requires type equalities e.g. (F a ~ G b)
909 or multi-parameter type classes
910 - an inferred type that includes unboxed tuples
911
912
913 Note [Impedence matching]
914 ~~~~~~~~~~~~~~~~~~~~~~~~~
915 Consider
916 f 0 x = x
917 f n x = g [] (not x)
918
919 g [] y = f 10 y
920 g _ y = f 9 y
921
922 After typechecking we'll get
923 f_mono_ty :: a -> Bool -> Bool
924 g_mono_ty :: [b] -> Bool -> Bool
925 with constraints
926 (Eq a, Num a)
927
928 Note that f is polymorphic in 'a' and g in 'b'; and these are not linked.
929 The types we really want for f and g are
930 f :: forall a. (Eq a, Num a) => a -> Bool -> Bool
931 g :: forall b. [b] -> Bool -> Bool
932
933 We can get these by "impedance matching":
934 tuple :: forall a b. (Eq a, Num a) => (a -> Bool -> Bool, [b] -> Bool -> Bool)
935 tuple a b d1 d1 = let ...bind f_mono, g_mono in (f_mono, g_mono)
936
937 f a d1 d2 = case tuple a Any d1 d2 of (f, g) -> f
938 g b = case tuple Integer b dEqInteger dNumInteger of (f,g) -> g
939
940 Suppose the shared quantified tyvars are qtvs and constraints theta.
941 Then we want to check that
942 forall qtvs. theta => f_mono_ty is more polymorphic than f's polytype
943 and the proof is the impedance matcher.
944
945 Notice that the impedance matcher may do defaulting. See Trac #7173.
946
947 It also cleverly does an ambiguity check; for example, rejecting
948 f :: F a -> F a
949 where F is a non-injective type function.
950 -}
951
952 --------------
953 -- If typechecking the binds fails, then return with each
954 -- signature-less binder given type (forall a.a), to minimise
955 -- subsequent error messages
956 recoveryCode :: [Name] -> TcSigFun -> TcM (LHsBinds TcId, [Id])
957 recoveryCode binder_names sig_fn
958 = do { traceTc "tcBindsWithSigs: error recovery" (ppr binder_names)
959 ; let poly_ids = map mk_dummy binder_names
960 ; return (emptyBag, poly_ids) }
961 where
962 mk_dummy name
963 | Just sig <- sig_fn name
964 , Just poly_id <- completeSigPolyId_maybe sig
965 = poly_id
966 | otherwise
967 = mkLocalId name forall_a_a
968
969 forall_a_a :: TcType
970 forall_a_a = mkSpecForAllTys [runtimeRep1TyVar, openAlphaTyVar] openAlphaTy
971
972 {- *********************************************************************
973 * *
974 Pragmas, including SPECIALISE
975 * *
976 ************************************************************************
977
978 Note [Handling SPECIALISE pragmas]
979 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
980 The basic idea is this:
981
982 foo :: Num a => a -> b -> a
983 {-# SPECIALISE foo :: Int -> b -> Int #-}
984
985 We check that
986 (forall a b. Num a => a -> b -> a)
987 is more polymorphic than
988 forall b. Int -> b -> Int
989 (for which we could use tcSubType, but see below), generating a HsWrapper
990 to connect the two, something like
991 wrap = /\b. <hole> Int b dNumInt
992 This wrapper is put in the TcSpecPrag, in the ABExport record of
993 the AbsBinds.
994
995
996 f :: (Eq a, Ix b) => a -> b -> Bool
997 {-# SPECIALISE f :: (Ix p, Ix q) => Int -> (p,q) -> Bool #-}
998 f = <poly_rhs>
999
1000 From this the typechecker generates
1001
1002 AbsBinds [ab] [d1,d2] [([ab], f, f_mono, prags)] binds
1003
1004 SpecPrag (wrap_fn :: forall a b. (Eq a, Ix b) => XXX
1005 -> forall p q. (Ix p, Ix q) => XXX[ Int/a, (p,q)/b ])
1006
1007 From these we generate:
1008
1009 Rule: forall p, q, (dp:Ix p), (dq:Ix q).
1010 f Int (p,q) dInt ($dfInPair dp dq) = f_spec p q dp dq
1011
1012 Spec bind: f_spec = wrap_fn <poly_rhs>
1013
1014 Note that
1015
1016 * The LHS of the rule may mention dictionary *expressions* (eg
1017 $dfIxPair dp dq), and that is essential because the dp, dq are
1018 needed on the RHS.
1019
1020 * The RHS of f_spec, <poly_rhs> has a *copy* of 'binds', so that it
1021 can fully specialise it.
1022
1023
1024
1025 From the TcSpecPrag, in DsBinds we generate a binding for f_spec and a RULE:
1026
1027 f_spec :: Int -> b -> Int
1028 f_spec = wrap<f rhs>
1029
1030 RULE: forall b (d:Num b). f b d = f_spec b
1031
1032 The RULE is generated by taking apart the HsWrapper, which is a little
1033 delicate, but works.
1034
1035 Some wrinkles
1036
1037 1. We don't use full-on tcSubType, because that does co and contra
1038 variance and that in turn will generate too complex a LHS for the
1039 RULE. So we use a single invocation of skolemise /
1040 topInstantiate in tcSpecWrapper. (Actually I think that even
1041 the "deeply" stuff may be too much, because it introduces lambdas,
1042 though I think it can be made to work without too much trouble.)
1043
1044 2. We need to take care with type families (Trac #5821). Consider
1045 type instance F Int = Bool
1046 f :: Num a => a -> F a
1047 {-# SPECIALISE foo :: Int -> Bool #-}
1048
1049 We *could* try to generate an f_spec with precisely the declared type:
1050 f_spec :: Int -> Bool
1051 f_spec = <f rhs> Int dNumInt |> co
1052
1053 RULE: forall d. f Int d = f_spec |> sym co
1054
1055 but the 'co' and 'sym co' are (a) playing no useful role, and (b) are
1056 hard to generate. At all costs we must avoid this:
1057 RULE: forall d. f Int d |> co = f_spec
1058 because the LHS will never match (indeed it's rejected in
1059 decomposeRuleLhs).
1060
1061 So we simply do this:
1062 - Generate a constraint to check that the specialised type (after
1063 skolemiseation) is equal to the instantiated function type.
1064 - But *discard* the evidence (coercion) for that constraint,
1065 so that we ultimately generate the simpler code
1066 f_spec :: Int -> F Int
1067 f_spec = <f rhs> Int dNumInt
1068
1069 RULE: forall d. f Int d = f_spec
1070 You can see this discarding happening in
1071
1072 3. Note that the HsWrapper can transform *any* function with the right
1073 type prefix
1074 forall ab. (Eq a, Ix b) => XXX
1075 regardless of XXX. It's sort of polymorphic in XXX. This is
1076 useful: we use the same wrapper to transform each of the class ops, as
1077 well as the dict. That's what goes on in TcInstDcls.mk_meth_spec_prags
1078 -}
1079
1080 mkPragEnv :: [LSig Name] -> LHsBinds Name -> TcPragEnv
1081 mkPragEnv sigs binds
1082 = foldl extendPragEnv emptyNameEnv prs
1083 where
1084 prs = mapMaybe get_sig sigs
1085
1086 get_sig :: LSig Name -> Maybe (Name, LSig Name)
1087 get_sig (L l (SpecSig lnm@(L _ nm) ty inl)) = Just (nm, L l $ SpecSig lnm ty (add_arity nm inl))
1088 get_sig (L l (InlineSig lnm@(L _ nm) inl)) = Just (nm, L l $ InlineSig lnm (add_arity nm inl))
1089 get_sig _ = Nothing
1090
1091 add_arity n inl_prag -- Adjust inl_sat field to match visible arity of function
1092 | Inline <- inl_inline inl_prag
1093 -- add arity only for real INLINE pragmas, not INLINABLE
1094 = case lookupNameEnv ar_env n of
1095 Just ar -> inl_prag { inl_sat = Just ar }
1096 Nothing -> WARN( True, text "mkPragEnv no arity" <+> ppr n )
1097 -- There really should be a binding for every INLINE pragma
1098 inl_prag
1099 | otherwise
1100 = inl_prag
1101
1102 -- ar_env maps a local to the arity of its definition
1103 ar_env :: NameEnv Arity
1104 ar_env = foldrBag lhsBindArity emptyNameEnv binds
1105
1106 extendPragEnv :: TcPragEnv -> (Name, LSig Name) -> TcPragEnv
1107 extendPragEnv prag_fn (n, sig) = extendNameEnv_Acc (:) singleton prag_fn n sig
1108
1109 lhsBindArity :: LHsBind Name -> NameEnv Arity -> NameEnv Arity
1110 lhsBindArity (L _ (FunBind { fun_id = id, fun_matches = ms })) env
1111 = extendNameEnv env (unLoc id) (matchGroupArity ms)
1112 lhsBindArity _ env = env -- PatBind/VarBind
1113
1114 ------------------
1115 tcSpecPrags :: Id -> [LSig Name]
1116 -> TcM [LTcSpecPrag]
1117 -- Add INLINE and SPECIALSE pragmas
1118 -- INLINE prags are added to the (polymorphic) Id directly
1119 -- SPECIALISE prags are passed to the desugarer via TcSpecPrags
1120 -- Pre-condition: the poly_id is zonked
1121 -- Reason: required by tcSubExp
1122 tcSpecPrags poly_id prag_sigs
1123 = do { traceTc "tcSpecPrags" (ppr poly_id <+> ppr spec_sigs)
1124 ; unless (null bad_sigs) warn_discarded_sigs
1125 ; pss <- mapAndRecoverM (wrapLocM (tcSpecPrag poly_id)) spec_sigs
1126 ; return $ concatMap (\(L l ps) -> map (L l) ps) pss }
1127 where
1128 spec_sigs = filter isSpecLSig prag_sigs
1129 bad_sigs = filter is_bad_sig prag_sigs
1130 is_bad_sig s = not (isSpecLSig s || isInlineLSig s)
1131
1132 warn_discarded_sigs
1133 = addWarnTc NoReason
1134 (hang (text "Discarding unexpected pragmas for" <+> ppr poly_id)
1135 2 (vcat (map (ppr . getLoc) bad_sigs)))
1136
1137 --------------
1138 tcSpecPrag :: TcId -> Sig Name -> TcM [TcSpecPrag]
1139 tcSpecPrag poly_id prag@(SpecSig fun_name hs_tys inl)
1140 -- See Note [Handling SPECIALISE pragmas]
1141 --
1142 -- The Name fun_name in the SpecSig may not be the same as that of the poly_id
1143 -- Example: SPECIALISE for a class method: the Name in the SpecSig is
1144 -- for the selector Id, but the poly_id is something like $cop
1145 -- However we want to use fun_name in the error message, since that is
1146 -- what the user wrote (Trac #8537)
1147 = addErrCtxt (spec_ctxt prag) $
1148 do { warnIf NoReason (not (isOverloadedTy poly_ty || isInlinePragma inl))
1149 (text "SPECIALISE pragma for non-overloaded function"
1150 <+> quotes (ppr fun_name))
1151 -- Note [SPECIALISE pragmas]
1152 ; spec_prags <- mapM tc_one hs_tys
1153 ; traceTc "tcSpecPrag" (ppr poly_id $$ nest 2 (vcat (map ppr spec_prags)))
1154 ; return spec_prags }
1155 where
1156 name = idName poly_id
1157 poly_ty = idType poly_id
1158 spec_ctxt prag = hang (text "In the SPECIALISE pragma") 2 (ppr prag)
1159
1160 tc_one hs_ty
1161 = do { spec_ty <- tcHsSigType (FunSigCtxt name False) hs_ty
1162 ; wrap <- tcSpecWrapper (FunSigCtxt name True) poly_ty spec_ty
1163 ; return (SpecPrag poly_id wrap inl) }
1164
1165 tcSpecPrag _ prag = pprPanic "tcSpecPrag" (ppr prag)
1166
1167 --------------
1168 tcSpecWrapper :: UserTypeCtxt -> TcType -> TcType -> TcM HsWrapper
1169 -- A simpler variant of tcSubType, used for SPECIALISE pragmas
1170 -- See Note [Handling SPECIALISE pragmas], wrinkle 1
1171 tcSpecWrapper ctxt poly_ty spec_ty
1172 = do { (sk_wrap, inst_wrap)
1173 <- tcSkolemise ctxt spec_ty $ \ _ spec_tau ->
1174 do { (inst_wrap, tau) <- topInstantiate orig poly_ty
1175 ; _ <- unifyType noThing spec_tau tau
1176 -- Deliberately ignore the evidence
1177 -- See Note [Handling SPECIALISE pragmas],
1178 -- wrinkle (2)
1179 ; return inst_wrap }
1180 ; return (sk_wrap <.> inst_wrap) }
1181 where
1182 orig = SpecPragOrigin ctxt
1183
1184 --------------
1185 tcImpPrags :: [LSig Name] -> TcM [LTcSpecPrag]
1186 -- SPECIALISE pragmas for imported things
1187 tcImpPrags prags
1188 = do { this_mod <- getModule
1189 ; dflags <- getDynFlags
1190 ; if (not_specialising dflags) then
1191 return []
1192 else do
1193 { pss <- mapAndRecoverM (wrapLocM tcImpSpec)
1194 [L loc (name,prag)
1195 | (L loc prag@(SpecSig (L _ name) _ _)) <- prags
1196 , not (nameIsLocalOrFrom this_mod name) ]
1197 ; return $ concatMap (\(L l ps) -> map (L l) ps) pss } }
1198 where
1199 -- Ignore SPECIALISE pragmas for imported things
1200 -- when we aren't specialising, or when we aren't generating
1201 -- code. The latter happens when Haddocking the base library;
1202 -- we don't wnat complaints about lack of INLINABLE pragmas
1203 not_specialising dflags
1204 | not (gopt Opt_Specialise dflags) = True
1205 | otherwise = case hscTarget dflags of
1206 HscNothing -> True
1207 HscInterpreted -> True
1208 _other -> False
1209
1210 tcImpSpec :: (Name, Sig Name) -> TcM [TcSpecPrag]
1211 tcImpSpec (name, prag)
1212 = do { id <- tcLookupId name
1213 ; unless (isAnyInlinePragma (idInlinePragma id))
1214 (addWarnTc NoReason (impSpecErr name))
1215 ; tcSpecPrag id prag }
1216
1217 impSpecErr :: Name -> SDoc
1218 impSpecErr name
1219 = hang (text "You cannot SPECIALISE" <+> quotes (ppr name))
1220 2 (vcat [ text "because its definition has no INLINE/INLINABLE pragma"
1221 , parens $ sep
1222 [ text "or its defining module" <+> quotes (ppr mod)
1223 , text "was compiled without -O"]])
1224 where
1225 mod = nameModule name
1226
1227
1228 {- *********************************************************************
1229 * *
1230 Vectorisation
1231 * *
1232 ********************************************************************* -}
1233
1234 tcVectDecls :: [LVectDecl Name] -> TcM ([LVectDecl TcId])
1235 tcVectDecls decls
1236 = do { decls' <- mapM (wrapLocM tcVect) decls
1237 ; let ids = [lvectDeclName decl | decl <- decls', not $ lvectInstDecl decl]
1238 dups = findDupsEq (==) ids
1239 ; mapM_ reportVectDups dups
1240 ; traceTcConstraints "End of tcVectDecls"
1241 ; return decls'
1242 }
1243 where
1244 reportVectDups (first:_second:_more)
1245 = addErrAt (getSrcSpan first) $
1246 text "Duplicate vectorisation declarations for" <+> ppr first
1247 reportVectDups _ = return ()
1248
1249 --------------
1250 tcVect :: VectDecl Name -> TcM (VectDecl TcId)
1251 -- FIXME: We can't typecheck the expression of a vectorisation declaration against the vectorised
1252 -- type of the original definition as this requires internals of the vectoriser not available
1253 -- during type checking. Instead, constrain the rhs of a vectorisation declaration to be a single
1254 -- identifier (this is checked in 'rnHsVectDecl'). Fix this by enabling the use of 'vectType'
1255 -- from the vectoriser here.
1256 tcVect (HsVect s name rhs)
1257 = addErrCtxt (vectCtxt name) $
1258 do { var <- wrapLocM tcLookupId name
1259 ; let L rhs_loc (HsVar (L lv rhs_var_name)) = rhs
1260 ; rhs_id <- tcLookupId rhs_var_name
1261 ; return $ HsVect s var (L rhs_loc (HsVar (L lv rhs_id)))
1262 }
1263
1264 {- OLD CODE:
1265 -- turn the vectorisation declaration into a single non-recursive binding
1266 ; let bind = L loc $ mkTopFunBind name [mkSimpleMatch [] rhs]
1267 sigFun = const Nothing
1268 pragFun = emptyPragEnv
1269
1270 -- perform type inference (including generalisation)
1271 ; (binds, [id'], _) <- tcPolyInfer False True sigFun pragFun NonRecursive [bind]
1272
1273 ; traceTc "tcVect inferred type" $ ppr (varType id')
1274 ; traceTc "tcVect bindings" $ ppr binds
1275
1276 -- add all bindings, including the type variable and dictionary bindings produced by type
1277 -- generalisation to the right-hand side of the vectorisation declaration
1278 ; let [AbsBinds tvs evs _ evBinds actualBinds] = (map unLoc . bagToList) binds
1279 ; let [bind'] = bagToList actualBinds
1280 MatchGroup
1281 [L _ (Match _ _ (GRHSs [L _ (GRHS _ rhs')] _))]
1282 _ = (fun_matches . unLoc) bind'
1283 rhsWrapped = mkHsLams tvs evs (mkHsDictLet evBinds rhs')
1284
1285 -- We return the type-checked 'Id', to propagate the inferred signature
1286 -- to the vectoriser - see "Note [Typechecked vectorisation pragmas]" in HsDecls
1287 ; return $ HsVect (L loc id') (Just rhsWrapped)
1288 }
1289 -}
1290 tcVect (HsNoVect s name)
1291 = addErrCtxt (vectCtxt name) $
1292 do { var <- wrapLocM tcLookupId name
1293 ; return $ HsNoVect s var
1294 }
1295 tcVect (HsVectTypeIn _ isScalar lname rhs_name)
1296 = addErrCtxt (vectCtxt lname) $
1297 do { tycon <- tcLookupLocatedTyCon lname
1298 ; checkTc ( not isScalar -- either we have a non-SCALAR declaration
1299 || isJust rhs_name -- or we explicitly provide a vectorised type
1300 || tyConArity tycon == 0 -- otherwise the type constructor must be nullary
1301 )
1302 scalarTyConMustBeNullary
1303
1304 ; rhs_tycon <- fmapMaybeM (tcLookupTyCon . unLoc) rhs_name
1305 ; return $ HsVectTypeOut isScalar tycon rhs_tycon
1306 }
1307 tcVect (HsVectTypeOut _ _ _)
1308 = panic "TcBinds.tcVect: Unexpected 'HsVectTypeOut'"
1309 tcVect (HsVectClassIn _ lname)
1310 = addErrCtxt (vectCtxt lname) $
1311 do { cls <- tcLookupLocatedClass lname
1312 ; return $ HsVectClassOut cls
1313 }
1314 tcVect (HsVectClassOut _)
1315 = panic "TcBinds.tcVect: Unexpected 'HsVectClassOut'"
1316 tcVect (HsVectInstIn linstTy)
1317 = addErrCtxt (vectCtxt linstTy) $
1318 do { (cls, tys) <- tcHsVectInst linstTy
1319 ; inst <- tcLookupInstance cls tys
1320 ; return $ HsVectInstOut inst
1321 }
1322 tcVect (HsVectInstOut _)
1323 = panic "TcBinds.tcVect: Unexpected 'HsVectInstOut'"
1324
1325 vectCtxt :: Outputable thing => thing -> SDoc
1326 vectCtxt thing = text "When checking the vectorisation declaration for" <+> ppr thing
1327
1328 scalarTyConMustBeNullary :: MsgDoc
1329 scalarTyConMustBeNullary = text "VECTORISE SCALAR type constructor must be nullary"
1330
1331 {-
1332 Note [SPECIALISE pragmas]
1333 ~~~~~~~~~~~~~~~~~~~~~~~~~
1334 There is no point in a SPECIALISE pragma for a non-overloaded function:
1335 reverse :: [a] -> [a]
1336 {-# SPECIALISE reverse :: [Int] -> [Int] #-}
1337
1338 But SPECIALISE INLINE *can* make sense for GADTS:
1339 data Arr e where
1340 ArrInt :: !Int -> ByteArray# -> Arr Int
1341 ArrPair :: !Int -> Arr e1 -> Arr e2 -> Arr (e1, e2)
1342
1343 (!:) :: Arr e -> Int -> e
1344 {-# SPECIALISE INLINE (!:) :: Arr Int -> Int -> Int #-}
1345 {-# SPECIALISE INLINE (!:) :: Arr (a, b) -> Int -> (a, b) #-}
1346 (ArrInt _ ba) !: (I# i) = I# (indexIntArray# ba i)
1347 (ArrPair _ a1 a2) !: i = (a1 !: i, a2 !: i)
1348
1349 When (!:) is specialised it becomes non-recursive, and can usefully
1350 be inlined. Scary! So we only warn for SPECIALISE *without* INLINE
1351 for a non-overloaded function.
1352
1353 ************************************************************************
1354 * *
1355 tcMonoBinds
1356 * *
1357 ************************************************************************
1358
1359 @tcMonoBinds@ deals with a perhaps-recursive group of HsBinds.
1360 The signatures have been dealt with already.
1361
1362 Note [Pattern bindings]
1363 ~~~~~~~~~~~~~~~~~~~~~~~
1364 The rule for typing pattern bindings is this:
1365
1366 ..sigs..
1367 p = e
1368
1369 where 'p' binds v1..vn, and 'e' may mention v1..vn,
1370 typechecks exactly like
1371
1372 ..sigs..
1373 x = e -- Inferred type
1374 v1 = case x of p -> v1
1375 ..
1376 vn = case x of p -> vn
1377
1378 Note that
1379 (f :: forall a. a -> a) = id
1380 should not typecheck because
1381 case id of { (f :: forall a. a->a) -> f }
1382 will not typecheck.
1383
1384 Note [Instantiate when inferring a type]
1385 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1386 Consider
1387 f = (*)
1388 As there is no incentive to instantiate the RHS, tcMonoBinds will
1389 produce a type of forall a. Num a => a -> a -> a for `f`. This will then go
1390 through simplifyInfer and such, remaining unchanged.
1391
1392 There are two problems with this:
1393 1) If the definition were `g _ = (*)`, we get a very unusual type of
1394 `forall {a}. a -> forall b. Num b => b -> b -> b` for `g`. This is
1395 surely confusing for users.
1396
1397 2) The monomorphism restriction can't work. The MR is dealt with in
1398 simplifyInfer, and simplifyInfer has no way of instantiating. This
1399 could perhaps be worked around, but it may be hard to know even
1400 when instantiation should happen.
1401
1402 There is an easy solution to both problems: instantiate (deeply) when
1403 inferring a type. So that's what we do. Note that this decision is
1404 user-facing.
1405
1406 We do this deep instantiation in tcMonoBinds, in the FunBind case
1407 only, and only when we do not have a type signature. Conveniently,
1408 the fun_co_fn field of FunBind gives a place to record the coercion.
1409
1410 We do not need to do this
1411 * for PatBinds, because we don't have a function type
1412 * for FunBinds where we have a signature, bucause we aren't doing inference
1413 -}
1414
1415 tcMonoBinds :: RecFlag -- Whether the binding is recursive for typechecking purposes
1416 -- i.e. the binders are mentioned in their RHSs, and
1417 -- we are not rescued by a type signature
1418 -> TcSigFun -> LetBndrSpec
1419 -> [LHsBind Name]
1420 -> TcM (LHsBinds TcId, [MonoBindInfo])
1421 tcMonoBinds is_rec sig_fn no_gen
1422 [ L b_loc (FunBind { fun_id = L nm_loc name,
1423 fun_matches = matches, bind_fvs = fvs })]
1424 -- Single function binding,
1425 | NonRecursive <- is_rec -- ...binder isn't mentioned in RHS
1426 , Nothing <- sig_fn name -- ...with no type signature
1427 = -- In this very special case we infer the type of the
1428 -- right hand side first (it may have a higher-rank type)
1429 -- and *then* make the monomorphic Id for the LHS
1430 -- e.g. f = \(x::forall a. a->a) -> <body>
1431 -- We want to infer a higher-rank type for f
1432 setSrcSpan b_loc $
1433 do { rhs_ty <- newOpenInferExpType
1434 ; (co_fn, matches')
1435 <- tcExtendIdBndrs [TcIdBndr_ExpType name rhs_ty NotTopLevel] $
1436 -- We extend the error context even for a non-recursive
1437 -- function so that in type error messages we show the
1438 -- type of the thing whose rhs we are type checking
1439 tcMatchesFun name matches rhs_ty
1440 ; rhs_ty <- readExpType rhs_ty
1441
1442 -- Deeply instantiate the inferred type
1443 -- See Note [Instantiate when inferring a type]
1444 ; let orig = matchesCtOrigin matches
1445 ; rhs_ty <- zonkTcType rhs_ty -- NB: zonk to uncover any foralls
1446 ; (inst_wrap, rhs_ty) <- addErrCtxtM (instErrCtxt name rhs_ty) $
1447 deeplyInstantiate orig rhs_ty
1448
1449 ; mono_id <- newNoSigLetBndr no_gen name rhs_ty
1450 ; return (unitBag $ L b_loc $
1451 FunBind { fun_id = L nm_loc mono_id,
1452 fun_matches = matches', bind_fvs = fvs,
1453 fun_co_fn = inst_wrap <.> co_fn, fun_tick = [] },
1454 [MBI { mbi_poly_name = name
1455 , mbi_sig = Nothing
1456 , mbi_mono_id = mono_id }]) }
1457
1458 tcMonoBinds _ sig_fn no_gen binds
1459 = do { tc_binds <- mapM (wrapLocM (tcLhs sig_fn no_gen)) binds
1460
1461 -- Bring the monomorphic Ids, into scope for the RHSs
1462 ; let mono_infos = getMonoBindInfo tc_binds
1463 rhs_id_env = [(name, mono_id) | MBI { mbi_poly_name = name
1464 , mbi_sig = mb_sig
1465 , mbi_mono_id = mono_id }
1466 <- mono_infos
1467 , case mb_sig of
1468 Just sig -> isPartialSig sig
1469 Nothing -> True ]
1470 -- A monomorphic binding for each term variable that lacks
1471 -- a type sig. (Ones with a sig are already in scope.)
1472
1473 ; traceTc "tcMonoBinds" $ vcat [ ppr n <+> ppr id <+> ppr (idType id)
1474 | (n,id) <- rhs_id_env]
1475 ; binds' <- tcExtendLetEnvIds NotTopLevel rhs_id_env $
1476 mapM (wrapLocM tcRhs) tc_binds
1477 ; return (listToBag binds', mono_infos) }
1478
1479 ------------------------
1480 -- tcLhs typechecks the LHS of the bindings, to construct the environment in which
1481 -- we typecheck the RHSs. Basically what we are doing is this: for each binder:
1482 -- if there's a signature for it, use the instantiated signature type
1483 -- otherwise invent a type variable
1484 -- You see that quite directly in the FunBind case.
1485 --
1486 -- But there's a complication for pattern bindings:
1487 -- data T = MkT (forall a. a->a)
1488 -- MkT f = e
1489 -- Here we can guess a type variable for the entire LHS (which will be refined to T)
1490 -- but we want to get (f::forall a. a->a) as the RHS environment.
1491 -- The simplest way to do this is to typecheck the pattern, and then look up the
1492 -- bound mono-ids. Then we want to retain the typechecked pattern to avoid re-doing
1493 -- it; hence the TcMonoBind data type in which the LHS is done but the RHS isn't
1494
1495 data TcMonoBind -- Half completed; LHS done, RHS not done
1496 = TcFunBind MonoBindInfo SrcSpan (MatchGroup Name (LHsExpr Name))
1497 | TcPatBind [MonoBindInfo] (LPat TcId) (GRHSs Name (LHsExpr Name)) TcSigmaType
1498
1499 data MonoBindInfo = MBI { mbi_poly_name :: Name
1500 , mbi_sig :: Maybe TcIdSigInfo
1501 , mbi_mono_id :: TcId }
1502
1503 tcLhs :: TcSigFun -> LetBndrSpec -> HsBind Name -> TcM TcMonoBind
1504 tcLhs sig_fn no_gen (FunBind { fun_id = L nm_loc name, fun_matches = matches })
1505 | Just (TcIdSig sig) <- sig_fn name
1506 , TISI { sig_tau = tau } <- sig
1507 = ASSERT2( case no_gen of { LetLclBndr -> True; LetGblBndr {} -> False }
1508 , ppr name )
1509 -- { f :: ty; f x = e } is always done via CheckGen (full signature)
1510 -- or InferGen (partial signature)
1511 -- see Note [Partial type signatures and generalisation]
1512 -- Both InferGen and CheckGen gives rise to LetLclBndr
1513 do { mono_name <- newLocalName name
1514 ; let mono_id = mkLocalIdOrCoVar mono_name tau
1515 ; return (TcFunBind (MBI { mbi_poly_name = name
1516 , mbi_sig = Just sig
1517 , mbi_mono_id = mono_id })
1518 nm_loc matches) }
1519
1520 | otherwise
1521 = do { mono_ty <- newOpenFlexiTyVarTy
1522 ; mono_id <- newNoSigLetBndr no_gen name mono_ty
1523 ; return (TcFunBind (MBI { mbi_poly_name = name
1524 , mbi_sig = Nothing
1525 , mbi_mono_id = mono_id })
1526 nm_loc matches) }
1527
1528 tcLhs sig_fn no_gen (PatBind { pat_lhs = pat, pat_rhs = grhss })
1529 = do { let tc_pat exp_ty = tcLetPat sig_fn no_gen pat exp_ty $
1530 mapM lookup_info (collectPatBinders pat)
1531
1532 -- After typechecking the pattern, look up the binder
1533 -- names, which the pattern has brought into scope.
1534 lookup_info :: Name -> TcM MonoBindInfo
1535 lookup_info name
1536 = do { mono_id <- tcLookupId name
1537 ; let mb_sig = case sig_fn name of
1538 Just (TcIdSig sig) -> Just sig
1539 _ -> Nothing
1540 ; return (MBI { mbi_poly_name = name
1541 , mbi_sig = mb_sig
1542 , mbi_mono_id = mono_id }) }
1543
1544 ; ((pat', infos), pat_ty) <- addErrCtxt (patMonoBindsCtxt pat grhss) $
1545 tcInfer tc_pat
1546
1547 ; return (TcPatBind infos pat' grhss pat_ty) }
1548
1549 tcLhs _ _ other_bind = pprPanic "tcLhs" (ppr other_bind)
1550 -- AbsBind, VarBind impossible
1551
1552 -------------------
1553 tcRhs :: TcMonoBind -> TcM (HsBind TcId)
1554 tcRhs (TcFunBind info@(MBI { mbi_sig = mb_sig, mbi_mono_id = mono_id })
1555 loc matches)
1556 = tcExtendIdBinderStackForRhs [info] $
1557 tcExtendTyVarEnvForRhs mb_sig $
1558 do { traceTc "tcRhs: fun bind" (ppr mono_id $$ ppr (idType mono_id))
1559 ; (co_fn, matches') <- tcMatchesFun (idName mono_id)
1560 matches (mkCheckExpType $ idType mono_id)
1561 ; return ( FunBind { fun_id = L loc mono_id
1562 , fun_matches = matches'
1563 , fun_co_fn = co_fn
1564 , bind_fvs = placeHolderNamesTc
1565 , fun_tick = [] } ) }
1566
1567 -- TODO: emit Hole Constraints for wildcards
1568 tcRhs (TcPatBind infos pat' grhss pat_ty)
1569 = -- When we are doing pattern bindings we *don't* bring any scoped
1570 -- type variables into scope unlike function bindings
1571 -- Wny not? They are not completely rigid.
1572 -- That's why we have the special case for a single FunBind in tcMonoBinds
1573 tcExtendIdBinderStackForRhs infos $
1574 do { traceTc "tcRhs: pat bind" (ppr pat' $$ ppr pat_ty)
1575 ; grhss' <- addErrCtxt (patMonoBindsCtxt pat' grhss) $
1576 tcGRHSsPat grhss pat_ty
1577 ; return ( PatBind { pat_lhs = pat', pat_rhs = grhss'
1578 , pat_rhs_ty = pat_ty
1579 , bind_fvs = placeHolderNamesTc
1580 , pat_ticks = ([],[]) } )}
1581
1582 tcExtendTyVarEnvForRhs :: Maybe TcIdSigInfo -> TcM a -> TcM a
1583 tcExtendTyVarEnvForRhs Nothing thing_inside
1584 = thing_inside
1585 tcExtendTyVarEnvForRhs (Just sig) thing_inside
1586 = tcExtendTyVarEnvFromSig sig thing_inside
1587
1588 tcExtendTyVarEnvFromSig :: TcIdSigInfo -> TcM a -> TcM a
1589 tcExtendTyVarEnvFromSig sig thing_inside
1590 | TISI { sig_bndr = s_bndr, sig_skols = skol_prs, sig_ctxt = ctxt } <- sig
1591 = tcExtendTyVarEnv2 skol_prs $
1592 case s_bndr of
1593 CompleteSig {} -> thing_inside
1594 PartialSig { sig_wcs = wc_prs } -- Extend the env ad emit the holes
1595 -> tcExtendTyVarEnv2 wc_prs $
1596 do { addErrCtxt (typeSigCtxt ctxt s_bndr) $
1597 emitWildCardHoleConstraints wc_prs
1598 ; thing_inside }
1599
1600 tcExtendIdBinderStackForRhs :: [MonoBindInfo] -> TcM a -> TcM a
1601 -- Extend the TcIdBinderStack for the RHS of the binding, with
1602 -- the monomorphic Id. That way, if we have, say
1603 -- f = \x -> blah
1604 -- and something goes wrong in 'blah', we get a "relevant binding"
1605 -- looking like f :: alpha -> beta
1606 -- This applies if 'f' has a type signature too:
1607 -- f :: forall a. [a] -> [a]
1608 -- f x = True
1609 -- We can't unify True with [a], and a relevant binding is f :: [a] -> [a]
1610 -- If we had the *polymorphic* version of f in the TcIdBinderStack, it
1611 -- would not be reported as relevant, because its type is closed
1612 tcExtendIdBinderStackForRhs infos thing_inside
1613 = tcExtendIdBndrs [ TcIdBndr mono_id NotTopLevel
1614 | MBI { mbi_mono_id = mono_id } <- infos ]
1615 thing_inside
1616 -- NotTopLevel: it's a monomorphic binding
1617
1618 ---------------------
1619 getMonoBindInfo :: [Located TcMonoBind] -> [MonoBindInfo]
1620 getMonoBindInfo tc_binds
1621 = foldr (get_info . unLoc) [] tc_binds
1622 where
1623 get_info (TcFunBind info _ _) rest = info : rest
1624 get_info (TcPatBind infos _ _ _) rest = infos ++ rest
1625
1626 {-
1627 ************************************************************************
1628 * *
1629 Signatures
1630 * *
1631 ************************************************************************
1632
1633 Type signatures are tricky. See Note [Signature skolems] in TcType
1634
1635 @tcSigs@ checks the signatures for validity, and returns a list of
1636 {\em freshly-instantiated} signatures. That is, the types are already
1637 split up, and have fresh type variables installed. All non-type-signature
1638 "RenamedSigs" are ignored.
1639
1640 The @TcSigInfo@ contains @TcTypes@ because they are unified with
1641 the variable's type, and after that checked to see whether they've
1642 been instantiated.
1643
1644 Note [Scoped tyvars]
1645 ~~~~~~~~~~~~~~~~~~~~
1646 The -XScopedTypeVariables flag brings lexically-scoped type variables
1647 into scope for any explicitly forall-quantified type variables:
1648 f :: forall a. a -> a
1649 f x = e
1650 Then 'a' is in scope inside 'e'.
1651
1652 However, we do *not* support this
1653 - For pattern bindings e.g
1654 f :: forall a. a->a
1655 (f,g) = e
1656
1657 Note [Signature skolems]
1658 ~~~~~~~~~~~~~~~~~~~~~~~~
1659 When instantiating a type signature, we do so with either skolems or
1660 SigTv meta-type variables depending on the use_skols boolean. This
1661 variable is set True when we are typechecking a single function
1662 binding; and False for pattern bindings and a group of several
1663 function bindings.
1664
1665 Reason: in the latter cases, the "skolems" can be unified together,
1666 so they aren't properly rigid in the type-refinement sense.
1667 NB: unless we are doing H98, each function with a sig will be done
1668 separately, even if it's mutually recursive, so use_skols will be True
1669
1670
1671 Note [Only scoped tyvars are in the TyVarEnv]
1672 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1673 We are careful to keep only the *lexically scoped* type variables in
1674 the type environment. Why? After all, the renamer has ensured
1675 that only legal occurrences occur, so we could put all type variables
1676 into the type env.
1677
1678 But we want to check that two distinct lexically scoped type variables
1679 do not map to the same internal type variable. So we need to know which
1680 the lexically-scoped ones are... and at the moment we do that by putting
1681 only the lexically scoped ones into the environment.
1682
1683 Note [Instantiate sig with fresh variables]
1684 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1685 It's vital to instantiate a type signature with fresh variables.
1686 For example:
1687 type T = forall a. [a] -> [a]
1688 f :: T;
1689 f = g where { g :: T; g = <rhs> }
1690
1691 We must not use the same 'a' from the defn of T at both places!!
1692 (Instantiation is only necessary because of type synonyms. Otherwise,
1693 it's all cool; each signature has distinct type variables from the renamer.)
1694
1695 Note [Fail eagerly on bad signatures]
1696 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1697 If a type signaure is wrong, fail immediately:
1698
1699 * the type sigs may bind type variables, so proceeding without them
1700 can lead to a cascade of errors
1701
1702 * the type signature might be ambiguous, in which case checking
1703 the code against the signature will give a very similar error
1704 to the ambiguity error.
1705
1706 ToDo: this means we fall over if any type sig
1707 is wrong (eg at the top level of the module),
1708 which is over-conservative
1709 -}
1710
1711 tcTySigs :: [LSig Name] -> TcM ([TcId], TcSigFun)
1712 tcTySigs hs_sigs
1713 = checkNoErrs $ -- See Note [Fail eagerly on bad signatures]
1714 do { ty_sigs_s <- mapAndRecoverM tcTySig hs_sigs
1715 ; let ty_sigs = concat ty_sigs_s
1716 poly_ids = mapMaybe completeSigPolyId_maybe ty_sigs
1717 -- The returned [TcId] are the ones for which we have
1718 -- a complete type signature.
1719 -- See Note [Complete and partial type signatures]
1720 env = mkNameEnv [(tcSigInfoName sig, sig) | sig <- ty_sigs]
1721 ; return (poly_ids, lookupNameEnv env) }
1722
1723 tcTySig :: LSig Name -> TcM [TcSigInfo]
1724 tcTySig (L _ (IdSig id))
1725 = do { sig <- instTcTySigFromId id
1726 ; return [TcIdSig sig] }
1727
1728 tcTySig (L loc (TypeSig names sig_ty))
1729 = setSrcSpan loc $
1730 do { sigs <- sequence [ tcUserTypeSig sig_ty (Just name)
1731 | L _ name <- names ]
1732 ; return (map TcIdSig sigs) }
1733
1734 tcTySig (L loc (PatSynSig (L _ name) sig_ty))
1735 = setSrcSpan loc $
1736 do { tpsi <- tcPatSynSig name sig_ty
1737 ; return [TcPatSynSig tpsi] }
1738
1739 tcTySig _ = return []
1740
1741 isCompleteHsSig :: LHsSigWcType Name -> Bool
1742 -- ^ If there are no wildcards, return a LHsSigType
1743 isCompleteHsSig sig_ty
1744 | HsWC { hswc_wcs = wcs, hswc_ctx = extra } <- hsib_body sig_ty
1745 , null wcs
1746 , Nothing <- extra
1747 = True
1748 | otherwise
1749 = False
1750
1751 tcUserTypeSig :: LHsSigWcType Name -> Maybe Name -> TcM TcIdSigInfo
1752 -- Just n => Function type signatre name :: type
1753 -- Nothing => Expression type signature <expr> :: type
1754 tcUserTypeSig hs_sig_ty mb_name
1755 | isCompleteHsSig hs_sig_ty
1756 = pushTcLevelM_ $ -- When instantiating the signature, do so "one level in"
1757 -- so that they can be unified under the forall
1758 do { sigma_ty <- tcHsSigWcType ctxt_F hs_sig_ty
1759 ; (inst_tvs, theta, tau) <- tcInstType tcInstSigTyVars sigma_ty
1760 ; loc <- getSrcSpanM
1761 ; return $
1762 TISI { sig_bndr = CompleteSig (mkLocalId name sigma_ty)
1763 , sig_skols = findScopedTyVars sigma_ty inst_tvs
1764 , sig_theta = theta
1765 , sig_tau = tau
1766 , sig_ctxt = ctxt_T
1767 , sig_loc = loc } }
1768
1769 -- Partial sig with wildcards
1770 | HsIB { hsib_vars = vars, hsib_body = wc_ty } <- hs_sig_ty
1771 , HsWC { hswc_wcs = wcs, hswc_ctx = extra, hswc_body = hs_ty } <- wc_ty
1772 , (hs_tvs, L _ hs_ctxt, hs_tau) <- splitLHsSigmaTy hs_ty
1773 = do { (vars1, (wcs, tvs2, theta, tau))
1774 <- pushTcLevelM_ $
1775 -- When instantiating the signature, do so "one level in"
1776 -- so that they can be unified under the forall
1777 tcImplicitTKBndrs vars $
1778 tcWildCardBinders wcs $ \ wcs ->
1779 tcExplicitTKBndrs hs_tvs $ \ tvs2 ->
1780 do { -- Instantiate the type-class context; but if there
1781 -- is an extra-constraints wildcard, just discard it here
1782 traceTc "tcPartial" (ppr name $$ ppr vars $$ ppr wcs)
1783 ; theta <- mapM tcLHsPredType $
1784 case extra of
1785 Nothing -> hs_ctxt
1786 Just _ -> dropTail 1 hs_ctxt
1787
1788 ; tau <- tcHsOpenType hs_tau
1789
1790 -- zonking is necessary to establish type representation
1791 -- invariants
1792 ; theta <- zonkTcTypes theta
1793 ; tau <- zonkTcType tau
1794
1795 -- Check for validity (eg rankN etc)
1796 -- The ambiguity check will happen (from checkValidType),
1797 -- but unnecessarily; it will always succeed because there
1798 -- is no quantification
1799 ; checkValidType ctxt_F (mkPhiTy theta tau)
1800 -- NB: Do this in the context of the pushTcLevel so that
1801 -- the TcLevel invariant is respected
1802
1803 ; let bound_tvs
1804 = unionVarSets [ allBoundVariabless theta
1805 , allBoundVariables tau
1806 , mkVarSet (map snd wcs) ]
1807 ; return ((wcs, tvs2, theta, tau), bound_tvs) }
1808
1809 ; loc <- getSrcSpanM
1810 ; return $
1811 TISI { sig_bndr = PartialSig { sig_name = name, sig_hs_ty = hs_ty
1812 , sig_cts = extra, sig_wcs = wcs }
1813 , sig_skols = [ (tyVarName tv, tv) | tv <- vars1 ++ tvs2 ]
1814 , sig_theta = theta
1815 , sig_tau = tau
1816 , sig_ctxt = ctxt_F
1817 , sig_loc = loc } }
1818 where
1819 name = case mb_name of
1820 Just n -> n
1821 Nothing -> mkUnboundName (mkVarOcc "<expression>")
1822 ctxt_F = case mb_name of
1823 Just n -> FunSigCtxt n False
1824 Nothing -> ExprSigCtxt
1825 ctxt_T = case mb_name of
1826 Just n -> FunSigCtxt n True
1827 Nothing -> ExprSigCtxt
1828
1829 instTcTySigFromId :: Id -> TcM TcIdSigInfo
1830 -- Used for instance methods and record selectors
1831 instTcTySigFromId id
1832 = do { let name = idName id
1833 loc = getSrcSpan name
1834 ; (tvs, theta, tau) <- tcInstType (tcInstSigTyVarsLoc loc)
1835 (idType id)
1836 ; return $ TISI { sig_bndr = CompleteSig id
1837 , sig_skols = [(tyVarName tv, tv) | tv <- tvs]
1838 -- These are freshly instantiated, so although
1839 -- we put them in the type envt, doing so has
1840 -- no effect
1841 , sig_theta = theta
1842 , sig_tau = tau
1843 , sig_ctxt = FunSigCtxt name False
1844 -- False: do not report redundant constraints
1845 -- The user has no control over the signature!
1846 , sig_loc = loc } }
1847
1848 instTcTySig :: UserTypeCtxt
1849 -> LHsSigType Name -- Used to get the scoped type variables
1850 -> TcType
1851 -> Name -- Name of the function
1852 -> TcM TcIdSigInfo
1853 instTcTySig ctxt hs_ty sigma_ty name
1854 = do { (inst_tvs, theta, tau) <- tcInstType tcInstSigTyVars sigma_ty
1855 ; return (TISI { sig_bndr = CompleteSig (mkLocalIdOrCoVar name sigma_ty)
1856 , sig_skols = findScopedTyVars sigma_ty inst_tvs
1857 , sig_theta = theta
1858 , sig_tau = tau
1859 , sig_ctxt = ctxt
1860 , sig_loc = getLoc (hsSigType hs_ty)
1861 -- SrcSpan from the signature
1862 }) }
1863
1864 -------------------------------
1865 data GeneralisationPlan
1866 = NoGen -- No generalisation, no AbsBinds
1867
1868 | InferGen -- Implicit generalisation; there is an AbsBinds
1869 Bool -- True <=> apply the MR; generalise only unconstrained type vars
1870
1871 | CheckGen (LHsBind Name) TcIdSigInfo
1872 -- One FunBind with a signature
1873 -- Explicit generalisation; there is an AbsBindsSig
1874
1875 -- A consequence of the no-AbsBinds choice (NoGen) is that there is
1876 -- no "polymorphic Id" and "monmomorphic Id"; there is just the one
1877
1878 instance Outputable GeneralisationPlan where
1879 ppr NoGen = text "NoGen"
1880 ppr (InferGen b) = text "InferGen" <+> ppr b
1881 ppr (CheckGen _ s) = text "CheckGen" <+> ppr s
1882
1883 decideGeneralisationPlan
1884 :: DynFlags -> TcTypeEnv -> [Name]
1885 -> [LHsBind Name] -> TcSigFun -> GeneralisationPlan
1886 decideGeneralisationPlan dflags type_env bndr_names lbinds sig_fn
1887 | unlifted_pat_binds = NoGen
1888 | Just bind_sig <- one_funbind_with_sig = sig_plan bind_sig
1889 | mono_local_binds = NoGen
1890 | otherwise = InferGen mono_restriction
1891 where
1892 bndr_set = mkNameSet bndr_names
1893 binds = map unLoc lbinds
1894
1895 sig_plan :: (LHsBind Name, TcIdSigInfo) -> GeneralisationPlan
1896 -- See Note [Partial type signatures and generalisation]
1897 -- We use InferGen False to say "do inference, but do not apply
1898 -- the MR". It's stupid to apply the MR when we are given a
1899 -- signature! C.f Trac #11016, function f2
1900 sig_plan (lbind, sig@(TISI { sig_bndr = s_bndr, sig_theta = theta }))
1901 = case s_bndr of
1902 CompleteSig {} -> CheckGen lbind sig
1903 PartialSig { sig_cts = extra_constraints }
1904 | Nothing <- extra_constraints
1905 , [] <- theta
1906 -> InferGen True -- No signature constraints: apply the MR
1907 | otherwise
1908 -> InferGen False -- Don't apply the MR
1909
1910 unlifted_pat_binds = any isUnliftedHsBind binds
1911 -- Unlifted patterns (unboxed tuple) must not
1912 -- be polymorphic, because we are going to force them
1913 -- See Trac #4498, #8762
1914
1915 mono_restriction = xopt LangExt.MonomorphismRestriction dflags
1916 && any restricted binds
1917
1918 is_closed_ns :: NameSet -> Bool -> Bool
1919 is_closed_ns ns b = foldNameSet ((&&) . is_closed_id) b ns
1920 -- ns are the Names referred to from the RHS of this bind
1921
1922 is_closed_id :: Name -> Bool
1923 -- See Note [Bindings with closed types] in TcRnTypes
1924 is_closed_id name
1925 | name `elemNameSet` bndr_set
1926 = True -- Ignore binders in this groups, of course
1927 | Just thing <- lookupNameEnv type_env name
1928 = case thing of
1929 ATcId { tct_closed = cl } -> isTopLevel cl -- This is the key line
1930 ATyVar {} -> False -- In-scope type variables
1931 AGlobal {} -> True -- are not closed!
1932 _ -> pprPanic "is_closed_id" (ppr name)
1933 | otherwise
1934 = WARN( isInternalName name, ppr name ) True
1935 -- The free-var set for a top level binding mentions
1936 -- imported things too, so that we can report unused imports
1937 -- These won't be in the local type env.
1938 -- Ditto class method etc from the current module
1939
1940 mono_local_binds = xopt LangExt.MonoLocalBinds dflags
1941 && not closed_flag
1942
1943 closed_flag = foldr (is_closed_ns . bind_fvs) True binds
1944
1945 no_sig n = noCompleteSig (sig_fn n)
1946
1947 -- With OutsideIn, all nested bindings are monomorphic
1948 -- except a single function binding with a signature
1949 one_funbind_with_sig
1950 | [lbind@(L _ (FunBind { fun_id = v }))] <- lbinds
1951 , Just (TcIdSig sig) <- sig_fn (unLoc v)
1952 = Just (lbind, sig)
1953 | otherwise
1954 = Nothing
1955
1956 -- The Haskell 98 monomorphism restriction
1957 restricted (PatBind {}) = True
1958 restricted (VarBind { var_id = v }) = no_sig v
1959 restricted (FunBind { fun_id = v, fun_matches = m }) = restricted_match m
1960 && no_sig (unLoc v)
1961 restricted (PatSynBind {}) = panic "isRestrictedGroup/unrestricted PatSynBind"
1962 restricted (AbsBinds {}) = panic "isRestrictedGroup/unrestricted AbsBinds"
1963 restricted (AbsBindsSig {}) = panic "isRestrictedGroup/unrestricted AbsBindsSig"
1964
1965 restricted_match (MG { mg_alts = L _ (L _ (Match _ [] _ _) : _ )}) = True
1966 restricted_match _ = False
1967 -- No args => like a pattern binding
1968 -- Some args => a function binding
1969
1970 -------------------
1971 checkStrictBinds :: TopLevelFlag -> RecFlag
1972 -> [LHsBind Name]
1973 -> LHsBinds TcId -> [Id]
1974 -> TcM ()
1975 -- Check that non-overloaded unlifted bindings are
1976 -- a) non-recursive,
1977 -- b) not top level,
1978 -- c) not a multiple-binding group (more or less implied by (a))
1979
1980 checkStrictBinds top_lvl rec_group orig_binds tc_binds poly_ids
1981 | any_unlifted_bndr || any_strict_pat -- This binding group must be matched strictly
1982 = do { check (isNotTopLevel top_lvl)
1983 (strictBindErr "Top-level" any_unlifted_bndr orig_binds)
1984 ; check (isNonRec rec_group)
1985 (strictBindErr "Recursive" any_unlifted_bndr orig_binds)
1986
1987 ; check (all is_monomorphic (bagToList tc_binds))
1988 (polyBindErr orig_binds)
1989 -- data Ptr a = Ptr Addr#
1990 -- f x = let p@(Ptr y) = ... in ...
1991 -- Here the binding for 'p' is polymorphic, but does
1992 -- not mix with an unlifted binding for 'y'. You should
1993 -- use a bang pattern. Trac #6078.
1994
1995 ; check (isSingleton orig_binds)
1996 (strictBindErr "Multiple" any_unlifted_bndr orig_binds)
1997
1998 -- Complain about a binding that looks lazy
1999 -- e.g. let I# y = x in ...
2000 -- Remember, in checkStrictBinds we are going to do strict
2001 -- matching, so (for software engineering reasons) we insist
2002 -- that the strictness is manifest on each binding
2003 -- However, lone (unboxed) variables are ok
2004 ; check (not any_pat_looks_lazy)
2005 (unliftedMustBeBang orig_binds) }
2006 | otherwise
2007 = traceTc "csb2" (ppr [(id, idType id) | id <- poly_ids]) >>
2008 return ()
2009 where
2010 any_unlifted_bndr = any is_unlifted poly_ids
2011 any_strict_pat = any (isUnliftedHsBind . unLoc) orig_binds
2012 any_pat_looks_lazy = any (looksLazyPatBind . unLoc) orig_binds
2013
2014 is_unlifted id = case tcSplitSigmaTy (idType id) of
2015 (_, _, rho) -> isUnliftedType rho
2016 -- For the is_unlifted check, we need to look inside polymorphism
2017 -- and overloading. E.g. x = (# 1, True #)
2018 -- would get type forall a. Num a => (# a, Bool #)
2019 -- and we want to reject that. See Trac #9140
2020
2021 is_monomorphic (L _ (AbsBinds { abs_tvs = tvs, abs_ev_vars = evs }))
2022 = null tvs && null evs
2023 is_monomorphic (L _ (AbsBindsSig { abs_tvs = tvs, abs_ev_vars = evs }))
2024 = null tvs && null evs
2025 is_monomorphic _ = True
2026
2027 check :: Bool -> MsgDoc -> TcM ()
2028 -- Just like checkTc, but with a special case for module GHC.Prim:
2029 -- see Note [Compiling GHC.Prim]
2030 check True _ = return ()
2031 check False err = do { mod <- getModule
2032 ; checkTc (mod == gHC_PRIM) err }
2033
2034 unliftedMustBeBang :: [LHsBind Name] -> SDoc
2035 unliftedMustBeBang binds
2036 = hang (text "Pattern bindings containing unlifted types should use an outermost bang pattern:")
2037 2 (vcat (map ppr binds))
2038
2039 polyBindErr :: [LHsBind Name] -> SDoc
2040 polyBindErr binds
2041 = hang (text "You can't mix polymorphic and unlifted bindings")
2042 2 (vcat [vcat (map ppr binds),
2043 text "Probable fix: add a type signature"])
2044
2045 strictBindErr :: String -> Bool -> [LHsBind Name] -> SDoc
2046 strictBindErr flavour any_unlifted_bndr binds
2047 = hang (text flavour <+> msg <+> text "aren't allowed:")
2048 2 (vcat (map ppr binds))
2049 where
2050 msg | any_unlifted_bndr = text "bindings for unlifted types"
2051 | otherwise = text "bang-pattern or unboxed-tuple bindings"
2052
2053
2054 {- Note [Compiling GHC.Prim]
2055 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2056 Module GHC.Prim has no source code: it is the host module for
2057 primitive, built-in functions and types. However, for Haddock-ing
2058 purposes we generate (via utils/genprimopcode) a fake source file
2059 GHC/Prim.hs, and give it to Haddock, so that it can generate
2060 documentation. It contains definitions like
2061 nullAddr# :: NullAddr#
2062 which would normally be rejected as a top-level unlifted binding. But
2063 we don't want to complain, because we are only "compiling" this fake
2064 mdule for documentation purposes. Hence this hacky test for gHC_PRIM
2065 in checkStrictBinds.
2066
2067 (We only make the test if things look wrong, so there is no cost in
2068 the common case.) -}
2069
2070
2071 {- *********************************************************************
2072 * *
2073 Error contexts and messages
2074 * *
2075 ********************************************************************* -}
2076
2077 -- This one is called on LHS, when pat and grhss are both Name
2078 -- and on RHS, when pat is TcId and grhss is still Name
2079 patMonoBindsCtxt :: (OutputableBndr id, Outputable body) => LPat id -> GRHSs Name body -> SDoc
2080 patMonoBindsCtxt pat grhss
2081 = hang (text "In a pattern binding:") 2 (pprPatBind pat grhss)
2082
2083 typeSigCtxt :: UserTypeCtxt -> TcIdSigBndr -> SDoc
2084 typeSigCtxt ctxt (PartialSig { sig_hs_ty = hs_ty })
2085 = pprSigCtxt ctxt empty (ppr hs_ty)
2086 typeSigCtxt ctxt (CompleteSig id)
2087 = pprSigCtxt ctxt empty (ppr (idType id))
2088
2089 instErrCtxt :: Name -> TcType -> TidyEnv -> TcM (TidyEnv, SDoc)
2090 instErrCtxt name ty env
2091 = do { let (env', ty') = tidyOpenType env ty
2092 ; return (env', hang (text "When instantiating" <+> quotes (ppr name) <>
2093 text ", initially inferred to have" $$
2094 text "this overly-general type:")
2095 2 (ppr ty') $$
2096 extra) }
2097 where
2098 extra = sdocWithDynFlags $ \dflags ->
2099 ppWhen (xopt LangExt.MonomorphismRestriction dflags) $
2100 text "NB: This instantiation can be caused by the" <+>
2101 text "monomorphism restriction."