6c631df592890424bed0d474eff619835e13d358
[ghc.git] / compiler / typecheck / TcDeriv.hs
1 {-
2 (c) The University of Glasgow 2006
3 (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4
5
6 Handles @deriving@ clauses on @data@ declarations.
7 -}
8
9 {-# LANGUAGE CPP #-}
10
11 module TcDeriv ( tcDeriving ) where
12
13 #include "HsVersions.h"
14
15 import HsSyn
16 import DynFlags
17
18 import TcRnMonad
19 import FamInst
20 import TcErrors( reportAllUnsolved )
21 import TcValidity( validDerivPred )
22 import TcEnv
23 import TcTyClsDecls( tcFamTyPats, famTyConShape, tcAddDataFamInstCtxt, kcDataDefn )
24 import TcClassDcl( tcAddDeclCtxt ) -- Small helper
25 import TcGenDeriv -- Deriv stuff
26 import TcGenGenerics
27 import InstEnv
28 import Inst
29 import FamInstEnv
30 import TcHsType
31 import TcMType
32 import TcSimplify
33 import LoadIface( loadInterfaceForName )
34 import Module( getModule )
35
36 import RnNames( extendGlobalRdrEnvRn )
37 import RnBinds
38 import RnEnv
39 import RnSource ( addTcgDUs )
40 import HscTypes
41 import Avail
42
43 import Unify( tcUnifyTy )
44 import Class
45 import Type
46 import ErrUtils
47 import DataCon
48 import Maybes
49 import RdrName
50 import Name
51 import NameSet
52 import TyCon
53 import TcType
54 import Var
55 import VarSet
56 import PrelNames
57 import SrcLoc
58 import Util
59 import Outputable
60 import FastString
61 import Bag
62 import Pair
63
64 import Control.Monad
65 import Data.List
66
67 {-
68 ************************************************************************
69 * *
70 Overview
71 * *
72 ************************************************************************
73
74 Overall plan
75 ~~~~~~~~~~~~
76 1. Convert the decls (i.e. data/newtype deriving clauses,
77 plus standalone deriving) to [EarlyDerivSpec]
78
79 2. Infer the missing contexts for the InferTheta's
80
81 3. Add the derived bindings, generating InstInfos
82 -}
83
84 -- DerivSpec is purely local to this module
85 data DerivSpec theta = DS { ds_loc :: SrcSpan
86 , ds_name :: Name -- DFun name
87 , ds_tvs :: [TyVar]
88 , ds_theta :: theta
89 , ds_cls :: Class
90 , ds_tys :: [Type]
91 , ds_tc :: TyCon
92 , ds_tc_args :: [Type]
93 , ds_overlap :: Maybe OverlapMode
94 , ds_newtype :: Bool }
95 -- This spec implies a dfun declaration of the form
96 -- df :: forall tvs. theta => C tys
97 -- The Name is the name for the DFun we'll build
98 -- The tyvars bind all the variables in the theta
99 -- For type families, the tycon in
100 -- in ds_tys is the *family* tycon
101 -- in ds_tc, ds_tc_args is the *representation* tycon
102 -- For non-family tycons, both are the same
103
104 -- the theta is either the given and final theta, in standalone deriving,
105 -- or the not-yet-simplified list of constraints together with their origin
106
107 -- ds_newtype = True <=> Generalised Newtype Deriving (GND)
108 -- False <=> Vanilla deriving
109
110 {-
111 Example:
112
113 newtype instance T [a] = MkT (Tree a) deriving( C s )
114 ==>
115 axiom T [a] = :RTList a
116 axiom :RTList a = Tree a
117
118 DS { ds_tvs = [a,s], ds_cls = C, ds_tys = [s, T [a]]
119 , ds_tc = :RTList, ds_tc_args = [a]
120 , ds_newtype = True }
121 -}
122
123 type DerivContext = Maybe ThetaType
124 -- Nothing <=> Vanilla deriving; infer the context of the instance decl
125 -- Just theta <=> Standalone deriving: context supplied by programmer
126
127 data PredOrigin = PredOrigin PredType CtOrigin
128 type ThetaOrigin = [PredOrigin]
129
130 mkPredOrigin :: CtOrigin -> PredType -> PredOrigin
131 mkPredOrigin origin pred = PredOrigin pred origin
132
133 mkThetaOrigin :: CtOrigin -> ThetaType -> ThetaOrigin
134 mkThetaOrigin origin = map (mkPredOrigin origin)
135
136 data EarlyDerivSpec = InferTheta (DerivSpec ThetaOrigin)
137 | GivenTheta (DerivSpec ThetaType)
138 -- InferTheta ds => the context for the instance should be inferred
139 -- In this case ds_theta is the list of all the constraints
140 -- needed, such as (Eq [a], Eq a), together with a suitable CtLoc
141 -- to get good error messages.
142 -- The inference process is to reduce this to a simpler form (e.g.
143 -- Eq a)
144 --
145 -- GivenTheta ds => the exact context for the instance is supplied
146 -- by the programmer; it is ds_theta
147
148 forgetTheta :: EarlyDerivSpec -> DerivSpec ()
149 forgetTheta (InferTheta spec) = spec { ds_theta = () }
150 forgetTheta (GivenTheta spec) = spec { ds_theta = () }
151
152 earlyDSLoc :: EarlyDerivSpec -> SrcSpan
153 earlyDSLoc (InferTheta spec) = ds_loc spec
154 earlyDSLoc (GivenTheta spec) = ds_loc spec
155
156 splitEarlyDerivSpec :: [EarlyDerivSpec] -> ([DerivSpec ThetaOrigin], [DerivSpec ThetaType])
157 splitEarlyDerivSpec [] = ([],[])
158 splitEarlyDerivSpec (InferTheta spec : specs) =
159 case splitEarlyDerivSpec specs of (is, gs) -> (spec : is, gs)
160 splitEarlyDerivSpec (GivenTheta spec : specs) =
161 case splitEarlyDerivSpec specs of (is, gs) -> (is, spec : gs)
162
163 pprDerivSpec :: Outputable theta => DerivSpec theta -> SDoc
164 pprDerivSpec (DS { ds_loc = l, ds_name = n, ds_tvs = tvs,
165 ds_cls = c, ds_tys = tys, ds_theta = rhs })
166 = parens (hsep [ppr l, ppr n, ppr tvs, ppr c, ppr tys]
167 <+> equals <+> ppr rhs)
168
169 instance Outputable theta => Outputable (DerivSpec theta) where
170 ppr = pprDerivSpec
171
172 instance Outputable EarlyDerivSpec where
173 ppr (InferTheta spec) = ppr spec <+> ptext (sLit "(Infer)")
174 ppr (GivenTheta spec) = ppr spec <+> ptext (sLit "(Given)")
175
176 instance Outputable PredOrigin where
177 ppr (PredOrigin ty _) = ppr ty -- The origin is not so interesting when debugging
178
179 {-
180 Inferring missing contexts
181 ~~~~~~~~~~~~~~~~~~~~~~~~~~
182 Consider
183
184 data T a b = C1 (Foo a) (Bar b)
185 | C2 Int (T b a)
186 | C3 (T a a)
187 deriving (Eq)
188
189 [NOTE: See end of these comments for what to do with
190 data (C a, D b) => T a b = ...
191 ]
192
193 We want to come up with an instance declaration of the form
194
195 instance (Ping a, Pong b, ...) => Eq (T a b) where
196 x == y = ...
197
198 It is pretty easy, albeit tedious, to fill in the code "...". The
199 trick is to figure out what the context for the instance decl is,
200 namely @Ping@, @Pong@ and friends.
201
202 Let's call the context reqd for the T instance of class C at types
203 (a,b, ...) C (T a b). Thus:
204
205 Eq (T a b) = (Ping a, Pong b, ...)
206
207 Now we can get a (recursive) equation from the @data@ decl:
208
209 Eq (T a b) = Eq (Foo a) u Eq (Bar b) -- From C1
210 u Eq (T b a) u Eq Int -- From C2
211 u Eq (T a a) -- From C3
212
213 Foo and Bar may have explicit instances for @Eq@, in which case we can
214 just substitute for them. Alternatively, either or both may have
215 their @Eq@ instances given by @deriving@ clauses, in which case they
216 form part of the system of equations.
217
218 Now all we need do is simplify and solve the equations, iterating to
219 find the least fixpoint. Notice that the order of the arguments can
220 switch around, as here in the recursive calls to T.
221
222 Let's suppose Eq (Foo a) = Eq a, and Eq (Bar b) = Ping b.
223
224 We start with:
225
226 Eq (T a b) = {} -- The empty set
227
228 Next iteration:
229 Eq (T a b) = Eq (Foo a) u Eq (Bar b) -- From C1
230 u Eq (T b a) u Eq Int -- From C2
231 u Eq (T a a) -- From C3
232
233 After simplification:
234 = Eq a u Ping b u {} u {} u {}
235 = Eq a u Ping b
236
237 Next iteration:
238
239 Eq (T a b) = Eq (Foo a) u Eq (Bar b) -- From C1
240 u Eq (T b a) u Eq Int -- From C2
241 u Eq (T a a) -- From C3
242
243 After simplification:
244 = Eq a u Ping b
245 u (Eq b u Ping a)
246 u (Eq a u Ping a)
247
248 = Eq a u Ping b u Eq b u Ping a
249
250 The next iteration gives the same result, so this is the fixpoint. We
251 need to make a canonical form of the RHS to ensure convergence. We do
252 this by simplifying the RHS to a form in which
253
254 - the classes constrain only tyvars
255 - the list is sorted by tyvar (major key) and then class (minor key)
256 - no duplicates, of course
257
258 So, here are the synonyms for the ``equation'' structures:
259
260
261 Note [Data decl contexts]
262 ~~~~~~~~~~~~~~~~~~~~~~~~~
263 Consider
264
265 data (RealFloat a) => Complex a = !a :+ !a deriving( Read )
266
267 We will need an instance decl like:
268
269 instance (Read a, RealFloat a) => Read (Complex a) where
270 ...
271
272 The RealFloat in the context is because the read method for Complex is bound
273 to construct a Complex, and doing that requires that the argument type is
274 in RealFloat.
275
276 But this ain't true for Show, Eq, Ord, etc, since they don't construct
277 a Complex; they only take them apart.
278
279 Our approach: identify the offending classes, and add the data type
280 context to the instance decl. The "offending classes" are
281
282 Read, Enum?
283
284 FURTHER NOTE ADDED March 2002. In fact, Haskell98 now requires that
285 pattern matching against a constructor from a data type with a context
286 gives rise to the constraints for that context -- or at least the thinned
287 version. So now all classes are "offending".
288
289 Note [Newtype deriving]
290 ~~~~~~~~~~~~~~~~~~~~~~~
291 Consider this:
292 class C a b
293 instance C [a] Char
294 newtype T = T Char deriving( C [a] )
295
296 Notice the free 'a' in the deriving. We have to fill this out to
297 newtype T = T Char deriving( forall a. C [a] )
298
299 And then translate it to:
300 instance C [a] Char => C [a] T where ...
301
302
303 Note [Newtype deriving superclasses]
304 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
305 (See also Trac #1220 for an interesting exchange on newtype
306 deriving and superclasses.)
307
308 The 'tys' here come from the partial application in the deriving
309 clause. The last arg is the new instance type.
310
311 We must pass the superclasses; the newtype might be an instance
312 of them in a different way than the representation type
313 E.g. newtype Foo a = Foo a deriving( Show, Num, Eq )
314 Then the Show instance is not done via Coercible; it shows
315 Foo 3 as "Foo 3"
316 The Num instance is derived via Coercible, but the Show superclass
317 dictionary must the Show instance for Foo, *not* the Show dictionary
318 gotten from the Num dictionary. So we must build a whole new dictionary
319 not just use the Num one. The instance we want is something like:
320 instance (Num a, Show (Foo a), Eq (Foo a)) => Num (Foo a) where
321 (+) = ((+)@a)
322 ...etc...
323 There may be a coercion needed which we get from the tycon for the newtype
324 when the dict is constructed in TcInstDcls.tcInstDecl2
325
326
327 Note [Unused constructors and deriving clauses]
328 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
329 See Trac #3221. Consider
330 data T = T1 | T2 deriving( Show )
331 Are T1 and T2 unused? Well, no: the deriving clause expands to mention
332 both of them. So we gather defs/uses from deriving just like anything else.
333
334 ************************************************************************
335 * *
336 \subsection[TcDeriv-driver]{Top-level function for \tr{derivings}}
337 * *
338 ************************************************************************
339 -}
340
341 tcDeriving :: [LTyClDecl Name] -- All type constructors
342 -> [LInstDecl Name] -- All instance declarations
343 -> [LDerivDecl Name] -- All stand-alone deriving declarations
344 -> TcM (TcGblEnv, Bag (InstInfo Name), HsValBinds Name)
345 tcDeriving tycl_decls inst_decls deriv_decls
346 = recoverM (do { g <- getGblEnv
347 ; return (g, emptyBag, emptyValBindsOut)}) $
348 do { -- Fish the "deriving"-related information out of the TcEnv
349 -- And make the necessary "equations".
350 is_boot <- tcIsHsBootOrSig
351 ; traceTc "tcDeriving" (ppr is_boot)
352
353 ; early_specs <- makeDerivSpecs is_boot tycl_decls inst_decls deriv_decls
354 ; traceTc "tcDeriving 1" (ppr early_specs)
355
356 -- for each type, determine the auxliary declarations that are common
357 -- to multiple derivations involving that type (e.g. Generic and
358 -- Generic1 should use the same TcGenGenerics.MetaTyCons)
359 ; (commonAuxs, auxDerivStuff) <- commonAuxiliaries $ map forgetTheta early_specs
360
361 ; let (infer_specs, given_specs) = splitEarlyDerivSpec early_specs
362 ; insts1 <- mapM (genInst commonAuxs) given_specs
363
364 -- the stand-alone derived instances (@insts1@) are used when inferring
365 -- the contexts for "deriving" clauses' instances (@infer_specs@)
366 ; final_specs <- extendLocalInstEnv (map (iSpec . fstOf3) insts1) $
367 inferInstanceContexts infer_specs
368
369 ; insts2 <- mapM (genInst commonAuxs) final_specs
370
371 ; let (inst_infos, deriv_stuff, maybe_fvs) = unzip3 (insts1 ++ insts2)
372 ; loc <- getSrcSpanM
373 ; let (binds, newTyCons, famInsts, extraInstances) =
374 genAuxBinds loc (unionManyBags (auxDerivStuff : deriv_stuff))
375
376 ; dflags <- getDynFlags
377
378 ; (inst_info, rn_binds, rn_dus) <-
379 renameDeriv is_boot (inst_infos ++ (bagToList extraInstances)) binds
380
381 ; unless (isEmptyBag inst_info) $
382 liftIO (dumpIfSet_dyn dflags Opt_D_dump_deriv "Derived instances"
383 (ddump_deriving inst_info rn_binds newTyCons famInsts))
384
385 ; let all_tycons = map ATyCon (bagToList newTyCons)
386 ; gbl_env <- tcExtendGlobalEnv all_tycons $
387 tcExtendGlobalEnvImplicit (concatMap implicitTyThings all_tycons) $
388 tcExtendLocalFamInstEnv (bagToList famInsts) $
389 tcExtendLocalInstEnv (map iSpec (bagToList inst_info)) getGblEnv
390 ; let all_dus = rn_dus `plusDU` usesOnly (mkFVs $ catMaybes maybe_fvs)
391 ; return (addTcgDUs gbl_env all_dus, inst_info, rn_binds) }
392 where
393 ddump_deriving :: Bag (InstInfo Name) -> HsValBinds Name
394 -> Bag TyCon -- ^ Empty data constructors
395 -> Bag FamInst -- ^ Rep type family instances
396 -> SDoc
397 ddump_deriving inst_infos extra_binds repMetaTys repFamInsts
398 = hang (ptext (sLit "Derived instances:"))
399 2 (vcat (map (\i -> pprInstInfoDetails i $$ text "") (bagToList inst_infos))
400 $$ ppr extra_binds)
401 $$ hangP "Generic representation:" (
402 hangP "Generated datatypes for meta-information:"
403 (vcat (map ppr (bagToList repMetaTys)))
404 $$ hangP "Representation types:"
405 (vcat (map pprRepTy (bagToList repFamInsts))))
406
407 hangP s x = text "" $$ hang (ptext (sLit s)) 2 x
408
409 {-
410 genTypeableTyConReps :: DynFlags ->
411 [LTyClDecl Name] ->
412 [LInstDecl Name] ->
413 TcM (Bag (LHsBind RdrName, LSig RdrName))
414 genTypeableTyConReps dflags decls insts =
415 do tcs1 <- mapM tyConsFromDecl decls
416 tcs2 <- mapM tyConsFromInst insts
417 return $ listToBag [ genTypeableTyConRep dflags loc tc
418 | (loc,tc) <- concat (tcs1 ++ tcs2) ]
419 where
420
421 tyConFromDataCon (L l n) = do dc <- tcLookupDataCon n
422 return (do tc <- promoteDataCon_maybe dc
423 return (l,tc))
424
425 -- Promoted data constructors from a data declaration, or
426 -- a data-family instance.
427 tyConsFromDataRHS = fmap catMaybes
428 . mapM tyConFromDataCon
429 . concatMap (con_names . unLoc)
430 . dd_cons
431
432 -- Tycons from a data-family declaration; not promotable.
433 tyConFromDataFamDecl FamilyDecl { fdLName = L loc name } =
434 do tc <- tcLookupTyCon name
435 return (loc,tc)
436
437
438 -- tycons from a type-level declaration
439 tyConsFromDecl (L _ d)
440
441 -- data or newtype declaration: promoted tycon, tycon, promoted ctrs.
442 | isDataDecl d =
443 do let L loc name = tcdLName d
444 tc <- tcLookupTyCon name
445 promotedCtrs <- tyConsFromDataRHS (tcdDataDefn d)
446 let tyCons = (loc,tc) : promotedCtrs
447
448 return (case promotableTyCon_maybe tc of
449 Nothing -> tyCons
450 Just kc -> (loc,kc) : tyCons)
451
452 -- data family: just the type constructor; these are not promotable.
453 | isDataFamilyDecl d =
454 do res <- tyConFromDataFamDecl (tcdFam d)
455 return [res]
456
457 -- class: the type constructors of associated data families
458 | isClassDecl d =
459 let isData FamilyDecl { fdInfo = DataFamily } = True
460 isData _ = False
461
462 in mapM tyConFromDataFamDecl (filter isData (map unLoc (tcdATs d)))
463
464 | otherwise = return []
465
466
467 tyConsFromInst (L _ d) =
468 case d of
469 ClsInstD ci -> fmap concat
470 $ mapM (tyConsFromDataRHS . dfid_defn . unLoc)
471 $ cid_datafam_insts ci
472 DataFamInstD dfi -> tyConsFromDataRHS (dfid_defn dfi)
473 TyFamInstD {} -> return []
474 -}
475
476 -- Prints the representable type family instance
477 pprRepTy :: FamInst -> SDoc
478 pprRepTy fi@(FamInst { fi_tys = lhs })
479 = ptext (sLit "type") <+> ppr (mkTyConApp (famInstTyCon fi) lhs) <+>
480 equals <+> ppr rhs
481 where rhs = famInstRHS fi
482
483 -- As of 24 April 2012, this only shares MetaTyCons between derivations of
484 -- Generic and Generic1; thus the types and logic are quite simple.
485 type CommonAuxiliary = MetaTyCons
486 type CommonAuxiliaries = [(TyCon, CommonAuxiliary)] -- NSF what is a more efficient map type?
487
488 commonAuxiliaries :: [DerivSpec ()] -> TcM (CommonAuxiliaries, BagDerivStuff)
489 commonAuxiliaries = foldM snoc ([], emptyBag) where
490 snoc acc@(cas, stuff) (DS {ds_name = nm, ds_cls = cls, ds_tc = rep_tycon})
491 | getUnique cls `elem` [genClassKey, gen1ClassKey] =
492 extendComAux $ genGenericMetaTyCons rep_tycon (nameModule nm)
493 | otherwise = return acc
494 where extendComAux m -- don't run m if its already in the accumulator
495 | any ((rep_tycon ==) . fst) cas = return acc
496 | otherwise = do (ca, new_stuff) <- m
497 return $ ((rep_tycon, ca) : cas, stuff `unionBags` new_stuff)
498
499 renameDeriv :: Bool
500 -> [InstInfo RdrName]
501 -> Bag (LHsBind RdrName, LSig RdrName)
502 -> TcM (Bag (InstInfo Name), HsValBinds Name, DefUses)
503 renameDeriv is_boot inst_infos bagBinds
504 | is_boot -- If we are compiling a hs-boot file, don't generate any derived bindings
505 -- The inst-info bindings will all be empty, but it's easier to
506 -- just use rn_inst_info to change the type appropriately
507 = do { (rn_inst_infos, fvs) <- mapAndUnzipM rn_inst_info inst_infos
508 ; return ( listToBag rn_inst_infos
509 , emptyValBindsOut, usesOnly (plusFVs fvs)) }
510
511 | otherwise
512 = discardWarnings $ -- Discard warnings about unused bindings etc
513 setXOptM Opt_EmptyCase $ -- Derived decls (for empty types) can have
514 -- case x of {}
515 setXOptM Opt_ScopedTypeVariables $ -- Derived decls (for newtype-deriving) can
516 setXOptM Opt_KindSignatures $ -- used ScopedTypeVariables & KindSignatures
517 do {
518 -- Bring the extra deriving stuff into scope
519 -- before renaming the instances themselves
520 ; (aux_binds, aux_sigs) <- mapAndUnzipBagM return bagBinds
521 ; let aux_val_binds = ValBindsIn aux_binds (bagToList aux_sigs)
522 ; rn_aux_lhs <- rnTopBindsLHS emptyFsEnv aux_val_binds
523 ; let bndrs = collectHsValBinders rn_aux_lhs
524 ; envs <- extendGlobalRdrEnvRn (map Avail bndrs) emptyFsEnv ;
525 ; setEnvs envs $
526 do { (rn_aux, dus_aux) <- rnValBindsRHS (TopSigCtxt (mkNameSet bndrs) False) rn_aux_lhs
527 ; (rn_inst_infos, fvs_insts) <- mapAndUnzipM rn_inst_info inst_infos
528 ; return (listToBag rn_inst_infos, rn_aux,
529 dus_aux `plusDU` usesOnly (plusFVs fvs_insts)) } }
530
531 where
532 rn_inst_info :: InstInfo RdrName -> TcM (InstInfo Name, FreeVars)
533 rn_inst_info
534 inst_info@(InstInfo { iSpec = inst
535 , iBinds = InstBindings
536 { ib_binds = binds
537 , ib_tyvars = tyvars
538 , ib_pragmas = sigs
539 , ib_extensions = exts -- Only for type-checking
540 , ib_derived = sa } })
541 = ASSERT( null sigs )
542 bindLocalNamesFV tyvars $
543 do { (rn_binds, fvs) <- rnMethodBinds (is_cls_nm inst) (\_ -> []) binds
544 ; let binds' = InstBindings { ib_binds = rn_binds
545 , ib_tyvars = tyvars
546 , ib_pragmas = []
547 , ib_extensions = exts
548 , ib_derived = sa }
549 ; return (inst_info { iBinds = binds' }, fvs) }
550
551 {-
552 Note [Newtype deriving and unused constructors]
553 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
554 Consider this (see Trac #1954):
555
556 module Bug(P) where
557 newtype P a = MkP (IO a) deriving Monad
558
559 If you compile with -fwarn-unused-binds you do not expect the warning
560 "Defined but not used: data consructor MkP". Yet the newtype deriving
561 code does not explicitly mention MkP, but it should behave as if you
562 had written
563 instance Monad P where
564 return x = MkP (return x)
565 ...etc...
566
567 So we want to signal a user of the data constructor 'MkP'.
568 This is the reason behind the (Maybe Name) part of the return type
569 of genInst.
570
571 ************************************************************************
572 * *
573 From HsSyn to DerivSpec
574 * *
575 ************************************************************************
576
577 @makeDerivSpecs@ fishes around to find the info about needed derived instances.
578 -}
579
580 makeDerivSpecs :: Bool
581 -> [LTyClDecl Name]
582 -> [LInstDecl Name]
583 -> [LDerivDecl Name]
584 -> TcM [EarlyDerivSpec]
585 makeDerivSpecs is_boot tycl_decls inst_decls deriv_decls
586 = do { eqns1 <- concatMapM (recoverM (return []) . deriveTyDecl) tycl_decls
587 ; eqns2 <- concatMapM (recoverM (return []) . deriveInstDecl) inst_decls
588 ; eqns3 <- concatMapM (recoverM (return []) . deriveStandalone) deriv_decls
589 ; let eqns = eqns1 ++ eqns2 ++ eqns3
590
591 ; if is_boot then -- No 'deriving' at all in hs-boot files
592 do { unless (null eqns) (add_deriv_err (head eqns))
593 ; return [] }
594 else return eqns }
595 where
596 add_deriv_err eqn
597 = setSrcSpan (earlyDSLoc eqn) $
598 addErr (hang (ptext (sLit "Deriving not permitted in hs-boot file"))
599 2 (ptext (sLit "Use an instance declaration instead")))
600
601 ------------------------------------------------------------------
602 deriveTyDecl :: LTyClDecl Name -> TcM [EarlyDerivSpec]
603 deriveTyDecl (L _ decl@(DataDecl { tcdLName = L _ tc_name
604 , tcdDataDefn = HsDataDefn { dd_derivs = preds } }))
605 = tcAddDeclCtxt decl $
606 do { tc <- tcLookupTyCon tc_name
607 ; let tvs = tyConTyVars tc
608 tys = mkTyVarTys tvs
609
610 ; case preds of
611 Just (L _ preds') -> concatMapM (deriveTyData tvs tc tys) preds'
612 Nothing -> return [] }
613
614 deriveTyDecl _ = return []
615
616 ------------------------------------------------------------------
617 deriveInstDecl :: LInstDecl Name -> TcM [EarlyDerivSpec]
618 deriveInstDecl (L _ (TyFamInstD {})) = return []
619 deriveInstDecl (L _ (DataFamInstD { dfid_inst = fam_inst }))
620 = deriveFamInst fam_inst
621 deriveInstDecl (L _ (ClsInstD { cid_inst = ClsInstDecl { cid_datafam_insts = fam_insts } }))
622 = concatMapM (deriveFamInst . unLoc) fam_insts
623
624 ------------------------------------------------------------------
625 deriveFamInst :: DataFamInstDecl Name -> TcM [EarlyDerivSpec]
626 deriveFamInst decl@(DataFamInstDecl
627 { dfid_tycon = L _ tc_name, dfid_pats = pats
628 , dfid_defn
629 = defn@(HsDataDefn { dd_derivs = Just (L _ preds) }) })
630 = tcAddDataFamInstCtxt decl $
631 do { fam_tc <- tcLookupTyCon tc_name
632 ; tcFamTyPats (famTyConShape fam_tc) pats (kcDataDefn defn) $
633 -- kcDataDefn defn: see Note [Finding the LHS patterns]
634 \ tvs' pats' _ ->
635 concatMapM (deriveTyData tvs' fam_tc pats') preds }
636
637 deriveFamInst _ = return []
638
639 {-
640 Note [Finding the LHS patterns]
641 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
642 When kind polymorphism is in play, we need to be careful. Here is
643 Trac #9359:
644 data Cmp a where
645 Sup :: Cmp a
646 V :: a -> Cmp a
647
648 data family CmpInterval (a :: Cmp k) (b :: Cmp k) :: *
649 data instance CmpInterval (V c) Sup = Starting c deriving( Show )
650
651 So CmpInterval is kind-polymorphic, but the data instance is not
652 CmpInterval :: forall k. Cmp k -> Cmp k -> *
653 data instance CmpInterval * (V (c::*)) Sup = Starting c deriving( Show )
654
655 Hence, when deriving the type patterns in deriveFamInst, we must kind
656 check the RHS (the data constructor 'Starting c') as well as the LHS,
657 so that we correctly see the instantiation to *.
658 -}
659
660 ------------------------------------------------------------------
661 deriveStandalone :: LDerivDecl Name -> TcM [EarlyDerivSpec]
662 -- Standalone deriving declarations
663 -- e.g. deriving instance Show a => Show (T a)
664 -- Rather like tcLocalInstDecl
665 deriveStandalone (L loc (DerivDecl deriv_ty overlap_mode))
666 = setSrcSpan loc $
667 addErrCtxt (standaloneCtxt deriv_ty) $
668 do { traceTc "Standalone deriving decl for" (ppr deriv_ty)
669 ; (tvs, theta, cls, inst_tys) <- tcHsInstHead TcType.InstDeclCtxt deriv_ty
670 ; traceTc "Standalone deriving;" $ vcat
671 [ text "tvs:" <+> ppr tvs
672 , text "theta:" <+> ppr theta
673 , text "cls:" <+> ppr cls
674 , text "tys:" <+> ppr inst_tys ]
675 -- C.f. TcInstDcls.tcLocalInstDecl1
676 ; checkTc (not (null inst_tys)) derivingNullaryErr
677
678 ; let cls_tys = take (length inst_tys - 1) inst_tys
679 inst_ty = last inst_tys
680 ; traceTc "Standalone deriving:" $ vcat
681 [ text "class:" <+> ppr cls
682 , text "class types:" <+> ppr cls_tys
683 , text "type:" <+> ppr inst_ty ]
684
685 ; case tcSplitTyConApp_maybe inst_ty of
686 Just (tc, tc_args)
687 | className cls == typeableClassName
688 -> do warn <- woptM Opt_WarnDerivingTypeable
689 when warn
690 $ addWarnTc
691 $ text "Standalone deriving `Typeable` has no effect."
692 return []
693
694 | isAlgTyCon tc -- All other classes
695 -> do { spec <- mkEqnHelp (fmap unLoc overlap_mode)
696 tvs cls cls_tys tc tc_args (Just theta)
697 ; return [spec] }
698
699 _ -> -- Complain about functions, primitive types, etc,
700 failWithTc $ derivingThingErr False cls cls_tys inst_ty $
701 ptext (sLit "The last argument of the instance must be a data or newtype application")
702 }
703
704
705 ------------------------------------------------------------------
706 deriveTyData :: [TyVar] -> TyCon -> [Type] -- LHS of data or data instance
707 -- Can be a data instance, hence [Type] args
708 -> LHsType Name -- The deriving predicate
709 -> TcM [EarlyDerivSpec]
710 -- The deriving clause of a data or newtype declaration
711 -- I.e. not standalone deriving
712 deriveTyData tvs tc tc_args (L loc deriv_pred)
713 = setSrcSpan loc $ -- Use the location of the 'deriving' item
714 do { (deriv_tvs, cls, cls_tys, cls_arg_kind)
715 <- tcExtendTyVarEnv tvs $
716 tcHsDeriv deriv_pred
717 -- Deriving preds may (now) mention
718 -- the type variables for the type constructor, hence tcExtendTyVarenv
719 -- The "deriv_pred" is a LHsType to take account of the fact that for
720 -- newtype deriving we allow deriving (forall a. C [a]).
721
722 -- Typeable is special, because Typeable :: forall k. k -> Constraint
723 -- so the argument kind 'k' is not decomposable by splitKindFunTys
724 -- as is the case for all other derivable type classes
725 ; if className cls == typeableClassName
726 then do warn <- woptM Opt_WarnDerivingTypeable
727 when warn
728 $ addWarnTc
729 $ text "Deriving `Typeable` has no effect."
730 return []
731 else
732
733 do { -- Given data T a b c = ... deriving( C d ),
734 -- we want to drop type variables from T so that (C d (T a)) is well-kinded
735 let (arg_kinds, _) = splitKindFunTys cls_arg_kind
736 n_args_to_drop = length arg_kinds
737 n_args_to_keep = tyConArity tc - n_args_to_drop
738 args_to_drop = drop n_args_to_keep tc_args
739 tc_args_to_keep = take n_args_to_keep tc_args
740 inst_ty_kind = typeKind (mkTyConApp tc tc_args_to_keep)
741 dropped_tvs = tyVarsOfTypes args_to_drop
742
743 -- Match up the kinds, and apply the resulting kind substitution
744 -- to the types. See Note [Unify kinds in deriving]
745 -- We are assuming the tycon tyvars and the class tyvars are distinct
746 mb_match = tcUnifyTy inst_ty_kind cls_arg_kind
747 Just kind_subst = mb_match
748 (univ_kvs, univ_tvs) = partition isKindVar $ varSetElems $
749 mkVarSet deriv_tvs `unionVarSet`
750 tyVarsOfTypes tc_args_to_keep
751 univ_kvs' = filter (`notElemTvSubst` kind_subst) univ_kvs
752 (subst', univ_tvs') = mapAccumL substTyVarBndr kind_subst univ_tvs
753 final_tc_args = substTys subst' tc_args_to_keep
754 final_cls_tys = substTys subst' cls_tys
755
756 ; traceTc "derivTyData1" (vcat [ pprTvBndrs tvs, ppr tc, ppr tc_args, ppr deriv_pred
757 , pprTvBndrs (varSetElems $ tyVarsOfTypes tc_args)
758 , ppr n_args_to_keep, ppr n_args_to_drop
759 , ppr inst_ty_kind, ppr cls_arg_kind, ppr mb_match
760 , ppr final_tc_args, ppr final_cls_tys ])
761
762 -- Check that the result really is well-kinded
763 ; checkTc (n_args_to_keep >= 0 && isJust mb_match)
764 (derivingKindErr tc cls cls_tys cls_arg_kind)
765
766 ; traceTc "derivTyData2" (vcat [ ppr univ_tvs ])
767
768 ; checkTc (allDistinctTyVars args_to_drop && -- (a) and (b)
769 not (any (`elemVarSet` dropped_tvs) univ_tvs)) -- (c)
770 (derivingEtaErr cls final_cls_tys (mkTyConApp tc final_tc_args))
771 -- Check that
772 -- (a) The args to drop are all type variables; eg reject:
773 -- data instance T a Int = .... deriving( Monad )
774 -- (b) The args to drop are all *distinct* type variables; eg reject:
775 -- class C (a :: * -> * -> *) where ...
776 -- data instance T a a = ... deriving( C )
777 -- (c) The type class args, or remaining tycon args,
778 -- do not mention any of the dropped type variables
779 -- newtype T a s = ... deriving( ST s )
780 -- newtype K a a = ... deriving( Monad )
781
782 ; spec <- mkEqnHelp Nothing (univ_kvs' ++ univ_tvs')
783 cls final_cls_tys tc final_tc_args Nothing
784 ; return [spec] } }
785
786
787 {-
788 Note [Unify kinds in deriving]
789 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
790 Consider (Trac #8534)
791 data T a b = MkT a deriving( Functor )
792 -- where Functor :: (*->*) -> Constraint
793
794 So T :: forall k. * -> k -> *. We want to get
795 instance Functor (T * (a:*)) where ...
796 Notice the '*' argument to T.
797
798 Moreover, as well as instantiating T's kind arguments, we may need to instantiate
799 C's kind args. Consider (Trac #8865):
800 newtype T a b = MkT (Either a b) deriving( Category )
801 where
802 Category :: forall k. (k -> k -> *) -> Constraint
803 We need to generate the instance
804 instance Category * (Either a) where ...
805 Notice the '*' argument to Category.
806
807 So we need to
808 * drop arguments from (T a b) to match the number of
809 arrows in the (last argument of the) class;
810 * and then *unify* kind of the remaining type against the
811 expected kind, to figure out how to instantiate C's and T's
812 kind arguments.
813
814 In the two examples,
815 * we unify kind-of( T k (a:k) ) ~ kind-of( Functor )
816 i.e. (k -> *) ~ (* -> *) to find k:=*.
817 yielding k:=*
818
819 * we unify kind-of( Either ) ~ kind-of( Category )
820 i.e. (* -> * -> *) ~ (k -> k -> k)
821 yielding k:=*
822
823 Now we get a kind substitution. We then need to:
824
825 1. Remove the substituted-out kind variables from the quantified kind vars
826
827 2. Apply the substitution to the kinds of quantified *type* vars
828 (and extend the substitution to reflect this change)
829
830 3. Apply that extended substitution to the non-dropped args (types and
831 kinds) of the type and class
832
833 Forgetting step (2) caused Trac #8893:
834 data V a = V [a] deriving Functor
835 data P (x::k->*) (a:k) = P (x a) deriving Functor
836 data C (x::k->*) (a:k) = C (V (P x a)) deriving Functor
837
838 When deriving Functor for P, we unify k to *, but we then want
839 an instance $df :: forall (x:*->*). Functor x => Functor (P * (x:*->*))
840 and similarly for C. Notice the modified kind of x, both at binding
841 and occurrence sites.
842 -}
843
844 mkEqnHelp :: Maybe OverlapMode
845 -> [TyVar]
846 -> Class -> [Type]
847 -> TyCon -> [Type]
848 -> DerivContext -- Just => context supplied (standalone deriving)
849 -- Nothing => context inferred (deriving on data decl)
850 -> TcRn EarlyDerivSpec
851 -- Make the EarlyDerivSpec for an instance
852 -- forall tvs. theta => cls (tys ++ [ty])
853 -- where the 'theta' is optional (that's the Maybe part)
854 -- Assumes that this declaration is well-kinded
855
856 mkEqnHelp overlap_mode tvs cls cls_tys tycon tc_args mtheta
857 = do { -- Find the instance of a data family
858 -- Note [Looking up family instances for deriving]
859 fam_envs <- tcGetFamInstEnvs
860 ; let (rep_tc, rep_tc_args, _co) = tcLookupDataFamInst fam_envs tycon tc_args
861
862 -- If it's still a data family, the lookup failed; i.e no instance exists
863 ; when (isDataFamilyTyCon rep_tc)
864 (bale_out (ptext (sLit "No family instance for") <+> quotes (pprTypeApp tycon tc_args)))
865
866 -- For standalone deriving (mtheta /= Nothing),
867 -- check that all the data constructors are in scope.
868 ; rdr_env <- getGlobalRdrEnv
869 ; let data_con_names = map dataConName (tyConDataCons rep_tc)
870 hidden_data_cons = not (isWiredInName (tyConName rep_tc)) &&
871 (isAbstractTyCon rep_tc ||
872 any not_in_scope data_con_names)
873 not_in_scope dc = null (lookupGRE_Name rdr_env dc)
874
875 -- Make a Qual RdrName that will do for each DataCon
876 -- so we can report it as used (Trac #7969)
877 data_con_rdrs = [ mkRdrQual (is_as (is_decl imp_spec)) occ
878 | dc_name <- data_con_names
879 , let occ = nameOccName dc_name
880 gres = lookupGRE_Name rdr_env dc_name
881 , not (null gres)
882 , Imported (imp_spec:_) <- [gre_prov (head gres)] ]
883
884 ; addUsedRdrNames data_con_rdrs
885 ; unless (isNothing mtheta || not hidden_data_cons)
886 (bale_out (derivingHiddenErr tycon))
887
888 ; dflags <- getDynFlags
889 ; if isDataTyCon rep_tc then
890 mkDataTypeEqn dflags overlap_mode tvs cls cls_tys
891 tycon tc_args rep_tc rep_tc_args mtheta
892 else
893 mkNewTypeEqn dflags overlap_mode tvs cls cls_tys
894 tycon tc_args rep_tc rep_tc_args mtheta }
895 where
896 bale_out msg = failWithTc (derivingThingErr False cls cls_tys (mkTyConApp tycon tc_args) msg)
897
898 {-
899 Note [Looking up family instances for deriving]
900 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
901 tcLookupFamInstExact is an auxiliary lookup wrapper which requires
902 that looked-up family instances exist. If called with a vanilla
903 tycon, the old type application is simply returned.
904
905 If we have
906 data instance F () = ... deriving Eq
907 data instance F () = ... deriving Eq
908 then tcLookupFamInstExact will be confused by the two matches;
909 but that can't happen because tcInstDecls1 doesn't call tcDeriving
910 if there are any overlaps.
911
912 There are two other things that might go wrong with the lookup.
913 First, we might see a standalone deriving clause
914 deriving Eq (F ())
915 when there is no data instance F () in scope.
916
917 Note that it's OK to have
918 data instance F [a] = ...
919 deriving Eq (F [(a,b)])
920 where the match is not exact; the same holds for ordinary data types
921 with standalone deriving declarations.
922
923 Note [Deriving, type families, and partial applications]
924 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
925 When there are no type families, it's quite easy:
926
927 newtype S a = MkS [a]
928 -- :CoS :: S ~ [] -- Eta-reduced
929
930 instance Eq [a] => Eq (S a) -- by coercion sym (Eq (:CoS a)) : Eq [a] ~ Eq (S a)
931 instance Monad [] => Monad S -- by coercion sym (Monad :CoS) : Monad [] ~ Monad S
932
933 When type familes are involved it's trickier:
934
935 data family T a b
936 newtype instance T Int a = MkT [a] deriving( Eq, Monad )
937 -- :RT is the representation type for (T Int a)
938 -- :Co:RT :: :RT ~ [] -- Eta-reduced!
939 -- :CoF:RT a :: T Int a ~ :RT a -- Also eta-reduced!
940
941 instance Eq [a] => Eq (T Int a) -- easy by coercion
942 -- d1 :: Eq [a]
943 -- d2 :: Eq (T Int a) = d1 |> Eq (sym (:Co:RT a ; :coF:RT a))
944
945 instance Monad [] => Monad (T Int) -- only if we can eta reduce???
946 -- d1 :: Monad []
947 -- d2 :: Monad (T Int) = d1 |> Monad (sym (:Co:RT ; :coF:RT))
948
949 Note the need for the eta-reduced rule axioms. After all, we can
950 write it out
951 instance Monad [] => Monad (T Int) -- only if we can eta reduce???
952 return x = MkT [x]
953 ... etc ...
954
955 See Note [Eta reduction for data family axioms] in TcInstDcls.
956
957
958 ************************************************************************
959 * *
960 Deriving data types
961 * *
962 ************************************************************************
963 -}
964
965 mkDataTypeEqn :: DynFlags
966 -> Maybe OverlapMode
967 -> [Var] -- Universally quantified type variables in the instance
968 -> Class -- Class for which we need to derive an instance
969 -> [Type] -- Other parameters to the class except the last
970 -> TyCon -- Type constructor for which the instance is requested
971 -- (last parameter to the type class)
972 -> [Type] -- Parameters to the type constructor
973 -> TyCon -- rep of the above (for type families)
974 -> [Type] -- rep of the above
975 -> DerivContext -- Context of the instance, for standalone deriving
976 -> TcRn EarlyDerivSpec -- Return 'Nothing' if error
977
978 mkDataTypeEqn dflags overlap_mode tvs cls cls_tys
979 tycon tc_args rep_tc rep_tc_args mtheta
980 = case checkSideConditions dflags mtheta cls cls_tys rep_tc rep_tc_args of
981 -- NB: pass the *representation* tycon to checkSideConditions
982 NonDerivableClass msg -> bale_out (nonStdErr cls $$ msg)
983 DerivableClassError msg -> bale_out msg
984 CanDerive -> go_for_it
985 DerivableViaInstance -> go_for_it
986 where
987 go_for_it = mk_data_eqn overlap_mode tvs cls tycon tc_args rep_tc rep_tc_args mtheta
988 bale_out msg = failWithTc (derivingThingErr False cls cls_tys (mkTyConApp tycon tc_args) msg)
989
990 mk_data_eqn :: Maybe OverlapMode -> [TyVar] -> Class
991 -> TyCon -> [TcType] -> TyCon -> [TcType] -> DerivContext
992 -> TcM EarlyDerivSpec
993 mk_data_eqn overlap_mode tvs cls tycon tc_args rep_tc rep_tc_args mtheta
994 = do loc <- getSrcSpanM
995 dfun_name <- new_dfun_name cls tycon
996 case mtheta of
997 Nothing -> do --Infer context
998 inferred_constraints <- inferConstraints cls inst_tys rep_tc rep_tc_args
999 return $ InferTheta $ DS
1000 { ds_loc = loc
1001 , ds_name = dfun_name, ds_tvs = tvs
1002 , ds_cls = cls, ds_tys = inst_tys
1003 , ds_tc = rep_tc, ds_tc_args = rep_tc_args
1004 , ds_theta = inferred_constraints
1005 , ds_overlap = overlap_mode
1006 , ds_newtype = False }
1007 Just theta -> do -- Specified context
1008 return $ GivenTheta $ DS
1009 { ds_loc = loc
1010 , ds_name = dfun_name, ds_tvs = tvs
1011 , ds_cls = cls, ds_tys = inst_tys
1012 , ds_tc = rep_tc, ds_tc_args = rep_tc_args
1013 , ds_theta = theta
1014 , ds_overlap = overlap_mode
1015 , ds_newtype = False }
1016 where
1017 inst_tys = [mkTyConApp tycon tc_args]
1018
1019 ----------------------
1020
1021 inferConstraints :: Class -> [TcType]
1022 -> TyCon -> [TcType]
1023 -> TcM ThetaOrigin
1024 -- Generate a sufficiently large set of constraints that typechecking the
1025 -- generated method definitions should succeed. This set will be simplified
1026 -- before being used in the instance declaration
1027 inferConstraints cls inst_tys rep_tc rep_tc_args
1028 | cls `hasKey` genClassKey -- Generic constraints are easy
1029 = return []
1030
1031 | cls `hasKey` gen1ClassKey -- Gen1 needs Functor
1032 = ASSERT(length rep_tc_tvs > 0) -- See Note [Getting base classes]
1033 do { functorClass <- tcLookupClass functorClassName
1034 ; return (con_arg_constraints functorClass (get_gen1_constrained_tys last_tv)) }
1035
1036 | otherwise -- The others are a bit more complicated
1037 = ASSERT2( equalLength rep_tc_tvs all_rep_tc_args, ppr cls <+> ppr rep_tc )
1038 do { traceTc "inferConstraints" (vcat [ppr cls <+> ppr inst_tys, ppr arg_constraints])
1039 ; return (stupid_constraints ++ extra_constraints
1040 ++ sc_constraints
1041 ++ arg_constraints) }
1042 where
1043 arg_constraints = con_arg_constraints cls get_std_constrained_tys
1044
1045 -- Constraints arising from the arguments of each constructor
1046 con_arg_constraints cls' get_constrained_tys
1047 = [ mkPredOrigin (DerivOriginDC data_con arg_n) (mkClassPred cls' [inner_ty])
1048 | data_con <- tyConDataCons rep_tc
1049 , (arg_n, arg_ty) <- ASSERT( isVanillaDataCon data_con )
1050 zip [1..] $ -- ASSERT is precondition of dataConInstOrigArgTys
1051 dataConInstOrigArgTys data_con all_rep_tc_args
1052 , not (isUnLiftedType arg_ty)
1053 , inner_ty <- get_constrained_tys arg_ty ]
1054
1055 -- No constraints for unlifted types
1056 -- See Note [Deriving and unboxed types]
1057
1058 -- For functor-like classes, two things are different
1059 -- (a) We recurse over argument types to generate constraints
1060 -- See Functor examples in TcGenDeriv
1061 -- (b) The rep_tc_args will be one short
1062 is_functor_like = getUnique cls `elem` functorLikeClassKeys
1063 || onlyOneAndTypeConstr inst_tys
1064 onlyOneAndTypeConstr [inst_ty] =
1065 typeKind inst_ty `tcEqKind` mkArrowKind liftedTypeKind liftedTypeKind
1066 onlyOneAndTypeConstr _ = False
1067
1068 get_std_constrained_tys :: Type -> [Type]
1069 get_std_constrained_tys ty
1070 | is_functor_like = deepSubtypesContaining last_tv ty
1071 | otherwise = [ty]
1072
1073 rep_tc_tvs = tyConTyVars rep_tc
1074 last_tv = last rep_tc_tvs
1075 all_rep_tc_args | cls `hasKey` gen1ClassKey || is_functor_like
1076 = rep_tc_args ++ [mkTyVarTy last_tv]
1077 | otherwise = rep_tc_args
1078
1079 -- Constraints arising from superclasses
1080 -- See Note [Superclasses of derived instance]
1081 sc_constraints = mkThetaOrigin DerivOrigin $
1082 substTheta (zipOpenTvSubst (classTyVars cls) inst_tys) (classSCTheta cls)
1083
1084 -- Stupid constraints
1085 stupid_constraints = mkThetaOrigin DerivOrigin $
1086 substTheta subst (tyConStupidTheta rep_tc)
1087 subst = zipTopTvSubst rep_tc_tvs all_rep_tc_args
1088
1089 -- Extra Data constraints
1090 -- The Data class (only) requires that for
1091 -- instance (...) => Data (T t1 t2)
1092 -- IF t1:*, t2:*
1093 -- THEN (Data t1, Data t2) are among the (...) constraints
1094 -- Reason: when the IF holds, we generate a method
1095 -- dataCast2 f = gcast2 f
1096 -- and we need the Data constraints to typecheck the method
1097 extra_constraints
1098 | cls `hasKey` dataClassKey
1099 , all (isLiftedTypeKind . typeKind) rep_tc_args
1100 = [mkPredOrigin DerivOrigin (mkClassPred cls [ty]) | ty <- rep_tc_args]
1101 | otherwise
1102 = []
1103
1104 {-
1105 Note [Getting base classes]
1106 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
1107 Functor and Typeable are defined in package 'base', and that is not available
1108 when compiling 'ghc-prim'. So we must be careful that 'deriving' for stuff in
1109 ghc-prim does not use Functor or Typeable implicitly via these lookups.
1110
1111 Note [Deriving and unboxed types]
1112 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1113 We have some special hacks to support things like
1114 data T = MkT Int# deriving ( Show )
1115
1116 Specifically, we use TcGenDeriv.box to box the Int# into an Int
1117 (which we know how to show), and append a '#'. Parenthesis are not required
1118 for unboxed values (`MkT -3#` is a valid expression).
1119
1120 Note [Deriving any class]
1121 ~~~~~~~~~~~~~~~~~~~~~~~~~
1122 Classic uses of a deriving clause, or a standalone-deriving declaration, are
1123 for:
1124 * a built-in class like Eq or Show, for which GHC knows how to generate
1125 the instance code
1126 * a newtype, via the mechanism enabled by GeneralizedNewtypeDeriving
1127
1128 The DeriveAnyClass extension adds a third way to derive instances, based on
1129 empty instance declarations.
1130
1131 The canonical use case is in combination with GHC.Generics and default method
1132 signatures. These allow us have have instance declarations be empty, but still
1133 useful, e.g.
1134
1135 data T a = ...blah..blah... deriving( Generic )
1136 instance C a => C (T a) -- No 'where' clause
1137
1138 where C is some "random" user-defined class.
1139
1140 This boilerplate code can be replaced by the more compact
1141
1142 data T a = ...blah..blah... deriving( Generic, C )
1143
1144 if DeriveAnyClass is enabled.
1145
1146 This is not restricted to Generics; any class can be derived, simply giving
1147 rise to an empty instance.
1148
1149 Unfortunately, it is not clear how to determine the context (in case of
1150 standard deriving; in standalone deriving, the user provides the context).
1151 GHC uses the same heuristic for figuring out the class context that it uses for
1152 Eq in the case of *-kinded classes, and for Functor in the case of
1153 * -> *-kinded classes. That may not be optimal or even wrong. But in such
1154 cases, standalone deriving can still be used.
1155 -}
1156
1157 ------------------------------------------------------------------
1158 -- Check side conditions that dis-allow derivability for particular classes
1159 -- This is *apart* from the newtype-deriving mechanism
1160 --
1161 -- Here we get the representation tycon in case of family instances as it has
1162 -- the data constructors - but we need to be careful to fall back to the
1163 -- family tycon (with indexes) in error messages.
1164
1165 data DerivStatus = CanDerive
1166 | DerivableClassError SDoc -- Standard class, but can't do it
1167 | DerivableViaInstance -- See Note [Deriving any class]
1168 | NonDerivableClass SDoc -- Non-standard class
1169
1170 checkSideConditions :: DynFlags -> DerivContext -> Class -> [TcType]
1171 -> TyCon -> [Type] -- tycon and its parameters
1172 -> DerivStatus
1173 checkSideConditions dflags mtheta cls cls_tys rep_tc rep_tc_args
1174 | Just cond <- sideConditions mtheta cls
1175 = case (cond (dflags, rep_tc, rep_tc_args)) of
1176 NotValid err -> DerivableClassError err -- Class-specific error
1177 IsValid | null cls_tys -> CanDerive -- All derivable classes are unary, so
1178 -- cls_tys (the type args other than last)
1179 -- should be null
1180 | otherwise -> DerivableClassError (classArgsErr cls cls_tys) -- e.g. deriving( Eq s )
1181 | otherwise = maybe DerivableViaInstance NonDerivableClass
1182 (canDeriveAnyClass dflags rep_tc cls)
1183
1184 classArgsErr :: Class -> [Type] -> SDoc
1185 classArgsErr cls cls_tys = quotes (ppr (mkClassPred cls cls_tys)) <+> ptext (sLit "is not a class")
1186
1187 nonStdErr :: Class -> SDoc
1188 nonStdErr cls = quotes (ppr cls) <+> ptext (sLit "is not a derivable class")
1189
1190 sideConditions :: DerivContext -> Class -> Maybe Condition
1191 sideConditions mtheta cls
1192 | cls_key == eqClassKey = Just (cond_std `andCond` cond_args cls)
1193 | cls_key == ordClassKey = Just (cond_std `andCond` cond_args cls)
1194 | cls_key == showClassKey = Just (cond_std `andCond` cond_args cls)
1195 | cls_key == readClassKey = Just (cond_std `andCond` cond_args cls)
1196 | cls_key == enumClassKey = Just (cond_std `andCond` cond_isEnumeration)
1197 | cls_key == ixClassKey = Just (cond_std `andCond` cond_enumOrProduct cls)
1198 | cls_key == boundedClassKey = Just (cond_std `andCond` cond_enumOrProduct cls)
1199 | cls_key == dataClassKey = Just (checkFlag Opt_DeriveDataTypeable `andCond`
1200 cond_std `andCond`
1201 cond_args cls)
1202 | cls_key == functorClassKey = Just (checkFlag Opt_DeriveFunctor `andCond`
1203 cond_vanilla `andCond`
1204 cond_functorOK True)
1205 | cls_key == foldableClassKey = Just (checkFlag Opt_DeriveFoldable `andCond`
1206 cond_vanilla `andCond`
1207 cond_functorOK False) -- Functor/Fold/Trav works ok for rank-n types
1208 | cls_key == traversableClassKey = Just (checkFlag Opt_DeriveTraversable `andCond`
1209 cond_vanilla `andCond`
1210 cond_functorOK False)
1211 | cls_key == genClassKey = Just (checkFlag Opt_DeriveGeneric `andCond`
1212 cond_vanilla `andCond`
1213 cond_RepresentableOk)
1214 | cls_key == gen1ClassKey = Just (checkFlag Opt_DeriveGeneric `andCond`
1215 cond_vanilla `andCond`
1216 cond_Representable1Ok)
1217 | otherwise = Nothing
1218 where
1219 cls_key = getUnique cls
1220 cond_std = cond_stdOK mtheta False -- Vanilla data constructors, at least one,
1221 -- and monotype arguments
1222 cond_vanilla = cond_stdOK mtheta True -- Vanilla data constructors but
1223 -- allow no data cons or polytype arguments
1224
1225 type Condition = (DynFlags, TyCon, [Type]) -> Validity
1226 -- first Bool is whether or not we are allowed to derive Data and Typeable
1227 -- second Bool is whether or not we are allowed to derive Functor
1228 -- TyCon is the *representation* tycon if the data type is an indexed one
1229 -- [Type] are the type arguments to the (representation) TyCon
1230 -- Nothing => OK
1231
1232 orCond :: Condition -> Condition -> Condition
1233 orCond c1 c2 tc
1234 = case (c1 tc, c2 tc) of
1235 (IsValid, _) -> IsValid -- c1 succeeds
1236 (_, IsValid) -> IsValid -- c21 succeeds
1237 (NotValid x, NotValid y) -> NotValid (x $$ ptext (sLit " or") $$ y)
1238 -- Both fail
1239
1240 andCond :: Condition -> Condition -> Condition
1241 andCond c1 c2 tc = c1 tc `andValid` c2 tc
1242
1243 cond_stdOK :: DerivContext -- Says whether this is standalone deriving or not;
1244 -- if standalone, we just say "yes, go for it"
1245 -> Bool -- True <=> permissive: allow higher rank
1246 -- args and no data constructors
1247 -> Condition
1248 cond_stdOK (Just _) _ _
1249 = IsValid -- Don't check these conservative conditions for
1250 -- standalone deriving; just generate the code
1251 -- and let the typechecker handle the result
1252 cond_stdOK Nothing permissive (_, rep_tc, _)
1253 | null data_cons
1254 , not permissive = NotValid (no_cons_why rep_tc $$ suggestion)
1255 | not (null con_whys) = NotValid (vcat con_whys $$ suggestion)
1256 | otherwise = IsValid
1257 where
1258 suggestion = ptext (sLit "Possible fix: use a standalone deriving declaration instead")
1259 data_cons = tyConDataCons rep_tc
1260 con_whys = getInvalids (map check_con data_cons)
1261
1262 check_con :: DataCon -> Validity
1263 check_con con
1264 | not (isVanillaDataCon con)
1265 = NotValid (badCon con (ptext (sLit "has existentials or constraints in its type")))
1266 | not (permissive || all isTauTy (dataConOrigArgTys con))
1267 = NotValid (badCon con (ptext (sLit "has a higher-rank type")))
1268 | otherwise
1269 = IsValid
1270
1271 no_cons_why :: TyCon -> SDoc
1272 no_cons_why rep_tc = quotes (pprSourceTyCon rep_tc) <+>
1273 ptext (sLit "must have at least one data constructor")
1274
1275 cond_RepresentableOk :: Condition
1276 cond_RepresentableOk (_, tc, tc_args) = canDoGenerics tc tc_args
1277
1278 cond_Representable1Ok :: Condition
1279 cond_Representable1Ok (_, tc, tc_args) = canDoGenerics1 tc tc_args
1280
1281 cond_enumOrProduct :: Class -> Condition
1282 cond_enumOrProduct cls = cond_isEnumeration `orCond`
1283 (cond_isProduct `andCond` cond_args cls)
1284
1285 cond_args :: Class -> Condition
1286 -- For some classes (eg Eq, Ord) we allow unlifted arg types
1287 -- by generating specialised code. For others (eg Data) we don't.
1288 cond_args cls (_, tc, _)
1289 = case bad_args of
1290 [] -> IsValid
1291 (ty:_) -> NotValid (hang (ptext (sLit "Don't know how to derive") <+> quotes (ppr cls))
1292 2 (ptext (sLit "for type") <+> quotes (ppr ty)))
1293 where
1294 bad_args = [ arg_ty | con <- tyConDataCons tc
1295 , arg_ty <- dataConOrigArgTys con
1296 , isUnLiftedType arg_ty
1297 , not (ok_ty arg_ty) ]
1298
1299 cls_key = classKey cls
1300 ok_ty arg_ty
1301 | cls_key == eqClassKey = check_in arg_ty ordOpTbl
1302 | cls_key == ordClassKey = check_in arg_ty ordOpTbl
1303 | cls_key == showClassKey = check_in arg_ty boxConTbl
1304 | otherwise = False -- Read, Ix etc
1305
1306 check_in :: Type -> [(Type,a)] -> Bool
1307 check_in arg_ty tbl = any (eqType arg_ty . fst) tbl
1308
1309
1310 cond_isEnumeration :: Condition
1311 cond_isEnumeration (_, rep_tc, _)
1312 | isEnumerationTyCon rep_tc = IsValid
1313 | otherwise = NotValid why
1314 where
1315 why = sep [ quotes (pprSourceTyCon rep_tc) <+>
1316 ptext (sLit "must be an enumeration type")
1317 , ptext (sLit "(an enumeration consists of one or more nullary, non-GADT constructors)") ]
1318 -- See Note [Enumeration types] in TyCon
1319
1320 cond_isProduct :: Condition
1321 cond_isProduct (_, rep_tc, _)
1322 | isProductTyCon rep_tc = IsValid
1323 | otherwise = NotValid why
1324 where
1325 why = quotes (pprSourceTyCon rep_tc) <+>
1326 ptext (sLit "must have precisely one constructor")
1327
1328 functorLikeClassKeys :: [Unique]
1329 functorLikeClassKeys = [functorClassKey, foldableClassKey, traversableClassKey]
1330
1331 cond_functorOK :: Bool -> Condition
1332 -- OK for Functor/Foldable/Traversable class
1333 -- Currently: (a) at least one argument
1334 -- (b) don't use argument contravariantly
1335 -- (c) don't use argument in the wrong place, e.g. data T a = T (X a a)
1336 -- (d) optionally: don't use function types
1337 -- (e) no "stupid context" on data type
1338 cond_functorOK allowFunctions (_, rep_tc, _)
1339 | null tc_tvs
1340 = NotValid (ptext (sLit "Data type") <+> quotes (ppr rep_tc)
1341 <+> ptext (sLit "must have some type parameters"))
1342
1343 | not (null bad_stupid_theta)
1344 = NotValid (ptext (sLit "Data type") <+> quotes (ppr rep_tc)
1345 <+> ptext (sLit "must not have a class context:") <+> pprTheta bad_stupid_theta)
1346
1347 | otherwise
1348 = allValid (map check_con data_cons)
1349 where
1350 tc_tvs = tyConTyVars rep_tc
1351 Just (_, last_tv) = snocView tc_tvs
1352 bad_stupid_theta = filter is_bad (tyConStupidTheta rep_tc)
1353 is_bad pred = last_tv `elemVarSet` tyVarsOfType pred
1354
1355 data_cons = tyConDataCons rep_tc
1356 check_con con = allValid (check_universal con : foldDataConArgs (ft_check con) con)
1357
1358 check_universal :: DataCon -> Validity
1359 check_universal con
1360 | Just tv <- getTyVar_maybe (last (tyConAppArgs (dataConOrigResTy con)))
1361 , tv `elem` dataConUnivTyVars con
1362 , not (tv `elemVarSet` tyVarsOfTypes (dataConTheta con))
1363 = IsValid -- See Note [Check that the type variable is truly universal]
1364 | otherwise
1365 = NotValid (badCon con existential)
1366
1367 ft_check :: DataCon -> FFoldType Validity
1368 ft_check con = FT { ft_triv = IsValid, ft_var = IsValid
1369 , ft_co_var = NotValid (badCon con covariant)
1370 , ft_fun = \x y -> if allowFunctions then x `andValid` y
1371 else NotValid (badCon con functions)
1372 , ft_tup = \_ xs -> allValid xs
1373 , ft_ty_app = \_ x -> x
1374 , ft_bad_app = NotValid (badCon con wrong_arg)
1375 , ft_forall = \_ x -> x }
1376
1377 existential = ptext (sLit "must be truly polymorphic in the last argument of the data type")
1378 covariant = ptext (sLit "must not use the type variable in a function argument")
1379 functions = ptext (sLit "must not contain function types")
1380 wrong_arg = ptext (sLit "must use the type variable only as the last argument of a data type")
1381
1382 checkFlag :: ExtensionFlag -> Condition
1383 checkFlag flag (dflags, _, _)
1384 | xopt flag dflags = IsValid
1385 | otherwise = NotValid why
1386 where
1387 why = ptext (sLit "You need ") <> text flag_str
1388 <+> ptext (sLit "to derive an instance for this class")
1389 flag_str = case [ flagSpecName f | f <- xFlags , flagSpecFlag f == flag ] of
1390 [s] -> s
1391 other -> pprPanic "checkFlag" (ppr other)
1392
1393 std_class_via_coercible :: Class -> Bool
1394 -- These standard classes can be derived for a newtype
1395 -- using the coercible trick *even if no -XGeneralizedNewtypeDeriving
1396 -- because giving so gives the same results as generating the boilerplate
1397 std_class_via_coercible clas
1398 = classKey clas `elem` [eqClassKey, ordClassKey, ixClassKey, boundedClassKey]
1399 -- Not Read/Show because they respect the type
1400 -- Not Enum, because newtypes are never in Enum
1401
1402
1403 non_coercible_class :: Class -> Bool
1404 -- *Never* derive Read, Show, Typeable, Data, Generic, Generic1 by Coercible,
1405 -- even with -XGeneralizedNewtypeDeriving
1406 -- Also, avoid Traversable, as the Coercible-derived instance and the "normal"-derived
1407 -- instance behave differently if there's a non-lawful Applicative out there.
1408 -- Besides, with roles, Coercible-deriving Traversable is ill-roled.
1409 non_coercible_class cls
1410 = classKey cls `elem` ([ readClassKey, showClassKey, dataClassKey
1411 , genClassKey, gen1ClassKey, typeableClassKey
1412 , traversableClassKey ])
1413
1414 new_dfun_name :: Class -> TyCon -> TcM Name
1415 new_dfun_name clas tycon -- Just a simple wrapper
1416 = do { loc <- getSrcSpanM -- The location of the instance decl, not of the tycon
1417 ; newDFunName clas [mkTyConApp tycon []] loc }
1418 -- The type passed to newDFunName is only used to generate
1419 -- a suitable string; hence the empty type arg list
1420
1421 badCon :: DataCon -> SDoc -> SDoc
1422 badCon con msg = ptext (sLit "Constructor") <+> quotes (ppr con) <+> msg
1423
1424 {-
1425 Note [Check that the type variable is truly universal]
1426 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1427 For Functor, Foldable, Traversable, we must check that the *last argument*
1428 of the type constructor is used truly universally quantified. Example
1429
1430 data T a b where
1431 T1 :: a -> b -> T a b -- Fine! Vanilla H-98
1432 T2 :: b -> c -> T a b -- Fine! Existential c, but we can still map over 'b'
1433 T3 :: b -> T Int b -- Fine! Constraint 'a', but 'b' is still polymorphic
1434 T4 :: Ord b => b -> T a b -- No! 'b' is constrained
1435 T5 :: b -> T b b -- No! 'b' is constrained
1436 T6 :: T a (b,b) -- No! 'b' is constrained
1437
1438 Notice that only the first of these constructors is vanilla H-98. We only
1439 need to take care about the last argument (b in this case). See Trac #8678.
1440 Eg. for T1-T3 we can write
1441
1442 fmap f (T1 a b) = T1 a (f b)
1443 fmap f (T2 b c) = T2 (f b) c
1444 fmap f (T3 x) = T3 (f x)
1445
1446
1447 Note [Superclasses of derived instance]
1448 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1449 In general, a derived instance decl needs the superclasses of the derived
1450 class too. So if we have
1451 data T a = ...deriving( Ord )
1452 then the initial context for Ord (T a) should include Eq (T a). Often this is
1453 redundant; we'll also generate an Ord constraint for each constructor argument,
1454 and that will probably generate enough constraints to make the Eq (T a) constraint
1455 be satisfied too. But not always; consider:
1456
1457 data S a = S
1458 instance Eq (S a)
1459 instance Ord (S a)
1460
1461 data T a = MkT (S a) deriving( Ord )
1462 instance Num a => Eq (T a)
1463
1464 The derived instance for (Ord (T a)) must have a (Num a) constraint!
1465 Similarly consider:
1466 data T a = MkT deriving( Data, Typeable )
1467 Here there *is* no argument field, but we must nevertheless generate
1468 a context for the Data instances:
1469 instance Typable a => Data (T a) where ...
1470
1471
1472 ************************************************************************
1473 * *
1474 Deriving newtypes
1475 * *
1476 ************************************************************************
1477 -}
1478
1479 mkNewTypeEqn :: DynFlags -> Maybe OverlapMode -> [Var] -> Class
1480 -> [Type] -> TyCon -> [Type] -> TyCon -> [Type]
1481 -> DerivContext
1482 -> TcRn EarlyDerivSpec
1483 mkNewTypeEqn dflags overlap_mode tvs
1484 cls cls_tys tycon tc_args rep_tycon rep_tc_args mtheta
1485 -- Want: instance (...) => cls (cls_tys ++ [tycon tc_args]) where ...
1486 | ASSERT( length cls_tys + 1 == classArity cls )
1487 might_derive_via_coercible && ((newtype_deriving && not deriveAnyClass)
1488 || std_class_via_coercible cls)
1489 = do traceTc "newtype deriving:" (ppr tycon <+> ppr rep_tys <+> ppr all_preds)
1490 dfun_name <- new_dfun_name cls tycon
1491 loc <- getSrcSpanM
1492 case mtheta of
1493 Just theta -> return $ GivenTheta $ DS
1494 { ds_loc = loc
1495 , ds_name = dfun_name, ds_tvs = varSetElemsKvsFirst dfun_tvs
1496 , ds_cls = cls, ds_tys = inst_tys
1497 , ds_tc = rep_tycon, ds_tc_args = rep_tc_args
1498 , ds_theta = theta
1499 , ds_overlap = overlap_mode
1500 , ds_newtype = True }
1501 Nothing -> return $ InferTheta $ DS
1502 { ds_loc = loc
1503 , ds_name = dfun_name, ds_tvs = varSetElemsKvsFirst dfun_tvs
1504 , ds_cls = cls, ds_tys = inst_tys
1505 , ds_tc = rep_tycon, ds_tc_args = rep_tc_args
1506 , ds_theta = all_preds
1507 , ds_overlap = overlap_mode
1508 , ds_newtype = True }
1509 | otherwise
1510 = case checkSideConditions dflags mtheta cls cls_tys rep_tycon rep_tc_args of
1511 -- Error with standard class
1512 DerivableClassError msg
1513 | might_derive_via_coercible -> bale_out (msg $$ suggest_nd)
1514 | otherwise -> bale_out msg
1515 -- Must use newtype deriving or DeriveAnyClass
1516 NonDerivableClass _msg
1517 -- Too hard, even with newtype deriving
1518 | newtype_deriving -> bale_out cant_derive_err
1519 -- Try newtype deriving!
1520 | might_derive_via_coercible -> bale_out (non_std $$ suggest_nd)
1521 | otherwise -> bale_out non_std
1522 -- CanDerive/DerivableViaInstance
1523 _ -> do when (newtype_deriving && deriveAnyClass) $
1524 addWarnTc (sep [ ptext (sLit "Both DeriveAnyClass and GeneralizedNewtypeDeriving are enabled")
1525 , ptext (sLit "Defaulting to the DeriveAnyClass strategy for instantiating") <+> ppr cls ])
1526 go_for_it
1527 where
1528 newtype_deriving = xopt Opt_GeneralizedNewtypeDeriving dflags
1529 deriveAnyClass = xopt Opt_DeriveAnyClass dflags
1530 go_for_it = mk_data_eqn overlap_mode tvs cls tycon tc_args
1531 rep_tycon rep_tc_args mtheta
1532 bale_out = bale_out' newtype_deriving
1533 bale_out' b = failWithTc . derivingThingErr b cls cls_tys inst_ty
1534
1535 non_std = nonStdErr cls
1536 suggest_nd = ptext (sLit "Try GeneralizedNewtypeDeriving for GHC's newtype-deriving extension")
1537
1538 -- Here is the plan for newtype derivings. We see
1539 -- newtype T a1...an = MkT (t ak+1...an) deriving (.., C s1 .. sm, ...)
1540 -- where t is a type,
1541 -- ak+1...an is a suffix of a1..an, and are all tyars
1542 -- ak+1...an do not occur free in t, nor in the s1..sm
1543 -- (C s1 ... sm) is a *partial applications* of class C
1544 -- with the last parameter missing
1545 -- (T a1 .. ak) matches the kind of C's last argument
1546 -- (and hence so does t)
1547 -- The latter kind-check has been done by deriveTyData already,
1548 -- and tc_args are already trimmed
1549 --
1550 -- We generate the instance
1551 -- instance forall ({a1..ak} u fvs(s1..sm)).
1552 -- C s1 .. sm t => C s1 .. sm (T a1...ak)
1553 -- where T a1...ap is the partial application of
1554 -- the LHS of the correct kind and p >= k
1555 --
1556 -- NB: the variables below are:
1557 -- tc_tvs = [a1, ..., an]
1558 -- tyvars_to_keep = [a1, ..., ak]
1559 -- rep_ty = t ak .. an
1560 -- deriv_tvs = fvs(s1..sm) \ tc_tvs
1561 -- tys = [s1, ..., sm]
1562 -- rep_fn' = t
1563 --
1564 -- Running example: newtype T s a = MkT (ST s a) deriving( Monad )
1565 -- We generate the instance
1566 -- instance Monad (ST s) => Monad (T s) where
1567
1568 nt_eta_arity = newTyConEtadArity rep_tycon
1569 -- For newtype T a b = MkT (S a a b), the TyCon machinery already
1570 -- eta-reduces the representation type, so we know that
1571 -- T a ~ S a a
1572 -- That's convenient here, because we may have to apply
1573 -- it to fewer than its original complement of arguments
1574
1575 -- Note [Newtype representation]
1576 -- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1577 -- Need newTyConRhs (*not* a recursive representation finder)
1578 -- to get the representation type. For example
1579 -- newtype B = MkB Int
1580 -- newtype A = MkA B deriving( Num )
1581 -- We want the Num instance of B, *not* the Num instance of Int,
1582 -- when making the Num instance of A!
1583 rep_inst_ty = newTyConInstRhs rep_tycon rep_tc_args
1584 rep_tys = cls_tys ++ [rep_inst_ty]
1585 rep_pred = mkClassPred cls rep_tys
1586 rep_pred_o = mkPredOrigin DerivOrigin rep_pred
1587 -- rep_pred is the representation dictionary, from where
1588 -- we are gong to get all the methods for the newtype
1589 -- dictionary
1590
1591
1592 -- Next we figure out what superclass dictionaries to use
1593 -- See Note [Newtype deriving superclasses] above
1594
1595 cls_tyvars = classTyVars cls
1596 dfun_tvs = tyVarsOfTypes inst_tys
1597 inst_ty = mkTyConApp tycon tc_args
1598 inst_tys = cls_tys ++ [inst_ty]
1599 sc_theta =
1600 mkThetaOrigin DerivOrigin $
1601 substTheta (zipOpenTvSubst cls_tyvars inst_tys) (classSCTheta cls)
1602
1603
1604 -- Next we collect Coercible constraints between
1605 -- the Class method types, instantiated with the representation and the
1606 -- newtype type; precisely the constraints required for the
1607 -- calls to coercible that we are going to generate.
1608 coercible_constraints =
1609 [ let (Pair t1 t2) = mkCoerceClassMethEqn cls (varSetElemsKvsFirst dfun_tvs) inst_tys rep_inst_ty meth
1610 in mkPredOrigin (DerivOriginCoerce meth t1 t2) (mkCoerciblePred t1 t2)
1611 | meth <- classMethods cls ]
1612
1613 -- If there are no tyvars, there's no need
1614 -- to abstract over the dictionaries we need
1615 -- Example: newtype T = MkT Int deriving( C )
1616 -- We get the derived instance
1617 -- instance C T
1618 -- rather than
1619 -- instance C Int => C T
1620 all_preds = rep_pred_o : coercible_constraints ++ sc_theta -- NB: rep_pred comes first
1621
1622 -------------------------------------------------------------------
1623 -- Figuring out whether we can only do this newtype-deriving thing
1624
1625 -- See Note [Determining whether newtype-deriving is appropriate]
1626 might_derive_via_coercible
1627 = not (non_coercible_class cls)
1628 && eta_ok
1629 && ats_ok
1630 -- && not (isRecursiveTyCon tycon) -- Note [Recursive newtypes]
1631
1632 -- Check that eta reduction is OK
1633 eta_ok = nt_eta_arity <= length rep_tc_args
1634 -- The newtype can be eta-reduced to match the number
1635 -- of type argument actually supplied
1636 -- newtype T a b = MkT (S [a] b) deriving( Monad )
1637 -- Here the 'b' must be the same in the rep type (S [a] b)
1638 -- And the [a] must not mention 'b'. That's all handled
1639 -- by nt_eta_rity.
1640
1641 ats_ok = null (classATs cls)
1642 -- No associated types for the class, because we don't
1643 -- currently generate type 'instance' decls; and cannot do
1644 -- so for 'data' instance decls
1645
1646 cant_derive_err
1647 = vcat [ ppUnless eta_ok eta_msg
1648 , ppUnless ats_ok ats_msg ]
1649 eta_msg = ptext (sLit "cannot eta-reduce the representation type enough")
1650 ats_msg = ptext (sLit "the class has associated types")
1651
1652 {-
1653 Note [Recursive newtypes]
1654 ~~~~~~~~~~~~~~~~~~~~~~~~~
1655 Newtype deriving works fine, even if the newtype is recursive.
1656 e.g. newtype S1 = S1 [T1 ()]
1657 newtype T1 a = T1 (StateT S1 IO a ) deriving( Monad )
1658 Remember, too, that type families are currently (conservatively) given
1659 a recursive flag, so this also allows newtype deriving to work
1660 for type famillies.
1661
1662 We used to exclude recursive types, because we had a rather simple
1663 minded way of generating the instance decl:
1664 newtype A = MkA [A]
1665 instance Eq [A] => Eq A -- Makes typechecker loop!
1666 But now we require a simple context, so it's ok.
1667
1668 Note [Determining whether newtype-deriving is appropriate]
1669 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1670 When we see
1671 newtype NT = MkNT Foo
1672 deriving C
1673 we have to decide how to perform the deriving. Do we do newtype deriving,
1674 or do we do normal deriving? In general, we prefer to do newtype deriving
1675 wherever possible. So, we try newtype deriving unless there's a glaring
1676 reason not to.
1677
1678 Note that newtype deriving might fail, even after we commit to it. This
1679 is because the derived instance uses `coerce`, which must satisfy its
1680 `Coercible` constraint. This is different than other deriving scenarios,
1681 where we're sure that the resulting instance will type-check.
1682
1683 ************************************************************************
1684 * *
1685 \subsection[TcDeriv-fixpoint]{Finding the fixed point of \tr{deriving} equations}
1686 * *
1687 ************************************************************************
1688
1689 A ``solution'' (to one of the equations) is a list of (k,TyVarTy tv)
1690 terms, which is the final correct RHS for the corresponding original
1691 equation.
1692 \begin{itemize}
1693 \item
1694 Each (k,TyVarTy tv) in a solution constrains only a type
1695 variable, tv.
1696
1697 \item
1698 The (k,TyVarTy tv) pairs in a solution are canonically
1699 ordered by sorting on type varible, tv, (major key) and then class, k,
1700 (minor key)
1701 \end{itemize}
1702 -}
1703
1704 inferInstanceContexts :: [DerivSpec ThetaOrigin] -> TcM [DerivSpec ThetaType]
1705
1706 inferInstanceContexts [] = return []
1707
1708 inferInstanceContexts infer_specs
1709 = do { traceTc "inferInstanceContexts" $ vcat (map pprDerivSpec infer_specs)
1710 ; iterate_deriv 1 initial_solutions }
1711 where
1712 ------------------------------------------------------------------
1713 -- The initial solutions for the equations claim that each
1714 -- instance has an empty context; this solution is certainly
1715 -- in canonical form.
1716 initial_solutions :: [ThetaType]
1717 initial_solutions = [ [] | _ <- infer_specs ]
1718
1719 ------------------------------------------------------------------
1720 -- iterate_deriv calculates the next batch of solutions,
1721 -- compares it with the current one; finishes if they are the
1722 -- same, otherwise recurses with the new solutions.
1723 -- It fails if any iteration fails
1724 iterate_deriv :: Int -> [ThetaType] -> TcM [DerivSpec ThetaType]
1725 iterate_deriv n current_solns
1726 | n > 20 -- Looks as if we are in an infinite loop
1727 -- This can happen if we have -XUndecidableInstances
1728 -- (See TcSimplify.tcSimplifyDeriv.)
1729 = pprPanic "solveDerivEqns: probable loop"
1730 (vcat (map pprDerivSpec infer_specs) $$ ppr current_solns)
1731 | otherwise
1732 = do { -- Extend the inst info from the explicit instance decls
1733 -- with the current set of solutions, and simplify each RHS
1734 inst_specs <- zipWithM newDerivClsInst current_solns infer_specs
1735 ; new_solns <- checkNoErrs $
1736 extendLocalInstEnv inst_specs $
1737 mapM gen_soln infer_specs
1738
1739 ; if (current_solns `eqSolution` new_solns) then
1740 return [ spec { ds_theta = soln }
1741 | (spec, soln) <- zip infer_specs current_solns ]
1742 else
1743 iterate_deriv (n+1) new_solns }
1744
1745 eqSolution = eqListBy (eqListBy eqType)
1746
1747 ------------------------------------------------------------------
1748 gen_soln :: DerivSpec ThetaOrigin -> TcM ThetaType
1749 gen_soln (DS { ds_loc = loc, ds_tvs = tyvars
1750 , ds_cls = clas, ds_tys = inst_tys, ds_theta = deriv_rhs })
1751 = setSrcSpan loc $
1752 addErrCtxt (derivInstCtxt the_pred) $
1753 do { theta <- simplifyDeriv the_pred tyvars deriv_rhs
1754 -- checkValidInstance tyvars theta clas inst_tys
1755 -- Not necessary; see Note [Exotic derived instance contexts]
1756
1757 ; traceTc "TcDeriv" (ppr deriv_rhs $$ ppr theta)
1758 -- Claim: the result instance declaration is guaranteed valid
1759 -- Hence no need to call:
1760 -- checkValidInstance tyvars theta clas inst_tys
1761 ; return (sortBy cmpType theta) } -- Canonicalise before returning the solution
1762 where
1763 the_pred = mkClassPred clas inst_tys
1764
1765 ------------------------------------------------------------------
1766 newDerivClsInst :: ThetaType -> DerivSpec theta -> TcM ClsInst
1767 newDerivClsInst theta (DS { ds_name = dfun_name, ds_overlap = overlap_mode
1768 , ds_tvs = tvs, ds_cls = clas, ds_tys = tys })
1769 = newClsInst overlap_mode dfun_name tvs theta clas tys
1770
1771 extendLocalInstEnv :: [ClsInst] -> TcM a -> TcM a
1772 -- Add new locally-defined instances; don't bother to check
1773 -- for functional dependency errors -- that'll happen in TcInstDcls
1774 extendLocalInstEnv dfuns thing_inside
1775 = do { env <- getGblEnv
1776 ; let inst_env' = extendInstEnvList (tcg_inst_env env) dfuns
1777 env' = env { tcg_inst_env = inst_env' }
1778 ; setGblEnv env' thing_inside }
1779
1780 {-
1781 ***********************************************************************************
1782 * *
1783 * Simplify derived constraints
1784 * *
1785 ***********************************************************************************
1786 -}
1787
1788 simplifyDeriv :: PredType
1789 -> [TyVar]
1790 -> ThetaOrigin -- Wanted
1791 -> TcM ThetaType -- Needed
1792 -- Given instance (wanted) => C inst_ty
1793 -- Simplify 'wanted' as much as possibles
1794 -- Fail if not possible
1795 simplifyDeriv pred tvs theta
1796 = do { (skol_subst, tvs_skols) <- tcInstSkolTyVars tvs -- Skolemize
1797 -- The constraint solving machinery
1798 -- expects *TcTyVars* not TyVars.
1799 -- We use *non-overlappable* (vanilla) skolems
1800 -- See Note [Overlap and deriving]
1801
1802 ; let subst_skol = zipTopTvSubst tvs_skols $ map mkTyVarTy tvs
1803 skol_set = mkVarSet tvs_skols
1804 doc = ptext (sLit "deriving") <+> parens (ppr pred)
1805
1806 ; wanted <- mapM (\(PredOrigin t o) -> newWanted o (substTy skol_subst t)) theta
1807
1808 ; traceTc "simplifyDeriv" $
1809 vcat [ pprTvBndrs tvs $$ ppr theta $$ ppr wanted, doc ]
1810 ; (residual_wanted, _ev_binds1)
1811 <- solveWantedsTcM (mkSimpleWC wanted)
1812 -- Post: residual_wanted are already zonked
1813
1814 ; let (good, bad) = partitionBagWith get_good (wc_simple residual_wanted)
1815 -- See Note [Exotic derived instance contexts]
1816 get_good :: Ct -> Either PredType Ct
1817 get_good ct | validDerivPred skol_set p
1818 , isWantedCt ct = Left p
1819 -- NB: residual_wanted may contain unsolved
1820 -- Derived and we stick them into the bad set
1821 -- so that reportUnsolved may decide what to do with them
1822 | otherwise = Right ct
1823 where p = ctPred ct
1824
1825 -- If we are deferring type errors, simply ignore any insoluble
1826 -- constraints. They'll come up again when we typecheck the
1827 -- generated instance declaration
1828 ; defer <- goptM Opt_DeferTypeErrors
1829 ; unless defer (reportAllUnsolved (residual_wanted { wc_simple = bad }))
1830
1831 ; let min_theta = mkMinimalBySCs (bagToList good)
1832 ; return (substTheta subst_skol min_theta) }
1833
1834 {-
1835 Note [Overlap and deriving]
1836 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
1837 Consider some overlapping instances:
1838 data Show a => Show [a] where ..
1839 data Show [Char] where ...
1840
1841 Now a data type with deriving:
1842 data T a = MkT [a] deriving( Show )
1843
1844 We want to get the derived instance
1845 instance Show [a] => Show (T a) where...
1846 and NOT
1847 instance Show a => Show (T a) where...
1848 so that the (Show (T Char)) instance does the Right Thing
1849
1850 It's very like the situation when we're inferring the type
1851 of a function
1852 f x = show [x]
1853 and we want to infer
1854 f :: Show [a] => a -> String
1855
1856 BOTTOM LINE: use vanilla, non-overlappable skolems when inferring
1857 the context for the derived instance.
1858 Hence tcInstSkolTyVars not tcInstSuperSkolTyVars
1859
1860 Note [Exotic derived instance contexts]
1861 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1862 In a 'derived' instance declaration, we *infer* the context. It's a
1863 bit unclear what rules we should apply for this; the Haskell report is
1864 silent. Obviously, constraints like (Eq a) are fine, but what about
1865 data T f a = MkT (f a) deriving( Eq )
1866 where we'd get an Eq (f a) constraint. That's probably fine too.
1867
1868 One could go further: consider
1869 data T a b c = MkT (Foo a b c) deriving( Eq )
1870 instance (C Int a, Eq b, Eq c) => Eq (Foo a b c)
1871
1872 Notice that this instance (just) satisfies the Paterson termination
1873 conditions. Then we *could* derive an instance decl like this:
1874
1875 instance (C Int a, Eq b, Eq c) => Eq (T a b c)
1876 even though there is no instance for (C Int a), because there just
1877 *might* be an instance for, say, (C Int Bool) at a site where we
1878 need the equality instance for T's.
1879
1880 However, this seems pretty exotic, and it's quite tricky to allow
1881 this, and yet give sensible error messages in the (much more common)
1882 case where we really want that instance decl for C.
1883
1884 So for now we simply require that the derived instance context
1885 should have only type-variable constraints.
1886
1887 Here is another example:
1888 data Fix f = In (f (Fix f)) deriving( Eq )
1889 Here, if we are prepared to allow -XUndecidableInstances we
1890 could derive the instance
1891 instance Eq (f (Fix f)) => Eq (Fix f)
1892 but this is so delicate that I don't think it should happen inside
1893 'deriving'. If you want this, write it yourself!
1894
1895 NB: if you want to lift this condition, make sure you still meet the
1896 termination conditions! If not, the deriving mechanism generates
1897 larger and larger constraints. Example:
1898 data Succ a = S a
1899 data Seq a = Cons a (Seq (Succ a)) | Nil deriving Show
1900
1901 Note the lack of a Show instance for Succ. First we'll generate
1902 instance (Show (Succ a), Show a) => Show (Seq a)
1903 and then
1904 instance (Show (Succ (Succ a)), Show (Succ a), Show a) => Show (Seq a)
1905 and so on. Instead we want to complain of no instance for (Show (Succ a)).
1906
1907 The bottom line
1908 ~~~~~~~~~~~~~~~
1909 Allow constraints which consist only of type variables, with no repeats.
1910
1911
1912 ************************************************************************
1913 * *
1914 \subsection[TcDeriv-normal-binds]{Bindings for the various classes}
1915 * *
1916 ************************************************************************
1917
1918 After all the trouble to figure out the required context for the
1919 derived instance declarations, all that's left is to chug along to
1920 produce them. They will then be shoved into @tcInstDecls2@, which
1921 will do all its usual business.
1922
1923 There are lots of possibilities for code to generate. Here are
1924 various general remarks.
1925
1926 PRINCIPLES:
1927 \begin{itemize}
1928 \item
1929 We want derived instances of @Eq@ and @Ord@ (both v common) to be
1930 ``you-couldn't-do-better-by-hand'' efficient.
1931
1932 \item
1933 Deriving @Show@---also pretty common--- should also be reasonable good code.
1934
1935 \item
1936 Deriving for the other classes isn't that common or that big a deal.
1937 \end{itemize}
1938
1939 PRAGMATICS:
1940
1941 \begin{itemize}
1942 \item
1943 Deriving @Ord@ is done mostly with the 1.3 @compare@ method.
1944
1945 \item
1946 Deriving @Eq@ also uses @compare@, if we're deriving @Ord@, too.
1947
1948 \item
1949 We {\em normally} generate code only for the non-defaulted methods;
1950 there are some exceptions for @Eq@ and (especially) @Ord@...
1951
1952 \item
1953 Sometimes we use a @_con2tag_<tycon>@ function, which returns a data
1954 constructor's numeric (@Int#@) tag. These are generated by
1955 @gen_tag_n_con_binds@, and the heuristic for deciding if one of
1956 these is around is given by @hasCon2TagFun@.
1957
1958 The examples under the different sections below will make this
1959 clearer.
1960
1961 \item
1962 Much less often (really just for deriving @Ix@), we use a
1963 @_tag2con_<tycon>@ function. See the examples.
1964
1965 \item
1966 We use the renamer!!! Reason: we're supposed to be
1967 producing @LHsBinds Name@ for the methods, but that means
1968 producing correctly-uniquified code on the fly. This is entirely
1969 possible (the @TcM@ monad has a @UniqueSupply@), but it is painful.
1970 So, instead, we produce @MonoBinds RdrName@ then heave 'em through
1971 the renamer. What a great hack!
1972 \end{itemize}
1973 -}
1974
1975 -- Generate the InstInfo for the required instance paired with the
1976 -- *representation* tycon for that instance,
1977 -- plus any auxiliary bindings required
1978 --
1979 -- Representation tycons differ from the tycon in the instance signature in
1980 -- case of instances for indexed families.
1981 --
1982 genInst :: CommonAuxiliaries
1983 -> DerivSpec ThetaType
1984 -> TcM (InstInfo RdrName, BagDerivStuff, Maybe Name)
1985 genInst comauxs
1986 spec@(DS { ds_tvs = tvs, ds_tc = rep_tycon, ds_tc_args = rep_tc_args
1987 , ds_theta = theta, ds_newtype = is_newtype, ds_tys = tys
1988 , ds_name = dfun_name, ds_cls = clas, ds_loc = loc })
1989 | is_newtype -- See Note [Bindings for Generalised Newtype Deriving]
1990 = do { inst_spec <- newDerivClsInst theta spec
1991 ; traceTc "genInst/is_newtype" (vcat [ppr loc, ppr clas, ppr tvs, ppr tys, ppr rhs_ty])
1992 ; return ( InstInfo
1993 { iSpec = inst_spec
1994 , iBinds = InstBindings
1995 { ib_binds = gen_Newtype_binds loc clas tvs tys rhs_ty
1996 , ib_tyvars = map Var.varName tvs -- Scope over bindings
1997 , ib_pragmas = []
1998 , ib_extensions = [ Opt_ImpredicativeTypes
1999 , Opt_RankNTypes ]
2000 , ib_derived = True } }
2001 , emptyBag
2002 , Just $ getName $ head $ tyConDataCons rep_tycon ) }
2003 -- See Note [Newtype deriving and unused constructors]
2004
2005 | otherwise
2006 = do { (meth_binds, deriv_stuff) <- genDerivStuff loc clas
2007 dfun_name rep_tycon
2008 (lookup rep_tycon comauxs)
2009 ; inst_spec <- newDerivClsInst theta spec
2010 ; traceTc "newder" (ppr inst_spec)
2011 ; let inst_info = InstInfo { iSpec = inst_spec
2012 , iBinds = InstBindings
2013 { ib_binds = meth_binds
2014 , ib_tyvars = map Var.varName tvs
2015 , ib_pragmas = []
2016 , ib_extensions = []
2017 , ib_derived = True } }
2018 ; return ( inst_info, deriv_stuff, Nothing ) }
2019 where
2020 rhs_ty = newTyConInstRhs rep_tycon rep_tc_args
2021
2022 genDerivStuff :: SrcSpan -> Class -> Name -> TyCon
2023 -> Maybe CommonAuxiliary
2024 -> TcM (LHsBinds RdrName, BagDerivStuff)
2025 genDerivStuff loc clas dfun_name tycon comaux_maybe
2026 | let ck = classKey clas
2027 , ck `elem` [genClassKey, gen1ClassKey] -- Special case because monadic
2028 = let gk = if ck == genClassKey then Gen0 else Gen1
2029 -- TODO NSF: correctly identify when we're building Both instead of One
2030 Just metaTyCons = comaux_maybe -- well-guarded by commonAuxiliaries and genInst
2031 in do
2032 (binds, faminst) <- gen_Generic_binds gk tycon metaTyCons (nameModule dfun_name)
2033 return (binds, unitBag (DerivFamInst faminst))
2034
2035 | otherwise -- Non-monadic generators
2036 = do { dflags <- getDynFlags
2037 ; fix_env <- getDataConFixityFun tycon
2038 ; return (genDerivedBinds dflags fix_env clas loc tycon) }
2039
2040 getDataConFixityFun :: TyCon -> TcM (Name -> Fixity)
2041 -- If the TyCon is locally defined, we want the local fixity env;
2042 -- but if it is imported (which happens for standalone deriving)
2043 -- we need to get the fixity env from the interface file
2044 -- c.f. RnEnv.lookupFixity, and Trac #9830
2045 getDataConFixityFun tc
2046 = do { this_mod <- getModule
2047 ; if nameIsLocalOrFrom this_mod name
2048 then do { fix_env <- getFixityEnv
2049 ; return (lookupFixity fix_env) }
2050 else do { iface <- loadInterfaceForName doc name
2051 -- Should already be loaded!
2052 ; return (mi_fix_fn iface . nameOccName) } }
2053 where
2054 name = tyConName tc
2055 doc = ptext (sLit "Data con fixities for") <+> ppr name
2056
2057 {-
2058 Note [Bindings for Generalised Newtype Deriving]
2059 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2060 Consider
2061 class Eq a => C a where
2062 f :: a -> a
2063 newtype N a = MkN [a] deriving( C )
2064 instance Eq (N a) where ...
2065
2066 The 'deriving C' clause generates, in effect
2067 instance (C [a], Eq a) => C (N a) where
2068 f = coerce (f :: [a] -> [a])
2069
2070 This generates a cast for each method, but allows the superclasse to
2071 be worked out in the usual way. In this case the superclass (Eq (N
2072 a)) will be solved by the explicit Eq (N a) instance. We do *not*
2073 create the superclasses by casting the superclass dictionaries for the
2074 representation type.
2075
2076 See the paper "Safe zero-cost coercions for Hsakell".
2077
2078
2079 ************************************************************************
2080 * *
2081 \subsection[TcDeriv-taggery-Names]{What con2tag/tag2con functions are available?}
2082 * *
2083 ************************************************************************
2084 -}
2085
2086 derivingNullaryErr :: MsgDoc
2087 derivingNullaryErr = ptext (sLit "Cannot derive instances for nullary classes")
2088
2089 derivingKindErr :: TyCon -> Class -> [Type] -> Kind -> MsgDoc
2090 derivingKindErr tc cls cls_tys cls_kind
2091 = hang (ptext (sLit "Cannot derive well-kinded instance of form")
2092 <+> quotes (pprClassPred cls cls_tys <+> parens (ppr tc <+> ptext (sLit "..."))))
2093 2 (ptext (sLit "Class") <+> quotes (ppr cls)
2094 <+> ptext (sLit "expects an argument of kind") <+> quotes (pprKind cls_kind))
2095
2096 derivingEtaErr :: Class -> [Type] -> Type -> MsgDoc
2097 derivingEtaErr cls cls_tys inst_ty
2098 = sep [ptext (sLit "Cannot eta-reduce to an instance of form"),
2099 nest 2 (ptext (sLit "instance (...) =>")
2100 <+> pprClassPred cls (cls_tys ++ [inst_ty]))]
2101
2102 derivingThingErr :: Bool -> Class -> [Type] -> Type -> MsgDoc -> MsgDoc
2103 derivingThingErr newtype_deriving clas tys ty why
2104 = sep [(hang (ptext (sLit "Can't make a derived instance of"))
2105 2 (quotes (ppr pred))
2106 $$ nest 2 extra) <> colon,
2107 nest 2 why]
2108 where
2109 extra | newtype_deriving = ptext (sLit "(even with cunning newtype deriving)")
2110 | otherwise = Outputable.empty
2111 pred = mkClassPred clas (tys ++ [ty])
2112
2113 derivingHiddenErr :: TyCon -> SDoc
2114 derivingHiddenErr tc
2115 = hang (ptext (sLit "The data constructors of") <+> quotes (ppr tc) <+> ptext (sLit "are not all in scope"))
2116 2 (ptext (sLit "so you cannot derive an instance for it"))
2117
2118 standaloneCtxt :: LHsType Name -> SDoc
2119 standaloneCtxt ty = hang (ptext (sLit "In the stand-alone deriving instance for"))
2120 2 (quotes (ppr ty))
2121
2122 derivInstCtxt :: PredType -> MsgDoc
2123 derivInstCtxt pred
2124 = ptext (sLit "When deriving the instance for") <+> parens (ppr pred)