Fix isDroppableCt (Trac #14763)
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2012
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [8.5], [glasgow-haskell-bugs@haskell.org], [ghc-AC_PACKAGE_VERSION])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 7.5, 7.4.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 7.4.20111220).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # git repository.  If this is a source distribution (not a git
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'python3 boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl this makes sure `./configure --target=<cross-compile-target>`
37 dnl works as expected, since we're slightly modifying how Autoconf
38 dnl interprets build/host/target and how this interacts with $CC tests
39 test -n "$target_alias" && ac_tool_prefix=$target_alias-
40
41 dnl ----------------------------------------------------------
42 dnl ** Find unixy sort and find commands,
43 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
44
45 dnl ** Find find command (for Win32's benefit)
46 FP_PROG_FIND
47 FP_PROG_SORT
48
49 dnl ----------------------------------------------------------
50 FP_SETUP_PROJECT_VERSION
51
52 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
53 AC_SUBST([release], [1])
54
55 # First off, a distrib sanity check..
56 AC_CONFIG_SRCDIR([mk/config.mk.in])
57
58 dnl * We require autoconf version 2.60
59 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
60 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
61 dnl Using autoconf 2.59 started to give nonsense like this
62 dnl  #define SIZEOF_CHAR 0
63 dnl recently.
64 AC_PREREQ([2.60])
65
66 # -------------------------------------------------------------------------
67 # Prepare to generate the following header files
68 #
69 #
70 AC_CONFIG_HEADER(mk/config.h)
71
72 # No, semi-sadly, we don't do `--srcdir'...
73 if test x"$srcdir" != 'x.' ; then
74     echo "This configuration does not support the \`--srcdir' option.."
75     exit 1
76 fi
77
78 dnl --------------------------------------------------------------
79 dnl * Project specific configuration options
80 dnl --------------------------------------------------------------
81 dnl What follows is a bunch of options that can either be configured
82 dnl through command line options to the configure script or by
83 dnl supplying defns in the build tree's mk/build.mk. Having the option to
84 dnl use either is considered a Feature.
85
86 dnl ** What command to use to compile compiler sources ?
87 dnl --------------------------------------------------------------
88
89 AC_ARG_WITH([ghc],
90 [AC_HELP_STRING([--with-ghc=ARG],
91   [Use ARG as the path to GHC  [default=autodetect]])],
92   [WithGhc="$withval"],
93   [if test "$GHC" = ""; then
94     AC_PATH_PROG([GHC], [ghc])
95   fi
96   WithGhc="$GHC"])
97
98 dnl ** Tell the make system which OS we are using
99 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
100 AC_SUBST(OSTYPE)
101
102 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
103 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
104                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
105         EnableBootstrapWithDevelSnaphost=YES,
106         EnableBootstrapWithDevelSnaphost=NO
107 )
108
109 AC_ARG_ENABLE(tarballs-autodownload,
110 [AC_HELP_STRING([--enable-tarballs-autodownload],
111                 [Automatically download Windows distribution binaries if needed.])],
112         TarballsAutodownload=YES,
113         TarballsAutodownload=NO
114 )
115
116 AC_ARG_ENABLE(distro-toolchain,
117 [AC_HELP_STRING([--enable-distro-toolchain],
118                 [Do not use bundled Windows toolchain binaries.])],
119         EnableDistroToolchain=YES,
120         EnableDistroToolchain=NO
121 )
122
123 if test "$EnableDistroToolchain" = "YES"; then
124   TarballsAutodownload=NO
125 fi
126
127 dnl CC_STAGE0 is like the "previous" variable CC (inherited by CC_STAGE[123])
128 dnl but instead used by stage0 for bootstrapping stage1
129 AC_ARG_VAR(CC_STAGE0, [C compiler command (bootstrap)])
130
131 if test "$WithGhc" != ""; then
132   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
133
134   if test "$GhcMajVersion" = "unknown" || test "$GhcMinVersion" = "unknown"; then
135      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
136   fi
137
138   AC_SUBST(GhcVersion)dnl
139   AC_SUBST(GhcMajVersion)dnl
140   AC_SUBST(GhcMinVersion)dnl
141   AC_SUBST(GhcPatchLevel)dnl
142   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
143   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
144
145   dnl infer CC_STAGE0 from `ghc --info` unless explicitly set by user
146   if test -z "$CC_STAGE0"; then
147     BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command])
148   fi
149
150   BOOTSTRAPPING_GHC_INFO_FIELD([LD_STAGE0],[ld command])
151   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command])
152   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags])
153   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file])
154 fi
155
156 dnl ** Must have GHC to build GHC
157 if test "$WithGhc" = ""
158 then
159     AC_MSG_ERROR([GHC is required.])
160 fi
161 FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[8.0],
162     [AC_MSG_ERROR([GHC version 8.0 or later is required to compile GHC.])])
163
164 if test `expr $GhcMinVersion % 2` = "1"
165 then
166     if test "$EnableBootstrapWithDevelSnaphost" = "NO"
167     then
168         AC_MSG_ERROR([
169      $WithGhc is a development snapshot of GHC, version $GhcVersion.
170      Bootstrapping using this version of GHC is not supported, and may not
171      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
172      or --with-ghc to specify a different GHC to use.])
173     fi
174 fi
175
176 GHC_PACKAGE_DB_FLAG=package-db
177 AC_SUBST(GHC_PACKAGE_DB_FLAG)
178
179 # GHC is passed to Cabal, so we need a native path
180 if test "${WithGhc}" != ""
181 then
182     ghc_host_os=`"${WithGhc}" +RTS --info | grep 'Host OS' | sed -e 's/.*, "//' -e 's/")//'`
183
184     if test "$ghc_host_os" = "mingw32"
185     then
186         if test "${OSTYPE}" = "msys"
187         then
188             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
189         else
190             # Canonicalise to <drive>:/path/to/ghc
191             WithGhc=`cygpath -m "${WithGhc}"`
192         fi
193         echo "GHC path canonicalised to: ${WithGhc}"
194     fi
195 fi
196 AC_SUBST([WithGhc])
197
198 dnl ** Without optimization some INLINE trickery fails for GHCi
199 SRC_CC_OPTS="-O"
200
201 dnl--------------------------------------------------------------------
202 dnl * Choose host(/target/build) platform
203 dnl--------------------------------------------------------------------
204 dnl If we aren't explicitly told what values to use with configure flags,
205 dnl we ask the bootstrapping compiler what platform it is for
206
207 if test "${WithGhc}" != ""
208 then
209         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
210         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
211         if test "$bootstrap_host" != "$bootstrap_target"
212         then
213                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
214         fi
215 fi
216
217 # We have to run these unconditionally, but we may discard their
218 # results in the following code
219 AC_CANONICAL_BUILD
220 AC_CANONICAL_HOST
221 AC_CANONICAL_TARGET
222
223 FPTOOLS_SET_PLATFORM_VARS
224
225 # Verify that the installed (bootstrap) GHC is capable of generating
226 # code for the requested build platform.
227 if test "$BuildPlatform" != "$bootstrap_target"
228 then
229     echo "This GHC (${WithGhc}) does not generate code for the build platform"
230     echo "   GHC target platform    : $bootstrap_target"
231     echo "   Desired build platform : $BuildPlatform"
232     exit 1
233 fi
234
235 # Testing if we shall enable shared libs support on Solaris.
236 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
237
238 SOLARIS_BROKEN_SHLD=NO
239
240 case $host in
241      i386-*-solaris2)
242      # here we go with the test
243      MINOR=`uname -r|cut -d '.' -f 2-`
244      if test "$MINOR" -lt "11"; then
245          SOLARIS_BROKEN_SHLD=YES
246      fi
247      ;;
248 esac
249
250 AC_SUBST(SOLARIS_BROKEN_SHLD)
251
252 dnl ** Do an unregisterised build?
253 dnl --------------------------------------------------------------
254 case "$TargetArch" in
255     i386|x86_64|powerpc|powerpc64|powerpc64le|arm|aarch64)
256         UnregisterisedDefault=NO
257         ;;
258     *)
259         UnregisterisedDefault=YES
260         ;;
261 esac
262 AC_ARG_ENABLE(unregisterised,
263 [AC_HELP_STRING([--enable-unregisterised],
264 [Build an unregisterised compiler (enabled by default on platforms without registerised support) [default="$UnregisterisedDefault"]])],
265 [ if test x"$enableval" = x"yes"; then
266         Unregisterised=YES
267   else
268         Unregisterised=NO
269   fi
270 ],
271 [Unregisterised="$UnregisterisedDefault"]
272 )
273 AC_SUBST(Unregisterised)
274
275 dnl ** Does target have runtime linker support?
276 dnl --------------------------------------------------------------
277 case "$target" in
278     powerpc64-*|powerpc64le-*|powerpc-ibm-aix*)
279         HaskellHaveRTSLinker=NO
280         ;;
281     *)
282         HaskellHaveRTSLinker=YES
283         ;;
284 esac
285 AC_SUBST(HaskellHaveRTSLinker)
286
287 # Requires FPTOOLS_SET_PLATFORM_VARS to be run first.
288 FP_FIND_ROOT
289
290 fail() {
291     echo >&2
292     echo "$1" >&2
293     exit 1
294 }
295
296
297 if test "$HostOS" = "mingw32"
298 then
299     # Find the mingw-w64 7z file to extract.
300     # NB. If you update the tarballs to a new version of gcc, don't
301     # forget to tweak the paths in driver/gcc/gcc.c.
302     if test "$HostArch" = "i386"
303     then
304         mingw_arch="i686"
305         tarball_dest_dir="mingw-w64/x86"
306         tarball_mingw_dir="mingw32"
307     else
308         mingw_arch="x86_64"
309         tarball_dest_dir="mingw-w64/x86_64"
310         tarball_mingw_dir="mingw64"
311     fi
312 fi
313
314 set_up_tarballs() {
315     AC_MSG_NOTICE([Checking for Windows toolchain tarballs...])
316     local action
317     if test "$TarballsAutodownload" = "NO"
318     then
319         action="verify"
320     else
321         action="download"
322     fi
323     mk/get-win32-tarballs.sh $action $HostArch > missing-win32-tarballs
324     case $? in
325         0)
326            rm missing-win32-tarballs
327            ;;
328         2)
329            echo
330            echo "Error:"
331            echo "Needed msys2 tarballs are missing. You have a few options to get them,"
332            echo
333            echo "  * run configure with the --enable-tarballs-autodownload option"
334            echo
335            echo "  * run mk/get-win32-tarballs.sh download ${HostArch}"
336            echo
337            echo "  * manually download the files listed in ./missing-win32-tarballs and place"
338            echo "    them in the ghc-tarballs directory."
339            echo
340            exit 1
341            ;;
342         *)
343            echo
344            echo "Error fetching msys2 tarballs; see errors above."
345            exit 1
346            ;;
347     esac
348
349     # Extract all the tarballs in one go
350     if ! test -d inplace/mingw
351     then
352         AC_MSG_NOTICE([Extracting Windows toolchain from archives (may take a while)...])
353         rm -rf inplace/mingw
354         local base_dir="../ghc-tarballs/${tarball_dest_dir}"
355         ( cd inplace &&
356         find "${base_dir}" -name "*.tar.xz" -exec tar xfJ {} \; &&
357         rm ".MTREE" &&
358         rm ".PKGINFO" &&
359         cd .. ) || fail "Error: Could not extract Windows toolchains."
360
361         mv "inplace/${tarball_mingw_dir}" inplace/mingw &&
362         touch inplace/mingw
363
364         # NB. Now since the GCC is hardcoded to use /mingw32 we need to
365         # make a wrapper around it to give it the proper paths
366         mv inplace/mingw/bin/gcc.exe inplace/mingw/bin/realgcc.exe
367         PATH=`pwd`/inplace/mingw/bin:$PATH
368         inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
369
370         AC_MSG_NOTICE([In-tree MingW-w64 tree created])
371     fi
372 }
373
374 if test "$HostOS" = "mingw32" -a "$EnableDistroToolchain" = "NO"
375 then
376     test -d inplace || mkdir inplace
377
378     # NB. Download and extract the MingW-w64 distribution if required
379     set_up_tarballs
380
381     mingwbin="$hardtop/inplace/mingw/bin/"
382     CC="${mingwbin}gcc.exe"
383     LD="${mingwbin}ld.exe"
384     NM="${mingwbin}nm.exe"
385     RANLIB="${mingwbin}ranlib.exe"
386     OBJDUMP="${mingwbin}objdump.exe"
387     fp_prog_ar="${mingwbin}ar.exe"
388
389     AC_PATH_PROG([Genlib],[genlib])
390
391     # NB. Download the perl binaries if required
392     if ! test -d inplace/perl ||
393          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
394     then
395         AC_MSG_NOTICE([Making in-tree perl tree])
396         rm -rf inplace/perl
397         mkdir inplace/perl
398         (
399             cd inplace/perl &&
400             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
401         )
402         AC_MSG_NOTICE([In-tree perl tree created])
403     fi
404 fi
405
406 # We don't want to bundle a MinGW-w64 toolchain
407 # So we have to find these individual tools.
408 if test "$EnableDistroToolchain" = "YES"
409 then
410     # Ideally should use AC_CHECK_TARGET_TOOL but our triples
411     # are screwed up. Configure doesn't think they're ever equal and
412     # so never tried without the prefix.
413     AC_PATH_PROG([CC],[gcc], [clang])
414     AC_PATH_PROG([NM],[nm])
415     AC_PATH_PROG([AR],[ar])
416     AC_PATH_PROG([RANLIB],[ranlib])
417     AC_PATH_PROG([OBJDUMP],[objdump])
418     AC_PATH_PROG([DllWrap],[dllwrap])
419     AC_PATH_PROG([Windres],[windres])
420     AC_PATH_PROG([Genlib],[genlib])
421 fi
422
423 DllWrapCmd="$DllWrap"
424 WindresCmd="$Windres"
425
426 HAVE_GENLIB=False
427 if test "$HostOS" = "mingw32"
428 then
429     if test "$Genlib" != ""; then
430         GenlibCmd="$(cygpath -m $Genlib)"
431         HAVE_GENLIB=True
432     fi
433 fi
434
435 AC_SUBST([DllWrapCmd])
436 AC_SUBST([WindresCmd])
437 AC_SUBST([GenlibCmd])
438 AC_SUBST([HAVE_GENLIB])
439
440 FP_ICONV
441 FP_GMP
442 FP_CURSES
443
444 XCODE_VERSION()
445
446
447 dnl ** Building a cross compiler?
448 dnl --------------------------------------------------------------
449 CrossCompiling=NO
450 # If 'host' and 'target' differ, then this means we are building a cross-compiler.
451 if test "$TargetPlatform" != "$HostPlatform" ; then
452     CrossCompiling=YES
453     cross_compiling=yes   # This tells configure that it can accept just 'target',
454                           # otherwise you get
455                           #   configure: error: cannot run C compiled programs.
456                           #   If you meant to cross compile, use `--host'.
457 fi
458 if test "$BuildPlatform" != "$HostPlatform" ; then
459    AC_MSG_ERROR([
460 You've selected:
461
462   BUILD:  $BuildPlatform   (the architecture we're building on)
463   HOST:   $HostPlatform    (the architecture the compiler we're building will execute on)
464   TARGET: $TargetPlatform  (the architecture the compiler we're building will produce code for)
465
466 BUILD must equal HOST; that is, we do not support building GHC itself
467 with a cross-compiler.  To cross-compile GHC itself, set TARGET: stage
468 1 will be a cross-compiler, and stage 2 will be the cross-compiled
469 GHC.
470 ])
471 fi
472 # Despite its similarity in name to TargetPlatform, TargetPlatformFull is used
473 # in calls to subproject configure scripts and thus must be set to the autoconf
474 # triple, not the normalized GHC triple that TargetPlatform is set to.
475 #
476 # We use the non-canonicalized triple, target_alias, here since the subproject
477 # configure scripts will use this triple to construct the names of the toolchain
478 # executables. If we instead passed down the triple produced by
479 # AC_CANONICAL_TARGET then it may look for the target toolchain under the wrong
480 # name (this is a known problem in the case of the Android NDK, which has
481 # slightly odd triples).
482 #
483 # It may be better to just do away with the GHC triples altogether. This would
484 # all be taken care of for us if we configured the subprojects using
485 # AC_CONFIG_DIR, but unfortunately Cabal needs to be the one to do the
486 # configuration.
487 #
488 # We also use non-canonicalized triple when install stage1 crosscompiler
489 if test -z "${target_alias}"
490 then
491   # --target wasn't given; use result from AC_CANONICAL_TARGET
492   TargetPlatformFull="${target}"
493 else
494   TargetPlatformFull="${target_alias}"
495 fi
496 if test "$CrossCompiling" = "YES"
497 then
498   # Use value passed by user from --target=
499   CrossCompilePrefix="${TargetPlatformFull}-"
500 else
501   CrossCompilePrefix=""
502 fi
503 AC_SUBST(CrossCompiling)
504 AC_SUBST(CrossCompilePrefix)
505 AC_SUBST(TargetPlatformFull)
506 AC_SUBST(EnableDistroToolchain)
507
508 dnl ** Which gcc to use?
509 dnl --------------------------------------------------------------
510
511 AC_ARG_WITH([gcc],
512         AS_HELP_STRING([--with-gcc=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
513         AC_MSG_ERROR([--with-gcc=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
514
515 AC_ARG_WITH([clang],
516         AS_HELP_STRING([--with-clang=ARG], [Use ARG as the path to gcc (obsolete, use CC=ARG instead) [default=autodetect]]),
517         AC_MSG_ERROR([--with-clang=$withval is obsolete (use './configure CC=$withval' or 'CC=$withval ./configure' instead)]))
518
519 dnl detect compiler (prefer gcc over clang) and set $CC (unless CC already set),
520 dnl later CC is copied to CC_STAGE{1,2,3}
521 AC_PROG_CC([gcc clang])
522
523 MAYBE_OVERRIDE_STAGE0([ar],[AR_STAGE0])
524
525 dnl make extensions visible to allow feature-tests to detect them lateron
526 AC_USE_SYSTEM_EXTENSIONS
527
528 dnl ** figure out how to invoke the C preprocessor (i.e. `gcc -E`)
529 AC_PROG_CPP
530
531 # --with-hs-cpp/--with-hs-cpp-flags
532 FP_CPP_CMD_WITH_ARGS(HaskellCPPCmd, HaskellCPPArgs)
533 AC_SUBST([HaskellCPPCmd])
534 AC_SUBST([HaskellCPPArgs])
535
536 FP_SET_CFLAGS_C99([CC],[CFLAGS],[CPPFLAGS])
537 FP_SET_CFLAGS_C99([CC_STAGE0],[CONF_CC_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
538 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
539 FP_SET_CFLAGS_C99([CC],[CONF_CC_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
540
541 dnl ** Which ld to use
542 dnl --------------------------------------------------------------
543 FIND_LD([$target],[GccUseLdOpt])
544 CONF_GCC_LINKER_OPTS_STAGE1="$CONF_GCC_LINKER_OPTS_STAGE1 $GccUseLdOpt"
545 CONF_GCC_LINKER_OPTS_STAGE2="$CONF_GCC_LINKER_OPTS_STAGE2 $GccUseLdOpt"
546 LdCmd="$LD"
547 CFLAGS="$CFLAGS $GccUseLdOpt"
548 AC_SUBST([LdCmd])
549
550 FP_PROG_LD_IS_GNU
551 FP_PROG_LD_BUILD_ID
552 FP_PROG_LD_NO_COMPACT_UNWIND
553 FP_PROG_LD_FILELIST
554
555 dnl ** Which nm to use?
556 dnl --------------------------------------------------------------
557 if test "$HostOS" != "mingw32"; then
558     AC_CHECK_TARGET_TOOL([NM], [nm])
559     if test "$NM" = ":"; then
560         AC_MSG_ERROR([cannot find nm in your PATH])
561     fi
562 fi
563 NmCmd="$NM"
564 AC_SUBST([NmCmd])
565
566 if test "$TargetOS_CPP" = "darwin"
567 then
568     AC_MSG_CHECKING(whether nm program is broken)
569     # Some versions of XCode ship a broken version of `nm`. Detect and work
570     # around this issue. See : https://ghc.haskell.org/trac/ghc/ticket/11744
571     nmver=$(${NM} --version | grep version | sed 's/ //g')
572     case "$nmver" in
573         LLVMversion7.3.0|LLVMversion7.3.1)
574             AC_MSG_RESULT(yes)
575             echo "The detected nm program is broken."
576             echo
577             echo "See: https://ghc.haskell.org/trac/ghc/ticket/11744"
578             echo
579             echo "Try re-running configure with:"
580             echo
581             echo '   NM=$(xcrun --find nm-classic) ./configure'
582             echo
583             exit 1
584             ;;
585         *)
586             AC_MSG_RESULT(no)
587             ;;
588         esac
589 fi
590
591 dnl ** Which objdump to use?
592 dnl --------------------------------------------------------------
593 dnl Note: we may not have objdump on OS X, and we only need it on
594 dnl Windows (for DLL checks), OpenBSD, and AIX
595 case $HostOS_CPP in
596   cygwin32|mingw32|openbsd|aix)
597     AC_CHECK_TARGET_TOOL([OBJDUMP], [objdump])
598     ;;
599 esac
600
601 ObjdumpCmd="$OBJDUMP"
602 AC_SUBST([ObjdumpCmd])
603
604 dnl ** Which ranlib to use?
605 dnl --------------------------------------------------------------
606 AC_PROG_RANLIB
607 if test "$RANLIB" = ":"; then
608     AC_MSG_ERROR([cannot find ranlib in your PATH])
609 fi
610 RanlibCmd="$RANLIB"
611 AC_SUBST([RanlibCmd])
612
613 dnl ** which strip to use?
614 dnl --------------------------------------------------------------
615 AC_CHECK_TARGET_TOOL([STRIP], [strip])
616 StripCmd="$STRIP"
617 AC_SUBST([StripCmd])
618
619
620 dnl ** which libtool to use?
621 dnl --------------------------------------------------------------
622 # The host normalization on Windows breaks autoconf, it no longer
623 # thinks that target == host so it never checks the unqualified
624 # tools for Windows. See #14274.
625 if test "$HostOS" = "mingw32"
626 then
627     AC_PATH_PROG([LIBTOOL],[libtool])
628     LibtoolCmd="$(cygpath -m $LIBTOOL)"
629 else
630     AC_CHECK_TARGET_TOOL([LIBTOOL], [libtool])
631     LibtoolCmd="$LIBTOOL"
632 fi
633 AC_SUBST([LibtoolCmd])
634
635 # Here is where we re-target which specific version of the LLVM
636 # tools we are looking for. In the past, GHC supported a number of
637 # versions of LLVM simultaneously, but that stopped working around
638 # 3.5/3.6 release of LLVM.
639 LlvmVersion=5.0
640 AC_SUBST([LlvmVersion])
641 sUPPORTED_LLVM_VERSION=$(echo \($LlvmVersion\) | sed 's/\./,/')
642 AC_DEFINE_UNQUOTED([sUPPORTED_LLVM_VERSION], ${sUPPORTED_LLVM_VERSION}, [The supported LLVM version number])
643
644 dnl ** Which LLVM clang to use?
645 dnl --------------------------------------------------------------
646 AC_CHECK_TARGET_TOOL([CLANG], [clang])
647 ClangCmd="$CLANG"
648 AC_SUBST([ClangCmd])
649
650 dnl ** Which LLVM llc to use?
651 dnl --------------------------------------------------------------
652 FIND_LLVM_PROG([LLC], [llc], [$LlvmVersion])
653 LlcCmd="$LLC"
654 AC_SUBST([LlcCmd])
655
656 dnl ** Which LLVM opt to use?
657 dnl --------------------------------------------------------------
658 FIND_LLVM_PROG([OPT], [opt], [$LlvmVersion])
659 OptCmd="$OPT"
660 AC_SUBST([OptCmd])
661
662 dnl --------------------------------------------------------------
663 dnl End of configure script option section
664 dnl --------------------------------------------------------------
665
666
667 dnl --------------------------------------------------------------
668 dnl ** Can the unix package be built?
669 dnl --------------------------------------------------------------
670
671 if test "$TargetOS" = "mingw32"
672 then
673     GhcLibsWithUnix=NO
674 else
675     GhcLibsWithUnix=YES
676 fi
677 AC_SUBST([GhcLibsWithUnix])
678
679 dnl ** does #! work?
680 AC_SYS_INTERPRETER()
681
682 # Check for split-objs
683 SplitObjsBroken=NO
684 dnl ** look for `perl'
685 case $HostOS_CPP in
686 cygwin32|mingw32)
687   if test "$EnableDistroToolchain" = "NO"; then
688     PerlCmd=$hardtop/inplace/perl/perl
689   else
690     AC_PATH_PROG([PerlCmd],[perl])
691   fi
692   ;;
693 *)
694     AC_PATH_PROG([PerlCmd],[perl])
695     if test -z "$PerlCmd"
696     then
697         AC_MSG_WARN([No Perl on PATH, disabling split object support])
698         SplitObjsBroken=YES
699     else
700         FPTOOLS_CHECK_PERL_VERSION
701     fi
702     ;;
703 esac
704 AC_SUBST([SplitObjsBroken])
705
706 dnl ** look for GCC and find out which version
707 dnl     Figure out which C compiler to use.  Gcc is preferred.
708 dnl     If gcc, make sure it's at least 3.0
709 dnl
710 FP_GCC_VERSION
711
712 dnl ** See whether gcc supports -no-pie
713 FP_GCC_SUPPORTS_NO_PIE
714
715 dnl ** Used to determine how to compile ghc-prim's atomics.c, used by
716 dnl    unregisterised, Sparc, and PPC backends.
717 FP_GCC_SUPPORTS__ATOMICS
718 AC_DEFINE([HAVE_C11_ATOMICS], [$CONF_GCC_SUPPORTS__ATOMICS], [Does GCC support __atomic primitives?])
719
720 FP_GCC_EXTRA_FLAGS
721
722 dnl ** look to see if we have a C compiler using an llvm back end.
723 dnl
724 FP_CC_LLVM_BACKEND
725
726 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
727 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
728 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
729 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
730 # Stage 3 won't be supported by cross-compilation
731
732 # See rules/distdir-way-opts.mk for details.
733 # Flags passed to the C compiler
734 AC_SUBST(CONF_CC_OPTS_STAGE0)
735 AC_SUBST(CONF_CC_OPTS_STAGE1)
736 AC_SUBST(CONF_CC_OPTS_STAGE2)
737 # Flags passed to the C compiler when we ask it to link
738 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
739 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
740 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
741 # Flags passed to the linker when we ask it to link
742 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
743 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
744 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
745 # Flags passed to the C preprocessor
746 AC_SUBST(CONF_CPP_OPTS_STAGE0)
747 AC_SUBST(CONF_CPP_OPTS_STAGE1)
748 AC_SUBST(CONF_CPP_OPTS_STAGE2)
749 # Flags passed to the Haskell compiler
750 AC_SUBST(CONF_HC_OPTS_STAGE0)
751 AC_SUBST(CONF_HC_OPTS_STAGE1)
752 AC_SUBST(CONF_HC_OPTS_STAGE2)
753
754 dnl ** Set up the variables for the platform in the settings file.
755 dnl May need to use gcc to find platform details.
756 dnl --------------------------------------------------------------
757 FPTOOLS_SET_HASKELL_PLATFORM_VARS
758
759 dnl ** figure out how to do context diffs
760 FP_PROG_CONTEXT_DIFF
761
762 dnl Let's make sure install-sh is executable here.  If we got it from
763 dnl a darcs repo, it might not be (see bug #978).
764 chmod +x install-sh
765 dnl ** figure out how to do a BSD-ish install
766 AC_PROG_INSTALL
767
768 dnl ** how to invoke `ar' and `ranlib'
769 FP_PROG_AR_SUPPORTS_ATFILE
770 FP_PROG_AR_NEEDS_RANLIB
771
772 dnl ** Check to see whether ln -s works
773 AC_PROG_LN_S
774
775 FP_SETTINGS
776
777 dnl ** Find the path to sed
778 AC_PATH_PROGS(SedCmd,gsed sed,sed)
779
780
781 dnl ** check for time command
782 AC_PATH_PROG(TimeCmd,time)
783
784 dnl ** check for tar
785 dnl   if GNU tar is named gtar, look for it first.
786 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
787
788 dnl ** check for compressors
789 AC_PATH_PROGS(Bzip2Cmd,bzip2, bzip2)
790 AC_PATH_PROGS(GzipCmd,gzip, gzip)
791 AC_PATH_PROGS(XzCmd,pxz xz, xz)
792
793 dnl ** check for patch
794 dnl if GNU patch is named gpatch, look for it first
795 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
796
797 dnl ** check for dtrace (currently only implemented for Mac OS X)
798 HaveDtrace=NO
799 AC_PATH_PROG(DtraceCmd,dtrace)
800 if test -n "$DtraceCmd"; then
801   if test "x$TargetOS_CPP-$TargetVendor_CPP" = "xdarwin-apple" \
802                 -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xfreebsd-portbld" \
803                 -o "x$TargetOS_CPP-$TargetVendor_CPP" = "xsolaris2-unknown"; then
804     HaveDtrace=YES
805   fi
806 fi
807 AC_SUBST(HaveDtrace)
808
809 AC_PATH_PROG(HSCOLOUR,HsColour)
810 # HsColour is passed to Cabal, so we need a native path
811 if test "$HostOS"      = "mingw32" && \
812    test "${OSTYPE}"   != "msys"    && \
813    test "${HSCOLOUR}" != ""
814 then
815     # Canonicalise to <drive>:/path/to/gcc
816     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
817 fi
818
819 dnl ** check for Sphinx toolchain
820 AC_PATH_PROG(SPHINXBUILD,sphinx-build)
821 AC_CACHE_CHECK([for version of sphinx-build], fp_cv_sphinx_version,
822 changequote(, )dnl
823 [if test -n "$SPHINXBUILD"; then
824   fp_cv_sphinx_version=`"$SPHINXBUILD" --version 2>&1 | sed 's/Sphinx\( (sphinx-build)\)\? v\?\([0-9]\.[0-9]\.[0-9]\)/\2/' | head -n1`;
825 fi;
826 changequote([, ])dnl
827 ])
828 FP_COMPARE_VERSIONS([$fp_cv_sphinx_version],-lt,1.0.0,
829     [AC_MSG_WARN([Sphinx version 1.0.0 or later is required to build documentation]); SPHINXBUILD=;])
830
831 dnl ** check for xelatex
832 AC_PATH_PROG(XELATEX,xelatex)
833
834 dnl ** check for ghc-pkg command
835 FP_PROG_GHC_PKG
836
837 dnl ** check for installed happy binary + version
838 FPTOOLS_HAPPY
839
840 dnl ** check for installed alex binary + version
841 FPTOOLS_ALEX
842
843 dnl --------------------------------------------------
844 dnl ### program checking section ends here ###
845 dnl --------------------------------------------------
846
847 dnl --------------------------------------------------
848 dnl * Platform header file and syscall feature tests
849 dnl ### checking the state of the local header files and syscalls ###
850
851 dnl ** check for full ANSI header (.h) files
852 AC_HEADER_STDC
853
854 dnl ** Enable large file support.  NB. do this before testing the type of
855 dnl    off_t, because it will affect the result of that test.
856 AC_SYS_LARGEFILE
857
858 dnl ** check for specific header (.h) files that we are interested in
859 AC_CHECK_HEADERS([ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/param.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timerfd.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
860
861 dnl sys/cpuset.h needs sys/param.h to be included first on FreeBSD 9.1; #7708
862 AC_CHECK_HEADERS([sys/cpuset.h], [], [],
863 [[#if HAVE_SYS_PARAM_H
864 # include <sys/param.h>
865 #endif
866 ]])
867
868 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
869 AC_HEADER_TIME
870
871 dnl ** do we have long longs?
872 AC_CHECK_TYPES([long long])
873
874 dnl ** what are the sizes of various types
875 FP_CHECK_SIZEOF_AND_ALIGNMENT(char)
876 FP_CHECK_SIZEOF_AND_ALIGNMENT(double)
877 FP_CHECK_SIZEOF_AND_ALIGNMENT(float)
878 FP_CHECK_SIZEOF_AND_ALIGNMENT(int)
879 FP_CHECK_SIZEOF_AND_ALIGNMENT(long)
880 if test "$ac_cv_type_long_long" = yes; then
881 FP_CHECK_SIZEOF_AND_ALIGNMENT(long long)
882 fi
883 FP_CHECK_SIZEOF_AND_ALIGNMENT(short)
884 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned char)
885 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned int)
886 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long)
887 if test "$ac_cv_type_long_long" = yes; then
888 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned long long)
889 fi
890 FP_CHECK_SIZEOF_AND_ALIGNMENT(unsigned short)
891 FP_CHECK_SIZEOF_AND_ALIGNMENT(void *)
892
893 FP_CHECK_SIZEOF_AND_ALIGNMENT(int8_t)
894 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint8_t)
895 FP_CHECK_SIZEOF_AND_ALIGNMENT(int16_t)
896 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint16_t)
897 FP_CHECK_SIZEOF_AND_ALIGNMENT(int32_t)
898 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint32_t)
899 FP_CHECK_SIZEOF_AND_ALIGNMENT(int64_t)
900 FP_CHECK_SIZEOF_AND_ALIGNMENT(uint64_t)
901
902
903 dnl for use in settings.in
904 TargetWordSize=$ac_cv_sizeof_void_p
905 if test "x$TargetWordSize" == 8; then
906   AC_SUBST([Cabal64bit],[True])
907 else
908   AC_SUBST([Cabal64bit],[False])
909 fi
910 AC_SUBST(TargetWordSize)
911 FP_CHECK_FUNC([WinExec],
912   [@%:@include <windows.h>], [WinExec("",0)])
913
914 FP_CHECK_FUNC([GetModuleFileName],
915   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
916
917 dnl ** check for more functions
918 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
919 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
920
921 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
922 dnl ** _POSIX_C_SOURCE is defined
923 AC_CHECK_DECLS([ctime_r], , ,
924 [#define _POSIX_SOURCE 1
925 #define _POSIX_C_SOURCE 199506L
926 #include <time.h>])
927
928 dnl ** check for mingwex library
929 AC_CHECK_LIB(
930   [mingwex],
931   [closedir],
932   [AC_SUBST([HaveLibMingwEx],[YES])] [AC_SUBST([CabalMingwex],[True])],
933   [AC_SUBST([HaveLibMingwEx],[NO])] [AC_SUBST([CabalMingwex],[False])])
934
935 if test $HaveLibMingwEx = YES ; then
936   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
937 fi
938
939 dnl ** check for math library
940 dnl    Keep that check as early as possible.
941 dnl    as we need to know whether we need libm
942 dnl    for math functions or not
943 dnl    (see http://ghc.haskell.org/trac/ghc/ticket/3730)
944 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
945 if test $HaveLibM = YES
946 then
947   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
948   AC_SUBST([CabalHaveLibm],[True])
949 else
950   AC_SUBST([CabalHaveLibm],[False])
951 fi
952
953 FP_BFD_SUPPORT
954
955 dnl ################################################################
956 dnl Check for libraries
957 dnl ################################################################
958
959 # system libffi
960
961 AC_ARG_WITH([system-libffi],
962 [AC_HELP_STRING([--with-system-libffi],
963   [Use system provided libffi for RTS [default=no]])
964 ])
965
966 AS_IF([test "x$with_system_libffi" = "xyes"],
967   [UseSystemLibFFI="YES"], [UseSystemLibFFI="NO"]
968 )
969
970
971 AC_SUBST(UseSystemLibFFI)
972
973 AC_ARG_WITH([ffi-includes],
974 [AC_HELP_STRING([--with-ffi-includes=ARG],
975   [Find includes for libffi in ARG [default=system default]])
976 ],
977 [
978  if test "x$UseSystemLibFFI" != "xYES"; then
979     AC_MSG_WARN([--with-ffi-includes will be ignored, --with-system-libffi not set])
980  else
981     FFIIncludeDir="$withval"
982     LIBFFI_CFLAGS="-I$withval"
983  fi
984 ])
985
986 AC_SUBST(FFIIncludeDir)
987
988 AC_ARG_WITH([ffi-libraries],
989 [AC_HELP_STRING([--with-ffi-libraries=ARG],
990   [Find libffi in ARG [default=system default]])
991 ],
992 [
993  if test "x$UseSystemLibFFI" != "xYES"; then
994     AC_MSG_WARN([--with-ffi-libraries will be ignored, --with-system-libffi not set])
995  else
996     FFILibDir="$withval" LIBFFI_LDFLAGS="-L$withval"
997  fi
998 ])
999
1000 AC_SUBST(FFILibDir)
1001
1002 AC_SUBST([CabalHaveLibffi],[False])
1003 AS_IF([test "$UseSystemLibFFI" = "YES"], [
1004  CFLAGS2="$CFLAGS"
1005  CFLAGS="$LIBFFI_CFLAGS $CFLAGS"
1006  LDFLAGS2="$LDFLAGS"
1007  LDFLAGS="$LIBFFI_LDFLAGS $LDFLAGS"
1008  if test "$HostOS" = "openbsd";
1009  then
1010    # OpenBSD's libffi is not directly linked to the libpthread but
1011    # still requires pthread functionality. This means that any client
1012    # binary which links with libffi also needs to link with
1013    # libpthread. If it does not, then linking fails with unresolved
1014    # symbols.
1015    LDFLAGS="$LDFLAGS -lpthread"
1016  fi
1017  AC_CHECK_LIB(ffi, ffi_call,
1018   [AC_CHECK_HEADERS([ffi.h], [break], [])
1019    AC_DEFINE([HAVE_LIBFFI], [1], [Define to 1 if you have libffi.])]
1020    AC_SUBST([CabalHaveLibffi],[True]),
1021   [AC_MSG_ERROR([Cannot find system libffi])])
1022  CFLAGS="$CFLAGS2"
1023  LDFLAGS="$LDFLAGS2"
1024 ])
1025
1026 dnl ** check whether we need -ldl to get dlopen()
1027 AC_CHECK_LIB([dl], [dlopen])
1028 AC_CHECK_LIB([dl], [dlopen], [AC_SUBST([CabalHaveLibdl], [True])], [AC_SUBST([CabalHaveLibdl], [False])])
1029
1030 dnl --------------------------------------------------
1031 dnl * Miscellaneous feature tests
1032 dnl --------------------------------------------------
1033
1034 dnl ** can we get alloca?
1035 AC_FUNC_ALLOCA
1036
1037 dnl ** working vfork?
1038 AC_FUNC_FORK
1039
1040 dnl ** determine whether or not const works
1041 AC_C_CONST
1042
1043 dnl ** are we big endian?
1044 AC_C_BIGENDIAN
1045 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
1046
1047 dnl ** check for leading underscores in symbol names
1048 FP_LEADING_UNDERSCORE
1049
1050 FP_VISIBILITY_HIDDEN
1051
1052 dnl ** check for librt
1053 AC_CHECK_LIB([rt], [clock_gettime])
1054 AC_CHECK_LIB([rt], [clock_gettime], [AC_SUBST([CabalHaveLibrt], [True])], [AC_SUBST([CabalHaveLibrt], [False])])
1055 AC_CHECK_FUNCS(clock_gettime timer_settime)
1056 FP_CHECK_TIMER_CREATE
1057
1058 dnl ** check for Apple's "interesting" long double compatibility scheme
1059 AC_MSG_CHECKING(for printf\$LDBLStub)
1060 AC_TRY_LINK_FUNC(printf\$LDBLStub,
1061     [
1062         AC_MSG_RESULT(yes)
1063         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
1064             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
1065     ],
1066     [
1067         AC_MSG_RESULT(no)
1068         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
1069             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
1070     ])
1071
1072 dnl Some platforms (e.g. Android's Bionic) have pthreads support available
1073 dnl without linking against libpthread. Check whether -lpthread is necessary
1074 dnl to use pthreads.
1075 dnl
1076 dnl Note that it is important that this happens before we AC_CHECK_LIB(thread)
1077 AC_MSG_CHECKING(whether -lpthread is needed for pthreads)
1078 AC_CHECK_FUNC(pthread_create,
1079     [
1080         AC_MSG_RESULT(no)
1081         AC_SUBST([CabalNeedLibpthread],[False])
1082         need_lpthread=0
1083     ],
1084     [
1085         AC_CHECK_LIB(pthread, pthread_create,
1086             [
1087                 AC_MSG_RESULT(yes)
1088                 AC_SUBST([CabalNeedLibpthread],[True])
1089                 need_lpthread=1
1090             ],
1091             [
1092                 AC_SUBST([CabalNeedLibpthread],[False])
1093                 AC_MSG_RESULT([no pthreads support found.])
1094                 need_lpthread=0
1095             ])
1096     ])
1097 AC_DEFINE_UNQUOTED([NEED_PTHREAD_LIB], [$need_lpthread],
1098     [Define 1 if we need to link code using pthreads with -lpthread])
1099
1100 dnl ** pthread_setname_np is a recent addition to glibc, and OS X has
1101 dnl    a different single-argument version.
1102 AC_CHECK_LIB(pthread, pthread_setname_np)
1103 AC_MSG_CHECKING(for pthread_setname_np)
1104 AC_TRY_LINK(
1105 [
1106 #define _GNU_SOURCE
1107 #include <pthread.h>
1108 ],
1109 [pthread_setname_np(pthread_self(), "name");],
1110     AC_MSG_RESULT(yes)
1111     AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1],
1112       [Define to 1 if you have the glibc version of pthread_setname_np]),
1113     AC_MSG_RESULT(no)
1114 )
1115
1116 dnl ** check for eventfd which is needed by the I/O manager
1117 AC_CHECK_HEADERS([sys/eventfd.h])
1118 AC_CHECK_FUNCS([eventfd])
1119
1120 dnl ** Check for __thread support in the compiler
1121 AC_MSG_CHECKING(for __thread support)
1122 AC_COMPILE_IFELSE(
1123   [ AC_LANG_SOURCE([[__thread int tester = 0;]]) ],
1124   [
1125    AC_MSG_RESULT(yes)
1126    AC_DEFINE([CC_SUPPORTS_TLS],[1],[Define to 1 if __thread is supported])
1127   ],
1128   [
1129    AC_MSG_RESULT(no)
1130    AC_DEFINE([CC_SUPPORTS_TLS],[0],[Define to 1 if __thread is supported])
1131   ])
1132
1133 dnl large address space support (see includes/rts/storage/MBlock.h)
1134 dnl
1135 dnl Darwin has vm_allocate/vm_protect
1136 dnl Linux has mmap(MAP_NORESERVE)/madv(MADV_DONTNEED)
1137 dnl FreeBSD, Solaris and maybe other have MAP_NORESERVE/MADV_FREE
1138 dnl (They also have MADV_DONTNEED, but it means something else!)
1139 dnl
1140 dnl Windows has VirtualAlloc MEM_RESERVE/MEM_COMMIT, however
1141 dnl it counts page-table space as committed memory, and so quickly
1142 dnl runs out of paging file when we have multiple processes reserving
1143 dnl 1TB of address space, we get the following error:
1144 dnl    VirtualAlloc MEM_RESERVE 1099512676352 bytes failed: The paging file is too small for this operation to complete.
1145 dnl
1146
1147 AC_ARG_ENABLE(large-address-space,
1148     [AC_HELP_STRING([--enable-large-address-space],
1149         [Use a single large address space on 64 bit systems (enabled by default on 64 bit platforms)])],
1150     EnableLargeAddressSpace=$enableval,
1151     EnableLargeAddressSpace=yes
1152 )
1153
1154 use_large_address_space=no
1155 if test "$ac_cv_sizeof_void_p" -eq 8 ; then
1156     if test "x$EnableLargeAddressSpace" = "xyes" ; then
1157         if test "$ghc_host_os" = "darwin" ; then
1158             use_large_address_space=yes
1159         elif test "$ghc_host_os" = "openbsd" ; then
1160             # as of OpenBSD 5.8 (2015), OpenBSD does not support mmap with MAP_NORESERVE.
1161             # The flag MAP_NORESERVE is supported for source compatibility reasons,
1162             # but is completely ignored by OS mmap
1163             use_large_address_space=no
1164         else
1165             AC_CHECK_DECLS([MAP_NORESERVE, MADV_FREE, MADV_DONTNEED],[],[],
1166                 [
1167                 #include <unistd.h>
1168                 #include <sys/types.h>
1169                 #include <sys/mman.h>
1170                 #include <fcntl.h>
1171             ])
1172             if test "$ac_cv_have_decl_MAP_NORESERVE" = "yes" &&
1173                 test "$ac_cv_have_decl_MADV_FREE" = "yes" ||
1174                 test "$ac_cv_have_decl_MADV_DONTNEED" = "yes" ; then
1175                     use_large_address_space=yes
1176             fi
1177         fi
1178     fi
1179 fi
1180 if test "$use_large_address_space" = "yes" ; then
1181    AC_DEFINE([USE_LARGE_ADDRESS_SPACE], [1], [Enable single heap address space support])
1182 fi
1183
1184 dnl ** Use MMAP in the runtime linker?
1185 dnl --------------------------------------------------------------
1186
1187 case ${TargetOS} in
1188     linux|linux-android|freebsd|dragonfly|netbsd|openbsd|kfreebsdgnu|gnu|solaris2)
1189         RtsLinkerUseMmap=1
1190         ;;
1191     darwin|ios)
1192         # Don't use mmap on powerpc/darwin as the mmap there doesn't support
1193         # reallocating. Reallocating is needed to allocate jump islands just
1194         # after each object image. Jumps to these jump islands use relative
1195         # branches which are limited to offsets that can be represented in
1196         # 24-bits.
1197         if test "$TargetArch" != "powerpc" ; then
1198             RtsLinkerUseMmap=1
1199         else
1200             RtsLinkerUseMmap=0
1201         fi
1202         ;;
1203     *)
1204         # Windows (which doesn't have mmap) and everything else.
1205         RtsLinkerUseMmap=0
1206         ;;
1207     esac
1208
1209 AC_DEFINE_UNQUOTED([RTS_LINKER_USE_MMAP], [$RtsLinkerUseMmap],
1210                    [Use mmap in the runtime linker])
1211
1212 dnl ** Have libdw?
1213 dnl --------------------------------------------------------------
1214 UseLibdw=NO
1215 USE_LIBDW=0
1216 AC_ARG_ENABLE(dwarf-unwind,
1217     [AC_HELP_STRING([--enable-dwarf-unwind],
1218         [Enable DWARF unwinding support in the runtime system via elfutils' libdw [default=no]])],
1219     [AC_CHECK_LIB(dw, dwfl_attach_state, [UseLibdw=YES], [UseLibdw=NO])],
1220     [UseLibdw=NO]
1221 )
1222 AC_SUBST(UseLibdw)
1223 if test $UseLibdw = "YES" ; then
1224         USE_LIBDW=1
1225   AC_SUBST([CabalHaveLibdw],[True])
1226 else
1227   AC_SUBST([CabalHaveLibdw],[False])
1228 fi
1229 AC_DEFINE_UNQUOTED([USE_LIBDW], [$USE_LIBDW], [Set to 1 to use libdw])
1230
1231 dnl ** Have libnuma?
1232 dnl --------------------------------------------------------------
1233 HaveLibNuma=0
1234 AC_CHECK_HEADERS([numa.h numaif.h])
1235
1236 if test "$ac_cv_header_numa_h$ac_cv_header_numaif_h" = "yesyes" ; then
1237     AC_CHECK_LIB(numa, numa_available,HaveLibNuma=1)
1238 fi
1239 AC_DEFINE_UNQUOTED([HAVE_LIBNUMA], [$HaveLibNuma], [Define to 1 if you have libnuma])
1240
1241 dnl ** Documentation
1242 dnl --------------------------------------------------------------
1243 if test -n "$SPHINXBUILD"; then
1244     BUILD_MAN=YES
1245     BUILD_SPHINX_HTML=YES
1246     if test -n "$XELATEX"; then
1247         BUILD_SPHINX_PDF=YES
1248     else
1249         BUILD_SPHINX_PDF=NO
1250     fi
1251 else
1252     BUILD_MAN=NO
1253     BUILD_SPHINX_HTML=NO
1254     BUILD_SPHINX_PDF=NO
1255 fi
1256 AC_SUBST(BUILD_MAN)
1257 AC_SUBST(BUILD_SPHINX_HTML)
1258 AC_SUBST(BUILD_SPHINX_PDF)
1259
1260 LIBRARY_VERSION(base)
1261 LIBRARY_VERSION(Cabal, Cabal/Cabal)
1262 LIBRARY_VERSION(ghc-prim)
1263 LIBRARY_VERSION(ghc-compact)
1264 LIBRARY_ghc_VERSION="$ProjectVersion"
1265 AC_SUBST(LIBRARY_ghc_VERSION)
1266
1267 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
1268    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
1269 fi
1270
1271 # Create the configuration for the Hadrian build system if it is present
1272 if test -e hadrian/cfg/system.config.in; then
1273     AC_CONFIG_FILES([hadrian/cfg/system.config])
1274 fi
1275
1276 # We got caught by
1277 #     http://savannah.gnu.org/bugs/index.php?1516
1278 #     $(eval ...) inside conditionals causes errors
1279 # with make 3.80, so warn the user if it looks like they're about to
1280 # try to use it.
1281 # We would use "grep -q" here, but Solaris's grep doesn't support it.
1282 print_make_warning=""
1283 checkMake380() {
1284     make_ver=`$1 --version 2>&1 | head -1`
1285     if echo "$make_ver" | grep 'GNU Make 3\.80' > /dev/null
1286     then
1287         print_make_warning="true"
1288     fi
1289     if echo "$make_ver" | grep 'GNU Make' > /dev/null
1290     then
1291         MakeCmd=$1
1292         AC_SUBST(MakeCmd)
1293     fi
1294 }
1295
1296 checkMake380 make
1297 checkMake380 gmake
1298
1299 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk rts/rts.cabal compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal utils/gen-dll/gen-dll.cabal libraries/ghc-boot/ghc-boot.cabal libraries/ghc-boot-th/ghc-boot-th.cabal libraries/ghci/ghci.cabal settings docs/users_guide/ghc_config.py docs/index.html libraries/prologue.txt distrib/configure.ac])
1300 AC_OUTPUT
1301 [
1302 if test "$print_make_warning" = "true"; then
1303    echo
1304    echo "WARNING: It looks like \"$MakeCmd\" is GNU make 3.80."
1305    echo "This version cannot be used to build GHC."
1306    echo "Please use GNU make >= 3.81."
1307 fi
1308
1309 echo "
1310 ----------------------------------------------------------------------
1311 Configure completed successfully.
1312
1313    Building GHC version  : $ProjectVersion
1314           Git commit id  : $ProjectGitCommitId
1315
1316    Build platform        : $BuildPlatform
1317    Host platform         : $HostPlatform
1318    Target platform       : $TargetPlatform
1319 "
1320
1321 echo "\
1322    Bootstrapping using   : $WithGhc
1323       which is version   : $GhcVersion
1324 "
1325
1326 if test "x$CC_LLVM_BACKEND" = "x1"; then
1327     if test "x$CC_CLANG_BACKEND" = "x1"; then
1328         CompilerName="clang        "
1329     else
1330         CompilerName="llvm-gcc     "
1331     fi
1332 else
1333     CompilerName="gcc          "
1334 fi
1335
1336 echo "\
1337    Using (for bootstrapping) : $CC_STAGE0
1338    Using $CompilerName       : $CC
1339       which is version       : $GccVersion
1340    Building a cross compiler : $CrossCompiling
1341    Unregisterised            : $Unregisterised
1342    hs-cpp       : $HaskellCPPCmd
1343    hs-cpp-flags : $HaskellCPPArgs
1344    ar           : $ArCmd
1345    ld           : $LdCmd
1346    nm           : $NmCmd
1347    libtool      : $LibtoolCmd
1348    objdump      : $ObjdumpCmd
1349    ranlib       : $RanlibCmd
1350    windres      : $WindresCmd
1351    dllwrap      : $DllWrapCmd
1352    genlib       : $GenlibCmd
1353    Happy        : $HappyCmd ($HappyVersion)
1354    Alex         : $AlexCmd ($AlexVersion)
1355    Perl         : $PerlCmd
1356    sphinx-build : $SPHINXBUILD
1357    xelatex      : $XELATEX
1358
1359    Using LLVM tools
1360       clang : $ClangCmd
1361       llc   : $LlcCmd
1362       opt   : $OptCmd"
1363
1364 if test "$HSCOLOUR" = ""; then
1365 echo "
1366    HsColour was not found; documentation will not contain source links
1367 "
1368 else
1369 echo "\
1370    HsColour : $HSCOLOUR
1371 "
1372 fi
1373
1374 echo "\
1375    Tools to build Sphinx HTML documentation available: $BUILD_SPHINX_HTML
1376    Tools to build Sphinx PDF documentation available: $BUILD_SPHINX_PDF"
1377
1378 echo "----------------------------------------------------------------------
1379 "
1380
1381 echo "\
1382 For a standard build of GHC (fully optimised with profiling), type (g)make.
1383
1384 To make changes to the default build configuration, copy the file
1385 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1386
1387 For more information on how to configure your GHC build, see
1388    http://ghc.haskell.org/trac/ghc/wiki/Building
1389 "]