Refactor configure.ac's: Put XCODE_VERSION() in aclocal.m4
[ghc.git] / configure.ac
1 dnl == autoconf source for the Glasgow FP tools ==
2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
3 dnl  (or some such) to see the outline of this file)
4 dnl
5 #
6 # (c) The University of Glasgow 1994-2004
7 #
8 # Configure script template for GHC
9 #
10 # Process with 'autoreconf' to get a working configure script.
11 #
12 # For the generated configure script, do "./configure --help" to
13 # see what flags are available. (Better yet, read the documentation!)
14 #
15
16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.3], [glasgow-haskell-bugs@haskell.org], [ghc])
17
18 # Set this to YES for a released version, otherwise NO
19 : ${RELEASE=NO}
20
21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
22 # above.  If this is not a released version, then we will append the
23 # date to the version number (e.g. 6.7.20070204).  The date is
24 # constructed by finding the date of the most recent patch in the
25 # darcs repository.  If this is a source distribution (not a darcs
26 # checkout), then we ship a file 'VERSION' containing the full version
27 # when the source distribution was created.
28
29 if test ! -f mk/config.h.in; then
30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
31    exit 1
32 fi
33
34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
35
36 dnl ----------------------------------------------------------
37 dnl ** Find unixy sort and find commands, 
38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
39
40 dnl ** Find find command (for Win32's benefit)
41 FP_PROG_FIND
42
43 dnl ** Find sort command (for the benefit of Win32 environs)
44 FP_PROG_SORT
45
46 dnl ----------------------------------------------------------
47 FP_SETUP_PROJECT_VERSION
48
49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
50 AC_SUBST([release], [1])
51
52 # First off, a distrib sanity check..
53 AC_CONFIG_SRCDIR([mk/config.mk.in])
54
55 dnl * We require autoconf version 2.52
56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
58 AC_PREREQ([2.52])
59
60 # -------------------------------------------------------------------------
61 # Prepare to generate the following header files
62 #
63 #
64 AC_CONFIG_HEADER(mk/config.h)
65
66 # No, semi-sadly, we don't do `--srcdir'...
67 if test x"$srcdir" != 'x.' ; then
68     echo "This configuration does not support the \`--srcdir' option.."
69     exit 1
70 fi
71
72 dnl --------------------------------------------------------------
73 dnl * Project specific configuration options
74 dnl --------------------------------------------------------------
75 dnl What follows is a bunch of options that can either be configured
76 dnl through command line options to the configure script or by
77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
78 dnl use either is considered a Feature.
79
80 dnl ** What command to use to compile compiler sources ?
81 dnl --------------------------------------------------------------
82
83 AC_ARG_WITH([ghc],
84 [AC_HELP_STRING([--with-ghc=ARG],
85   [Use ARG as the path to GHC  [default=autodetect]])],
86   [WithGhc="$withval"],
87   [if test "$GHC" = ""; then
88     AC_PATH_PROG([GHC], [ghc])
89   fi
90   WithGhc="$GHC"])
91
92
93 dnl ** Tell the make system which OS we are using
94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something 
95 AC_SUBST(OSTYPE)
96
97 dnl ** Booting from .hc files?
98 dnl --------------------------------------------------------------
99 AC_ARG_ENABLE(hc-boot,
100 [AC_HELP_STRING([--enable-hc-boot],
101 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
102  (This option is mostly of interest to porters.) [default=no]])],
103 [ if test x"$enableval" = x"yes"; then
104         BootingFromHc=YES
105   else
106         BootingFromHc=NO
107   fi
108 ],
109 [BootingFromHc=NO]
110 )
111 AC_SUBST(BootingFromHc)
112
113 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
114 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
115                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
116         EnableBootstrapWithDevelSnaphost=YES,
117         EnableBootstrapWithDevelSnaphost=NO
118 )
119
120 if test "$WithGhc" != ""; then
121   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
122
123   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
124      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
125   fi
126
127   AC_SUBST(GhcVersion)dnl
128   AC_SUBST(GhcMajVersion)dnl
129   AC_SUBST(GhcMinVersion)dnl
130   AC_SUBST(GhcPatchLevel)dnl
131   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
132   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
133   if test $GhcCanonVersion -ge 613; then ghc_ge_613=YES; else ghc_ge_613=NO; fi
134   AC_SUBST(ghc_ge_613)dnl
135
136   BOOTSTRAPPING_GHC_INFO_FIELD([CC_STAGE0],[C compiler command],['$(CC)'])
137   BOOTSTRAPPING_GHC_INFO_FIELD([AR_STAGE0],[ar command],['$(AR)'])
138   BOOTSTRAPPING_GHC_INFO_FIELD([AR_OPTS_STAGE0],[ar flags],['$(AR_OPTS)'])
139   BOOTSTRAPPING_GHC_INFO_FIELD([ArSupportsAtFile_STAGE0],[ar supports at file],['$(ArSupportsAtFile)'])
140 fi
141
142 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
143 if test "$BootingFromHc" = "NO"; then
144   if test "$WithGhc" = ""; then
145      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
146   fi
147   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.12],
148     [AC_MSG_ERROR([GHC version 6.12 or later is required to compile GHC.])])dnl
149
150   if test `expr $GhcMinVersion % 2` = "1"; then
151      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
152         AC_MSG_ERROR([
153      $WithGhc is a development snapshot of GHC, version $GhcVersion.
154      Bootstrapping using this version of GHC is not supported, and may not
155      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
156      or --with-ghc to specify a different GHC to use.])
157      fi
158   fi
159 fi;
160
161 # GHC is passed to Cabal, so we need a native path
162 if test "${WithGhc}" != ""
163 then
164     ghc_host=`"${WithGhc}" +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
165
166     if test "$ghc_host" = "i386-unknown-mingw32"
167     then
168         if test "${OSTYPE}" = "msys"
169         then
170             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
171         else
172             # Canonicalise to <drive>:/path/to/ghc
173             WithGhc=`cygpath -m "${WithGhc}"`
174         fi
175         echo "GHC path canonicalised to: ${WithGhc}"
176     fi
177 fi
178 AC_SUBST([WithGhc])
179
180 dnl ** Without optimization some INLINE trickery fails for GHCi
181 SRC_CC_OPTS="-O"
182
183 FP_ICONV
184 FP_GMP
185
186 dnl--------------------------------------------------------------------
187 dnl * Choose host(/target/build) platform
188 dnl--------------------------------------------------------------------
189 dnl If we aren't explicitly told what values to use with configure flags,
190 dnl we ask the bootstrapping compiler what platform it is for
191
192 if test "${WithGhc}" != ""
193 then
194         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
195         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
196         if test "$bootstrap_host" != "$bootstrap_target"
197         then
198                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
199         fi
200 fi
201
202 # We have to run these unconditionally, but we may discard their
203 # results in the following code
204 AC_CANONICAL_BUILD
205 AC_CANONICAL_HOST
206 AC_CANONICAL_TARGET
207
208 FPTOOLS_SET_PLATFORM_VARS
209
210 # Testing if we shall enable shared libs support on Solaris.
211 # Anything older than SunOS 5.11 aka Solaris 11 (Express) is broken.
212
213 SOLARIS_BROKEN_SHLD=NO
214
215 case $host in
216      i386-*-solaris2)
217      # here we go with the test
218      MINOR=`uname -r|cut -d '.' -f 2-`
219      if test "$MINOR" -lt "11"; then
220         SOLARIS_BROKEN_SHLD=YES
221      fi
222      ;;
223 esac
224
225 checkArch() {
226     case $1 in
227     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
228         ;;
229     *)
230         echo "Unknown arch $1"
231         exit 1
232         ;;
233     esac
234 }
235
236 checkVendor() {
237     case $1 in
238     dec|unknown|hp|apple|next|sun|sgi|ibm)
239         ;;
240     *)
241         echo "Unknown vendor $1"
242         exit 1
243         ;;
244     esac
245 }
246
247 checkOS() {
248     case $1 in
249     linux|freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
250         ;;
251     *)
252         echo "Unknown OS '$1'"
253         exit 1
254         ;;
255     esac
256 }
257
258 BuildPlatform="$BuildArch-$BuildVendor-$BuildOS"
259 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
260 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
261 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
262 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
263
264 checkArch "$BuildArch"
265 checkVendor "$BuildVendor"
266 checkOS "$BuildOS"
267
268 HostPlatform="$HostArch-$HostVendor-$HostOS"
269 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
270 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
271 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
272 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
273
274 checkArch "$HostArch"
275 checkVendor "$HostVendor"
276 checkOS "$HostOS"
277
278 TargetPlatform="$TargetArch-$TargetVendor-$TargetOS"
279 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
280 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
281 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
282 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
283
284 checkArch "$TargetArch"
285 checkVendor "$TargetVendor"
286 checkOS "$TargetOS"
287
288 # Verify that the installed (bootstrap) GHC is capable of generating
289 # code for the requested build platform.
290 if test "$BootingFromHc" = "NO"
291 then
292     if test "$BuildPlatform" != "$bootstrap_target"
293     then
294         echo "This GHC (${WithGhc}) does not generate code for the build platform"
295         echo "   GHC target platform    : $bootstrap_target"
296         echo "   Desired build platform : $BuildPlatform"
297         exit 1
298     fi
299 fi
300
301 echo "GHC build  : $BuildPlatform"
302 echo "GHC host   : $HostPlatform"
303 echo "GHC target : $TargetPlatform"
304
305 AC_SUBST(BuildPlatform)
306 AC_SUBST(HostPlatform)
307 AC_SUBST(TargetPlatform)
308 AC_SUBST(HostPlatform_CPP)
309 AC_SUBST(BuildPlatform_CPP)
310 AC_SUBST(TargetPlatform_CPP)
311
312 AC_SUBST(HostArch_CPP)
313 AC_SUBST(BuildArch_CPP)
314 AC_SUBST(TargetArch_CPP)
315
316 AC_SUBST(HostOS_CPP)
317 AC_SUBST(BuildOS_CPP)
318 AC_SUBST(TargetOS_CPP)
319
320 AC_SUBST(HostVendor_CPP)
321 AC_SUBST(BuildVendor_CPP)
322 AC_SUBST(TargetVendor_CPP)
323
324 AC_SUBST(exeext)
325 AC_SUBST(soext)
326
327 AC_SUBST(SOLARIS_BROKEN_SHLD)
328
329 AC_ARG_WITH(hc,
330 [AC_HELP_STRING([--with-hc=ARG],
331         [Use ARG as the path to the compiler for compiling ordinary
332          Haskell code  (default= value of --with-ghc)])],
333 [WithHc="$withval"],
334 [WithHc=$WithGhc]
335 )
336 AC_SUBST(WithHc)
337
338 # This uses GHC, so put it after the "GHC is required" check above:
339 FP_INTREE_GHC_PWD
340 FP_FIND_ROOT
341
342 if test "$HostOS" = "mingw32"
343 then
344     test -d inplace || mkdir inplace
345
346     CC="$hardtop/inplace/mingw/bin/gcc.exe"
347     LD="$hardtop/inplace/mingw/bin/ld.exe"
348     NM="$hardtop/inplace/mingw/bin/nm.exe"
349     fp_prog_ar_raw="$hardtop/inplace/mingw/bin/ar.exe"
350
351     # NB. If you update the tarbballs to a new version of gcc, don't
352     # forget to tweak the paths in driver/gcc/gcc.c.
353     if ! test -d inplace/mingw ||
354          test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
355          test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
356          test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
357          test inplace/mingw -ot ghc-tarballs/mingw/libgcc*.tar.gz      ||
358          test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
359          test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
360          test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
361          test inplace/mingw -ot ghc-tarballs/mingw/libstdc*.tar.lzma   ||
362          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
363          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
364          test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
365     then
366         AC_MSG_NOTICE([Making in-tree mingw tree])
367         rm -rf inplace/mingw
368         mkdir inplace/mingw
369         (
370             cd inplace/mingw &&
371             tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
372             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
373             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
374             tar --lzma -xf ../../ghc-tarballs/mingw/libgcc*.tar.lzma    &&
375             tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
376             tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
377             tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
378             tar --lzma -xf ../../ghc-tarballs/mingw/libstdc*.tar.lzma   &&
379             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
380             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
381             tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
382             mv bin/gcc.exe bin/realgcc.exe
383         )
384         PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
385         if ! test -e inplace/mingw/bin/gcc.exe
386         then
387             AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
388         fi
389         AC_MSG_NOTICE([In-tree mingw tree created])
390     fi
391     if ! test -d inplace/perl ||
392          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
393     then
394         AC_MSG_NOTICE([Making in-tree perl tree])
395         rm -rf inplace/perl
396         mkdir inplace
397         mkdir inplace/perl
398         (
399             cd inplace/perl &&
400             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
401         )
402         AC_MSG_NOTICE([In-tree perl tree created])
403     fi
404 fi
405
406 XCODE_VERSION()
407
408 SplitObjsBroken=NO
409 if test "$TargetOS_CPP" = "darwin"
410 then
411     # Split objects is broken (#4013) with XCode < 3.2
412     if test "$XCodeVersion1" -lt 3
413     then
414         SplitObjsBroken=YES
415     else
416         if test "$XCodeVersion1" -eq 3
417         then
418             if test "$XCodeVersion2" -lt 2
419             then
420                 SplitObjsBroken=YES
421             fi
422         fi
423     fi
424 fi
425 AC_SUBST([SplitObjsBroken])
426
427 dnl ** Which gcc to use?
428 dnl --------------------------------------------------------------
429 if test "$TargetOS_CPP" = "darwin" &&
430    test "$XCodeVersion1" -ge 4
431 then
432   # From Xcode 4, use 'gcc-4.2' to force the use of the gcc legacy
433   # backend (instead of the LLVM backend)
434   FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc-4.2])
435 else
436   FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc])
437 fi
438 export CC
439 WhatGccIsCalled="$CC"
440 AC_SUBST(WhatGccIsCalled)
441
442 dnl ** Which ld to use?
443 dnl --------------------------------------------------------------
444 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld])
445 LdCmd="$LD"
446 AC_SUBST([LdCmd])
447
448 dnl ** Which nm to use?
449 dnl --------------------------------------------------------------
450 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm])
451 NmCmd="$NM"
452 AC_SUBST([NmCmd])
453
454 dnl ** Mac OS X: explicit deployment target
455 dnl --------------------------------------------------------------
456 AC_ARG_WITH([macosx-deployment-target],
457 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
458         [Build for Mac OS VERSION and higher  (default= version of build host)])],
459 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
460  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
461    # ignore everywhere, but on Mac OS
462    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
463    FP_MACOSX_DEPLOYMENT_TARGET=none
464  fi],
465 [FP_MACOSX_DEPLOYMENT_TARGET=none]
466 )
467 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
468 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
469 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
470
471 dnl --------------------------------------------------------------
472 dnl End of configure script option section
473 dnl --------------------------------------------------------------
474
475
476 dnl --------------------------------------------------------------
477 dnl * General configuration checks
478 dnl --------------------------------------------------------------
479
480 dnl ** Can the unix package be built?
481 dnl --------------------------------------------------------------
482
483 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
484    GhcLibsWithUnix=NO
485 else
486    GhcLibsWithUnix=YES
487 fi
488 AC_SUBST([GhcLibsWithUnix])
489
490 dnl ** does #! work?
491 AC_SYS_INTERPRETER()
492
493 dnl ** look for `perl'
494 case $HostOS_CPP in
495 cygwin32|mingw32)
496     PerlCmd=$hardtop/inplace/perl/perl
497     ;;
498 *)
499     AC_PATH_PROG(PerlCmd,perl)
500     if test -z "$PerlCmd"
501     then
502         echo "You must install perl before you can continue"
503         echo "Perhaps it is already installed, but not in your PATH?"
504         exit 1
505     else
506         FPTOOLS_CHECK_PERL_VERSION
507     fi
508     ;;
509 esac
510
511 dnl ** does #! path/to/perl work? (sometimes it's too long...)
512 FPTOOLS_SHEBANG_PERL
513
514 dnl ** check for Python
515 AC_PATH_PROG(PythonCmd,python)
516
517 dnl ** look for GCC and find out which version
518 dnl     Figure out which C compiler to use.  Gcc is preferred.
519 dnl     If gcc, make sure it's at least 2.1
520 dnl
521 FP_GCC_VERSION
522
523 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
524 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
525 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
526 # Stage 3 won't be supported by cross-compilation
527 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
528
529 FP_GCC_EXTRA_FLAGS
530
531 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
532 AC_PROG_CPP
533
534 AC_SUBST(CONF_CC_OPTS_STAGE0)
535 AC_SUBST(CONF_CC_OPTS_STAGE1)
536 AC_SUBST(CONF_CC_OPTS_STAGE2)
537 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
538 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
539 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
540 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
541 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
542 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
543 AC_SUBST(CONF_CPP_OPTS_STAGE0)
544 AC_SUBST(CONF_CPP_OPTS_STAGE1)
545 AC_SUBST(CONF_CPP_OPTS_STAGE2)
546
547 FP_SETTINGS
548
549 dnl ** figure out how to do context diffs
550 FP_PROG_CONTEXT_DIFF
551
552 dnl Let's make sure install-sh is executable here.  If we got it from
553 dnl a darcs repo, it might not be (see bug #978).
554 chmod +x install-sh
555 dnl ** figure out how to do a BSD-ish install
556 AC_PROG_INSTALL
557
558 dnl If you can run configure, you certainly have /bin/sh
559 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
560
561 dnl ** how to invoke `ar' and `ranlib'
562 FP_PROG_AR_SUPPORTS_ATFILE
563 FP_PROG_AR_NEEDS_RANLIB
564
565 dnl ** Check to see whether ln -s works
566 AC_PROG_LN_S
567
568
569 dnl ** Find the path to sed
570 AC_PATH_PROGS(SedCmd,gsed sed,sed)
571
572
573 dnl ** check for time command
574 AC_PATH_PROG(TimeCmd,time)
575
576 dnl ** check for tar
577 dnl   if GNU tar is named gtar, look for it first.
578 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
579
580 dnl ** check for patch
581 dnl if GNU patch is named gpatch, look for it first
582 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
583
584 dnl ** check for dtrace (currently only implemented for Mac OS X)
585 HaveDtrace=NO
586 AC_PATH_PROG(DtraceCmd,dtrace)
587 if test -n "$DtraceCmd"; then
588   if test "x$TargetOS_CPP-$TargetVendor_CPP" == "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" == "xsolaris2-unknown"; then
589     HaveDtrace=YES
590   fi
591 fi
592 AC_SUBST(HaveDtrace)
593
594 AC_PATH_PROG(HSCOLOUR,HsColour)
595 # HsColour is passed to Cabal, so we need a native path
596 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
597    test "${OSTYPE}"      != "msys"                  && \
598    test "${HSCOLOUR}"    != ""
599 then
600     # Canonicalise to <drive>:/path/to/gcc
601     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
602 fi
603
604 dnl ** check for DocBook toolchain
605 FP_CHECK_DOCBOOK_DTD
606 FP_DOCBOOK_XSL
607 FP_PROG_DBLATEX
608
609 dnl ** check for ghc-pkg command
610 FP_PROG_GHC_PKG
611
612 dnl ** check for installed happy binary + version
613 dnl    (don't do it if we're booting from .hc files though.)
614 if test "$BootingFromHc" = "NO"; then
615 FPTOOLS_HAPPY
616 fi;
617
618 dnl ** check for installed alex binary + version
619 dnl    (don't do it if we're booting from .hc files though.)
620 if test "$BootingFromHc" = "NO"; then
621 FPTOOLS_ALEX
622 fi;
623
624 dnl --------------------------------------------------
625 dnl ### program checking section ends here ###
626 dnl --------------------------------------------------
627
628 dnl --------------------------------------------------
629 dnl * Platform header file and syscall feature tests
630 dnl ### checking the state of the local header files and syscalls ###
631
632 dnl ** check for full ANSI header (.h) files
633 AC_HEADER_STDC
634
635 dnl ** Enable large file support.  NB. do this before testing the type of
636 dnl    off_t, because it will affect the result of that test.
637 AC_SYS_LARGEFILE
638
639 dnl ** check for specific header (.h) files that we are interested in
640 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/cpuset.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
641
642 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
643 AC_HEADER_TIME
644
645 dnl ** do we have long longs?
646 AC_CHECK_TYPES([long long])
647
648 dnl ** what are the sizes of various types
649 AC_CHECK_SIZEOF(char,               1)
650 AC_CHECK_SIZEOF(double,             8)
651 AC_CHECK_SIZEOF(float,              4)
652 AC_CHECK_SIZEOF(int,                4)
653 AC_CHECK_SIZEOF(long,               4)
654 if test "$ac_cv_type_long_long" = yes; then
655 AC_CHECK_SIZEOF(long long,          8)
656 fi
657 AC_CHECK_SIZEOF(short,              2)
658 AC_CHECK_SIZEOF(unsigned char,      1)
659 AC_CHECK_SIZEOF(unsigned int,       4)
660 AC_CHECK_SIZEOF(unsigned long,      4)
661 if test "$ac_cv_type_long_long" = yes; then
662 AC_CHECK_SIZEOF(unsigned long long, 8)
663 fi
664 AC_CHECK_SIZEOF(unsigned short,     2)
665 AC_CHECK_SIZEOF(void *,             4)
666
667 dnl ** what are alignment constraints on various types
668 FP_CHECK_ALIGNMENT(char)
669 FP_CHECK_ALIGNMENT(double)
670 FP_CHECK_ALIGNMENT(float)
671 FP_CHECK_ALIGNMENT(int)
672 FP_CHECK_ALIGNMENT(long)
673 if test "$ac_cv_type_long_long" = yes; then
674 FP_CHECK_ALIGNMENT(long long)
675 fi
676 FP_CHECK_ALIGNMENT(short)
677 FP_CHECK_ALIGNMENT(unsigned char)
678 FP_CHECK_ALIGNMENT(unsigned int)
679 FP_CHECK_ALIGNMENT(unsigned long)
680 if test "$ac_cv_type_long_long" = yes; then
681 FP_CHECK_ALIGNMENT(unsigned long long)
682 fi
683 FP_CHECK_ALIGNMENT(unsigned short)
684 FP_CHECK_ALIGNMENT(void *)
685
686 FP_CHECK_FUNC([WinExec],
687   [@%:@include <windows.h>], [WinExec("",0)])
688
689 FP_CHECK_FUNC([GetModuleFileName],
690   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
691
692 dnl ** check return type of signal handlers
693 dnl Foo: assumes we can use prototypes.
694 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
695 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
696 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
697 dnl #include <signal.h>
698 dnl #ifdef signal
699 dnl #undef signal
700 dnl #endif
701 dnl void (*signal (int, void (*)(int)))(int);
702 dnl ]],
703 dnl [[int i;]])],
704 dnl [ac_cv_type_signal_handler=void_int],
705 dnl [ac_cv_type_signal_handler=int_void])])
706 dnl if test "$ac_cv_type_signal_handler" = void_int; then
707 dnl AC_DEFINE(VOID_INT_SIGNALS)
708 dnl fi
709
710 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
711 AC_TYPE_SIGNAL
712 if test "$ac_cv_type_signal" = void; then
713   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
714 fi
715
716 dnl ** check for more functions
717 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
718 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
719
720 AC_TRY_RUN([
721 #include <sys/types.h>
722 #include <sys/time.h>
723 int main(void) {
724   struct itimerval tval;
725   tval.it_value.tv_sec = 1;
726   tval.it_value.tv_usec = 0;
727   tval.it_interval = tval.it_value;
728   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
729 }
730 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
731
732 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
733 dnl ** _POSIX_C_SOURCE is defined
734 AC_CHECK_DECLS([ctime_r], , ,
735 [#define _POSIX_SOURCE 1
736 #define _POSIX_C_SOURCE 199506L
737 #include <time.h>])
738
739 dnl ** check for mingwex library
740 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
741 AC_SUBST(HaveLibMingwEx)
742
743 if test $HaveLibMingwEx = YES ; then
744   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
745 fi
746
747 dnl ** check for math library
748 dnl    Keep that check as early as possible.
749 dnl    as we need to know whether we need libm
750 dnl    for math functions or not
751 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
752 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
753 if test $HaveLibM = YES
754 then
755   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
756 fi
757
758 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
759 dnl    the order of these tests matters: bfd needs liberty
760 AC_CHECK_LIB(iberty, xmalloc)
761 AC_CHECK_LIB(bfd,    bfd_uncompress_section_contents)
762
763 dnl ################################################################
764 dnl Check for libraries
765 dnl ################################################################
766
767 dnl ** check whether we need -ldl to get dlopen()
768
769 AC_CHECK_LIB(dl, dlopen,
770     [HaveLibDL=YES
771      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
772      LIBS="$LIBS -ldl"],
773     [HaveLibDL=NO])
774 AC_SUBST(HaveLibDL)
775
776 dnl --------------------------------------------------
777 dnl * Miscellaneous feature tests
778 dnl --------------------------------------------------
779
780 dnl ** can we get alloca?
781 AC_FUNC_ALLOCA
782
783 dnl ** Working vfork?
784 AC_FUNC_FORK
785
786 dnl ** determine whether or not const works
787 AC_C_CONST
788
789 dnl ** are we big endian?
790 AC_C_BIGENDIAN
791 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
792
793 dnl ** check for leading underscores in symbol names
794 FP_LEADING_UNDERSCORE
795
796 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
797 FP_PROG_LD_X
798 FP_PROG_LD_IS_GNU
799 FP_PROG_LD_BUILD_ID
800
801 dnl ** check for Apple-style dead-stripping support
802 dnl    (.subsections-via-symbols assembler directive)
803
804
805 AC_MSG_CHECKING(for .subsections_via_symbols)
806 AC_COMPILE_IFELSE(
807     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
808     [AC_MSG_RESULT(yes)
809      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
810                [Define to 1 if Apple-style dead-stripping is supported.])
811     ],
812     [AC_MSG_RESULT(no)])
813
814 dnl *** check for GNU non-executable stack note support (ELF only)
815 dnl     (.section .note.GNU-stack,"",@progbits)
816
817 dnl This test doesn't work with "gcc -g" in gcc 4.4 (GHC trac #3889:
818 dnl     Error: can't resolve `.note.GNU-stack' {.note.GNU-stack section} - `.Ltext0' {.text section}
819 dnl so we empty CFLAGS while running this test
820 CFLAGS2="$CFLAGS"
821 CFLAGS=
822 AC_MSG_CHECKING(for GNU non-executable stack support)
823 AC_COMPILE_IFELSE(
824     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
825     [AC_MSG_RESULT(yes)
826      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
827                [Define to 1 if GNU non-executable stack notes are supported.])
828     ],
829     [AC_MSG_RESULT(no)])
830 CFLAGS="$CFLAGS2"
831
832 FP_VISIBILITY_HIDDEN
833
834 dnl ** check for librt
835 AC_CHECK_LIB(rt, clock_gettime)
836 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
837 FP_CHECK_TIMER_CREATE
838
839 dnl ** check for Apple's "interesting" long double compatibility scheme
840 AC_MSG_CHECKING(for printf\$LDBLStub)
841 AC_TRY_LINK_FUNC(printf\$LDBLStub,
842     [
843         AC_MSG_RESULT(yes)
844         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
845             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
846     ],
847     [
848         AC_MSG_RESULT(no)
849         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
850             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
851     ])
852
853 dnl ** check for eventfd which is needed by the I/O manager
854 AC_CHECK_HEADERS([sys/eventfd.h])
855 AC_CHECK_FUNCS([eventfd])
856
857 # test for GTK+
858 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
859 if test -n "$GTK_CONFIG"; then
860   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
861     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
862   else
863     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
864     GTK_CONFIG=
865   fi
866 fi
867 AC_SUBST([GTK_CONFIG])
868
869 #Checking for PAPI
870 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
871 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
872 AC_SUBST(HavePapiLib)
873 AC_SUBST(HavePapiHeader)
874
875 AC_CHECK_FUNCS(__mingw_vfprintf)
876
877 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
878    HavePapi=YES
879 else
880    HavePapi=NO
881 fi
882 AC_SUBST(HavePapi)
883
884 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
885    test "$XsltprocCmd" = ""
886 then
887     BUILD_DOCBOOK_HTML=NO
888 else
889     BUILD_DOCBOOK_HTML=YES
890 fi
891 AC_SUBST(BUILD_DOCBOOK_HTML)
892
893 if test "$DblatexCmd" = ""
894 then
895     BUILD_DOCBOOK_PS=NO
896     BUILD_DOCBOOK_PDF=NO
897 else
898     BUILD_DOCBOOK_PS=YES
899     BUILD_DOCBOOK_PDF=YES
900 fi
901 AC_SUBST(BUILD_DOCBOOK_PS)
902 AC_SUBST(BUILD_DOCBOOK_PDF)
903
904 LIBRARY_VERSION(base)
905 LIBRARY_VERSION(Cabal, Cabal/cabal)
906 LIBRARY_VERSION(ghc-prim)
907 LIBRARY_ghc_VERSION="$ProjectVersion"
908 AC_SUBST(LIBRARY_ghc_VERSION)
909
910 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
911    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
912 fi
913
914 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal ghc.spec settings docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/ghc.iss distrib/configure.ac])
915 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
916 AC_OUTPUT
917
918 # We get caught by
919 #     http://savannah.gnu.org/bugs/index.php?1516
920 #     $(eval ...) inside conditionals causes errors
921 # with make 3.80, so warn the user if it looks like they're about to
922 # try to use it.
923 # We would use "grep -q" here, but Solaris's grep doesn't support it.
924 checkMake380() {
925     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
926     then
927         echo
928         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
929         echo "This version cannot be used to build GHC."
930         echo "Please use GNU make >= 3.81."
931     fi
932 }
933
934 checkMake380 make
935 checkMake380 gmake
936
937 echo ["
938 ----------------------------------------------------------------------
939 Configure completed successfully.
940
941    Building GHC version  : $ProjectVersion
942
943    Build platform        : $BuildPlatform
944    Host platform         : $HostPlatform
945    Target platform       : $TargetPlatform
946 "]
947
948 if test "$BootingFromHc" = "YES"; then
949 echo ["\
950    Bootstrapping from HC files.
951 "]
952 else
953 echo ["\
954    Bootstrapping using   : $WithGhc
955       which is version   : $GhcVersion
956 "]
957 fi
958
959 echo ["\
960    Using GCC             : $WhatGccIsCalled
961       which is version   : $GccVersion
962
963    ld       : $LdCmd
964    Happy    : $HappyCmd ($HappyVersion)
965    Alex     : $AlexCmd ($AlexVersion)
966    Python   : $PythonCmd
967    Perl     : $PerlCmd
968    dblatex  : $DblatexCmd
969    xsltproc : $XsltprocCmd"]
970
971 if test "$HSCOLOUR" = ""; then
972 echo ["
973    HsColour was not found; documentation will not contain source links
974 "]
975 else
976 echo ["\
977    HsColour : $HSCOLOUR
978 "]
979 fi
980
981 echo ["\
982    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
983    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
984    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
985
986 echo ["----------------------------------------------------------------------
987 "]
988
989 echo "\
990 For a standard build of GHC (fully optimised with profiling), type (g)make.
991
992 To make changes to the default build configuration, copy the file
993 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
994
995 For more information on how to configure your GHC build, see
996    http://hackage.haskell.org/trac/ghc/wiki/Building
997 "