Make warning names more consistent
[ghc.git] / compiler / typecheck / TcBinds.hs
1 {-
2 (c) The University of Glasgow 2006
3 (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4
5 \section[TcBinds]{TcBinds}
6 -}
7
8 {-# LANGUAGE CPP, RankNTypes, ScopedTypeVariables #-}
9
10 module TcBinds ( tcLocalBinds, tcTopBinds, tcRecSelBinds,
11 tcValBinds, tcHsBootSigs, tcPolyCheck,
12 tcSpecPrags, tcSpecWrapper,
13 tcVectDecls, addTypecheckedBinds,
14 TcSigInfo(..), TcSigFun,
15 TcPragEnv, mkPragEnv,
16 tcUserTypeSig, instTcTySig, chooseInferredQuantifiers,
17 instTcTySigFromId, tcExtendTyVarEnvFromSig,
18 badBootDeclErr ) where
19
20 import {-# SOURCE #-} TcMatches ( tcGRHSsPat, tcMatchesFun )
21 import {-# SOURCE #-} TcExpr ( tcMonoExpr )
22 import {-# SOURCE #-} TcPatSyn ( tcInferPatSynDecl, tcCheckPatSynDecl
23 , tcPatSynBuilderBind, tcPatSynSig )
24 import DynFlags
25 import HsSyn
26 import HscTypes( isHsBootOrSig )
27 import TcRnMonad
28 import TcEnv
29 import TcUnify
30 import TcSimplify
31 import TcEvidence
32 import TcHsType
33 import TcPat
34 import TcMType
35 import Inst( topInstantiate, deeplyInstantiate )
36 import FamInstEnv( normaliseType )
37 import FamInst( tcGetFamInstEnvs )
38 import TyCon
39 import TcType
40 import TysPrim
41 import Id
42 import Var
43 import VarSet
44 import VarEnv( TidyEnv )
45 import Module
46 import Name
47 import NameSet
48 import NameEnv
49 import SrcLoc
50 import Bag
51 import ListSetOps
52 import ErrUtils
53 import Digraph
54 import Maybes
55 import Util
56 import BasicTypes
57 import Outputable
58 import Type(mkStrLitTy, tidyOpenType)
59 import PrelNames( mkUnboundName, gHC_PRIM, ipClassName )
60 import TcValidity (checkValidType)
61 import qualified GHC.LanguageExtensions as LangExt
62
63 import Control.Monad
64
65 #include "HsVersions.h"
66
67 {- *********************************************************************
68 * *
69 A useful helper function
70 * *
71 ********************************************************************* -}
72
73 addTypecheckedBinds :: TcGblEnv -> [LHsBinds Id] -> TcGblEnv
74 addTypecheckedBinds tcg_env binds
75 | isHsBootOrSig (tcg_src tcg_env) = tcg_env
76 -- Do not add the code for record-selector bindings
77 -- when compiling hs-boot files
78 | otherwise = tcg_env { tcg_binds = foldr unionBags
79 (tcg_binds tcg_env)
80 binds }
81
82 {-
83 ************************************************************************
84 * *
85 \subsection{Type-checking bindings}
86 * *
87 ************************************************************************
88
89 @tcBindsAndThen@ typechecks a @HsBinds@. The "and then" part is because
90 it needs to know something about the {\em usage} of the things bound,
91 so that it can create specialisations of them. So @tcBindsAndThen@
92 takes a function which, given an extended environment, E, typechecks
93 the scope of the bindings returning a typechecked thing and (most
94 important) an LIE. It is this LIE which is then used as the basis for
95 specialising the things bound.
96
97 @tcBindsAndThen@ also takes a "combiner" which glues together the
98 bindings and the "thing" to make a new "thing".
99
100 The real work is done by @tcBindWithSigsAndThen@.
101
102 Recursive and non-recursive binds are handled in essentially the same
103 way: because of uniques there are no scoping issues left. The only
104 difference is that non-recursive bindings can bind primitive values.
105
106 Even for non-recursive binding groups we add typings for each binder
107 to the LVE for the following reason. When each individual binding is
108 checked the type of its LHS is unified with that of its RHS; and
109 type-checking the LHS of course requires that the binder is in scope.
110
111 At the top-level the LIE is sure to contain nothing but constant
112 dictionaries, which we resolve at the module level.
113
114 Note [Polymorphic recursion]
115 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
116 The game plan for polymorphic recursion in the code above is
117
118 * Bind any variable for which we have a type signature
119 to an Id with a polymorphic type. Then when type-checking
120 the RHSs we'll make a full polymorphic call.
121
122 This fine, but if you aren't a bit careful you end up with a horrendous
123 amount of partial application and (worse) a huge space leak. For example:
124
125 f :: Eq a => [a] -> [a]
126 f xs = ...f...
127
128 If we don't take care, after typechecking we get
129
130 f = /\a -> \d::Eq a -> let f' = f a d
131 in
132 \ys:[a] -> ...f'...
133
134 Notice the the stupid construction of (f a d), which is of course
135 identical to the function we're executing. In this case, the
136 polymorphic recursion isn't being used (but that's a very common case).
137 This can lead to a massive space leak, from the following top-level defn
138 (post-typechecking)
139
140 ff :: [Int] -> [Int]
141 ff = f Int dEqInt
142
143 Now (f dEqInt) evaluates to a lambda that has f' as a free variable; but
144 f' is another thunk which evaluates to the same thing... and you end
145 up with a chain of identical values all hung onto by the CAF ff.
146
147 ff = f Int dEqInt
148
149 = let f' = f Int dEqInt in \ys. ...f'...
150
151 = let f' = let f' = f Int dEqInt in \ys. ...f'...
152 in \ys. ...f'...
153
154 Etc.
155
156 NOTE: a bit of arity anaysis would push the (f a d) inside the (\ys...),
157 which would make the space leak go away in this case
158
159 Solution: when typechecking the RHSs we always have in hand the
160 *monomorphic* Ids for each binding. So we just need to make sure that
161 if (Method f a d) shows up in the constraints emerging from (...f...)
162 we just use the monomorphic Id. We achieve this by adding monomorphic Ids
163 to the "givens" when simplifying constraints. That's what the "lies_avail"
164 is doing.
165
166 Then we get
167
168 f = /\a -> \d::Eq a -> letrec
169 fm = \ys:[a] -> ...fm...
170 in
171 fm
172 -}
173
174 tcTopBinds :: [(RecFlag, LHsBinds Name)] -> [LSig Name] -> TcM (TcGblEnv, TcLclEnv)
175 -- The TcGblEnv contains the new tcg_binds and tcg_spects
176 -- The TcLclEnv has an extended type envt for the new bindings
177 tcTopBinds binds sigs
178 = do { -- Pattern synonym bindings populate the global environment
179 (binds', (tcg_env, tcl_env)) <- tcValBinds TopLevel binds sigs $
180 do { gbl <- getGblEnv
181 ; lcl <- getLclEnv
182 ; return (gbl, lcl) }
183 ; specs <- tcImpPrags sigs -- SPECIALISE prags for imported Ids
184
185 ; let { tcg_env' = tcg_env { tcg_imp_specs = specs ++ tcg_imp_specs tcg_env }
186 `addTypecheckedBinds` map snd binds' }
187
188 ; return (tcg_env', tcl_env) }
189 -- The top level bindings are flattened into a giant
190 -- implicitly-mutually-recursive LHsBinds
191
192 tcRecSelBinds :: HsValBinds Name -> TcM TcGblEnv
193 tcRecSelBinds (ValBindsOut binds sigs)
194 = tcExtendGlobalValEnv [sel_id | L _ (IdSig sel_id) <- sigs] $
195 do { (rec_sel_binds, tcg_env) <- discardWarnings $
196 tcValBinds TopLevel binds sigs getGblEnv
197 ; let tcg_env' = tcg_env `addTypecheckedBinds` map snd rec_sel_binds
198 ; return tcg_env' }
199 tcRecSelBinds (ValBindsIn {}) = panic "tcRecSelBinds"
200
201 tcHsBootSigs :: [(RecFlag, LHsBinds Name)] -> [LSig Name] -> TcM [Id]
202 -- A hs-boot file has only one BindGroup, and it only has type
203 -- signatures in it. The renamer checked all this
204 tcHsBootSigs binds sigs
205 = do { checkTc (null binds) badBootDeclErr
206 ; concat <$> mapM (addLocM tc_boot_sig) (filter isTypeLSig sigs) }
207 where
208 tc_boot_sig (TypeSig lnames hs_ty) = mapM f lnames
209 where
210 f (L _ name)
211 = do { sigma_ty <- solveEqualities $
212 tcHsSigWcType (FunSigCtxt name False) hs_ty
213 ; return (mkVanillaGlobal name sigma_ty) }
214 -- Notice that we make GlobalIds, not LocalIds
215 tc_boot_sig s = pprPanic "tcHsBootSigs/tc_boot_sig" (ppr s)
216
217 badBootDeclErr :: MsgDoc
218 badBootDeclErr = text "Illegal declarations in an hs-boot file"
219
220 ------------------------
221 tcLocalBinds :: HsLocalBinds Name -> TcM thing
222 -> TcM (HsLocalBinds TcId, thing)
223
224 tcLocalBinds EmptyLocalBinds thing_inside
225 = do { thing <- thing_inside
226 ; return (EmptyLocalBinds, thing) }
227
228 tcLocalBinds (HsValBinds (ValBindsOut binds sigs)) thing_inside
229 = do { (binds', thing) <- tcValBinds NotTopLevel binds sigs thing_inside
230 ; return (HsValBinds (ValBindsOut binds' sigs), thing) }
231 tcLocalBinds (HsValBinds (ValBindsIn {})) _ = panic "tcLocalBinds"
232
233 tcLocalBinds (HsIPBinds (IPBinds ip_binds _)) thing_inside
234 = do { ipClass <- tcLookupClass ipClassName
235 ; (given_ips, ip_binds') <-
236 mapAndUnzipM (wrapLocSndM (tc_ip_bind ipClass)) ip_binds
237
238 -- If the binding binds ?x = E, we must now
239 -- discharge any ?x constraints in expr_lie
240 -- See Note [Implicit parameter untouchables]
241 ; (ev_binds, result) <- checkConstraints (IPSkol ips)
242 [] given_ips thing_inside
243
244 ; return (HsIPBinds (IPBinds ip_binds' ev_binds), result) }
245 where
246 ips = [ip | L _ (IPBind (Left (L _ ip)) _) <- ip_binds]
247
248 -- I wonder if we should do these one at at time
249 -- Consider ?x = 4
250 -- ?y = ?x + 1
251 tc_ip_bind ipClass (IPBind (Left (L _ ip)) expr)
252 = do { ty <- newOpenFlexiTyVarTy
253 ; let p = mkStrLitTy $ hsIPNameFS ip
254 ; ip_id <- newDict ipClass [ p, ty ]
255 ; expr' <- tcMonoExpr expr (mkCheckExpType ty)
256 ; let d = toDict ipClass p ty `fmap` expr'
257 ; return (ip_id, (IPBind (Right ip_id) d)) }
258 tc_ip_bind _ (IPBind (Right {}) _) = panic "tc_ip_bind"
259
260 -- Coerces a `t` into a dictionry for `IP "x" t`.
261 -- co : t -> IP "x" t
262 toDict ipClass x ty = HsWrap $ mkWpCastR $
263 wrapIP $ mkClassPred ipClass [x,ty]
264
265 {- Note [Implicit parameter untouchables]
266 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
267 We add the type variables in the types of the implicit parameters
268 as untouchables, not so much because we really must not unify them,
269 but rather because we otherwise end up with constraints like this
270 Num alpha, Implic { wanted = alpha ~ Int }
271 The constraint solver solves alpha~Int by unification, but then
272 doesn't float that solved constraint out (it's not an unsolved
273 wanted). Result disaster: the (Num alpha) is again solved, this
274 time by defaulting. No no no.
275
276 However [Oct 10] this is all handled automatically by the
277 untouchable-range idea.
278
279 Note [Inlining and hs-boot files]
280 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
281 Consider this example (Trac #10083):
282
283 ---------- RSR.hs-boot ------------
284 module RSR where
285 data RSR
286 eqRSR :: RSR -> RSR -> Bool
287
288 ---------- SR.hs ------------
289 module SR where
290 import {-# SOURCE #-} RSR
291 data SR = MkSR RSR
292 eqSR (MkSR r1) (MkSR r2) = eqRSR r1 r2
293
294 ---------- RSR.hs ------------
295 module RSR where
296 import SR
297 data RSR = MkRSR SR -- deriving( Eq )
298 eqRSR (MkRSR s1) (MkRSR s2) = (eqSR s1 s2)
299 foo x y = not (eqRSR x y)
300
301 When compiling RSR we get this code
302
303 RSR.eqRSR :: RSR -> RSR -> Bool
304 RSR.eqRSR = \ (ds1 :: RSR.RSR) (ds2 :: RSR.RSR) ->
305 case ds1 of _ { RSR.MkRSR s1 ->
306 case ds2 of _ { RSR.MkRSR s2 ->
307 SR.eqSR s1 s2 }}
308
309 RSR.foo :: RSR -> RSR -> Bool
310 RSR.foo = \ (x :: RSR) (y :: RSR) -> not (RSR.eqRSR x y)
311
312 Now, when optimising foo:
313 Inline eqRSR (small, non-rec)
314 Inline eqSR (small, non-rec)
315 but the result of inlining eqSR from SR is another call to eqRSR, so
316 everything repeats. Neither eqSR nor eqRSR are (apparently) loop
317 breakers.
318
319 Solution: when compiling RSR, add a NOINLINE pragma to every function
320 exported by the boot-file for RSR (if it exists).
321
322 ALAS: doing so makes the boostrappted GHC itself slower by 8% overall
323 (on Trac #9872a-d, and T1969. So I un-did this change, and
324 parked it for now. Sigh.
325 -}
326
327 tcValBinds :: TopLevelFlag
328 -> [(RecFlag, LHsBinds Name)] -> [LSig Name]
329 -> TcM thing
330 -> TcM ([(RecFlag, LHsBinds TcId)], thing)
331
332 tcValBinds top_lvl binds sigs thing_inside
333 = do { let patsyns = getPatSynBinds binds
334
335 -- Typecheck the signature
336 ; (poly_ids, sig_fn) <- tcAddPatSynPlaceholders patsyns $
337 tcTySigs sigs
338
339 ; _self_boot <- tcSelfBootInfo
340 ; let prag_fn = mkPragEnv sigs (foldr (unionBags . snd) emptyBag binds)
341
342 -- ------- See Note [Inlining and hs-boot files] (change parked) --------
343 -- prag_fn | isTopLevel top_lvl -- See Note [Inlining and hs-boot files]
344 -- , SelfBoot { sb_ids = boot_id_names } <- self_boot
345 -- = foldNameSet add_no_inl prag_fn1 boot_id_names
346 -- | otherwise
347 -- = prag_fn1
348 -- add_no_inl boot_id_name prag_fn
349 -- = extendPragEnv prag_fn (boot_id_name, no_inl_sig boot_id_name)
350 -- no_inl_sig name = L boot_loc (InlineSig (L boot_loc name) neverInlinePragma)
351 -- boot_loc = mkGeneralSrcSpan (fsLit "The hs-boot file for this module")
352
353 -- Extend the envt right away with all the Ids
354 -- declared with complete type signatures
355 -- Do not extend the TcIdBinderStack; instead
356 -- we extend it on a per-rhs basis in tcExtendForRhs
357 ; tcExtendLetEnvIds top_lvl [(idName id, id) | id <- poly_ids] $ do
358 { (binds', (extra_binds', thing)) <- tcBindGroups top_lvl sig_fn prag_fn binds $ do
359 { thing <- thing_inside
360 -- See Note [Pattern synonym builders don't yield dependencies]
361 ; patsyn_builders <- mapM (tcPatSynBuilderBind sig_fn) patsyns
362 ; let extra_binds = [ (NonRecursive, builder) | builder <- patsyn_builders ]
363 ; return (extra_binds, thing) }
364 ; return (binds' ++ extra_binds', thing) }}
365
366 ------------------------
367 tcBindGroups :: TopLevelFlag -> TcSigFun -> TcPragEnv
368 -> [(RecFlag, LHsBinds Name)] -> TcM thing
369 -> TcM ([(RecFlag, LHsBinds TcId)], thing)
370 -- Typecheck a whole lot of value bindings,
371 -- one strongly-connected component at a time
372 -- Here a "strongly connected component" has the strightforward
373 -- meaning of a group of bindings that mention each other,
374 -- ignoring type signatures (that part comes later)
375
376 tcBindGroups _ _ _ [] thing_inside
377 = do { thing <- thing_inside
378 ; return ([], thing) }
379
380 tcBindGroups top_lvl sig_fn prag_fn (group : groups) thing_inside
381 = do { (group', (groups', thing))
382 <- tc_group top_lvl sig_fn prag_fn group $
383 tcBindGroups top_lvl sig_fn prag_fn groups thing_inside
384 ; return (group' ++ groups', thing) }
385
386 ------------------------
387 tc_group :: forall thing.
388 TopLevelFlag -> TcSigFun -> TcPragEnv
389 -> (RecFlag, LHsBinds Name) -> TcM thing
390 -> TcM ([(RecFlag, LHsBinds TcId)], thing)
391
392 -- Typecheck one strongly-connected component of the original program.
393 -- We get a list of groups back, because there may
394 -- be specialisations etc as well
395
396 tc_group top_lvl sig_fn prag_fn (NonRecursive, binds) thing_inside
397 -- A single non-recursive binding
398 -- We want to keep non-recursive things non-recursive
399 -- so that we desugar unlifted bindings correctly
400 = do { let bind = case bagToList binds of
401 [bind] -> bind
402 [] -> panic "tc_group: empty list of binds"
403 _ -> panic "tc_group: NonRecursive binds is not a singleton bag"
404 ; (bind', thing) <- tc_single top_lvl sig_fn prag_fn bind thing_inside
405 ; return ( [(NonRecursive, bind')], thing) }
406
407 tc_group top_lvl sig_fn prag_fn (Recursive, binds) thing_inside
408 = -- To maximise polymorphism, we do a new
409 -- strongly-connected-component analysis, this time omitting
410 -- any references to variables with type signatures.
411 -- (This used to be optional, but isn't now.)
412 -- See Note [Polymorphic recursion] in HsBinds.
413 do { traceTc "tc_group rec" (pprLHsBinds binds)
414 ; when hasPatSyn $ recursivePatSynErr binds
415 ; (binds1, thing) <- go sccs
416 ; return ([(Recursive, binds1)], thing) }
417 -- Rec them all together
418 where
419 hasPatSyn = anyBag (isPatSyn . unLoc) binds
420 isPatSyn PatSynBind{} = True
421 isPatSyn _ = False
422
423 sccs :: [SCC (LHsBind Name)]
424 sccs = stronglyConnCompFromEdgedVertices (mkEdges sig_fn binds)
425
426 go :: [SCC (LHsBind Name)] -> TcM (LHsBinds TcId, thing)
427 go (scc:sccs) = do { (binds1, ids1) <- tc_scc scc
428 ; (binds2, thing) <- tcExtendLetEnv top_lvl ids1 $
429 go sccs
430 ; return (binds1 `unionBags` binds2, thing) }
431 go [] = do { thing <- thing_inside; return (emptyBag, thing) }
432
433 tc_scc (AcyclicSCC bind) = tc_sub_group NonRecursive [bind]
434 tc_scc (CyclicSCC binds) = tc_sub_group Recursive binds
435
436 tc_sub_group = tcPolyBinds top_lvl sig_fn prag_fn Recursive
437
438 recursivePatSynErr :: OutputableBndr name => LHsBinds name -> TcM a
439 recursivePatSynErr binds
440 = failWithTc $
441 hang (text "Recursive pattern synonym definition with following bindings:")
442 2 (vcat $ map pprLBind . bagToList $ binds)
443 where
444 pprLoc loc = parens (text "defined at" <+> ppr loc)
445 pprLBind (L loc bind) = pprWithCommas ppr (collectHsBindBinders bind) <+>
446 pprLoc loc
447
448 tc_single :: forall thing.
449 TopLevelFlag -> TcSigFun -> TcPragEnv
450 -> LHsBind Name -> TcM thing
451 -> TcM (LHsBinds TcId, thing)
452 tc_single _top_lvl sig_fn _prag_fn (L _ (PatSynBind psb@PSB{ psb_id = L _ name })) thing_inside
453 = do { (aux_binds, tcg_env) <- tc_pat_syn_decl
454 ; thing <- setGblEnv tcg_env thing_inside
455 ; return (aux_binds, thing)
456 }
457 where
458 tc_pat_syn_decl :: TcM (LHsBinds TcId, TcGblEnv)
459 tc_pat_syn_decl = case sig_fn name of
460 Nothing -> tcInferPatSynDecl psb
461 Just (TcPatSynSig tpsi) -> tcCheckPatSynDecl psb tpsi
462 Just _ -> panic "tc_single"
463
464 tc_single top_lvl sig_fn prag_fn lbind thing_inside
465 = do { (binds1, ids) <- tcPolyBinds top_lvl sig_fn prag_fn
466 NonRecursive NonRecursive
467 [lbind]
468 ; thing <- tcExtendLetEnv top_lvl ids thing_inside
469 ; return (binds1, thing) }
470
471 ------------------------
472 type BKey = Int -- Just number off the bindings
473
474 mkEdges :: TcSigFun -> LHsBinds Name -> [Node BKey (LHsBind Name)]
475 -- See Note [Polymorphic recursion] in HsBinds.
476 mkEdges sig_fn binds
477 = [ (bind, key, [key | n <- nameSetElems (bind_fvs (unLoc bind)),
478 Just key <- [lookupNameEnv key_map n], no_sig n ])
479 | (bind, key) <- keyd_binds
480 ]
481 where
482 no_sig :: Name -> Bool
483 no_sig n = noCompleteSig (sig_fn n)
484
485 keyd_binds = bagToList binds `zip` [0::BKey ..]
486
487 key_map :: NameEnv BKey -- Which binding it comes from
488 key_map = mkNameEnv [(bndr, key) | (L _ bind, key) <- keyd_binds
489 , bndr <- collectHsBindBinders bind ]
490
491 ------------------------
492 tcPolyBinds :: TopLevelFlag -> TcSigFun -> TcPragEnv
493 -> RecFlag -- Whether the group is really recursive
494 -> RecFlag -- Whether it's recursive after breaking
495 -- dependencies based on type signatures
496 -> [LHsBind Name] -- None are PatSynBind
497 -> TcM (LHsBinds TcId, [TcId])
498
499 -- Typechecks a single bunch of values bindings all together,
500 -- and generalises them. The bunch may be only part of a recursive
501 -- group, because we use type signatures to maximise polymorphism
502 --
503 -- Returns a list because the input may be a single non-recursive binding,
504 -- in which case the dependency order of the resulting bindings is
505 -- important.
506 --
507 -- Knows nothing about the scope of the bindings
508 -- None of the bindings are pattern synonyms
509
510 tcPolyBinds top_lvl sig_fn prag_fn rec_group rec_tc bind_list
511 = setSrcSpan loc $
512 recoverM (recoveryCode binder_names sig_fn) $ do
513 -- Set up main recover; take advantage of any type sigs
514
515 { traceTc "------------------------------------------------" Outputable.empty
516 ; traceTc "Bindings for {" (ppr binder_names)
517 ; dflags <- getDynFlags
518 ; type_env <- getLclTypeEnv
519 ; let plan = decideGeneralisationPlan dflags type_env
520 binder_names bind_list sig_fn
521 ; traceTc "Generalisation plan" (ppr plan)
522 ; result@(tc_binds, poly_ids) <- case plan of
523 NoGen -> tcPolyNoGen rec_tc prag_fn sig_fn bind_list
524 InferGen mn -> tcPolyInfer rec_tc prag_fn sig_fn mn bind_list
525 CheckGen lbind sig -> tcPolyCheck rec_tc prag_fn sig lbind
526
527 -- Check whether strict bindings are ok
528 -- These must be non-recursive etc, and are not generalised
529 -- They desugar to a case expression in the end
530 ; checkStrictBinds top_lvl rec_group bind_list tc_binds poly_ids
531 ; traceTc "} End of bindings for" (vcat [ ppr binder_names, ppr rec_group
532 , vcat [ppr id <+> ppr (idType id) | id <- poly_ids]
533 ])
534
535 ; return result }
536 where
537 binder_names = collectHsBindListBinders bind_list
538 loc = foldr1 combineSrcSpans (map getLoc bind_list)
539 -- The mbinds have been dependency analysed and
540 -- may no longer be adjacent; so find the narrowest
541 -- span that includes them all
542
543 ------------------
544 tcPolyNoGen -- No generalisation whatsoever
545 :: RecFlag -- Whether it's recursive after breaking
546 -- dependencies based on type signatures
547 -> TcPragEnv -> TcSigFun
548 -> [LHsBind Name]
549 -> TcM (LHsBinds TcId, [TcId])
550
551 tcPolyNoGen rec_tc prag_fn tc_sig_fn bind_list
552 = do { (binds', mono_infos) <- tcMonoBinds rec_tc tc_sig_fn
553 (LetGblBndr prag_fn)
554 bind_list
555 ; mono_ids' <- mapM tc_mono_info mono_infos
556 ; return (binds', mono_ids') }
557 where
558 tc_mono_info (MBI { mbi_poly_name = name, mbi_mono_id = mono_id })
559 = do { mono_ty' <- zonkTcType (idType mono_id)
560 -- Zonk, mainly to expose unboxed types to checkStrictBinds
561 ; let mono_id' = setIdType mono_id mono_ty'
562 ; _specs <- tcSpecPrags mono_id' (lookupPragEnv prag_fn name)
563 ; return mono_id' }
564 -- NB: tcPrags generates error messages for
565 -- specialisation pragmas for non-overloaded sigs
566 -- Indeed that is why we call it here!
567 -- So we can safely ignore _specs
568
569 ------------------
570 tcPolyCheck :: RecFlag -- Whether it's recursive after breaking
571 -- dependencies based on type signatures
572 -> TcPragEnv
573 -> TcIdSigInfo
574 -> LHsBind Name
575 -> TcM (LHsBinds TcId, [TcId])
576 -- There is just one binding,
577 -- it binds a single variable,
578 -- it has a complete type signature,
579 tcPolyCheck rec_tc prag_fn
580 sig@(TISI { sig_bndr = CompleteSig poly_id
581 , sig_skols = skol_prs
582 , sig_theta = theta
583 , sig_tau = tau
584 , sig_ctxt = ctxt
585 , sig_loc = loc })
586 bind
587 = do { ev_vars <- newEvVars theta
588 ; let skol_info = SigSkol ctxt (mkCheckExpType $ mkPhiTy theta tau)
589 prag_sigs = lookupPragEnv prag_fn name
590 skol_tvs = map snd skol_prs
591 -- Find the location of the original source type sig, if
592 -- there is was one. This will appear in messages like
593 -- "type variable x is bound by .. at <loc>"
594 name = idName poly_id
595 ; (ev_binds, (binds', _))
596 <- setSrcSpan loc $
597 checkConstraints skol_info skol_tvs ev_vars $
598 tcMonoBinds rec_tc (\_ -> Just (TcIdSig sig)) LetLclBndr [bind]
599
600 ; spec_prags <- tcSpecPrags poly_id prag_sigs
601 ; poly_id <- addInlinePrags poly_id prag_sigs
602
603 ; let bind' = case bagToList binds' of
604 [b] -> b
605 _ -> pprPanic "tcPolyCheck" (ppr binds')
606 abs_bind = L loc $ AbsBindsSig
607 { abs_tvs = skol_tvs
608 , abs_ev_vars = ev_vars
609 , abs_sig_export = poly_id
610 , abs_sig_prags = SpecPrags spec_prags
611 , abs_sig_ev_bind = ev_binds
612 , abs_sig_bind = bind' }
613
614 ; return (unitBag abs_bind, [poly_id]) }
615
616 tcPolyCheck _rec_tc _prag_fn sig _bind
617 = pprPanic "tcPolyCheck" (ppr sig)
618
619 ------------------
620 tcPolyInfer
621 :: RecFlag -- Whether it's recursive after breaking
622 -- dependencies based on type signatures
623 -> TcPragEnv -> TcSigFun
624 -> Bool -- True <=> apply the monomorphism restriction
625 -> [LHsBind Name]
626 -> TcM (LHsBinds TcId, [TcId])
627 tcPolyInfer rec_tc prag_fn tc_sig_fn mono bind_list
628 = do { (tclvl, wanted, (binds', mono_infos))
629 <- pushLevelAndCaptureConstraints $
630 tcMonoBinds rec_tc tc_sig_fn LetLclBndr bind_list
631
632 ; let name_taus = [ (mbi_poly_name info, idType (mbi_mono_id info))
633 | info <- mono_infos ]
634 sigs = [ sig | MBI { mbi_sig = Just sig } <- mono_infos ]
635
636 ; traceTc "simplifyInfer call" (ppr tclvl $$ ppr name_taus $$ ppr wanted)
637 ; (qtvs, givens, ev_binds)
638 <- simplifyInfer tclvl mono sigs name_taus wanted
639
640 ; let inferred_theta = map evVarPred givens
641 ; exports <- checkNoErrs $
642 mapM (mkExport prag_fn qtvs inferred_theta) mono_infos
643
644 ; loc <- getSrcSpanM
645 ; let poly_ids = map abe_poly exports
646 abs_bind = L loc $
647 AbsBinds { abs_tvs = qtvs
648 , abs_ev_vars = givens, abs_ev_binds = [ev_binds]
649 , abs_exports = exports, abs_binds = binds' }
650
651 ; traceTc "Binding:" (ppr (poly_ids `zip` map idType poly_ids))
652 ; return (unitBag abs_bind, poly_ids) }
653 -- poly_ids are guaranteed zonked by mkExport
654
655 --------------
656 mkExport :: TcPragEnv
657 -> [TyVar] -> TcThetaType -- Both already zonked
658 -> MonoBindInfo
659 -> TcM (ABExport Id)
660 -- Only called for generalisation plan InferGen, not by CheckGen or NoGen
661 --
662 -- mkExport generates exports with
663 -- zonked type variables,
664 -- zonked poly_ids
665 -- The former is just because no further unifications will change
666 -- the quantified type variables, so we can fix their final form
667 -- right now.
668 -- The latter is needed because the poly_ids are used to extend the
669 -- type environment; see the invariant on TcEnv.tcExtendIdEnv
670
671 -- Pre-condition: the qtvs and theta are already zonked
672
673 mkExport prag_fn qtvs theta
674 mono_info@(MBI { mbi_poly_name = poly_name
675 , mbi_sig = mb_sig
676 , mbi_mono_id = mono_id })
677 = do { mono_ty <- zonkTcType (idType mono_id)
678 ; poly_id <- case mb_sig of
679 Just sig | Just poly_id <- completeIdSigPolyId_maybe sig
680 -> return poly_id
681 _other -> checkNoErrs $
682 mkInferredPolyId qtvs theta
683 poly_name mb_sig mono_ty
684 -- The checkNoErrs ensures that if the type is ambiguous
685 -- we don't carry on to the impedence matching, and generate
686 -- a duplicate ambiguity error. There is a similar
687 -- checkNoErrs for complete type signatures too.
688
689 -- NB: poly_id has a zonked type
690 ; poly_id <- addInlinePrags poly_id prag_sigs
691 ; spec_prags <- tcSpecPrags poly_id prag_sigs
692 -- tcPrags requires a zonked poly_id
693
694 -- See Note [Impedence matching]
695 -- NB: we have already done checkValidType, including an ambiguity check,
696 -- on the type; either when we checked the sig or in mkInferredPolyId
697 ; let sel_poly_ty = mkInvSigmaTy qtvs theta mono_ty
698 -- this type is just going into tcSubType, so Inv vs. Spec doesn't
699 -- matter
700
701 poly_ty = idType poly_id
702 ; wrap <- if sel_poly_ty `eqType` poly_ty -- NB: eqType ignores visibility
703 then return idHsWrapper -- Fast path; also avoids complaint when we infer
704 -- an ambiguouse type and have AllowAmbiguousType
705 -- e..g infer x :: forall a. F a -> Int
706 else addErrCtxtM (mk_impedence_match_msg mono_info sel_poly_ty poly_ty) $
707 tcSubType_NC sig_ctxt sel_poly_ty (mkCheckExpType poly_ty)
708
709 ; warn_missing_sigs <- woptM Opt_WarnMissingLocalSignatures
710 ; when warn_missing_sigs $ localSigWarn poly_id mb_sig
711
712 ; return (ABE { abe_wrap = wrap
713 -- abe_wrap :: idType poly_id ~ (forall qtvs. theta => mono_ty)
714 , abe_poly = poly_id
715 , abe_mono = mono_id
716 , abe_prags = SpecPrags spec_prags}) }
717 where
718 prag_sigs = lookupPragEnv prag_fn poly_name
719 sig_ctxt = InfSigCtxt poly_name
720
721 mkInferredPolyId :: [TyVar] -> TcThetaType
722 -> Name -> Maybe TcIdSigInfo -> TcType
723 -> TcM TcId
724 mkInferredPolyId qtvs inferred_theta poly_name mb_sig mono_ty
725 = do { fam_envs <- tcGetFamInstEnvs
726 ; let (_co, mono_ty') = normaliseType fam_envs Nominal mono_ty
727 -- Unification may not have normalised the type,
728 -- (see Note [Lazy flattening] in TcFlatten) so do it
729 -- here to make it as uncomplicated as possible.
730 -- Example: f :: [F Int] -> Bool
731 -- should be rewritten to f :: [Char] -> Bool, if possible
732 --
733 -- We can discard the coercion _co, because we'll reconstruct
734 -- it in the call to tcSubType below
735
736 ; (binders, theta') <- chooseInferredQuantifiers inferred_theta
737 (tyCoVarsOfType mono_ty') qtvs mb_sig
738
739 ; let inferred_poly_ty = mkForAllTys binders (mkPhiTy theta' mono_ty')
740
741 ; traceTc "mkInferredPolyId" (vcat [ppr poly_name, ppr qtvs, ppr theta'
742 , ppr inferred_poly_ty])
743 ; addErrCtxtM (mk_inf_msg poly_name inferred_poly_ty) $
744 checkValidType (InfSigCtxt poly_name) inferred_poly_ty
745 -- See Note [Validity of inferred types]
746
747 ; return (mkLocalIdOrCoVar poly_name inferred_poly_ty) }
748
749
750 chooseInferredQuantifiers :: TcThetaType -- inferred
751 -> TcTyVarSet -- tvs free in tau type
752 -> [TcTyVar] -- inferred quantified tvs
753 -> Maybe TcIdSigInfo
754 -> TcM ([TcTyBinder], TcThetaType)
755 chooseInferredQuantifiers inferred_theta tau_tvs qtvs Nothing
756 = do { let free_tvs = closeOverKinds (growThetaTyVars inferred_theta tau_tvs)
757 -- Include kind variables! Trac #7916
758 my_theta = pickQuantifiablePreds free_tvs inferred_theta
759 binders = [ mkNamedBinder Invisible tv
760 | tv <- qtvs
761 , tv `elemVarSet` free_tvs ]
762 ; return (binders, my_theta) }
763
764 chooseInferredQuantifiers inferred_theta tau_tvs qtvs
765 (Just (TISI { sig_bndr = bndr_info
766 , sig_ctxt = ctxt
767 , sig_theta = annotated_theta
768 , sig_skols = annotated_tvs }))
769 | PartialSig { sig_cts = extra } <- bndr_info
770 , Nothing <- extra
771 = do { annotated_theta <- zonkTcTypes annotated_theta
772 ; let free_tvs = closeOverKinds (tyCoVarsOfTypes annotated_theta
773 `unionVarSet` tau_tvs)
774 ; traceTc "ciq" (vcat [ ppr bndr_info, ppr annotated_theta, ppr free_tvs])
775 ; return (mk_binders free_tvs, annotated_theta) }
776
777 | PartialSig { sig_cts = extra } <- bndr_info
778 , Just loc <- extra
779 = do { annotated_theta <- zonkTcTypes annotated_theta
780 ; let free_tvs = closeOverKinds (tyCoVarsOfTypes annotated_theta
781 `unionVarSet` tau_tvs)
782 my_theta = pickQuantifiablePreds free_tvs inferred_theta
783
784 -- Report the inferred constraints for an extra-constraints wildcard/hole as
785 -- an error message, unless the PartialTypeSignatures flag is enabled. In this
786 -- case, the extra inferred constraints are accepted without complaining.
787 -- Returns the annotated constraints combined with the inferred constraints.
788 inferred_diff = [ pred
789 | pred <- my_theta
790 , all (not . (`eqType` pred)) annotated_theta ]
791 final_theta = annotated_theta ++ inferred_diff
792 ; partial_sigs <- xoptM LangExt.PartialTypeSignatures
793 ; warn_partial_sigs <- woptM Opt_WarnPartialTypeSignatures
794 ; msg <- mkLongErrAt loc (mk_msg inferred_diff partial_sigs) empty
795 ; traceTc "completeTheta" $
796 vcat [ ppr bndr_info
797 , ppr annotated_theta, ppr inferred_theta
798 , ppr inferred_diff ]
799 ; case partial_sigs of
800 True | warn_partial_sigs -> reportWarning msg
801 | otherwise -> return ()
802 False -> reportError msg
803
804 ; return (mk_binders free_tvs, final_theta) }
805
806 | otherwise = pprPanic "chooseInferredQuantifiers" (ppr bndr_info)
807
808 where
809 pts_hint = text "To use the inferred type, enable PartialTypeSignatures"
810 mk_msg inferred_diff suppress_hint
811 = vcat [ hang ((text "Found constraint wildcard") <+> quotes (char '_'))
812 2 (text "standing for") <+> quotes (pprTheta inferred_diff)
813 , if suppress_hint then empty else pts_hint
814 , typeSigCtxt ctxt bndr_info ]
815
816 spec_tv_set = mkVarSet $ map snd annotated_tvs
817 mk_binders free_tvs
818 = [ mkNamedBinder vis tv
819 | tv <- qtvs
820 , tv `elemVarSet` free_tvs
821 , let vis | tv `elemVarSet` spec_tv_set = Specified
822 | otherwise = Invisible ]
823 -- Pulling from qtvs maintains original order
824
825 mk_impedence_match_msg :: MonoBindInfo
826 -> TcType -> TcType
827 -> TidyEnv -> TcM (TidyEnv, SDoc)
828 -- This is a rare but rather awkward error messages
829 mk_impedence_match_msg (MBI { mbi_poly_name = name, mbi_sig = mb_sig })
830 inf_ty sig_ty tidy_env
831 = do { (tidy_env1, inf_ty) <- zonkTidyTcType tidy_env inf_ty
832 ; (tidy_env2, sig_ty) <- zonkTidyTcType tidy_env1 sig_ty
833 ; let msg = vcat [ text "When checking that the inferred type"
834 , nest 2 $ ppr name <+> dcolon <+> ppr inf_ty
835 , text "is as general as its" <+> what <+> text "signature"
836 , nest 2 $ ppr name <+> dcolon <+> ppr sig_ty ]
837 ; return (tidy_env2, msg) }
838 where
839 what = case mb_sig of
840 Nothing -> text "inferred"
841 Just sig | isPartialSig sig -> text "(partial)"
842 | otherwise -> empty
843
844
845 mk_inf_msg :: Name -> TcType -> TidyEnv -> TcM (TidyEnv, SDoc)
846 mk_inf_msg poly_name poly_ty tidy_env
847 = do { (tidy_env1, poly_ty) <- zonkTidyTcType tidy_env poly_ty
848 ; let msg = vcat [ text "When checking the inferred type"
849 , nest 2 $ ppr poly_name <+> dcolon <+> ppr poly_ty ]
850 ; return (tidy_env1, msg) }
851
852
853 -- | Warn the user about polymorphic local binders that lack type signatures.
854 localSigWarn :: Id -> Maybe TcIdSigInfo -> TcM ()
855 localSigWarn id mb_sig
856 | Just _ <- mb_sig = return ()
857 | not (isSigmaTy (idType id)) = return ()
858 | otherwise = warnMissingSignatures msg id
859 where
860 msg = text "Polymorphic local binding with no type signature:"
861
862 warnMissingSignatures :: SDoc -> Id -> TcM ()
863 warnMissingSignatures msg id
864 = do { env0 <- tcInitTidyEnv
865 ; let (env1, tidy_ty) = tidyOpenType env0 (idType id)
866 ; addWarnTcM (env1, mk_msg tidy_ty) }
867 where
868 mk_msg ty = sep [ msg, nest 2 $ pprPrefixName (idName id) <+> dcolon <+> ppr ty ]
869
870 {-
871 Note [Partial type signatures and generalisation]
872 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
873 When we have a partial type signature, like
874 f :: _ -> Int
875 then we *always* use the InferGen plan, and hence tcPolyInfer.
876 We do this even for a local binding with -XMonoLocalBinds.
877 Reasons:
878 * The TcSigInfo for 'f' has a unification variable for the '_',
879 whose TcLevel is one level deeper than the current level.
880 (See pushTcLevelM in tcTySig.) But NoGen doesn't increase
881 the TcLevel like InferGen, so we lose the level invariant.
882
883 * The signature might be f :: forall a. _ -> a
884 so it really is polymorphic. It's not clear what it would
885 mean to use NoGen on this, and indeed the ASSERT in tcLhs,
886 in the (Just sig) case, checks that if there is a signature
887 then we are using LetLclBndr, and hence a nested AbsBinds with
888 increased TcLevel
889
890 It might be possible to fix these difficulties somehow, but there
891 doesn't seem much point. Indeed, adding a partial type signature is a
892 way to get per-binding inferred generalisation.
893
894 Note [Validity of inferred types]
895 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
896 We need to check inferred type for validity, in case it uses language
897 extensions that are not turned on. The principle is that if the user
898 simply adds the inferred type to the program source, it'll compile fine.
899 See #8883.
900
901 Examples that might fail:
902 - the type might be ambiguous
903
904 - an inferred theta that requires type equalities e.g. (F a ~ G b)
905 or multi-parameter type classes
906 - an inferred type that includes unboxed tuples
907
908
909 Note [Impedence matching]
910 ~~~~~~~~~~~~~~~~~~~~~~~~~
911 Consider
912 f 0 x = x
913 f n x = g [] (not x)
914
915 g [] y = f 10 y
916 g _ y = f 9 y
917
918 After typechecking we'll get
919 f_mono_ty :: a -> Bool -> Bool
920 g_mono_ty :: [b] -> Bool -> Bool
921 with constraints
922 (Eq a, Num a)
923
924 Note that f is polymorphic in 'a' and g in 'b'; and these are not linked.
925 The types we really want for f and g are
926 f :: forall a. (Eq a, Num a) => a -> Bool -> Bool
927 g :: forall b. [b] -> Bool -> Bool
928
929 We can get these by "impedance matching":
930 tuple :: forall a b. (Eq a, Num a) => (a -> Bool -> Bool, [b] -> Bool -> Bool)
931 tuple a b d1 d1 = let ...bind f_mono, g_mono in (f_mono, g_mono)
932
933 f a d1 d2 = case tuple a Any d1 d2 of (f, g) -> f
934 g b = case tuple Integer b dEqInteger dNumInteger of (f,g) -> g
935
936 Suppose the shared quantified tyvars are qtvs and constraints theta.
937 Then we want to check that
938 forall qtvs. theta => f_mono_ty is more polymorphic than f's polytype
939 and the proof is the impedance matcher.
940
941 Notice that the impedance matcher may do defaulting. See Trac #7173.
942
943 It also cleverly does an ambiguity check; for example, rejecting
944 f :: F a -> F a
945 where F is a non-injective type function.
946 -}
947
948 --------------
949 -- If typechecking the binds fails, then return with each
950 -- signature-less binder given type (forall a.a), to minimise
951 -- subsequent error messages
952 recoveryCode :: [Name] -> TcSigFun -> TcM (LHsBinds TcId, [Id])
953 recoveryCode binder_names sig_fn
954 = do { traceTc "tcBindsWithSigs: error recovery" (ppr binder_names)
955 ; let poly_ids = map mk_dummy binder_names
956 ; return (emptyBag, poly_ids) }
957 where
958 mk_dummy name
959 | Just sig <- sig_fn name
960 , Just poly_id <- completeSigPolyId_maybe sig
961 = poly_id
962 | otherwise
963 = mkLocalId name forall_a_a
964
965 forall_a_a :: TcType
966 forall_a_a = mkSpecForAllTys [runtimeRep1TyVar, openAlphaTyVar] openAlphaTy
967
968 {- *********************************************************************
969 * *
970 Pragmas, including SPECIALISE
971 * *
972 ************************************************************************
973
974 Note [Handling SPECIALISE pragmas]
975 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
976 The basic idea is this:
977
978 foo :: Num a => a -> b -> a
979 {-# SPECIALISE foo :: Int -> b -> Int #-}
980
981 We check that
982 (forall a b. Num a => a -> b -> a)
983 is more polymorphic than
984 forall b. Int -> b -> Int
985 (for which we could use tcSubType, but see below), generating a HsWrapper
986 to connect the two, something like
987 wrap = /\b. <hole> Int b dNumInt
988 This wrapper is put in the TcSpecPrag, in the ABExport record of
989 the AbsBinds.
990
991
992 f :: (Eq a, Ix b) => a -> b -> Bool
993 {-# SPECIALISE f :: (Ix p, Ix q) => Int -> (p,q) -> Bool #-}
994 f = <poly_rhs>
995
996 From this the typechecker generates
997
998 AbsBinds [ab] [d1,d2] [([ab], f, f_mono, prags)] binds
999
1000 SpecPrag (wrap_fn :: forall a b. (Eq a, Ix b) => XXX
1001 -> forall p q. (Ix p, Ix q) => XXX[ Int/a, (p,q)/b ])
1002
1003 From these we generate:
1004
1005 Rule: forall p, q, (dp:Ix p), (dq:Ix q).
1006 f Int (p,q) dInt ($dfInPair dp dq) = f_spec p q dp dq
1007
1008 Spec bind: f_spec = wrap_fn <poly_rhs>
1009
1010 Note that
1011
1012 * The LHS of the rule may mention dictionary *expressions* (eg
1013 $dfIxPair dp dq), and that is essential because the dp, dq are
1014 needed on the RHS.
1015
1016 * The RHS of f_spec, <poly_rhs> has a *copy* of 'binds', so that it
1017 can fully specialise it.
1018
1019
1020
1021 From the TcSpecPrag, in DsBinds we generate a binding for f_spec and a RULE:
1022
1023 f_spec :: Int -> b -> Int
1024 f_spec = wrap<f rhs>
1025
1026 RULE: forall b (d:Num b). f b d = f_spec b
1027
1028 The RULE is generated by taking apart the HsWrapper, which is a little
1029 delicate, but works.
1030
1031 Some wrinkles
1032
1033 1. We don't use full-on tcSubType, because that does co and contra
1034 variance and that in turn will generate too complex a LHS for the
1035 RULE. So we use a single invocation of skolemise /
1036 topInstantiate in tcSpecWrapper. (Actually I think that even
1037 the "deeply" stuff may be too much, because it introduces lambdas,
1038 though I think it can be made to work without too much trouble.)
1039
1040 2. We need to take care with type families (Trac #5821). Consider
1041 type instance F Int = Bool
1042 f :: Num a => a -> F a
1043 {-# SPECIALISE foo :: Int -> Bool #-}
1044
1045 We *could* try to generate an f_spec with precisely the declared type:
1046 f_spec :: Int -> Bool
1047 f_spec = <f rhs> Int dNumInt |> co
1048
1049 RULE: forall d. f Int d = f_spec |> sym co
1050
1051 but the 'co' and 'sym co' are (a) playing no useful role, and (b) are
1052 hard to generate. At all costs we must avoid this:
1053 RULE: forall d. f Int d |> co = f_spec
1054 because the LHS will never match (indeed it's rejected in
1055 decomposeRuleLhs).
1056
1057 So we simply do this:
1058 - Generate a constraint to check that the specialised type (after
1059 skolemiseation) is equal to the instantiated function type.
1060 - But *discard* the evidence (coercion) for that constraint,
1061 so that we ultimately generate the simpler code
1062 f_spec :: Int -> F Int
1063 f_spec = <f rhs> Int dNumInt
1064
1065 RULE: forall d. f Int d = f_spec
1066 You can see this discarding happening in
1067
1068 3. Note that the HsWrapper can transform *any* function with the right
1069 type prefix
1070 forall ab. (Eq a, Ix b) => XXX
1071 regardless of XXX. It's sort of polymorphic in XXX. This is
1072 useful: we use the same wrapper to transform each of the class ops, as
1073 well as the dict. That's what goes on in TcInstDcls.mk_meth_spec_prags
1074 -}
1075
1076 mkPragEnv :: [LSig Name] -> LHsBinds Name -> TcPragEnv
1077 mkPragEnv sigs binds
1078 = foldl extendPragEnv emptyNameEnv prs
1079 where
1080 prs = mapMaybe get_sig sigs
1081
1082 get_sig :: LSig Name -> Maybe (Name, LSig Name)
1083 get_sig (L l (SpecSig lnm@(L _ nm) ty inl)) = Just (nm, L l $ SpecSig lnm ty (add_arity nm inl))
1084 get_sig (L l (InlineSig lnm@(L _ nm) inl)) = Just (nm, L l $ InlineSig lnm (add_arity nm inl))
1085 get_sig _ = Nothing
1086
1087 add_arity n inl_prag -- Adjust inl_sat field to match visible arity of function
1088 | Inline <- inl_inline inl_prag
1089 -- add arity only for real INLINE pragmas, not INLINABLE
1090 = case lookupNameEnv ar_env n of
1091 Just ar -> inl_prag { inl_sat = Just ar }
1092 Nothing -> WARN( True, text "mkPragEnv no arity" <+> ppr n )
1093 -- There really should be a binding for every INLINE pragma
1094 inl_prag
1095 | otherwise
1096 = inl_prag
1097
1098 -- ar_env maps a local to the arity of its definition
1099 ar_env :: NameEnv Arity
1100 ar_env = foldrBag lhsBindArity emptyNameEnv binds
1101
1102 extendPragEnv :: TcPragEnv -> (Name, LSig Name) -> TcPragEnv
1103 extendPragEnv prag_fn (n, sig) = extendNameEnv_Acc (:) singleton prag_fn n sig
1104
1105 lhsBindArity :: LHsBind Name -> NameEnv Arity -> NameEnv Arity
1106 lhsBindArity (L _ (FunBind { fun_id = id, fun_matches = ms })) env
1107 = extendNameEnv env (unLoc id) (matchGroupArity ms)
1108 lhsBindArity _ env = env -- PatBind/VarBind
1109
1110 ------------------
1111 tcSpecPrags :: Id -> [LSig Name]
1112 -> TcM [LTcSpecPrag]
1113 -- Add INLINE and SPECIALSE pragmas
1114 -- INLINE prags are added to the (polymorphic) Id directly
1115 -- SPECIALISE prags are passed to the desugarer via TcSpecPrags
1116 -- Pre-condition: the poly_id is zonked
1117 -- Reason: required by tcSubExp
1118 tcSpecPrags poly_id prag_sigs
1119 = do { traceTc "tcSpecPrags" (ppr poly_id <+> ppr spec_sigs)
1120 ; unless (null bad_sigs) warn_discarded_sigs
1121 ; pss <- mapAndRecoverM (wrapLocM (tcSpecPrag poly_id)) spec_sigs
1122 ; return $ concatMap (\(L l ps) -> map (L l) ps) pss }
1123 where
1124 spec_sigs = filter isSpecLSig prag_sigs
1125 bad_sigs = filter is_bad_sig prag_sigs
1126 is_bad_sig s = not (isSpecLSig s || isInlineLSig s)
1127
1128 warn_discarded_sigs
1129 = addWarnTc (hang (text "Discarding unexpected pragmas for" <+> ppr poly_id)
1130 2 (vcat (map (ppr . getLoc) bad_sigs)))
1131
1132 --------------
1133 tcSpecPrag :: TcId -> Sig Name -> TcM [TcSpecPrag]
1134 tcSpecPrag poly_id prag@(SpecSig fun_name hs_tys inl)
1135 -- See Note [Handling SPECIALISE pragmas]
1136 --
1137 -- The Name fun_name in the SpecSig may not be the same as that of the poly_id
1138 -- Example: SPECIALISE for a class method: the Name in the SpecSig is
1139 -- for the selector Id, but the poly_id is something like $cop
1140 -- However we want to use fun_name in the error message, since that is
1141 -- what the user wrote (Trac #8537)
1142 = addErrCtxt (spec_ctxt prag) $
1143 do { warnIf (not (isOverloadedTy poly_ty || isInlinePragma inl))
1144 (text "SPECIALISE pragma for non-overloaded function"
1145 <+> quotes (ppr fun_name))
1146 -- Note [SPECIALISE pragmas]
1147 ; spec_prags <- mapM tc_one hs_tys
1148 ; traceTc "tcSpecPrag" (ppr poly_id $$ nest 2 (vcat (map ppr spec_prags)))
1149 ; return spec_prags }
1150 where
1151 name = idName poly_id
1152 poly_ty = idType poly_id
1153 spec_ctxt prag = hang (text "In the SPECIALISE pragma") 2 (ppr prag)
1154
1155 tc_one hs_ty
1156 = do { spec_ty <- tcHsSigType (FunSigCtxt name False) hs_ty
1157 ; wrap <- tcSpecWrapper (FunSigCtxt name True) poly_ty spec_ty
1158 ; return (SpecPrag poly_id wrap inl) }
1159
1160 tcSpecPrag _ prag = pprPanic "tcSpecPrag" (ppr prag)
1161
1162 --------------
1163 tcSpecWrapper :: UserTypeCtxt -> TcType -> TcType -> TcM HsWrapper
1164 -- A simpler variant of tcSubType, used for SPECIALISE pragmas
1165 -- See Note [Handling SPECIALISE pragmas], wrinkle 1
1166 tcSpecWrapper ctxt poly_ty spec_ty
1167 = do { (sk_wrap, inst_wrap)
1168 <- tcSkolemise ctxt spec_ty $ \ _ spec_tau ->
1169 do { (inst_wrap, tau) <- topInstantiate orig poly_ty
1170 ; _ <- unifyType noThing spec_tau tau
1171 -- Deliberately ignore the evidence
1172 -- See Note [Handling SPECIALISE pragmas],
1173 -- wrinkle (2)
1174 ; return inst_wrap }
1175 ; return (sk_wrap <.> inst_wrap) }
1176 where
1177 orig = SpecPragOrigin ctxt
1178
1179 --------------
1180 tcImpPrags :: [LSig Name] -> TcM [LTcSpecPrag]
1181 -- SPECIALISE pragmas for imported things
1182 tcImpPrags prags
1183 = do { this_mod <- getModule
1184 ; dflags <- getDynFlags
1185 ; if (not_specialising dflags) then
1186 return []
1187 else do
1188 { pss <- mapAndRecoverM (wrapLocM tcImpSpec)
1189 [L loc (name,prag)
1190 | (L loc prag@(SpecSig (L _ name) _ _)) <- prags
1191 , not (nameIsLocalOrFrom this_mod name) ]
1192 ; return $ concatMap (\(L l ps) -> map (L l) ps) pss } }
1193 where
1194 -- Ignore SPECIALISE pragmas for imported things
1195 -- when we aren't specialising, or when we aren't generating
1196 -- code. The latter happens when Haddocking the base library;
1197 -- we don't wnat complaints about lack of INLINABLE pragmas
1198 not_specialising dflags
1199 | not (gopt Opt_Specialise dflags) = True
1200 | otherwise = case hscTarget dflags of
1201 HscNothing -> True
1202 HscInterpreted -> True
1203 _other -> False
1204
1205 tcImpSpec :: (Name, Sig Name) -> TcM [TcSpecPrag]
1206 tcImpSpec (name, prag)
1207 = do { id <- tcLookupId name
1208 ; unless (isAnyInlinePragma (idInlinePragma id))
1209 (addWarnTc (impSpecErr name))
1210 ; tcSpecPrag id prag }
1211
1212 impSpecErr :: Name -> SDoc
1213 impSpecErr name
1214 = hang (text "You cannot SPECIALISE" <+> quotes (ppr name))
1215 2 (vcat [ text "because its definition has no INLINE/INLINABLE pragma"
1216 , parens $ sep
1217 [ text "or its defining module" <+> quotes (ppr mod)
1218 , text "was compiled without -O"]])
1219 where
1220 mod = nameModule name
1221
1222
1223 {- *********************************************************************
1224 * *
1225 Vectorisation
1226 * *
1227 ********************************************************************* -}
1228
1229 tcVectDecls :: [LVectDecl Name] -> TcM ([LVectDecl TcId])
1230 tcVectDecls decls
1231 = do { decls' <- mapM (wrapLocM tcVect) decls
1232 ; let ids = [lvectDeclName decl | decl <- decls', not $ lvectInstDecl decl]
1233 dups = findDupsEq (==) ids
1234 ; mapM_ reportVectDups dups
1235 ; traceTcConstraints "End of tcVectDecls"
1236 ; return decls'
1237 }
1238 where
1239 reportVectDups (first:_second:_more)
1240 = addErrAt (getSrcSpan first) $
1241 text "Duplicate vectorisation declarations for" <+> ppr first
1242 reportVectDups _ = return ()
1243
1244 --------------
1245 tcVect :: VectDecl Name -> TcM (VectDecl TcId)
1246 -- FIXME: We can't typecheck the expression of a vectorisation declaration against the vectorised
1247 -- type of the original definition as this requires internals of the vectoriser not available
1248 -- during type checking. Instead, constrain the rhs of a vectorisation declaration to be a single
1249 -- identifier (this is checked in 'rnHsVectDecl'). Fix this by enabling the use of 'vectType'
1250 -- from the vectoriser here.
1251 tcVect (HsVect s name rhs)
1252 = addErrCtxt (vectCtxt name) $
1253 do { var <- wrapLocM tcLookupId name
1254 ; let L rhs_loc (HsVar (L lv rhs_var_name)) = rhs
1255 ; rhs_id <- tcLookupId rhs_var_name
1256 ; return $ HsVect s var (L rhs_loc (HsVar (L lv rhs_id)))
1257 }
1258
1259 {- OLD CODE:
1260 -- turn the vectorisation declaration into a single non-recursive binding
1261 ; let bind = L loc $ mkTopFunBind name [mkSimpleMatch [] rhs]
1262 sigFun = const Nothing
1263 pragFun = emptyPragEnv
1264
1265 -- perform type inference (including generalisation)
1266 ; (binds, [id'], _) <- tcPolyInfer False True sigFun pragFun NonRecursive [bind]
1267
1268 ; traceTc "tcVect inferred type" $ ppr (varType id')
1269 ; traceTc "tcVect bindings" $ ppr binds
1270
1271 -- add all bindings, including the type variable and dictionary bindings produced by type
1272 -- generalisation to the right-hand side of the vectorisation declaration
1273 ; let [AbsBinds tvs evs _ evBinds actualBinds] = (map unLoc . bagToList) binds
1274 ; let [bind'] = bagToList actualBinds
1275 MatchGroup
1276 [L _ (Match _ _ (GRHSs [L _ (GRHS _ rhs')] _))]
1277 _ = (fun_matches . unLoc) bind'
1278 rhsWrapped = mkHsLams tvs evs (mkHsDictLet evBinds rhs')
1279
1280 -- We return the type-checked 'Id', to propagate the inferred signature
1281 -- to the vectoriser - see "Note [Typechecked vectorisation pragmas]" in HsDecls
1282 ; return $ HsVect (L loc id') (Just rhsWrapped)
1283 }
1284 -}
1285 tcVect (HsNoVect s name)
1286 = addErrCtxt (vectCtxt name) $
1287 do { var <- wrapLocM tcLookupId name
1288 ; return $ HsNoVect s var
1289 }
1290 tcVect (HsVectTypeIn _ isScalar lname rhs_name)
1291 = addErrCtxt (vectCtxt lname) $
1292 do { tycon <- tcLookupLocatedTyCon lname
1293 ; checkTc ( not isScalar -- either we have a non-SCALAR declaration
1294 || isJust rhs_name -- or we explicitly provide a vectorised type
1295 || tyConArity tycon == 0 -- otherwise the type constructor must be nullary
1296 )
1297 scalarTyConMustBeNullary
1298
1299 ; rhs_tycon <- fmapMaybeM (tcLookupTyCon . unLoc) rhs_name
1300 ; return $ HsVectTypeOut isScalar tycon rhs_tycon
1301 }
1302 tcVect (HsVectTypeOut _ _ _)
1303 = panic "TcBinds.tcVect: Unexpected 'HsVectTypeOut'"
1304 tcVect (HsVectClassIn _ lname)
1305 = addErrCtxt (vectCtxt lname) $
1306 do { cls <- tcLookupLocatedClass lname
1307 ; return $ HsVectClassOut cls
1308 }
1309 tcVect (HsVectClassOut _)
1310 = panic "TcBinds.tcVect: Unexpected 'HsVectClassOut'"
1311 tcVect (HsVectInstIn linstTy)
1312 = addErrCtxt (vectCtxt linstTy) $
1313 do { (cls, tys) <- tcHsVectInst linstTy
1314 ; inst <- tcLookupInstance cls tys
1315 ; return $ HsVectInstOut inst
1316 }
1317 tcVect (HsVectInstOut _)
1318 = panic "TcBinds.tcVect: Unexpected 'HsVectInstOut'"
1319
1320 vectCtxt :: Outputable thing => thing -> SDoc
1321 vectCtxt thing = text "When checking the vectorisation declaration for" <+> ppr thing
1322
1323 scalarTyConMustBeNullary :: MsgDoc
1324 scalarTyConMustBeNullary = text "VECTORISE SCALAR type constructor must be nullary"
1325
1326 {-
1327 Note [SPECIALISE pragmas]
1328 ~~~~~~~~~~~~~~~~~~~~~~~~~
1329 There is no point in a SPECIALISE pragma for a non-overloaded function:
1330 reverse :: [a] -> [a]
1331 {-# SPECIALISE reverse :: [Int] -> [Int] #-}
1332
1333 But SPECIALISE INLINE *can* make sense for GADTS:
1334 data Arr e where
1335 ArrInt :: !Int -> ByteArray# -> Arr Int
1336 ArrPair :: !Int -> Arr e1 -> Arr e2 -> Arr (e1, e2)
1337
1338 (!:) :: Arr e -> Int -> e
1339 {-# SPECIALISE INLINE (!:) :: Arr Int -> Int -> Int #-}
1340 {-# SPECIALISE INLINE (!:) :: Arr (a, b) -> Int -> (a, b) #-}
1341 (ArrInt _ ba) !: (I# i) = I# (indexIntArray# ba i)
1342 (ArrPair _ a1 a2) !: i = (a1 !: i, a2 !: i)
1343
1344 When (!:) is specialised it becomes non-recursive, and can usefully
1345 be inlined. Scary! So we only warn for SPECIALISE *without* INLINE
1346 for a non-overloaded function.
1347
1348 ************************************************************************
1349 * *
1350 tcMonoBinds
1351 * *
1352 ************************************************************************
1353
1354 @tcMonoBinds@ deals with a perhaps-recursive group of HsBinds.
1355 The signatures have been dealt with already.
1356
1357 Note [Pattern bindings]
1358 ~~~~~~~~~~~~~~~~~~~~~~~
1359 The rule for typing pattern bindings is this:
1360
1361 ..sigs..
1362 p = e
1363
1364 where 'p' binds v1..vn, and 'e' may mention v1..vn,
1365 typechecks exactly like
1366
1367 ..sigs..
1368 x = e -- Inferred type
1369 v1 = case x of p -> v1
1370 ..
1371 vn = case x of p -> vn
1372
1373 Note that
1374 (f :: forall a. a -> a) = id
1375 should not typecheck because
1376 case id of { (f :: forall a. a->a) -> f }
1377 will not typecheck.
1378
1379 Note [Instantiate when inferring a type]
1380 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1381 Consider
1382 f = (*)
1383 As there is no incentive to instantiate the RHS, tcMonoBinds will
1384 produce a type of forall a. Num a => a -> a -> a for `f`. This will then go
1385 through simplifyInfer and such, remaining unchanged.
1386
1387 There are two problems with this:
1388 1) If the definition were `g _ = (*)`, we get a very unusual type of
1389 `forall {a}. a -> forall b. Num b => b -> b -> b` for `g`. This is
1390 surely confusing for users.
1391
1392 2) The monomorphism restriction can't work. The MR is dealt with in
1393 simplifyInfer, and simplifyInfer has no way of instantiating. This
1394 could perhaps be worked around, but it may be hard to know even
1395 when instantiation should happen.
1396
1397 There is an easy solution to both problems: instantiate (deeply) when
1398 inferring a type. So that's what we do. Note that this decision is
1399 user-facing.
1400
1401 We do this deep instantiation in tcMonoBinds, in the FunBind case
1402 only, and only when we do not have a type signature. Conveniently,
1403 the fun_co_fn field of FunBind gives a place to record the coercion.
1404
1405 We do not need to do this
1406 * for PatBinds, because we don't have a function type
1407 * for FunBinds where we have a signature, bucause we aren't doing inference
1408 -}
1409
1410 tcMonoBinds :: RecFlag -- Whether the binding is recursive for typechecking purposes
1411 -- i.e. the binders are mentioned in their RHSs, and
1412 -- we are not rescued by a type signature
1413 -> TcSigFun -> LetBndrSpec
1414 -> [LHsBind Name]
1415 -> TcM (LHsBinds TcId, [MonoBindInfo])
1416 tcMonoBinds is_rec sig_fn no_gen
1417 [ L b_loc (FunBind { fun_id = L nm_loc name,
1418 fun_matches = matches, bind_fvs = fvs })]
1419 -- Single function binding,
1420 | NonRecursive <- is_rec -- ...binder isn't mentioned in RHS
1421 , Nothing <- sig_fn name -- ...with no type signature
1422 = -- In this very special case we infer the type of the
1423 -- right hand side first (it may have a higher-rank type)
1424 -- and *then* make the monomorphic Id for the LHS
1425 -- e.g. f = \(x::forall a. a->a) -> <body>
1426 -- We want to infer a higher-rank type for f
1427 setSrcSpan b_loc $
1428 do { rhs_ty <- newOpenInferExpType
1429 ; (co_fn, matches')
1430 <- tcExtendIdBndrs [TcIdBndr_ExpType name rhs_ty NotTopLevel] $
1431 -- We extend the error context even for a non-recursive
1432 -- function so that in type error messages we show the
1433 -- type of the thing whose rhs we are type checking
1434 tcMatchesFun name matches rhs_ty
1435 ; rhs_ty <- readExpType rhs_ty
1436
1437 -- Deeply instantiate the inferred type
1438 -- See Note [Instantiate when inferring a type]
1439 ; let orig = matchesCtOrigin matches
1440 ; rhs_ty <- zonkTcType rhs_ty -- NB: zonk to uncover any foralls
1441 ; (inst_wrap, rhs_ty) <- addErrCtxtM (instErrCtxt name rhs_ty) $
1442 deeplyInstantiate orig rhs_ty
1443
1444 ; mono_id <- newNoSigLetBndr no_gen name rhs_ty
1445 ; return (unitBag $ L b_loc $
1446 FunBind { fun_id = L nm_loc mono_id,
1447 fun_matches = matches', bind_fvs = fvs,
1448 fun_co_fn = inst_wrap <.> co_fn, fun_tick = [] },
1449 [MBI { mbi_poly_name = name
1450 , mbi_sig = Nothing
1451 , mbi_mono_id = mono_id }]) }
1452
1453 tcMonoBinds _ sig_fn no_gen binds
1454 = do { tc_binds <- mapM (wrapLocM (tcLhs sig_fn no_gen)) binds
1455
1456 -- Bring the monomorphic Ids, into scope for the RHSs
1457 ; let mono_infos = getMonoBindInfo tc_binds
1458 rhs_id_env = [(name, mono_id) | MBI { mbi_poly_name = name
1459 , mbi_sig = mb_sig
1460 , mbi_mono_id = mono_id }
1461 <- mono_infos
1462 , case mb_sig of
1463 Just sig -> isPartialSig sig
1464 Nothing -> True ]
1465 -- A monomorphic binding for each term variable that lacks
1466 -- a type sig. (Ones with a sig are already in scope.)
1467
1468 ; traceTc "tcMonoBinds" $ vcat [ ppr n <+> ppr id <+> ppr (idType id)
1469 | (n,id) <- rhs_id_env]
1470 ; binds' <- tcExtendLetEnvIds NotTopLevel rhs_id_env $
1471 mapM (wrapLocM tcRhs) tc_binds
1472 ; return (listToBag binds', mono_infos) }
1473
1474 ------------------------
1475 -- tcLhs typechecks the LHS of the bindings, to construct the environment in which
1476 -- we typecheck the RHSs. Basically what we are doing is this: for each binder:
1477 -- if there's a signature for it, use the instantiated signature type
1478 -- otherwise invent a type variable
1479 -- You see that quite directly in the FunBind case.
1480 --
1481 -- But there's a complication for pattern bindings:
1482 -- data T = MkT (forall a. a->a)
1483 -- MkT f = e
1484 -- Here we can guess a type variable for the entire LHS (which will be refined to T)
1485 -- but we want to get (f::forall a. a->a) as the RHS environment.
1486 -- The simplest way to do this is to typecheck the pattern, and then look up the
1487 -- bound mono-ids. Then we want to retain the typechecked pattern to avoid re-doing
1488 -- it; hence the TcMonoBind data type in which the LHS is done but the RHS isn't
1489
1490 data TcMonoBind -- Half completed; LHS done, RHS not done
1491 = TcFunBind MonoBindInfo SrcSpan (MatchGroup Name (LHsExpr Name))
1492 | TcPatBind [MonoBindInfo] (LPat TcId) (GRHSs Name (LHsExpr Name)) TcSigmaType
1493
1494 data MonoBindInfo = MBI { mbi_poly_name :: Name
1495 , mbi_sig :: Maybe TcIdSigInfo
1496 , mbi_mono_id :: TcId }
1497
1498 tcLhs :: TcSigFun -> LetBndrSpec -> HsBind Name -> TcM TcMonoBind
1499 tcLhs sig_fn no_gen (FunBind { fun_id = L nm_loc name, fun_matches = matches })
1500 | Just (TcIdSig sig) <- sig_fn name
1501 , TISI { sig_tau = tau } <- sig
1502 = ASSERT2( case no_gen of { LetLclBndr -> True; LetGblBndr {} -> False }
1503 , ppr name )
1504 -- { f :: ty; f x = e } is always done via CheckGen (full signature)
1505 -- or InferGen (partial signature)
1506 -- see Note [Partial type signatures and generalisation]
1507 -- Both InferGen and CheckGen gives rise to LetLclBndr
1508 do { mono_name <- newLocalName name
1509 ; let mono_id = mkLocalIdOrCoVar mono_name tau
1510 ; return (TcFunBind (MBI { mbi_poly_name = name
1511 , mbi_sig = Just sig
1512 , mbi_mono_id = mono_id })
1513 nm_loc matches) }
1514
1515 | otherwise
1516 = do { mono_ty <- newOpenFlexiTyVarTy
1517 ; mono_id <- newNoSigLetBndr no_gen name mono_ty
1518 ; return (TcFunBind (MBI { mbi_poly_name = name
1519 , mbi_sig = Nothing
1520 , mbi_mono_id = mono_id })
1521 nm_loc matches) }
1522
1523 tcLhs sig_fn no_gen (PatBind { pat_lhs = pat, pat_rhs = grhss })
1524 = do { let tc_pat exp_ty = tcLetPat sig_fn no_gen pat exp_ty $
1525 mapM lookup_info (collectPatBinders pat)
1526
1527 -- After typechecking the pattern, look up the binder
1528 -- names, which the pattern has brought into scope.
1529 lookup_info :: Name -> TcM MonoBindInfo
1530 lookup_info name
1531 = do { mono_id <- tcLookupId name
1532 ; let mb_sig = case sig_fn name of
1533 Just (TcIdSig sig) -> Just sig
1534 _ -> Nothing
1535 ; return (MBI { mbi_poly_name = name
1536 , mbi_sig = mb_sig
1537 , mbi_mono_id = mono_id }) }
1538
1539 ; ((pat', infos), pat_ty) <- addErrCtxt (patMonoBindsCtxt pat grhss) $
1540 tcInfer tc_pat
1541
1542 ; return (TcPatBind infos pat' grhss pat_ty) }
1543
1544 tcLhs _ _ other_bind = pprPanic "tcLhs" (ppr other_bind)
1545 -- AbsBind, VarBind impossible
1546
1547 -------------------
1548 tcRhs :: TcMonoBind -> TcM (HsBind TcId)
1549 tcRhs (TcFunBind info@(MBI { mbi_sig = mb_sig, mbi_mono_id = mono_id })
1550 loc matches)
1551 = tcExtendIdBinderStackForRhs [info] $
1552 tcExtendTyVarEnvForRhs mb_sig $
1553 do { traceTc "tcRhs: fun bind" (ppr mono_id $$ ppr (idType mono_id))
1554 ; (co_fn, matches') <- tcMatchesFun (idName mono_id)
1555 matches (mkCheckExpType $ idType mono_id)
1556 ; return ( FunBind { fun_id = L loc mono_id
1557 , fun_matches = matches'
1558 , fun_co_fn = co_fn
1559 , bind_fvs = placeHolderNamesTc
1560 , fun_tick = [] } ) }
1561
1562 -- TODO: emit Hole Constraints for wildcards
1563 tcRhs (TcPatBind infos pat' grhss pat_ty)
1564 = -- When we are doing pattern bindings we *don't* bring any scoped
1565 -- type variables into scope unlike function bindings
1566 -- Wny not? They are not completely rigid.
1567 -- That's why we have the special case for a single FunBind in tcMonoBinds
1568 tcExtendIdBinderStackForRhs infos $
1569 do { traceTc "tcRhs: pat bind" (ppr pat' $$ ppr pat_ty)
1570 ; grhss' <- addErrCtxt (patMonoBindsCtxt pat' grhss) $
1571 tcGRHSsPat grhss pat_ty
1572 ; return ( PatBind { pat_lhs = pat', pat_rhs = grhss'
1573 , pat_rhs_ty = pat_ty
1574 , bind_fvs = placeHolderNamesTc
1575 , pat_ticks = ([],[]) } )}
1576
1577 tcExtendTyVarEnvForRhs :: Maybe TcIdSigInfo -> TcM a -> TcM a
1578 tcExtendTyVarEnvForRhs Nothing thing_inside
1579 = thing_inside
1580 tcExtendTyVarEnvForRhs (Just sig) thing_inside
1581 = tcExtendTyVarEnvFromSig sig thing_inside
1582
1583 tcExtendTyVarEnvFromSig :: TcIdSigInfo -> TcM a -> TcM a
1584 tcExtendTyVarEnvFromSig sig thing_inside
1585 | TISI { sig_bndr = s_bndr, sig_skols = skol_prs, sig_ctxt = ctxt } <- sig
1586 = tcExtendTyVarEnv2 skol_prs $
1587 case s_bndr of
1588 CompleteSig {} -> thing_inside
1589 PartialSig { sig_wcs = wc_prs } -- Extend the env ad emit the holes
1590 -> tcExtendTyVarEnv2 wc_prs $
1591 do { addErrCtxt (typeSigCtxt ctxt s_bndr) $
1592 emitWildCardHoleConstraints wc_prs
1593 ; thing_inside }
1594
1595 tcExtendIdBinderStackForRhs :: [MonoBindInfo] -> TcM a -> TcM a
1596 -- Extend the TcIdBinderStack for the RHS of the binding, with
1597 -- the monomorphic Id. That way, if we have, say
1598 -- f = \x -> blah
1599 -- and something goes wrong in 'blah', we get a "relevant binding"
1600 -- looking like f :: alpha -> beta
1601 -- This applies if 'f' has a type signature too:
1602 -- f :: forall a. [a] -> [a]
1603 -- f x = True
1604 -- We can't unify True with [a], and a relevant binding is f :: [a] -> [a]
1605 -- If we had the *polymorphic* version of f in the TcIdBinderStack, it
1606 -- would not be reported as relevant, because its type is closed
1607 tcExtendIdBinderStackForRhs infos thing_inside
1608 = tcExtendIdBndrs [ TcIdBndr mono_id NotTopLevel
1609 | MBI { mbi_mono_id = mono_id } <- infos ]
1610 thing_inside
1611 -- NotTopLevel: it's a monomorphic binding
1612
1613 ---------------------
1614 getMonoBindInfo :: [Located TcMonoBind] -> [MonoBindInfo]
1615 getMonoBindInfo tc_binds
1616 = foldr (get_info . unLoc) [] tc_binds
1617 where
1618 get_info (TcFunBind info _ _) rest = info : rest
1619 get_info (TcPatBind infos _ _ _) rest = infos ++ rest
1620
1621 {-
1622 ************************************************************************
1623 * *
1624 Signatures
1625 * *
1626 ************************************************************************
1627
1628 Type signatures are tricky. See Note [Signature skolems] in TcType
1629
1630 @tcSigs@ checks the signatures for validity, and returns a list of
1631 {\em freshly-instantiated} signatures. That is, the types are already
1632 split up, and have fresh type variables installed. All non-type-signature
1633 "RenamedSigs" are ignored.
1634
1635 The @TcSigInfo@ contains @TcTypes@ because they are unified with
1636 the variable's type, and after that checked to see whether they've
1637 been instantiated.
1638
1639 Note [Scoped tyvars]
1640 ~~~~~~~~~~~~~~~~~~~~
1641 The -XScopedTypeVariables flag brings lexically-scoped type variables
1642 into scope for any explicitly forall-quantified type variables:
1643 f :: forall a. a -> a
1644 f x = e
1645 Then 'a' is in scope inside 'e'.
1646
1647 However, we do *not* support this
1648 - For pattern bindings e.g
1649 f :: forall a. a->a
1650 (f,g) = e
1651
1652 Note [Signature skolems]
1653 ~~~~~~~~~~~~~~~~~~~~~~~~
1654 When instantiating a type signature, we do so with either skolems or
1655 SigTv meta-type variables depending on the use_skols boolean. This
1656 variable is set True when we are typechecking a single function
1657 binding; and False for pattern bindings and a group of several
1658 function bindings.
1659
1660 Reason: in the latter cases, the "skolems" can be unified together,
1661 so they aren't properly rigid in the type-refinement sense.
1662 NB: unless we are doing H98, each function with a sig will be done
1663 separately, even if it's mutually recursive, so use_skols will be True
1664
1665
1666 Note [Only scoped tyvars are in the TyVarEnv]
1667 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1668 We are careful to keep only the *lexically scoped* type variables in
1669 the type environment. Why? After all, the renamer has ensured
1670 that only legal occurrences occur, so we could put all type variables
1671 into the type env.
1672
1673 But we want to check that two distinct lexically scoped type variables
1674 do not map to the same internal type variable. So we need to know which
1675 the lexically-scoped ones are... and at the moment we do that by putting
1676 only the lexically scoped ones into the environment.
1677
1678 Note [Instantiate sig with fresh variables]
1679 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1680 It's vital to instantiate a type signature with fresh variables.
1681 For example:
1682 type T = forall a. [a] -> [a]
1683 f :: T;
1684 f = g where { g :: T; g = <rhs> }
1685
1686 We must not use the same 'a' from the defn of T at both places!!
1687 (Instantiation is only necessary because of type synonyms. Otherwise,
1688 it's all cool; each signature has distinct type variables from the renamer.)
1689
1690 Note [Fail eagerly on bad signatures]
1691 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1692 If a type signaure is wrong, fail immediately:
1693
1694 * the type sigs may bind type variables, so proceeding without them
1695 can lead to a cascade of errors
1696
1697 * the type signature might be ambiguous, in which case checking
1698 the code against the signature will give a very similar error
1699 to the ambiguity error.
1700
1701 ToDo: this means we fall over if any type sig
1702 is wrong (eg at the top level of the module),
1703 which is over-conservative
1704 -}
1705
1706 tcTySigs :: [LSig Name] -> TcM ([TcId], TcSigFun)
1707 tcTySigs hs_sigs
1708 = checkNoErrs $ -- See Note [Fail eagerly on bad signatures]
1709 do { ty_sigs_s <- mapAndRecoverM tcTySig hs_sigs
1710 ; let ty_sigs = concat ty_sigs_s
1711 poly_ids = mapMaybe completeSigPolyId_maybe ty_sigs
1712 -- The returned [TcId] are the ones for which we have
1713 -- a complete type signature.
1714 -- See Note [Complete and partial type signatures]
1715 env = mkNameEnv [(tcSigInfoName sig, sig) | sig <- ty_sigs]
1716 ; return (poly_ids, lookupNameEnv env) }
1717
1718 tcTySig :: LSig Name -> TcM [TcSigInfo]
1719 tcTySig (L _ (IdSig id))
1720 = do { sig <- instTcTySigFromId id
1721 ; return [TcIdSig sig] }
1722
1723 tcTySig (L loc (TypeSig names sig_ty))
1724 = setSrcSpan loc $
1725 do { sigs <- sequence [ tcUserTypeSig sig_ty (Just name)
1726 | L _ name <- names ]
1727 ; return (map TcIdSig sigs) }
1728
1729 tcTySig (L loc (PatSynSig (L _ name) sig_ty))
1730 = setSrcSpan loc $
1731 do { tpsi <- tcPatSynSig name sig_ty
1732 ; return [TcPatSynSig tpsi] }
1733
1734 tcTySig _ = return []
1735
1736 isCompleteHsSig :: LHsSigWcType Name -> Bool
1737 -- ^ If there are no wildcards, return a LHsSigType
1738 isCompleteHsSig sig_ty
1739 | HsWC { hswc_wcs = wcs, hswc_ctx = extra } <- hsib_body sig_ty
1740 , null wcs
1741 , Nothing <- extra
1742 = True
1743 | otherwise
1744 = False
1745
1746 tcUserTypeSig :: LHsSigWcType Name -> Maybe Name -> TcM TcIdSigInfo
1747 -- Just n => Function type signatre name :: type
1748 -- Nothing => Expression type signature <expr> :: type
1749 tcUserTypeSig hs_sig_ty mb_name
1750 | isCompleteHsSig hs_sig_ty
1751 = pushTcLevelM_ $ -- When instantiating the signature, do so "one level in"
1752 -- so that they can be unified under the forall
1753 do { sigma_ty <- tcHsSigWcType ctxt_F hs_sig_ty
1754 ; (inst_tvs, theta, tau) <- tcInstType tcInstSigTyVars sigma_ty
1755 ; loc <- getSrcSpanM
1756 ; return $
1757 TISI { sig_bndr = CompleteSig (mkLocalId name sigma_ty)
1758 , sig_skols = findScopedTyVars sigma_ty inst_tvs
1759 , sig_theta = theta
1760 , sig_tau = tau
1761 , sig_ctxt = ctxt_T
1762 , sig_loc = loc } }
1763
1764 -- Partial sig with wildcards
1765 | HsIB { hsib_vars = vars, hsib_body = wc_ty } <- hs_sig_ty
1766 , HsWC { hswc_wcs = wcs, hswc_ctx = extra, hswc_body = hs_ty } <- wc_ty
1767 , (hs_tvs, L _ hs_ctxt, hs_tau) <- splitLHsSigmaTy hs_ty
1768 = do { (vars1, (wcs, tvs2, theta, tau))
1769 <- pushTcLevelM_ $
1770 -- When instantiating the signature, do so "one level in"
1771 -- so that they can be unified under the forall
1772 tcImplicitTKBndrs vars $
1773 tcWildCardBinders wcs $ \ wcs ->
1774 tcExplicitTKBndrs hs_tvs $ \ tvs2 ->
1775 do { -- Instantiate the type-class context; but if there
1776 -- is an extra-constraints wildcard, just discard it here
1777 traceTc "tcPartial" (ppr name $$ ppr vars $$ ppr wcs)
1778 ; theta <- mapM tcLHsPredType $
1779 case extra of
1780 Nothing -> hs_ctxt
1781 Just _ -> dropTail 1 hs_ctxt
1782
1783 ; tau <- tcHsOpenType hs_tau
1784
1785 -- zonking is necessary to establish type representation
1786 -- invariants
1787 ; theta <- zonkTcTypes theta
1788 ; tau <- zonkTcType tau
1789
1790 -- Check for validity (eg rankN etc)
1791 -- The ambiguity check will happen (from checkValidType),
1792 -- but unnecessarily; it will always succeed because there
1793 -- is no quantification
1794 ; checkValidType ctxt_F (mkPhiTy theta tau)
1795 -- NB: Do this in the context of the pushTcLevel so that
1796 -- the TcLevel invariant is respected
1797
1798 ; let bound_tvs
1799 = unionVarSets [ allBoundVariabless theta
1800 , allBoundVariables tau
1801 , mkVarSet (map snd wcs) ]
1802 ; return ((wcs, tvs2, theta, tau), bound_tvs) }
1803
1804 ; loc <- getSrcSpanM
1805 ; return $
1806 TISI { sig_bndr = PartialSig { sig_name = name, sig_hs_ty = hs_ty
1807 , sig_cts = extra, sig_wcs = wcs }
1808 , sig_skols = [ (tyVarName tv, tv) | tv <- vars1 ++ tvs2 ]
1809 , sig_theta = theta
1810 , sig_tau = tau
1811 , sig_ctxt = ctxt_F
1812 , sig_loc = loc } }
1813 where
1814 name = case mb_name of
1815 Just n -> n
1816 Nothing -> mkUnboundName (mkVarOcc "<expression>")
1817 ctxt_F = case mb_name of
1818 Just n -> FunSigCtxt n False
1819 Nothing -> ExprSigCtxt
1820 ctxt_T = case mb_name of
1821 Just n -> FunSigCtxt n True
1822 Nothing -> ExprSigCtxt
1823
1824 instTcTySigFromId :: Id -> TcM TcIdSigInfo
1825 -- Used for instance methods and record selectors
1826 instTcTySigFromId id
1827 = do { let name = idName id
1828 loc = getSrcSpan name
1829 ; (tvs, theta, tau) <- tcInstType (tcInstSigTyVarsLoc loc)
1830 (idType id)
1831 ; return $ TISI { sig_bndr = CompleteSig id
1832 , sig_skols = [(tyVarName tv, tv) | tv <- tvs]
1833 -- These are freshly instantiated, so although
1834 -- we put them in the type envt, doing so has
1835 -- no effect
1836 , sig_theta = theta
1837 , sig_tau = tau
1838 , sig_ctxt = FunSigCtxt name False
1839 -- False: do not report redundant constraints
1840 -- The user has no control over the signature!
1841 , sig_loc = loc } }
1842
1843 instTcTySig :: UserTypeCtxt
1844 -> LHsSigType Name -- Used to get the scoped type variables
1845 -> TcType
1846 -> Name -- Name of the function
1847 -> TcM TcIdSigInfo
1848 instTcTySig ctxt hs_ty sigma_ty name
1849 = do { (inst_tvs, theta, tau) <- tcInstType tcInstSigTyVars sigma_ty
1850 ; return (TISI { sig_bndr = CompleteSig (mkLocalIdOrCoVar name sigma_ty)
1851 , sig_skols = findScopedTyVars sigma_ty inst_tvs
1852 , sig_theta = theta
1853 , sig_tau = tau
1854 , sig_ctxt = ctxt
1855 , sig_loc = getLoc (hsSigType hs_ty)
1856 -- SrcSpan from the signature
1857 }) }
1858
1859 -------------------------------
1860 data GeneralisationPlan
1861 = NoGen -- No generalisation, no AbsBinds
1862
1863 | InferGen -- Implicit generalisation; there is an AbsBinds
1864 Bool -- True <=> apply the MR; generalise only unconstrained type vars
1865
1866 | CheckGen (LHsBind Name) TcIdSigInfo
1867 -- One FunBind with a signature
1868 -- Explicit generalisation; there is an AbsBindsSig
1869
1870 -- A consequence of the no-AbsBinds choice (NoGen) is that there is
1871 -- no "polymorphic Id" and "monmomorphic Id"; there is just the one
1872
1873 instance Outputable GeneralisationPlan where
1874 ppr NoGen = text "NoGen"
1875 ppr (InferGen b) = text "InferGen" <+> ppr b
1876 ppr (CheckGen _ s) = text "CheckGen" <+> ppr s
1877
1878 decideGeneralisationPlan
1879 :: DynFlags -> TcTypeEnv -> [Name]
1880 -> [LHsBind Name] -> TcSigFun -> GeneralisationPlan
1881 decideGeneralisationPlan dflags type_env bndr_names lbinds sig_fn
1882 | unlifted_pat_binds = NoGen
1883 | Just bind_sig <- one_funbind_with_sig = sig_plan bind_sig
1884 | mono_local_binds = NoGen
1885 | otherwise = InferGen mono_restriction
1886 where
1887 bndr_set = mkNameSet bndr_names
1888 binds = map unLoc lbinds
1889
1890 sig_plan :: (LHsBind Name, TcIdSigInfo) -> GeneralisationPlan
1891 -- See Note [Partial type signatures and generalisation]
1892 -- We use InferGen False to say "do inference, but do not apply
1893 -- the MR". It's stupid to apply the MR when we are given a
1894 -- signature! C.f Trac #11016, function f2
1895 sig_plan (lbind, sig@(TISI { sig_bndr = s_bndr, sig_theta = theta }))
1896 = case s_bndr of
1897 CompleteSig {} -> CheckGen lbind sig
1898 PartialSig { sig_cts = extra_constraints }
1899 | Nothing <- extra_constraints
1900 , [] <- theta
1901 -> InferGen True -- No signature constraints: apply the MR
1902 | otherwise
1903 -> InferGen False -- Don't apply the MR
1904
1905 unlifted_pat_binds = any isUnliftedHsBind binds
1906 -- Unlifted patterns (unboxed tuple) must not
1907 -- be polymorphic, because we are going to force them
1908 -- See Trac #4498, #8762
1909
1910 mono_restriction = xopt LangExt.MonomorphismRestriction dflags
1911 && any restricted binds
1912
1913 is_closed_ns :: NameSet -> Bool -> Bool
1914 is_closed_ns ns b = foldNameSet ((&&) . is_closed_id) b ns
1915 -- ns are the Names referred to from the RHS of this bind
1916
1917 is_closed_id :: Name -> Bool
1918 -- See Note [Bindings with closed types] in TcRnTypes
1919 is_closed_id name
1920 | name `elemNameSet` bndr_set
1921 = True -- Ignore binders in this groups, of course
1922 | Just thing <- lookupNameEnv type_env name
1923 = case thing of
1924 ATcId { tct_closed = cl } -> isTopLevel cl -- This is the key line
1925 ATyVar {} -> False -- In-scope type variables
1926 AGlobal {} -> True -- are not closed!
1927 _ -> pprPanic "is_closed_id" (ppr name)
1928 | otherwise
1929 = WARN( isInternalName name, ppr name ) True
1930 -- The free-var set for a top level binding mentions
1931 -- imported things too, so that we can report unused imports
1932 -- These won't be in the local type env.
1933 -- Ditto class method etc from the current module
1934
1935 mono_local_binds = xopt LangExt.MonoLocalBinds dflags
1936 && not closed_flag
1937
1938 closed_flag = foldr (is_closed_ns . bind_fvs) True binds
1939
1940 no_sig n = noCompleteSig (sig_fn n)
1941
1942 -- With OutsideIn, all nested bindings are monomorphic
1943 -- except a single function binding with a signature
1944 one_funbind_with_sig
1945 | [lbind@(L _ (FunBind { fun_id = v }))] <- lbinds
1946 , Just (TcIdSig sig) <- sig_fn (unLoc v)
1947 = Just (lbind, sig)
1948 | otherwise
1949 = Nothing
1950
1951 -- The Haskell 98 monomorphism restriction
1952 restricted (PatBind {}) = True
1953 restricted (VarBind { var_id = v }) = no_sig v
1954 restricted (FunBind { fun_id = v, fun_matches = m }) = restricted_match m
1955 && no_sig (unLoc v)
1956 restricted (PatSynBind {}) = panic "isRestrictedGroup/unrestricted PatSynBind"
1957 restricted (AbsBinds {}) = panic "isRestrictedGroup/unrestricted AbsBinds"
1958 restricted (AbsBindsSig {}) = panic "isRestrictedGroup/unrestricted AbsBindsSig"
1959
1960 restricted_match (MG { mg_alts = L _ (L _ (Match _ [] _ _) : _ )}) = True
1961 restricted_match _ = False
1962 -- No args => like a pattern binding
1963 -- Some args => a function binding
1964
1965 -------------------
1966 checkStrictBinds :: TopLevelFlag -> RecFlag
1967 -> [LHsBind Name]
1968 -> LHsBinds TcId -> [Id]
1969 -> TcM ()
1970 -- Check that non-overloaded unlifted bindings are
1971 -- a) non-recursive,
1972 -- b) not top level,
1973 -- c) not a multiple-binding group (more or less implied by (a))
1974
1975 checkStrictBinds top_lvl rec_group orig_binds tc_binds poly_ids
1976 | any_unlifted_bndr || any_strict_pat -- This binding group must be matched strictly
1977 = do { check (isNotTopLevel top_lvl)
1978 (strictBindErr "Top-level" any_unlifted_bndr orig_binds)
1979 ; check (isNonRec rec_group)
1980 (strictBindErr "Recursive" any_unlifted_bndr orig_binds)
1981
1982 ; check (all is_monomorphic (bagToList tc_binds))
1983 (polyBindErr orig_binds)
1984 -- data Ptr a = Ptr Addr#
1985 -- f x = let p@(Ptr y) = ... in ...
1986 -- Here the binding for 'p' is polymorphic, but does
1987 -- not mix with an unlifted binding for 'y'. You should
1988 -- use a bang pattern. Trac #6078.
1989
1990 ; check (isSingleton orig_binds)
1991 (strictBindErr "Multiple" any_unlifted_bndr orig_binds)
1992
1993 -- Complain about a binding that looks lazy
1994 -- e.g. let I# y = x in ...
1995 -- Remember, in checkStrictBinds we are going to do strict
1996 -- matching, so (for software engineering reasons) we insist
1997 -- that the strictness is manifest on each binding
1998 -- However, lone (unboxed) variables are ok
1999 ; check (not any_pat_looks_lazy)
2000 (unliftedMustBeBang orig_binds) }
2001 | otherwise
2002 = traceTc "csb2" (ppr [(id, idType id) | id <- poly_ids]) >>
2003 return ()
2004 where
2005 any_unlifted_bndr = any is_unlifted poly_ids
2006 any_strict_pat = any (isUnliftedHsBind . unLoc) orig_binds
2007 any_pat_looks_lazy = any (looksLazyPatBind . unLoc) orig_binds
2008
2009 is_unlifted id = case tcSplitSigmaTy (idType id) of
2010 (_, _, rho) -> isUnliftedType rho
2011 -- For the is_unlifted check, we need to look inside polymorphism
2012 -- and overloading. E.g. x = (# 1, True #)
2013 -- would get type forall a. Num a => (# a, Bool #)
2014 -- and we want to reject that. See Trac #9140
2015
2016 is_monomorphic (L _ (AbsBinds { abs_tvs = tvs, abs_ev_vars = evs }))
2017 = null tvs && null evs
2018 is_monomorphic (L _ (AbsBindsSig { abs_tvs = tvs, abs_ev_vars = evs }))
2019 = null tvs && null evs
2020 is_monomorphic _ = True
2021
2022 check :: Bool -> MsgDoc -> TcM ()
2023 -- Just like checkTc, but with a special case for module GHC.Prim:
2024 -- see Note [Compiling GHC.Prim]
2025 check True _ = return ()
2026 check False err = do { mod <- getModule
2027 ; checkTc (mod == gHC_PRIM) err }
2028
2029 unliftedMustBeBang :: [LHsBind Name] -> SDoc
2030 unliftedMustBeBang binds
2031 = hang (text "Pattern bindings containing unlifted types should use an outermost bang pattern:")
2032 2 (vcat (map ppr binds))
2033
2034 polyBindErr :: [LHsBind Name] -> SDoc
2035 polyBindErr binds
2036 = hang (text "You can't mix polymorphic and unlifted bindings")
2037 2 (vcat [vcat (map ppr binds),
2038 text "Probable fix: add a type signature"])
2039
2040 strictBindErr :: String -> Bool -> [LHsBind Name] -> SDoc
2041 strictBindErr flavour any_unlifted_bndr binds
2042 = hang (text flavour <+> msg <+> text "aren't allowed:")
2043 2 (vcat (map ppr binds))
2044 where
2045 msg | any_unlifted_bndr = text "bindings for unlifted types"
2046 | otherwise = text "bang-pattern or unboxed-tuple bindings"
2047
2048
2049 {- Note [Compiling GHC.Prim]
2050 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2051 Module GHC.Prim has no source code: it is the host module for
2052 primitive, built-in functions and types. However, for Haddock-ing
2053 purposes we generate (via utils/genprimopcode) a fake source file
2054 GHC/Prim.hs, and give it to Haddock, so that it can generate
2055 documentation. It contains definitions like
2056 nullAddr# :: NullAddr#
2057 which would normally be rejected as a top-level unlifted binding. But
2058 we don't want to complain, because we are only "compiling" this fake
2059 mdule for documentation purposes. Hence this hacky test for gHC_PRIM
2060 in checkStrictBinds.
2061
2062 (We only make the test if things look wrong, so there is no cost in
2063 the common case.) -}
2064
2065
2066 {- *********************************************************************
2067 * *
2068 Error contexts and messages
2069 * *
2070 ********************************************************************* -}
2071
2072 -- This one is called on LHS, when pat and grhss are both Name
2073 -- and on RHS, when pat is TcId and grhss is still Name
2074 patMonoBindsCtxt :: (OutputableBndr id, Outputable body) => LPat id -> GRHSs Name body -> SDoc
2075 patMonoBindsCtxt pat grhss
2076 = hang (text "In a pattern binding:") 2 (pprPatBind pat grhss)
2077
2078 typeSigCtxt :: UserTypeCtxt -> TcIdSigBndr -> SDoc
2079 typeSigCtxt ctxt (PartialSig { sig_hs_ty = hs_ty })
2080 = pprSigCtxt ctxt empty (ppr hs_ty)
2081 typeSigCtxt ctxt (CompleteSig id)
2082 = pprSigCtxt ctxt empty (ppr (idType id))
2083
2084 instErrCtxt :: Name -> TcType -> TidyEnv -> TcM (TidyEnv, SDoc)
2085 instErrCtxt name ty env
2086 = do { let (env', ty') = tidyOpenType env ty
2087 ; return (env', hang (text "When instantiating" <+> quotes (ppr name) <>
2088 text ", initially inferred to have" $$
2089 text "this overly-general type:")
2090 2 (ppr ty') $$
2091 extra) }
2092 where
2093 extra = sdocWithDynFlags $ \dflags ->
2094 ppWhen (xopt LangExt.MonomorphismRestriction dflags) $
2095 text "NB: This instantiation can be caused by the" <+>
2096 text "monomorphism restriction."