add a comment
[ghc.git] / compiler / cmm / CmmLex.x
1 -----------------------------------------------------------------------------
2 --
3 -- (c) The University of Glasgow, 2004-2006
4 --
5 -- Lexer for concrete Cmm.  We try to stay close to the C-- spec, but there
6 -- are a few minor differences:
7 --
8 --   * extra keywords for our macros, and float32/float64 types
9 --   * global registers (Sp,Hp, etc.)
10 --
11 -----------------------------------------------------------------------------
12
13 {
14 {-# LANGUAGE BangPatterns #-}
15 {-# OPTIONS -Wwarn -w #-}
16 -- The above -Wwarn supression flag is a temporary kludge.
17 -- While working on this module you are encouraged to remove it and fix
18 -- any warnings in the module. See
19 --     http://ghc.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
20 -- for details
21
22 module CmmLex (
23    CmmToken(..), cmmlex,
24   ) where
25
26 import CmmExpr
27
28 import Lexer
29 import SrcLoc
30 import UniqFM
31 import StringBuffer
32 import FastString
33 import Ctype
34 import Util
35 --import TRACE
36
37 import Data.Word
38 import Data.Char
39 }
40
41 $whitechar   = [\ \t\n\r\f\v\xa0] -- \xa0 is Unicode no-break space
42 $white_no_nl = $whitechar # \n
43
44 $ascdigit  = 0-9
45 $unidigit  = \x01 -- Trick Alex into handling Unicode. See alexGetChar.
46 $digit     = [$ascdigit $unidigit]
47 $octit     = 0-7
48 $hexit     = [$digit A-F a-f]
49
50 $unilarge  = \x03 -- Trick Alex into handling Unicode. See alexGetChar.
51 $asclarge  = [A-Z \xc0-\xd6 \xd8-\xde]
52 $large     = [$asclarge $unilarge]
53
54 $unismall  = \x04 -- Trick Alex into handling Unicode. See alexGetChar.
55 $ascsmall  = [a-z \xdf-\xf6 \xf8-\xff]
56 $small     = [$ascsmall $unismall \_]
57
58 $namebegin = [$large $small \. \$ \@]
59 $namechar  = [$namebegin $digit]
60
61 @decimal     = $digit+
62 @octal       = $octit+
63 @hexadecimal = $hexit+
64 @exponent    = [eE] [\-\+]? @decimal
65
66 @floating_point = @decimal \. @decimal @exponent? | @decimal @exponent
67
68 @escape      = \\ ([abfnrt\\\'\"\?] | x $hexit{1,2} | $octit{1,3})
69 @strchar     = ($printable # [\"\\]) | @escape
70
71 cmm :-
72
73 $white_no_nl+           ;
74 ^\# pragma .* \n        ; -- Apple GCC 3.3 CPP generates pragmas in its output
75
76 ^\# (line)?             { begin line_prag }
77
78 -- single-line line pragmas, of the form
79 --    # <line> "<file>" <extra-stuff> \n
80 <line_prag> $digit+                     { setLine line_prag1 }
81 <line_prag1> \" [^\"]* \"       { setFile line_prag2 }
82 <line_prag2> .*                         { pop }
83
84 <0> {
85   \n                    ;
86
87   [\:\;\{\}\[\]\(\)\=\`\~\/\*\%\-\+\&\^\|\>\<\,\!]      { special_char }
88
89   ".."                  { kw CmmT_DotDot }
90   "::"                  { kw CmmT_DoubleColon }
91   ">>"                  { kw CmmT_Shr }
92   "<<"                  { kw CmmT_Shl }
93   ">="                  { kw CmmT_Ge }
94   "<="                  { kw CmmT_Le }
95   "=="                  { kw CmmT_Eq }
96   "!="                  { kw CmmT_Ne }
97   "&&"                  { kw CmmT_BoolAnd }
98   "||"                  { kw CmmT_BoolOr }
99
100   P@decimal             { global_regN (\n -> VanillaReg n VGcPtr) }
101   R@decimal             { global_regN (\n -> VanillaReg n VNonGcPtr) }
102   F@decimal             { global_regN FloatReg }
103   D@decimal             { global_regN DoubleReg }
104   L@decimal             { global_regN LongReg }
105   Sp                    { global_reg Sp }
106   SpLim                 { global_reg SpLim }
107   Hp                    { global_reg Hp }
108   HpLim                 { global_reg HpLim }
109   CCCS                  { global_reg CCCS }
110   CurrentTSO            { global_reg CurrentTSO }
111   CurrentNursery        { global_reg CurrentNursery }
112   HpAlloc               { global_reg HpAlloc }
113   BaseReg               { global_reg BaseReg }
114
115   $namebegin $namechar* { name }
116
117   0 @octal              { tok_octal }
118   @decimal              { tok_decimal }
119   0[xX] @hexadecimal    { tok_hexadecimal }
120   @floating_point       { strtoken tok_float }
121
122   \" @strchar* \"       { strtoken tok_string }
123 }
124
125 {
126 data CmmToken
127   = CmmT_SpecChar  Char
128   | CmmT_DotDot
129   | CmmT_DoubleColon
130   | CmmT_Shr
131   | CmmT_Shl
132   | CmmT_Ge
133   | CmmT_Le
134   | CmmT_Eq
135   | CmmT_Ne
136   | CmmT_BoolAnd
137   | CmmT_BoolOr
138   | CmmT_CLOSURE
139   | CmmT_INFO_TABLE
140   | CmmT_INFO_TABLE_RET
141   | CmmT_INFO_TABLE_FUN
142   | CmmT_INFO_TABLE_CONSTR
143   | CmmT_INFO_TABLE_SELECTOR
144   | CmmT_else
145   | CmmT_export
146   | CmmT_section
147   | CmmT_align
148   | CmmT_goto
149   | CmmT_if
150   | CmmT_call
151   | CmmT_jump
152   | CmmT_foreign
153   | CmmT_never
154   | CmmT_prim
155   | CmmT_reserve
156   | CmmT_return
157   | CmmT_returns
158   | CmmT_import
159   | CmmT_switch
160   | CmmT_case
161   | CmmT_default
162   | CmmT_push
163   | CmmT_bits8
164   | CmmT_bits16
165   | CmmT_bits32
166   | CmmT_bits64
167   | CmmT_bits128
168   | CmmT_bits256
169   | CmmT_bits512
170   | CmmT_float32
171   | CmmT_float64
172   | CmmT_gcptr
173   | CmmT_GlobalReg GlobalReg
174   | CmmT_Name      FastString
175   | CmmT_String    String
176   | CmmT_Int       Integer
177   | CmmT_Float     Rational
178   | CmmT_EOF
179   deriving (Show)
180
181 -- -----------------------------------------------------------------------------
182 -- Lexer actions
183
184 type Action = RealSrcSpan -> StringBuffer -> Int -> P (RealLocated CmmToken)
185
186 begin :: Int -> Action
187 begin code _span _str _len = do pushLexState code; lexToken
188
189 pop :: Action
190 pop _span _buf _len = do popLexState; lexToken
191
192 special_char :: Action
193 special_char span buf len = return (L span (CmmT_SpecChar (currentChar buf)))
194
195 kw :: CmmToken -> Action
196 kw tok span buf len = return (L span tok)
197
198 global_regN :: (Int -> GlobalReg) -> Action
199 global_regN con span buf len
200   = return (L span (CmmT_GlobalReg (con (fromIntegral n))))
201   where buf' = stepOn buf
202         n = parseUnsignedInteger buf' (len-1) 10 octDecDigit
203
204 global_reg :: GlobalReg -> Action
205 global_reg r span buf len = return (L span (CmmT_GlobalReg r))
206
207 strtoken :: (String -> CmmToken) -> Action
208 strtoken f span buf len =
209   return (L span $! (f $! lexemeToString buf len))
210
211 name :: Action
212 name span buf len =
213   case lookupUFM reservedWordsFM fs of
214         Just tok -> return (L span tok)
215         Nothing  -> return (L span (CmmT_Name fs))
216   where
217         fs = lexemeToFastString buf len
218
219 reservedWordsFM = listToUFM $
220         map (\(x, y) -> (mkFastString x, y)) [
221         ( "CLOSURE",            CmmT_CLOSURE ),
222         ( "INFO_TABLE",         CmmT_INFO_TABLE ),
223         ( "INFO_TABLE_RET",     CmmT_INFO_TABLE_RET ),
224         ( "INFO_TABLE_FUN",     CmmT_INFO_TABLE_FUN ),
225         ( "INFO_TABLE_CONSTR",  CmmT_INFO_TABLE_CONSTR ),
226         ( "INFO_TABLE_SELECTOR",CmmT_INFO_TABLE_SELECTOR ),
227         ( "else",               CmmT_else ),
228         ( "export",             CmmT_export ),
229         ( "section",            CmmT_section ),
230         ( "align",              CmmT_align ),
231         ( "goto",               CmmT_goto ),
232         ( "if",                 CmmT_if ),
233         ( "call",               CmmT_call ),
234         ( "jump",               CmmT_jump ),
235         ( "foreign",            CmmT_foreign ),
236         ( "never",              CmmT_never ),
237         ( "prim",               CmmT_prim ),
238         ( "reserve",            CmmT_reserve ),
239         ( "return",             CmmT_return ),
240         ( "returns",            CmmT_returns ),
241         ( "import",             CmmT_import ),
242         ( "switch",             CmmT_switch ),
243         ( "case",               CmmT_case ),
244         ( "default",            CmmT_default ),
245         ( "push",               CmmT_push ),
246         ( "bits8",              CmmT_bits8 ),
247         ( "bits16",             CmmT_bits16 ),
248         ( "bits32",             CmmT_bits32 ),
249         ( "bits64",             CmmT_bits64 ),
250         ( "bits128",            CmmT_bits128 ),
251         ( "bits256",            CmmT_bits256 ),
252         ( "bits512",            CmmT_bits512 ),
253         ( "float32",            CmmT_float32 ),
254         ( "float64",            CmmT_float64 ),
255 -- New forms
256         ( "b8",                 CmmT_bits8 ),
257         ( "b16",                CmmT_bits16 ),
258         ( "b32",                CmmT_bits32 ),
259         ( "b64",                CmmT_bits64 ),
260         ( "b128",               CmmT_bits128 ),
261         ( "b256",               CmmT_bits256 ),
262         ( "b512",               CmmT_bits512 ),
263         ( "f32",                CmmT_float32 ),
264         ( "f64",                CmmT_float64 ),
265         ( "gcptr",              CmmT_gcptr )
266         ]
267
268 tok_decimal span buf len
269   = return (L span (CmmT_Int  $! parseUnsignedInteger buf len 10 octDecDigit))
270
271 tok_octal span buf len
272   = return (L span (CmmT_Int  $! parseUnsignedInteger (offsetBytes 1 buf) (len-1) 8 octDecDigit))
273
274 tok_hexadecimal span buf len
275   = return (L span (CmmT_Int  $! parseUnsignedInteger (offsetBytes 2 buf) (len-2) 16 hexDigit))
276
277 tok_float str = CmmT_Float $! readRational str
278
279 tok_string str = CmmT_String (read str)
280                  -- urk, not quite right, but it'll do for now
281
282 -- -----------------------------------------------------------------------------
283 -- Line pragmas
284
285 setLine :: Int -> Action
286 setLine code span buf len = do
287   let line = parseUnsignedInteger buf len 10 octDecDigit
288   setSrcLoc (mkRealSrcLoc (srcSpanFile span) (fromIntegral line - 1) 1)
289         -- subtract one: the line number refers to the *following* line
290   -- trace ("setLine "  ++ show line) $ do
291   popLexState
292   pushLexState code
293   lexToken
294
295 setFile :: Int -> Action
296 setFile code span buf len = do
297   let file = lexemeToFastString (stepOn buf) (len-2)
298   setSrcLoc (mkRealSrcLoc file (srcSpanEndLine span) (srcSpanEndCol span))
299   popLexState
300   pushLexState code
301   lexToken
302
303 -- -----------------------------------------------------------------------------
304 -- This is the top-level function: called from the parser each time a
305 -- new token is to be read from the input.
306
307 cmmlex :: (Located CmmToken -> P a) -> P a
308 cmmlex cont = do
309   (L span tok) <- lexToken
310   --trace ("token: " ++ show tok) $ do
311   cont (L (RealSrcSpan span) tok)
312
313 lexToken :: P (RealLocated CmmToken)
314 lexToken = do
315   inp@(loc1,buf) <- getInput
316   sc <- getLexState
317   case alexScan inp sc of
318     AlexEOF -> do let span = mkRealSrcSpan loc1 loc1
319                   setLastToken span 0
320                   return (L span CmmT_EOF)
321     AlexError (loc2,_) -> do failLocMsgP loc1 loc2 "lexical error"
322     AlexSkip inp2 _ -> do
323         setInput inp2
324         lexToken
325     AlexToken inp2@(end,buf2) len t -> do
326         setInput inp2
327         let span = mkRealSrcSpan loc1 end
328         span `seq` setLastToken span len
329         t span buf len
330
331 -- -----------------------------------------------------------------------------
332 -- Monad stuff
333
334 -- Stuff that Alex needs to know about our input type:
335 type AlexInput = (RealSrcLoc,StringBuffer)
336
337 alexInputPrevChar :: AlexInput -> Char
338 alexInputPrevChar (_,s) = prevChar s '\n'
339
340 -- backwards compatibility for Alex 2.x
341 alexGetChar :: AlexInput -> Maybe (Char,AlexInput)
342 alexGetChar inp = case alexGetByte inp of
343                     Nothing    -> Nothing
344                     Just (b,i) -> c `seq` Just (c,i)
345                        where c = chr $ fromIntegral b
346
347 alexGetByte :: AlexInput -> Maybe (Word8,AlexInput)
348 alexGetByte (loc,s)
349   | atEnd s   = Nothing
350   | otherwise = b `seq` loc' `seq` s' `seq` Just (b, (loc', s'))
351   where c    = currentChar s
352         b    = fromIntegral $ ord $ c
353         loc' = advanceSrcLoc loc c
354         s'   = stepOn s
355
356 getInput :: P AlexInput
357 getInput = P $ \s@PState{ loc=l, buffer=b } -> POk s (l,b)
358
359 setInput :: AlexInput -> P ()
360 setInput (l,b) = P $ \s -> POk s{ loc=l, buffer=b } ()
361 }