Make the package -Wall clean
[ghc.git] / libraries / template-haskell / Language / Haskell / TH / Ppr.hs
1 -- TH.Ppr contains a prettyprinter for the
2 -- Template Haskell datatypes
3
4 module Language.Haskell.TH.Ppr where
5 -- All of the exports from this module should
6 -- be "public" functions. The main module TH
7 -- re-exports them all.
8
9 import Text.PrettyPrint.HughesPJ (render)
10 import Language.Haskell.TH.PprLib
11 import Language.Haskell.TH.Syntax
12 import Data.Char ( toLower )
13
14 nestDepth :: Int
15 nestDepth = 4
16
17 type Precedence = Int
18 appPrec, opPrec, noPrec :: Precedence
19 appPrec = 2 -- Argument of a function application
20 opPrec = 1 -- Argument of an infix operator
21 noPrec = 0 -- Others
22
23 parensIf :: Bool -> Doc -> Doc
24 parensIf True d = parens d
25 parensIf False d = d
26
27 ------------------------------
28
29 pprint :: Ppr a => a -> String
30 pprint x = render $ to_HPJ_Doc $ ppr x
31
32 class Ppr a where
33 ppr :: a -> Doc
34 ppr_list :: [a] -> Doc
35 ppr_list = vcat . map ppr
36
37 instance Ppr a => Ppr [a] where
38 ppr x = ppr_list x
39
40 ------------------------------
41 instance Ppr Name where
42 ppr v = pprName v
43
44 ------------------------------
45 instance Ppr Info where
46 ppr (ClassI d) = ppr d
47 ppr (TyConI d) = ppr d
48 ppr (PrimTyConI name arity is_unlifted)
49 = text "Primitive"
50 <+> (if is_unlifted then text "unlifted" else empty)
51 <+> text "type construtor" <+> quotes (ppr name)
52 <+> parens (text "arity" <+> int arity)
53 ppr (ClassOpI v ty cls fix)
54 = text "Class op from" <+> ppr cls <> colon <+>
55 vcat [ppr_sig v ty, pprFixity v fix]
56 ppr (DataConI v ty tc fix)
57 = text "Constructor from" <+> ppr tc <> colon <+>
58 vcat [ppr_sig v ty, pprFixity v fix]
59 ppr (TyVarI v ty)
60 = text "Type variable" <+> ppr v <+> equals <+> ppr ty
61 ppr (VarI v ty mb_d fix)
62 = vcat [ppr_sig v ty, pprFixity v fix,
63 case mb_d of { Nothing -> empty; Just d -> ppr d }]
64
65 ppr_sig :: Name -> Type -> Doc
66 ppr_sig v ty = ppr v <+> text "::" <+> ppr ty
67
68 pprFixity :: Name -> Fixity -> Doc
69 pprFixity _ f | f == defaultFixity = empty
70 pprFixity v (Fixity i d) = ppr_fix d <+> int i <+> ppr v
71 where ppr_fix InfixR = text "infixr"
72 ppr_fix InfixL = text "infixl"
73 ppr_fix InfixN = text "infix"
74
75
76 ------------------------------
77 instance Ppr Exp where
78 ppr = pprExp noPrec
79
80 pprInfixExp :: Exp -> Doc
81 pprInfixExp (VarE v) = pprName' Infix v
82 pprInfixExp (ConE v) = pprName' Infix v
83 pprInfixExp _ = error "Attempt to pretty-print non-variable or constructor in infix context!"
84
85 pprExp :: Precedence -> Exp -> Doc
86 pprExp _ (VarE v) = pprName' Applied v
87 pprExp _ (ConE c) = pprName' Applied c
88 pprExp i (LitE l) = pprLit i l
89 pprExp i (AppE e1 e2) = parensIf (i >= appPrec) $ pprExp opPrec e1
90 <+> pprExp appPrec e2
91 pprExp i (InfixE (Just e1) op (Just e2))
92 = parensIf (i >= opPrec) $ pprExp opPrec e1
93 <+> pprInfixExp op
94 <+> pprExp opPrec e2
95 pprExp _ (InfixE me1 op me2) = parens $ pprMaybeExp noPrec me1
96 <+> pprInfixExp op
97 <+> pprMaybeExp noPrec me2
98 pprExp i (LamE ps e) = parensIf (i > noPrec) $ char '\\' <> hsep (map (pprPat appPrec) ps)
99 <+> text "->" <+> ppr e
100 pprExp _ (TupE es) = parens $ sep $ punctuate comma $ map ppr es
101 -- Nesting in Cond is to avoid potential problems in do statments
102 pprExp i (CondE guard true false)
103 = parensIf (i > noPrec) $ sep [text "if" <+> ppr guard,
104 nest 1 $ text "then" <+> ppr true,
105 nest 1 $ text "else" <+> ppr false]
106 pprExp i (LetE ds e) = parensIf (i > noPrec) $ text "let" <+> ppr ds
107 $$ text " in" <+> ppr e
108 pprExp i (CaseE e ms)
109 = parensIf (i > noPrec) $ text "case" <+> ppr e <+> text "of"
110 $$ nest nestDepth (ppr ms)
111 pprExp i (DoE ss) = parensIf (i > noPrec) $ text "do" <+> ppr ss
112 pprExp _ (CompE []) = error "Can't happen: pprExp (CompExp [])"
113 -- This will probably break with fixity declarations - would need a ';'
114 pprExp _ (CompE ss) = text "[" <> ppr s
115 <+> text "|"
116 <+> (sep $ punctuate comma $ map ppr ss')
117 <> text "]"
118 where s = last ss
119 ss' = init ss
120 pprExp _ (ArithSeqE d) = ppr d
121 pprExp _ (ListE es) = brackets $ sep $ punctuate comma $ map ppr es
122 pprExp i (SigE e t) = parensIf (i > noPrec) $ ppr e <+> text "::" <+> ppr t
123 pprExp _ (RecConE nm fs) = ppr nm <> braces (pprFields fs)
124 pprExp _ (RecUpdE e fs) = pprExp appPrec e <> braces (pprFields fs)
125
126 pprFields :: [(Name,Exp)] -> Doc
127 pprFields = sep . punctuate comma . map (\(s,e) -> ppr s <+> equals <+> ppr e)
128
129 pprMaybeExp :: Precedence -> Maybe Exp -> Doc
130 pprMaybeExp _ Nothing = empty
131 pprMaybeExp i (Just e) = pprExp i e
132
133 ------------------------------
134 instance Ppr Stmt where
135 ppr (BindS p e) = ppr p <+> text "<-" <+> ppr e
136 ppr (LetS ds) = text "let" <+> ppr ds
137 ppr (NoBindS e) = ppr e
138 ppr (ParS sss) = sep $ punctuate (text "|")
139 $ map (sep . punctuate comma . map ppr) sss
140
141 ------------------------------
142 instance Ppr Match where
143 ppr (Match p rhs ds) = ppr p <+> pprBody False rhs
144 $$ where_clause ds
145
146 ------------------------------
147 pprBody :: Bool -> Body -> Doc
148 pprBody eq (GuardedB xs) = nest nestDepth $ vcat $ map do_guard xs
149 where eqd = if eq then text "=" else text "->"
150 do_guard (NormalG g, e) = text "|" <+> ppr g <+> eqd <+> ppr e
151 do_guard (PatG ss, e) = text "|" <+> vcat (map ppr ss)
152 $$ nest nestDepth (eqd <+> ppr e)
153 pprBody eq (NormalB e) = (if eq then text "=" else text "->") <+> ppr e
154
155 ------------------------------
156 pprLit :: Precedence -> Lit -> Doc
157 pprLit i (IntPrimL x) = parensIf (i > noPrec && x < 0)
158 (integer x <> char '#')
159 pprLit _ (WordPrimL x) = integer x <> text "##"
160 pprLit i (FloatPrimL x) = parensIf (i > noPrec && x < 0)
161 (float (fromRational x) <> char '#')
162 pprLit i (DoublePrimL x) = parensIf (i > noPrec && x < 0)
163 (double (fromRational x) <> text "##")
164 pprLit i (IntegerL x) = parensIf (i > noPrec && x < 0) (integer x)
165 pprLit _ (CharL c) = text (show c)
166 pprLit _ (StringL s) = text (show s)
167 pprLit i (RationalL rat) = parensIf (i > noPrec) $ rational rat
168
169 ------------------------------
170 instance Ppr Pat where
171 ppr = pprPat noPrec
172
173 pprPat :: Precedence -> Pat -> Doc
174 pprPat i (LitP l) = pprLit i l
175 pprPat _ (VarP v) = pprName' Applied v
176 pprPat _ (TupP ps) = parens $ sep $ punctuate comma $ map ppr ps
177 pprPat i (ConP s ps) = parensIf (i > noPrec) $ pprName' Applied s
178 <+> sep (map (pprPat appPrec) ps)
179 pprPat i (InfixP p1 n p2)
180 = parensIf (i > noPrec) (pprPat opPrec p1 <+>
181 pprName' Infix n <+>
182 pprPat opPrec p2)
183 pprPat i (TildeP p) = parensIf (i > noPrec) $ char '~' <> pprPat appPrec p
184 pprPat i (AsP v p) = parensIf (i > noPrec) $ ppr v <> text "@"
185 <> pprPat appPrec p
186 pprPat _ WildP = text "_"
187 pprPat _ (RecP nm fs)
188 = parens $ ppr nm
189 <+> braces (sep $ punctuate comma $
190 map (\(s,p) -> ppr s <+> equals <+> ppr p) fs)
191 pprPat _ (ListP ps) = brackets $ sep $ punctuate comma $ map ppr ps
192 pprPat i (SigP p t) = parensIf (i > noPrec) $ ppr p <+> text "::" <+> ppr t
193
194 ------------------------------
195 instance Ppr Dec where
196 ppr (FunD f cs) = vcat $ map (\c -> ppr f <+> ppr c) cs
197 ppr (ValD p r ds) = ppr p <+> pprBody True r
198 $$ where_clause ds
199 ppr (TySynD t xs rhs) = text "type" <+> ppr t <+> hsep (map ppr xs)
200 <+> text "=" <+> ppr rhs
201 ppr (DataD ctxt t xs cs decs)
202 = text "data"
203 <+> pprCxt ctxt
204 <+> ppr t <+> hsep (map ppr xs)
205 <+> sep (pref $ map ppr cs)
206 $$ if null decs
207 then empty
208 else nest nestDepth
209 $ text "deriving"
210 <+> parens (hsep $ punctuate comma $ map ppr decs)
211 where pref :: [Doc] -> [Doc]
212 pref [] = [char '='] -- Can't happen in H98
213 pref (d:ds) = (char '=' <+> d):map (char '|' <+>) ds
214 ppr (NewtypeD ctxt t xs c decs)
215 = text "newtype"
216 <+> pprCxt ctxt
217 <+> ppr t <+> hsep (map ppr xs)
218 <+> char '=' <+> ppr c
219 $$ if null decs
220 then empty
221 else nest nestDepth
222 $ text "deriving"
223 <+> parens (hsep $ punctuate comma $ map ppr decs)
224 ppr (ClassD ctxt c xs fds ds) = text "class" <+> pprCxt ctxt
225 <+> ppr c <+> hsep (map ppr xs) <+> ppr fds
226 $$ where_clause ds
227 ppr (InstanceD ctxt i ds) = text "instance" <+> pprCxt ctxt <+> ppr i
228 $$ where_clause ds
229 ppr (SigD f t) = ppr f <+> text "::" <+> ppr t
230 ppr (ForeignD f) = ppr f
231
232 ------------------------------
233 instance Ppr FunDep where
234 ppr (FunDep xs ys) = hsep (map ppr xs) <+> text "->" <+> hsep (map ppr ys)
235 ppr_list [] = empty
236 ppr_list xs = char '|' <+> sep (punctuate (text ", ") (map ppr xs))
237
238 ------------------------------
239 instance Ppr Foreign where
240 ppr (ImportF callconv safety impent as typ)
241 = text "foreign import"
242 <+> showtextl callconv
243 <+> showtextl safety
244 <+> text (show impent)
245 <+> ppr as
246 <+> text "::" <+> ppr typ
247 ppr (ExportF callconv expent as typ)
248 = text "foreign export"
249 <+> showtextl callconv
250 <+> text (show expent)
251 <+> ppr as
252 <+> text "::" <+> ppr typ
253
254 ------------------------------
255 instance Ppr Clause where
256 ppr (Clause ps rhs ds) = hsep (map (pprPat appPrec) ps) <+> pprBody True rhs
257 $$ where_clause ds
258
259 ------------------------------
260 instance Ppr Con where
261 ppr (NormalC c sts) = ppr c <+> sep (map pprStrictType sts)
262 ppr (RecC c vsts)
263 = ppr c <+> braces (sep (punctuate comma $ map pprVarStrictType vsts))
264 ppr (InfixC st1 c st2) = pprStrictType st1
265 <+> pprName' Infix c
266 <+> pprStrictType st2
267 ppr (ForallC ns ctxt con) = text "forall" <+> hsep (map ppr ns)
268 <+> char '.' <+> pprCxt ctxt <+> ppr con
269
270 ------------------------------
271 pprVarStrictType :: (Name, Strict, Type) -> Doc
272 -- Slight infelicity: with print non-atomic type with parens
273 pprVarStrictType (v, str, t) = ppr v <+> text "::" <+> pprStrictType (str, t)
274
275 ------------------------------
276 pprStrictType :: (Strict, Type) -> Doc
277 -- Prints with parens if not already atomic
278 pprStrictType (IsStrict, t) = char '!' <> pprParendType t
279 pprStrictType (NotStrict, t) = pprParendType t
280
281 ------------------------------
282 pprParendType :: Type -> Doc
283 pprParendType (VarT v) = ppr v
284 pprParendType (ConT c) = ppr c
285 pprParendType (TupleT 0) = text "()"
286 pprParendType (TupleT n) = parens (hcat (replicate (n-1) comma))
287 pprParendType ArrowT = parens (text "->")
288 pprParendType ListT = text "[]"
289 pprParendType other = parens (ppr other)
290
291 instance Ppr Type where
292 ppr (ForallT tvars ctxt ty) =
293 text "forall" <+> hsep (map ppr tvars) <+> text "."
294 <+> pprCxt ctxt <+> ppr ty
295 ppr ty = pprTyApp (split ty)
296
297 pprTyApp :: (Type, [Type]) -> Doc
298 pprTyApp (ArrowT, [arg1,arg2]) = sep [ppr arg1 <+> text "->", ppr arg2]
299 pprTyApp (ListT, [arg]) = brackets (ppr arg)
300 pprTyApp (TupleT n, args)
301 | length args == n = parens (sep (punctuate comma (map ppr args)))
302 pprTyApp (fun, args) = pprParendType fun <+> sep (map pprParendType args)
303
304 split :: Type -> (Type, [Type]) -- Split into function and args
305 split t = go t []
306 where go (AppT t1 t2) args = go t1 (t2:args)
307 go ty args = (ty, args)
308
309 ------------------------------
310 pprCxt :: Cxt -> Doc
311 pprCxt [] = empty
312 pprCxt [t] = ppr t <+> text "=>"
313 pprCxt ts = parens (hsep $ punctuate comma $ map ppr ts) <+> text "=>"
314
315 ------------------------------
316 instance Ppr Range where
317 ppr = brackets . pprRange
318 where pprRange :: Range -> Doc
319 pprRange (FromR e) = ppr e <> text ".."
320 pprRange (FromThenR e1 e2) = ppr e1 <> text ","
321 <> ppr e2 <> text ".."
322 pprRange (FromToR e1 e2) = ppr e1 <> text ".." <> ppr e2
323 pprRange (FromThenToR e1 e2 e3) = ppr e1 <> text ","
324 <> ppr e2 <> text ".."
325 <> ppr e3
326
327 ------------------------------
328 where_clause :: [Dec] -> Doc
329 where_clause [] = empty
330 where_clause ds = nest nestDepth $ text "where" <+> vcat (map ppr ds)
331
332 showtextl :: Show a => a -> Doc
333 showtextl = text . map toLower . show
334